configure.ac

   1 #
   2 # Autoconf script for Wireshark
   3 #
   4
   5 #
   6 # Define variables for the components of the Wireshark version number.
   7 #
   8 m4_define([version_major], [1])
   9 m4_define([version_minor], [11])
  10 m4_define([version_micro], [3])
  11 m4_define([version_micro_extra], version_micro)
  12 m4_append([version_micro_extra], [])
  13
  14 AC_INIT(wireshark, [version_major.version_minor.version_micro_extra], http://bugs.wireshark.org/, , http://www.wireshark.org/)
  15 CONFIG_ARGS="$*"
  16 AC_SUBST(CONFIG_ARGS)
  17
  18 # Minimum autoconf version we require.
  19 AC_PREREQ(2.60)
  20 # Variable expansion doesn't work in AC_PREREQ()
  21 AC_MIN_VERSION=2.60
  22 AC_SUBST(AC_MIN_VERSION)
  23
  24 dnl Check for CPU / vendor / OS
  25 dnl The user is encouraged to use either `AC_CANONICAL_BUILD', or
  26 dnl `AC_CANONICAL_HOST', or `AC_CANONICAL_TARGET', depending on the
  27 dnl needs.  Using `AC_CANONICAL_TARGET' is enough to run the two other
  28 dnl macros.
  29 dnl
  30 dnl As nothing in the Wireshark is itself a build tool (we are not,
  31 dnl for example, a compiler that generates machine code), we probably
  32 dnl don't need AC_CANONICAL_TARGET, so, in theory, we should be able
  33 dnl to use AC_CANONICAL_BUILD and AC_CANONICAL_HOST - or perhaps just
  34 dnl AC_CANONICAL_HOST - instead.  Note that we do have tools, such as
  35 dnl lemon, that need to be built for the build machine, not for the
  36 dnl host machine, so we might need both.
  37 dnl
  38 dnl This has to be done *after* AC_INIT, otherwise autogen.sh fails.
  39
  40 dnl AC_CANONICAL_BUILD
  41 dnl AC_CANONICAL_HOST
  42 AC_CANONICAL_TARGET
  43
  44 AM_INIT_AUTOMAKE([1.9 tar-ustar dist-bzip2 no-dist-gzip])
  45
  46 # Make Wireshark's version available in config.h
  47 AC_DEFINE(VERSION_MAJOR, version_major, [Wireshark's major version])
  48 AC_DEFINE(VERSION_MINOR, version_minor, [Wireshark's minor version])
  49 AC_DEFINE(VERSION_MICRO, version_micro, [Wireshark's micro version])
  50
  51 AM_DISABLE_STATIC
  52
  53 #
  54 # Checks for programs used in the main build process.
  55 #
  56 AC_PROG_CC
  57 AM_PROG_CC_C_O
  58 AC_PROG_CXX
  59 AC_PROG_CPP
  60 AC_PROG_MKDIR_P
  61 AC_WIRESHARK_CLANG_CHECK
  62
  63 dnl Work around libtool bug (fixed in the version 1.5a?)
  64 AC_DEFUN([AC_PROVIDE_AC_LIBTOOL_DLOPEN], )
  65 AC_LIBTOOL_DLOPEN
  66 AC_PROG_LIBTOOL
  67 if test ! -z "$CXX"; then
  68         #
  69         # OK, we found something AC_LANG_CXX thinks is a C++ compiler,
  70         # but is it one?
  71         #
  72         # Some UN*Xes have, by default, a case-insensitive file
  73         # system, and AC_PROG_CXX looks for, among other things,
  74         # "CC" as a C++ compiler, and, if you have a case-insensitive
  75         # file system and a C compiler named "cc" (both true, by
  76         # default, on OS X), AC_PROG_CXX may end up thinking it's
  77         # the C++ compiler.
  78         #
  79         # So we check by feeding the purported C++ compiler a
  80         # program using C++ features (iostream).
  81         #
  82         # We do this after AC_PROG_LIBTOOL; if we did so before, and
  83         # cleared CXX if what we had isn't a C++ compiler, that'd
  84         # get undone by AC_PROG_LIBTOOL for some reason.
  85         #
  86         AC_MSG_CHECKING(whether $CXX is a C++ compiler)
  87         AC_LANG_PUSH([C++])
  88         AC_LINK_IFELSE([AC_LANG_PROGRAM(
  89         [
  90 #include <iostream>
  91         ],
  92         [
  93         std::cout << "Hello World! ";
  94         return 0;
  95         ])],
  96                 [AC_MSG_RESULT(yes)],
  97                 [
  98                         AC_MSG_RESULT(no)
  99                         CXX=""
 100                 ])
 101         AC_LANG_POP([C++])
 102 fi
 103 AC_PATH_PROG(PERL, perl)
 104
 105 # Check for Python.
 106 AC_PATH_PROG(PYTHON, python)
 107 if test ! -z "$PYTHON"; then
 108         #
 109         # OK, we found Python; is it Python 2.5 or later?
 110         # Note: we don't use named components for sys.version_info to get
 111         # the major version number, as named components for version_info
 112         # were apparently introduced in Python 2.7.
 113         #
 114         AC_MSG_CHECKING([whether $PYTHON is Python 2.5 or later])
 115         python_major_version=`$PYTHON -c 'import sys; print (sys.version_info[[0]])'`
 116         python_minor_version=`$PYTHON -c 'import sys; print (sys.version_info[[1]])'`
 117         if test "$python_major_version" -eq 2 -a "$python_minor_version" -lt 5 ; then
 118                 AC_MSG_RESULT(no)
 119                 AC_MSG_WARN([Building with Python $python_major_version.$python_minor_version may not work])
 120         else
 121                 AC_MSG_RESULT(yes)
 122         fi
 123 fi
 124
 125 #
 126 # XXX - should autogen.sh check for YACC/Bison and Flex?  A user building
 127 # from a distribution tarball shouldn't have to have YACC/Bison or Flex,
 128 # as the tarball should contain the results of running YACC/Bison on .y
 129 # files and running Flex on .l files, but a user building from SVN
 130 # will have to run YACC/Bison and Flex to process those files.
 131 #
 132 # On the other hand, what about users who use a distribution tarball to
 133 # do development?  They *shouldn't* - that's what the SVN repository is
 134 # for - but they might.  They'd get errors if they modify a .y or .l
 135 # file and try to do a build - but the error should tell them that they
 136 # need to get YACC/Bison and/or Flex.
 137 #
 138 # Then again, getting them shouldn't be too big of a burden.
 139 #
 140 # XXX - is the same true of pod2man and pod2html, or are they needed
 141 # even when building from a distribution tarball?
 142 #
 143 #
 144 AC_PROG_YACC
 145 AC_PATH_PROG(YACCDUMMY, $YACC)
 146 if test "x$YACCDUMMY" = x
 147 then
 148         AC_MSG_ERROR(I couldn't find yacc (or bison or ...); make sure it's installed and in your path)
 149 fi
 150 AM_PROG_LEX
 151 AC_PATH_PROG(LEX, flex)
 152 if test "x$LEX" = x
 153 then
 154         AC_MSG_ERROR(I couldn't find flex; make sure it's installed and in your path)
 155 fi
 156 AC_PATH_PROG(POD2MAN, pod2man)
 157 if test "x$POD2MAN" = x
 158 then
 159         #
 160         # The alternative is not to build the man pages....
 161         #
 162         AC_MSG_ERROR(I couldn't find pod2man; make sure it's installed and in your path)
 163 fi
 164 AC_PATH_PROG(POD2HTML, pod2html)
 165 if test "x$POD2HTML" = x
 166 then
 167         #
 168         # The alternative is not to build the HTML man pages....
 169         #
 170         AC_MSG_ERROR(I couldn't find pod2html; make sure it's installed and in your path)
 171 fi
 172
 173 #
 174 # Checks for programs used by Wireshark/TShark/etc.
 175 #
 176
 177 #
 178 # XXX - this looks for various HTML viewers on the host, not the target;
 179 # we really want to know what's available on the target, for cross-builds.
 180 # That would probably require us to, at run time, look for xdg-open and,
 181 # if we don't find it, look for mozilla, htmlview, etc.
 182 #
 183 AC_PATH_PROG(HTML_VIEWER, xdg-open)
 184 if test "x$HTML_VIEWER" != x
 185 then
 186         #
 187         # XXX - the HTML_VIEWER shell variable is the full path of xdg-open.
 188         # Define some variable to be that, so we just run that?
 189         #
 190         AC_DEFINE(HAVE_XDG_OPEN, 1, [Define if we have xdg-open])
 191
 192         #
 193         # XXX - we have to define HTML_VIEWER for the prefs.c code that
 194         # sets the default value of the Web browser preference, even
 195         # though that preference won't be offered.
 196         #
 197         AC_DEFINE_UNQUOTED(HTML_VIEWER, "xdg-open", [HTML viewer, e.g. mozilla])
 198 else
 199         AC_PATH_PROG(HTML_VIEWER, htmlview)
 200         if test "x$HTML_VIEWER" = x
 201         then
 202                 AC_DEFINE_UNQUOTED(HTML_VIEWER, "mozilla", [HTML viewer, e.g. mozilla])
 203         else
 204                 AC_DEFINE_UNQUOTED(HTML_VIEWER, "htmlview", [HTML viewer, e.g. mozilla])
 205         fi
 206 fi
 207
 208 #
 209 # Set "ac_supports_gcc_flags" if the compiler is known to support GCC-style
 210 # flags such as -pedantic, -W warning flags and -f feature flags.  Currently,
 211 # we assume GCC and clang do; other compilers should be added here.
 212 #
 213 # This is done to avoid getting tripped up by compilers that support
 214 # those flags but give them a different meaning.
 215 #
 216 if test "x$GCC" = "xyes" -o "x$CC" = "xclang" ; then
 217         ac_supports_gcc_flags=yes
 218 fi
 219
 220 #
 221 # Set "ac_supports_W_linker_passthrough" if the compiler is known to
 222 # support "-Wl,{options}" to pass options through to the linker.
 223 # Currently, we assume GCC, xlc, and clang do; other compilers should
 224 # be added here.
 225 #
 226 if test "x$GCC" = "xyes" -o "x$CC" = "xxlc" -o "x$CC" = "xclang" ; then
 227         ac_supports_W_linker_passthrough=yes
 228 fi
 229
 230 #
 231 # Set "ac_supports_attribute_unused" if the compiler is known to
 232 # support "__attribute__(unused)".
 233 # Currently, we assume GCC and clang do; other compilers should
 234 # be added here.
 235 #
 236 # XXX - do this with a compiler test?
 237 #
 238 if test "x$GCC" = "xyes" -o "x$CC" = "xclang" ; then
 239         ac_supports_W_linker_passthrough=yes
 240 fi
 241
 242 if test "x$CC_FOR_BUILD" = x
 243 then
 244        CC_FOR_BUILD=$CC
 245 fi
 246 AC_SUBST(CC_FOR_BUILD)
 247 AC_SUBST(CFLAGS_FOR_BUILD)
 248
 249 # Check for doxygen
 250 AC_PATH_PROG(DOXYGEN, doxygen)
 251 AC_CHECK_PROG(HAVE_DOXYGEN, doxygen, "yes", "no")
 252 AM_CONDITIONAL(HAVE_DOXYGEN, test x$HAVE_DOXYGEN = xyes)
 253
 254 #
 255 # Check for pkg-config and set PKG_CONFIG accordingly.
 256 #
 257 # This is referenced via AC_REQUIRE([PKG_PROG_PKG_CONFIG] in some macros
 258 # like PKG_CHECK_MODULES. If the first call to such a macro is under an
 259 # "if" statement, it's safer to call PKG_PROG_PKG_CONFIG directly, see
 260 # the comments in acolocal.m4
 261 #
 262 PKG_PROG_PKG_CONFIG
 263
 264 AC_ARG_ENABLE(osx-deploy-target,
 265   AC_HELP_STRING( [--enable-osx-deploy-target],
 266     [choose an OS X deployment target @<:@default=major release on which you're building@:>@]),
 267 [
 268         #
 269         # Is this OS X?
 270         #
 271         case "$host_os" in
 272         darwin*)
 273                 #
 274                 # Yes.
 275                 #
 276                 # Let the user specify an OS X release to use as a
 277                 # deplayment target; if they specify that we should
 278                 # have a deployment target but don't specify the
 279                 # deployment target, then, if we have SDKs available,
 280                 # pick the OS version on which the build is being done.
 281                 # This also causes the build to be done against an SDK
 282                 # rather than against the headers and libraries in
 283                 # /usr/include and /usr/lib.
 284                 #
 285                 # Check for an OS X deployment target early, so that
 286                 # as many tests using the compiler are done using the
 287                 # flags that we'll be using when building.
 288                 #
 289                 if test $enableval = no
 290                 then
 291                         #
 292                         # The user explicitly said
 293                         # --disable-osx-deploy-target, so don't build
 294                         # against an SDK.
 295                         #
 296                         deploy_target=
 297                 elif test $enableval = yes
 298                 then
 299                         #
 300                         # The user said --enable-osx-deploy-target, but
 301                         # didn't say what version to target; target the
 302                         # major version number of the version of OS X on
 303                         # which we're running.
 304                         #
 305                         # (We quote the command so that we can use
 306                         # autoconf's M4 quoting characters, [ and ], in
 307                         # the sed expression.)
 308                         #
 309                         [deploy_target=`sw_vers -productVersion | sed 's/\([0-9][0-9]*\)\.\([0-9][0-9]*\)\.[0-9]*/\1.\2/'`]
 310                 else
 311                         deploy_target="$enableval"
 312                 fi
 313                 ;;
 314
 315         *)
 316                 #
 317                 # No.  Fail, because whatever the user intended for us to
 318                 # do, we can't do it.
 319                 #
 320                 AC_MSG_ERROR([--enable-osx-deploy-target specified on an OS other than OS X])
 321                 ;;
 322         esac
 323 ],[
 324         #
 325         # Is this OS X?
 326         #
 327         case "$host_os" in
 328         darwin*)
 329                 #
 330                 # Yes.
 331                 #
 332                 # If we have SDKs available, default to targeting the major
 333                 # version number of the version of OS X on which we're
 334                 # running.
 335                 #
 336                 # (We quote the command so that we can use autoconf's
 337                 # M4 quoting characters, [ and ], in the sed expression.)
 338                 #
 339                 for i in /Developer/SDKs \
 340                     /Applications/Xcode.app/Contents/Developer/Platforms/MacOSX.platform/Developer/SDKs \
 341                     /Library/Developer/CommandLineTools/SDKs
 342                 do
 343                         if test -d "$i"
 344                         then
 345                                 [deploy_target=`sw_vers -productVersion | sed 's/\([0-9][0-9]*\)\.\([0-9][0-9]*\)\.[0-9]*/\1.\2/'`]
 346                                 break
 347                         fi
 348                 done
 349                 ;;
 350
 351         *)
 352                 #
 353                 # No.  There's nothing to do.
 354                 #
 355                 ;;
 356         esac
 357 ])
 358
 359 if test ! -z "$deploy_target"
 360 then
 361         AC_MSG_CHECKING([whether we can build for OS X $deploy_target])
 362         case $deploy_target in
 363
 364         10.0|10.1|10.2)
 365                 #
 366                 # I'm not sure this would even work.
 367                 #
 368                 AC_MSG_RESULT(no)
 369                 AC_ERROR([We don't support building for OS X $deploy_target])
 370                 ;;
 371
 372         10.3)
 373                 #
 374                 # XXX - never tested.
 375                 #
 376                 AC_MSG_RESULT(yes)
 377                 SDKPATH="/Developer/SDKs/MacOSX10.3.9.sdk"
 378                 ;;
 379
 380         *)
 381                 #
 382                 # XXX - for 10.4, do we need 10.4u?  We're
 383                 # not currently doing fat builds (we'd need
 384                 # fat versions of the support libraries for
 385                 # that to be useful), but, if we do, we'd
 386                 # need to use 10.4u.
 387                 #
 388                 for i in /Developer/SDKs \
 389                     /Applications/Xcode.app/Contents/Developer/Platforms/MacOSX.platform/Developer/SDKs \
 390                     /Library/Developer/CommandLineTools/SDKs
 391                 do
 392                         if test -d "$i"/"MacOSX$deploy_target.sdk"
 393                         then
 394                                 SDKPATH="$i"/"MacOSX$deploy_target.sdk"
 395                                 break
 396                         fi
 397                 done
 398                 if test -z "$SDKPATH"
 399                 then
 400                         AC_MSG_RESULT(no)
 401                         AC_MSG_ERROR([We couldn't find the SDK for OS X $deploy_target])
 402                 fi
 403                 AC_MSG_RESULT(yes)
 404                 ;;
 405         esac
 406
 407         #
 408         # Add a -mmacosx-version-min flag to force tests that
 409         # use the compiler, as well as the build itself, not to,
 410         # for example, use compiler or linker features not supported
 411         # by the minimum targeted version of the OS.
 412         #
 413         # Add an -isysroot flag to use the SDK.
 414         #
 415         CFLAGS="-mmacosx-version-min=$deploy_target -isysroot $SDKPATH $CFLAGS"
 416         CXXFLAGS="-mmacosx-version-min=$deploy_target -isysroot $SDKPATH $CXXFLAGS"
 417         LDFLAGS="-mmacosx-version-min=$deploy_target -isysroot $SDKPATH $LDFLAGS"
 418
 419         #
 420         # Add a -sdkroot flag to use with osx-app.sh.
 421         #
 422         OSX_APP_FLAGS="-sdkroot $SDKPATH"
 423
 424         #
 425         # XXX - do we need this to build the Wireshark wrapper?
 426         # XXX - is this still necessary with the -mmacosx-version-min
 427         # flag being set?
 428         #
 429         OSX_DEPLOY_TARGET="MACOSX_DEPLOYMENT_TARGET=$deploy_target"
 430
 431         #
 432         # In the installer package XML file, give the deployment target
 433         # as the minimum version.
 434         #
 435         OSX_MIN_VERSION="$deploy_target"
 436
 437         case $deploy_target in
 438
 439         10.4|10.5)
 440                 #
 441                 # Only 32-bit builds are supported.  10.5
 442                 # (and 10.4?) had a bug that causes some BPF
 443                 # functions not to work with 64-bit userland
 444                 # code, so capturing won't work.
 445                 #
 446                 CFLAGS="-m32 $CFLAGS"
 447                 CXXFLAGS="-m32 $CXXFLAGS"
 448                 LDFLAGS="-m32 $LDFLAGS"
 449                 ;;
 450         esac
 451 else
 452         #
 453         # Is this OS X?
 454         #
 455         case "$host_os" in
 456         darwin*)
 457                 #
 458                 # Yes.
 459                 #
 460                 # In the installer package XML file, give the current OS
 461                 # version, minor version and all, as the minimum version.
 462                 # We can't guarantee that the resulting binary will work
 463                 # on older OS versions, not even older minor versions
 464                 # (original release or earlier software updates).
 465                 #
 466                 OSX_MIN_VERSION=`sw_vers -productVersion`
 467                 ;;
 468         esac
 469 fi
 470 AC_SUBST(OSX_MIN_VERSION)
 471
 472 #
 473 # Try to arrange for large file support.
 474 #
 475 AC_SYS_LARGEFILE
 476
 477 #
 478 # GUI toolkit options
 479 #
 480 AC_ARG_WITH([qt],
 481   AC_HELP_STRING( [--with-qt=@<:@yes/no@:>@],
 482                   [use Qt @<:@default=yes@:>@]),
 483   with_qt="$withval", with_qt="unspecified")
 484
 485 AC_ARG_WITH([gtk2],
 486   AC_HELP_STRING( [--with-gtk2=@<:@yes/no@:>@],
 487                   [use GTK+ 2.0 @<:@default=no@:>@]),
 488   with_gtk2="$withval", with_gtk2="unspecified")
 489
 490 AC_ARG_WITH([gtk3],
 491   AC_HELP_STRING( [--with-gtk3=@<:@yes/no@:>@],
 492                   [use GTK+ 3.0 instead of 2.0 @<:@default=yes@:>@]),
 493   with_gtk3="$withval", with_gtk3="unspecified")
 494
 495 # GnuTLS
 496 # Version 3.0 switched from LGPLv2.1+ to LGPLv3+, then switched back to
 497 # LGPLv2.1+ in version 3.1.10
 498 tls_message="no"
 499 AC_ARG_WITH([gnutls],
 500   AC_HELP_STRING( [--with-gnutls=@<:@yes/no@:>@],
 501                   [use GnuTLS library @<:@default=yes@:>@]),
 502   with_gnutls="$withval", with_gnutls="yes")
 503 if test "x$with_gnutls" = "xyes"; then
 504   have_license_compatible_gnutls="no"
 505   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 3.1.10 ],
 506     [ have_license_compatible_gnutls="yes" ], [ echo "GnuTLS >= 3.1.10 not found " ]
 507   )
 508
 509   if test "x$have_license_compatible_gnutls" != "xyes"; then
 510     PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 1.2.0 gnutls < 3],
 511       [ have_license_compatible_gnutls="yes" ] , [ echo "GnuTLS >= 1.2.0, < 3.0 not found " ]
 512     )
 513   fi
 514
 515   if test "x$have_license_compatible_gnutls" = "xyes"; then
 516     echo "GnuTLS found, enabling SSL decryption"
 517     AC_DEFINE(HAVE_LIBGNUTLS, 1, [Define to use GnuTLS library])
 518     tls_message="yes"
 519   else
 520     echo "GnuTLS with compatible license not found, disabling SSL decryption"
 521     tls_message="no"
 522   fi
 523 fi
 524
 525 # libgrypt
 526 gcrypt_message="no"
 527 AC_ARG_WITH([gcrypt],
 528   AC_HELP_STRING( [--with-gcrypt=@<:@yes/no@:>@],
 529                   [use gcrypt library @<:@default=yes@:>@]),
 530   with_gcrypt="$withval", with_gcrypt="yes")
 531 if test "x$with_gcrypt" = "xyes"; then
 532   AM_PATH_LIBGCRYPT(1.1.92,
 533         [
 534                 echo "libgcrypt found, enabling ipsec decryption"
 535                 AC_DEFINE(HAVE_LIBGCRYPT, 1, [Define to use libgcrypt])
 536                 gcrypt_message="yes"
 537         ]
 538         , [
 539                 if test x$libgcrypt_config_prefix != x ; then
 540                         AC_MSG_ERROR([[libgcrypt not found; install libgcrypt-devel package for your system]])
 541                 else
 542                         echo "libgcrypt not found, disabling ipsec decryption"
 543                         gcrypt_message="no"
 544                 fi
 545         ]
 546   )
 547 fi
 548
 549 AC_ARG_WITH(libnl,
 550   AC_HELP_STRING([--with-libnl@<:@=VERSION@:>@],
 551                  [use libnl (force version VERSION, if supplied) @<:@default: yes, if available@:>@]),
 552 [
 553         if test "x$withval" = "xno"
 554         then
 555                 want_libnl=no
 556         elif test "x$withval" = "xyes"
 557         then
 558                 want_libnl=yes
 559                 libnl_version=any
 560         elif test "x$withval" = "x1"
 561         then
 562                 want_libnl=yes
 563                 libnl_version=1
 564         elif test "x$withval" = "x2"
 565         then
 566                 want_libnl=yes
 567                 libnl_version=2
 568         elif test "x$withval" = "x3"
 569         then
 570                 want_libnl=yes
 571                 libnl_version=3
 572         else
 573                 AC_MSG_ERROR(["$withval" is not a valid argument to --with-libnl])
 574         fi
 575 ],[
 576         #
 577         # Use libnl if it's present, otherwise don't.
 578         #
 579         want_libnl=ifavailable
 580         libnl_version=any
 581 ])
 582 #
 583 # Libnl is Linux-specific.
 584 #
 585 libnl_message="no"
 586 case "$host_os" in
 587 linux*)
 588         AC_MSG_CHECKING(whether to use libnl for various network interface purposes)
 589
 590         if test x$want_libnl = "xno"; then
 591                 AC_MSG_RESULT(no)
 592         else
 593                 AC_MSG_RESULT(yes)
 594                 #
 595                 # Test for specific libnl versions only if no version
 596                 # was specified by the user or if the version in question
 597                 # was requested by the user.
 598                 #
 599                 if test x$libnl_version = "xany" -o x$libnl_version = "x3"; then
 600                         PKG_CHECK_MODULES(LIBNL3, [libnl-route-3.0 >= 3.0 libnl-genl-3.0] >= 3.0, [have_libnl3=yes], [have_libnl3=no])
 601                 fi
 602                 if test x$libnl_version = "xany" -o x$libnl_version = "x2"; then
 603                         PKG_CHECK_MODULES(LIBNL2, libnl-2.0 >= 2.0, [have_libnl2=yes], [have_libnl2=no])
 604                 fi
 605                 if test x$libnl_version = "xany" -o x$libnl_version = "x1"; then
 606                         PKG_CHECK_MODULES(LIBNL1, libnl-1 >= 1.0, [have_libnl1=yes], [have_libnl1=no])
 607                 fi
 608                 if (test "${have_libnl3}" = "yes"); then
 609                         CFLAGS="$CFLAGS $LIBNL3_CFLAGS"
 610                         LIBS="$LIBS $LIBNL3_LIBS"
 611                         AC_DEFINE(HAVE_LIBNL, 1, [Enable libnl support])
 612                         AC_DEFINE(HAVE_LIBNL3, 1, [libnl version 3])
 613                         libnl_message="yes (v3)"
 614                         enable_airpcap=no
 615                 elif (test "${have_libnl2}" = "yes"); then
 616                         CFLAGS="$CFLAGS $LIBNL2_CFLAGS"
 617                         LIBS="$LIBS $LIBNL2_LIBS"
 618                         AC_DEFINE(HAVE_LIBNL, 1, [Enable libnl support])
 619                         AC_DEFINE(HAVE_LIBNL2, 1, [libnl version 2])
 620                         libnl_message="yes (v2)"
 621                         enable_airpcap=no
 622                 elif (test "${have_libnl1}" = "yes"); then
 623                         CFLAGS="$CFLAGS $LIBNL1_CFLAGS"
 624                         LIBS="$LIBS $LIBNL1_LIBS"
 625                         AC_DEFINE(HAVE_LIBNL, 1, [Enable libnl support])
 626                         AC_DEFINE(HAVE_LIBNL1, 1, [libnl version 1])
 627                         libnl_message="yes (v1)"
 628                         enable_airpcap=no
 629                 else
 630                         if test x$want_libnl = "xyes"; then
 631                                 case "$libnl_version" in
 632
 633                                 any)
 634                                         AC_MSG_ERROR("I couldn't find libnl even though you manually enabled it.")
 635                                         ;;
 636
 637                                 *)
 638                                         AC_MSG_ERROR("I couldn't find libnl version $libnl_version even though you manually enabled it.")
 639                                         ;;
 640                                 esac
 641                         fi
 642                 fi
 643         fi
 644
 645         AC_MSG_CHECKING([if nl80211.h is new enough])
 646           AC_TRY_COMPILE([#include <linux/nl80211.h>],
 647             [int x = NL80211_FREQUENCY_ATTR_MAX_TX_POWER;
 648                 x = NL80211_ATTR_SUPPORTED_IFTYPES;
 649                 x = NL80211_ATTR_SUPPORTED_COMMANDS;
 650                 x = NL80211_ATTR_WIPHY_FREQ;
 651                 x = NL80211_CHAN_NO_HT;],
 652             [AC_MSG_RESULT(yes) AC_DEFINE(HAVE_NL80211, 1, [nl80211.h is new enough])],
 653             [AC_MSG_RESULT(no)])
 654
 655         AC_MSG_CHECKING([for NL80211_SET_CHANNEL])
 656           AC_TRY_COMPILE([#include <linux/nl80211.h>],
 657             [enum nl80211_commands x = NL80211_CMD_SET_CHANNEL;],
 658             [AC_MSG_RESULT(yes) AC_DEFINE(HAVE_NL80211_CMD_SET_CHANNEL, 1, [SET_CHANNEL is supported])],
 659             [AC_MSG_RESULT(no)])
 660         ;;
 661
 662 *)
 663         if test x$want_libnl != "xno" -a x$want_libnl != "xifavailable"; then
 664                 AC_MSG_WARN([libnl is Linux-specific, ignoring --with-libnl])
 665         fi
 666 esac
 667
 668 # libsmi
 669 # FIXME: currently the path argument to with-libsmi is being ignored
 670 AX_LIBSMI
 671
 672 #
 673 # Check for programs used when building DocBook documentation.
 674 #
 675
 676 # Check for a2x (convert asciidoc to another format)
 677 AC_PATH_PROG(A2X, a2x)
 678 AC_CHECK_PROG(HAVE_A2X, a2x, "yes", "no")
 679 AM_CONDITIONAL(HAVE_A2X, test x$HAVE_A2X = xyes)
 680
 681 # Want to control a tape drive? Use mt. Want to convert HTML to text?
 682 # Uhhhhh... elinks? lynx? w3m? pandoc? html2text?
 683 AC_PATH_PROG(ELINKS, elinks)
 684 AC_CHECK_PROG(HAVE_ELINKS, elinks, "yes", "no")
 685 AM_CONDITIONAL(HAVE_ELINKS, test x$HAVE_ELINKS = xyes)
 686
 687 # Check for fop (translate .fo to e.g. pdf)
 688 AC_PATH_PROG(FOP, fop)
 689 AC_CHECK_PROG(HAVE_FOP, fop, "yes", "no")
 690 AM_CONDITIONAL(HAVE_FOP, test x$HAVE_FOP = xyes)
 691
 692 # Check for lynx (html -> text)
 693 AC_PATH_PROG(LYNX, lynx)
 694 AC_CHECK_PROG(HAVE_LYNX, lynx, "yes", "no")
 695 AM_CONDITIONAL(HAVE_LYNX, test x$HAVE_LYNX = xyes)
 696
 697 # Check for w3m (html -> text)
 698 AC_PATH_PROG(W3M, w3m)
 699 AC_CHECK_PROG(HAVE_W3M, w3m, "yes", "no")
 700 AM_CONDITIONAL(HAVE_W3M, test x$HAVE_W3M = xyes)
 701
 702 # Check for xmllint
 703 AC_PATH_PROG(XMLLINT, xmllint)
 704 AC_CHECK_PROG(HAVE_XMLLINT, xmllint, "yes", "no")
 705 AM_CONDITIONAL(HAVE_XMLLINT, test x$HAVE_XMLLINT = xyes)
 706
 707 # Check for xsltproc
 708 AC_PATH_PROG(XSLTPROC, xsltproc)
 709 AC_CHECK_PROG(HAVE_XSLTPROC, xsltproc, "yes", "no")
 710 AM_CONDITIONAL(HAVE_XSLTPROC, test x$HAVE_XSLTPROC = xyes)
 711
 712
 713 # Check for packaging utilities
 714 # For now, we check to see if the various packaging utilites are in our
 715 # path.  I'm too lazy to write code to go hunt for them.  -  Gerald
 716
 717 #
 718 # Source packages.
 719 # (Lets you install the desktop files.)
 720 #
 721 AC_PATH_PROG(DESKTOP_FILE_INSTALL, desktop-file-install)
 722
 723 # SVR4/Solaris
 724 AC_CHECK_PROG(HAVE_PKGPROTO, pkgproto, "yes", "no")
 725 AC_CHECK_PROG(HAVE_PKGMK, pkgmk, "yes", "no")
 726 AC_CHECK_PROG(HAVE_PKGTRANS, pkgtrans, "yes", "no")
 727
 728 if test x$HAVE_PKGPROTO = xyes -a x$HAVE_PKGMK = xyes \
 729      -a x$HAVE_PKGTRANS = xyes ; then
 730   HAVE_SVR4_PACKAGING=yes
 731 else
 732   HAVE_SVR4_PACKAGING=no
 733 fi
 734 AC_SUBST(HAVE_SVR4_PACKAGING)
 735
 736 # RPM
 737 AC_WIRESHARK_RPM_CHECK
 738 AC_SUBST(HAVE_RPM)
 739
 740 # Debian
 741 AC_CHECK_PROG(HAVE_DPKG_BUILDPACKAGE, dpkg-buildpackage, "yes", "no")
 742
 743 # Mac OS X
 744 AC_CHECK_PROG(HAVE_XCODEBUILD, xcodebuild, "yes", "no")
 745 AC_CHECK_PROG(HAVE_HDIUTIL, hdiutil, "yes", "no")
 746 AC_CHECK_PROG(HAVE_BLESS, bless, "yes", "no")
 747
 748 if test x$HAVE_XCODEBUILD = xyes -a x$HAVE_HDIUTIL = xyes \
 749      -a x$HAVE_BLESS = xyes ; then
 750   HAVE_OSX_PACKAGING=yes
 751 else
 752   HAVE_OSX_PACKAGING=no
 753 fi
 754 AC_SUBST(HAVE_OSX_PACKAGING)
 755
 756 #
 757 # Some compilers have to be told to fail when passed an unknown -W flag;
 758 # make sure we do that.
 759 #
 760 AC_WIRESHARK_CHECK_UNKNOWN_WARNING_OPTION_ERROR
 761
 762 #
 763 # Some C++ compilers have to be told to fail when passed a -W flag that
 764 # they don't think should apply to C++; make sure we do that.
 765 #
 766 AC_WIRESHARK_CHECK_NON_CXX_WARNING_OPTION_ERROR
 767
 768 #
 769 # Try to add some additional gcc checks to CFLAGS
 770 #
 771 AC_ARG_ENABLE(extra-gcc-checks,
 772   AC_HELP_STRING( [--enable-extra-gcc-checks],
 773                   [do additional -W checks in GCC @<:@default=no@:>@]),
 774 [
 775         wireshark_extra_gcc_flags=$enableval
 776         if test $enableval != no
 777         then
 778                 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-pedantic)
 779                 #
 780                 # Various code blocks this one.
 781                 #
 782                 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Woverflow)
 783                 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-fstrict-overflow -Wstrict-overflow=4)
 784                 #
 785                 # Due to various places where APIs we don't control
 786                 # require us to cast away constness, we can probably
 787                 # never enable these ones with -Werror.
 788                 #
 789                 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wcast-qual)
 790                 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wbad-function-cast, C)
 791                 #
 792                 # Some generated ASN.1 dissectors block this one;
 793                 # multiple function declarations for the same
 794                 # function are being generated.
 795                 #
 796                 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wredundant-decls)
 797                 #
 798                 # Some loops are safe, but it's hard to convince the
 799                 # compiler of that.
 800                 #
 801                 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wunsafe-loop-optimizations)
 802                 #
 803                 # All the registration functions block these for now.
 804                 #
 805                 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wmissing-prototypes)
 806                 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wmissing-declarations)
 807                 #
 808                 # A bunch of "that might not work on SPARC" code blocks
 809                 # this one for now.
 810                 #
 811                 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wcast-align)
 812         fi
 813 ],)
 814 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wall -W) # -W is now known as -Wextra
 815 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wextra) # -W is now known as -Wextra
 816 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wdeclaration-after-statement, C)
 817 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wendif-labels)
 818 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wpointer-arith)
 819 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wno-pointer-sign, C)
 820 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Warray-bounds)
 821 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wformat-security)
 822 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-fwrapv)
 823 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-fno-strict-overflow)
 824 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-fno-delete-null-pointer-checks)
 825 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wold-style-definition, C)
 826 # The Qt headers generate a ton of shortening errors on 64-bit systems
 827 # so only enable this for C for now.
 828 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wshorten-64-to-32, C)
 829 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wstrict-prototypes, C)
 830 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wjump-misses-init, C)
 831 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wvla)
 832 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Waddress)
 833 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wattributes)
 834 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wdiv-by-zero)
 835 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wignored-qualifiers)
 836 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wpragmas)
 837 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wno-overlength-strings)
 838 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wwrite-strings)
 839 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wno-long-long)
 840 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wc++-compat, C)
 841 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wheader-guard)
 842
 843 #
 844 # XXX - OK for C++?
 845 #
 846 # Make sure -Wshadow doesn't complain about variables in function and
 847 # function pointer declarations shadowing other variables; if not, don't
 848 # turn it on, as some versions of GCC (including the one in at least
 849 # some Xcode versions that came with Mac OS X 10.5) complain about
 850 # that.
 851 #
 852 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wshadow, C,
 853   [
 854 extern int bar(int a);
 855 extern int foo(int);
 856
 857 int
 858 foo(int a)
 859 {
 860         int (*fptr)(int a) = bar;
 861
 862         return fptr(a) * 2;
 863 }
 864   ],
 865   [warns about variables in function declarations shadowing other variables])
 866
 867 # Unfortunately some versions of gcc generate logical-op warnings when strchr()
 868 # is given a constant string.
 869 # gcc versions 4.3.2 and 4.4.5 are known to have the problem.
 870 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wlogical-op, C,
 871   [
 872 #include <string.h>
 873
 874 int foo(const char *, int);
 875 int bar(void);
 876
 877 int
 878 foo(const char *sep, int c)
 879 {
 880         if (strchr (sep, c) != NULL)
 881                 return 1;
 882         else
 883                 return 0;
 884 }
 885
 886 int
 887 bar(void)
 888 {
 889         return foo("<", 'a');
 890 }
 891   ],
 892   [generates warnings from strchr()])
 893
 894
 895 #
 896 # On OS X, suppress warnings about deprecated declarations, because
 897 # they apparently think everything on OS X is Shiny Happy Apple-
 898 # Framework-Based Apps and are deprecating some perfectly OK
 899 # multi-platform open-source libraries that we use in our multi-platform
 900 # open-source application in favor of various frameworks that are
 901 # OS X-only.
 902 #
 903 case "$host_os" in
 904 darwin*)
 905         AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wno-deprecated-declarations)
 906         ;;
 907 esac
 908
 909 #
 910 # Use the faster pre gcc 4.5 floating point precision if available.
 911 #
 912 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-fexcess-precision=fast)
 913
 914 CFLAGS_before_fvhidden="$CFLAGS"
 915 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-fvisibility=hidden)
 916 if test "x$CFLAGS" = "x$CFLAGS_before_fvhidden"
 917 then
 918         # TODO add other ways of hiding symbols
 919         AC_MSG_WARN(Compiler will export all symbols from shared libraries)
 920 fi
 921
 922 AC_WIRESHARK_LDFLAGS_CHECK([-Wl,--as-needed])
 923 ###AC_WIRESHARK_LDFLAGS_CHECK([-Wl,-M])
 924 ###AC_WIRESHARK_LDFLAGS_CHECK([-Wl,--cref])
 925 # AC_WIRESHARK_LDFLAGS_CHECK([-flto])
 926 # AC_WIRESHARK_LDFLAGS_CHECK([-fwhopr])
 927 # AC_WIRESHARK_LDFLAGS_CHECK([-fwhole-program])
 928
 929 #
 930 # Put -fPIE in PIE_CFLAGS and -pie in PIE_LDFLAGS if we can use them,
 931 # so that we can build dumpcap PIE - it may run with elevated
 932 # privileges, and using PIE means the OS can run it at random locations
 933 # in the address space to make attacks more difficult.
 934 #
 935 CFLAGS_before_pie="$CFLAGS"
 936 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-fPIE)
 937 if test "x$CFLAGS" != "x$CFLAGS_before_pie"
 938 then
 939         # Restore CFLAGS
 940         CFLAGS="$CFLAGS_before_pie"
 941
 942         LDFLAGS_before_pie="$LDFLAGS"
 943         AC_WIRESHARK_LDFLAGS_CHECK([-fPIE -pie])
 944         if test "x$LDFLAGS" != "x$LDFLAGS_before_pie"
 945         then
 946                 # We can use PIE
 947                 PIE_CFLAGS="-fPIE"
 948                 PIE_LDFLAGS="-pie"
 949
 950                 # Restore LDFLAGS
 951                 LDFLAGS="$LDFLAGS_before_pie"
 952         fi
 953
 954 fi
 955 AC_SUBST(PIE_CFLAGS)
 956 AC_SUBST(PIE_LDFLAGS)
 957
 958 #
 959 # If we're running GCC or clang define _U_ to be "__attribute__((unused))"
 960 # so we can use _U_ to flag unused function parameters and not get warnings
 961 # about them. Otherwise, define _U_ to be an empty string so that _U_ used
 962 # to flag an unused function parameters will compile with other compilers.
 963 #
 964 # XXX - similar hints for other compilers?
 965 #
 966 if test "x$GCC" = "xyes" -o "x$CC" = "xclang" ; then
 967   AC_DEFINE(_U_, __attribute__((unused)), [Hint to the compiler that a function parameters is not used])
 968 else
 969   AC_DEFINE(_U_, , [Hint to the compiler that a function parameters is not used])
 970 fi
 971
 972 # If we're running GCC or CLang, use FORTIFY_SOURCE=2
 973 #  (only if the GCC 'optimization level' > 0).
 974 #
 975 # See: http://gcc.gnu.org/ml/gcc-patches/2004-09/msg02055.html
 976 # See: http://sourceware.org/bugzilla/show_bug.cgi?id=13979
 977 #
 978 # Note: FORTIFY_SOURCE is only effective for gcc optimization level > 0 (-O1, etc)
 979 AC_WIRESHARK_GCC_FORTIFY_SOURCE_CHECK
 980
 981 #
 982 # If the compiler supports GCC-style flags, enable a barrier "stop on
 983 # warning".
 984 # This barrier is set for a very large part of the code. However, it is
 985 # typically not set for "generated" code  (flex, ans2wrs, idl2wrs, ...)
 986 #
 987 warnings_as_errors_default="yes"
 988 AC_MSG_CHECKING(whether we should treat compiler warnings as errors)
 989 AC_ARG_ENABLE(warnings-as-errors,
 990   AC_HELP_STRING( [--enable-warnings-as-errors],
 991                   [treat warnings as errors (only for GCC or clang) @<:@default=yes, unless extra warnings are enabled@:>@]),
 992 [
 993   if test "x$ac_supports_gcc_flags" = "xyes" -a "x$enableval" = "xyes"; then
 994     with_warnings_as_errors="yes"
 995     AC_MSG_RESULT(yes)
 996   else
 997     with_warnings_as_errors="no"
 998     AC_MSG_RESULT(no)
 999   fi
1000 ],
1001 [
1002   if test "x$ac_supports_gcc_flags" = "xyes" -a "x$wireshark_extra_gcc_flags" = "x" -a "x$warnings_as_errors_default" = "xyes"; then
1003     with_warnings_as_errors="yes"
1004     AC_MSG_RESULT(yes)
1005   else
1006     with_warnings_as_errors="no"
1007     AC_MSG_RESULT(no)
1008   fi
1009 ]
1010 )
1011 AM_CONDITIONAL(HAVE_WARNINGS_AS_ERRORS, test "x$with_warnings_as_errors" = "xyes")
1012
1013 #
1014 # Add any platform-specific compiler flags needed.
1015 #
1016 AC_MSG_CHECKING(for platform-specific compiler flags)
1017 if test "x$GCC" = "xyes" ; then
1018         #
1019         # GCC - do any platform-specific tweaking necessary.
1020         #
1021         case "$host_os" in
1022         solaris*)
1023                 # the X11 headers don't automatically include prototype info
1024                 # and a lot don't include the return type
1025                 CPPFLAGS="$CPPFLAGS -DFUNCPROTO=15"
1026                 CFLAGS="$CFLAGS -Wno-return-type"
1027                 CXXFLAGS="$CXXFLAGS -Wno-return-type"
1028                 AC_MSG_RESULT(GCC on Solaris - added -Wno-return-type -DFUNCPROTO=15)
1029                 ;;
1030         *)
1031                 AC_MSG_RESULT(none needed)
1032                 ;;
1033         esac
1034 else
1035         #
1036         # Not GCC - assume it's the vendor's compiler.
1037         #
1038         case "$host_os" in
1039         hpux*)
1040                 #
1041                 # HP's ANSI C compiler; flags suggested by Jost Martin.
1042                 # "-Ae" for ANSI C plus extensions such as "long long".
1043                 # "+O2", for optimization.  XXX - works with "-g"?
1044                 #
1045                 # HP's ANSI C++ compiler doesn't support "-Ae", but
1046                 # does support "+O2", at least according to the
1047                 # documentation I can find online.
1048                 #
1049                 CFLAGS="-Ae +O2 $CFLAGS"
1050                 CFLAGS_FOR_BUILD="-Ae +O2 $CFLAGS"
1051                 CXXFLAGS="+O2 $CFLAGS"
1052                 AC_MSG_RESULT(HP ANSI C compiler - added -Ae +O2)
1053                 ;;
1054         *)
1055                 AC_MSG_RESULT(none needed)
1056                 ;;
1057         esac
1058 fi
1059
1060 #
1061 # Add any platform-specific linker flags needed.
1062 #
1063 AC_MSG_CHECKING(for platform-specific linker flags)
1064 case "$host_os" in
1065 darwin*)
1066         #
1067         # Add -Wl,-single_module to the LDFLAGS used with shared
1068         # libraries, to fix some error that show up in some cases;
1069         # some Apple documentation recommends it for most shared
1070         # libraries.
1071         #
1072         LDFLAGS_SHAREDLIB="-Wl,-single_module"
1073         #
1074         # Add -Wl,-search_paths_first to make sure that if we search
1075         # directories A and B, in that order, for a given library, a
1076         # non-shared version in directory A, rather than a shared
1077         # version in directory B, is chosen (so we can use
1078         # --with-pcap=/usr/local to force all programs to be linked
1079         # with a static version installed in /usr/local/lib rather than
1080         # the system version in /usr/lib).
1081         #
1082         # Also add -Wl,-rpath,@executable_path/../lib and
1083         # -Wl,-rpath,/usr/local/lib, so that, if we build an app
1084         # bundle, we can tweak all the executable images, shared
1085         # libraries, and plugins in the bundle to look for non-system
1086         # libraries in the rpath, rather than having a script tweak
1087         # DYLD_LIBRARY_PATH.
1088         #
1089         LDFLAGS="-Wl,-search_paths_first -Wl,-rpath,@executable_path/../lib -Wl,-rpath,@executable_path/../Frameworks -Wl,-rpath,/usr/local/lib $LDFLAGS"
1090         AC_MSG_RESULT([Apple linker - added -Wl,-single_module and -Wl,-search_paths_first, and rpaths])
1091         ;;
1092 cygwin*)
1093         #
1094         # Shared libraries in cygwin/Win32 must never contain
1095         # undefined symbols.
1096         #
1097         LDFLAGS="$LDFLAGS -no-undefined"
1098         AC_MSG_RESULT(CygWin GNU ld - added -no-undefined)
1099         ;;
1100 *)
1101         AC_MSG_RESULT(none needed)
1102         ;;
1103 esac
1104 AC_SUBST(LDFLAGS_SHAREDLIB)
1105
1106 # Enable silent builds by default
1107 # Verbose builds can be enabled with "./configure
1108 # --enable-silent-rules ..." or "make V=1 ..."
1109 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
1110   [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
1111
1112 #
1113 # On "Darwin", which we assume to mean "OS X" rather than "iOS" or
1114 # "just Darwin" (as we don't currently support iOS, and as I don't
1115 # think you can build and run "just Darwin" as an OS for PCs), we
1116 # arrange to build some programs with Application Services so they
1117 # can launch Web browsers and Finder windows, arrange to build some
1118 # programs with System Configuration so they can get "friendly names"
1119 # and other information about interfaces, and build any programs that
1120 # use either of those frameworks or that report version information
1121 # with Core Foundation as the frameworks in question use it and as we
1122 # get version information from plists and thus need Core Foundation
1123 # to process those plists.
1124 #
1125 case "$host_os" in
1126
1127 darwin*)
1128         AC_DEFINE(HAVE_OS_X_FRAMEWORKS, 1, [Define to 1 if you have OS X frameworks])
1129         APPLICATIONSERVICES_FRAMEWORKS="-framework ApplicationServices"
1130         SYSTEMCONFIGURATION_FRAMEWORKS="-framework SystemConfiguration"
1131         COREFOUNDATION_FRAMEWORKS="-framework CoreFoundation"
1132
1133         #
1134         # OK, so we have the OS X frameworks; do they include
1135         # CFPropertyListCreateWithStream, or do we have
1136         # to fall back on CFPropertyListCreateFromStream?
1137         # (They only differ in the error return, which we
1138         # don't care about.  And, no, we shouldn't just
1139         # use CFPropertyListCreateFromStream, because it's
1140         # deprecated in newer releases.)
1141         #
1142         ac_save_LIBS="$LIBS"
1143         LIBS="$LIBS $COREFOUNDATION_FRAMEWORKS"
1144         AC_CHECK_FUNCS(CFPropertyListCreateWithStream)
1145         LIBS="$ac_save_LIBS"
1146         ;;
1147 esac
1148 AC_SUBST(APPLICATIONSERVICES_FRAMEWORKS)
1149 AC_SUBST(SYSTEMCONFIGURATION_FRAMEWORKS)
1150 AC_SUBST(COREFOUNDATION_FRAMEWORKS)
1151
1152 #
1153 # On Solaris, check whether we have getexecname().
1154 #
1155 case "$host_os" in
1156 solaris*)
1157         AC_CHECK_FUNC(getexecname)
1158         ;;
1159 esac
1160
1161 dnl Look in /usr/local for header files and libraries ?
1162 dnl XXX FIXME don't include /usr/local if it is already in the system
1163 dnl search path as this causes gcc 3.2 on Linux to complain about a change
1164 dnl of the system search order for includes
1165 AC_ARG_ENABLE(usr-local,
1166   AC_HELP_STRING( [--enable-usr-local],
1167                   [look for headers and libs in /usr/local tree @<:@default=yes@:>@]),
1168     ac_cv_enable_usr_local=$enableval,ac_cv_enable_usr_local=yes)
1169
1170 AC_MSG_CHECKING(whether to use /usr/local for headers and libraries)
1171 if test "x$ac_cv_enable_usr_local" = "xyes" ; then
1172         if test -d "/usr/local"; then
1173                 AC_MSG_RESULT(yes)
1174                 #
1175                 # Arrange that we search for header files in the source directory
1176                 # and in its "wiretap" subdirectory, as well as in "/usr/local/include",
1177                 # as various packages we use ("libpcap", "zlib", "adns")
1178                 # may have been installed under "/usr/local/include".
1179                 #
1180                 CPPFLAGS="$CPPFLAGS -I/usr/local/include"
1181
1182                 #
1183                 # Arrange that we search for libraries in "/usr/local/lib".
1184                 #
1185                 AC_WIRESHARK_ADD_DASH_L(LDFLAGS, /usr/local/lib)
1186         else
1187                 AC_MSG_RESULT(no)
1188         fi
1189 else
1190         AC_MSG_RESULT(no)
1191 fi
1192
1193 #
1194 # If we're running Solaris, and LD_LIBRARY_PATH is defined, add it as a
1195 # link directory.
1196 #
1197 case "$host_os" in
1198   solaris*)
1199     AC_MSG_CHECKING(for LD_LIBRARY_PATH, since you appear to be running Solaris)
1200     if test x$LD_LIBRARY_PATH != x ; then
1201       LIBS="$LIBS -R$LD_LIBRARY_PATH"
1202       AC_MSG_RESULT(yes -- added LD_LIBRARY_PATH to run-time linker path)
1203     else
1204       AC_MSG_RESULT(no -- this may be a problem in a few seconds)
1205     fi
1206   ;;
1207 esac
1208
1209 #
1210 # Check for versions of "sed" inadequate to handle, in libtool, a list
1211 # of object files as large as the list in Wireshark.
1212 #
1213 # On Solaris, we check for "/bin/sed", "/usr/bin/sed", and "/usr/ucb/sed",
1214 # as both "/usr/bin/sed" (which is also "/bin/sed", as "/bin" is just a
1215 # symlink to "/usr/bin", but people may have "/bin" before "/usr/bin" in
1216 # their search path) and "/usr/ucb/sed" are inadequate; "/usr/xpg4/bin/sed"
1217 # is the only "sed" that comes with Solaris that can handle Wireshark.
1218 #
1219 # Add any checks here that are necessary for other OSes.
1220 #
1221 AC_PATH_PROG(SED, sed)
1222 if test "x$SED" = x
1223 then
1224         AC_MSG_ERROR(I couldn't find sed; make sure it's installed and in your path)
1225 fi
1226 AC_WIRESHARK_GNU_SED_CHECK
1227 if test "$HAVE_GNU_SED" = no ; then
1228         case "$host_os" in
1229         solaris*)
1230                 AC_MSG_CHECKING(whether one of /usr/bin/sed or /bin/sed or /usr/ucb/sed will be used)
1231                 case `which sed` in
1232                         /bin/sed|/usr/bin/sed|/usr/ucb/sed)
1233                         AC_MSG_RESULT(yes)
1234                         AC_MSG_ERROR([change your path to search /usr/xpg4/bin or directory containing GNU sed before /usr/bin (and /bin and /usr/ucb)])
1235                         ;;
1236
1237                         *)
1238                         AC_MSG_RESULT(no)
1239                         ;;
1240                 esac
1241                 ;;
1242
1243         *)
1244                 :
1245                 ;;
1246         esac
1247 fi
1248
1249 # Enable/disable wireshark
1250 AC_ARG_ENABLE(wireshark,
1251   AC_HELP_STRING( [--enable-wireshark],
1252                   [build the Wireshark GUI (with Gtk+, Qt, or both) @<:@default=yes@:>@]),
1253     enable_wireshark=$enableval,enable_wireshark=yes)
1254
1255 AC_ARG_ENABLE(packet-editor,
1256   AC_HELP_STRING( [--enable-packet-editor],
1257                   [add support for packet editor in Wireshark @<:@default=yes@:>@]),
1258     enable_packet_editor=$enableval,enable_packet_editor=yes)
1259 if test x$enable_packet_editor = xyes; then
1260         AC_DEFINE(WANT_PACKET_EDITOR, 1, [Support for packet editor])
1261 fi
1262
1263 AC_ARG_ENABLE(profile-build,
1264   AC_HELP_STRING( [--enable-profile-build],
1265                   [build profile-ready binaries @<:@default=no@:>@]),
1266     enable_profile_build=$enableval,enable_profile_build=no)
1267 AM_CONDITIONAL(USE_PROFILE_BUILD, test x$enable_profile_build = xyes)
1268 AC_MSG_CHECKING(if profile builds must be generated)
1269 if test "x$enable_profile_build" = "xyes" ; then
1270         if test "x$GCC" = "xyes" -o "x$CLANG" = "xyes" ; then
1271                 AC_MSG_RESULT(yes)
1272                 CFLAGS=" -pg $CFLAGS"
1273                 CXXFLAGS=" -pg $CXXFLAGS"
1274         else
1275                 AC_MSG_RESULT(no)
1276                 echo "Building profile binaries currently only supported for GCC and clang."
1277         fi
1278 else
1279         AC_MSG_RESULT(no)
1280 fi
1281
1282 # Create DATAFILE_DIR #define for config.h
1283 datafiledir=$datadir/wireshark
1284 datafiledir=`(
1285     test "x$prefix" = xNONE && prefix=$ac_default_prefix
1286     test "x$exec_prefix" = xNONE && exec_prefix=${prefix}
1287     # Ugly hack, but I don't see how this problem can be solved
1288     # properly that DATAFILE_DIR had a value starting with
1289     # "${prefix}/" instead of e.g. "/usr/local/"
1290     eval eval echo "$datafiledir"
1291 )`
1292 AC_DEFINE_UNQUOTED(DATAFILE_DIR,"$datafiledir", [Directory for data])
1293
1294 # Create DOC_DIR #define for config.h
1295 docdir=`(
1296     test "x$prefix" = xNONE && prefix=$ac_default_prefix
1297     test "x$exec_prefix" = xNONE && exec_prefix=${prefix}
1298     # Ugly hack, but I don't see how this problem can be solved
1299     # properly that DOC_DIR had a value starting with
1300     # "${prefix}/" instead of e.g. "/usr/local/"
1301     eval eval echo "$docdir"
1302 )`
1303 AC_DEFINE_UNQUOTED(DOC_DIR, "$docdir", [Directory for docs])
1304
1305 GTK2_MIN_VERSION=2.12.0
1306 AC_SUBST(GTK2_MIN_VERSION)
1307 GTK3_MIN_VERSION=3.0.0
1308 AC_SUBST(GTK3_MIN_VERSION)
1309 QT_MIN_VERSION=4.6.0
1310 AC_SUBST(QT_MIN_VERSION)
1311 # GTK+ and Qt checks; we require GTK+ $GTK2_MIN_VERSION or later or
1312 # GTK3_MIN_VERSION or later or Qt $QT_MIN_VERSION or later.
1313 #
1314 # We only do those if we're going to be building Wireshark;
1315 # otherwise, we don't have any GUI to build, so we don't use
1316 # GTK+ or Qt.
1317 #
1318 # We don't add $GTK_LIBS or $Qt_LIBS to LIBS, because we don't want to
1319 # force all programs to be built with GTK+ or Qt.
1320 #
1321 # Release dates for GTK+ versions:
1322 # 2.12.0: 14 Sep 2007
1323 # 2.14.0: 04 Sep 2008
1324 # 2.16.0: 13 Mar 2009
1325 # 2.18.0: 23 Sep 2009
1326 # 2.20.0: 23 Mar 2010
1327 # 2.22.0: 23 Sep 2010
1328 # 2.24.0: 30 Jan 2011
1329 # 3.0.0:  10 Feb 2011
1330 # 3.2.0:  25 Sep 2011
1331 # 3.4.0:  26 Mar 2012
1332 # 3.6.0:  24 Sep 2012
1333 # 3.8.0:  25 Mar 2013
1334
1335 have_qt=no
1336 have_gtk=no
1337 if test "x$enable_wireshark" = "xyes"; then
1338         if test "x$with_gtk2" = "xunspecified" -a \
1339                 "x$with_gtk3" = "xunspecified" -a \
1340                 "x$with_qt" = "xunspecified"; then
1341                 #
1342                 # No GUI toolkit was explicitly specified; pick Qt and GTK+ 3.
1343                 #
1344                 with_qt=yes
1345                 with_gtk3=yes
1346         fi
1347         if test "x$with_qt" = "xyes"; then
1348                 #
1349                 # Qt was specified; Make sure we have a C++ compiler.
1350                 #
1351                 if test -z "$CXX"; then
1352                         AC_MSG_ERROR(Need a working C++ compiler to build Wireshark with Qt)
1353                 fi
1354
1355                 #
1356                 # Now make sure we have Qt and, if so, add the flags
1357                 # for it to CFLAGS and CXXFLAGS.
1358                 #
1359                 AC_WIRESHARK_QT_CHECK($QT_MIN_VERSION,
1360                 [
1361                         CFLAGS="$CFLAGS $Qt_CFLAGS"
1362                         CXXFLAGS="$CXXFLAGS $Qt_CFLAGS"
1363                         have_qt=yes
1364                         GUI_CONFIGURE_FLAGS="$GUI_CONFIGURE_FLAGS --with-qt"
1365                         OSX_APP_FLAGS="$OSX_APP_FLAGS -qt"
1366                         OSX_DMG_FLAGS="-qt"
1367                 ],
1368                 [AC_MSG_ERROR([Qt is not available])])
1369
1370                 #
1371                 # XXX - greasy hack to make ui/gtk/recent.c
1372                 # compile.
1373                 #
1374                 CPPFLAGS="-DQT_GUI_LIB"
1375         fi
1376
1377         if test "x$with_gtk3" = "xyes"; then
1378                 #
1379                 # GTK+ 3 was specified; make sure they didn't also
1380                 # specify GTK+ 2, as we don't support building both
1381                 # GTK+ 2 and GTK+ 3 versions at the same time.
1382                 #
1383                 if test "x$with_gtk2" = "xyes"; then
1384                         AC_MSG_ERROR([Both GTK+ 2 and GTK+ 3 were specified; choose one but not both])
1385                 fi
1386
1387                 #
1388                 # Make sure we have GTK+ 3.
1389                 #
1390                 AM_PATH_GTK_3_0(3.0.0,
1391                 [
1392                         CFLAGS="$CFLAGS $GTK_CFLAGS"
1393                         CXXFLAGS="$CXXFLAGS $GTK_CFLAGS"
1394                         have_gtk=yes
1395                         GUI_CONFIGURE_FLAGS="$GUI_CONFIGURE_FLAGS --with-gtk3"
1396                 ],
1397                 [AC_MSG_ERROR([GTK+ 3 is not available])])
1398         elif test "x$with_gtk2" = "xyes"; then
1399                 #
1400                 # GTK+ 3 wasn't specified, and GTK+ 2 was specified;
1401                 # make sure we have GTK+ 2.
1402                 #
1403                 AM_PATH_GTK_2_0($GTK2_MIN_VERSION,
1404                 [
1405                         CFLAGS="$CFLAGS $GTK_CFLAGS"
1406                         CXXFLAGS="$CXXFLAGS $GTK_CFLAGS"
1407                         have_gtk=yes
1408                         GUI_CONFIGURE_FLAGS="$GUI_CONFIGURE_FLAGS --with-gtk2"
1409                 ],
1410                 [AC_MSG_ERROR([GTK+ 2 is not available])])
1411         fi
1412 fi
1413 AC_SUBST(GUI_CONFIGURE_FLAGS)
1414
1415 GLIB_MIN_VERSION=2.16.0
1416 AC_SUBST(GLIB_MIN_VERSION)
1417 # GLib checks; we require GLib $GLIB_MIN_VERSION or later, and require gmodule
1418 # support, as we need that for dynamically loading plugins.
1419 # If we found GTK+, this doesn't add GLIB_CFLAGS to CFLAGS, because
1420 # AM_PATH_GTK will add GTK_CFLAGS to CFLAGS, and GTK_CFLAGS is a
1421 # superset of GLIB_CFLAGS.  If we didn't find GTK+, it does add
1422 # GLIB_CFLAGS to CFLAGS.
1423 # However, this means that both @GLIB_LIBS@ and @GTK_LIBS@ will be
1424 # set when generating the Makefile, so we can make programs that require
1425 # only GLib link with @GLIB_LIBS@ and make programs that require GTK+
1426 # link with @GTK_LIBS@ (which includes @GLIB_LIBS@).
1427 # We don't add $GLIB_LIBS to LIBS, because we don't want to force all
1428 # programs to be built with GLib.
1429 #
1430 # Release dates for GLib versions:
1431 # 2.14.0: 03 Aug 2007
1432 # 2.16.0: 10 Mar 2008
1433 # 2.18.0: 02 Sep 2008
1434 # 2.20.0: 13 Mar 2009
1435 # 2.22.0: 22 Sep 2009
1436 # 2.24.0: 28 Mar 2010
1437 # 2.26.0: 27 Sep 2010
1438 # 2.28.0: 08 Feb 2011
1439 # 2.30.0: 27 Sep 2011
1440 # 2.32.0: 24 Mar 2012
1441 # 2.34.0: 24 Sep 2012
1442 # 2.36.0: 25 Mar 2013
1443
1444 use_glib_cflags="true"
1445 if test "$have_gtk" = "yes" -a "$have_qt" = "yes" ; then
1446         # We have both GTK and Qt and thus will be building both wireshark
1447         # and wireshark-qt.
1448
1449         wireshark_bin="wireshark\$(EXEEXT) wireshark-qt\$(EXEEXT)"
1450         wireshark_man="wireshark.1"
1451         wireshark_SUBDIRS="codecs ui/qt ui/gtk"
1452 fi
1453 if test "$have_gtk" = "no" -a "$have_qt" = "yes" ; then
1454         # We don't have GTK+ but we have Qt.
1455
1456         wireshark_bin="wireshark-qt\$(EXEEXT)"
1457         wireshark_man="wireshark.1"
1458         wireshark_SUBDIRS="codecs ui/qt"
1459 fi
1460 if test "$have_gtk" = "yes" -a "$have_qt" = "no" ; then
1461         # We have GTK+ but not Qt.
1462
1463         wireshark_bin="wireshark\$(EXEEXT)"
1464         wireshark_man="wireshark.1"
1465         wireshark_SUBDIRS="codecs ui/gtk"
1466         use_glib_cflags="false"
1467 fi
1468 if test "$have_gtk" = "no" -a "$have_qt" = "no" ; then
1469         # We have neither GTK+ nor Qt.
1470         #
1471         # If they didn't explicitly say "--disable-wireshark",
1472         # fail (so that, unless they explicitly indicated that
1473         # they don't want Wireshark, we stop so they know they
1474         # won't be getting Wireshark unless they fix the GTK+/Qt
1475         # problem).
1476         #
1477         if test "x$enable_wireshark" = "xyes"; then
1478                 if test "x$with_gtk3" = "xyes"; then
1479                         AC_MSG_ERROR([Neither Qt nor GTK+ $GTK3_MIN_VERSION or later are available, so Wireshark can't be compiled])
1480                 else
1481                         AC_MSG_ERROR([Neither Qt nor GTK+ $GTK2_MIN_VERSION or later are available, so Wireshark can't be compiled])
1482                 fi
1483         fi
1484         wireshark_bin=""
1485         wireshark_man=""
1486 fi
1487
1488 if test "$have_gtk" = "yes" ; then
1489         # If we have GTK then add flags for it.
1490
1491         CPPFLAGS="-DGDK_PIXBUF_DISABLE_DEPRECATED $CPPFLAGS"
1492         CPPFLAGS="-DGDK_DISABLE_DEPRECATED $CPPFLAGS"
1493         if test \( $gtk_config_major_version -eq 3 -a $gtk_config_minor_version -ge 10 \) ; then
1494                 ## Allow use of deprecated & disable deprecated warnings if Gtk >= 3.10;
1495                 ##  The deprecations in Gtk 3.10 will not be fixed ...
1496                 CPPFLAGS="-DGDK_DISABLE_DEPRECATION_WARNINGS $CPPFLAGS"
1497         else
1498                 CPPFLAGS="-DGTK_DISABLE_DEPRECATED $CPPFLAGS"
1499         fi
1500         CPPFLAGS="-DGTK_DISABLE_SINGLE_INCLUDES $CPPFLAGS"
1501         if test ! \( $gtk_config_major_version -eq 2 -a $gtk_config_minor_version -lt 20 \) ; then
1502                 # Enable GSEAL when building with GTK > 2.20
1503                 # (Versions prior to 2.22 lacked some necessary accessors.)
1504                 CPPFLAGS="-DGSEAL_ENABLE $CPPFLAGS"
1505         fi
1506 fi
1507
1508 # XXX - Is this really necessary?  When we build with both Gtk+ and Qt it works...
1509 if test "$use_glib_cflags" = "true"; then
1510         # Use GLIB_CFLAGS
1511         AM_PATH_GLIB_2_0($GLIB_MIN_VERSION,
1512         [
1513                 CFLAGS="$CFLAGS $GLIB_CFLAGS"
1514                 CXXFLAGS="$CXXFLAGS $GLIB_CFLAGS"
1515         ], AC_MSG_ERROR(GLib $GLIB_MIN_VERSION or later distribution not found.), gthread gmodule)
1516 else
1517         # Don't use GLIB_CFLAGS
1518         AM_PATH_GLIB_2_0($GLIB_MIN_VERSION, , AC_MSG_ERROR(GLib $GLIB_MIN_VERSION or later distribution not found.), gthread gmodule)
1519 fi
1520
1521 #
1522 # "make dist" requires that we have the Qt build tools.
1523 #
1524 # Annoyingly, at least on Fedora 16, uic and moc are named XXX-qt4
1525 # rather than just XXX, perhaps to allow Qt 3 and Qt 4 tools to be
1526 # installed; if they're still doing that in current Fedora releases,
1527 # perhaps there will also be XXX-qt5 when they pick up Qt 5.
1528 #
1529 AC_PATH_PROG(UIC, uic)
1530 if test "x$UIC" = x
1531 then
1532         AC_PATH_PROG(UIC, uic-qt4)
1533         if test "x$UIC" = x
1534         then
1535                 if test "x$with_qt" = "xyes"; then
1536                         #
1537                         # If you want to build with Qt, you'd better
1538                         # have uic.
1539                         #
1540                         AC_MSG_ERROR(I couldn't find uic or uic-qt4; make sure it's installed and in your path)
1541                 else
1542                         #
1543                         # We shouldn't fail here, as the user's not
1544                         # building with Qt, and we shouldn't force them
1545                         # to have Qt installed if they're not doing so.
1546                         # "make dist" will fail if they do that, but
1547                         # we don't know whether they'll be doing that,
1548                         # so this is the best we can do.
1549                         #
1550                         UIC=uic
1551                 fi
1552         fi
1553 fi
1554 AC_SUBST(UIC)
1555 AC_PATH_PROG(MOC, moc)
1556 if test "x$MOC" = x
1557 then
1558         AC_PATH_PROG(MOC, moc-qt4)
1559         if test "x$MOC" = x
1560         then
1561                 if test "x$with_qt" = "xyes"; then
1562                         #
1563                         # If you want to build with Qt, you'd better
1564                         # have moc.
1565                         #
1566                         AC_MSG_ERROR(I couldn't find moc or moc-qt4; make sure it's installed and in your path)
1567                 else
1568                         #
1569                         # We shouldn't fail here, as the user's not
1570                         # building with Qt, and we shouldn't force them
1571                         # to have Qt installed if they're not doing so.
1572                         # "make dist" will fail if they do that, but
1573                         # we don't know whether they'll be doing that,
1574                         # so this is the best we can do.
1575                         #
1576                         MIC=moc
1577                 fi
1578         fi
1579 fi
1580 AC_SUBST(MOC)
1581
1582 # Error out if a glib header other than a "top level" header
1583 #  (glib.h, glib-object.h, gio.h) or certain other headers( e.g.,gmodule.h)
1584 #  is used.
1585 CPPFLAGS="-DG_DISABLE_SINGLE_INCLUDES $CPPFLAGS"
1586
1587 # Error out on the usage of deprecated glib functions
1588 CPPFLAGS="-DG_DISABLE_DEPRECATED $CPPFLAGS"
1589
1590 #
1591 # Check whether GLib modules are supported, to determine whether we
1592 # can support plugins.
1593 #
1594 AC_MSG_CHECKING(whether GLib supports loadable modules)
1595 ac_save_CFLAGS="$CFLAGS"
1596 ac_save_LIBS="$LIBS"
1597 CFLAGS="$CFLAGS $GLIB_CFLAGS"
1598 LIBS="$GLIB_LIBS $LIBS"
1599 AC_TRY_RUN([
1600 #include <glib.h>
1601 #include <gmodule.h>
1602 #include <stdio.h>
1603 #include <stdlib.h>
1604
1605 int
1606 main ()
1607 {
1608   if (g_module_supported())
1609     return 0;   /* success */
1610   else
1611     return 1;   /* failure */
1612 }
1613 ], ac_cv_glib_supports_modules=yes, ac_cv_glib_supports_modules=no,
1614    [echo $ac_n "cross compiling; assumed OK... $ac_c"
1615     ac_cv_glib_supports_modules=yes])
1616 CFLAGS="$ac_save_CFLAGS"
1617 LIBS="$ac_save_LIBS"
1618 if test "$ac_cv_glib_supports_modules" = yes ; then
1619   AC_MSG_RESULT(yes)
1620   have_plugins=yes
1621 else
1622   AC_MSG_RESULT(no)
1623   have_plugins=no
1624 fi
1625
1626 #
1627 # If we have <dlfcn.h>, check whether we have dladdr.
1628 #
1629 if test "$ac_cv_header_dlfcn_h" = "yes"
1630 then
1631         #
1632         # Use GLib compiler flags and linker flags; GLib's gmodule
1633         # stuff uses the dl APIs if available, so it might know
1634         # what flags are needed.
1635         #
1636         ac_save_CFLAGS="$CFLAGS"
1637         ac_save_LIBS="$LIBS"
1638         CFLAGS="$CFLAGS $GLIB_CFLAGS"
1639         LIBS="$GLIB_LIBS $LIBS"
1640         AC_CHECK_FUNCS(dladdr)
1641         if test x$ac_cv_func_dladdr = xno
1642         then
1643                 #
1644                 # OK, try it with -ldl, in case you need that to get
1645                 # dladdr().  For some reason, on Linux, that's not
1646                 # part of the GLib flags; perhaps GLib itself is
1647                 # linked with libdl, so that you can link with
1648                 # Glib and it'll pull libdl in itself.
1649                 #
1650                 LIBS="$LIBS -ldl"
1651                 AC_CHECK_FUNCS(dladdr)
1652         fi
1653         CFLAGS="$ac_save_CFLAGS"
1654         LIBS="$ac_save_LIBS"
1655 fi
1656
1657 #
1658 # Check whether GLib's printf supports thousands grouping. (This might
1659 # be different from the system's printf since GLib can optionally use
1660 # its own printf implementation.)
1661 #
1662 AC_MSG_CHECKING(whether GLib supports POSIX/XSI thousands grouping)
1663 ac_save_CFLAGS="$CFLAGS"
1664 ac_save_LIBS="$LIBS"
1665 CFLAGS="$CFLAGS $GLIB_CFLAGS"
1666 LIBS="$GLIB_LIBS $LIBS"
1667 AC_TRY_RUN([
1668 #include <glib.h>
1669 #include <locale.h>
1670 #include <stdio.h>
1671 #include <string.h>
1672
1673 int
1674 main ()
1675 {
1676   gchar *str;
1677   setlocale(LC_ALL, "en_US.UTF-8");
1678   str = g_strdup_printf("%'u", 123456);
1679   return (strcmp (str, "123,456") != 0);
1680 }
1681 ], ac_cv_glib_supports_printf_grouping=yes, ac_cv_glib_supports_printf_grouping=no,
1682    [echo $ac_n "cross compiling; playing it safe... $ac_c"
1683     ac_cv_glib_supports_printf_grouping=no])
1684 CFLAGS="$ac_save_CFLAGS"
1685 LIBS="$ac_save_LIBS"
1686 if test "$ac_cv_glib_supports_printf_grouping" = yes ; then
1687   AC_MSG_RESULT(yes)
1688   AC_DEFINE(HAVE_GLIB_PRINTF_GROUPING, 1, [Define if your printf() function supports thousands grouping.])
1689 else
1690   AC_MSG_RESULT(no)
1691 fi
1692
1693 if test "x$have_gtk" = "xyes"
1694 then
1695     #
1696     # We have GTK+; do we want the OS X integration functions and,
1697     # if so, do we have them and, if so, which versions do we have,
1698     # the old Carbon-based ones or the new Cocoa-based ones?
1699     #
1700     AC_MSG_CHECKING(whether to use OS X integration functions)
1701
1702     AC_ARG_WITH(osx-integration,
1703       AC_HELP_STRING( [--with-osx-integration],
1704                       [use OS X integration functions @<:@default=yes, if available@:>@]),
1705     [
1706         if test $withval = no
1707         then
1708             want_osx_integration=no
1709         else
1710             want_osx_integration=yes
1711         fi
1712     ],[
1713         want_osx_integration=yes
1714     ])
1715     if test "x$want_osx_integration" = "xno"; then
1716         AC_MSG_RESULT(no)
1717     else
1718         AC_MSG_RESULT(yes)
1719         AC_WIRESHARK_OSX_INTEGRATION_CHECK
1720     fi
1721 fi
1722
1723 AC_SUBST(wireshark_bin)
1724 AC_SUBST(wireshark_man)
1725 AM_CONDITIONAL(HAVE_Qt, test "$have_qt" = "yes")
1726 AM_CONDITIONAL(HAVE_GTK, test "$have_gtk" = "yes")
1727 AC_SUBST(OSX_APP_FLAGS)
1728 AC_SUBST(OSX_DMG_FLAGS)
1729
1730 # Enable/disable tshark
1731 AC_ARG_ENABLE(tshark,
1732   AC_HELP_STRING( [--enable-tshark],
1733                   [build TShark @<:@default=yes@:>@]),
1734     tshark=$enableval,enable_tshark=yes)
1735
1736 if test "x$enable_tshark" = "xyes" ; then
1737         tshark_bin="tshark\$(EXEEXT)"
1738         tshark_man="tshark.1"
1739         wiresharkfilter_man="wireshark-filter.4"
1740 else
1741         tshark_bin=""
1742         tshark_man=""
1743 fi
1744 AC_SUBST(tshark_bin)
1745 AC_SUBST(tshark_man)
1746
1747 # Enable/disable tfshark
1748 AC_ARG_ENABLE(tfshark,
1749   AC_HELP_STRING( [--enable-tfshark],
1750                   [build TFShark @<:@default=no@:>@]),
1751     tfshark=$enableval,enable_tfshark=no)
1752
1753 if test "x$enable_tfshark" = "xyes" ; then
1754         tfshark_bin="tfshark\$(EXEEXT)"
1755         tfshark_man="tfshark.1"
1756         wiresharkfilter_man="wireshark-filter.4"
1757 else
1758         tfshark_bin=""
1759         tfshark_man=""
1760 fi
1761 AC_SUBST(tfshark_bin)
1762 AC_SUBST(tfshark_man)
1763
1764 # Enable/disable editcap
1765
1766 AC_ARG_ENABLE(editcap,
1767   AC_HELP_STRING( [--enable-editcap],
1768                   [build editcap @<:@default=yes@:>@]),
1769     enable_editcap=$enableval,enable_editcap=yes)
1770
1771 if test "x$enable_editcap" = "xyes" ; then
1772         editcap_bin="editcap\$(EXEEXT)"
1773         editcap_man="editcap.1"
1774 else
1775         editcap_bin=""
1776         editcap_man=""
1777 fi
1778 AC_SUBST(editcap_bin)
1779 AC_SUBST(editcap_man)
1780
1781 # Enable/disable echld
1782
1783 AC_ARG_ENABLE(echld,
1784   AC_HELP_STRING( [--enable-echld],
1785                   [support echld]),
1786     have_echld=$enableval,have_echld=no)
1787
1788 AM_CONDITIONAL(HAVE_ECHLD, test "x$have_echld" = "xyes")
1789 if test "x$have_echld" = "xyes"
1790 then
1791   AC_DEFINE(HAVE_ECHLD, 1, [Define if echld is enabled])
1792   echld_test_bin="echld_test\$(EXEEXT)"
1793   echld_dir="echld"
1794 else
1795   have_echld="no"
1796   echld_test_bin=""
1797   echld_dir=""
1798 fi
1799 AC_SUBST(echld_test_bin)
1800 AC_SUBST(echld_dir)
1801
1802 # Enabling/disabling of dumpcap is done later (after we know if we have PCAP
1803 # or not)
1804
1805 # Enable/disable capinfos
1806
1807 AC_ARG_ENABLE(capinfos,
1808   AC_HELP_STRING( [--enable-capinfos],
1809                   [build capinfos @<:@default=yes@:>@]),
1810     enable_capinfos=$enableval,enable_capinfos=yes)
1811
1812 if test "x$enable_capinfos" = "xyes" ; then
1813         capinfos_bin="capinfos\$(EXEEXT)"
1814         capinfos_man="capinfos.1"
1815 else
1816         capinfos_bin=""
1817         capinfos_man=""
1818 fi
1819 AC_SUBST(capinfos_bin)
1820 AC_SUBST(capinfos_man)
1821
1822 # Enable/disable captype
1823
1824 AC_ARG_ENABLE(captype,
1825   AC_HELP_STRING( [--enable-captype],
1826                   [build captype @<:@default=yes@:>@]),
1827     enable_captype=$enableval,enable_captype=yes)
1828
1829 if test "x$enable_captype" = "xyes" ; then
1830         captype_bin="captype\$(EXEEXT)"
1831         captype_man="captype.1"
1832 else
1833         captype_bin=""
1834         captype_man=""
1835 fi
1836 AC_SUBST(captype_bin)
1837 AC_SUBST(captype_man)
1838
1839 # Enable/disable mergecap
1840
1841 AC_ARG_ENABLE(mergecap,
1842   AC_HELP_STRING( [--enable-mergecap],
1843                   [build mergecap @<:@default=yes@:>@]),
1844     enable_mergecap=$enableval,enable_mergecap=yes)
1845
1846 if test "x$enable_mergecap" = "xyes" ; then
1847         mergecap_bin="mergecap\$(EXEEXT)"
1848         mergecap_man="mergecap.1"
1849 else
1850         mergecap_bin=""
1851         mergecap_man=""
1852 fi
1853 AC_SUBST(mergecap_bin)
1854 AC_SUBST(mergecap_man)
1855
1856 # Enable/disable reordercap
1857
1858 AC_ARG_ENABLE(reordercap,
1859   AC_HELP_STRING( [--enable-reordercap],
1860                   [build reordercap @<:@default=yes@:>@]),
1861     enable_reordercap=$enableval,enable_reordercap=yes)
1862
1863 if test "x$enable_reordercap" = "xyes" ; then
1864         reordercap_bin="reordercap\$(EXEEXT)"
1865         reordercap_man="reordercap.1"
1866 else
1867         reordercap_bin=""
1868         reordercap_man=""
1869 fi
1870 AC_SUBST(reordercap_bin)
1871 AC_SUBST(reordercap_man)
1872
1873 # Enable/disable text2pcap
1874
1875 AC_ARG_ENABLE(text2pcap,
1876   AC_HELP_STRING( [--enable-text2pcap],
1877                   [build text2pcap @<:@default=yes@:>@]),
1878     text2pcap=$enableval,enable_text2pcap=yes)
1879
1880 if test "x$enable_text2pcap" = "xyes" ; then
1881         text2pcap_bin="text2pcap\$(EXEEXT)"
1882         text2pcap_man="text2pcap.1"
1883 else
1884         text2pcap_bin=""
1885         text2pcap_man=""
1886 fi
1887 AC_SUBST(text2pcap_bin)
1888 AC_SUBST(text2pcap_man)
1889
1890 # Enable/disable dftest
1891
1892 AC_ARG_ENABLE(dftest,
1893   AC_HELP_STRING( [--enable-dftest],
1894                   [build dftest @<:@default=yes@:>@]),
1895     enable_dftest=$enableval,enable_dftest=yes)
1896
1897 if test "x$enable_dftest" = "xyes" ; then
1898         dftest_bin="dftest\$(EXEEXT)"
1899         dftest_man="dftest.1"
1900 else
1901         dftest_bin=""
1902         dftest_man=""
1903 fi
1904 AC_SUBST(dftest_bin)
1905 AC_SUBST(dftest_man)
1906
1907 # Enable/disable randpkt
1908
1909 AC_ARG_ENABLE(randpkt,
1910   AC_HELP_STRING( [--enable-randpkt],
1911                   [build randpkt @<:@default=yes@:>@]),
1912     enable_randpkt=$enableval,enable_randpkt=yes)
1913
1914 if test "x$enable_randpkt" = "xyes" ; then
1915         randpkt_bin="randpkt\$(EXEEXT)"
1916         randpkt_man="randpkt.1"
1917 else
1918         randpkt_bin=""
1919         randpkt_man=""
1920 fi
1921 AC_SUBST(randpkt_bin)
1922 AC_SUBST(randpkt_man)
1923
1924 AC_SUBST(wiresharkfilter_man)
1925
1926 dnl Checks for "gethostbyname()" - and "-lnsl", if we need it to get
1927 dnl "gethostbyname()".
1928 AC_WIRESHARK_GETHOSTBY_LIB_CHECK
1929
1930 dnl Checks for "connect()", used as a proxy for "socket()" - and
1931 dnl "-lsocket", if we need it to get "connect()".
1932 AC_WIRESHARK_SOCKET_LIB_CHECK
1933
1934 dnl pcap check
1935 AC_MSG_CHECKING(whether to use libpcap for packet capture)
1936
1937 AC_ARG_WITH(pcap,
1938   AC_HELP_STRING( [--with-pcap@<:@=DIR@:>@],
1939                   [use libpcap for packet capturing @<:@default=yes@:>@]),
1940 [
1941         if test $withval = no
1942         then
1943                 want_pcap=no
1944         elif test $withval = yes
1945         then
1946                 want_pcap=yes
1947         else
1948                 want_pcap=yes
1949                 pcap_dir=$withval
1950         fi
1951 ],[
1952         want_pcap=yes
1953         pcap_dir=
1954 ])
1955 if test "x$want_pcap" = "xno" ; then
1956         AC_MSG_RESULT(no)
1957 else
1958         AC_MSG_RESULT(yes)
1959         AC_WIRESHARK_PCAP_CHECK
1960 fi
1961
1962
1963 dnl Check for airpcap
1964 AC_MSG_CHECKING(whether to include airpcap support)
1965 AC_ARG_ENABLE(airpcap,
1966   AC_HELP_STRING( [--enable-airpcap],
1967                   [use AirPcap in Wireshark @<:@default=yes@:>@]),
1968   enable_airpcap=$enableval, enable_airpcap=yes)
1969
1970 if test x$enable_airpcap = xyes; then
1971         if test "x$want_pcap" = "xno" ; then
1972                 enable_airpcap=no
1973                 AC_MSG_RESULT(pcap not available - disabling airpcap)
1974         else
1975                 AC_MSG_RESULT(yes)
1976                 AC_DEFINE(HAVE_AIRPCAP, 1, [Enable AirPcap])
1977         fi
1978 else
1979         AC_MSG_RESULT(no)
1980 fi
1981
1982
1983 dnl dumpcap check
1984 AC_MSG_CHECKING(whether to build dumpcap)
1985
1986 AC_ARG_ENABLE(dumpcap,
1987   AC_HELP_STRING( [--enable-dumpcap],
1988                   [build dumpcap @<:@default=yes@:>@]),
1989     enable_dumpcap=$enableval,enable_dumpcap=yes)
1990
1991 if test "x$enable_dumpcap" = "xyes" ; then
1992         if test "x$want_pcap" = "xno" ; then
1993                 enable_dumpcap=no
1994                 AC_MSG_RESULT(pcap not available - disabling dumpcap)
1995         else
1996                 AC_MSG_RESULT(yes)
1997         fi
1998 else
1999         AC_MSG_RESULT(no)
2000 fi
2001
2002 if test "x$enable_dumpcap" = "xyes" ; then
2003         dumpcap_bin="dumpcap\$(EXEEXT)"
2004         dumpcap_man="dumpcap.1"
2005 else
2006         dumpcap_bin=""
2007         dumpcap_man=""
2008 fi
2009 AC_SUBST(dumpcap_bin)
2010 AC_SUBST(dumpcap_man)
2011
2012 # Enable/disable rawshark
2013
2014 dnl rawshark check
2015 AC_MSG_CHECKING(whether to build rawshark)
2016
2017 AC_ARG_ENABLE(rawshark,
2018   AC_HELP_STRING( [--enable-rawshark],
2019                   [build rawshark @<:@default=yes@:>@]),
2020     rawshark=$enableval,enable_rawshark=yes)
2021
2022 if test "x$enable_rawshark" = "xyes" ; then
2023         if test "x$want_pcap" = "xno" ; then
2024                 enable_rawshark=no
2025                 AC_MSG_RESULT(pcap not available - disabling rawshark)
2026         else
2027                 AC_MSG_RESULT(yes)
2028         fi
2029 else
2030         AC_MSG_RESULT(no)
2031 fi
2032
2033 if test "x$enable_rawshark" = "xyes" ; then
2034         rawshark_bin="rawshark\$(EXEEXT)"
2035         rawshark_man="rawshark.1"
2036 else
2037         rawshark_bin=""
2038         rawshark_man=""
2039 fi
2040 AC_SUBST(rawshark_bin)
2041 AC_SUBST(rawshark_man)
2042
2043 dnl Use pcap-ng by default
2044 AC_ARG_ENABLE(pcap-ng-default,
2045   AC_HELP_STRING( [--enable-pcap-ng-default],
2046                   [use the pcap-ng file format by default instead of pcap @<:@default=yes@:>@]),
2047     enable_pcap_ng_default=$enableval,enable_pcap_ng_default=yes)
2048 if test x$enable_pcap_ng_default = xyes; then
2049         AC_DEFINE(PCAP_NG_DEFAULT, 1, [Support for pcap-ng])
2050 fi
2051
2052 dnl pcap remote check
2053 AC_MSG_CHECKING(whether to use libpcap remote capturing feature)
2054
2055 AC_ARG_WITH(pcap-remote,
2056     AC_HELP_STRING([--with-pcap-remote],
2057                    [use libpcap remote capturing (requires libpcap)]),
2058 [
2059     if test $withval = no
2060     then
2061         want_pcap_remote=no
2062     else
2063         want_pcap_remote=yes
2064     fi
2065 ],[
2066     want_pcap_remote=no
2067 ])
2068 if test "x$want_pcap_remote" = "xno" -o "x$want_pcap" = "xno" ; then
2069     AC_MSG_RESULT(no)
2070 else
2071     AC_MSG_RESULT(yes)
2072     AC_WIRESHARK_PCAP_REMOTE_CHECK
2073 fi
2074
2075 dnl zlib check
2076 AC_MSG_CHECKING(whether to use zlib for gzip compression and decompression)
2077
2078 AC_ARG_WITH(zlib,
2079   AC_HELP_STRING([--with-zlib@<:@=DIR@:>@],
2080                  [use zlib (located in directory DIR, if supplied) for gzip compression and decompression @<:@default=yes, if available@:>@]),
2081 [
2082         if test "x$withval" = "xno"
2083         then
2084                 want_zlib=no
2085         elif test "x$withval" = "xyes"
2086         then
2087                 want_zlib=yes
2088         else
2089                 want_zlib=yes
2090                 zlib_dir="$withval"
2091         fi
2092 ],[
2093         #
2094         # Use zlib if it's present, otherwise don't.
2095         #
2096         want_zlib=ifavailable
2097         zlib_dir=
2098 ])
2099 if test "x$want_zlib" = "xno" ; then
2100         AC_MSG_RESULT(no)
2101 else
2102         AC_MSG_RESULT(yes)
2103         AC_WIRESHARK_ZLIB_CHECK
2104         if test "x$want_zlib" = "xno" ; then
2105                 AC_MSG_RESULT(zlib not found - disabling gzip compression and decompression)
2106         else
2107                 if test "x$ac_cv_func_inflatePrime" = "xno" ; then
2108                         AC_MSG_RESULT(inflatePrime not found in zlib - disabling gzipped capture file support)
2109                 fi
2110         fi
2111 fi
2112
2113 dnl Lua check
2114 AC_MSG_CHECKING(whether to use liblua for the Lua scripting plugin)
2115
2116 AC_ARG_WITH(lua,
2117   AC_HELP_STRING( [--with-lua@<:@=DIR@:>@],
2118                   [use liblua (located in directory DIR, if supplied) for the Lua scripting plugin @<:@default=yes, if available@:>@]),
2119 [
2120         if test $withval = no
2121         then
2122                 want_lua=no
2123         elif test $withval = yes
2124         then
2125                 want_lua=yes
2126         else
2127                 want_lua=yes
2128                 lua_dir=$withval
2129         fi
2130 ],[
2131         #
2132         # Use liblua by default
2133         #
2134         want_lua=ifavailable
2135         lua_dir=
2136 ])
2137 if test "x$want_lua" = "xno" ; then
2138         AC_MSG_RESULT(no)
2139 else
2140         AC_MSG_RESULT(yes)
2141         AC_WIRESHARK_LIBLUA_CHECK
2142         if test "x$want_lua" = "xno" ; then
2143                 AC_MSG_RESULT(liblua not found - disabling support for the lua scripting plugin)
2144         fi
2145 fi
2146 AM_CONDITIONAL(HAVE_LIBLUA, test x$want_lua = xyes)
2147
2148
2149 dnl portaudio check
2150 AC_MSG_CHECKING(whether to use libportaudio for the rtp_player)
2151
2152 AC_ARG_WITH(portaudio,
2153   AC_HELP_STRING( [--with-portaudio@<:@=DIR@:>@],
2154                   [use libportaudio (located in directory DIR, if supplied) for the rtp_player @<:@default=yes, if available@:>@]),
2155 [
2156         if test $withval = no
2157         then
2158                 want_portaudio=no
2159         elif test $withval = yes
2160         then
2161                 want_portaudio=yes
2162         else
2163                 want_portaudio=yes
2164                 portaudio_dir=$withval
2165         fi
2166 ],[
2167         #
2168         # Use libportaudio by default
2169         #
2170         want_portaudio=ifavailable
2171         portaudio_dir=
2172 ])
2173 if test "x$want_portaudio" = "xno" ; then
2174         AC_MSG_RESULT(no)
2175 else
2176         AC_MSG_RESULT(yes)
2177         AC_WIRESHARK_LIBPORTAUDIO_CHECK
2178         if test "x$want_portaudio" = "xno" ; then
2179                 AC_MSG_RESULT(libportaudio not found - disabling support for the rtp_player)
2180         fi
2181 fi
2182 AM_CONDITIONAL(HAVE_LIBPORTAUDIO, test x$want_portaudio = xyes)
2183
2184
2185 dnl ipv6 check
2186 AC_ARG_ENABLE(ipv6,
2187   AC_HELP_STRING( [--enable-ipv6],
2188                   [use IPv6 name resolution, if available @<:@default=yes@:>@]),
2189     enable_ipv6=$enableval,enable_ipv6=yes)
2190
2191 AC_MSG_CHECKING(whether to enable ipv6 name resolution if available)
2192 if test "x$enable_ipv6" = "xno" ; then
2193         AC_MSG_RESULT(no)
2194 else
2195         AC_MSG_RESULT(yes)
2196         AC_WIRESHARK_IPV6_STACK
2197 fi
2198
2199
2200 dnl Check if dumpcap should be installed with filesystem capabilities
2201 AC_PATH_PROG(SETCAP, setcap)
2202 AC_ARG_ENABLE(setcap-install,
2203   AC_HELP_STRING( [--enable-setcap-install],
2204                   [install dumpcap with cap_net_admin and cap_net_raw @<:@default=no@:>@]),
2205     enable_setcap_install=$enableval,enable_setcap_install=no)
2206
2207 AC_MSG_CHECKING(whether to install dumpcap with cap_net_admin and cap_net_raw capabilities)
2208 if test "x$enable_setcap_install" = "xno" ; then
2209         AC_MSG_RESULT(no)
2210 else
2211         if test "x$SETCAP" = "x" ; then
2212                 AC_MSG_RESULT(no. Setcap not found)
2213         elif test "x$enable_dumpcap" = "xno" ; then
2214                 AC_MSG_ERROR(Setcap install works only with dumpcap but dumpcap is disabled)
2215         else
2216                 AC_MSG_RESULT(yes)
2217         fi
2218 fi
2219
2220 AM_CONDITIONAL(SETCAP_INSTALL, test x$enable_setcap_install = xyes)
2221
2222 dnl Check if dumpcap should be installed setuid
2223 AC_ARG_ENABLE(setuid-install,
2224   AC_HELP_STRING( [--enable-setuid-install],
2225                   [install dumpcap as setuid @<:@default=no@:>@]),
2226     enable_setuid_install=$enableval,enable_setuid_install=no)
2227
2228 AC_MSG_CHECKING(whether to install dumpcap setuid)
2229 if test "x$enable_setuid_install" = "xno" ; then
2230         AC_MSG_RESULT(no)
2231 else
2232         if test "x$enable_setcap_install" = "xyes" ; then
2233                 enable_setuid_install=no
2234                 AC_MSG_RESULT(no; using setcap instead)
2235         elif test "x$enable_dumpcap" = "xno" ; then
2236                 AC_MSG_ERROR(Setuid install works only with dumpcap but dumpcap is disabled)
2237         else
2238                 AC_MSG_RESULT(yes)
2239         fi
2240 fi
2241
2242 AM_CONDITIONAL(SETUID_INSTALL, test x$enable_setuid_install = xyes)
2243 AC_CHECK_FUNCS(setresuid setresgid)
2244
2245 dnl ...but our Network Operations group is named "no"!
2246 DUMPCAP_GROUP=''
2247 AC_ARG_WITH(dumpcap-group,
2248   AC_HELP_STRING( [--with-dumpcap-group=GROUP],
2249                   [restrict dumpcap to GROUP]),
2250 [
2251   if test "x$withval" = "xyes"; then
2252       AC_MSG_ERROR([No dumpcap group specified.])
2253   elif test "x$withval" != "xno"; then
2254       if test "x$enable_dumpcap" = "xno" ; then
2255           AC_MSG_ERROR(dumpcap group install works only with dumpcap but dumpcap is disabled)
2256       fi
2257       AC_MSG_RESULT($withval)
2258       DUMPCAP_GROUP="$withval"
2259   fi
2260 ])
2261 AC_SUBST(DUMPCAP_GROUP)
2262 AM_CONDITIONAL(HAVE_DUMPCAP_GROUP, test x$DUMPCAP_GROUP != x)
2263
2264 dnl libcap (not libpcap) check
2265 LIBCAP_LIBS=''
2266 AC_MSG_CHECKING(whether to use the libcap capabilities library)
2267
2268 AC_ARG_WITH(libcap,
2269   AC_HELP_STRING( [--with-libcap@<:@=DIR@:>@],
2270                   [use libcap (located in directory DIR, if supplied) for POSIX.1e capabilities management @<:@default=yes, if present@:>@]),
2271 [
2272 if   test "x$withval" = "xno";  then
2273         want_libcap=no
2274 elif test "x$withval" = "xyes"; then
2275         want_libcap=yes
2276 elif test -d "$withval"; then
2277         want_libcap=yes
2278         AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
2279 fi
2280 ])
2281 if test "x$with_libcap" = "xno" ; then
2282         AC_MSG_RESULT(no)
2283 else
2284         AC_MSG_RESULT(yes)
2285         AC_WIRESHARK_LIBCAP_CHECK
2286 fi
2287 AC_SUBST(LIBCAP_LIBS)
2288
2289 dnl Checks for header files.
2290 dnl Some of these may not be needed: http://hacks.owlfolio.org/header-survey/
2291 AC_CHECK_HEADERS(direct.h dirent.h fcntl.h getopt.h grp.h inttypes.h netdb.h pwd.h stdarg.h stddef.h unistd.h)
2292 AC_CHECK_HEADERS(sys/ioctl.h sys/param.h sys/socket.h sys/sockio.h sys/stat.h sys/time.h sys/types.h sys/utsname.h sys/wait.h)
2293 AC_CHECK_HEADERS(netinet/in.h)
2294 AC_CHECK_HEADERS(arpa/inet.h arpa/nameser.h)
2295
2296 dnl SSL Check
2297 SSL_LIBS=''
2298 AC_MSG_CHECKING(whether to use SSL library)
2299
2300 AC_ARG_WITH(ssl,
2301   AC_HELP_STRING( [--with-ssl@<:@=DIR@:>@],
2302                   [use SSL crypto library (located in directory DIR, if supplied) @<:@default=no@:>@]),
2303 [
2304 if test "x$withval" = "xno";  then
2305         want_ssl=no
2306 elif test "x$withval" = "xyes"; then
2307         want_ssl=yes
2308 elif test -d "$withval"; then
2309         want_ssl=yes
2310         AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
2311 fi
2312 ],[
2313         want_ssl=no
2314 ])
2315 if test "x$want_ssl" = "xyes"; then
2316         AC_MSG_RESULT(yes)
2317         AC_CHECK_LIB(crypto,EVP_md5,
2318             [
2319                 SSL_LIBS=-lcrypto
2320             ],
2321             [
2322                 AC_MSG_ERROR([SSL crypto library was requested, but is not available])
2323             ])
2324 else
2325         AC_MSG_RESULT(no)
2326 fi
2327 AC_SUBST(SSL_LIBS)
2328
2329 dnl kerberos check
2330 AC_MSG_CHECKING(whether to use Kerberos library)
2331
2332 AC_ARG_WITH(krb5,
2333   AC_HELP_STRING( [--with-krb5@<:@=DIR@:>@],
2334                   [use Kerberos library (located in directory DIR, if supplied) to use in Kerberos dissection @<:@default=yes@:>@]),
2335 [
2336         if test $withval = no
2337         then
2338                 want_krb5=no
2339         elif test $withval = yes
2340         then
2341                 want_krb5=yes
2342         else
2343                 want_krb5=yes
2344                 krb5_dir=$withval
2345         fi
2346 ],[
2347         #
2348         # Use Kerberos library if available, otherwise don't.
2349         #
2350         want_krb5=ifavailable
2351         krb5_dir=
2352 ])
2353 if test "x$want_krb5" = "xno" ; then
2354         AC_MSG_RESULT(no)
2355 else
2356         AC_MSG_RESULT(yes)
2357         AC_WIRESHARK_KRB5_CHECK
2358 fi
2359
2360
2361 dnl c-ares Check
2362 C_ARES_LIBS=''
2363 AC_MSG_CHECKING(whether to use the c-ares library if available)
2364
2365 AC_ARG_WITH(c-ares,
2366   AC_HELP_STRING( [--with-c-ares@<:@=DIR@:>@],
2367                   [use c-ares (located in directory DIR, if supplied) - supersedes --with-adns @<:@default=yes, if present@:>@]),
2368 [
2369 if   test "x$withval" = "xno";  then
2370         want_c_ares=no
2371 elif test "x$withval" = "xyes"; then
2372         want_c_ares=yes
2373 elif test -d "$withval"; then
2374         want_c_ares=yes
2375         AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
2376 fi
2377 ])
2378 if test "x$want_c_ares" = "xno" ; then
2379         AC_MSG_RESULT(no)
2380 else
2381         AC_MSG_RESULT(yes)
2382         AC_WIRESHARK_C_ARES_CHECK
2383 fi
2384 AC_SUBST(C_ARES_LIBS)
2385
2386 dnl ADNS Check
2387 ADNS_LIBS=''
2388 AC_MSG_CHECKING(whether to use the GNU ADNS library if available)
2389
2390 AC_ARG_WITH(adns,
2391   AC_HELP_STRING( [--with-adns@<:@=DIR@:>@],
2392                   [use GNU ADNS (located in directory DIR, if supplied) @<:@default=yes, if present@:>@]),
2393 [
2394 if   test "x$withval" = "xno";  then
2395         want_adns=no
2396 elif test "x$withval" = "xyes"; then
2397         want_adns=yes
2398 elif test -d "$withval"; then
2399         want_adns=yes
2400         AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
2401 fi
2402 ])
2403 if test "x$want_adns" = "xno" -o "x$have_good_c_ares" = "xyes" ; then
2404         AC_MSG_RESULT(no)
2405 else
2406         AC_MSG_RESULT(yes)
2407         AC_WIRESHARK_ADNS_CHECK
2408 fi
2409 AC_SUBST(ADNS_LIBS)
2410
2411 dnl GEOIP Check
2412 GEOIP_LIBS=''
2413 AC_MSG_CHECKING(whether to use the GeoIP IP address mapping library if available)
2414
2415 AC_ARG_WITH(geoip,
2416   AC_HELP_STRING( [--with-geoip@<:@=DIR@:>@],
2417                   [use GeoIP (located in directory DIR, if supplied) @<:@default=yes, if present@:>@]),
2418 [
2419 if   test "x$withval" = "xno";  then
2420         want_geoip=no
2421 elif test "x$withval" = "xyes"; then
2422         want_geoip=yes
2423 elif test -d "$withval"; then
2424         want_geoip=yes
2425         AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
2426 fi
2427 ])
2428 if test "x$want_geoip" = "xno"; then
2429         AC_MSG_RESULT(no)
2430 else
2431         AC_MSG_RESULT(yes)
2432         AC_WIRESHARK_GEOIP_CHECK
2433 fi
2434 AC_SUBST(GEOIP_LIBS)
2435
2436 # Warning: this Python scripting appears to be broken (does not work at all).
2437 # Running it also causes Valgrind to complain about all sorts of memory errors.
2438 # Suggestion: do not enable it unless you are working on fixing it.
2439 #
2440 # An alternative might be https://code.google.com/p/pyreshark/
2441 #
2442 dnl Python devel Check
2443 AC_MSG_CHECKING(whether to use the Python interpreter for scripting)
2444
2445 AC_ARG_WITH(broken-python,
2446     AC_HELP_STRING( [--with-broken-python@<:@=DIR@:>@],
2447                     [use the (BROKEN) Python interpreter (installed in DIR, if supplied) @<:@default=no@:>@]),
2448 [
2449         pythondir='${libdir}/wireshark/python/${VERSION}'
2450         if test "x$withval" = "xno"
2451         then
2452                 want_python=no
2453         elif test "x$withval" = "xyes"
2454         then
2455                 want_python=yes
2456         else
2457                 want_python=yes
2458                 pythondir="$withval"
2459         fi
2460 ],[
2461         # By default (user didn't explicitly enable Python), don't enable
2462         # Python support.
2463         #
2464         want_python=no
2465         #pythondir='${libdir}/wireshark/python/${VERSION}'
2466 ])
2467 if test "x$want_python" = "xno" ; then
2468         AC_MSG_RESULT(no)
2469 else
2470         AC_MSG_RESULT(yes)
2471         AC_WIRESHARK_PYTHON_CHECK
2472 fi
2473 AM_CONDITIONAL(HAVE_LIBPY, test x$want_python != xno)
2474 AC_SUBST(pythondir)
2475
2476 #
2477 # Define WS_MSVC_NORETURN appropriately for declarations of routines that
2478 # never return (just like Charlie on the MTA).
2479 #
2480 # Note that MSVC++ expects __declspec(noreturn) to precede the function
2481 # name and GCC, as far as I know, expects __attribute__((noreturn)) to
2482 # follow the function name, so we need two different flavors of
2483 # noreturn tag.
2484 #
2485 AC_DEFINE(WS_MSVC_NORETURN,, [Define as the string to precede declarations of routines that never return])
2486
2487 dnl Checks for typedefs, structures, and compiler characteristics.
2488 # AC_C_CONST
2489
2490 # Check how we can get the time zone abbreviation
2491 AC_WIRESHARK_TIMEZONE_ABBREV
2492
2493 # We need to know whether "struct stat" has an "st_flags" member
2494 # for file_user_immutable().
2495
2496 AC_WIRESHARK_STRUCT_ST_FLAGS
2497
2498 # We need to know whether "struct sockaddr" has an "sa_len" member
2499 # for get_interface_list().
2500
2501 AC_WIRESHARK_STRUCT_SA_LEN
2502
2503 # We must know our byte order
2504 AC_C_BIGENDIAN
2505
2506 # Checks whether "-traditional" is needed when using "ioctl".
2507 # XXX - do we need this?
2508 AC_PROG_GCC_TRADITIONAL
2509
2510 GETOPT_LO=""
2511 AC_CHECK_FUNC(getopt,
2512   [GETOPT_LO=""
2513    AC_DEFINE(HAVE_GETOPT, 1, [Define to 1 if you have the getopt function.])
2514   ],
2515   GETOPT_LO="wsgetopt.lo"
2516 )
2517 if test "$ac_cv_func_getopt" = no ; then
2518   GETOPT_LO="wsgetopt.lo"
2519 fi
2520 AM_CONDITIONAL(NEED_GETOPT_LO, test "x$ac_cv_func_getopt" = "xno")
2521 AC_SUBST(GETOPT_LO)
2522
2523 AC_CHECK_FUNC(strncasecmp, STRNCASECMP_LO="",
2524   STRNCASECMP_LO="strncasecmp.lo")
2525 if test "$ac_cv_func_strncasecmp" = no ; then
2526   STRNCASECMP_LO="strncasecmp.lo"
2527 fi
2528 AM_CONDITIONAL(NEED_STRNCASECMP_LO, test "x$ac_cv_func_strncasecmp" = "xno")
2529 AC_SUBST(STRNCASECMP_LO)
2530
2531 AC_CHECK_FUNCS(mkstemp mkdtemp)
2532
2533 AC_SEARCH_LIBS(inet_aton, [socket nsl], have_inet_aton=yes,
2534     have_inet_aton=no)
2535 if test "$have_inet_aton" = no; then
2536   INET_ATON_LO="inet_aton.lo"
2537   AC_DEFINE(HAVE_INET_ATON_H, 0, [Define unless inet/aton.h needs to be included])
2538 else
2539   INET_ATON_LO=""
2540 fi
2541 AM_CONDITIONAL(NEED_INET_ATON_LO, test "x$have_inet_aton" = "xno")
2542 AC_SUBST(INET_ATON_LO)
2543
2544 AC_SEARCH_LIBS(inet_pton, [socket nsl], [
2545   dnl check for pre-BIND82 inet_pton() bug.
2546   AC_MSG_CHECKING(for broken inet_pton)
2547   AC_TRY_RUN([#include <sys/types.h>
2548 #include <sys/socket.h>
2549 #include <netinet/in.h>
2550 #include <arpa/inet.h>
2551 int main()
2552 {
2553 #ifdef AF_INET6
2554   char buf[16];
2555   /* this should return 0 (error) */
2556   return inet_pton(AF_INET6, "0:1:2:3:4:5:6:7:", buf);
2557 #else
2558   return 1;
2559 #endif
2560 }], [AC_MSG_RESULT(ok);
2561 have_inet_pton=yes], [AC_MSG_RESULT(broken);
2562 have_inet_pton=no], [AC_MSG_RESULT(cross compiling, assume it is broken);
2563 have_inet_pton=no])],
2564 have_inet_pton=no)
2565 if test "$have_inet_pton" = no; then
2566   INET_PTON_LO="inet_pton.lo"
2567 else
2568   INET_PTON_LO=""
2569 fi
2570 AM_CONDITIONAL(NEED_INET_PTON_LO, test "x$have_inet_pton" = "xno")
2571 AC_SUBST(INET_PTON_LO)
2572
2573 AC_SEARCH_LIBS(inet_ntop, [socket nsl], [
2574   AC_MSG_CHECKING([for inet_ntop prototype])
2575   AC_TRY_COMPILE([#include <stdio.h>
2576 #include <sys/types.h>
2577 #include <sys/socket.h>
2578 #include <netinet/in.h>
2579 #include <arpa/inet.h>
2580
2581 extern const char *inet_ntop(int, const void *, char *, size_t);],, [
2582     AC_MSG_RESULT(yes)
2583     AC_DEFINE(HAVE_INET_NTOP_PROTO, 1,
2584     [Define if inet_ntop() prototype exists])], [
2585     AC_TRY_COMPILE([#include <stdio.h>
2586 #include <sys/types.h>
2587 #include <sys/socket.h>
2588 #include <netinet/in.h>
2589 #include <arpa/inet.h>
2590
2591 extern const char *inet_ntop(int, const void *, char *, socklen_t);],, [
2592       AC_MSG_RESULT(yes)
2593       AC_DEFINE(HAVE_INET_NTOP_PROTO, 1,
2594       [Define if inet_ntop() prototype exists])], [
2595       AC_MSG_RESULT(no)])])
2596   INET_NTOP_LO=""], [
2597   INET_NTOP_LO="inet_ntop.lo"
2598   AC_DEFINE(NEED_INET_V6DEFS_H, 1,
2599   [Define if inet/v6defs.h needs to be included])])
2600 AM_CONDITIONAL(NEED_INET_NTOP_LO, test "x$INET_NTOP_LO" != "x")
2601 AC_SUBST(INET_NTOP_LO)
2602
2603 AC_CHECK_FUNC(strptime, STRPTIME_LO="",
2604   [STRPTIME_LO="strptime.lo"
2605    AC_DEFINE(NEED_STRPTIME_H, 1, [Define if strptime.h needs to be included])
2606 ])
2607 if test "$ac_cv_func_strptime" = no ; then
2608   STRPTIME_LO="strptime.lo"
2609 fi
2610 AC_SUBST(STRPTIME_C)
2611 AM_CONDITIONAL(NEED_STRPTIME_LO, test "x$ac_cv_func_strptime" = "no")
2612 AC_SUBST(STRPTIME_LO)
2613
2614 AC_CHECK_FUNCS(getprotobynumber gethostbyname2)
2615 AC_CHECK_FUNCS(issetugid)
2616 AC_CHECK_FUNCS(mmap mprotect sysconf)
2617
2618 dnl blank for now, but will be used in future
2619 AC_SUBST(wireshark_SUBDIRS)
2620
2621 # Check Bluetooth SBC codec for RTP Player
2622 # git://git.kernel.org/pub/scm/bluetooth/sbc.git
2623 PKG_CHECK_MODULES(SBC, sbc >= 1.0, [have_sbc=yes], [have_sbc=no])
2624 if (test "${have_sbc}" = "yes"); then
2625     AC_DEFINE(HAVE_SBC, 1, [Define to support playing SBC by standalone BlueZ SBC library])
2626     CFLAGS="$CFLAGS $(pkg-config sbc --cflags)"
2627     LIBS="$LIBS $(pkg-config sbc --libs)"
2628 fi
2629
2630 dnl
2631 dnl check whether plugins should be enabled and, if they should be,
2632 dnl check for plugins directory - stolen from Amanda's configure.ac
2633 dnl
2634 dnl we don't wish to expand ${libdir} yet
2635 plugindir='${libdir}/wireshark/plugins/${VERSION}'
2636 AC_ARG_WITH(plugins,
2637   AC_HELP_STRING( [--with-plugins@<:@=DIR@:>@],
2638                   [support plugins (installed in DIR, if supplied) @<:@default=yes, if possible@:>@]),
2639 [
2640   if test "x$withval" = "xno"; then
2641     have_plugins=no
2642   elif test "x$have_plugins" = "xno"; then
2643       AC_MSG_ERROR([GLib on this platform doesn't support loadable modules, so you can't enable plugins.])
2644   elif test "x$withval" != "xyes"; then
2645       plugindir="$withval"
2646   fi
2647 ])
2648 AM_CONDITIONAL(HAVE_PLUGINS, test "x$have_plugins" = "xyes")
2649 if test x$have_plugins = xyes
2650 then
2651   AC_DEFINE(HAVE_PLUGINS, 1, [Define if plugins are enabled])
2652 fi
2653 AC_SUBST(plugindir)
2654 CPPFLAGS="$CPPFLAGS '-DPLUGIN_DIR=\"\$(plugindir)\"'"
2655
2656 #
2657 # The plugin dissectors reside in ./plugins/PROTO/
2658 #
2659 PLUGIN_LIBS=""
2660 AC_SUBST(PLUGIN_LIBS)
2661
2662 #
2663 # Check if (emem) memory allocations must be 8-byte aligned.
2664 # I haven't been able to write C code that reliably makes that determination
2665 # (different versions of GCC with or without optimization give different
2666 # results) so just assume everything except (32-bit) x86 needs 8-byte
2667 # alignment (64-bit platforms either require 8-byte alignment for pointers
2668 # and 64-bit integral data types or may get better performance from that;
2669 # 64-bit x86 will get 8-byte alignment from G_MEM_ALIGN anyway.  32-bit
2670 # platforms would only require it, or get better performance from it,
2671 # for 64-bit floating-point values.).
2672 #
2673 AC_MSG_CHECKING(whether we need memory allocations to be 8-byte aligned)
2674 case $host_cpu in
2675         i386|i486|i586|i686)
2676                 AC_MSG_RESULT(no)
2677                 ;;
2678         *)
2679                 AC_MSG_RESULT(yes)
2680                 AC_DEFINE(NEED_8_BYTE_ALIGNMENT, 1, [Define if we need memory allocations to be 8-byte aligned])
2681                 ;;
2682 esac
2683
2684 # Gather only the "--with*" arguments and also a list of --with arguments for rpmbuild
2685 for f in $CONFIG_ARGS
2686 do
2687         case $f in
2688         --with-gtk2*)
2689                 CONFIG_WITH_ARGS="$CONFIG_WITH_ARGS $f"
2690                 RPMBUILD_WITH_ARGS="$RPMBUILD_WITH_ARGS --with gtk2"
2691                 ;;
2692         --without-gtk2*)
2693                 CONFIG_WITH_ARGS="$CONFIG_WITH_ARGS $f"
2694                 RPMBUILD_WITH_ARGS="$RPMBUILD_WITH_ARGS --without gtk2"
2695                 ;;
2696         --with-gtk3*)
2697                 CONFIG_WITH_ARGS="$CONFIG_WITH_ARGS $f"
2698                 RPMBUILD_WITH_ARGS="$RPMBUILD_WITH_ARGS --with gtk3"
2699                 ;;
2700         --without-gtk3*)
2701                 CONFIG_WITH_ARGS="$CONFIG_WITH_ARGS $f"
2702                 RPMBUILD_WITH_ARGS="$RPMBUILD_WITH_ARGS --without gtk3"
2703                 ;;
2704         --with-qt*)
2705                 CONFIG_WITH_ARGS="$CONFIG_WITH_ARGS $f"
2706                 RPMBUILD_WITH_ARGS="$RPMBUILD_WITH_ARGS --with qt"
2707                 ;;
2708         --without-qt*)
2709                 CONFIG_WITH_ARGS="$CONFIG_WITH_ARGS $f"
2710                 RPMBUILD_WITH_ARGS="$RPMBUILD_WITH_ARGS --without qt"
2711                 ;;
2712         --with*)
2713                 CONFIG_WITH_ARGS="$CONFIG_WITH_ARGS $f"
2714                 ;;
2715         esac
2716
2717 done
2718 AC_SUBST(CONFIG_WITH_ARGS)
2719 AC_SUBST(RPMBUILD_WITH_ARGS)
2720
2721 dnl libtool defs
2722 #
2723 # Yes, AM_PROG_LIBTOOL is redundant with newer version(s) of some tool(s)
2724 # (autoconf?  automake?  libtool?) - with the newer version(s), it's
2725 # just an alias for AC_PROG_LIBTOOL, which is called earlier.
2726 #
2727 # With older version(s) of those tool(s), however, it's not just an
2728 # alias, and the configure scripts don't work without it.
2729 #
2730 AM_PROG_LIBTOOL
2731 AC_SUBST(LIBTOOL_DEPS)
2732
2733 AM_CONDITIONAL(ENABLE_STATIC, test x$enable_static = xyes)
2734 if test x$enable_static = xyes -a x$have_plugins = xyes
2735 then
2736   AC_DEFINE(ENABLE_STATIC, 1, [Link plugins statically into Wireshark])
2737 fi
2738 AC_SUBST(ENABLE_STATIC)
2739
2740 dnl Save the cacheable configure results to config.cache before recursing
2741 AC_CACHE_SAVE
2742
2743 sinclude(plugins/Custom.m4) dnl
2744 ifdef(_CUSTOM_AC_OUTPUT_,, define(_CUSTOM_AC_OUTPUT_, )) dnl
2745
2746 sinclude(asn1/Custom.m4) dnl
2747 ifdef(_CUSTOM_ASN1_AC_OUTPUT_,, define(_CUSTOM_ASN1_AC_OUTPUT_, )) dnl
2748
2749 AC_CONFIG_HEADERS(config.h)
2750 AC_OUTPUT(
2751   Makefile
2752   doxygen.cfg
2753   asn1/Makefile
2754   _CUSTOM_ASN1_AC_OUTPUT_
2755   asn1/acp133/Makefile
2756   asn1/acse/Makefile
2757   asn1/ansi_map/Makefile
2758   asn1/ansi_tcap/Makefile
2759   asn1/atn-cm/Makefile
2760   asn1/atn-cpdlc/Makefile
2761   asn1/atn-ulcs/Makefile
2762   asn1/c1222/Makefile
2763   asn1/camel/Makefile
2764   asn1/cdt/Makefile
2765   asn1/charging_ase/Makefile
2766   asn1/cmip/Makefile
2767   asn1/cmp/Makefile
2768   asn1/crmf/Makefile
2769   asn1/cms/Makefile
2770   asn1/credssp/Makefile
2771   asn1/dap/Makefile
2772   asn1/disp/Makefile
2773   asn1/dop/Makefile
2774   asn1/dsp/Makefile
2775   asn1/ess/Makefile
2776   asn1/ftam/Makefile
2777   asn1/goose/Makefile
2778   asn1/gprscdr/Makefile
2779   asn1/gsm_map/Makefile
2780   asn1/h225/Makefile
2781   asn1/h235/Makefile
2782   asn1/h245/Makefile
2783   asn1/h248/Makefile
2784   asn1/h282/Makefile
2785   asn1/h283/Makefile
2786   asn1/h323/Makefile
2787   asn1/h450/Makefile
2788   asn1/h450-ros/Makefile
2789   asn1/h460/Makefile
2790   asn1/h501/Makefile
2791   asn1/HI2Operations/Makefile
2792   asn1/hnbap/Makefile
2793   asn1/idmp/Makefile
2794   asn1/ilp/Makefile
2795   asn1/inap/Makefile
2796   asn1/isdn-sup/Makefile
2797   asn1/kerberos/Makefile
2798   asn1/lcsap/Makefile
2799   asn1/ldap/Makefile
2800   asn1/logotypecertextn/Makefile
2801   asn1/lpp/Makefile
2802   asn1/lppa/Makefile
2803   asn1/lppe/Makefile
2804   asn1/lte-rrc/Makefile
2805   asn1/m3ap/Makefile
2806   asn1/mms/Makefile
2807   asn1/mpeg-audio/Makefile
2808   asn1/mpeg-pes/Makefile
2809   asn1/nbap/Makefile
2810   asn1/ns_cert_exts/Makefile
2811   asn1/novell_pkis/Makefile
2812   asn1/ocsp/Makefile
2813   asn1/p1/Makefile
2814   asn1/p22/Makefile
2815   asn1/p7/Makefile
2816   asn1/p772/Makefile
2817   asn1/pcap/Makefile
2818   asn1/pkcs1/Makefile
2819   asn1/pkcs12/Makefile
2820   asn1/pkinit/Makefile
2821   asn1/pkixac/Makefile
2822   asn1/pkix1explicit/Makefile
2823   asn1/pkix1implicit/Makefile
2824   asn1/pkixproxy/Makefile
2825   asn1/pkixqualified/Makefile
2826   asn1/pkixtsp/Makefile
2827   asn1/pres/Makefile
2828   asn1/q932/Makefile
2829   asn1/q932-ros/Makefile
2830   asn1/qsig/Makefile
2831   asn1/ranap/Makefile
2832   asn1/rnsap/Makefile
2833   asn1/ros/Makefile
2834   asn1/rrc/Makefile
2835   asn1/rrlp/Makefile
2836   asn1/rtse/Makefile
2837   asn1/rua/Makefile
2838   asn1/s1ap/Makefile
2839   asn1/sabp/Makefile
2840   asn1/sbc-ap/Makefile
2841   asn1/smrse/Makefile
2842   asn1/snmp/Makefile
2843   asn1/spnego/Makefile
2844   asn1/sv/Makefile
2845   asn1/t124/Makefile
2846   asn1/t125/Makefile
2847   asn1/t38/Makefile
2848   asn1/tcap/Makefile
2849   asn1/tetra/Makefile
2850   asn1/ulp/Makefile
2851   asn1/wlancertextn/Makefile
2852   asn1/x2ap/Makefile
2853   asn1/x509af/Makefile
2854   asn1/x509ce/Makefile
2855   asn1/x509if/Makefile
2856   asn1/x509sat/Makefile
2857   asn1/x721/Makefile
2858   doc/Makefile
2859   docbook/Makefile
2860   epan/Makefile
2861   epan/crypt/Makefile
2862   epan/doxygen.cfg
2863   epan/dfilter/Makefile
2864   epan/dissectors/Makefile
2865   epan/dissectors/dcerpc/Makefile
2866   epan/dissectors/pidl/Makefile
2867   epan/ftypes/Makefile
2868   epan/wmem/Makefile
2869   epan/wslua/Makefile
2870   epan/wspython/Makefile
2871   filetap/Makefile
2872   codecs/Makefile
2873   ui/Makefile
2874   ui/doxygen.cfg
2875   ui/gtk/Makefile
2876   ui/gtk/doxygen.cfg
2877   ui/cli/Makefile
2878   ui/qt/Makefile
2879   ui/qt/doxygen.cfg
2880   help/Makefile
2881   packaging/Makefile
2882   packaging/macosx/Info.plist
2883   packaging/macosx/Makefile
2884   packaging/macosx/osx-dmg.sh
2885   packaging/macosx/Wireshark_package.pmdoc/index.xml
2886   packaging/nsis/Makefile
2887   packaging/rpm/Makefile
2888   packaging/rpm/SPECS/Makefile
2889   packaging/rpm/SPECS/wireshark.spec
2890   packaging/svr4/Makefile
2891   packaging/svr4/checkinstall
2892   packaging/svr4/pkginfo
2893   plugins/Makefile
2894   plugins/docsis/Makefile
2895   plugins/ethercat/Makefile
2896   plugins/gryphon/Makefile
2897   plugins/irda/Makefile
2898   plugins/m2m/Makefile
2899   plugins/mate/Makefile
2900   plugins/opcua/Makefile
2901   plugins/profinet/Makefile
2902   plugins/stats_tree/Makefile
2903   plugins/unistim/Makefile
2904   plugins/wimax/Makefile
2905   plugins/wimaxasncp/Makefile
2906   plugins/wimaxmacphy/Makefile
2907   tools/Makefile
2908   tools/lemon/Makefile
2909   wiretap/Makefile
2910   wsutil/Makefile
2911   echld/Makefile
2912   _CUSTOM_AC_OUTPUT_
2913   ,)
2914 dnl AC_CONFIG_FILES([tools/setuid-root.pl], [chmod +x tools/setuid-root.pl])
2915
2916
2917 # Pretty messages
2918
2919 if test "x$have_gtk" = "xyes"; then
2920         if test "x$with_gtk3" = "xyes"; then
2921                 gtk_lib_message=" (with GTK+ 3"
2922         else
2923                 gtk_lib_message=" (with GTK+ 2"
2924         fi
2925         if test "x$have_ige_mac" = "xyes"; then
2926                 gtk_lib_message="$gtk_lib_message and Mac OS X integration)"
2927         else
2928                 gtk_lib_message="$gtk_lib_message)"
2929         fi
2930 fi
2931
2932 if test "x$have_qt" = "xyes" ; then
2933         enable_qtshark="yes"
2934 else
2935         enable_qtshark="no"
2936 fi
2937
2938 if test "x$enable_setcap_install" = "xyes" ; then
2939         setcap_message="yes"
2940 else
2941         setcap_message="no"
2942 fi
2943
2944 if test "x$enable_setuid_install" = "xyes" ; then
2945         setuid_message="yes"
2946 else
2947         setuid_message="no"
2948 fi
2949
2950 if test "x$DUMPCAP_GROUP" = "x" ; then
2951         dumpcap_group_message="(none)"
2952 else
2953         dumpcap_group_message="$DUMPCAP_GROUP"
2954 fi
2955
2956 if test "x$want_zlib" = "xno" ; then
2957         zlib_message="no"
2958 else
2959         zlib_message="yes"
2960 fi
2961
2962 if test "x$want_lua" = "xyes" ; then
2963         lua_message="yes"
2964 else
2965         lua_message="no"
2966 fi
2967
2968 if test "x$want_python" = "xno"; then
2969         python_message="no"
2970 else
2971         python_message="yes"
2972 fi
2973
2974 if test "x$want_portaudio" = "xyes" ; then
2975         portaudio_message="yes"
2976 else
2977         portaudio_message="no"
2978 fi
2979
2980 if test "x$want_ssl" = "xno" ; then
2981         ssl_message="no"
2982 else
2983         ssl_message="yes"
2984 fi
2985
2986 if test "x$want_krb5" = "xno" ; then
2987         krb5_message="no"
2988 else
2989         krb5_message="yes ($ac_krb5_version)"
2990 fi
2991
2992 if test "x$have_good_c_ares" = "xyes" ; then
2993         c_ares_message="yes"
2994 else
2995         c_ares_message="no"
2996 fi
2997
2998 if test "x$have_good_adns" = "xyes" ; then
2999         adns_message="yes"
3000 else
3001         if test "x$have_good_c_ares" = "xyes" ; then
3002                 adns_message="no (using c-ares instead)"
3003         else
3004                 adns_message="no"
3005         fi
3006 fi
3007
3008 if test "x$have_good_libcap" = "xyes" ; then
3009         libcap_message="yes"
3010 else
3011         libcap_message="no"
3012 fi
3013
3014 if test "x$have_good_geoip" = "xyes" ; then
3015         geoip_message="yes"
3016 else
3017         geoip_message="no"
3018 fi
3019
3020 echo ""
3021 echo "The Wireshark package has been configured with the following options."
3022 echo "             Build wireshark (Gtk+) : $have_gtk""$gtk_lib_message"
3023 echo "                 Build wireshark-qt : $enable_qtshark"
3024 echo "                       Build tshark : $enable_tshark"
3025 echo "                      Build tfshark : $enable_tfshark"
3026 echo "                     Build capinfos : $enable_capinfos"
3027 echo "                      Build captype : $enable_captype"
3028 echo "                      Build editcap : $enable_editcap"
3029 echo "                      Build dumpcap : $enable_dumpcap"
3030 echo "                     Build mergecap : $enable_mergecap"
3031 echo "                   Build reordercap : $enable_reordercap"
3032 echo "                    Build text2pcap : $enable_text2pcap"
3033 echo "                      Build randpkt : $enable_randpkt"
3034 echo "                       Build dftest : $enable_dftest"
3035 echo "                     Build rawshark : $enable_rawshark"
3036 echo "                        Build echld : $have_echld"
3037 echo ""
3038 echo "   Save files as pcap-ng by default : $enable_pcap_ng_default"
3039 echo "  Install dumpcap with capabilities : $setcap_message"
3040 echo "             Install dumpcap setuid : $setuid_message"
3041 echo "                  Use dumpcap group : $dumpcap_group_message"
3042 echo "                        Use plugins : $have_plugins"
3043 echo "                    Use Lua library : $lua_message"
3044 echo "                 Use Python binding : $python_message"
3045 echo "                   Build rtp_player : $portaudio_message"
3046 echo "             Build profile binaries : $enable_profile_build"
3047 echo "                   Use pcap library : $want_pcap"
3048 echo "                   Use zlib library : $zlib_message"
3049 echo "               Use kerberos library : $krb5_message"
3050 echo "                 Use c-ares library : $c_ares_message"
3051 echo "               Use GNU ADNS library : $adns_message"
3052 echo "                Use SMI MIB library : $libsmi_message"
3053 echo "             Use GNU crypto library : $gcrypt_message"
3054 echo "             Use SSL crypto library : $ssl_message"
3055 echo "           Use IPv6 name resolution : $enable_ipv6"
3056 echo "                 Use gnutls library : $tls_message"
3057 echo "     Use POSIX capabilities library : $libcap_message"
3058 echo "                  Use GeoIP library : $geoip_message"
3059 echo "                     Use nl library : $libnl_message"
3060 echo "              Use SBC codec library : $have_sbc"