arch/arm64/kernel/vmlinux.lds.S

   1 /*
   2  * ld script to make ARM Linux kernel
   3  * taken from the i386 version by Russell King
   4  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   5  */
   6
   7 #include <asm-generic/vmlinux.lds.h>
   8 #include <asm/cache.h>
   9 #include <asm/kernel-pgtable.h>
  10 #include <asm/thread_info.h>
  11 #include <asm/memory.h>
  12 #include <asm/page.h>
  13 #include <asm/pgtable.h>
  14
  15 #include "image.h"
  16
  17 /* .exit.text needed in case of alternative patching */
  18 #define ARM_EXIT_KEEP(x)        x
  19 #define ARM_EXIT_DISCARD(x)
  20
  21 OUTPUT_ARCH(aarch64)
  22 ENTRY(_text)
  23
  24 jiffies = jiffies_64;
  25
  26 #define HYPERVISOR_TEXT                                 \
  27         /*                                              \
  28          * Align to 4 KB so that                        \
  29          * a) the HYP vector table is at its minimum    \
  30          *    alignment of 2048 bytes                   \
  31          * b) the HYP init code will not cross a page   \
  32          *    boundary if its size does not exceed      \
  33          *    4 KB (see related ASSERT() below)         \
  34          */                                             \
  35         . = ALIGN(SZ_4K);                               \
  36         VMLINUX_SYMBOL(__hyp_idmap_text_start) = .;     \
  37         *(.hyp.idmap.text)                              \
  38         VMLINUX_SYMBOL(__hyp_idmap_text_end) = .;       \
  39         VMLINUX_SYMBOL(__hyp_text_start) = .;           \
  40         *(.hyp.text)                                    \
  41         VMLINUX_SYMBOL(__hyp_text_end) = .;
  42
  43 #define IDMAP_TEXT                                      \
  44         . = ALIGN(SZ_4K);                               \
  45         VMLINUX_SYMBOL(__idmap_text_start) = .;         \
  46         *(.idmap.text)                                  \
  47         VMLINUX_SYMBOL(__idmap_text_end) = .;
  48
  49 /*
  50  * The size of the PE/COFF section that covers the kernel image, which
  51  * runs from stext to _edata, must be a round multiple of the PE/COFF
  52  * FileAlignment, which we set to its minimum value of 0x200. 'stext'
  53  * itself is 4 KB aligned, so padding out _edata to a 0x200 aligned
  54  * boundary should be sufficient.
  55  */
  56 PECOFF_FILE_ALIGNMENT = 0x200;
  57
  58 #ifdef CONFIG_EFI
  59 #define PECOFF_EDATA_PADDING    \
  60         .pecoff_edata_padding : { BYTE(0); . = ALIGN(PECOFF_FILE_ALIGNMENT); }
  61 #else
  62 #define PECOFF_EDATA_PADDING
  63 #endif
  64
  65 #if defined(CONFIG_DEBUG_ALIGN_RODATA)
  66 #define ALIGN_DEBUG_RO                  . = ALIGN(1<<SECTION_SHIFT);
  67 #define ALIGN_DEBUG_RO_MIN(min)         ALIGN_DEBUG_RO
  68 #elif defined(CONFIG_DEBUG_RODATA)
  69 #define ALIGN_DEBUG_RO                  . = ALIGN(1<<PAGE_SHIFT);
  70 #define ALIGN_DEBUG_RO_MIN(min)         ALIGN_DEBUG_RO
  71 #else
  72 #define ALIGN_DEBUG_RO
  73 #define ALIGN_DEBUG_RO_MIN(min)         . = ALIGN(min);
  74 #endif
  75
  76 SECTIONS
  77 {
  78         /*
  79          * XXX: The linker does not define how output sections are
  80          * assigned to input sections when there are multiple statements
  81          * matching the same input section name.  There is no documented
  82          * order of matching.
  83          */
  84         /DISCARD/ : {
  85                 ARM_EXIT_DISCARD(EXIT_TEXT)
  86                 ARM_EXIT_DISCARD(EXIT_DATA)
  87                 EXIT_CALL
  88                 *(.discard)
  89                 *(.discard.*)
  90                 *(.interp .dynamic)
  91         }
  92
  93         . = KIMAGE_VADDR + TEXT_OFFSET;
  94
  95         .head.text : {
  96                 _text = .;
  97                 HEAD_TEXT
  98         }
  99         ALIGN_DEBUG_RO_MIN(PAGE_SIZE)
 100         .text : {                       /* Real text segment            */
 101                 _stext = .;             /* Text and read-only data      */
 102                         __exception_text_start = .;
 103                         *(.exception.text)
 104                         __exception_text_end = .;
 105                         IRQENTRY_TEXT
 106                         SOFTIRQENTRY_TEXT
 107                         TEXT_TEXT
 108                         SCHED_TEXT
 109                         LOCK_TEXT
 110                         HYPERVISOR_TEXT
 111                         IDMAP_TEXT
 112                         *(.fixup)
 113                         *(.gnu.warning)
 114                 . = ALIGN(16);
 115                 *(.got)                 /* Global offset table          */
 116         }
 117
 118         ALIGN_DEBUG_RO_MIN(PAGE_SIZE)
 119         RO_DATA(PAGE_SIZE)              /* everything from this point to */
 120         EXCEPTION_TABLE(8)              /* _etext will be marked RO NX   */
 121         NOTES
 122
 123         ALIGN_DEBUG_RO_MIN(PAGE_SIZE)
 124         _etext = .;                     /* End of text and rodata section */
 125         __init_begin = .;
 126
 127         INIT_TEXT_SECTION(8)
 128         .exit.text : {
 129                 ARM_EXIT_KEEP(EXIT_TEXT)
 130         }
 131
 132         .init.data : {
 133                 INIT_DATA
 134                 INIT_SETUP(16)
 135                 INIT_CALLS
 136                 CON_INITCALL
 137                 SECURITY_INITCALL
 138                 INIT_RAM_FS
 139                 *(.init.rodata.* .init.bss)     /* from the EFI stub */
 140         }
 141         .exit.data : {
 142                 ARM_EXIT_KEEP(EXIT_DATA)
 143         }
 144
 145         PERCPU_SECTION(L1_CACHE_BYTES)
 146
 147         . = ALIGN(4);
 148         .altinstructions : {
 149                 __alt_instructions = .;
 150                 *(.altinstructions)
 151                 __alt_instructions_end = .;
 152         }
 153         .altinstr_replacement : {
 154                 *(.altinstr_replacement)
 155         }
 156         .rela : ALIGN(8) {
 157                 __reloc_start = .;
 158                 *(.rela .rela*)
 159                 __reloc_end = .;
 160         }
 161         .dynsym : ALIGN(8) {
 162                 __dynsym_start = .;
 163                 *(.dynsym)
 164         }
 165         .dynstr : {
 166                 *(.dynstr)
 167         }
 168         .hash : {
 169                 *(.hash)
 170         }
 171
 172         . = ALIGN(PAGE_SIZE);
 173         __init_end = .;
 174
 175         _data = .;
 176         _sdata = .;
 177         RW_DATA_SECTION(L1_CACHE_BYTES, PAGE_SIZE, THREAD_SIZE)
 178         PECOFF_EDATA_PADDING
 179         _edata = .;
 180
 181         BSS_SECTION(0, 0, 0)
 182
 183         . = ALIGN(PAGE_SIZE);
 184         idmap_pg_dir = .;
 185         . += IDMAP_DIR_SIZE;
 186         swapper_pg_dir = .;
 187         . += SWAPPER_DIR_SIZE;
 188
 189         _end = .;
 190
 191         STABS_DEBUG
 192
 193         HEAD_SYMBOLS
 194 }
 195
 196 /*
 197  * The HYP init code and ID map text can't be longer than a page each,
 198  * and should not cross a page boundary.
 199  */
 200 ASSERT(__hyp_idmap_text_end - (__hyp_idmap_text_start & ~(SZ_4K - 1)) <= SZ_4K,
 201         "HYP init code too big or misaligned")
 202 ASSERT(__idmap_text_end - (__idmap_text_start & ~(SZ_4K - 1)) <= SZ_4K,
 203         "ID map text too big or misaligned")
 204
 205 /*
 206  * If padding is applied before .head.text, virt<->phys conversions will fail.
 207  */
 208 ASSERT(_text == (KIMAGE_VADDR + TEXT_OFFSET), "HEAD is misaligned")