arch/arm/kernel/head-common.S

   1 /*
   2  *  linux/arch/arm/kernel/head-common.S
   3  *
   4  *  Copyright (C) 1994-2002 Russell King
   5  *  Copyright (c) 2003 ARM Limited
   6  *  All Rights Reserved
   7  *
   8  * This program is free software; you can redistribute it and/or modify
   9  * it under the terms of the GNU General Public License version 2 as
  10  * published by the Free Software Foundation.
  11  *
  12  */
  13
  14 #define ATAG_CORE 0x54410001
  15 #define ATAG_CORE_SIZE ((2*4 + 3*4) >> 2)
  16
  17         .type   __switch_data, %object
  18 __switch_data:
  19         .long   __mmap_switched
  20         .long   __data_loc                      @ r4
  21         .long   _data                           @ r5
  22         .long   __bss_start                     @ r6
  23         .long   _end                            @ r7
  24         .long   processor_id                    @ r4
  25         .long   __machine_arch_type             @ r5
  26         .long   __atags_pointer                 @ r6
  27         .long   cr_alignment                    @ r7
  28         .long   init_thread_union + THREAD_START_SP @ sp
  29
  30 /*
  31  * The following fragment of code is executed with the MMU on in MMU mode,
  32  * and uses absolute addresses; this is not position independent.
  33  *
  34  *  r0  = cp#15 control register
  35  *  r1  = machine ID
  36  *  r2  = atags pointer
  37  *  r9  = processor ID
  38  */
  39 __mmap_switched:
  40         adr     r3, __switch_data + 4
  41
  42         ldmia   r3!, {r4, r5, r6, r7}
  43         cmp     r4, r5                          @ Copy data segment if needed
  44 1:      cmpne   r5, r6
  45         ldrne   fp, [r4], #4
  46         strne   fp, [r5], #4
  47         bne     1b
  48
  49         mov     fp, #0                          @ Clear BSS (and zero fp)
  50 1:      cmp     r6, r7
  51         strcc   fp, [r6],#4
  52         bcc     1b
  53
  54         ldmia   r3, {r4, r5, r6, r7, sp}
  55         str     r9, [r4]                        @ Save processor ID
  56         str     r1, [r5]                        @ Save machine type
  57         str     r2, [r6]                        @ Save atags pointer
  58         bic     r4, r0, #CR_A                   @ Clear 'A' bit
  59         stmia   r7, {r0, r4}                    @ Save control register values
  60         b       start_kernel
  61 ENDPROC(__mmap_switched)
  62
  63 /*
  64  * Exception handling.  Something went wrong and we can't proceed.  We
  65  * ought to tell the user, but since we don't have any guarantee that
  66  * we're even running on the right architecture, we do virtually nothing.
  67  *
  68  * If CONFIG_DEBUG_LL is set we try to print out something about the error
  69  * and hope for the best (useful if bootloader fails to pass a proper
  70  * machine ID for example).
  71  */
  72 __error_p:
  73 #ifdef CONFIG_DEBUG_LL
  74         adr     r0, str_p1
  75         bl      printascii
  76         mov     r0, r9
  77         bl      printhex8
  78         adr     r0, str_p2
  79         bl      printascii
  80         b       __error
  81 str_p1: .asciz  "\nError: unrecognized/unsupported processor variant (0x"
  82 str_p2: .asciz  ").\n"
  83         .align
  84 #endif
  85 ENDPROC(__error_p)
  86
  87 __error_a:
  88 #ifdef CONFIG_DEBUG_LL
  89         mov     r4, r1                          @ preserve machine ID
  90         adr     r0, str_a1
  91         bl      printascii
  92         mov     r0, r4
  93         bl      printhex8
  94         adr     r0, str_a2
  95         bl      printascii
  96         adr     r3, 3f
  97         ldmia   r3, {r4, r5, r6}                @ get machine desc list
  98         sub     r4, r3, r4                      @ get offset between virt&phys
  99         add     r5, r5, r4                      @ convert virt addresses to
 100         add     r6, r6, r4                      @ physical address space
 101 1:      ldr     r0, [r5, #MACHINFO_TYPE]        @ get machine type
 102         bl      printhex8
 103         mov     r0, #'\t'
 104         bl      printch
 105         ldr     r0, [r5, #MACHINFO_NAME]        @ get machine name
 106         add     r0, r0, r4
 107         bl      printascii
 108         mov     r0, #'\n'
 109         bl      printch
 110         add     r5, r5, #SIZEOF_MACHINE_DESC    @ next machine_desc
 111         cmp     r5, r6
 112         blo     1b
 113         adr     r0, str_a3
 114         bl      printascii
 115         b       __error
 116 ENDPROC(__error_a)
 117
 118 str_a1: .asciz  "\nError: unrecognized/unsupported machine ID (r1 = 0x"
 119 str_a2: .asciz  ").\n\nAvailable machine support:\n\nID (hex)\tNAME\n"
 120 str_a3: .asciz  "\nPlease check your kernel config and/or bootloader.\n"
 121         .align
 122 #endif
 123
 124 __error:
 125 #ifdef CONFIG_ARCH_RPC
 126 /*
 127  * Turn the screen red on a error - RiscPC only.
 128  */
 129         mov     r0, #0x02000000
 130         mov     r3, #0x11
 131         orr     r3, r3, r3, lsl #8
 132         orr     r3, r3, r3, lsl #16
 133         str     r3, [r0], #4
 134         str     r3, [r0], #4
 135         str     r3, [r0], #4
 136         str     r3, [r0], #4
 137 #endif
 138 1:      mov     r0, r0
 139         b       1b
 140 ENDPROC(__error)
 141
 142
 143 /*
 144  * Read processor ID register (CP#15, CR0), and look up in the linker-built
 145  * supported processor list.  Note that we can't use the absolute addresses
 146  * for the __proc_info lists since we aren't running with the MMU on
 147  * (and therefore, we are not in the correct address space).  We have to
 148  * calculate the offset.
 149  *
 150  *      r9 = cpuid
 151  * Returns:
 152  *      r3, r4, r6 corrupted
 153  *      r5 = proc_info pointer in physical address space
 154  *      r9 = cpuid (preserved)
 155  */
 156 __lookup_processor_type:
 157         adr     r3, 3f
 158         ldmda   r3, {r5 - r7}
 159         sub     r3, r3, r7                      @ get offset between virt&phys
 160         add     r5, r5, r3                      @ convert virt addresses to
 161         add     r6, r6, r3                      @ physical address space
 162 1:      ldmia   r5, {r3, r4}                    @ value, mask
 163         and     r4, r4, r9                      @ mask wanted bits
 164         teq     r3, r4
 165         beq     2f
 166         add     r5, r5, #PROC_INFO_SZ           @ sizeof(proc_info_list)
 167         cmp     r5, r6
 168         blo     1b
 169         mov     r5, #0                          @ unknown processor
 170 2:      mov     pc, lr
 171 ENDPROC(__lookup_processor_type)
 172
 173 /*
 174  * This provides a C-API version of the above function.
 175  */
 176 ENTRY(lookup_processor_type)
 177         stmfd   sp!, {r4 - r7, r9, lr}
 178         mov     r9, r0
 179         bl      __lookup_processor_type
 180         mov     r0, r5
 181         ldmfd   sp!, {r4 - r7, r9, pc}
 182 ENDPROC(lookup_processor_type)
 183
 184 /*
 185  * Look in <asm/procinfo.h> and arch/arm/kernel/arch.[ch] for
 186  * more information about the __proc_info and __arch_info structures.
 187  */
 188         .long   __proc_info_begin
 189         .long   __proc_info_end
 190 3:      .long   .
 191         .long   __arch_info_begin
 192         .long   __arch_info_end
 193
 194 /*
 195  * Lookup machine architecture in the linker-build list of architectures.
 196  * Note that we can't use the absolute addresses for the __arch_info
 197  * lists since we aren't running with the MMU on (and therefore, we are
 198  * not in the correct address space).  We have to calculate the offset.
 199  *
 200  *  r1 = machine architecture number
 201  * Returns:
 202  *  r3, r4, r6 corrupted
 203  *  r5 = mach_info pointer in physical address space
 204  */
 205 __lookup_machine_type:
 206         adr     r3, 3b
 207         ldmia   r3, {r4, r5, r6}
 208         sub     r3, r3, r4                      @ get offset between virt&phys
 209         add     r5, r5, r3                      @ convert virt addresses to
 210         add     r6, r6, r3                      @ physical address space
 211 1:      ldr     r3, [r5, #MACHINFO_TYPE]        @ get machine type
 212         teq     r3, r1                          @ matches loader number?
 213         beq     2f                              @ found
 214         add     r5, r5, #SIZEOF_MACHINE_DESC    @ next machine_desc
 215         cmp     r5, r6
 216         blo     1b
 217         mov     r5, #0                          @ unknown machine
 218 2:      mov     pc, lr
 219 ENDPROC(__lookup_machine_type)
 220
 221 /*
 222  * This provides a C-API version of the above function.
 223  */
 224 ENTRY(lookup_machine_type)
 225         stmfd   sp!, {r4 - r6, lr}
 226         mov     r1, r0
 227         bl      __lookup_machine_type
 228         mov     r0, r5
 229         ldmfd   sp!, {r4 - r6, pc}
 230 ENDPROC(lookup_machine_type)
 231
 232 /* Determine validity of the r2 atags pointer.  The heuristic requires
 233  * that the pointer be aligned, in the first 16k of physical RAM and
 234  * that the ATAG_CORE marker is first and present.  Future revisions
 235  * of this function may be more lenient with the physical address and
 236  * may also be able to move the ATAGS block if necessary.
 237  *
 238  * r8  = machinfo
 239  *
 240  * Returns:
 241  *  r2 either valid atags pointer, or zero
 242  *  r5, r6 corrupted
 243  */
 244 __vet_atags:
 245         tst     r2, #0x3                        @ aligned?
 246         bne     1f
 247
 248         ldr     r5, [r2, #0]                    @ is first tag ATAG_CORE?
 249         subs    r5, r5, #ATAG_CORE_SIZE
 250         bne     1f
 251         ldr     r5, [r2, #4]
 252         ldr     r6, =ATAG_CORE
 253         cmp     r5, r6
 254         bne     1f
 255
 256         mov     pc, lr                          @ atag pointer is ok
 257
 258 1:      mov     r2, #0
 259         mov     pc, lr
 260 ENDPROC(__vet_atags)