ConfigureChecks.cmake

   1 include(CheckIncludeFile)
   2 include(CheckSymbolExists)
   3 include(CheckFunctionExists)
   4 include(CheckLibraryExists)
   5 include(CheckTypeSize)
   6 include(CheckStructHasMember)
   7 include(CheckPrototypeDefinition)
   8 include(TestBigEndian)
   9
  10 set(PACKAGE ${APPLICATION_NAME})
  11 set(VERSION ${APPLICATION_VERSION})
  12 set(DATADIR ${DATA_INSTALL_DIR})
  13 set(LIBDIR ${LIB_INSTALL_DIR})
  14 set(PLUGINDIR "${PLUGIN_INSTALL_DIR}-${LIBRARY_SOVERSION}")
  15 set(SYSCONFDIR ${SYSCONF_INSTALL_DIR})
  16
  17 set(BINARYDIR ${CMAKE_BINARY_DIR})
  18 set(SOURCEDIR ${CMAKE_SOURCE_DIR})
  19
  20 function(COMPILER_DUMPVERSION _OUTPUT_VERSION)
  21     # Remove whitespaces from the argument.
  22     # This is needed for CC="ccache gcc" cmake ..
  23     string(REPLACE " " "" _C_COMPILER_ARG "${CMAKE_C_COMPILER_ARG1}")
  24
  25     execute_process(
  26         COMMAND
  27             ${CMAKE_C_COMPILER} ${_C_COMPILER_ARG} -dumpversion
  28         OUTPUT_VARIABLE _COMPILER_VERSION
  29     )
  30
  31     string(REGEX REPLACE "([0-9])\\.([0-9])(\\.[0-9])?" "\\1\\2"
  32            _COMPILER_VERSION "${_COMPILER_VERSION}")
  33
  34     set(${_OUTPUT_VERSION} ${_COMPILER_VERSION} PARENT_SCOPE)
  35 endfunction()
  36
  37 if(CMAKE_COMPILER_IS_GNUCC AND NOT MINGW AND NOT OS2)
  38     compiler_dumpversion(GNUCC_VERSION)
  39     if (NOT GNUCC_VERSION EQUAL 34)
  40         set(CMAKE_REQUIRED_FLAGS "-fvisibility=hidden")
  41         check_c_source_compiles(
  42 "void __attribute__((visibility(\"default\"))) test() {}
  43 int main(void){ return 0; }
  44 " WITH_VISIBILITY_HIDDEN)
  45         set(CMAKE_REQUIRED_FLAGS "")
  46     endif (NOT GNUCC_VERSION EQUAL 34)
  47 endif(CMAKE_COMPILER_IS_GNUCC AND NOT MINGW AND NOT OS2)
  48
  49 # HEADERS
  50 check_include_file(sys/filio.h HAVE_SYS_FILIO_H)
  51 check_include_file(sys/signalfd.h HAVE_SYS_SIGNALFD_H)
  52 check_include_file(sys/eventfd.h HAVE_SYS_EVENTFD_H)
  53 check_include_file(sys/timerfd.h HAVE_SYS_TIMERFD_H)
  54 check_include_file(gnu/lib-names.h HAVE_GNU_LIB_NAMES_H)
  55 check_include_file(rpc/rpc.h HAVE_RPC_RPC_H)
  56
  57 # FUNCTIONS
  58 check_function_exists(strncpy HAVE_STRNCPY)
  59 check_function_exists(vsnprintf HAVE_VSNPRINTF)
  60 check_function_exists(snprintf HAVE_SNPRINTF)
  61 check_function_exists(signalfd HAVE_SIGNALFD)
  62 check_function_exists(eventfd HAVE_EVENTFD)
  63 check_function_exists(timerfd_create HAVE_TIMERFD_CREATE)
  64 check_function_exists(bindresvport HAVE_BINDRESVPORT)
  65
  66
  67 if (UNIX)
  68     if (NOT LINUX)
  69         # libsocket (Solaris)
  70         check_library_exists(socket getaddrinfo "" HAVE_LIBSOCKET)
  71         if (HAVE_LIBSOCKET)
  72           set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} socket)
  73         endif (HAVE_LIBSOCKET)
  74
  75         # libnsl/inet_pton (Solaris)
  76         check_library_exists(nsl inet_pton "" HAVE_LIBNSL)
  77         if (HAVE_LIBNSL)
  78             set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} nsl)
  79         endif (HAVE_LIBNSL)
  80     endif (NOT LINUX)
  81
  82     check_function_exists(getaddrinfo HAVE_GETADDRINFO)
  83 endif (UNIX)
  84
  85 set(SWRAP_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} CACHE INTERNAL "socket_wrapper required system libraries")
  86
  87 # STRUCTS
  88 check_struct_has_member("struct in_pktinfo" ipi_addr "sys/types.h;sys/socket.h;netinet/in.h" HAVE_STRUCT_IN_PKTINFO)
  89 set(CMAKE_REQUIRED_FLAGS -D_GNU_SOURCE)
  90 check_struct_has_member("struct in6_pktinfo" ipi6_addr "sys/types.h;sys/socket.h;netinet/in.h" HAVE_STRUCT_IN6_PKTINFO)
  91 set(CMAKE_REQUIRED_FLAGS)
  92
  93 # STRUCT MEMBERS
  94 check_struct_has_member("struct sockaddr" sa_len "sys/types.h;sys/socket.h;netinet/in.h" HAVE_STRUCT_SOCKADDR_SA_LEN)
  95 check_struct_has_member("struct msghdr" msg_control "sys/types.h;sys/socket.h" HAVE_STRUCT_MSGHDR_MSG_CONTROL)
  96
  97 # PROTOTYPES
  98 check_prototype_definition(gettimeofday
  99     "int gettimeofday(struct timeval *tv, struct timezone *tz)"
 100     "-1"
 101     "sys/time.h"
 102     HAVE_GETTIMEOFDAY_TZ)
 103
 104 check_prototype_definition(gettimeofday
 105     "int gettimeofday(struct timeval *tv, void *tzp)"
 106     "-1"
 107     "sys/time.h"
 108     HAVE_GETTIMEOFDAY_TZ_VOID)
 109
 110 check_prototype_definition(accept
 111     "int accept(int s, struct sockaddr *addr, Psocklen_t addrlen)"
 112     "-1"
 113     "sys/types.h;sys/socket.h"
 114     HAVE_ACCEPT_PSOCKLEN_T)
 115
 116 check_prototype_definition(ioctl
 117     "int ioctl(int s, int r, ...)"
 118     "-1"
 119     "unistd.h;sys/ioctl.h"
 120     HAVE_IOCTL_INT)
 121
 122 if (HAVE_EVENTFD)
 123     check_prototype_definition(eventfd
 124         "int eventfd(unsigned int count, int flags)"
 125         "-1"
 126         "sys/eventfd.h"
 127         HAVE_EVENTFD_UNSIGNED_INT)
 128 endif (HAVE_EVENTFD)
 129
 130 # IPV6
 131 check_c_source_compiles("
 132     #include <stdlib.h>
 133     #include <sys/socket.h>
 134     #include <netdb.h>
 135     #include <netinet/in.h>
 136     #include <net/if.h>
 137
 138 int main(void) {
 139     struct sockaddr_storage sa_store;
 140     struct addrinfo *ai = NULL;
 141     struct in6_addr in6addr;
 142     int idx = if_nametoindex(\"iface1\");
 143     int s = socket(AF_INET6, SOCK_STREAM, 0);
 144     int ret = getaddrinfo(NULL, NULL, NULL, &ai);
 145     if (ret != 0) {
 146         const char *es = gai_strerror(ret);
 147     }
 148
 149     freeaddrinfo(ai);
 150     {
 151         int val = 1;
 152 #ifdef HAVE_LINUX_IPV6_V6ONLY_26
 153 #define IPV6_V6ONLY 26
 154 #endif
 155         ret = setsockopt(s, IPPROTO_IPV6, IPV6_V6ONLY,
 156                          (const void *)&val, sizeof(val));
 157     }
 158
 159     return 0;
 160 }" HAVE_IPV6)
 161
 162 check_c_source_compiles("
 163 #include <sys/socket.h>
 164
 165 int main(void) {
 166     struct sockaddr_storage s;
 167
 168     return 0;
 169 }" HAVE_SOCKADDR_STORAGE)
 170
 171 check_c_source_compiles("
 172 void test_destructor_attribute(void) __attribute__ ((destructor));
 173
 174 void test_destructor_attribute(void)
 175 {
 176     return;
 177 }
 178
 179 int main(void) {
 180     return 0;
 181 }" HAVE_DESTRUCTOR_ATTRIBUTE)
 182
 183 check_c_source_compiles("
 184 __thread int tls;
 185
 186 int main(void) {
 187     return 0;
 188 }" HAVE_GCC_THREAD_LOCAL_STORAGE)
 189
 190 check_c_source_compiles("
 191 void log_fn(const char *format, ...) __attribute__ ((format (printf, 1, 2)));
 192
 193 int main(void) {
 194     return 0;
 195 }" HAVE_FUNCTION_ATTRIBUTE_FORMAT)
 196
 197 # If this produces a warning treat it as error!
 198 set(CMAKE_REQUIRED_FLAGS "-Werror")
 199 check_c_source_compiles("
 200 void test_address_sanitizer_attribute(void) __attribute__((no_sanitize_address));
 201
 202 void test_address_sanitizer_attribute(void)
 203 {
 204     return;
 205 }
 206
 207 int main(void) {
 208     return 0;
 209 }" HAVE_ADDRESS_SANITIZER_ATTRIBUTE)
 210 set(CMAKE_REQUIRED_FLAGS)
 211
 212 check_library_exists(dl dlopen "" HAVE_LIBDL)
 213 if (HAVE_LIBDL)
 214     find_library(DLFCN_LIBRARY dl)
 215     set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} ${DLFCN_LIBRARY})
 216 endif (HAVE_LIBDL)
 217
 218 if (OSX)
 219     set(HAVE_APPLE 1)
 220 endif (OSX)
 221
 222 # ENDIAN
 223 if (NOT WIN32)
 224     test_big_endian(WORDS_BIGENDIAN)
 225 endif (NOT WIN32)
 226
 227 check_type_size(pid_t SIZEOF_PID_T)
 228
 229 set(SWRAP_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} CACHE INTERNAL "swrap required system libraries")