arch/s390/kernel/vdso64/clock_gettime.S

   1 /*
   2  * Userland implementation of clock_gettime() for 64 bits processes in a
   3  * s390 kernel for use in the vDSO
   4  *
   5  *  Copyright IBM Corp. 2008
   6  *  Author(s): Martin Schwidefsky (schwidefsky@de.ibm.com)
   7  *
   8  * This program is free software; you can redistribute it and/or modify
   9  * it under the terms of the GNU General Public License (version 2 only)
  10  * as published by the Free Software Foundation.
  11  */
  12 #include <asm/vdso.h>
  13 #include <asm/asm-offsets.h>
  14 #include <asm/unistd.h>
  15
  16         .text
  17         .align 4
  18         .globl __kernel_clock_gettime
  19         .type  __kernel_clock_gettime,@function
  20 __kernel_clock_gettime:
  21         .cfi_startproc
  22         larl    %r5,_vdso_data
  23         cghi    %r2,__CLOCK_REALTIME
  24         je      5f
  25         cghi    %r2,__CLOCK_THREAD_CPUTIME_ID
  26         je      9f
  27         cghi    %r2,-2          /* Per-thread CPUCLOCK with PID=0, VIRT=1 */
  28         je      9f
  29         cghi    %r2,__CLOCK_MONOTONIC
  30         jne     12f
  31
  32         /* CLOCK_MONOTONIC */
  33 0:      lg      %r4,__VDSO_UPD_COUNT(%r5)       /* load update counter */
  34         tmll    %r4,0x0001                      /* pending update ? loop */
  35         jnz     0b
  36         stck    48(%r15)                        /* Store TOD clock */
  37         lgf     %r2,__VDSO_TK_SHIFT(%r5)        /* Timekeeper shift */
  38         lg      %r0,__VDSO_WTOM_SEC(%r5)
  39         lg      %r1,48(%r15)
  40         sg      %r1,__VDSO_XTIME_STAMP(%r5)     /* TOD - cycle_last */
  41         msgf    %r1,__VDSO_TK_MULT(%r5)         /*  * tk->mult */
  42         alg     %r1,__VDSO_WTOM_NSEC(%r5)
  43         srlg    %r1,%r1,0(%r2)                  /*  >> tk->shift */
  44         clg     %r4,__VDSO_UPD_COUNT(%r5)       /* check update counter */
  45         jne     0b
  46         larl    %r5,13f
  47 1:      clg     %r1,0(%r5)
  48         jl      2f
  49         slg     %r1,0(%r5)
  50         aghi    %r0,1
  51         j       1b
  52 2:      stg     %r0,0(%r3)                      /* store tp->tv_sec */
  53         stg     %r1,8(%r3)                      /* store tp->tv_nsec */
  54         lghi    %r2,0
  55         br      %r14
  56
  57         /* CLOCK_REALTIME */
  58 5:      lg      %r4,__VDSO_UPD_COUNT(%r5)       /* load update counter */
  59         tmll    %r4,0x0001                      /* pending update ? loop */
  60         jnz     5b
  61         stck    48(%r15)                        /* Store TOD clock */
  62         lgf     %r2,__VDSO_TK_SHIFT(%r5)        /* Timekeeper shift */
  63         lg      %r1,48(%r15)
  64         sg      %r1,__VDSO_XTIME_STAMP(%r5)     /* TOD - cycle_last */
  65         msgf    %r1,__VDSO_TK_MULT(%r5)         /*  * tk->mult */
  66         alg     %r1,__VDSO_XTIME_NSEC(%r5)      /*  + tk->xtime_nsec */
  67         srlg    %r1,%r1,0(%r2)                  /*  >> tk->shift */
  68         lg      %r0,__VDSO_XTIME_SEC(%r5)       /* tk->xtime_sec */
  69         clg     %r4,__VDSO_UPD_COUNT(%r5)       /* check update counter */
  70         jne     5b
  71         larl    %r5,13f
  72 6:      clg     %r1,0(%r5)
  73         jl      7f
  74         slg     %r1,0(%r5)
  75         aghi    %r0,1
  76         j       6b
  77 7:      stg     %r0,0(%r3)                      /* store tp->tv_sec */
  78         stg     %r1,8(%r3)                      /* store tp->tv_nsec */
  79         lghi    %r2,0
  80         br      %r14
  81
  82         /* CLOCK_THREAD_CPUTIME_ID for this thread */
  83 9:      icm     %r0,15,__VDSO_ECTG_OK(%r5)
  84         jz      12f
  85         ear     %r2,%a4
  86         llilh   %r4,0x0100
  87         sar     %a4,%r4
  88         lghi    %r4,0
  89         epsw    %r5,0
  90         sacf    512                             /* Magic ectg instruction */
  91         .insn   ssf,0xc80100000000,__VDSO_ECTG_BASE(4),__VDSO_ECTG_USER(4),4
  92         tml     %r5,0x4000
  93         jo      11f
  94         tml     %r5,0x8000
  95         jno     10f
  96         sacf    256
  97         j       11f
  98 10:     sacf    0
  99 11:     sar     %a4,%r2
 100         algr    %r1,%r0                         /* r1 = cputime as TOD value */
 101         mghi    %r1,1000                        /* convert to nanoseconds */
 102         srlg    %r1,%r1,12                      /* r1 = cputime in nanosec */
 103         lgr     %r4,%r1
 104         larl    %r5,13f
 105         srlg    %r1,%r1,9                       /* divide by 1000000000 */
 106         mlg     %r0,8(%r5)
 107         srlg    %r0,%r0,11                      /* r0 = tv_sec */
 108         stg     %r0,0(%r3)
 109         msg     %r0,0(%r5)                      /* calculate tv_nsec */
 110         slgr    %r4,%r0                         /* r4 = tv_nsec */
 111         stg     %r4,8(%r3)
 112         lghi    %r2,0
 113         br      %r14
 114
 115         /* Fallback to system call */
 116 12:     lghi    %r1,__NR_clock_gettime
 117         svc     0
 118         br      %r14
 119
 120 13:     .quad   1000000000
 121 14:     .quad   19342813113834067
 122         .cfi_endproc
 123         .size   __kernel_clock_gettime,.-__kernel_clock_gettime