source/build/smb_build/output.pm

   1 # SMB Build System
   2 # - the output generating functions
   3 #
   4 #  Copyright (C) Stefan (metze) Metzmacher 2004
   5 #  Copyright (C) Jelmer Vernooij 2004
   6 #  Released under the GNU GPL
   7
   8 package output;
   9 use strict;
  10
  11 sub add_dir($$)
  12 {
  13         my ($dir,$files) = @_;
  14         my @ret = ();
  15
  16         $dir =~ s/^\.\///g;
  17
  18         foreach (@$files) {
  19                 $_ = "$dir/$_";
  20                 s/([^\/\.]+)\/\.\.\///g;
  21                 push (@ret, $_);
  22         }
  23
  24         return @ret;
  25 }
  26
  27 sub generate_mergedobj($)
  28 {
  29         my $subsys = shift;
  30
  31         $subsys->{OUTPUT} = $subsys->{TARGET} = "bin/subsystems/$subsys->{TYPE}_$subsys->{NAME}.o";
  32 }
  33
  34 sub generate_objlist($)
  35 {
  36         my $subsys = shift;
  37
  38         $subsys->{TARGET} = "bin/.$subsys->{TYPE}_$subsys->{NAME}";
  39         $subsys->{OUTPUT} = "\$($subsys->{TYPE}_$subsys->{NAME}_OBJ_LIST)";
  40 }
  41
  42 sub generate_shared_library($)
  43 {
  44         my $lib = shift;
  45         my $link_name;
  46         my $lib_name;
  47
  48         @{$lib->{DEPEND_LIST}} = ();
  49         @{$lib->{LINK_LIST}} = ("\$($lib->{TYPE}_$lib->{NAME}\_OBJ_LIST)");
  50
  51         $link_name = lc($lib->{NAME});
  52         $lib_name = $link_name;
  53
  54         if ($lib->{TYPE} eq "LIBRARY") {
  55                 $link_name = $lib->{NAME};
  56                 $link_name =~ s/^LIB//;
  57                 $link_name = lc($link_name);
  58                 $lib_name = "lib$link_name";
  59                 $lib->{OUTPUT} = "-l$link_name";
  60         }
  61
  62         $lib->{LIBRARY_REALNAME} = $lib->{LIBRARY_NAME} = "$lib_name.\$(SHLIBEXT)";
  63         $lib->{TARGET} = "bin/$lib->{LIBRARY_NAME}";
  64         if (defined($lib->{MAJOR_VERSION})) {
  65                 $lib->{LIBRARY_SONAME} = $lib->{LIBRARY_NAME}.".$lib->{MAJOR_VERSION}";
  66                 $lib->{LIBRARY_REALNAME} = $lib->{LIBRARY_SONAME}.".$lib->{MINOR_VERSION}.$lib->{RELEASE_VERSION}";
  67                 $lib->{TARGET} = "bin/$lib->{LIBRARY_REALNAME}";
  68                 @{$lib->{LINK_FLAGS}} = ("\$(SONAMEFLAG)$lib->{LIBRARY_SONAME}");
  69         }
  70 }
  71
  72 sub generate_static_library($)
  73 {
  74         my $lib = shift;
  75         my $link_name;
  76
  77         @{$lib->{DEPEND_LIST}} = ();
  78
  79         $link_name = $lib->{NAME};
  80         $link_name =~ s/^LIB//;
  81
  82         $lib->{LIBRARY_NAME} = "lib".lc($link_name).".a";
  83         @{$lib->{LINK_LIST}} = ("\$($lib->{TYPE}_$lib->{NAME}\_OBJ_LIST)");
  84         @{$lib->{LINK_FLAGS}} = ();
  85
  86         $lib->{TARGET} = "bin/$lib->{LIBRARY_NAME}";
  87         $lib->{OUTPUT} = "-l".lc($link_name);
  88 }
  89
  90 sub generate_binary($)
  91 {
  92         my $bin = shift;
  93
  94         @{$bin->{DEPEND_LIST}} = ();
  95         @{$bin->{LINK_LIST}} = ("\$($bin->{TYPE}_$bin->{NAME}\_OBJ_LIST)");
  96         @{$bin->{LINK_FLAGS}} = ();
  97
  98         $bin->{TARGET} = $bin->{OUTPUT} = "bin/$bin->{NAME}";
  99         $bin->{BINARY} = $bin->{NAME};
 100 }
 101
 102 sub create_output($$)
 103 {
 104         my ($depend, $config) = @_;
 105         my $part;
 106
 107         foreach $part (values %{$depend}) {
 108                 next if not defined($part->{OUTPUT_TYPE});
 109
 110                 # Combine object lists
 111                 push(@{$part->{OBJ_LIST}}, add_dir($part->{BASEDIR}, $part->{INIT_OBJ_FILES})) if defined($part->{INIT_OBJ_FILES});
 112                 push(@{$part->{OBJ_LIST}}, add_dir($part->{BASEDIR}, $part->{ADD_OBJ_FILES})) if defined($part->{ADD_OBJ_FILES});
 113                 push(@{$part->{OBJ_LIST}}, add_dir($part->{BASEDIR}, $part->{OBJ_FILES})) if defined($part->{OBJ_FILES});
 114
 115                 if ((not defined($part->{OBJ_LIST}) or
 116                         scalar(@{$part->{OBJ_LIST}}) == 0) and
 117                         $part->{OUTPUT_TYPE} eq "MERGEDOBJ") {
 118                         $part->{OUTPUT_TYPE} = "OBJLIST";
 119                 }
 120
 121                 if (($part->{STANDARD_VISIBILITY} ne "default") and
 122                         ($config->{visibility_attribute} eq "yes")) {
 123                         $part->{EXTRA_CFLAGS} .= " -fvisibility=$part->{STANDARD_VISIBILITY}";
 124                 }
 125
 126                 generate_binary($part) if $part->{OUTPUT_TYPE} eq "BINARY";
 127                 generate_mergedobj($part) if $part->{OUTPUT_TYPE} eq "MERGEDOBJ";
 128                 generate_objlist($part) if $part->{OUTPUT_TYPE} eq "OBJLIST";
 129                 generate_shared_library($part) if $part->{OUTPUT_TYPE} eq "SHARED_LIBRARY";
 130                 generate_static_library($part) if $part->{OUTPUT_TYPE} eq "STATIC_LIBRARY";
 131
 132         }
 133
 134         foreach $part (values %{$depend}) {
 135                 next if not defined($part->{OUTPUT_TYPE});
 136
 137                 # Always import the CFLAGS and CPPFLAGS of the unique dependencies
 138                 foreach my $elem (values %{$part->{UNIQUE_DEPENDENCIES}}) {
 139                         next if $elem == $part;
 140
 141                         push(@{$part->{CPPFLAGS}}, @{$elem->{CPPFLAGS}}) if defined(@{$elem->{CPPFLAGS}});
 142                         push(@{$part->{CFLAGS}}, @{$elem->{CFLAGS}}) if defined(@{$elem->{CFLAGS}});
 143                         push(@{$part->{LINK_LIST}}, $elem->{OUTPUT}) if defined($elem->{OUTPUT});
 144                         push(@{$part->{LINK_FLAGS}}, @{$elem->{LIBS}}) if defined($elem->{LIBS});
 145                         push(@{$part->{LINK_FLAGS}},@{$elem->{LDFLAGS}}) if defined($elem->{LDFLAGS});
 146                         if (defined($elem->{OUTPUT_TYPE}) and ($elem->{OUTPUT_TYPE} eq "SHARED_LIBRARY")) {
 147                             push(@{$part->{DEPEND_LIST}}, "bin/$elem->{LIBRARY_NAME}");
 148                         } else {
 149                             push(@{$part->{DEPEND_LIST}}, $elem->{TARGET}) if defined($elem->{TARGET});
 150                         }
 151                         push(@{$part->{SUBSYSTEM_INIT_FUNCTIONS}}, $elem->{INIT_FUNCTION}) if
 152                                 defined($elem->{INIT_FUNCTION}) and
 153                                 $elem->{TYPE} ne "MODULE" and
 154                                 $part->{OUTPUT_TYPE} ne "SHARED_LIBRARY";
 155                 }
 156         }
 157
 158         return $depend;
 159 }
 160
 161 1;