docs/docbook/xslt/generate-attributions.xsl

   1 <?xml version='1.0'?>
   2 <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   3                 xmlns:exsl="http://exslt.org/common"
   4                 xmlns:samba="http://samba.org/common"
   5                                 version="1.1"
   6                 extension-element-prefixes="exsl">
   7
   8 <xsl:output method="xml" omit-xml-declaration="yes"/>
   9
  10 <!-- Remove all character data -->
  11 <xsl:template match="@*|node()">
  12    <xsl:apply-templates select="@*|node()"/>
  13 </xsl:template>
  14
  15 <xsl:template match="book">
  16         <xsl:element name="variablelist">
  17         <xsl:apply-templates/>
  18         </xsl:element>
  19 </xsl:template>
  20
  21 <xsl:template match="chapter">
  22         <xsl:element name="varlistentry">
  23                 <xsl:element name="term">
  24                         <xsl:element name="link">
  25                                 <xsl:attribute name="linkend"><xsl:value-of select="@id"/></xsl:attribute>
  26                                 <xsl:value-of select="title"/>
  27                         </xsl:element>
  28                 </xsl:element>
  29                 <xsl:element name="listitem">
  30                         <xsl:element name="para">
  31                                 <xsl:element name="itemizedlist">
  32                                 <xsl:apply-templates/>
  33                                 </xsl:element>
  34                         </xsl:element>
  35                 </xsl:element>
  36         </xsl:element>
  37 </xsl:template>
  38
  39 <xsl:template match="author">
  40         <xsl:element name="listitem">
  41                 <xsl:element name="para">
  42                         <xsl:value-of select="firstname"/><xsl:text> </xsl:text><xsl:value-of select="surname"/>
  43                         <xsl:choose>
  44                                 <xsl:when test="affiliation/address/email != ''">
  45                                         <xsl:text> &lt;</xsl:text>
  46                                         <xsl:element name="ulink">
  47                                                 <xsl:attribute name="url">
  48                                                         <xsl:text>mailto:</xsl:text>
  49                                                         <xsl:value-of select="affiliation/address/email"/>
  50                                                 </xsl:attribute>
  51                                                 <xsl:value-of select="affiliation/address/email"/>
  52                                         </xsl:element>
  53                                         <xsl:text>&gt;</xsl:text>
  54                                 </xsl:when>
  55                         </xsl:choose>
  56                 </xsl:element>
  57         </xsl:element>
  58 </xsl:template>
  59
  60 </xsl:stylesheet>