scripts/recordmcount.pl

   1 #!/usr/bin/perl -w
   2 # (c) 2008, Steven Rostedt <srostedt@redhat.com>
   3 # Licensed under the terms of the GNU GPL License version 2
   4 #
   5 # recordmcount.pl - makes a section called __mcount_loc that holds
   6 #                   all the offsets to the calls to mcount.
   7 #
   8 #
   9 # What we want to end up with is a section in vmlinux called
  10 # __mcount_loc that contains a list of pointers to all the
  11 # call sites in the kernel that call mcount. Later on boot up, the kernel
  12 # will read this list, save the locations and turn them into nops.
  13 # When tracing or profiling is later enabled, these locations will then
  14 # be converted back to pointers to some function.
  15 #
  16 # This is no easy feat. This script is called just after the original
  17 # object is compiled and before it is linked.
  18 #
  19 # The references to the call sites are offsets from the section of text
  20 # that the call site is in. Hence, all functions in a section that
  21 # has a call site to mcount, will have the offset from the beginning of
  22 # the section and not the beginning of the function.
  23 #
  24 # The trick is to find a way to record the beginning of the section.
  25 # The way we do this is to look at the first function in the section
  26 # which will also be the location of that section after final link.
  27 # e.g.
  28 #
  29 #  .section ".text.sched"
  30 #  .globl my_func
  31 #  my_func:
  32 #        [...]
  33 #        call mcount  (offset: 0x5)
  34 #        [...]
  35 #        ret
  36 #  other_func:
  37 #        [...]
  38 #        call mcount (offset: 0x1b)
  39 #        [...]
  40 #
  41 # Both relocation offsets for the mcounts in the above example will be
  42 # offset from .text.sched. If we make another file called tmp.s with:
  43 #
  44 #  .section __mcount_loc
  45 #  .quad  my_func + 0x5
  46 #  .quad  my_func + 0x1b
  47 #
  48 # We can then compile this tmp.s into tmp.o, and link it to the original
  49 # object.
  50 #
  51 # But this gets hard if my_func is not globl (a static function).
  52 # In such a case we have:
  53 #
  54 #  .section ".text.sched"
  55 #  my_func:
  56 #        [...]
  57 #        call mcount  (offset: 0x5)
  58 #        [...]
  59 #        ret
  60 #  .globl my_func
  61 #  other_func:
  62 #        [...]
  63 #        call mcount (offset: 0x1b)
  64 #        [...]
  65 #
  66 # If we make the tmp.s the same as above, when we link together with
  67 # the original object, we will end up with two symbols for my_func:
  68 # one local, one global.  After final compile, we will end up with
  69 # an undefined reference to my_func.
  70 #
  71 # Since local objects can reference local variables, we need to find
  72 # a way to make tmp.o reference the local objects of the original object
  73 # file after it is linked together. To do this, we convert the my_func
  74 # into a global symbol before linking tmp.o. Then after we link tmp.o
  75 # we will only have a single symbol for my_func that is global.
  76 # We can convert my_func back into a local symbol and we are done.
  77 #
  78 # Here are the steps we take:
  79 #
  80 # 1) Record all the local symbols by using 'nm'
  81 # 2) Use objdump to find all the call site offsets and sections for
  82 #    mcount.
  83 # 3) Compile the list into its own object.
  84 # 4) Do we have to deal with local functions? If not, go to step 8.
  85 # 5) Make an object that converts these local functions to global symbols
  86 #    with objcopy.
  87 # 6) Link together this new object with the list object.
  88 # 7) Convert the local functions back to local symbols and rename
  89 #    the result as the original object.
  90 #    End.
  91 # 8) Link the object with the list object.
  92 # 9) Move the result back to the original object.
  93 #    End.
  94 #
  95
  96 use strict;
  97
  98 my $P = $0;
  99 $P =~ s@.*/@@g;
 100
 101 my $V = '0.1';
 102
 103 if ($#ARGV < 6) {
 104         print "usage: $P arch objdump objcopy cc ld nm rm mv inputfile\n";
 105         print "version: $V\n";
 106         exit(1);
 107 }
 108
 109 my ($arch, $bits, $objdump, $objcopy, $cc,
 110     $ld, $nm, $rm, $mv, $inputfile) = @ARGV;
 111
 112 # Acceptable sections to record.
 113 my %text_sections = (
 114      ".text" => 1,
 115      ".sched.text" => 1,
 116      ".spinlock.text" => 1,
 117 );
 118
 119 $objdump = "objdump" if ((length $objdump) == 0);
 120 $objcopy = "objcopy" if ((length $objcopy) == 0);
 121 $cc = "gcc" if ((length $cc) == 0);
 122 $ld = "ld" if ((length $ld) == 0);
 123 $nm = "nm" if ((length $nm) == 0);
 124 $rm = "rm" if ((length $rm) == 0);
 125 $mv = "mv" if ((length $mv) == 0);
 126
 127 #print STDERR "running: $P '$arch' '$objdump' '$objcopy' '$cc' '$ld' " .
 128 #    "'$nm' '$rm' '$mv' '$inputfile'\n";
 129
 130 my %locals;             # List of local (static) functions
 131 my %weak;               # List of weak functions
 132 my %convert;            # List of local functions used that needs conversion
 133
 134 my $type;
 135 my $nm_regex;           # Find the local functions (return function)
 136 my $section_regex;      # Find the start of a section
 137 my $function_regex;     # Find the name of a function
 138                         #    (return offset and func name)
 139 my $mcount_regex;       # Find the call site to mcount (return offset)
 140 my $alignment;          # The .align value to use for $mcount_section
 141 my $section_type;       # Section header plus possible alignment command
 142
 143 if ($arch eq "x86") {
 144     if ($bits == 64) {
 145         $arch = "x86_64";
 146     } else {
 147         $arch = "i386";
 148     }
 149 }
 150
 151 #
 152 # We base the defaults off of i386, the other archs may
 153 # feel free to change them in the below if statements.
 154 #
 155 $nm_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\S+)";
 156 $section_regex = "Disassembly of section\\s+(\\S+):";
 157 $function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
 158 $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount\$";
 159 $section_type = '@progbits';
 160 $type = ".long";
 161
 162 if ($arch eq "x86_64") {
 163     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount([+-]0x[0-9a-zA-Z]+)?\$";
 164     $type = ".quad";
 165     $alignment = 8;
 166
 167     # force flags for this arch
 168     $ld .= " -m elf_x86_64";
 169     $objdump .= " -M x86-64";
 170     $objcopy .= " -O elf64-x86-64";
 171     $cc .= " -m64";
 172
 173 } elsif ($arch eq "i386") {
 174     $alignment = 4;
 175
 176     # force flags for this arch
 177     $ld .= " -m elf_i386";
 178     $objdump .= " -M i386";
 179     $objcopy .= " -O elf32-i386";
 180     $cc .= " -m32";
 181
 182 } elsif ($arch eq "sh") {
 183     $alignment = 2;
 184
 185     # force flags for this arch
 186     $ld .= " -m shlelf_linux";
 187     $objcopy .= " -O elf32-sh-linux";
 188     $cc .= " -m32";
 189
 190 } elsif ($arch eq "powerpc") {
 191     $nm_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\.?\\S+)";
 192     $function_regex = "^([0-9a-fA-F]+)\\s+<(\\.?.*?)>:";
 193     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s\\.?_mcount\$";
 194
 195     if ($bits == 64) {
 196         $type = ".quad";
 197     }
 198
 199 } elsif ($arch eq "arm") {
 200     $alignment = 2;
 201     $section_type = '%progbits';
 202
 203 } else {
 204     die "Arch $arch is not supported with CONFIG_FTRACE_MCOUNT_RECORD";
 205 }
 206
 207 my $text_found = 0;
 208 my $read_function = 0;
 209 my $opened = 0;
 210 my $mcount_section = "__mcount_loc";
 211
 212 my $dirname;
 213 my $filename;
 214 my $prefix;
 215 my $ext;
 216
 217 if ($inputfile =~ m,^(.*)/([^/]*)$,) {
 218     $dirname = $1;
 219     $filename = $2;
 220 } else {
 221     $dirname = ".";
 222     $filename = $inputfile;
 223 }
 224
 225 if ($filename =~ m,^(.*)(\.\S),) {
 226     $prefix = $1;
 227     $ext = $2;
 228 } else {
 229     $prefix = $filename;
 230     $ext = "";
 231 }
 232
 233 my $mcount_s = $dirname . "/.tmp_mc_" . $prefix . ".s";
 234 my $mcount_o = $dirname . "/.tmp_mc_" . $prefix . ".o";
 235
 236 #
 237 # --globalize-symbols came out in 2.17, we must test the version
 238 # of objcopy, and if it is less than 2.17, then we can not
 239 # record local functions.
 240 my $use_locals = 01;
 241 my $local_warn_once = 0;
 242 my $found_version = 0;
 243
 244 open (IN, "$objcopy --version |") || die "error running $objcopy";
 245 while (<IN>) {
 246     if (/objcopy.*\s(\d+)\.(\d+)/) {
 247         my $major = $1;
 248         my $minor = $2;
 249
 250         $found_version = 1;
 251         if ($major < 2 ||
 252             ($major == 2 && $minor < 17)) {
 253             $use_locals = 0;
 254         }
 255         last;
 256     }
 257 }
 258 close (IN);
 259
 260 if (!$found_version) {
 261     print STDERR "WARNING: could not find objcopy version.\n" .
 262         "\tDisabling local function references.\n";
 263 }
 264
 265
 266 #
 267 # Step 1: find all the local (static functions) and weak symbols.
 268 #        't' is local, 'w/W' is weak (we never use a weak function)
 269 #
 270 open (IN, "$nm $inputfile|") || die "error running $nm";
 271 while (<IN>) {
 272     if (/$nm_regex/) {
 273         $locals{$1} = 1;
 274     } elsif (/^[0-9a-fA-F]+\s+([wW])\s+(\S+)/) {
 275         $weak{$2} = $1;
 276     }
 277 }
 278 close(IN);
 279
 280 my @offsets;            # Array of offsets of mcount callers
 281 my $ref_func;           # reference function to use for offsets
 282 my $offset = 0;         # offset of ref_func to section beginning
 283
 284 ##
 285 # update_funcs - print out the current mcount callers
 286 #
 287 #  Go through the list of offsets to callers and write them to
 288 #  the output file in a format that can be read by an assembler.
 289 #
 290 sub update_funcs
 291 {
 292     return if ($#offsets < 0);
 293
 294     defined($ref_func) || die "No function to reference";
 295
 296     # A section only had a weak function, to represent it.
 297     # Unfortunately, a weak function may be overwritten by another
 298     # function of the same name, making all these offsets incorrect.
 299     # To be safe, we simply print a warning and bail.
 300     if (defined $weak{$ref_func}) {
 301         print STDERR
 302             "$inputfile: WARNING: referencing weak function" .
 303             " $ref_func for mcount\n";
 304         return;
 305     }
 306
 307     # is this function static? If so, note this fact.
 308     if (defined $locals{$ref_func}) {
 309
 310         # only use locals if objcopy supports globalize-symbols
 311         if (!$use_locals) {
 312             return;
 313         }
 314         $convert{$ref_func} = 1;
 315     }
 316
 317     # Loop through all the mcount caller offsets and print a reference
 318     # to the caller based from the ref_func.
 319     for (my $i=0; $i <= $#offsets; $i++) {
 320         if (!$opened) {
 321             open(FILE, ">$mcount_s") || die "can't create $mcount_s\n";
 322             $opened = 1;
 323             print FILE "\t.section $mcount_section,\"a\",$section_type\n";
 324             print FILE "\t.align $alignment\n" if (defined($alignment));
 325         }
 326         printf FILE "\t%s %s + %d\n", $type, $ref_func, $offsets[$i] - $offset;
 327     }
 328 }
 329
 330 #
 331 # Step 2: find the sections and mcount call sites
 332 #
 333 open(IN, "$objdump -dr $inputfile|") || die "error running $objdump";
 334
 335 my $text;
 336
 337 while (<IN>) {
 338     # is it a section?
 339     if (/$section_regex/) {
 340
 341         # Only record text sections that we know are safe
 342         if (defined($text_sections{$1})) {
 343             $read_function = 1;
 344         } else {
 345             $read_function = 0;
 346         }
 347         # print out any recorded offsets
 348         update_funcs() if ($text_found);
 349
 350         # reset all markers and arrays
 351         $text_found = 0;
 352         undef($ref_func);
 353         undef(@offsets);
 354
 355     # section found, now is this a start of a function?
 356     } elsif ($read_function && /$function_regex/) {
 357         $text_found = 1;
 358         $offset = hex $1;
 359         $text = $2;
 360
 361         # if this is either a local function or a weak function
 362         # keep looking for functions that are global that
 363         # we can use safely.
 364         if (!defined($locals{$text}) && !defined($weak{$text})) {
 365             $ref_func = $text;
 366             $read_function = 0;
 367         } else {
 368             # if we already have a function, and this is weak, skip it
 369             if (!defined($ref_func) || !defined($weak{$text})) {
 370                 $ref_func = $text;
 371             }
 372         }
 373     }
 374
 375     # is this a call site to mcount? If so, record it to print later
 376     if ($text_found && /$mcount_regex/) {
 377         $offsets[$#offsets + 1] = hex $1;
 378     }
 379 }
 380
 381 # dump out anymore offsets that may have been found
 382 update_funcs() if ($text_found);
 383
 384 # If we did not find any mcount callers, we are done (do nothing).
 385 if (!$opened) {
 386     exit(0);
 387 }
 388
 389 close(FILE);
 390
 391 #
 392 # Step 3: Compile the file that holds the list of call sites to mcount.
 393 #
 394 `$cc -o $mcount_o -c $mcount_s`;
 395
 396 my @converts = keys %convert;
 397
 398 #
 399 # Step 4: Do we have sections that started with local functions?
 400 #
 401 if ($#converts >= 0) {
 402     my $globallist = "";
 403     my $locallist = "";
 404
 405     foreach my $con (@converts) {
 406         $globallist .= " --globalize-symbol $con";
 407         $locallist .= " --localize-symbol $con";
 408     }
 409
 410     my $globalobj = $dirname . "/.tmp_gl_" . $filename;
 411     my $globalmix = $dirname . "/.tmp_mx_" . $filename;
 412
 413     #
 414     # Step 5: set up each local function as a global
 415     #
 416     `$objcopy $globallist $inputfile $globalobj`;
 417
 418     #
 419     # Step 6: Link the global version to our list.
 420     #
 421     `$ld -r $globalobj $mcount_o -o $globalmix`;
 422
 423     #
 424     # Step 7: Convert the local functions back into local symbols
 425     #
 426     `$objcopy $locallist $globalmix $inputfile`;
 427
 428     # Remove the temp files
 429     `$rm $globalobj $globalmix`;
 430
 431 } else {
 432
 433     my $mix = $dirname . "/.tmp_mx_" . $filename;
 434
 435     #
 436     # Step 8: Link the object with our list of call sites object.
 437     #
 438     `$ld -r $inputfile $mcount_o -o $mix`;
 439
 440     #
 441     # Step 9: Move the result back to the original object.
 442     #
 443     `$mv $mix $inputfile`;
 444 }
 445
 446 # Clean up the temp files
 447 `$rm $mcount_o $mcount_s`;
 448
 449 exit(0);