source4/build/m4/public.m4

   1 dnl SMB Build System
   2 dnl ----------------
   3 dnl Copyright (C) 2004 Stefan Metzmacher
   4 dnl Copyright (C) 2004-2005 Jelmer Vernooij
   5 dnl Published under the GPL
   6 dnl
   7 dnl SMB_SUBSYSTEM(name,obj_files,required_subsystems)
   8 dnl
   9 dnl SMB_EXT_LIB_FROM_PKGCONFIG(name,pkg-config name)
  10 dnl
  11 dnl SMB_EXT_LIB(name,libs,cflags,cppflags,ldflags)
  12 dnl
  13 dnl SMB_ENABLE(name,default_build)
  14 dnl
  15 dnl #######################################################
  16 dnl ### And now the implementation                      ###
  17 dnl #######################################################
  18
  19 dnl SMB_SUBSYSTEM(name,obj_files,required_subsystems)
  20 AC_DEFUN([SMB_SUBSYSTEM],
  21 [
  22         if test -z "$[SMB_SUBSYSTEM_NOPROTO_][$1]"; then
  23                 [SMB_SUBSYSTEM_NOPROTO_][$1]="NO";
  24         fi
  25
  26 SMB_INFO_SUBSYSTEMS="$SMB_INFO_SUBSYSTEMS
  27 ###################################
  28 # Start Subsystem $1
  29 @<:@SUBSYSTEM::$1@:>@
  30 OBJ_FILES = $2
  31 PRIVATE_DEPENDENCIES = $3
  32 ENABLE = YES
  33 # End Subsystem $1
  34 ###################################
  35 "
  36 ])
  37
  38 dnl SMB_EXT_LIB_FROM_PKGCONFIG(name,pkg-config name)
  39 AC_DEFUN([SMB_EXT_LIB_FROM_PKGCONFIG],
  40 [
  41         dnl Figure out the correct variables and call SMB_EXT_LIB()
  42
  43         if test -z "$PKG_CONFIG"; then
  44                 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
  45         fi
  46
  47         if test "$PKG_CONFIG" = "no" ; then
  48                 echo "*** The pkg-config script could not be found. Make sure it is"
  49                 echo "*** in your path, or set the PKG_CONFIG environment variable"
  50                 echo "*** to the full path to pkg-config."
  51                 echo "*** Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config."
  52                         SMB_EXT_LIB($1)
  53                         SMB_ENABLE($1, NO)
  54         else
  55                 if $PKG_CONFIG --atleast-pkgconfig-version 0.9.0; then
  56                         AC_MSG_CHECKING(for $2)
  57
  58                         if test "$SMB_$1"x = "NO"x ; then
  59                                 SMB_ENABLE($1, NO)
  60                                 AC_MSG_RESULT(disabled)
  61                         elif $PKG_CONFIG --exists '$2' ; then
  62                                 AC_MSG_RESULT(yes)
  63
  64
  65                                 $1_CFLAGS="`$PKG_CONFIG --cflags '$2'`"
  66                         OLD_CFLAGS="$CFLAGS"
  67                         CFLAGS="$CFLAGS $$1_CFLAGS"
  68                         AC_MSG_CHECKING([that the C compiler can use the $1_CFLAGS])
  69                         AC_TRY_RUN([#include "${srcdir-.}/build/tests/trivial.c"],
  70                                         SMB_ENABLE($1, YES)
  71                                 AC_MSG_RESULT(yes),
  72                                         AC_MSG_RESULT(no),
  73                                         AC_MSG_WARN([cannot run when cross-compiling]))
  74                         CFLAGS="$OLD_CFLAGS"
  75
  76
  77                                 SMB_EXT_LIB($1,
  78                                         [`$PKG_CONFIG --libs-only-l '$2'`],
  79                                         [`$PKG_CONFIG --cflags-only-other '$2'`],
  80                                         [`$PKG_CONFIG --cflags-only-I '$2'`],
  81                                         [`$PKG_CONFIG --libs-only-other '$2'` `$PKG_CONFIG --libs-only-L '$2'`])
  82
  83                         else
  84                                 SMB_EXT_LIB($1)
  85                                 SMB_ENABLE($1, NO)
  86                                 AC_MSG_RESULT(no)
  87                                 $PKG_CONFIG --errors-to-stdout --print-errors '$2'
  88                         fi
  89                 else
  90                         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
  91                                 echo "*** See http://www.freedesktop.org/software/pkgconfig"
  92                                 SMB_EXT_LIB($1)
  93                                 SMB_ENABLE($1, NO)
  94                 fi
  95         fi
  96 ])
  97
  98 dnl SMB_EXT_LIB(name,libs,cflags,cppflags,ldflags)
  99 AC_DEFUN([SMB_EXT_LIB],
 100 [
 101
 102 SMB_INFO_EXT_LIBS="$SMB_INFO_EXT_LIBS
 103 ###################################
 104 # Start Ext Lib $1
 105 @<:@EXT_LIB::$1@:>@
 106 LIBS = $2
 107 CFLAGS = $3
 108 CPPFLAGS = $4
 109 LDFLAGS = $5
 110 # End Ext Lib $1
 111 ###################################
 112 "
 113 ])
 114
 115 dnl SMB_ENABLE(name,default_build)
 116 AC_DEFUN([SMB_ENABLE],
 117 [
 118         [SMB_ENABLE_][$1]="$2";
 119
 120 SMB_INFO_ENABLES="$SMB_INFO_ENABLES
 121 \$enabled{$1} = \"$2\";"
 122 ])