source/build/smb_build/input.pm

   1 # Samba Build System
   2 # - the input checking functions
   3 #
   4 #  Copyright (C) Stefan (metze) Metzmacher 2004
   5 #  Copyright (C) Jelmer Vernooij 2004
   6 #  Released under the GNU GPL
   7
   8 use smb_build::config;
   9 use strict;
  10 package smb_build::input;
  11 use File::Basename;
  12
  13 my $srcdir = $config::config{srcdir};
  14
  15 sub strtrim($)
  16 {
  17         $_ = shift;
  18         s/^[\t\n ]*//g;
  19         s/[\t\n ]*$//g;
  20         return $_;
  21 }
  22
  23 sub str2array($)
  24 {
  25         $_ = shift;
  26         s/^[\t\n ]*//g;
  27         s/[\t\n ]*$//g;
  28         s/([\t\n ]+)/ /g;
  29
  30         return () if (length($_)==0);
  31         return split /[ \t\n]/;
  32 }
  33
  34 sub add_libreplace($)
  35 {
  36         my ($part) = @_;
  37
  38         return if ($part->{NAME} eq "LIBREPLACE");
  39         return if ($part->{NAME} eq "LIBREPLACE_HOSTCC");
  40         return if ($part->{NAME} eq "REPLACE_READDIR");
  41
  42         foreach my $n (@{$part->{PRIVATE_DEPENDENCIES}}) {
  43                 return if ($n eq "LIBREPLACE");
  44                 return if ($n eq "LIBREPLACE_HOSTCC");
  45         }
  46         foreach my $n (@{$part->{PUBLIC_DEPENDENCIES}}) {
  47                 return if ($n eq "LIBREPLACE");
  48                 return if ($n eq "LIBREPLACE_HOSTCC");
  49         }
  50
  51         if (defined($part->{USE_HOSTCC}) && $part->{USE_HOSTCC} eq "YES") {
  52                 unshift (@{$part->{PRIVATE_DEPENDENCIES}}, "LIBREPLACE_HOSTCC");
  53         } else {
  54                 unshift (@{$part->{PRIVATE_DEPENDENCIES}}, "LIBREPLACE");
  55         }
  56 }
  57
  58 sub check_subsystem($$$)
  59 {
  60         my ($INPUT, $subsys, $default_ot) = @_;
  61         return if ($subsys->{ENABLE} ne "YES");
  62
  63         unless(defined($subsys->{OUTPUT_TYPE})) {
  64                 $subsys->{OUTPUT_TYPE} = $default_ot;
  65         }
  66
  67         unless (defined($subsys->{INIT_FUNCTION_TYPE})) { $subsys->{INIT_FUNCTION_TYPE} = "NTSTATUS (*) (void)"; }
  68         unless (defined($subsys->{INIT_FUNCTION_SENTINEL})) { $subsys->{INIT_FUNCTION_SENTINEL} = "NULL"; }
  69
  70         add_libreplace($subsys);
  71 }
  72
  73 sub check_module($$$)
  74 {
  75         my ($INPUT, $mod, $default_ot) = @_;
  76
  77         die("Module $mod->{NAME} does not have a SUBSYSTEM set") if not defined($mod->{SUBSYSTEM});
  78
  79         if (not exists($INPUT->{$mod->{SUBSYSTEM}}{INIT_FUNCTIONS})) {
  80                 $INPUT->{$mod->{SUBSYSTEM}}{INIT_FUNCTIONS} = [];
  81         }
  82
  83         if (!(defined($INPUT->{$mod->{SUBSYSTEM}}))) {
  84                 $mod->{ENABLE} = "NO";
  85                 return;
  86         }
  87
  88         if ($INPUT->{$mod->{SUBSYSTEM}} eq "NO") {
  89                 $mod->{ENABLE} = "NO";
  90                 return;
  91         }
  92
  93         return if ($mod->{ENABLE} ne "YES");
  94
  95         if (exists($INPUT->{$mod->{SUBSYSTEM}}{INIT_FUNCTION_TYPE})) {
  96                 $mod->{INIT_FUNCTION_TYPE} = $INPUT->{$mod->{SUBSYSTEM}}{INIT_FUNCTION_TYPE};
  97         } else {
  98                 $mod->{INIT_FUNCTION_TYPE} = "NTSTATUS (*) (void)";
  99         }
 100
 101         if (not defined($mod->{OUTPUT_TYPE})) {
 102                 if ($INPUT->{$mod->{SUBSYSTEM}}->{TYPE} eq "EXT_LIB") {
 103                         $mod->{OUTPUT_TYPE} = ["SHARED_LIBRARY"];
 104                 } else {
 105                         $mod->{OUTPUT_TYPE} = $default_ot;
 106                 }
 107         }
 108
 109         if (grep(/SHARED_LIBRARY/, @{$mod->{OUTPUT_TYPE}})) {
 110                 my $sane_subsystem = lc($mod->{SUBSYSTEM});
 111                 $sane_subsystem =~ s/^lib//;
 112                 $mod->{INSTALLDIR} = "MODULESDIR/$sane_subsystem";
 113                 push (@{$mod->{PUBLIC_DEPENDENCIES}}, $mod->{SUBSYSTEM});
 114         }
 115         if (grep(/INTEGRATED/, @{$mod->{OUTPUT_TYPE}})) {
 116                 push (@{$INPUT->{$mod->{SUBSYSTEM}}{INIT_FUNCTIONS}}, $mod->{INIT_FUNCTION}) if defined($mod->{INIT_FUNCTION});
 117         }
 118         add_libreplace($mod);
 119 }
 120
 121 sub check_library($$$)
 122 {
 123         my ($INPUT, $lib, $default_ot) = @_;
 124
 125         return if ($lib->{ENABLE} ne "YES");
 126
 127         unless (defined($lib->{OUTPUT_TYPE})) { $lib->{OUTPUT_TYPE} = $default_ot; }
 128
 129         if (defined($lib->{VERSION}) and not defined($lib->{SO_VERSION})) {
 130                 print "$lib->{NAME}: Please specify SO_VERSION when specifying VERSION\n";
 131                 return;
 132         }
 133
 134         if (defined($lib->{SO_VERSION}) and not defined($lib->{VERSION})) {
 135                 print "$lib->{NAME}: Please specify VERSION when specifying SO_VERSION\n";
 136                 return;
 137         }
 138
 139         unless (defined($lib->{INIT_FUNCTION_TYPE})) { $lib->{INIT_FUNCTION_TYPE} = "NTSTATUS (*) (void)"; }
 140         unless (defined($lib->{INIT_FUNCTION_SENTINEL})) { $lib->{INIT_FUNCTION_SENTINEL} = "NULL"; }
 141         unless (defined($lib->{INSTALLDIR})) { $lib->{INSTALLDIR} = "LIBDIR"; }
 142
 143         add_libreplace($lib);
 144 }
 145
 146 sub check_python($$$)
 147 {
 148         my ($INPUT, $python, $default_ot) = @_;
 149
 150         return if ($INPUT->{LIBPYTHON}{ENABLE} ne "YES");
 151
 152         $python->{INSTALLDIR} = "PYTHONDIR";
 153         unless (defined($python->{CFLAGS})) { $python->{CFLAGS} = []; }
 154         if (defined($python->{SWIG_FILE})) {
 155                 my $dirname = dirname($python->{SWIG_FILE});
 156                 my $basename = basename($python->{SWIG_FILE}, ".i");
 157
 158                 $dirname .= "/" unless $dirname =~ /\/$/;
 159                 $dirname = "" if $dirname eq "./";
 160
 161                 $python->{OBJ_FILES} = ["$dirname$basename\_wrap.o"];
 162                 $python->{LIBRARY_REALNAME} = "_$basename.\$(SHLIBEXT)";
 163                 $python->{PYTHON_FILES} = ["$dirname$basename.py"];
 164                 push (@{$python->{CFLAGS}}, $config::config{CFLAG_NO_UNUSED_MACROS});
 165                 push (@{$python->{CFLAGS}}, $config::config{CFLAG_NO_CAST_QUAL});
 166                 $python->{INIT_FUNCTION} = "{ (char *)\"_$basename\", init_$basename }";
 167         } else {
 168                 my $basename = $python->{NAME};
 169                 $basename =~ s/^python_//g;
 170                 $python->{LIBRARY_REALNAME} = "$basename.\$(SHLIBEXT)";
 171                 $python->{INIT_FUNCTION} = "{ (char *)\"$basename\", init$basename }";
 172         }
 173         push (@{$python->{CFLAGS}}, @{$INPUT->{EXT_LIB_PYTHON}->{CFLAGS}});
 174
 175         $python->{SUBSYSTEM} = "LIBPYTHON";
 176
 177         check_module($INPUT, $python, $default_ot);
 178 }
 179
 180 sub check_binary($$)
 181 {
 182         my ($INPUT, $bin) = @_;
 183
 184         return if ($bin->{ENABLE} ne "YES");
 185
 186         ($bin->{BINARY} = (lc $bin->{NAME})) if not defined($bin->{BINARY});
 187
 188         $bin->{OUTPUT_TYPE} = ["BINARY"];
 189         add_libreplace($bin);
 190 }
 191
 192 sub import_integrated($$)
 193 {
 194         my ($lib, $depend) = @_;
 195
 196         foreach my $mod (values %$depend) {
 197                 next if(not defined($mod->{OUTPUT_TYPE}));
 198                 next if(not grep(/INTEGRATED/, @{$mod->{OUTPUT_TYPE}}));
 199                 next if(not defined($mod->{SUBSYSTEM}));
 200                 next if($mod->{SUBSYSTEM} ne $lib->{NAME});
 201                 next if($mod->{ENABLE} ne "YES");
 202
 203                 push (@{$lib->{FULL_OBJ_LIST}}, "\$($mod->{NAME}_OBJ_LIST)");
 204                 push (@{$lib->{LINK_FLAGS}}, "\$($mod->{NAME}_LINK_FLAGS)");
 205                 push (@{$lib->{CFLAGS}}, @{$mod->{CFLAGS}}) if defined($mod->{CFLAGS});
 206                 push (@{$lib->{PUBLIC_DEPENDENCIES}}, @{$mod->{PUBLIC_DEPENDENCIES}}) if defined($mod->{PUBLIC_DEPENDENCIES});
 207                 push (@{$lib->{PRIVATE_DEPENDENCIES}}, @{$mod->{PRIVATE_DEPENDENCIES}}) if defined($mod->{PRIVATE_DEPENDENCIES});
 208
 209                 $mod->{ENABLE} = "NO";
 210         }
 211 }
 212
 213 sub calc_unique_deps($$$$$$$$)
 214 {
 215         sub calc_unique_deps($$$$$$$$);
 216         my ($name, $INPUT, $deps, $udeps, $withlibs, $forward, $pubonly, $busy) = @_;
 217
 218         foreach my $n (@$deps) {
 219                 die("Dependency unknown: $n (for $name)") unless (defined($INPUT->{$n}));
 220                 die("Recursive dependency: $n, list: " . join(',', @$busy)) if (grep (/^$n$/, @$busy));
 221                 next if (grep /^$n$/, @$udeps);
 222                 my $dep = $INPUT->{$n};
 223
 224                 push (@{$udeps}, $dep->{NAME}) if $forward;
 225
 226                 if (defined ($dep->{OUTPUT_TYPE}) &&
 227                         ($withlibs or
 228                         (@{$dep->{OUTPUT_TYPE}}[0] eq "INTEGRATED") or
 229                         (@{$dep->{OUTPUT_TYPE}}[0] eq "MERGED_OBJ") or
 230                         (@{$dep->{OUTPUT_TYPE}}[0] eq "STATIC_LIBRARY"))) {
 231                                 push (@$busy, $dep->{NAME});
 232                                 calc_unique_deps($dep->{NAME}, $INPUT, $dep->{PUBLIC_DEPENDENCIES}, $udeps, $withlibs, $forward, $pubonly, $busy);
 233                                 calc_unique_deps($dep->{NAME}, $INPUT, $dep->{PRIVATE_DEPENDENCIES}, $udeps, $withlibs, $forward, $pubonly, $busy) unless $pubonly;
 234                                 pop (@$busy);
 235                 }
 236
 237                 unshift (@{$udeps}, $dep->{NAME}) unless $forward;
 238         }
 239 }
 240
 241 sub check($$$$$)
 242 {
 243         my ($INPUT, $enabled, $subsys_ot, $lib_ot, $module_ot) = @_;
 244
 245         foreach my $part (values %$INPUT) {
 246                 unless (defined($part->{STANDARD_VISIBILITY})) {
 247                         if ($part->{TYPE} eq "MODULE" or $part->{TYPE} eq "BINARY") {
 248                                 $part->{STANDARD_VISIBILITY} = "hidden";
 249                         } else {
 250                                 $part->{STANDARD_VISIBILITY} = "default";
 251                         }
 252                 }
 253
 254                 unless (defined($part->{PUBLIC_HEADERS})) {
 255                         $part->{PUBLIC_HEADERS} = [];
 256                 }
 257
 258                 if (defined($part->{PUBLIC_PROTO_HEADER})) {
 259                         push (@{$part->{PUBLIC_HEADERS}}, $part->{PUBLIC_PROTO_HEADER});
 260                 }
 261
 262                 if (defined($enabled->{$part->{NAME}})) {
 263                         $part->{ENABLE} = $enabled->{$part->{NAME}};
 264                         next;
 265                 }
 266
 267                 unless(defined($part->{ENABLE})) {
 268                         if ($part->{TYPE} eq "EXT_LIB") {
 269                                 $part->{ENABLE} = "NO";
 270                         } else {
 271                                 $part->{ENABLE} = "YES";
 272                         }
 273                 }
 274         }
 275
 276         foreach my $part (values %$INPUT) {
 277                 $part->{LINK_FLAGS} = [];
 278                 $part->{FULL_OBJ_LIST} = ["\$($part->{NAME}_OBJ_LIST)"];
 279
 280                 if ($part->{TYPE} eq "SUBSYSTEM") {
 281                         check_subsystem($INPUT, $part, $subsys_ot);
 282                 } elsif ($part->{TYPE} eq "MODULE") {
 283                         check_module($INPUT, $part, $module_ot);
 284                 } elsif ($part->{TYPE} eq "LIBRARY") {
 285                         check_library($INPUT, $part, $lib_ot);
 286                 } elsif ($part->{TYPE} eq "BINARY") {
 287                         check_binary($INPUT, $part);
 288                 } elsif ($part->{TYPE} eq "PYTHON") {
 289                         check_python($INPUT, $part, $module_ot);
 290                 } elsif ($part->{TYPE} eq "EXT_LIB") {
 291                 } else {
 292                         die("Unknown type $part->{TYPE}");
 293                 }
 294         }
 295
 296         foreach my $part (values %$INPUT) {
 297                 if (defined($part->{INIT_FUNCTIONS})) {
 298                         push (@{$part->{LINK_FLAGS}}, "\$(DYNEXP)");
 299                 }
 300                 import_integrated($part, $INPUT);
 301         }
 302
 303         foreach my $part (values %$INPUT) {
 304                 $part->{UNIQUE_DEPENDENCIES_LINK} = [];
 305                 calc_unique_deps($part->{NAME}, $INPUT, $part->{PUBLIC_DEPENDENCIES}, $part->{UNIQUE_DEPENDENCIES_LINK}, 0, 0, 0, []);
 306                 calc_unique_deps($part->{NAME}, $INPUT, $part->{PRIVATE_DEPENDENCIES}, $part->{UNIQUE_DEPENDENCIES_LINK}, 0, 0, 0, []);
 307         }
 308
 309         foreach my $part (values %$INPUT) {
 310                 $part->{UNIQUE_DEPENDENCIES_COMPILE} = [];
 311                 calc_unique_deps($part->{NAME}, $INPUT, $part->{PUBLIC_DEPENDENCIES}, $part->{UNIQUE_DEPENDENCIES_COMPILE}, 1, 1, 1, []);
 312                 calc_unique_deps($part->{NAME}, $INPUT, $part->{PRIVATE_DEPENDENCIES}, $part->{UNIQUE_DEPENDENCIES_COMPILE}, 1, 1, 1, []);
 313         }
 314
 315         foreach my $part (values %$INPUT) {
 316                 $part->{UNIQUE_DEPENDENCIES_ALL} = [];
 317                 calc_unique_deps($part->{NAME}, $INPUT, $part->{PUBLIC_DEPENDENCIES}, $part->{UNIQUE_DEPENDENCIES_ALL}, 1, 0, 0, []);
 318                 calc_unique_deps($part->{NAME}, $INPUT, $part->{PRIVATE_DEPENDENCIES}, $part->{UNIQUE_DEPENDENCIES_ALL}, 1, 0, 0, []);
 319         }
 320
 321         return $INPUT;
 322 }
 323
 324 1;