source3/aclocal.m4

   1 dnl AC_VALIDATE_CACHE_SYSTEM_TYPE[(cmd)]
   2 dnl if the cache file is inconsistent with the current host,
   3 dnl target and build system types, execute CMD or print a default
   4 dnl error message.
   5 AC_DEFUN(AC_VALIDATE_CACHE_SYSTEM_TYPE, [
   6     AC_REQUIRE([AC_CANONICAL_SYSTEM])
   7     AC_MSG_CHECKING([config.cache system type])
   8     if { test x"${ac_cv_host_system_type+set}" = x"set" &&
   9          test x"$ac_cv_host_system_type" != x"$host"; } ||
  10        { test x"${ac_cv_build_system_type+set}" = x"set" &&
  11          test x"$ac_cv_build_system_type" != x"$build"; } ||
  12        { test x"${ac_cv_target_system_type+set}" = x"set" &&
  13          test x"$ac_cv_target_system_type" != x"$target"; }; then
  14         AC_MSG_RESULT([different])
  15         ifelse($#, 1, [$1],
  16                 [AC_MSG_ERROR(["you must remove config.cache and restart configure"])])
  17     else
  18         AC_MSG_RESULT([same])
  19     fi
  20     ac_cv_host_system_type="$host"
  21     ac_cv_build_system_type="$build"
  22     ac_cv_target_system_type="$target"
  23 ])
  24
  25
  26 dnl test whether dirent has a d_off member
  27 AC_DEFUN(AC_DIRENT_D_OFF,
  28 [AC_CACHE_CHECK([for d_off in dirent], ac_cv_dirent_d_off,
  29 [AC_TRY_COMPILE([
  30 #include <unistd.h>
  31 #include <sys/types.h>
  32 #include <dirent.h>], [struct dirent d; d.d_off;],
  33 ac_cv_dirent_d_off=yes, ac_cv_dirent_d_off=no)])
  34 if test $ac_cv_dirent_d_off = yes; then
  35   AC_DEFINE(HAVE_DIRENT_D_OFF,1,[Whether dirent has a d_off member])
  36 fi
  37 ])
  38
  39 dnl Mark specified module as shared
  40 dnl SMB_MODULE(name,static_files,shared_files,subsystem,whatif-static,whatif-shared)
  41 AC_DEFUN(SMB_MODULE,
  42 [
  43         AC_MSG_CHECKING([how to build $1])
  44         if test "$[MODULE_][$1]"; then
  45                 DEST=$[MODULE_][$1]
  46         elif test "$[MODULE_]translit([$4], [A-Z], [a-z])" -a "$[MODULE_DEFAULT_][$1]"; then
  47                 DEST=$[MODULE_]translit([$4], [A-Z], [a-z])
  48         else
  49                 DEST=$[MODULE_DEFAULT_][$1]
  50         fi
  51
  52         if test x"$DEST" = xSHARED; then
  53                 AC_DEFINE([$1][_init], [init_module], [Whether to build $1 as shared module])
  54                 $4_MODULES="$$4_MODULES $3"
  55                 AC_MSG_RESULT([shared])
  56                 [$6]
  57                 string_shared_modules="$string_shared_modules $1"
  58         elif test x"$DEST" = xSTATIC; then
  59                 [init_static_modules_]translit([$4], [A-Z], [a-z])="$[init_static_modules_]translit([$4], [A-Z], [a-z]) $1_init();"
  60                 string_static_modules="$string_static_modules $1"
  61                 $4_STATIC="$$4_STATIC $2"
  62                 AC_SUBST($4_STATIC)
  63                 [$5]
  64                 AC_MSG_RESULT([static])
  65         else
  66             string_ignored_modules="$string_ignored_modules $1"
  67                 AC_MSG_RESULT([not])
  68         fi
  69 ])
  70
  71 AC_DEFUN(SMB_SUBSYSTEM,
  72 [
  73         AC_SUBST($1_STATIC)
  74         AC_SUBST($1_MODULES)
  75         AC_DEFINE_UNQUOTED([static_init_]translit([$1], [A-Z], [a-z]), [{$init_static_modules_]translit([$1], [A-Z], [a-z])[}], [Static init functions])
  76         ifelse([$2], , :, [rm -f $2])
  77 ])
  78
  79 dnl AC_PROG_CC_FLAG(flag)
  80 AC_DEFUN(AC_PROG_CC_FLAG,
  81 [AC_CACHE_CHECK(whether ${CC-cc} accepts -$1, ac_cv_prog_cc_$1,
  82 [echo 'void f(){}' > conftest.c
  83 if test -z "`${CC-cc} -$1 -c conftest.c 2>&1`"; then
  84   ac_cv_prog_cc_$1=yes
  85 else
  86   ac_cv_prog_cc_$1=no
  87 fi
  88 rm -f conftest*
  89 ])])
  90
  91 dnl see if a declaration exists for a function or variable
  92 dnl defines HAVE_function_DECL if it exists
  93 dnl AC_HAVE_DECL(var, includes)
  94 AC_DEFUN(AC_HAVE_DECL,
  95 [
  96  AC_CACHE_CHECK([for $1 declaration],ac_cv_have_$1_decl,[
  97     AC_TRY_COMPILE([$2],[int i = (int)$1],
  98         ac_cv_have_$1_decl=yes,ac_cv_have_$1_decl=no)])
  99  if test x"$ac_cv_have_$1_decl" = x"yes"; then
 100     AC_DEFINE([HAVE_]translit([$1], [a-z], [A-Z])[_DECL],1,[Whether $1() is available])
 101  fi
 102 ])
 103
 104
 105 dnl check for a function in a library, but don't
 106 dnl keep adding the same library to the LIBS variable.
 107 dnl AC_LIBTESTFUNC(lib,func)
 108 AC_DEFUN(AC_LIBTESTFUNC,
 109 [case "$LIBS" in
 110   *-l$1*) AC_CHECK_FUNCS($2) ;;
 111   *) AC_CHECK_LIB($1, $2)
 112      AC_CHECK_FUNCS($2)
 113   ;;
 114   esac
 115 ])
 116
 117 # AC_CHECK_LIB_EXT(LIBRARY, [EXT_LIBS], [FUNCTION],
 118 #              [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND],
 119 #              [ADD-ACTION-IF-FOUND],[OTHER-LIBRARIES])
 120 # ------------------------------------------------------
 121 #
 122 # Use a cache variable name containing both the library and function name,
 123 # because the test really is for library $1 defining function $3, not
 124 # just for library $1.  Separate tests with the same $1 and different $3s
 125 # may have different results.
 126 #
 127 # Note that using directly AS_VAR_PUSHDEF([ac_Lib], [ac_cv_lib_$1_$3])
 128 # is asking for trouble, since AC_CHECK_LIB($lib, fun) would give
 129 # ac_cv_lib_$lib_fun, which is definitely not what was meant.  Hence
 130 # the AS_LITERAL_IF indirection.
 131 #
 132 # FIXME: This macro is extremely suspicious.  It DEFINEs unconditionally,
 133 # whatever the FUNCTION, in addition to not being a *S macro.  Note
 134 # that the cache does depend upon the function we are looking for.
 135 #
 136 # It is on purpose we used `ac_check_lib_ext_save_LIBS' and not just
 137 # `ac_save_LIBS': there are many macros which don't want to see `LIBS'
 138 # changed but still want to use AC_CHECK_LIB_EXT, so they save `LIBS'.
 139 # And ``ac_save_LIBS' is too tempting a name, so let's leave them some
 140 # freedom.
 141 AC_DEFUN([AC_CHECK_LIB_EXT],
 142 [
 143 AH_CHECK_LIB_EXT([$1])
 144 ac_check_lib_ext_save_LIBS=$LIBS
 145 LIBS="-l$1 $$2 $7 $LIBS"
 146 AS_LITERAL_IF([$1],
 147       [AS_VAR_PUSHDEF([ac_Lib_ext], [ac_cv_lib_ext_$1])],
 148       [AS_VAR_PUSHDEF([ac_Lib_ext], [ac_cv_lib_ext_$1''])])dnl
 149
 150 m4_ifval([$3],
 151  [
 152     AH_CHECK_FUNC_EXT([$3])
 153     AS_LITERAL_IF([$1],
 154               [AS_VAR_PUSHDEF([ac_Lib_func], [ac_cv_lib_ext_$1_$3])],
 155               [AS_VAR_PUSHDEF([ac_Lib_func], [ac_cv_lib_ext_$1''_$3])])dnl
 156     AC_CACHE_CHECK([for $3 in -l$1], ac_Lib_func,
 157         [AC_TRY_LINK_FUNC($3,
 158                  [AS_VAR_SET(ac_Lib_func, yes);
 159                   AS_VAR_SET(ac_Lib_ext, yes)],
 160                  [AS_VAR_SET(ac_Lib_func, no);
 161                   AS_VAR_SET(ac_Lib_ext, no)])
 162         ])
 163     AS_IF([test AS_VAR_GET(ac_Lib_func) = yes],
 164         [AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_$3))])dnl
 165     AS_VAR_POPDEF([ac_Lib_func])dnl
 166  ],[
 167     AC_CACHE_CHECK([for -l$1], ac_Lib_ext,
 168         [AC_TRY_LINK_FUNC([main],
 169                  [AS_VAR_SET(ac_Lib_ext, yes)],
 170                  [AS_VAR_SET(ac_Lib_ext, no)])
 171         ])
 172  ])
 173 LIBS=$ac_check_lib_ext_save_LIBS
 174
 175 AS_IF([test AS_VAR_GET(ac_Lib_ext) = yes],
 176     [m4_default([$4],
 177         [AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_LIB$1))
 178                 case "$$2" in
 179                     *-l$1*)
 180                         ;;
 181                     *)
 182                         $2="-l$1 $$2"
 183                         ;;
 184                 esac])
 185                 [$6]
 186             ],
 187             [$5])dnl
 188 AS_VAR_POPDEF([ac_Lib_ext])dnl
 189 ])# AC_CHECK_LIB_EXT
 190
 191 # AH_CHECK_LIB_EXT(LIBNAME)
 192 # ---------------------
 193 m4_define([AH_CHECK_LIB_EXT],
 194 [AH_TEMPLATE(AS_TR_CPP(HAVE_LIB$1),
 195              [Define to 1 if you have the `]$1[' library (-l]$1[).])])
 196
 197 # AC_CHECK_FUNCS_EXT(FUNCTION, [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
 198 # -----------------------------------------------------------------
 199 dnl check for a function in a $LIBS and $OTHER_LIBS libraries variable.
 200 dnl AC_CHECK_FUNC_EXT(func,OTHER_LIBS,IF-TRUE,IF-FALSE)
 201 AC_DEFUN([AC_CHECK_FUNC_EXT],
 202 [
 203     AH_CHECK_FUNC_EXT($1)
 204     ac_check_func_ext_save_LIBS=$LIBS
 205     LIBS="$2 $LIBS"
 206     AS_VAR_PUSHDEF([ac_var], [ac_cv_func_ext_$1])dnl
 207     AC_CACHE_CHECK([for $1], ac_var,
 208         [AC_LINK_IFELSE([AC_LANG_FUNC_LINK_TRY([$1])],
 209                 [AS_VAR_SET(ac_var, yes)],
 210                 [AS_VAR_SET(ac_var, no)])])
 211     LIBS=$ac_check_func_ext_save_LIBS
 212     AS_IF([test AS_VAR_GET(ac_var) = yes],
 213             [AC_DEFINE_UNQUOTED(AS_TR_CPP([HAVE_$1])) $3],
 214             [$4])dnl
 215 AS_VAR_POPDEF([ac_var])dnl
 216 ])# AC_CHECK_FUNC
 217
 218 # AH_CHECK_FUNC_EXT(FUNCNAME)
 219 # ---------------------
 220 m4_define([AH_CHECK_FUNC_EXT],
 221 [AH_TEMPLATE(AS_TR_CPP(HAVE_$1),
 222              [Define to 1 if you have the `]$1[' function.])])
 223
 224 dnl Define an AC_DEFINE with ifndef guard.
 225 dnl AC_N_DEFINE(VARIABLE [, VALUE])
 226 define(AC_N_DEFINE,
 227 [cat >> confdefs.h <<\EOF
 228 [#ifndef] $1
 229 [#define] $1 ifelse($#, 2, [$2], $#, 3, [$2], 1)
 230 [#endif]
 231 EOF
 232 ])
 233
 234 dnl Add an #include
 235 dnl AC_ADD_INCLUDE(VARIABLE)
 236 define(AC_ADD_INCLUDE,
 237 [cat >> confdefs.h <<\EOF
 238 [#include] $1
 239 EOF
 240 ])
 241
 242 dnl Copied from libtool.m4
 243 AC_DEFUN(AC_PROG_LD_GNU,
 244 [AC_CACHE_CHECK([if the linker ($LD) is GNU ld], ac_cv_prog_gnu_ld,
 245 [# I'd rather use --version here, but apparently some GNU ld's only accept -v.
 246 if $LD -v 2>&1 </dev/null | egrep '(GNU|with BFD)' 1>&5; then
 247   ac_cv_prog_gnu_ld=yes
 248 else
 249   ac_cv_prog_gnu_ld=no
 250 fi])
 251 ])
 252
 253 # Configure paths for LIBXML2
 254 # Toshio Kuratomi 2001-04-21
 255 # Adapted from:
 256 # Configure paths for GLIB
 257 # Owen Taylor     97-11-3
 258
 259 dnl AM_PATH_XML2([MINIMUM-VERSION, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]])
 260 dnl Test for XML, and define XML_CFLAGS and XML_LIBS
 261 dnl
 262 AC_DEFUN(AM_PATH_XML2,[
 263 AC_ARG_WITH(xml-prefix,
 264             [  --with-xml-prefix=PFX   Prefix where libxml is installed (optional)],
 265             xml_config_prefix="$withval", xml_config_prefix="")
 266 AC_ARG_WITH(xml-exec-prefix,
 267             [  --with-xml-exec-prefix=PFX Exec prefix where libxml is installed (optional)],
 268             xml_config_exec_prefix="$withval", xml_config_exec_prefix="")
 269 AC_ARG_ENABLE(xmltest,
 270               [  --disable-xmltest       Do not try to compile and run a test LIBXML program],,
 271               enable_xmltest=yes)
 272
 273   if test x$xml_config_exec_prefix != x ; then
 274      xml_config_args="$xml_config_args --exec-prefix=$xml_config_exec_prefix"
 275      if test x${XML2_CONFIG+set} != xset ; then
 276         XML2_CONFIG=$xml_config_exec_prefix/bin/xml2-config
 277      fi
 278   fi
 279   if test x$xml_config_prefix != x ; then
 280      xml_config_args="$xml_config_args --prefix=$xml_config_prefix"
 281      if test x${XML2_CONFIG+set} != xset ; then
 282         XML2_CONFIG=$xml_config_prefix/bin/xml2-config
 283      fi
 284   fi
 285
 286   AC_PATH_PROG(XML2_CONFIG, xml2-config, no)
 287   min_xml_version=ifelse([$1], ,2.0.0,[$1])
 288   AC_MSG_CHECKING(for libxml - version >= $min_xml_version)
 289   no_xml=""
 290   if test "$XML2_CONFIG" = "no" ; then
 291     no_xml=yes
 292   else
 293     XML_CFLAGS=`$XML2_CONFIG $xml_config_args --cflags`
 294     XML_LIBS=`$XML2_CONFIG $xml_config_args --libs`
 295     xml_config_major_version=`$XML2_CONFIG $xml_config_args --version | \
 296            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\1/'`
 297     xml_config_minor_version=`$XML2_CONFIG $xml_config_args --version | \
 298            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\2/'`
 299     xml_config_micro_version=`$XML2_CONFIG $xml_config_args --version | \
 300            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\3/'`
 301     if test "x$enable_xmltest" = "xyes" ; then
 302       ac_save_CFLAGS="$CFLAGS"
 303       ac_save_LIBS="$LIBS"
 304       CFLAGS="$CFLAGS $XML_CFLAGS"
 305       LIBS="$XML_LIBS $LIBS"
 306 dnl
 307 dnl Now check if the installed libxml is sufficiently new.
 308 dnl (Also sanity checks the results of xml2-config to some extent)
 309 dnl
 310       rm -f conf.xmltest
 311       AC_TRY_RUN([
 312 #include <stdlib.h>
 313 #include <stdio.h>
 314 #include <string.h>
 315 #include <libxml/xmlversion.h>
 316
 317 int
 318 main()
 319 {
 320   int xml_major_version, xml_minor_version, xml_micro_version;
 321   int major, minor, micro;
 322   char *tmp_version;
 323
 324   system("touch conf.xmltest");
 325
 326   /* Capture xml2-config output via autoconf/configure variables */
 327   /* HP/UX 9 (%@#!) writes to sscanf strings */
 328   tmp_version = (char *)strdup("$min_xml_version");
 329   if (sscanf(tmp_version, "%d.%d.%d", &major, &minor, &micro) != 3) {
 330      printf("%s, bad version string from xml2-config\n", "$min_xml_version");
 331      exit(1);
 332    }
 333    free(tmp_version);
 334
 335    /* Capture the version information from the header files */
 336    tmp_version = (char *)strdup(LIBXML_DOTTED_VERSION);
 337    if (sscanf(tmp_version, "%d.%d.%d", &xml_major_version, &xml_minor_version, &xml_micro_version) != 3) {
 338      printf("%s, bad version string from libxml includes\n", "LIBXML_DOTTED_VERSION");
 339      exit(1);
 340    }
 341    free(tmp_version);
 342
 343  /* Compare xml2-config output to the libxml headers */
 344   if ((xml_major_version != $xml_config_major_version) ||
 345       (xml_minor_version != $xml_config_minor_version) ||
 346       (xml_micro_version != $xml_config_micro_version))
 347     {
 348       printf("*** libxml header files (version %d.%d.%d) do not match\n",
 349          xml_major_version, xml_minor_version, xml_micro_version);
 350       printf("*** xml2-config (version %d.%d.%d)\n",
 351          $xml_config_major_version, $xml_config_minor_version, $xml_config_micro_version);
 352       return 1;
 353     }
 354 /* Compare the headers to the library to make sure we match */
 355   /* Less than ideal -- doesn't provide us with return value feedback,
 356    * only exits if there's a serious mismatch between header and library.
 357    */
 358     LIBXML_TEST_VERSION;
 359
 360     /* Test that the library is greater than our minimum version */
 361     if ((xml_major_version > major) ||
 362         ((xml_major_version == major) && (xml_minor_version > minor)) ||
 363         ((xml_major_version == major) && (xml_minor_version == minor) &&
 364         (xml_micro_version >= micro)))
 365       {
 366         return 0;
 367        }
 368      else
 369       {
 370         printf("\n*** An old version of libxml (%d.%d.%d) was found.\n",
 371                xml_major_version, xml_minor_version, xml_micro_version);
 372         printf("*** You need a version of libxml newer than %d.%d.%d. The latest version of\n",
 373            major, minor, micro);
 374         printf("*** libxml is always available from ftp://ftp.xmlsoft.org.\n");
 375         printf("***\n");
 376         printf("*** If you have already installed a sufficiently new version, this error\n");
 377         printf("*** probably means that the wrong copy of the xml2-config shell script is\n");
 378         printf("*** being found. The easiest way to fix this is to remove the old version\n");
 379         printf("*** of LIBXML, but you can also set the XML2_CONFIG environment to point to the\n");
 380         printf("*** correct copy of xml2-config. (In this case, you will have to\n");
 381         printf("*** modify your LD_LIBRARY_PATH enviroment variable, or edit /etc/ld.so.conf\n");
 382         printf("*** so that the correct libraries are found at run-time))\n");
 383     }
 384   return 1;
 385 }
 386 ],, no_xml=yes,[echo $ac_n "cross compiling; assumed OK... $ac_c"])
 387        CFLAGS="$ac_save_CFLAGS"
 388        LIBS="$ac_save_LIBS"
 389      fi
 390   fi
 391
 392   if test "x$no_xml" = x ; then
 393      AC_MSG_RESULT(yes (version $xml_config_major_version.$xml_config_minor_version.$xml_config_micro_version))
 394      ifelse([$2], , :, [$2])
 395   else
 396      AC_MSG_RESULT(no)
 397      if test "$XML2_CONFIG" = "no" ; then
 398        echo "*** The xml2-config script installed by LIBXML could not be found"
 399        echo "*** If libxml was installed in PREFIX, make sure PREFIX/bin is in"
 400        echo "*** your path, or set the XML2_CONFIG environment variable to the"
 401        echo "*** full path to xml2-config."
 402      else
 403        if test -f conf.xmltest ; then
 404         :
 405        else
 406           echo "*** Could not run libxml test program, checking why..."
 407           CFLAGS="$CFLAGS $XML_CFLAGS"
 408           LIBS="$LIBS $XML_LIBS"
 409           AC_TRY_LINK([
 410 #include <libxml/xmlversion.h>
 411 #include <stdio.h>
 412 ],      [ LIBXML_TEST_VERSION; return 0;],
 413         [ echo "*** The test program compiled, but did not run. This usually means"
 414           echo "*** that the run-time linker is not finding LIBXML or finding the wrong"
 415           echo "*** version of LIBXML. If it is not finding LIBXML, you'll need to set your"
 416           echo "*** LD_LIBRARY_PATH environment variable, or edit /etc/ld.so.conf to point"
 417           echo "*** to the installed location  Also, make sure you have run ldconfig if that"
 418           echo "*** is required on your system"
 419           echo "***"
 420           echo "*** If you have an old version installed, it is best to remove it, although"
 421           echo "*** you may also be able to get things to work by modifying LD_LIBRARY_PATH" ],
 422         [ echo "*** The test program failed to compile or link. See the file config.log for the"
 423           echo "*** exact error that occured. This usually means LIBXML was incorrectly installed"
 424           echo "*** or that you have moved LIBXML since it was installed. In the latter case, you"
 425           echo "*** may want to edit the xml2-config script: $XML2_CONFIG" ])
 426           CFLAGS="$ac_save_CFLAGS"
 427           LIBS="$ac_save_LIBS"
 428        fi
 429      fi
 430
 431      XML_CFLAGS=""
 432      XML_LIBS=""
 433      ifelse([$3], , :, [$3])
 434   fi
 435   AC_SUBST(XML_CFLAGS)
 436   AC_SUBST(XML_LIBS)
 437   rm -f conf.xmltest
 438 ])
 439
 440 # =========================================================================
 441 # AM_PATH_MYSQL : MySQL library
 442
 443 dnl AM_PATH_MYSQL([MINIMUM-VERSION, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]])
 444 dnl Test for MYSQL, and define MYSQL_CFLAGS and MYSQL_LIBS
 445 dnl
 446 AC_DEFUN(AM_PATH_MYSQL,
 447 [dnl
 448 dnl Get the cflags and libraries from the mysql_config script
 449 dnl
 450 AC_ARG_WITH(mysql-prefix,[  --with-mysql-prefix=PFX   Prefix where MYSQL is installed (optional)],
 451             mysql_prefix="$withval", mysql_prefix="")
 452 AC_ARG_WITH(mysql-exec-prefix,[  --with-mysql-exec-prefix=PFX Exec prefix where MYSQL is installed (optional)],
 453             mysql_exec_prefix="$withval", mysql_exec_prefix="")
 454
 455   if test x$mysql_exec_prefix != x ; then
 456      mysql_args="$mysql_args --exec-prefix=$mysql_exec_prefix"
 457      if test x${MYSQL_CONFIG+set} != xset ; then
 458         MYSQL_CONFIG=$mysql_exec_prefix/bin/mysql_config
 459      fi
 460   fi
 461   if test x$mysql_prefix != x ; then
 462      mysql_args="$mysql_args --prefix=$mysql_prefix"
 463      if test x${MYSQL_CONFIG+set} != xset ; then
 464         MYSQL_CONFIG=$mysql_prefix/bin/mysql_config
 465      fi
 466   fi
 467
 468   AC_REQUIRE([AC_CANONICAL_TARGET])
 469   AC_PATH_PROG(MYSQL_CONFIG, mysql_config, no)
 470   AC_MSG_CHECKING(for MYSQL)
 471   no_mysql=""
 472   if test "$MYSQL_CONFIG" = "no" ; then
 473     MYSQL_CFLAGS=""
 474     MYSQL_LIBS=""
 475     AC_MSG_RESULT(no)
 476      ifelse([$2], , :, [$2])
 477   else
 478     MYSQL_CFLAGS=`$MYSQL_CONFIG $mysqlconf_args --cflags | sed -e "s/'//g"`
 479     MYSQL_LIBS=`$MYSQL_CONFIG $mysqlconf_args --libs | sed -e "s/'//g"`
 480     AC_MSG_RESULT(yes)
 481     ifelse([$1], , :, [$1])
 482   fi
 483   AC_SUBST(MYSQL_CFLAGS)
 484   AC_SUBST(MYSQL_LIBS)
 485 ])
 486
 487 dnl Removes -I/usr/include/? from given variable
 488 AC_DEFUN(CFLAGS_REMOVE_USR_INCLUDE,[
 489   ac_new_flags=""
 490   for i in [$]$1; do
 491     case [$]i in
 492     -I/usr/include|-I/usr/include/) ;;
 493     *) ac_new_flags="[$]ac_new_flags [$]i" ;;
 494     esac
 495   done
 496   $1=[$]ac_new_flags
 497 ])
 498
 499 dnl Removes -L/usr/lib/? from given variable
 500 AC_DEFUN(LIB_REMOVE_USR_LIB,[
 501   ac_new_flags=""
 502   for i in [$]$1; do
 503     case [$]i in
 504     -L/usr/lib|-L/usr/lib/) ;;
 505     *) ac_new_flags="[$]ac_new_flags [$]i" ;;
 506     esac
 507   done
 508   $1=[$]ac_new_flags
 509 ])
 510
 511 dnl From Bruno Haible.
 512
 513 AC_DEFUN(jm_ICONV,
 514 [
 515   dnl Some systems have iconv in libc, some have it in libiconv (OSF/1 and
 516   dnl those with the standalone portable libiconv installed).
 517   AC_MSG_CHECKING(for iconv in $1)
 518     jm_cv_func_iconv="no"
 519     jm_cv_lib_iconv=""
 520     jm_cv_giconv=no
 521     jm_save_LIBS="$LIBS"
 522     LIBS="$LIBS -lbiconv"
 523     AC_TRY_LINK([#include <stdlib.h>
 524 #include <biconv.h>],
 525         [iconv_t cd = iconv_open("","");
 526          iconv(cd,NULL,NULL,NULL,NULL);
 527          iconv_close(cd);],
 528       jm_cv_func_iconv=yes
 529       jm_cv_biconv=yes
 530       jm_cv_include="biconv.h"
 531       jm_cv_lib_iconv="biconv")
 532       LIBS="$jm_save_LIBS"
 533
 534     dnl Check for include in funny place but no lib needed
 535     if test "$jm_cv_func_iconv" != yes; then
 536       AC_TRY_LINK([#include <stdlib.h>
 537 #include <giconv.h>],
 538         [iconv_t cd = iconv_open("","");
 539          iconv(cd,NULL,NULL,NULL,NULL);
 540          iconv_close(cd);],
 541          jm_cv_func_iconv=yes
 542          jm_cv_include="giconv.h"
 543          jm_cv_giconv="yes"
 544          jm_cv_lib_iconv="")
 545
 546       dnl Standard iconv.h include, lib in glibc or libc ...
 547       if test "$jm_cv_func_iconv" != yes; then
 548         AC_TRY_LINK([#include <stdlib.h>
 549 #include <iconv.h>],
 550           [iconv_t cd = iconv_open("","");
 551            iconv(cd,NULL,NULL,NULL,NULL);
 552            iconv_close(cd);],
 553            jm_cv_include="iconv.h"
 554            jm_cv_func_iconv=yes
 555            jm_cv_lib_iconv="")
 556
 557           if test "$jm_cv_lib_iconv" != yes; then
 558             jm_save_LIBS="$LIBS"
 559             LIBS="$LIBS -lgiconv"
 560             AC_TRY_LINK([#include <stdlib.h>
 561 #include <giconv.h>],
 562               [iconv_t cd = iconv_open("","");
 563                iconv(cd,NULL,NULL,NULL,NULL);
 564                iconv_close(cd);],
 565               jm_cv_lib_iconv=yes
 566               jm_cv_func_iconv=yes
 567               jm_cv_include="giconv.h"
 568               jm_cv_giconv=yes
 569               jm_cv_lib_iconv="giconv")
 570
 571            LIBS="$jm_save_LIBS"
 572
 573         if test "$jm_cv_func_iconv" != yes; then
 574           jm_save_LIBS="$LIBS"
 575           LIBS="$LIBS -liconv"
 576           AC_TRY_LINK([#include <stdlib.h>
 577 #include <iconv.h>],
 578             [iconv_t cd = iconv_open("","");
 579              iconv(cd,NULL,NULL,NULL,NULL);
 580              iconv_close(cd);],
 581             jm_cv_include="iconv.h"
 582             jm_cv_func_iconv=yes
 583             jm_cv_lib_iconv="iconv")
 584           LIBS="$jm_save_LIBS"
 585         fi
 586       fi
 587     fi
 588   fi
 589   if test "$jm_cv_func_iconv" = yes; then
 590     if test "$jm_cv_giconv" = yes; then
 591       AC_DEFINE(HAVE_GICONV, 1, [What header to include for iconv() function: giconv.h])
 592       AC_MSG_RESULT(yes)
 593       ICONV_FOUND=yes
 594     else
 595       if test "$jm_cv_biconv" = yes; then
 596         AC_DEFINE(HAVE_BICONV, 1, [What header to include for iconv() function: biconv.h])
 597         AC_MSG_RESULT(yes)
 598         ICONV_FOUND=yes
 599       else
 600         AC_DEFINE(HAVE_ICONV, 1, [What header to include for iconv() function: iconv.h])
 601         AC_MSG_RESULT(yes)
 602         ICONV_FOUND=yes
 603       fi
 604     fi
 605   else
 606     AC_MSG_RESULT(no)
 607   fi
 608 ])
 609
 610 AC_DEFUN(rjs_CHARSET,[
 611   dnl Find out if we can convert from $1 to UCS2-LE
 612   AC_MSG_CHECKING([can we convert from $1 to UCS2-LE?])
 613   AC_TRY_RUN([
 614 #include <$jm_cv_include>
 615 main(){
 616     iconv_t cd = iconv_open("$1", "UCS-2LE");
 617     if (cd == 0 || cd == (iconv_t)-1) {
 618         return -1;
 619     }
 620     return 0;
 621 }
 622   ],ICONV_CHARSET=$1,ICONV_CHARSET=no,ICONV_CHARSET=cross)
 623   AC_MSG_RESULT($ICONV_CHARSET)
 624 ])
 625
 626 dnl CFLAGS_ADD_DIR(CFLAGS, $INCDIR)
 627 dnl This function doesn't add -I/usr/include into CFLAGS
 628 AC_DEFUN(CFLAGS_ADD_DIR,[
 629 if test "$2" != "/usr/include" ; then
 630     $1="$$1 -I$2"
 631 fi
 632 ])
 633
 634 dnl LIB_ADD_DIR(LDFLAGS, $LIBDIR)
 635 dnl This function doesn't add -L/usr/lib into LDFLAGS
 636 AC_DEFUN(LIB_ADD_DIR,[
 637 if test "$2" != "/usr/lib" ; then
 638     $1="$$1 -L$2"
 639 fi
 640 ])
 641
 642 dnl AC_ENABLE_SHARED - implement the --enable-shared flag
 643 dnl Usage: AC_ENABLE_SHARED[(DEFAULT)]
 644 dnl   Where DEFAULT is either `yes' or `no'.  If omitted, it defaults to
 645 dnl   `yes'.
 646 AC_DEFUN([AC_ENABLE_SHARED],
 647 [define([AC_ENABLE_SHARED_DEFAULT], ifelse($1, no, no, yes))dnl
 648 AC_ARG_ENABLE(shared,
 649 changequote(<<, >>)dnl
 650 <<  --enable-shared[=PKGS]    build shared libraries [default=>>AC_ENABLE_SHARED_DEFAULT],
 651 changequote([, ])dnl
 652 [p=${PACKAGE-default}
 653 case $enableval in
 654 yes) enable_shared=yes ;;
 655 no) enable_shared=no ;;
 656 *)
 657   enable_shared=no
 658   # Look at the argument we got.  We use all the common list separators.
 659   IFS="${IFS=   }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 660   for pkg in $enableval; do
 661     if test "X$pkg" = "X$p"; then
 662       enable_shared=yes
 663     fi
 664
 665   done
 666   IFS="$ac_save_ifs"
 667   ;;
 668 esac],
 669 enable_shared=AC_ENABLE_SHARED_DEFAULT)dnl
 670 ])
 671
 672 dnl AC_ENABLE_STATIC - implement the --enable-static flag
 673 dnl Usage: AC_ENABLE_STATIC[(DEFAULT)]
 674 dnl   Where DEFAULT is either `yes' or `no'.  If omitted, it defaults to
 675 dnl   `yes'.
 676 AC_DEFUN([AC_ENABLE_STATIC],
 677 [define([AC_ENABLE_STATIC_DEFAULT], ifelse($1, no, no, yes))dnl
 678 AC_ARG_ENABLE(static,
 679 changequote(<<, >>)dnl
 680 <<  --enable-static[=PKGS]    build static libraries [default=>>AC_ENABLE_STATIC_DEFAULT],
 681 changequote([, ])dnl
 682 [p=${PACKAGE-default}
 683 case $enableval in
 684 yes) enable_static=yes ;;
 685 no) enable_static=no ;;
 686 *)
 687   enable_static=no
 688   # Look at the argument we got.  We use all the common list separators.
 689   IFS="${IFS=   }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 690   for pkg in $enableval; do
 691     if test "X$pkg" = "X$p"; then
 692       enable_static=yes
 693     fi
 694   done
 695   IFS="$ac_save_ifs"
 696   ;;
 697 esac],
 698 enable_static=AC_ENABLE_STATIC_DEFAULT)dnl
 699 ])
 700
 701 dnl AC_DISABLE_STATIC - set the default static flag to --disable-static
 702 AC_DEFUN([AC_DISABLE_STATIC],
 703 [AC_BEFORE([$0],[AC_LIBTOOL_SETUP])dnl
 704 AC_ENABLE_STATIC(no)])
 705
 706 dnl AC_TRY_RUN_STRICT(PROGRAM,CFLAGS,CPPFLAGS,LDFLAGS,
 707 dnl             [ACTION-IF-TRUE],[ACTION-IF-FALSE],
 708 dnl             [ACTION-IF-CROSS-COMPILING = RUNTIME-ERROR])
 709 AC_DEFUN( [AC_TRY_RUN_STRICT],
 710 [
 711         old_CFLAGS="$CFLAGS";
 712         CFLAGS="$2";
 713         export CFLAGS;
 714         old_CPPFLAGS="$CPPFLAGS";
 715         CPPFLAGS="$3";
 716         export CPPFLAGS;
 717         old_LDFLAGS="$LDFLAGS";
 718         LDFLAGS="$4";
 719         export LDFLAGS;
 720         AC_TRY_RUN([$1],[$5],[$6],[$7]);
 721         CFLAGS="$old_CFLAGS";
 722         old_CFLAGS="";
 723         export CFLAGS;
 724         CPPFLAGS="$old_CPPFLAGS";
 725         old_CPPFLAGS="";
 726         export CPPFLAGS;
 727         LDFLAGS="$old_LDFLAGS";
 728         old_LDFLAGS="";
 729         export LDFLAGS;
 730 ])