source3/samba4.m4

   1 BLDSHARED=true
   2 AC_SUBST(BLDSHARED)
   3 smbtorture4_path=bin/smbtorture4
   4 m4_include(build/m4/public.m4)
   5
   6 m4_include(build/m4/check_python.m4)
   7
   8 m4_include(build/m4/ac_pkg_swig.m4)
   9
  10 AC_PROG_SWIG(1.3.36)
  11
  12 AC_SAMBA_PYTHON_DEVEL([
  13 SMB_EXT_LIB(EXT_LIB_PYTHON, [$PYTHON_LDFLAGS], [$PYTHON_CFLAGS])
  14 SMB_ENABLE(EXT_LIB_PYTHON,YES)
  15 SMB_ENABLE(LIBPYTHON,YES)
  16 ],[
  17 AC_MSG_ERROR([Python not found. Please install Python 2.x and its development headers/libraries.])
  18 ])
  19
  20 AC_MSG_CHECKING(python library directory)
  21 pythondir=`$PYTHON -c "from distutils import sysconfig; print sysconfig.get_python_lib(1, 0, '\\${prefix}')"`
  22 AC_MSG_RESULT($pythondir)
  23
  24 AC_SUBST(pythondir)
  25
  26 m4_include(lib/smbreadline/readline.m4)
  27 m4_include(heimdal_build/internal.m4)
  28 m4_include(../lib/util/fault.m4)
  29 m4_include(../lib/util/signal.m4)
  30 m4_include(../lib/util/util.m4)
  31 m4_include(../lib/util/fsusage.m4)
  32 m4_include(../lib/util/xattr.m4)
  33 m4_include(../lib/util/capability.m4)
  34 m4_include(../lib/util/time.m4)
  35 m4_include(../lib/popt/samba.m4)
  36 m4_include(lib/charset/config.m4)
  37 m4_include(lib/socket/config.m4)
  38 m4_include(nsswitch/nsstest.m4)
  39 m4_include(../pidl/config.m4)
  40 m4_include(lib/zlib.m4)
  41
  42 AC_CONFIG_FILES(../source4/lib/registry/registry.pc)
  43 AC_CONFIG_FILES(../source4/librpc/dcerpc.pc)
  44 AC_CONFIG_FILES(../librpc/ndr.pc)
  45 AC_CONFIG_FILES(../source4/lib/torture/torture.pc)
  46 AC_CONFIG_FILES(../source4/auth/gensec/gensec.pc)
  47 AC_CONFIG_FILES(../source4/param/samba-hostconfig.pc)
  48 AC_CONFIG_FILES(../source4/librpc/dcerpc_samr.pc)
  49 AC_CONFIG_FILES(../source4/librpc/dcerpc_atsvc.pc)
  50
  51 SMB_EXT_LIB_FROM_PKGCONFIG(LIBTALLOC, talloc >= 1.2.0,
  52         [],
  53         [
  54                 SMB_INCLUDE_MK(../lib/talloc/config.mk)
  55         ]
  56 )
  57
  58 SMB_EXT_LIB_FROM_PKGCONFIG(LIBTDB, tdb >= 1.1.3,
  59         [],
  60         [
  61                 m4_include(../lib/tdb/libtdb.m4)
  62                 SMB_INCLUDE_MK(../lib/tdb/config.mk)
  63         ]
  64 )
  65
  66 SMB_INCLUDE_MK(../lib/tdb/python.mk)
  67
  68 SMB_EXT_LIB_FROM_PKGCONFIG(LIBLDB, ldb >= 0.9.1,
  69         [
  70                 SMB_INCLUDE_MK(lib/ldb/ldb_ildap/config.mk)
  71                 SMB_INCLUDE_MK(lib/ldb/tools/config.mk)
  72                 define_ldb_modulesdir=no
  73         ],
  74         [
  75                 # Here we need to do some tricks
  76                 # with AC_CONFIG_COMMANDS_PRE
  77                 # as that's the deferrs the commands
  78                 # to location after $prefix and $exec_prefix
  79                 # have usefull values and directly before
  80                 # creating config.status.
  81                 #
  82                 # The 'eval eval echo' trick is used to
  83                 # actually get the raw absolute directory
  84                 # path as this is needed in config.h
  85                 define_ldb_modulesdir=yes
  86                 AC_CONFIG_COMMANDS_PRE([
  87                 if test x"$define_ldb_modulesdir" = x"yes";then
  88                         LDB_MODULESDIR=`eval eval echo ${modulesdir}/ldb`
  89                         AC_DEFINE_UNQUOTED(LDB_MODULESDIR, "${LDB_MODULESDIR}" , [ldb Modules directory])
  90                 fi
  91                 ])
  92                 ldbdir="\$(abspath \$(srcdir)/../source4/lib/ldb)"
  93                 AC_SUBST(ldbdir)
  94                 m4_include(lib/ldb/sqlite3.m4)
  95                 m4_include(lib/ldb/libldb.m4)
  96                 SMB_INCLUDE_MK(lib/ldb/config.mk)
  97                 AC_CONFIG_FILES(../source4/lib/ldb/ldb.pc)
  98         ]
  99 )
 100 SMB_INCLUDE_MK(lib/ldb/python.mk)
 101
 102 # Not sure why we need this..
 103 SMB_ENABLE(swig_ldb,YES)
 104
 105 m4_include(lib/tls/config.m4)
 106 eventsdir="../source4/lib/events"
 107 m4_include(lib/events/libevents.m4)
 108
 109 dnl m4_include(auth/kerberos/config.m4)
 110 m4_include(auth/gensec/config.m4)
 111 m4_include(smbd/process_model.m4)
 112 m4_include(ntvfs/posix/config.m4)
 113 m4_include(ntvfs/unixuid/config.m4)
 114 m4_include(auth/config.m4)
 115 m4_include(kdc/config.m4)
 116 m4_include(ntvfs/sysdep/config.m4)
 117 m4_include(nsswitch/config.m4)
 118
 119 dnl Samba 4 files
 120 AC_SUBST(LD)
 121 AC_LIBREPLACE_SHLD_FLAGS
 122 SMB_WRITE_MAKEVARS(samba4-config.mk, [prefix exec_prefix CPPFLAGS LDSHFLAGS POPT_OBJ CFLAGS TALLOC_OBJ POPT_LIBS])
 123
 124 oldbuilddir="$builddir"
 125 builddir="$builddir/../source4"
 126 SMB_WRITE_PERLVARS(../source4/build/smb_build/config.pm)
 127 builddir="$oldbuilddir"
 128
 129 echo "configure: creating ../source4/config.mk"
 130 cat >../source4/config.mk<<CEOF
 131 # config.mk - Autogenerated by configure, DO NOT EDIT!
 132 $SMB_INFO_EXT_LIBS
 133 $SMB_INFO_SUBSYSTEMS
 134 $SMB_INFO_LIBRARIES
 135 CEOF
 136
 137 AC_OUTPUT_COMMANDS([
 138 cd ${srcdir}/../source4
 139 USESHARED=false $PERL -I${builddir} -I${builddir}/build \
 140     -I. -Ibuild \
 141     build/smb_build/main.pl --output=../source3/samba4-data.mk main.mk || exit $?
 142 cd ../source3
 143 ],[
 144 srcdir="$srcdir"
 145 builddir="$builddir"
 146 PERL="$PERL"
 147
 148 export PERL
 149 export srcdir
 150 export builddir
 151 ])
 152
 153 AC_CONFIG_COMMANDS([Makefile-samba4], [
 154 echo "include samba4.mk" >> ${builddir}/Makefile
 155 ])
 156