arch/sparc64/kernel/sys32.S

   1 /* $Id: sys32.S,v 1.12 2000/03/24 04:17:37 davem Exp $
   2  * sys32.S: I-cache tricks for 32-bit compatibility layer simple
   3  *          conversions.
   4  *
   5  * Copyright (C) 1997 David S. Miller (davem@caip.rutgers.edu)
   6  * Copyright (C) 1998 Jakub Jelinek   (jj@ultra.linux.cz)
   7  */
   8
   9 #include <linux/config.h>
  10 #include <asm/errno.h>
  11
  12 /* NOTE: call as jump breaks return stack, we have to avoid that */
  13
  14         .text
  15
  16 #define SIGN1(STUB,SYSCALL,REG1) \
  17         .align  32; \
  18         .globl  STUB; \
  19 STUB:   sethi   %hi(SYSCALL), %g1; \
  20         jmpl    %g1 + %lo(SYSCALL), %g0; \
  21         sra     REG1, 0, REG1
  22
  23 #define SIGN2(STUB,SYSCALL,REG1,REG2) \
  24         .align  32; \
  25         .globl  STUB; \
  26 STUB:   sethi   %hi(SYSCALL), %g1; \
  27         sra     REG1, 0, REG1; \
  28         jmpl    %g1 + %lo(SYSCALL), %g0; \
  29         sra     REG2, 0, REG2
  30
  31 #define SIGN3(STUB,SYSCALL,REG1,REG2,REG3) \
  32         .align  32; \
  33         .globl  STUB; \
  34 STUB:   sra     REG1, 0, REG1; \
  35         sethi   %hi(SYSCALL), %g1; \
  36         sra     REG2, 0, REG2; \
  37         jmpl    %g1 + %lo(SYSCALL), %g0; \
  38         sra     REG3, 0, REG3
  39
  40 #define SIGN4(STUB,SYSCALL,REG1,REG2,REG3,REG4) \
  41         .align  32; \
  42         .globl  STUB; \
  43 STUB:   sra     REG1, 0, REG1; \
  44         sethi   %hi(SYSCALL), %g1; \
  45         sra     REG2, 0, REG2; \
  46         sra     REG3, 0, REG3; \
  47         jmpl    %g1 + %lo(SYSCALL), %g0; \
  48         sra     REG4, 0, REG4
  49
  50 SIGN1(sys32_exit, sparc_exit, %o0)
  51 SIGN1(sys32_exit_group, sys_exit_group, %o0)
  52 SIGN1(sys32_wait4, compat_sys_wait4, %o2)
  53 SIGN1(sys32_creat, sys_creat, %o1)
  54 SIGN1(sys32_mknod, sys_mknod, %o1)
  55 SIGN1(sys32_perfctr, sys_perfctr, %o0)
  56 SIGN1(sys32_umount, sys_umount, %o1)
  57 SIGN1(sys32_signal, sys_signal, %o0)
  58 SIGN1(sys32_access, sys_access, %o1)
  59 SIGN1(sys32_msync, sys_msync, %o2)
  60 SIGN2(sys32_reboot, sys_reboot, %o0, %o1)
  61 SIGN1(sys32_setitimer, compat_sys_setitimer, %o0)
  62 SIGN1(sys32_getitimer, compat_sys_getitimer, %o0)
  63 SIGN1(sys32_sethostname, sys_sethostname, %o1)
  64 SIGN1(sys32_swapon, sys_swapon, %o1)
  65 SIGN1(sys32_sigaction, compat_sys_sigaction, %o0)
  66 SIGN1(sys32_rt_sigaction, compat_sys_rt_sigaction, %o0)
  67 SIGN1(sys32_sigprocmask, compat_sys_sigprocmask, %o0)
  68 SIGN1(sys32_rt_sigprocmask, compat_sys_rt_sigprocmask, %o0)
  69 SIGN2(sys32_rt_sigqueueinfo, compat_sys_rt_sigqueueinfo, %o0, %o1)
  70 SIGN1(sys32_getrusage, compat_sys_getrusage, %o0)
  71 SIGN1(sys32_setxattr, sys_setxattr, %o4)
  72 SIGN1(sys32_lsetxattr, sys_lsetxattr, %o4)
  73 SIGN1(sys32_fsetxattr, sys_fsetxattr, %o4)
  74 SIGN1(sys32_fgetxattr, sys_fgetxattr, %o0)
  75 SIGN1(sys32_flistxattr, sys_flistxattr, %o0)
  76 SIGN1(sys32_fremovexattr, sys_fremovexattr, %o0)
  77 SIGN2(sys32_tkill, sys_tkill, %o0, %o1)
  78 SIGN1(sys32_epoll_create, sys_epoll_create, %o0)
  79 SIGN3(sys32_epoll_ctl, sys_epoll_ctl, %o0, %o1, %o2)
  80 SIGN3(sys32_epoll_wait, sys_epoll_wait, %o0, %o2, %o3)
  81 SIGN1(sys32_readahead, compat_sys_readahead, %o0)
  82 SIGN2(sys32_fadvise64, compat_sys_fadvise64, %o0, %o4)
  83 SIGN2(sys32_fadvise64_64, compat_sys_fadvise64_64, %o0, %o5)
  84 SIGN2(sys32_bdflush, sys_bdflush, %o0, %o1)
  85 SIGN1(sys32_mlockall, sys_mlockall, %o0)
  86 SIGN1(sys32_nfsservctl, compat_sys_nfsservctl, %o0)
  87 SIGN1(sys32_clock_settime, compat_sys_clock_settime, %o1)
  88 SIGN1(sys32_clock_nanosleep, compat_sys_clock_nanosleep, %o1)
  89 SIGN1(sys32_timer_settime, compat_sys_timer_settime, %o1)
  90 SIGN1(sys32_io_submit, compat_sys_io_submit, %o1)
  91 SIGN1(sys32_mq_open, compat_sys_mq_open, %o1)
  92 SIGN1(sys32_select, compat_sys_select, %o0)
  93 SIGN1(sys32_mkdir, sys_mkdir, %o1)
  94 SIGN3(sys32_futex, compat_sys_futex, %o1, %o2, %o5)
  95 SIGN1(sys32_sysfs, compat_sys_sysfs, %o0)
  96 SIGN3(sys32_ipc, compat_sys_ipc, %o1, %o2, %o3)
  97 SIGN2(sys32_sendfile, compat_sys_sendfile, %o0, %o1)
  98 SIGN2(sys32_sendfile64, compat_sys_sendfile64, %o0, %o1)
  99 SIGN1(sys32_prctl, sys_prctl, %o0)
 100 SIGN1(sys32_sched_rr_get_interval, compat_sys_sched_rr_get_interval, %o0)
 101 SIGN2(sys32_waitpid, sys_waitpid, %o0, %o2)
 102 SIGN1(sys32_getgroups, sys_getgroups, %o0)
 103 SIGN1(sys32_getpgid, sys_getpgid, %o0)
 104 SIGN2(sys32_getpriority, sys_getpriority, %o0, %o1)
 105 SIGN1(sys32_getsid, sys_getsid, %o0)
 106 SIGN2(sys32_kill, sys_kill, %o0, %o1)
 107 SIGN1(sys32_nice, sys_nice, %o0)
 108 SIGN1(sys32_lseek, sys_lseek, %o1)
 109 SIGN2(sys32_open, sparc32_open, %o1, %o2)
 110 SIGN1(sys32_readlink, sys_readlink, %o2)
 111 SIGN1(sys32_sched_get_priority_max, sys_sched_get_priority_max, %o0)
 112 SIGN1(sys32_sched_get_priority_min, sys_sched_get_priority_min, %o0)
 113 SIGN1(sys32_sched_getparam, sys_sched_getparam, %o0)
 114 SIGN1(sys32_sched_getscheduler, sys_sched_getscheduler, %o0)
 115 SIGN1(sys32_sched_setparam, sys_sched_setparam, %o0)
 116 SIGN2(sys32_sched_setscheduler, sys_sched_setscheduler, %o0, %o1)
 117 SIGN1(sys32_getdomainname, sys_getdomainname, %o1)
 118 SIGN1(sys32_setdomainname, sys_setdomainname, %o1)
 119 SIGN1(sys32_setgroups, sys_setgroups, %o0)
 120 SIGN2(sys32_setpgid, sys_setpgid, %o0, %o1)
 121 SIGN3(sys32_setpriority, sys_setpriority, %o0, %o1, %o2)
 122 SIGN1(sys32_ssetmask, sys_ssetmask, %o0)
 123 SIGN2(sys32_syslog, sys_syslog, %o0, %o2)
 124 SIGN1(sys32_umask, sys_umask, %o0)
 125 SIGN3(sys32_tgkill, sys_tgkill, %o0, %o1, %o2)
 126 SIGN1(sys32_sendto, sys_sendto, %o0)
 127 SIGN1(sys32_recvfrom, sys_recvfrom, %o0)
 128 SIGN3(sys32_socket, sys_socket, %o0, %o1, %o2)
 129 SIGN2(sys32_connect, sys_connect, %o0, %o2)
 130 SIGN2(sys32_bind, sys_bind, %o0, %o2)
 131 SIGN2(sys32_listen, sys_listen, %o0, %o1)
 132 SIGN1(sys32_recvmsg, compat_sys_recvmsg, %o0)
 133 SIGN1(sys32_sendmsg, compat_sys_sendmsg, %o0)
 134 SIGN2(sys32_shutdown, sys_shutdown, %o0, %o1)
 135 SIGN3(sys32_socketpair, sys_socketpair, %o0, %o1, %o2)
 136 SIGN1(sys32_getpeername, sys_getpeername, %o0)
 137 SIGN1(sys32_getsockname, sys_getsockname, %o0)
 138 SIGN2(sys32_ioprio_get, sys_ioprio_get, %o0, %o1)
 139 SIGN3(sys32_ioprio_set, sys_ioprio_set, %o0, %o1, %o2)
 140
 141         .globl          sys32_mmap2
 142 sys32_mmap2:
 143         sethi           %hi(sys_mmap), %g1
 144         jmpl            %g1 + %lo(sys_mmap), %g0
 145          sllx           %o5, 12, %o5
 146
 147         .align          32
 148         .globl          sys32_socketcall
 149 sys32_socketcall:       /* %o0=call, %o1=args */
 150         cmp             %o0, 1
 151         bl,pn           %xcc, do_einval
 152          cmp            %o0, 17
 153         bg,pn           %xcc, do_einval
 154          sub            %o0, 1, %o0
 155         sllx            %o0, 5, %o0
 156         sethi           %hi(__socketcall_table_begin), %g2
 157         or              %g2, %lo(__socketcall_table_begin), %g2
 158         jmpl            %g2 + %o0, %g0
 159          nop
 160
 161         /* Each entry is exactly 32 bytes. */
 162         .align          32
 163 __socketcall_table_begin:
 164 do_sys_socket: /* sys_socket(int, int, int) */
 165         ldswa           [%o1 + 0x0] %asi, %o0
 166         sethi           %hi(sys_socket), %g1
 167         ldswa           [%o1 + 0x8] %asi, %o2
 168         jmpl            %g1 + %lo(sys_socket), %g0
 169          ldswa          [%o1 + 0x4] %asi, %o1
 170         nop
 171         nop
 172         nop
 173 do_sys_bind: /* sys_bind(int fd, struct sockaddr *, int) */
 174         ldswa           [%o1 + 0x0] %asi, %o0
 175         sethi           %hi(sys_bind), %g1
 176         ldswa           [%o1 + 0x8] %asi, %o2
 177         jmpl            %g1 + %lo(sys_bind), %g0
 178          lduwa          [%o1 + 0x4] %asi, %o1
 179         nop
 180         nop
 181         nop
 182 do_sys_connect: /* sys_connect(int, struct sockaddr *, int) */
 183         ldswa           [%o1 + 0x0] %asi, %o0
 184         sethi           %hi(sys_connect), %g1
 185         ldswa           [%o1 + 0x8] %asi, %o2
 186         jmpl            %g1 + %lo(sys_connect), %g0
 187          lduwa          [%o1 + 0x4] %asi, %o1
 188         nop
 189         nop
 190         nop
 191 do_sys_listen: /* sys_listen(int, int) */
 192         ldswa           [%o1 + 0x0] %asi, %o0
 193         sethi           %hi(sys_listen), %g1
 194         jmpl            %g1 + %lo(sys_listen), %g0
 195          ldswa          [%o1 + 0x4] %asi, %o1
 196         nop
 197         nop
 198         nop
 199         nop
 200 do_sys_accept: /* sys_accept(int, struct sockaddr *, int *) */
 201         ldswa           [%o1 + 0x0] %asi, %o0
 202         sethi           %hi(sys_accept), %g1
 203         lduwa           [%o1 + 0x8] %asi, %o2
 204         jmpl            %g1 + %lo(sys_accept), %g0
 205          lduwa          [%o1 + 0x4] %asi, %o1
 206         nop
 207         nop
 208         nop
 209 do_sys_getsockname: /* sys_getsockname(int, struct sockaddr *, int *) */
 210         ldswa           [%o1 + 0x0] %asi, %o0
 211         sethi           %hi(sys_getsockname), %g1
 212         lduwa           [%o1 + 0x8] %asi, %o2
 213         jmpl            %g1 + %lo(sys_getsockname), %g0
 214          lduwa          [%o1 + 0x4] %asi, %o1
 215         nop
 216         nop
 217         nop
 218 do_sys_getpeername: /* sys_getpeername(int, struct sockaddr *, int *) */
 219         ldswa           [%o1 + 0x0] %asi, %o0
 220         sethi           %hi(sys_getpeername), %g1
 221         lduwa           [%o1 + 0x8] %asi, %o2
 222         jmpl            %g1 + %lo(sys_getpeername), %g0
 223          lduwa          [%o1 + 0x4] %asi, %o1
 224         nop
 225         nop
 226         nop
 227 do_sys_socketpair: /* sys_socketpair(int, int, int, int *) */
 228         ldswa           [%o1 + 0x0] %asi, %o0
 229         sethi           %hi(sys_socketpair), %g1
 230         ldswa           [%o1 + 0x8] %asi, %o2
 231         lduwa           [%o1 + 0xc] %asi, %o3
 232         jmpl            %g1 + %lo(sys_socketpair), %g0
 233          ldswa          [%o1 + 0x4] %asi, %o1
 234         nop
 235         nop
 236 do_sys_send: /* sys_send(int, void *, size_t, unsigned int) */
 237         ldswa           [%o1 + 0x0] %asi, %o0
 238         sethi           %hi(sys_send), %g1
 239         lduwa           [%o1 + 0x8] %asi, %o2
 240         lduwa           [%o1 + 0xc] %asi, %o3
 241         jmpl            %g1 + %lo(sys_send), %g0
 242          lduwa          [%o1 + 0x4] %asi, %o1
 243         nop
 244         nop
 245 do_sys_recv: /* sys_recv(int, void *, size_t, unsigned int) */
 246         ldswa           [%o1 + 0x0] %asi, %o0
 247         sethi           %hi(sys_recv), %g1
 248         lduwa           [%o1 + 0x8] %asi, %o2
 249         lduwa           [%o1 + 0xc] %asi, %o3
 250         jmpl            %g1 + %lo(sys_recv), %g0
 251          lduwa          [%o1 + 0x4] %asi, %o1
 252         nop
 253         nop
 254 do_sys_sendto: /* sys_sendto(int, u32, compat_size_t, unsigned int, u32, int) */
 255         ldswa           [%o1 + 0x0] %asi, %o0
 256         sethi           %hi(sys_sendto), %g1
 257         lduwa           [%o1 + 0x8] %asi, %o2
 258         lduwa           [%o1 + 0xc] %asi, %o3
 259         lduwa           [%o1 + 0x10] %asi, %o4
 260         ldswa           [%o1 + 0x14] %asi, %o5
 261         jmpl            %g1 + %lo(sys_sendto), %g0
 262          lduwa          [%o1 + 0x4] %asi, %o1
 263 do_sys_recvfrom: /* sys_recvfrom(int, u32, compat_size_t, unsigned int, u32, u32) */
 264         ldswa           [%o1 + 0x0] %asi, %o0
 265         sethi           %hi(sys_recvfrom), %g1
 266         lduwa           [%o1 + 0x8] %asi, %o2
 267         lduwa           [%o1 + 0xc] %asi, %o3
 268         lduwa           [%o1 + 0x10] %asi, %o4
 269         lduwa           [%o1 + 0x14] %asi, %o5
 270         jmpl            %g1 + %lo(sys_recvfrom), %g0
 271          lduwa          [%o1 + 0x4] %asi, %o1
 272 do_sys_shutdown: /* sys_shutdown(int, int) */
 273         ldswa           [%o1 + 0x0] %asi, %o0
 274         sethi           %hi(sys_shutdown), %g1
 275         jmpl            %g1 + %lo(sys_shutdown), %g0
 276          ldswa          [%o1 + 0x4] %asi, %o1
 277         nop
 278         nop
 279         nop
 280         nop
 281 do_sys_setsockopt: /* compat_sys_setsockopt(int, int, int, char *, int) */
 282         ldswa           [%o1 + 0x0] %asi, %o0
 283         sethi           %hi(compat_sys_setsockopt), %g1
 284         ldswa           [%o1 + 0x8] %asi, %o2
 285         lduwa           [%o1 + 0xc] %asi, %o3
 286         ldswa           [%o1 + 0x10] %asi, %o4
 287         jmpl            %g1 + %lo(compat_sys_setsockopt), %g0
 288          ldswa          [%o1 + 0x4] %asi, %o1
 289         nop
 290 do_sys_getsockopt: /* compat_sys_getsockopt(int, int, int, u32, u32) */
 291         ldswa           [%o1 + 0x0] %asi, %o0
 292         sethi           %hi(compat_sys_getsockopt), %g1
 293         ldswa           [%o1 + 0x8] %asi, %o2
 294         lduwa           [%o1 + 0xc] %asi, %o3
 295         lduwa           [%o1 + 0x10] %asi, %o4
 296         jmpl            %g1 + %lo(compat_sys_getsockopt), %g0
 297          ldswa          [%o1 + 0x4] %asi, %o1
 298         nop
 299 do_sys_sendmsg: /* compat_sys_sendmsg(int, struct compat_msghdr *, unsigned int) */
 300         ldswa           [%o1 + 0x0] %asi, %o0
 301         sethi           %hi(compat_sys_sendmsg), %g1
 302         lduwa           [%o1 + 0x8] %asi, %o2
 303         jmpl            %g1 + %lo(compat_sys_sendmsg), %g0
 304          lduwa          [%o1 + 0x4] %asi, %o1
 305         nop
 306         nop
 307         nop
 308 do_sys_recvmsg: /* compat_sys_recvmsg(int, struct compat_msghdr *, unsigned int) */
 309         ldswa           [%o1 + 0x0] %asi, %o0
 310         sethi           %hi(compat_sys_recvmsg), %g1
 311         lduwa           [%o1 + 0x8] %asi, %o2
 312         jmpl            %g1 + %lo(compat_sys_recvmsg), %g0
 313          lduwa          [%o1 + 0x4] %asi, %o1
 314         nop
 315         nop
 316         nop
 317 __socketcall_table_end:
 318
 319 do_einval:
 320         retl
 321          mov            -EINVAL, %o0
 322 do_efault:
 323         retl
 324          mov            -EFAULT, %o0
 325
 326         .section        __ex_table
 327         .align          4
 328         .word           __socketcall_table_begin, 0, __socketcall_table_end, do_efault
 329         .previous