configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([rsync],[ ],[https://rsync.samba.org/bug-tracking.html])
   4
   5 AC_C_BIGENDIAN
   6 AC_HEADER_DIRENT
   7 AC_HEADER_TIME
   8 AC_HEADER_SYS_WAIT
   9 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \
  10     unistd.h utime.h compat.h sys/param.h ctype.h sys/wait.h sys/stat.h \
  11     sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h grp.h \
  12     sys/un.h sys/attr.h arpa/inet.h arpa/nameser.h locale.h sys/types.h \
  13     netdb.h malloc.h float.h limits.h iconv.h libcharset.h langinfo.h mcheck.h \
  14     sys/acl.h acl/libacl.h attr/xattr.h sys/xattr.h sys/extattr.h dl.h \
  15     popt.h popt/popt.h linux/falloc.h netinet/in_systm.h netgroup.h \
  16     zlib.h xxhash.h openssl/md4.h openssl/md5.h zstd.h lz4.h sys/file.h)
  17 AC_CHECK_HEADERS([netinet/ip.h], [], [], [[#include <netinet/in.h>]])
  18 AC_HEADER_MAJOR_FIXED
  19
  20 AC_CONFIG_MACRO_DIR([m4])
  21 AC_CONFIG_SRCDIR([byteorder.h])
  22 AC_CONFIG_HEADER(config.h)
  23 AC_PREREQ([2.69])
  24
  25 PACKAGE_VERSION=`sed 's/.*"\(.*\)".*/\1/' <$srcdir/version.h`
  26
  27 AC_MSG_NOTICE([Configuring rsync $PACKAGE_VERSION])
  28
  29 LDFLAGS=${LDFLAGS-""}
  30
  31 AC_CANONICAL_HOST
  32
  33 dnl define the directory for replacement function since AC_LIBOBJ does not
  34 dnl officially support subdirs and fails with automake
  35 AC_CONFIG_LIBOBJ_DIR([lib])
  36
  37 # We must decide this before testing the compiler.
  38
  39 # Please allow this to default to yes, so that your users have more
  40 # chance of getting a useful stack trace if problems occur.
  41
  42 AC_MSG_CHECKING([whether to include debugging symbols])
  43 AC_ARG_ENABLE(debug,
  44         AS_HELP_STRING([--disable-debug],[disable to omit debugging symbols and features]))
  45
  46 if test x"$enable_debug" = x"no"; then
  47     AC_MSG_RESULT(no)
  48     ac_cv_prog_cc_g=no
  49 else
  50     AC_MSG_RESULT([yes])
  51     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  52     # leave ac_cv_prog_cc_g alone; AC_PROG_CC will try to include -g if it can
  53 fi
  54
  55 dnl Checks for programs.
  56 AC_PROG_CC
  57 AC_PROG_CPP
  58 AC_PROG_CXX
  59 AC_PROG_AWK
  60 AC_PROG_EGREP
  61 AC_PROG_INSTALL
  62 AC_PROG_MKDIR_P
  63 AC_PROG_CC_STDC
  64 AC_SUBST(SHELL)
  65 AC_PATH_PROG([PERL], [perl])
  66 AC_PATH_PROG([PYTHON3], [python3])
  67
  68 AC_DEFINE([_GNU_SOURCE], 1,
  69           [Define _GNU_SOURCE so that we get all necessary prototypes])
  70
  71 if test x"$ac_cv_prog_cc_stdc" = x"no"; then
  72         AC_MSG_WARN([rsync requires an ANSI C compiler and you do not seem to have one])
  73 fi
  74
  75 no_lib=''
  76 err_msg=''
  77 nl='
  78 '
  79
  80 AC_ARG_ENABLE(profile,
  81         AS_HELP_STRING([--enable-profile],[enable to turn on CPU profiling]))
  82 if test x"$enable_profile" = x"yes"; then
  83         CFLAGS="$CFLAGS -pg"
  84 fi
  85
  86 AC_MSG_CHECKING([if md2man can create man pages])
  87 if test x"$ac_cv_path_PYTHON3" = x; then
  88     AC_MSG_RESULT(no - python3 not found)
  89     md2man_works=no
  90 else
  91     md2man_out=`"$srcdir/md2man" --test "$srcdir/rsync-ssl.1.md" 2>&1`
  92     if test $? = 0; then
  93         AC_MSG_RESULT(yes)
  94         md2man_works=yes
  95     else
  96         AC_MSG_RESULT(no)
  97         md2man_works=no
  98         echo "$md2man_out"
  99     fi
 100 fi
 101
 102 AC_MSG_CHECKING([if we require man-page building])
 103 AC_ARG_ENABLE([md2man],
 104         AS_HELP_STRING([--disable-md2man],[disable to omit man page creation]))
 105 if test x"$enable_md2man" != x"no"; then
 106     if test -f "$srcdir/rsync.1"; then
 107         AC_MSG_RESULT(optional)
 108     else
 109         AC_MSG_RESULT(required)
 110         if test x"$md2man_works" = x"no"; then
 111             err_msg="$err_msg$nl- You need python3 and either the cmarkgfm OR commonmark python3 lib in order"
 112             err_msg="$err_msg$nl  to build man pages based on the git source (man pages are included in the"
 113             err_msg="$err_msg$nl  official release tar files)."
 114             no_lib="$no_lib md2man"
 115         fi
 116     fi
 117     MAKE_MAN=man
 118 else
 119     AC_MSG_RESULT(no)
 120     MAKE_MAN=''
 121 fi
 122
 123 # Specifically, this turns on panic_action handling.
 124 AC_ARG_ENABLE(maintainer-mode,
 125         AS_HELP_STRING([--enable-maintainer-mode],[enable to turn on extra debug features]))
 126 if test x"$enable_maintainer_mode" = x"yes"; then
 127         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
 128 fi
 129
 130 # This is needed for our included version of popt.  Kind of silly, but
 131 # I don't want our version too far out of sync.
 132 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
 133
 134 # If GCC, turn on warnings.
 135 if test x"$GCC" = x"yes"; then
 136         CFLAGS="$CFLAGS -Wall -W"
 137 fi
 138
 139 AC_ARG_WITH(included-popt,
 140         AS_HELP_STRING([--with-included-popt],[use bundled popt library, not from system]))
 141
 142 AC_ARG_WITH(included-zlib,
 143         AS_HELP_STRING([--with-included-zlib],[use bundled zlib library, not from system]))
 144
 145 AC_ARG_WITH(protected-args,
 146         AS_HELP_STRING([--with-protected-args],[make --protected-args option the default]))
 147 if test x"$with_protected_args" = x"yes"; then
 148         AC_DEFINE_UNQUOTED(RSYNC_USE_PROTECTED_ARGS, 1, [Define to 1 if --protected-args should be the default])
 149 fi
 150
 151 AC_ARG_WITH(rsync-path,
 152         AS_HELP_STRING([--with-rsync-path=PATH],[set default --rsync-path to PATH (default: rsync)]),
 153         [ RSYNC_PATH="$with_rsync_path" ],
 154         [ RSYNC_PATH="rsync" ])
 155
 156 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
 157
 158 AC_ARG_WITH(rsyncd-conf,
 159         AS_HELP_STRING([--with-rsyncd-conf=PATH],[set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]),
 160         [ if test ! -z "$with_rsyncd_conf" ; then
 161                 case $with_rsyncd_conf in
 162                         yes|no)
 163                                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 164                                 ;;
 165                         /*)
 166                                 RSYNCD_SYSCONF="$with_rsyncd_conf"
 167                                 ;;
 168                         *)
 169                                 AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH)
 170                                 ;;
 171                 esac
 172         else
 173                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 174         fi ],
 175         [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ])
 176
 177 AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server])
 178
 179 AC_ARG_WITH(rsh,
 180         AS_HELP_STRING([--with-rsh=CMD],[set remote shell command to CMD (default: ssh)]))
 181
 182 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
 183 if test x$HAVE_REMSH = x1; then
 184         AC_DEFINE(HAVE_REMSH, 1, [Define to 1 if remote shell is remsh, not rsh])
 185 fi
 186
 187 if test x"$with_rsh" != x; then
 188         RSYNC_RSH="$with_rsh"
 189 else
 190         RSYNC_RSH="ssh"
 191 fi
 192 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
 193
 194 # Some programs on solaris are only found in /usr/xpg4/bin (or work better than others versions).
 195 AC_PATH_PROG(SHELL_PATH, sh, /bin/sh, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 196 AC_PATH_PROG(FAKEROOT_PATH, fakeroot, /usr/bin/fakeroot, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 197
 198 AC_ARG_WITH(nobody-user,
 199     AS_HELP_STRING([--with-nobody-user=USER],[set the default unprivileged user (default nobody)]),
 200     [ NOBODY_USER="$with_nobody_user" ],
 201     [ NOBODY_USER="nobody" ])
 202
 203 AC_ARG_WITH(nobody-group,
 204     AS_HELP_STRING([--with-nobody-group=GROUP],[set the default unprivileged group (default nobody or nogroup)]),
 205     [ NOBODY_GROUP="$with_nobody_group" ])
 206
 207 if test x"$with_nobody_group" = x; then
 208     AC_MSG_CHECKING([the group for user "nobody"])
 209     if grep '^nobody:' /etc/group >/dev/null 2>&1; then
 210         NOBODY_GROUP=nobody
 211     elif grep '^nogroup:' /etc/group >/dev/null 2>&1; then
 212         NOBODY_GROUP=nogroup
 213     else
 214         NOBODY_GROUP=nobody # test for others?
 215     fi
 216     AC_MSG_RESULT($NOBODY_GROUP)
 217 fi
 218
 219 AC_DEFINE_UNQUOTED(NOBODY_USER, "$NOBODY_USER", [unprivileged user--e.g. nobody])
 220 AC_DEFINE_UNQUOTED(NOBODY_GROUP, "$NOBODY_GROUP", [unprivileged group for unprivileged user])
 221
 222 # SIMD optimizations
 223 SIMD=
 224
 225 AC_MSG_CHECKING([whether to enable SIMD optimizations])
 226 AC_ARG_ENABLE(simd,
 227     AS_HELP_STRING([--enable-simd],[enable/disable to control SIMD optimizations (requires c++)]))
 228
 229 # Clag is crashing with -g -O2, so we'll get rid of -g for now.
 230 CXXFLAGS=`echo "$CXXFLAGS" | sed 's/-g //'`
 231 m4_define(SIMD_X86_64_TEST, [[#include <stdio.h>
 232 #if HAVE_STDLIB_H
 233 #include <stdlib.h>
 234 #endif
 235 #include <immintrin.h>
 236 __attribute__ ((target("default"))) int test_ssse3(int x) { return x; }
 237 __attribute__ ((target("default"))) int test_sse2(int x) { return x; }
 238 __attribute__ ((target("default"))) int test_avx2(int x) { return x; }
 239 __attribute__ ((target("ssse3"))) int test_ssse3(int x) { return x; }
 240 __attribute__ ((target("sse2"))) int test_sse2(int x) { return x; }
 241 __attribute__ ((target("avx2"))) int test_avx2(int x) { return x; }
 242 typedef long long __m128i_u __attribute__((__vector_size__(16), __may_alias__, __aligned__(1)));
 243 typedef long long __m256i_u __attribute__((__vector_size__(32), __may_alias__, __aligned__(1)));
 244 __attribute__ ((target("default"))) void more_testing(char* buf, int len) { }
 245 __attribute__ ((target("ssse3"))) void more_testing(char* buf, int len)
 246 {
 247     int i;
 248     for (i = 0; i < (len-32); i+=32) {
 249         __m128i in8_1, in8_2;
 250         in8_1 = _mm_lddqu_si128((__m128i_u*)&buf[i]);
 251         in8_2 = _mm_lddqu_si128((__m128i_u*)&buf[i + 16]);
 252     }
 253 }
 254 ]])
 255
 256 if test x"$enable_simd" = x""; then
 257     case "$host_os" in
 258         *linux*) ;;
 259         *) enable_simd=no ;;
 260     esac
 261 fi
 262
 263 if test x"$enable_simd" != x"no"; then
 264     # For x86-64 SIMD, g++ >=5 or clang++ >=7 is required
 265     if test x"$host_cpu" = x"x86_64" -o x"$host_cpu" = x"amd64"; then
 266         AC_LANG(C++)
 267         if test x"$host_cpu" = x"$build_cpu"; then
 268             AC_RUN_IFELSE([AC_LANG_PROGRAM([SIMD_X86_64_TEST],[[if (test_ssse3(42) != 42 || test_sse2(42) != 42 || test_avx2(42) != 42) exit(1);]])],
 269                 [CXX_OK=yes],[CXX_OK=no])
 270         else
 271             AC_COMPILE_IFELSE([AC_LANG_PROGRAM([SIMD_X86_64_TEST])],[CXX_OK=yes],[CXX_OK=no])
 272         fi
 273         AC_LANG(C)
 274         if test x"$CXX_OK" = x"yes"; then
 275             # AC_MSG_RESULT() is called below.
 276             SIMD="$host_cpu"
 277         elif test x"$enable_simd" = x"yes"; then
 278             AC_MSG_RESULT(error)
 279             AC_MSG_ERROR(The SIMD compilation test failed.
 280 Omit --enable-simd to continue without it.)
 281         fi
 282     elif test x"$enable_simd" = x"yes"; then
 283         AC_MSG_RESULT(unavailable)
 284         AC_MSG_ERROR(The SIMD optimizations are currently x86_64|amd64 only.
 285 Omit --enable-simd to continue without it.)
 286     fi
 287 fi
 288
 289 if test x"$SIMD" != x""; then
 290     AC_MSG_RESULT([yes ($SIMD)])
 291     AC_DEFINE(HAVE_SIMD, 1, [Define to 1 to enable SIMD optimizations])
 292     SIMD='$(SIMD_'"$SIMD)"
 293     # We only use c++ for its target attribute dispatching, disable unneeded bulky features
 294     CXXFLAGS="$CXXFLAGS -fno-exceptions -fno-rtti"
 295     # Apple often has "g++" as a symlink for clang. Try to find out the truth.
 296     CXX_VERSION=`$CXX --version 2>/dev/null | head -n 2`
 297     case "$CXX_VERSION" in
 298     *clang*) CXXFLAGS="$CXXFLAGS -fno-slp-vectorize" ;; # avoid a performance hit
 299     esac
 300 else
 301     AC_MSG_RESULT(no)
 302 fi
 303
 304 AC_SUBST(SIMD)
 305
 306 AC_MSG_CHECKING([if assembler accepts noexecstack])
 307 OLD_CFLAGS="$CFLAGS"
 308 CFLAGS="$CFLAGS -Wa,--noexecstack"
 309 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ ]], [[return 0;]])],
 310 [ NOEXECSTACK='-Wa,--noexecstack' ; AC_MSG_RESULT(yes) ],
 311 [ NOEXECSTACK='' ; AC_MSG_RESULT(no) ])
 312 CFLAGS="$OLD_CFLAGS"
 313 AC_SUBST(NOEXECSTACK)
 314
 315 ASM=
 316
 317 AC_MSG_CHECKING([whether to enable ASM optimizations])
 318 AC_ARG_ENABLE(asm,
 319     AS_HELP_STRING([--enable-asm],[enable/disable to control ASM optimizations]))
 320
 321 if test x"$enable_asm" = x""; then
 322     case "$host_os" in
 323         *linux*) ;;
 324         *) enable_asm=no ;;
 325     esac
 326 fi
 327
 328 if test x"$enable_asm" != x"no"; then
 329     if test x"$host_cpu" = x"x86_64" -o x"$host_cpu" = x"amd64"; then
 330         ASM="$host_cpu"
 331     elif test x"$enable_asm" = x"yes"; then
 332         AC_MSG_RESULT(unavailable)
 333         AC_MSG_ERROR(The ASM optimizations are currently x86_64|amd64 only.
 334 Omit --enable-asm to continue without it.)
 335     fi
 336 fi
 337
 338 if test x"$ASM" != x""; then
 339     AC_MSG_RESULT([yes ($ASM)])
 340     AC_DEFINE(HAVE_ASM, 1, [Define to 1 to enable ASM optimizations])
 341     ASM='$(ASM_'"$ASM)"
 342 else
 343     AC_MSG_RESULT(no)
 344 fi
 345
 346 AC_SUBST(ASM)
 347
 348 # arrgh. libc in some old debian version screwed up the largefile
 349 # stuff, getting byte range locking wrong
 350 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
 351 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 352 #define _FILE_OFFSET_BITS 64
 353 #include <stdio.h>
 354 #include <fcntl.h>
 355 #ifdef HAVE_SYS_TYPES_H
 356 #include <sys/types.h>
 357 #endif
 358 #include <sys/wait.h>
 359 #if HAVE_UNISTD_H
 360 #include <unistd.h>
 361 #endif
 362
 363 int main(void)
 364 {
 365         struct flock lock;
 366         int status;
 367         char tpl[32] = "/tmp/locktest.XXXXXX";
 368         int fd = mkstemp(tpl);
 369         if (fd < 0) {
 370                 strcpy(tpl, "conftest.dat");
 371                 fd = open(tpl, O_CREAT|O_RDWR, 0600);
 372         }
 373
 374         lock.l_type = F_WRLCK;
 375         lock.l_whence = SEEK_SET;
 376         lock.l_start = 0;
 377         lock.l_len = 1;
 378         lock.l_pid = 0;
 379         fcntl(fd,F_SETLK,&lock);
 380         if (fork() == 0) {
 381                 lock.l_start = 1;
 382                 _exit(fcntl(fd,F_SETLK,&lock) == 0);
 383         }
 384         wait(&status);
 385         unlink(tpl);
 386         return WEXITSTATUS(status);
 387 }
 388 ]])],[rsync_cv_HAVE_BROKEN_LARGEFILE=yes],[rsync_cv_HAVE_BROKEN_LARGEFILE=no],[rsync_cv_HAVE_BROKEN_LARGEFILE=cross])])
 389 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
 390    AC_SYS_LARGEFILE
 391 fi
 392
 393 AC_MSG_CHECKING([whether to enable ipv6])
 394 AC_ARG_ENABLE(ipv6,
 395 AS_HELP_STRING([--disable-ipv6],[disable to omit ipv6 support]),
 396 [ case "$enableval" in
 397   no)
 398         AC_MSG_RESULT(no)
 399         ;;
 400   *)    AC_MSG_RESULT(yes)
 401         AC_DEFINE(INET6, 1, [true if you have IPv6])
 402         ;;
 403   esac ],
 404
 405   AC_TRY_RUN([ /* AF_INET6 avalable check */
 406 #include <stdlib.h>
 407 #include <sys/types.h>
 408 #include <sys/socket.h>
 409 main()
 410 {
 411    if (socket(AF_INET6, SOCK_STREAM, 0) < 0)
 412      exit(1);
 413    else
 414      exit(0);
 415 }
 416 ],
 417   AC_MSG_RESULT(yes)
 418   AC_DEFINE(INET6, 1, [true if you have IPv6]),
 419   AC_MSG_RESULT(no),
 420   AC_MSG_RESULT(no)
 421 ))
 422
 423 dnl Do you want to disable use of locale functions
 424 AC_ARG_ENABLE([locale],
 425         AS_HELP_STRING([--disable-locale],[disable to omit locale features]))
 426 AH_TEMPLATE([CONFIG_LOCALE],
 427 [Undefine if you do not want locale features.  By default this is defined.])
 428 if test x"$enable_locale" != x"no"; then
 429         AC_DEFINE(CONFIG_LOCALE)
 430 fi
 431
 432 AC_MSG_CHECKING([whether to call shutdown on all sockets])
 433 case $host_os in
 434         *cygwin* ) AC_MSG_RESULT(yes)
 435                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
 436                             [Define to 1 if sockets need to be shutdown])
 437                    ;;
 438                * ) AC_MSG_RESULT(no);;
 439 esac
 440
 441 AC_MSG_CHECKING([whether to enable use of openssl crypto library])
 442 AC_ARG_ENABLE([openssl],
 443         AS_HELP_STRING([--disable-openssl],[disable to omit openssl crypto library]))
 444 AH_TEMPLATE([USE_OPENSSL],
 445 [Undefine if you do not want to use openssl crypto library.  By default this is defined.])
 446 if test x"$enable_openssl" != x"no"; then
 447     if test x"$ac_cv_header_openssl_md4_h" = x"yes" && test x"$ac_cv_header_openssl_md5_h" = x"yes"; then
 448       AC_MSG_RESULT(yes)
 449       AC_SEARCH_LIBS(MD5_Init, crypto,
 450           [AC_DEFINE(USE_OPENSSL)],
 451           [err_msg="$err_msg$nl- Failed to find MD5_Init function in openssl crypto lib.";
 452            no_lib="$no_lib openssl"])
 453     else
 454         AC_MSG_RESULT(no)
 455         err_msg="$err_msg$nl- Failed to find openssl/md4.h and openssl/md5.h for openssl crypto lib support."
 456         no_lib="$no_lib openssl"
 457     fi
 458 else
 459     AC_MSG_RESULT(no)
 460 fi
 461
 462 AC_MSG_CHECKING([whether to enable xxhash checksum support])
 463 AC_ARG_ENABLE([xxhash],
 464         AS_HELP_STRING([--disable-xxhash],[disable to omit xxhash checksums]))
 465 AH_TEMPLATE([SUPPORT_XXHASH],
 466 [Undefine if you do not want xxhash checksums.  By default this is defined.])
 467 if test x"$enable_xxhash" != x"no"; then
 468     if test x"$ac_cv_header_xxhash_h" = x"yes"; then
 469         AC_MSG_RESULT(yes)
 470         AC_SEARCH_LIBS(XXH64_createState, xxhash,
 471             [AC_DEFINE(SUPPORT_XXHASH)],
 472             [err_msg="$err_msg$nl- Failed to find XXH64_createState function in xxhash lib.";
 473              no_lib="$no_lib xxhash"])
 474     else
 475         AC_MSG_RESULT(no)
 476         err_msg="$err_msg$nl- Failed to find xxhash.h for xxhash checksum support.";
 477         no_lib="$no_lib xxhash"
 478     fi
 479 else
 480     AC_MSG_RESULT(no)
 481 fi
 482
 483 AC_MSG_CHECKING([whether to enable zstd compression])
 484 AC_ARG_ENABLE([zstd],
 485         AC_HELP_STRING([--disable-zstd], [disable to omit zstd compression]))
 486 AH_TEMPLATE([SUPPORT_ZSTD],
 487 [Undefine if you do not want zstd compression.  By default this is defined.])
 488 if test x"$enable_zstd" != x"no"; then
 489     if test x"$ac_cv_header_zstd_h" = x"yes"; then
 490         AC_MSG_RESULT(yes)
 491         AC_SEARCH_LIBS(ZSTD_minCLevel, zstd,
 492             [AC_DEFINE(SUPPORT_ZSTD)],
 493             [err_msg="$err_msg$nl- Failed to find ZSTD_minCLevel function in zstd lib.";
 494              no_lib="$no_lib zstd"])
 495     else
 496         AC_MSG_RESULT(no)
 497         err_msg="$err_msg$nl- Failed to find zstd.h for zstd compression support.";
 498         no_lib="$no_lib zstd"
 499     fi
 500 else
 501     AC_MSG_RESULT(no)
 502 fi
 503
 504 AC_MSG_CHECKING([whether to enable LZ4 compression])
 505 AC_ARG_ENABLE([lz4],
 506         AC_HELP_STRING([--disable-lz4], [disable to omit LZ4 compression]))
 507 AH_TEMPLATE([SUPPORT_LZ4],
 508 [Undefine if you do not want LZ4 compression.  By default this is defined.])
 509 if test x"$enable_lz4" != x"no"; then
 510     if test x"$ac_cv_header_lz4_h" = x"yes"; then
 511         AC_MSG_RESULT(yes)
 512         AC_SEARCH_LIBS(LZ4_compress_default, lz4,
 513             [AC_DEFINE(SUPPORT_LZ4)],
 514             [err_msg="$err_msg$nl- Failed to find LZ4_compress_default function in lz4 lib.";
 515              no_lib="$no_lib lz4"])
 516     else
 517         AC_MSG_RESULT(no)
 518         err_msg="$err_msg$nl- Failed to find lz4.h for lz4 compression support."
 519         no_lib="$no_lib lz4"
 520     fi
 521 else
 522     AC_MSG_RESULT(no)
 523 fi
 524
 525 if test x"$no_lib" != x; then
 526     echo ""
 527     echo "Configure found the following issues:"
 528     echo "$err_msg"
 529     echo ""
 530     echo "See the INSTALL file for hints on how to install the missing libraries and/or"
 531     echo "how to generate (or fetch) man pages:"
 532     echo "    https://github.com/WayneD/rsync/blob/master/INSTALL.md"
 533     echo ""
 534     echo "To disable one or more features, the relevant configure options are:"
 535     for lib in $no_lib; do
 536         echo "    --disable-$lib"
 537     done
 538     echo ""
 539     AC_MSG_ERROR(Aborting configure run)
 540 fi
 541
 542 AC_CACHE_CHECK([if makedev takes 3 args],rsync_cv_MAKEDEV_TAKES_3_ARGS,[
 543 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 544 #ifdef HAVE_SYS_TYPES_H
 545 #include <sys/types.h>
 546 #endif
 547 #ifdef MAJOR_IN_MKDEV
 548 #include <sys/mkdev.h>
 549 # if !defined makedev && (defined mkdev || defined _WIN32 || defined __WIN32__)
 550 #  define makedev mkdev
 551 # endif
 552 #elif defined MAJOR_IN_SYSMACROS
 553 #include <sys/sysmacros.h>
 554 #endif
 555
 556 int main(void)
 557 {
 558         dev_t dev = makedev(0, 5, 7);
 559         if (major(dev) != 5 || minor(dev) != 7)
 560                 return 1;
 561         return 0;
 562 }
 563 ]])],[rsync_cv_MAKEDEV_TAKES_3_ARGS=yes],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no])])
 564 if test x"$rsync_cv_MAKEDEV_TAKES_3_ARGS" = x"yes"; then
 565    AC_DEFINE(MAKEDEV_TAKES_3_ARGS, 1, [Define to 1 if makedev() takes 3 args])
 566 fi
 567
 568 AC_CHECK_SIZEOF(int)
 569 AC_CHECK_SIZEOF(long)
 570 AC_CHECK_SIZEOF(long long)
 571 AC_CHECK_SIZEOF(short)
 572 AC_CHECK_SIZEOF(int16_t)
 573 AC_CHECK_SIZEOF(uint16_t)
 574 AC_CHECK_SIZEOF(int32_t)
 575 AC_CHECK_SIZEOF(uint32_t)
 576 AC_CHECK_SIZEOF(int64_t)
 577 AC_CHECK_SIZEOF(off_t)
 578 AC_CHECK_SIZEOF(off64_t)
 579 AC_CHECK_SIZEOF(time_t)
 580 AC_CHECK_SIZEOF(char*)
 581
 582 AC_C_INLINE
 583
 584 AC_TYPE_LONG_DOUBLE_WIDER
 585 ac_cv_c_long_double=$ac_cv_type_long_double_wider
 586 if test $ac_cv_c_long_double = yes; then
 587   AC_DEFINE([HAVE_LONG_DOUBLE],[1],[Define to 1 if the type `long double' works and has more range or precision than `double'.])
 588 fi
 589
 590 AC_TYPE_UID_T
 591 AC_CHECK_TYPES([mode_t,off_t,size_t,pid_t,id_t])
 592 AC_TYPE_GETGROUPS
 593 AC_CHECK_MEMBERS([struct stat.st_rdev,
 594                   struct stat.st_mtimensec,
 595                   struct stat.st_mtimespec.tv_nsec,
 596                   struct stat.st_mtim.tv_nsec],,,[
 597 #ifdef HAVE_SYS_TYPES_H
 598 #include <sys/types.h>
 599 #endif
 600 #ifdef HAVE_SYS_STAT_H
 601 #include <sys/stat.h>
 602 #endif
 603 #ifdef HAVE_UNISTD_H
 604 #include <unistd.h>
 605 #endif])
 606
 607 TYPE_SOCKLEN_T
 608
 609 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 610     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]], [[int i = errno]])],[rsync_cv_errno=yes],[rsync_cv_have_errno_decl=no])])
 611 if test x"$rsync_cv_errno" = x"yes"; then
 612    AC_DEFINE(HAVE_ERRNO_DECL, 1, [Define to 1 if errno is declared in errno.h])
 613 fi
 614
 615 # The following test taken from the cvs sources
 616 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 617 # These need checks to be before checks for any other functions that
 618 #    might be in the same libraries.
 619 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 620 # libsocket.so which has a bad implementation of gethostbyname (it
 621 # only looks in /etc/hosts), so we only look for -lsocket if we need
 622 # it.
 623 AC_CHECK_FUNCS(connect)
 624 if test x"$ac_cv_func_connect" = x"no"; then
 625     case "$LIBS" in
 626     *-lnsl*) ;;
 627     *) AC_CHECK_LIB(nsl_s, printf) ;;
 628     esac
 629     case "$LIBS" in
 630     *-lnsl*) ;;
 631     *) AC_CHECK_LIB(nsl, printf) ;;
 632     esac
 633     case "$LIBS" in
 634     *-lsocket*) ;;
 635     *) AC_CHECK_LIB(socket, connect) ;;
 636     esac
 637     case "$LIBS" in
 638     *-linet*) ;;
 639     *) AC_CHECK_LIB(inet, connect) ;;
 640     esac
 641     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 642     dnl has been cached.
 643     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 644        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 645         # ac_cv_func_connect=yes
 646         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 647         AC_DEFINE(HAVE_CONNECT, 1, [Define to 1 if you have the "connect" function])
 648     fi
 649 fi
 650
 651 AC_SEARCH_LIBS(inet_ntop, resolv)
 652
 653 # For OS X, Solaris, HP-UX, etc.: figure out if -liconv is needed.  We'll
 654 # accept either iconv_open or libiconv_open, since some include files map
 655 # the former to the latter.
 656 AC_SEARCH_LIBS(iconv_open, iconv)
 657 AC_SEARCH_LIBS(libiconv_open, iconv)
 658
 659 AC_MSG_CHECKING([for iconv declaration])
 660 AC_CACHE_VAL(am_cv_proto_iconv, [
 661     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 662 #if HAVE_STDLIB_H
 663 #include <stdlib.h>
 664 #endif
 665 #include <iconv.h>
 666 extern
 667 #ifdef __cplusplus
 668 "C"
 669 #endif
 670 #if defined(__STDC__) || defined(__cplusplus)
 671 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 672 #else
 673 size_t iconv();
 674 #endif
 675 ]], [[]])],[am_cv_proto_iconv_arg1=""],[am_cv_proto_iconv_arg1="const"])
 676       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
 677     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed 's/( /(/'`
 678 AC_MSG_RESULT([$]{ac_t:-
 679          }[$]am_cv_proto_iconv)
 680 AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
 681                    [Define as const if the declaration of iconv() needs const.])
 682
 683 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
 684
 685 AC_REPLACE_FUNCS([inet_ntop inet_pton])
 686
 687 AC_HAVE_TYPE([struct addrinfo], [#include <netdb.h>])
 688 AC_HAVE_TYPE([struct sockaddr_storage], [
 689 #ifdef HAVE_SYS_TYPES_H
 690 #include <sys/types.h>
 691 #endif
 692 #ifdef HAVE_SYS_SOCKET_H
 693 #include <sys/socket.h>
 694 #endif])
 695
 696 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
 697 #   builtin getaddrinfo if one of the defines don't exist
 698 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
 699                rsync_cv_HAVE_GETADDR_DEFINES,[
 700                         AC_EGREP_CPP(yes, [
 701 #ifdef HAVE_SYS_TYPES_H
 702 #include <sys/types.h>
 703 #endif
 704 #ifdef HAVE_SYS_SOCKET_H
 705 #include <sys/socket.h>
 706 #endif
 707 #ifdef HAVE_NETDB_H
 708 #include <netdb.h>
 709 #endif
 710 #ifdef AI_PASSIVE
 711 yes
 712 #endif],
 713                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
 714                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
 715 AS_IF([test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes" -a x"$ac_cv_type_struct_addrinfo" = x"yes"],[
 716         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
 717         # something else so we must include <netdb.h> to get the
 718         # redefinition.
 719         AC_CHECK_FUNCS(getaddrinfo, ,
 720                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
 721                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 722 #ifdef HAVE_SYS_TYPES_H
 723 #include <sys/types.h>
 724 #endif
 725 #ifdef HAVE_SYS_SOCKET_H
 726 #include <sys/socket.h>
 727 #endif
 728 #include <netdb.h>]], [[getaddrinfo(NULL, NULL, NULL, NULL);]])],[AC_MSG_RESULT([yes])
 729                         AC_DEFINE(HAVE_GETADDRINFO, 1,
 730                                 [Define to 1 if you have the "getaddrinfo" function and required types.])],[AC_MSG_RESULT([no])
 731                         AC_LIBOBJ([getaddrinfo])])])
 732     ],[AC_LIBOBJ([getaddrinfo])])
 733
 734 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 735                 [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ],
 736                 [],
 737                 [
 738 #ifdef HAVE_SYS_TYPES_H
 739 #include <sys/types.h>
 740 #endif
 741 #ifdef HAVE_SYS_SOCKET_H
 742 #include <sys/socket.h>
 743 #endif
 744 ])
 745
 746 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
 747                 [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ],
 748                 [],
 749                 [
 750 #ifdef HAVE_SYS_TYPES_H
 751 #include <sys/types.h>
 752 #endif
 753 #ifdef HAVE_SYS_SOCKET_H
 754 #include <sys/socket.h>
 755 #endif
 756 #include <netinet/in.h>
 757 ])
 758
 759 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 760                 [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ],
 761                 [],
 762                 [
 763 #ifdef HAVE_SYS_TYPES_H
 764 #include <sys/types.h>
 765 #endif
 766 #ifdef HAVE_SYS_SOCKET_H
 767 #include <sys/socket.h>
 768 #endif
 769 #include <netinet/in.h>
 770 ])
 771
 772 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
 773                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ],
 774                 [],
 775                 [
 776 #ifdef HAVE_SYS_TYPES_H
 777 #include <sys/types.h>
 778 #endif
 779 #ifdef HAVE_SYS_SOCKET_H
 780 #include <sys/socket.h>
 781 #endif
 782 #include <netinet/in.h>
 783 ])
 784
 785 AC_HAVE_TYPE([struct stat64], [#include <stdio.h>
 786 #if HAVE_SYS_TYPES_H
 787 # include <sys/types.h>
 788 #endif
 789 #if HAVE_SYS_STAT_H
 790 # include <sys/stat.h>
 791 #endif
 792 #if STDC_HEADERS
 793 # include <stdlib.h>
 794 # include <stddef.h>
 795 #else
 796 # if HAVE_STDLIB_H
 797 #  include <stdlib.h>
 798 # endif
 799 #endif
 800 ])
 801
 802 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 803 #
 804 AC_CHECK_FUNCS(strcasecmp)
 805 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 806     AC_CHECK_LIB(resolv, strcasecmp)
 807 fi
 808
 809 AC_CHECK_FUNCS(aclsort)
 810 if test x"$ac_cv_func_aclsort" = x"no"; then
 811     AC_CHECK_LIB(sec, aclsort)
 812 fi
 813
 814 dnl At the moment we don't test for a broken memcmp(), because all we
 815 dnl need to do is test for equality, not comparison, and it seems that
 816 dnl every platform has a memcmp that can do at least that.
 817 dnl AC_FUNC_MEMCMP
 818
 819 AC_FUNC_UTIME_NULL
 820 AC_FUNC_ALLOCA
 821 AC_CHECK_FUNCS(waitpid wait4 getcwd chown chmod lchmod mknod mkfifo \
 822     fchmod fstat ftruncate strchr readlink link utime utimes lutimes strftime \
 823     chflags getattrlist mktime innetgr linkat \
 824     memmove lchown vsnprintf snprintf vasprintf asprintf setsid strpbrk \
 825     strlcat strlcpy strtol mallinfo getgroups setgroups geteuid getegid \
 826     setlocale setmode open64 lseek64 mkstemp64 mtrace va_copy __va_copy \
 827     seteuid strerror putenv iconv_open locale_charset nl_langinfo getxattr \
 828     extattr_get_link sigaction sigprocmask setattrlist getgrouplist \
 829     initgroups utimensat posix_fallocate attropen setvbuf nanosleep usleep \
 830     setenv unsetenv)
 831
 832 dnl cygwin iconv.h defines iconv_open as libiconv_open
 833 if test x"$ac_cv_func_iconv_open" != x"yes"; then
 834     AC_CHECK_FUNC(libiconv_open, [ac_cv_func_iconv_open=yes; AC_DEFINE(HAVE_ICONV_OPEN, 1)])
 835 fi
 836
 837 dnl Preallocation stuff (also fallocate, posix_fallocate function tests above):
 838
 839 AC_CACHE_CHECK([for useable fallocate],rsync_cv_have_fallocate,[
 840 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <fcntl.h>
 841 #ifdef HAVE_SYS_TYPES_H
 842 #include <sys/types.h>
 843 #endif]], [[fallocate(0, 0, 0, 0);]])],[rsync_cv_have_fallocate=yes],[rsync_cv_have_fallocate=no])])
 844 if test x"$rsync_cv_have_fallocate" = x"yes"; then
 845     AC_DEFINE(HAVE_FALLOCATE, 1, [Define to 1 if you have the fallocate function and it compiles and links without error])
 846 fi
 847
 848 AC_MSG_CHECKING([for FALLOC_FL_PUNCH_HOLE])
 849 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 850         #define _GNU_SOURCE 1
 851         #include <linux/falloc.h>
 852         #ifndef FALLOC_FL_PUNCH_HOLE
 853         #error FALLOC_FL_PUNCH_HOLE is missing
 854         #endif
 855     ]])], [
 856         AC_MSG_RESULT([yes])
 857         AC_DEFINE([HAVE_FALLOC_FL_PUNCH_HOLE], [1], [Define if FALLOC_FL_PUNCH_HOLE is available.])
 858     ], [
 859         AC_MSG_RESULT([no])
 860     ]
 861 )
 862
 863 AC_MSG_CHECKING([for FALLOC_FL_ZERO_RANGE])
 864 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 865         #define _GNU_SOURCE 1
 866         #include <linux/falloc.h>
 867         #ifndef FALLOC_FL_ZERO_RANGE
 868         #error FALLOC_FL_ZERO_RANGE is missing
 869         #endif
 870     ]])], [
 871         AC_MSG_RESULT([yes])
 872         AC_DEFINE([HAVE_FALLOC_FL_ZERO_RANGE], [1], [Define if FALLOC_FL_ZERO_RANGE is available.])
 873     ], [
 874         AC_MSG_RESULT([no])
 875     ]
 876 )
 877
 878 AC_CACHE_CHECK([for SYS_fallocate],rsync_cv_have_sys_fallocate,[
 879 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/syscall.h>
 880 #ifdef HAVE_UNISTD_H
 881 #include <unistd.h>
 882 #endif
 883 #ifdef HAVE_SYS_TYPES_H
 884 #include <sys/types.h>
 885 #endif]], [[syscall(SYS_fallocate, 0, 0, (loff_t)0, (loff_t)0);]])],[rsync_cv_have_sys_fallocate=yes],[rsync_cv_have_sys_fallocate=no])])
 886 if test x"$rsync_cv_have_sys_fallocate" = x"yes"; then
 887     AC_DEFINE(HAVE_SYS_FALLOCATE, 1, [Define to 1 if you have the SYS_fallocate syscall number])
 888 fi
 889
 890 if test x"$ac_cv_func_posix_fallocate" = x"yes"; then
 891     AC_MSG_CHECKING([whether posix_fallocate is efficient])
 892     case $host_os in
 893     *cygwin*)
 894         AC_MSG_RESULT(yes)
 895         AC_DEFINE(HAVE_EFFICIENT_POSIX_FALLOCATE, 1,
 896                   [Define if posix_fallocate is efficient (Cygwin)])
 897         ;;
 898     *)
 899         AC_MSG_RESULT(no)
 900         ;;
 901     esac
 902 fi
 903
 904 dnl End of preallocation stuff
 905
 906 AC_CHECK_FUNCS(getpgrp tcgetpgrp)
 907 if test $ac_cv_func_getpgrp = yes; then
 908     AC_FUNC_GETPGRP
 909 fi
 910
 911 AC_ARG_ENABLE(iconv-open,
 912     AS_HELP_STRING([--disable-iconv-open],[disable to avoid all use of iconv_open()]),
 913     [], [enable_iconv_open=$ac_cv_func_iconv_open])
 914
 915 if test x"$enable_iconv_open" != x"no"; then
 916     AC_DEFINE(USE_ICONV_OPEN, 1, [Define to 1 if you want rsync to make use of iconv_open()])
 917 fi
 918
 919 AC_ARG_ENABLE(iconv,
 920     AS_HELP_STRING([--disable-iconv],[disable to omit the --iconv option]),
 921     [], [enable_iconv=$enable_iconv_open])
 922 AH_TEMPLATE([ICONV_OPTION],
 923 [Define if you want the --iconv option.  Specifying a value will set the
 924 default iconv setting (a NULL means no --iconv processing by default).])
 925 if test x"$enable_iconv" != x"no"; then
 926         if test x"$enable_iconv" = x"yes"; then
 927                 AC_DEFINE(ICONV_OPTION, NULL)
 928         else
 929                 AC_DEFINE_UNQUOTED(ICONV_OPTION, "$enable_iconv")
 930         fi
 931         AC_DEFINE(UTF8_CHARSET, "UTF-8", [String to pass to iconv() for the UTF-8 charset.])
 932 fi
 933
 934 AC_CACHE_CHECK([whether chown() modifies symlinks],rsync_cv_chown_modifies_symlink,[
 935   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 936 #if HAVE_UNISTD_H
 937 # include <unistd.h>
 938 #endif
 939 #include <stdlib.h>
 940 #include <errno.h>
 941 int main(void) {
 942         char const *dangling_symlink = "conftest.dangle";
 943         unlink(dangling_symlink);
 944         if (symlink("conftest.no-such", dangling_symlink) < 0) abort();
 945         if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) return 1;
 946         return 0;
 947     }]])],[rsync_cv_chown_modifies_symlink=yes],[rsync_cv_chown_modifies_symlink=no],[rsync_cv_chown_modifies_symlink=no])])
 948 if test $rsync_cv_chown_modifies_symlink = yes; then
 949   AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define to 1 if chown modifies symlinks.])
 950 fi
 951
 952 AC_CACHE_CHECK([whether link() can hard-link symlinks],rsync_cv_can_hardlink_symlink,[
 953   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 954 #ifdef HAVE_FCNTL_H
 955 # include <fcntl.h>
 956 #elif defined HAVE_SYS_FCNTL_H
 957 # include <sys/fcntl.h>
 958 #endif
 959 #if HAVE_UNISTD_H
 960 # include <unistd.h>
 961 #endif
 962 #include <stdlib.h>
 963 #include <errno.h>
 964 #define FILENAME "conftest.dangle"
 965 int main(void) {
 966         unlink(FILENAME);
 967         if (symlink("conftest.no-such", FILENAME) < 0) abort();
 968         unlink(FILENAME "2");
 969 #ifdef HAVE_LINKAT
 970         if (linkat(AT_FDCWD, FILENAME, AT_FDCWD, FILENAME "2", 0) < 0) return 1;
 971 #else
 972         if (link(FILENAME, FILENAME "2") < 0) return 1;
 973 #endif
 974         return 0;
 975     }]])],[rsync_cv_can_hardlink_symlink=yes],[rsync_cv_can_hardlink_symlink=no],[rsync_cv_can_hardlink_symlink=no])])
 976 if test $rsync_cv_can_hardlink_symlink = yes; then
 977   AC_DEFINE(CAN_HARDLINK_SYMLINK, 1, [Define to 1 if link() can hard-link symlinks.])
 978 fi
 979
 980 AC_CACHE_CHECK([whether link() can hard-link special files],rsync_cv_can_hardlink_special,[
 981   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 982 #if HAVE_UNISTD_H
 983 # include <unistd.h>
 984 #endif
 985 #ifdef HAVE_SYS_STAT_H
 986 #include <sys/stat.h>
 987 #endif
 988 #include <stdlib.h>
 989 #include <errno.h>
 990 #define FILENAME "conftest.fifi"
 991 int main(void) {
 992         unlink(FILENAME);
 993         if (mkfifo(FILENAME, 0777) < 0) abort();
 994         unlink(FILENAME "2");
 995         if (link(FILENAME, FILENAME "2") < 0) return 1;
 996         return 0;
 997     }]])],[rsync_cv_can_hardlink_special=yes],[rsync_cv_can_hardlink_special=no],[rsync_cv_can_hardlink_special=no])])
 998 if test $rsync_cv_can_hardlink_special = yes; then
 999     AC_DEFINE(CAN_HARDLINK_SPECIAL, 1, [Define to 1 if link() can hard-link special files.])
1000 fi
1001
1002 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
1003 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1004 #ifdef HAVE_SYS_TYPES_H
1005 #include <sys/types.h>
1006 #endif
1007 #ifdef HAVE_SYS_SOCKET_H
1008 #include <sys/socket.h>
1009 #endif
1010
1011 int main(void) {
1012        int fd[2];
1013        return (socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1;
1014 }]])],[rsync_cv_HAVE_SOCKETPAIR=yes],[rsync_cv_HAVE_SOCKETPAIR=no],[rsync_cv_HAVE_SOCKETPAIR=cross])])
1015 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
1016     AC_DEFINE(HAVE_SOCKETPAIR, 1, [Define to 1 if you have the "socketpair" function])
1017 fi
1018
1019 AC_REPLACE_FUNCS([getpass])
1020
1021 if test x"$with_included_popt" != x"yes"; then
1022     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
1023 fi
1024 if test x"$ac_cv_header_popt_popt_h" = x"yes"; then
1025     # If the system has /usr/include/popt/popt.h, we enable the
1026     # included popt because an attempt to "#include <popt/popt.h>"
1027     # would use our included header file anyway (due to -I.), and
1028     # might conflict with the system popt.
1029     with_included_popt=yes
1030 elif test x"$ac_cv_header_popt_h" != x"yes"; then
1031     with_included_popt=yes
1032 fi
1033
1034 if test x"$GCC" = x"yes"; then
1035     if test x"$with_included_popt" != x"yes"; then
1036         # Turn pedantic warnings into errors to ensure an array-init overflow is an error.
1037         CFLAGS="$CFLAGS -pedantic-errors"
1038     else
1039         # Our internal popt code cannot be compiled with pedantic warnings as errors, so try to
1040         # turn off pedantic warnings (which will not lose the error for array-init overflow).
1041         # Older gcc versions don't understand -Wno-pedantic, so check if --help=warnings lists
1042         # -Wpedantic and use that as a flag.
1043         case `$CC --help=warnings 2>/dev/null | grep Wpedantic` in
1044             *-Wpedantic*) CFLAGS="$CFLAGS -pedantic-errors -Wno-pedantic" ;;
1045         esac
1046     fi
1047 fi
1048
1049 AC_MSG_CHECKING([whether to use included libpopt])
1050 if test x"$with_included_popt" = x"yes"; then
1051     AC_MSG_RESULT($srcdir/popt)
1052     BUILD_POPT='$(popt_OBJS)'
1053     CFLAGS="-I$srcdir/popt $CFLAGS"
1054     if test x"$ALLOCA" != x
1055     then
1056         # this can be removed when/if we add an included alloca.c;
1057         #  see autoconf documentation on AC_FUNC_ALLOCA
1058         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
1059     fi
1060 else
1061     AC_MSG_RESULT(no)
1062 fi
1063
1064 # We default to using our zlib unless --with-included-zlib=no is given.
1065 if test x"$with_included_zlib" != x"no"; then
1066     with_included_zlib=yes
1067 elif test x"$ac_cv_header_zlib_h" != x"yes"; then
1068     with_included_zlib=yes
1069 fi
1070 if test x"$with_included_zlib" != x"yes"; then
1071     AC_CHECK_LIB(z, deflateParams, , [with_included_zlib=yes])
1072 fi
1073
1074 AC_MSG_CHECKING([whether to use included zlib])
1075 if test x"$with_included_zlib" = x"yes"; then
1076     AC_MSG_RESULT($srcdir/zlib)
1077     BUILD_ZLIB='$(zlib_OBJS)'
1078     CFLAGS="-I$srcdir/zlib $CFLAGS"
1079 else
1080     AC_DEFINE(EXTERNAL_ZLIB, 1, [Define to 1 if using external zlib])
1081     AC_MSG_RESULT(no)
1082 fi
1083
1084 AC_CACHE_CHECK([for unsigned char],rsync_cv_SIGNED_CHAR_OK,[
1085 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[signed char *s = ""]])],[rsync_cv_SIGNED_CHAR_OK=yes],[rsync_cv_SIGNED_CHAR_OK=no])])
1086 if test x"$rsync_cv_SIGNED_CHAR_OK" = x"yes"; then
1087     AC_DEFINE(SIGNED_CHAR_OK, 1, [Define to 1 if "signed char" is a valid type])
1088 fi
1089
1090 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
1091 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1092 #ifdef HAVE_SYS_TYPES_H
1093 #include <sys/types.h>
1094 #endif
1095 #include <dirent.h>
1096 int main(void) { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
1097 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
1098 di->d_name[0] == 0) return 0; return 1;} ]])],[rsync_cv_HAVE_BROKEN_READDIR=yes],[rsync_cv_HAVE_BROKEN_READDIR=no],[rsync_cv_HAVE_BROKEN_READDIR=cross])])
1099 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
1100     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [Define to 1 if readdir() is broken])
1101 fi
1102
1103 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_STRUCT_UTIMBUF,[
1104 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1105 #ifdef HAVE_SYS_TYPES_H
1106 #include <sys/types.h>
1107 #endif
1108 #include <utime.h>]], [[struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; return utime("foo.c",&tbuf);]])],[rsync_cv_HAVE_STRUCT_UTIMBUF=yes],[rsync_cv_HAVE_STRUCT_UTIMBUF=no])])
1109 if test x"$rsync_cv_HAVE_STRUCT_UTIMBUF" = x"yes"; then
1110     AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if you have the "struct utimbuf" type])
1111 fi
1112
1113 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
1114 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/time.h>
1115 #ifdef HAVE_UNISTD_H
1116 #include <unistd.h>
1117 #endif]], [[struct timeval tv; return gettimeofday(&tv, NULL);]])],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=no])])
1118 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then
1119     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [Define to 1 if gettimeofday() takes a time-zone arg])
1120 fi
1121
1122 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
1123 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1124 #ifdef HAVE_SYS_TYPES_H
1125 #include <sys/types.h>
1126 #endif
1127 #include <stdarg.h>
1128 #include <stdio.h>
1129 #if HAVE_STDLIB_H
1130 #include <stdlib.h>
1131 #endif
1132 #include <string.h>
1133 void foo(const char *format, ...) {
1134        va_list ap;
1135        int len;
1136        static char buf[] = "12345678901234567890";
1137
1138        va_start(ap, format);
1139        len = vsnprintf(0, 0, format, ap);
1140        va_end(ap);
1141        if (len != 5) exit(1);
1142
1143        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
1144 }
1145 int main(void) { foo("hello"); return 0; }
1146 ]])],[rsync_cv_HAVE_C99_VSNPRINTF=yes],[rsync_cv_HAVE_C99_VSNPRINTF=no],[rsync_cv_HAVE_C99_VSNPRINTF=cross])])
1147 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
1148     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [Define to 1 if vsprintf has a C99-compatible return value])
1149 fi
1150
1151
1152 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
1153 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1154 #ifdef HAVE_SYS_TYPES_H
1155 #include <sys/types.h>
1156 #endif
1157 #include <sys/stat.h>
1158 #ifdef HAVE_UNISTD_H
1159 #include <unistd.h>
1160 #endif
1161 int main(void) {
1162   struct stat st;
1163   char tpl[20]="/tmp/test.XXXXXX";
1164   int fd = mkstemp(tpl);
1165   if (fd == -1) return 1;
1166   unlink(tpl);
1167   if (fstat(fd, &st) != 0) return 1;
1168   if ((st.st_mode & 0777) != 0600) return 1;
1169   return 0;
1170 }]])],[rsync_cv_HAVE_SECURE_MKSTEMP=yes],[rsync_cv_HAVE_SECURE_MKSTEMP=no],[rsync_cv_HAVE_SECURE_MKSTEMP=cross])])
1171 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
1172     case $host_os in
1173     hpux*)
1174         dnl HP-UX has a broken mkstemp() implementation they refuse to fix,
1175         dnl so we noisily skip using it.  See HP change request JAGaf34426
1176         dnl for details. (sbonds)
1177         AC_MSG_WARN(Skipping broken HP-UX mkstemp() -- using mktemp() instead)
1178         ;;
1179     *)
1180         AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [Define to 1 if mkstemp() is available and works right])
1181         ;;
1182     esac
1183 fi
1184
1185
1186 AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[
1187 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1188 #include <stdio.h>
1189 #include <sys/stat.h>
1190 #include <errno.h>
1191 #if HAVE_UNISTD_H
1192 # include <unistd.h>
1193 #endif
1194 int main(void) { int rc, ec; char *fn = "fifo-test";
1195 unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn);
1196 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
1197 return 0;}]])],[rsync_cv_MKNOD_CREATES_FIFOS=yes],[rsync_cv_MKNOD_CREATES_FIFOS=no],[rsync_cv_MKNOD_CREATES_FIFOS=cross])])
1198 if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then
1199     AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.])
1200 fi
1201
1202 AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[
1203 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1204 #include <stdio.h>
1205 #include <sys/stat.h>
1206 #include <errno.h>
1207 #if HAVE_UNISTD_H
1208 # include <unistd.h>
1209 #endif
1210 int main(void) { int rc, ec; char *fn = "sock-test";
1211 unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn);
1212 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
1213 return 0;}]])],[rsync_cv_MKNOD_CREATES_SOCKETS=yes],[rsync_cv_MKNOD_CREATES_SOCKETS=no],[rsync_cv_MKNOD_CREATES_SOCKETS=cross])])
1214 if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then
1215     AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.])
1216 fi
1217
1218 #
1219 # The following test was mostly taken from the tcl/tk plus patches
1220 #
1221 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
1222 rm -rf conftest*
1223 cat > conftest.$ac_ext <<EOF
1224 int main(void) { return 0; }
1225 EOF
1226 ${CC-cc} -c -o conftest..o conftest.$ac_ext
1227 if test -f conftest..o; then
1228     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
1229 else
1230     rsync_cv_DASHC_WORKS_WITH_DASHO=no
1231 fi
1232 rm -rf conftest*
1233 ])
1234 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
1235     OBJ_SAVE="#"
1236     OBJ_RESTORE="#"
1237     CC_SHOBJ_FLAG='-o $@'
1238 else
1239     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
1240     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
1241     CC_SHOBJ_FLAG=""
1242 fi
1243
1244 AC_SUBST(OBJ_SAVE)
1245 AC_SUBST(OBJ_RESTORE)
1246 AC_SUBST(CC_SHOBJ_FLAG)
1247 AC_SUBST(BUILD_POPT)
1248 AC_SUBST(BUILD_ZLIB)
1249 AC_SUBST(MAKE_MAN)
1250
1251 AC_CHECK_FUNCS(_acl __acl _facl __facl)
1252 #################################################
1253 # check for ACL support
1254
1255 AC_MSG_CHECKING([whether to support ACLs])
1256 AC_ARG_ENABLE(acl-support,
1257         AS_HELP_STRING([--disable-acl-support],[disable to omit ACL support]))
1258
1259 if test x"$enable_acl_support" = x"no"; then
1260     AC_MSG_RESULT(no)
1261 else
1262     case "$host_os" in
1263     *sysv5*)
1264         AC_MSG_RESULT(Using UnixWare ACLs)
1265         AC_DEFINE(HAVE_UNIXWARE_ACLS, 1, [true if you have UnixWare ACLs])
1266         AC_DEFINE(SUPPORT_ACLS, 1, [Define to 1 to add support for ACLs])
1267         ;;
1268     solaris*)
1269         AC_MSG_RESULT(Using solaris ACLs)
1270         AC_DEFINE(HAVE_SOLARIS_ACLS, 1, [true if you have solaris ACLs])
1271         AC_DEFINE(SUPPORT_ACLS, 1)
1272         ;;
1273     *irix*)
1274         AC_MSG_RESULT(Using IRIX ACLs)
1275         AC_DEFINE(HAVE_IRIX_ACLS, 1, [true if you have IRIX ACLs])
1276         AC_DEFINE(SUPPORT_ACLS, 1)
1277         ;;
1278     *aix*)
1279         AC_MSG_RESULT(Using AIX ACLs)
1280         AC_DEFINE(HAVE_AIX_ACLS, 1, [true if you have AIX ACLs])
1281         AC_DEFINE(SUPPORT_ACLS, 1)
1282         ;;
1283     *osf*)
1284         AC_MSG_RESULT(Using Tru64 ACLs)
1285         AC_DEFINE(HAVE_TRU64_ACLS, 1, [true if you have Tru64 ACLs])
1286         AC_DEFINE(SUPPORT_ACLS, 1)
1287         LIBS="$LIBS -lpacl"
1288         ;;
1289     darwin*)
1290         AC_MSG_RESULT(Using OS X ACLs)
1291         AC_DEFINE(HAVE_OSX_ACLS, 1, [true if you have Mac OS X ACLs])
1292         AC_DEFINE(SUPPORT_ACLS, 1)
1293         ;;
1294     *hpux*|*nsk*)
1295         AC_MSG_RESULT(Using HPUX ACLs)
1296         AC_DEFINE(HAVE_HPUX_ACLS, 1, [true if you have HPUX ACLs])
1297         AC_DEFINE(SUPPORT_ACLS, 1)
1298         ;;
1299     *)
1300         AC_MSG_RESULT(running tests:)
1301         AC_CHECK_LIB(acl,acl_get_file)
1302         AC_CACHE_CHECK([for ACL support],samba_cv_HAVE_POSIX_ACLS,[
1303             AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1304 #ifdef HAVE_SYS_TYPES_H
1305 #include <sys/types.h>
1306 #endif
1307 #ifdef HAVE_SYS_ACL_H
1308 #include <sys/acl.h>
1309 #endif]], [[ acl_t acl; int entry_id; acl_entry_t *entry_p; return acl_get_entry( acl, entry_id, entry_p);]])],[samba_cv_HAVE_POSIX_ACLS=yes],[samba_cv_HAVE_POSIX_ACLS=no])])
1310         AC_MSG_CHECKING(ACL test results)
1311         if test x"$samba_cv_HAVE_POSIX_ACLS" = x"yes"; then
1312             AC_MSG_RESULT(Using posix ACLs)
1313             AC_DEFINE(HAVE_POSIX_ACLS, 1, [true if you have posix ACLs])
1314             AC_DEFINE(SUPPORT_ACLS, 1)
1315             AC_CACHE_CHECK([for acl_get_perm_np],samba_cv_HAVE_ACL_GET_PERM_NP,[
1316                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1317 #ifdef HAVE_SYS_TYPES_H
1318 #include <sys/types.h>
1319 #endif
1320 #ifdef HAVE_SYS_ACL_H
1321 #include <sys/acl.h>
1322 #endif]], [[ acl_permset_t permset_d; acl_perm_t perm; return acl_get_perm_np( permset_d, perm);]])],[samba_cv_HAVE_ACL_GET_PERM_NP=yes],[samba_cv_HAVE_ACL_GET_PERM_NP=no])])
1323             if test x"$samba_cv_HAVE_ACL_GET_PERM_NP" = x"yes"; then
1324                 AC_DEFINE(HAVE_ACL_GET_PERM_NP, 1, [true if you have acl_get_perm_np])
1325             fi
1326         else
1327             if test x"$enable_acl_support" = x"yes"; then
1328                 AC_MSG_ERROR(Failed to find ACL support)
1329             else
1330                 AC_MSG_RESULT(No ACL support found)
1331             fi
1332         fi
1333         ;;
1334     esac
1335 fi
1336
1337 #################################################
1338 # check for extended attribute support
1339 AC_MSG_CHECKING(whether to support extended attributes)
1340 AC_ARG_ENABLE(xattr-support,
1341     AS_HELP_STRING([--disable-xattr-support],[disable to omit extended attributes]),
1342     [], [case "$ac_cv_func_getxattr$ac_cv_func_extattr_get_link$ac_cv_func_attropen" in
1343         *yes*) enable_xattr_support=maybe ;;
1344         *) enable_xattr_support=no ;;
1345         esac])
1346 AH_TEMPLATE([SUPPORT_XATTRS],
1347 [Define to 1 to add support for extended attributes])
1348 if test x"$enable_xattr_support" = x"no"; then
1349     AC_MSG_RESULT(no)
1350 else
1351     case "$host_os" in
1352     *linux*|*netbsd*|*cygwin*)
1353         AC_MSG_RESULT(Using Linux xattrs)
1354         AC_DEFINE(HAVE_LINUX_XATTRS, 1, [True if you have Linux xattrs (or equivalent)])
1355         AC_DEFINE(SUPPORT_XATTRS, 1)
1356         AC_DEFINE(NO_SYMLINK_USER_XATTRS, 1, [True if symlinks do not support user xattrs])
1357         AC_CHECK_LIB(attr,getxattr)
1358         ;;
1359     darwin*)
1360         AC_MSG_RESULT(Using OS X xattrs)
1361         AC_DEFINE(HAVE_OSX_XATTRS, 1, [True if you have Mac OS X xattrs])
1362         AC_DEFINE(SUPPORT_XATTRS, 1)
1363         AC_DEFINE(NO_DEVICE_XATTRS, 1, [True if device files do not support xattrs])
1364         AC_DEFINE(NO_SPECIAL_XATTRS, 1, [True if special files do not support xattrs])
1365         ;;
1366     freebsd*)
1367         AC_MSG_RESULT(Using FreeBSD extattrs)
1368         AC_DEFINE(HAVE_FREEBSD_XATTRS, 1, [True if you have FreeBSD xattrs])
1369         AC_DEFINE(SUPPORT_XATTRS, 1)
1370         ;;
1371     solaris*)
1372         AC_MSG_RESULT(Using Solaris xattrs)
1373         AC_DEFINE(HAVE_SOLARIS_XATTRS, 1, [True if you have Solaris xattrs])
1374         AC_DEFINE(SUPPORT_XATTRS, 1)
1375         AC_DEFINE(NO_SYMLINK_XATTRS, 1, [True if symlinks do not support xattrs])
1376         ;;
1377     *)
1378         if test x"$enable_xattr_support" = x"yes"; then
1379             AC_MSG_ERROR(Failed to find extended attribute support)
1380         else
1381             AC_MSG_RESULT(No extended attribute support found)
1382         fi
1383         ;;
1384     esac
1385 fi
1386
1387 if test x"$enable_acl_support" = x"no" -o x"$enable_xattr_support" = x"no" -o x"$enable_iconv" = x"no"; then
1388     AC_MSG_CHECKING([whether $CC supports -Wno-unused-parameter])
1389     OLD_CFLAGS="$CFLAGS"
1390     CFLAGS="$CFLAGS -Wno-unused-parameter"
1391     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>]], [[printf("hello\n");]])],[rsync_warn_flag=yes],[rsync_warn_flag=no])
1392     AC_MSG_RESULT([$rsync_warn_flag])
1393     if test x"$rsync_warn_flag" = x"no"; then
1394         CFLAGS="$OLD_CFLAGS"
1395     fi
1396 fi
1397
1398 case "$CC" in
1399 ' checker'*|checker*)
1400     AC_DEFINE(FORCE_FD_ZERO_MEMSET, 1, [Used to make "checker" understand that FD_ZERO() clears memory.])
1401     ;;
1402 esac
1403
1404 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
1405 AC_OUTPUT
1406
1407 AC_MSG_RESULT()
1408 AC_MSG_RESULT([    rsync $PACKAGE_VERSION configuration successful])
1409 AC_MSG_RESULT()