configure.ac

   1 #
   2 # Autoconf script for Wireshark
   3 #
   4
   5 #
   6 # Define variables for the components of the Wireshark version number.
   7 #
   8 m4_define([version_major], [2])
   9 m4_define([version_minor], [1])
  10 m4_define([version_micro], [0])
  11 dnl Updated by make-version.pl
  12 m4_define([version_extra], [-git])
  13 m4_define([version_micro_extra], m4_join([], version_micro, version_extra))
  14
  15 AC_INIT(wireshark, [version_major.version_minor.version_micro_extra], http://bugs.wireshark.org/, , http://www.wireshark.org/)
  16 CONFIG_ARGS="$*"
  17 AC_SUBST(CONFIG_ARGS)
  18
  19 # Minimum autoconf version we require.
  20 AC_PREREQ(2.64)
  21 # Variable expansion doesn't work in AC_PREREQ()
  22 AC_MIN_VERSION=2.64
  23 AC_SUBST(AC_MIN_VERSION)
  24
  25 dnl Make sure to keep ACLOCAL_AMFLAGS in Makefile.am and AC_CONFIG_MACRO_DIRS
  26 dnl in configure.ac in sync, otherwise there will be an error running autogen.sh.
  27 m4_ifdef([AC_CONFIG_MACRO_DIRS],[AC_CONFIG_MACRO_DIRS([m4])])
  28
  29 dnl Check for CPU / vendor / OS
  30 dnl The user is encouraged to use either `AC_CANONICAL_BUILD', or
  31 dnl `AC_CANONICAL_HOST', or `AC_CANONICAL_TARGET', depending on the
  32 dnl needs.  Using `AC_CANONICAL_TARGET' is enough to run the two other
  33 dnl macros.
  34 dnl
  35 dnl As nothing in the Wireshark is itself a build tool (we are not,
  36 dnl for example, a compiler that generates machine code), we probably
  37 dnl don't need AC_CANONICAL_TARGET, so, in theory, we should be able
  38 dnl to use AC_CANONICAL_BUILD and AC_CANONICAL_HOST - or perhaps just
  39 dnl AC_CANONICAL_HOST - instead.  Note that we do have tools, such as
  40 dnl lemon, that need to be built for the build machine, not for the
  41 dnl host machine, so we might need both.
  42 dnl
  43 dnl This has to be done *after* AC_INIT, otherwise autogen.sh fails.
  44
  45 dnl AC_CANONICAL_BUILD
  46 dnl AC_CANONICAL_HOST
  47 AC_CANONICAL_TARGET
  48
  49 AM_INIT_AUTOMAKE([1.11 tar-ustar dist-bzip2 no-dist-gzip subdir-objects])
  50
  51 # Enable silent builds by default. Verbose builds can be enabled with "./configure
  52 # --enable-silent-rules ..." or "make V=1 ..."
  53 AM_SILENT_RULES([yes])
  54
  55 # Make Wireshark's version available in config.h
  56 AC_DEFINE(VERSION_MAJOR, version_major, [Wireshark's major version])
  57 AC_DEFINE(VERSION_MINOR, version_minor, [Wireshark's minor version])
  58 AC_DEFINE(VERSION_MICRO, version_micro, [Wireshark's micro version])
  59
  60 AC_DEFINE_UNQUOTED(VERSION_FLAVOR,
  61         ["${WIRESHARK_VERSION_FLAVOR:-"Development Build"}"], [Wireshark's package flavor])
  62
  63 LT_PREREQ([2.2.2])
  64 LT_INIT([disable-static dlopen])
  65 AC_SUBST([LIBTOOL_DEPS])
  66
  67 AC_CONFIG_LIBOBJ_DIR([wsutil])
  68
  69 #
  70 # Checks for programs used in the main build process.
  71 #
  72 AC_PROG_CC_STDC
  73 if test "$ac_cv_prog_cc_stdc" = "no"
  74 then
  75         AC_MSG_ERROR([The C compiler does not support standard C])
  76 fi
  77 AC_PROG_CPP
  78
  79 AC_PROG_CXX
  80 if test ! -z "$CXX"; then
  81         #
  82         # OK, we found something AC_LANG_CXX thinks is a C++ compiler,
  83         # but is it one?
  84         #
  85         # Some UN*Xes have, by default, a case-insensitive file
  86         # system, and AC_PROG_CXX looks for, among other things,
  87         # "CC" as a C++ compiler, and, if you have a case-insensitive
  88         # file system and a C compiler named "cc" (both true, by
  89         # default, on OS X), AC_PROG_CXX may end up thinking it's
  90         # the C++ compiler.
  91         #
  92         # So we check by feeding the purported C++ compiler a
  93         # program using C++ features (iostream).
  94         #
  95         AC_MSG_CHECKING(whether $CXX is a C++ compiler)
  96         AC_LANG_PUSH([C++])
  97         AC_LINK_IFELSE([AC_LANG_PROGRAM(
  98         [
  99 #include <iostream>
 100         ],
 101         [
 102         std::cout << "Hello World! ";
 103         return 0;
 104         ])],
 105                 [AC_MSG_RESULT(yes)],
 106                 [
 107                         AC_MSG_RESULT(no)
 108                         CXX=""
 109                 ])
 110         AC_LANG_POP([C++])
 111 fi
 112
 113 # Set CC_FOR_BUILD (the *local* gcc to use for building e.g. lemon)
 114 if test "x$cross_compiling" = xno -a -z "$CC_FOR_BUILD"; then
 115         CC_FOR_BUILD="$CC"
 116 fi
 117 AX_PROG_CC_FOR_BUILD
 118
 119 #
 120 # Check for versions of "sed" inadequate to handle, in libtool, a list
 121 # of object files as large as the list in Wireshark.
 122 #
 123 AC_PROG_SED
 124
 125 AC_PROG_LN_S
 126 AC_PROG_MKDIR_P
 127
 128 AC_PATH_PROG(PERL, perl)
 129
 130 # Check for Python.
 131 AC_PATH_PROGS(PYTHON, python python3)
 132 if test ! -z "$PYTHON"; then
 133         #
 134         # OK, we found Python; is it Python 2.5 or later?
 135         # Note: we don't use named components for sys.version_info to get
 136         # the major version number, as named components for version_info
 137         # were apparently introduced in Python 2.7.
 138         #
 139         AC_MSG_CHECKING([whether $PYTHON is Python 2.5 or later])
 140         python_major_version=`$PYTHON -c 'import sys; print (sys.version_info[[0]])'`
 141         python_minor_version=`$PYTHON -c 'import sys; print (sys.version_info[[1]])'`
 142         if test "$python_major_version" -eq 2 -a "$python_minor_version" -lt 5 ; then
 143                 AC_MSG_RESULT(no)
 144                 AC_MSG_WARN([Building with Python $python_major_version.$python_minor_version may not work])
 145         else
 146                 AC_MSG_RESULT(yes)
 147         fi
 148 else
 149         AC_MSG_ERROR(I couldn't find python; make sure it's installed and in your path)
 150 fi
 151
 152 #
 153 # XXX - should autogen.sh check for YACC/Bison and Flex?  A user building
 154 # from a distribution tarball shouldn't have to have YACC/Bison or Flex,
 155 # as the tarball should contain the results of running YACC/Bison on .y
 156 # files and running Flex on .l files, but a user building from SVN
 157 # will have to run YACC/Bison and Flex to process those files.
 158 #
 159 # On the other hand, what about users who use a distribution tarball to
 160 # do development?  They *shouldn't* - that's what the SVN repository is
 161 # for - but they might.  They'd get errors if they modify a .y or .l
 162 # file and try to do a build - but the error should tell them that they
 163 # need to get YACC/Bison and/or Flex.
 164 #
 165 # Then again, getting them shouldn't be too big of a burden.
 166 #
 167 # XXX - is the same true of pod2man and pod2html, or are they needed
 168 # even when building from a distribution tarball?
 169 #
 170 #
 171 AC_PROG_YACC
 172 AC_PATH_PROG(YACCDUMMY, $YACC)
 173 if test "x$YACCDUMMY" = x
 174 then
 175         AC_MSG_ERROR(I couldn't find yacc (or bison or ...); make sure it's installed and in your path)
 176 fi
 177 AM_PROG_LEX
 178 AC_PATH_PROG(LEX, flex)
 179 if test "x$LEX" = x
 180 then
 181         AC_MSG_ERROR(I couldn't find flex; make sure it's installed and in your path)
 182 fi
 183 AC_PATH_PROG(POD2MAN, pod2man)
 184 if test "x$POD2MAN" = x
 185 then
 186         #
 187         # The alternative is not to build the man pages....
 188         #
 189         AC_MSG_ERROR(I couldn't find pod2man; make sure it's installed and in your path)
 190 fi
 191 AC_PATH_PROG(POD2HTML, pod2html)
 192 if test "x$POD2HTML" = x
 193 then
 194         #
 195         # The alternative is not to build the HTML man pages....
 196         #
 197         AC_MSG_ERROR(I couldn't find pod2html; make sure it's installed and in your path)
 198 fi
 199
 200 #
 201 # Set "ac_supports_gcc_flags" if the compiler is known to support GCC-style
 202 # flags such as -pedantic, -W warning flags and -f feature flags.  Currently,
 203 # we assume GCC and clang do; other compilers should be added here.
 204 #
 205 # This is done to avoid getting tripped up by compilers that support
 206 # those flags but give them a different meaning.
 207 #
 208 if test "x$GCC" = "xyes" -o "x$CC" = "xclang" ; then
 209         ac_supports_gcc_flags=yes
 210 fi
 211
 212 # Check for doxygen
 213 AC_PATH_PROG(DOXYGEN, doxygen)
 214 AC_CHECK_PROG(HAVE_DOXYGEN, doxygen, "yes", "no")
 215 AM_CONDITIONAL(HAVE_DOXYGEN, test x$HAVE_DOXYGEN = xyes)
 216
 217 #
 218 # Check for pkg-config and set PKG_CONFIG accordingly.
 219 #
 220 # This is referenced via AC_REQUIRE([PKG_PROG_PKG_CONFIG] in some macros
 221 # like PKG_CHECK_MODULES. If the first call to such a macro is under an
 222 # "if" statement, it's safer to call PKG_PROG_PKG_CONFIG directly, see
 223 # the comments in acolocal.m4
 224 #
 225 # We want version 0.7 or better.  (XXX - explain why. Is that just
 226 # because our Qt tests were originally based on AM_PATH_GTK, and *it*
 227 # requires 0.7 or better?)
 228 #
 229 PKG_PROG_PKG_CONFIG(0.7)
 230 if test -z "$PKG_CONFIG"; then
 231         AC_MSG_ERROR(I couldn't find pkg-config; make sure it's installed and in your path)
 232 fi
 233
 234 AC_ARG_ENABLE(osx-deploy-target,
 235   AC_HELP_STRING( [--enable-osx-deploy-target],
 236     [choose an OS X deployment target @<:@default=major release on which you're building@:>@]),
 237 [
 238         #
 239         # Is this OS X?
 240         #
 241         case "$host_os" in
 242         darwin*)
 243                 #
 244                 # Yes.
 245                 #
 246                 # Let the user specify an OS X release to use as a
 247                 # deplayment target; if they specify that we should
 248                 # have a deployment target but don't specify the
 249                 # deployment target, then, if we have SDKs available,
 250                 # pick the OS version on which the build is being done.
 251                 # This also causes the build to be done against an SDK
 252                 # rather than against the headers and libraries in
 253                 # /usr/include and /usr/lib.
 254                 #
 255                 # Check for an OS X deployment target early, so that
 256                 # as many tests using the compiler are done using the
 257                 # flags that we'll be using when building.
 258                 #
 259                 if test $enableval = no
 260                 then
 261                         #
 262                         # The user explicitly said
 263                         # --disable-osx-deploy-target, so don't build
 264                         # against an SDK.
 265                         #
 266                         deploy_target=
 267                 elif test $enableval = yes
 268                 then
 269                         #
 270                         # The user said --enable-osx-deploy-target, but
 271                         # didn't say what version to target; target the
 272                         # major version number of the version of OS X on
 273                         # which we're running.
 274                         #
 275                         # (We quote the command so that we can use
 276                         # autoconf's M4 quoting characters, [ and ], in
 277                         # the sed expression.)
 278                         #
 279                         [deploy_target=`sw_vers -productVersion | sed 's/\([0-9][0-9]*\)\.\([0-9][0-9]*\)\.[0-9]*/\1.\2/'`]
 280                 else
 281                         deploy_target="$enableval"
 282                 fi
 283                 ;;
 284
 285         *)
 286                 #
 287                 # No.  Fail, because whatever the user intended for us to
 288                 # do, we can't do it.
 289                 #
 290                 AC_MSG_ERROR([--enable-osx-deploy-target specified on an OS other than OS X])
 291                 ;;
 292         esac
 293 ],[
 294         #
 295         # Is this OS X?
 296         #
 297         case "$host_os" in
 298         darwin*)
 299                 #
 300                 # Yes.
 301                 #
 302                 # If we have SDKs available, default to targeting the major
 303                 # version number of the version of OS X on which we're
 304                 # running.
 305                 #
 306                 # (We quote the command so that we can use autoconf's
 307                 # M4 quoting characters, [ and ], in the sed expression.)
 308                 #
 309                 for i in /Developer/SDKs \
 310                     /Applications/Xcode.app/Contents/Developer/Platforms/MacOSX.platform/Developer/SDKs \
 311                     /Library/Developer/CommandLineTools/SDKs
 312                 do
 313                         if test -d "$i"
 314                         then
 315                                 [deploy_target=`sw_vers -productVersion | sed 's/\([0-9][0-9]*\)\.\([0-9][0-9]*\)\.[0-9]*/\1.\2/'`]
 316                                 break
 317                         fi
 318                 done
 319                 ;;
 320
 321         *)
 322                 #
 323                 # No.  There's nothing to do.
 324                 #
 325                 ;;
 326         esac
 327 ])
 328
 329 if test ! -z "$deploy_target"
 330 then
 331         AC_MSG_CHECKING([whether we can build for OS X $deploy_target])
 332         case $deploy_target in
 333
 334         10.0|10.1|10.2)
 335                 #
 336                 # I'm not sure this would even work.
 337                 #
 338                 AC_MSG_RESULT(no)
 339                 AC_MSG_ERROR([We don't support building for OS X $deploy_target])
 340                 ;;
 341
 342         10.3)
 343                 #
 344                 # XXX - never tested.
 345                 #
 346                 AC_MSG_RESULT(yes)
 347                 SDKPATH="/Developer/SDKs/MacOSX10.3.9.sdk"
 348                 ;;
 349
 350         *)
 351                 #
 352                 # Look for the oldest SDK we can find that's
 353                 # for an OS equal to or later than this one.
 354                 #
 355                 # XXX - for 10.4, do we need 10.4u?  We're
 356                 # not currently doing fat builds (we'd need
 357                 # fat versions of the support libraries for
 358                 # that to be useful), but, if we do, we'd
 359                 # need to use 10.4u.
 360                 #
 361
 362                 #
 363                 # Get the real version - strip off the "10.".
 364                 # We'll worry about that if, as, and when there's ever
 365                 # an OS XI.
 366                 #
 367                 deploy_real_version=`echo "$deploy_target" | sed -n 's/10\.\(.*\)/\1/p'`
 368
 369                 #
 370                 # Search each directory that might contain SDKs.
 371                 #
 372                 sdkpath=""
 373                 for sdksdir in /Developer/SDKs \
 374                     /Applications/Xcode.app/Contents/Developer/Platforms/MacOSX.platform/Developer/SDKs \
 375                     /Library/Developer/CommandLineTools/SDKs
 376                 do
 377                         #
 378                         # Get a list of all the SDKs.
 379                         #
 380                         if ! test -d "$sdksdir"
 381                         then
 382                                 #
 383                                 # There is no directory with that name.
 384                                 # Move on to the next one in the list,
 385                                 # if any.
 386                                 #
 387                                 continue
 388                         fi
 389
 390                         #
 391                         # Get a list of all the SDKs in that directory,
 392                         # if any.
 393                         #
 394                         # We have to use @<:@ for [ and @:>@ for ] to
 395                         # avoid m4 removing the square brackets.
 396                         #
 397                         sdklist=`(cd "$sdksdir"; ls -d MacOSX10.@<:@0-9@:>@*.sdk 2>/dev/null)`
 398
 399                         for sdk in $sdklist
 400                         do
 401                                 #
 402                                 # Get the real version for this SDK.
 403                                 #
 404                                 sdk_real_version=`echo "$sdk" | sed -n 's/MacOSX10\.\(.*\)\.sdk/\1/p'`
 405
 406                                 #
 407                                 # Is it for the deployment target or
 408                                 # some later release?
 409                                 #
 410                                 if test "$sdk_real_version" -ge "$deploy_real_version"
 411                                 then
 412                                         #
 413                                         # Yes, use it.
 414                                         #
 415                                         sdkpath="$sdksdir/$sdk"
 416                                         break 2
 417                                 fi
 418                         done
 419                 done
 420                 if test -z "$sdkpath"
 421                 then
 422                         AC_MSG_RESULT(no)
 423                         AC_MSG_ERROR([We couldn't find an SDK for OS X $deploy_target or later])
 424                 fi
 425                 SDKPATH="$sdkpath"
 426                 AC_MSG_RESULT([yes, with the 10.$sdk_real_version SDK])
 427                 ;;
 428         esac
 429
 430         #
 431         # Add a -mmacosx-version-min flag to force tests that
 432         # use the compiler, as well as the build itself, not to,
 433         # for example, use compiler or linker features not supported
 434         # by the minimum targeted version of the OS.
 435         #
 436         # Add an -isysroot flag to use the SDK.
 437         #
 438         WS_CFLAGS="-mmacosx-version-min=$deploy_target -isysroot $SDKPATH $WS_CFLAGS"
 439         WS_CXXFLAGS="-mmacosx-version-min=$deploy_target -isysroot $SDKPATH $WS_CXXFLAGS"
 440         WS_LDFLAGS="-mmacosx-version-min=$deploy_target -isysroot $SDKPATH $WS_LDFLAGS"
 441
 442         #
 443         # Add a -sdkroot flag to use with osx-app.sh.
 444         #
 445         OSX_APP_FLAGS="-sdkroot $SDKPATH"
 446
 447         #
 448         # XXX - do we need this to build the Wireshark wrapper?
 449         # XXX - is this still necessary with the -mmacosx-version-min
 450         # flag being set?
 451         #
 452         OSX_DEPLOY_TARGET="MACOSX_DEPLOYMENT_TARGET=$deploy_target"
 453
 454         #
 455         # In the installer package XML file, give the deployment target
 456         # as the minimum version.
 457         #
 458         OSX_MIN_VERSION="$deploy_target"
 459
 460         case $deploy_target in
 461
 462         10.4|10.5)
 463                 #
 464                 # Only 32-bit builds are supported.  10.5
 465                 # (and 10.4?) had a bug that causes some BPF
 466                 # functions not to work with 64-bit userland
 467                 # code, so capturing won't work.
 468                 #
 469                 WS_CFLAGS="-m32 $WS_CFLAGS"
 470                 WS_CXXFLAGS="-m32 $WS_CXXFLAGS"
 471                 WS_LDFLAGS="-m32 $WS_LDFLAGS"
 472                 ;;
 473         esac
 474 else
 475         #
 476         # Is this OS X?
 477         #
 478         case "$host_os" in
 479         darwin*)
 480                 #
 481                 # Yes.
 482                 #
 483                 # In the installer package XML file, give the current OS
 484                 # version, minor version and all, as the minimum version.
 485                 # We can't guarantee that the resulting binary will work
 486                 # on older OS versions, not even older minor versions
 487                 # (original release or earlier software updates).
 488                 #
 489                 OSX_MIN_VERSION=`sw_vers -productVersion`
 490                 ;;
 491         esac
 492 fi
 493 AC_SUBST(OSX_MIN_VERSION)
 494
 495 #
 496 # Try to arrange for large file support.
 497 #
 498 AC_SYS_LARGEFILE
 499
 500 #
 501 # Check if we need to link with libm
 502 #
 503 AC_SEARCH_LIBS([cos], [m])
 504
 505 #
 506 # Check for C99 math functions.
 507 #
 508 AC_CHECK_FUNCS([floorl lrint])
 509
 510 #
 511 # Check if we need to link with -lnsl and -lsocket
 512 #
 513 AX_LIB_SOCKET_NSL
 514
 515 #
 516 # GUI toolkit options
 517 #
 518 AC_ARG_WITH([qt],
 519   AC_HELP_STRING( [--with-qt=@<:@yes/no/4/5@:>@],
 520                   [use Qt @<:@default=yes, if available@:>@]),
 521   with_qt="$withval", with_qt="unspecified")
 522
 523 AC_ARG_WITH([gtk],
 524   AC_HELP_STRING( [--with-gtk=@<:@yes/no/2/3@:>@],
 525         [use GTK+ @<:@default=yes, if available@:>@]),
 526         AS_CASE([$withval],
 527           [yes], [with_gtk="3 2 fail"],
 528           [no],  [with_gtk="no"],
 529           [3],   [with_gtk="3 fail3"],
 530           [2],   [with_gtk="2 fail2"],
 531           [AC_MSG_ERROR([--with-gtk must be one of yes/no/2/3])]),
 532         with_gtk="3 2")
 533
 534 # GnuTLS
 535 # Version 3.0 switched from LGPLv2.1+ to LGPLv3+, then switched back to
 536 # LGPLv2.1+ in version 3.1.10.
 537 # GnuTLS depends on GMP which switched from LGPLv2.1+ to LGPLv3+ in
 538 # version 4.2.2, the switched to LGPLv3+ / GPLv2+ in version 6.0.0.
 539
 540 tls_message="no"
 541 want_gnutls="if_available"
 542 AC_ARG_WITH([gnutls],
 543   AC_HELP_STRING( [--with-gnutls=@<:@yes/no@:>@],
 544                   [use GnuTLS library @<:@default=yes, if available@:>@]),
 545   [ with_gnutls="$withval"; want_gnutls="yes" ], with_gnutls="yes")
 546
 547 if test "x$with_gnutls" = "xyes"; then
 548   have_license_compatible_gnutls="no"
 549   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 3.1.10 ],
 550     [ have_license_compatible_gnutls="yes" ], [ echo "GnuTLS >= 3.1.10 not found " ]
 551   )
 552
 553   if test "x$have_license_compatible_gnutls" != "xyes"; then
 554     PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.12.0 gnutls < 3],
 555       [ have_license_compatible_gnutls="yes" ] , [ echo "GnuTLS >= 2.12.0, < 3.0 not found " ]
 556     )
 557   fi
 558
 559   if test "x$have_license_compatible_gnutls" != "xyes"; then
 560     if test "x$want_gnutls" = "xyes"; then
 561       AC_MSG_ERROR([GnuTLS crypto library was requested, but is not available])
 562     else
 563       AS_ECHO(["GnuTLS with compatible license not found, disabling SSL decryption"])
 564     fi
 565   else
 566     AC_DEFINE(HAVE_LIBGNUTLS, 1, [Define to use GnuTLS library])
 567     tls_message="yes"
 568   fi
 569 fi
 570
 571 # libgrypt
 572 gcrypt_message="no"
 573 want_gcrypt="if_available"
 574 AC_ARG_WITH([gcrypt],
 575   AC_HELP_STRING( [--with-gcrypt=@<:@yes/no@:>@],
 576                   [use gcrypt library @<:@default=yes, if available@:>@]),
 577   [ with_gcrypt="$withval"; want_gcrypt="yes" ], with_gcrypt="yes")
 578
 579 if test "x$with_gcrypt" = "xyes"; then
 580   AM_PATH_LIBGCRYPT(1.4.2,
 581         [
 582                 AC_DEFINE(HAVE_LIBGCRYPT, 1, [Define to use libgcrypt])
 583                 gcrypt_message="yes"
 584         ]
 585         , [
 586                 if test x$libgcrypt_config_prefix != x ; then
 587                         AC_MSG_ERROR([[libgcrypt not found; install libgcrypt-devel package for your system]])
 588                 else
 589                         AS_ECHO(["libgcrypt not found, disabling decryption for ipsec, ssl, etc."])
 590                         gcrypt_message="no"
 591                 fi
 592
 593                 # Error out if the user explicitly requested gcrypt
 594                 if test "x$want_gcrypt" = "xyes"; then
 595                     AC_MSG_ERROR([libgcrypt library was requested, but is not available])
 596                 fi
 597         ]
 598   )
 599 fi
 600
 601 AC_ARG_WITH(libnl,
 602   AC_HELP_STRING([--with-libnl@<:@=VERSION@:>@],
 603                  [use libnl (force version VERSION, if supplied) @<:@default: yes, if available@:>@]),
 604 [
 605         if test "x$withval" = "xno"
 606         then
 607                 want_libnl=no
 608         elif test "x$withval" = "xyes"
 609         then
 610                 want_libnl=yes
 611                 libnl_version=any
 612         elif test "x$withval" = "x1"
 613         then
 614                 want_libnl=yes
 615                 libnl_version=1
 616         elif test "x$withval" = "x2"
 617         then
 618                 want_libnl=yes
 619                 libnl_version=2
 620         elif test "x$withval" = "x3"
 621         then
 622                 want_libnl=yes
 623                 libnl_version=3
 624         else
 625                 AC_MSG_ERROR(["$withval" is not a valid argument to --with-libnl])
 626         fi
 627 ],[
 628         #
 629         # Use libnl if it's present, otherwise don't.
 630         #
 631         want_libnl=ifavailable
 632         libnl_version=any
 633 ])
 634 #
 635 # Libnl is Linux-specific.
 636 #
 637 libnl_message="no"
 638 case "$host_os" in
 639 linux*)
 640         AC_MSG_CHECKING(whether to use libnl for various network interface purposes)
 641
 642         if test x$want_libnl = "xno"; then
 643                 AC_MSG_RESULT(no)
 644         else
 645                 AC_MSG_RESULT(yes)
 646                 #
 647                 # Test for specific libnl versions only if no version
 648                 # was specified by the user or if the version in question
 649                 # was requested by the user.
 650                 #
 651                 if test x$libnl_version = "xany" -o x$libnl_version = "x3"; then
 652                         PKG_CHECK_EXISTS([libnl-3.0 libnl-route-3.0 libnl-genl-3.0], [have_libnl3=yes], [have_libnl3=no])
 653                 fi
 654                 if test x$libnl_version = "xany" -o x$libnl_version = "x2"; then
 655                         PKG_CHECK_EXISTS([libnl-2.0], [have_libnl2=yes], [have_libnl2=no])
 656                 fi
 657                 if test x$libnl_version = "xany" -o x$libnl_version = "x1"; then
 658                         PKG_CHECK_EXISTS([libnl-1], [have_libnl1=yes], [have_libnl1=no])
 659                 fi
 660                 if (test "${have_libnl3}" = "yes"); then
 661                         PKG_WIRESHARK_CHECK_SYSTEM_MODULES([LIBNL], [libnl-3.0 libnl-route-3.0 libnl-genl-3.0])
 662                         AC_DEFINE(HAVE_LIBNL, 1, [Enable libnl support])
 663                         AC_DEFINE(HAVE_LIBNL3, 1, [libnl version 3])
 664                         libnl_message="yes (v3)"
 665                 elif (test "${have_libnl2}" = "yes"); then
 666                         PKG_WIRESHARK_CHECK_SYSTEM_MODULES([LIBNL], [libnl-2.0])
 667                         AC_DEFINE(HAVE_LIBNL, 1, [Enable libnl support])
 668                         AC_DEFINE(HAVE_LIBNL2, 1, [libnl version 2])
 669                         libnl_message="yes (v2)"
 670                 elif (test "${have_libnl1}" = "yes"); then
 671                         PKG_WIRESHARK_CHECK_SYSTEM_MODULES([LIBNL], [libnl-1])
 672                         AC_DEFINE(HAVE_LIBNL, 1, [Enable libnl support])
 673                         AC_DEFINE(HAVE_LIBNL1, 1, [libnl version 1])
 674                         libnl_message="yes (v1)"
 675                 else
 676                         if test x$want_libnl = "xyes"; then
 677                                 case "$libnl_version" in
 678
 679                                 any)
 680                                         AC_MSG_ERROR("I couldn't find libnl even though you manually enabled it.")
 681                                         ;;
 682
 683                                 *)
 684                                         AC_MSG_ERROR("I couldn't find libnl version $libnl_version even though you manually enabled it.")
 685                                         ;;
 686                                 esac
 687                         fi
 688                 fi
 689         fi
 690
 691         AC_MSG_CHECKING([if nl80211.h is new enough])
 692           AC_TRY_COMPILE([#include <linux/nl80211.h>],
 693             [int x = NL80211_FREQUENCY_ATTR_MAX_TX_POWER;
 694              x |= NL80211_ATTR_SUPPORTED_IFTYPES;
 695              x |= NL80211_ATTR_SUPPORTED_COMMANDS;
 696              x |= NL80211_ATTR_WIPHY_FREQ;
 697              x |= NL80211_CHAN_NO_HT;
 698              (void)x;],
 699             [AC_MSG_RESULT(yes) AC_DEFINE(HAVE_NL80211, 1, [nl80211.h is new enough])],
 700             [AC_MSG_RESULT(no)])
 701
 702         AC_MSG_CHECKING([for NL80211_SET_CHANNEL])
 703           AC_TRY_COMPILE([#include <linux/nl80211.h>],
 704             [enum nl80211_commands x = NL80211_CMD_SET_CHANNEL;],
 705             [AC_MSG_RESULT(yes) AC_DEFINE(HAVE_NL80211_CMD_SET_CHANNEL, 1, [SET_CHANNEL is supported])],
 706             [AC_MSG_RESULT(no)])
 707
 708         AC_MSG_CHECKING([for NL80211_SPLIT_WIPHY_DUMP])
 709           AC_TRY_COMPILE([#include <linux/nl80211.h>],
 710             [enum nl80211_protocol_features x = NL80211_PROTOCOL_FEATURE_SPLIT_WIPHY_DUMP;],
 711             [AC_MSG_RESULT(yes) AC_DEFINE(HAVE_NL80211_SPLIT_WIPHY_DUMP, 1, [SPLIT_WIPHY_DUMP is supported])],
 712             [AC_MSG_RESULT(no)])
 713
 714         AC_MSG_CHECKING([for NL80211_VHT_CAPABILITY])
 715           AC_TRY_COMPILE([#include <linux/nl80211.h>],
 716             [enum nl80211_attrs x = NL80211_ATTR_VHT_CAPABILITY;],
 717             [AC_MSG_RESULT(yes) AC_DEFINE(HAVE_NL80211_VHT_CAPABILITY, 1, [VHT_CAPABILITY is supported])],
 718             [AC_MSG_RESULT(no)])
 719         ;;
 720
 721 *)
 722         if test x$want_libnl != "xno" -a x$want_libnl != "xifavailable"; then
 723                 AC_MSG_WARN([libnl is Linux-specific, ignoring --with-libnl])
 724         fi
 725 esac
 726
 727 # libsmi
 728 # FIXME: currently the path argument to with-libsmi is being ignored
 729 AX_LIBSMI
 730
 731 #
 732 # Check for programs used when building DocBook documentation.
 733 #
 734 AC_CHECK_PROGS(XSLTPROC, xsltproc, xsltproc)
 735 AC_CHECK_PROGS(A2X, a2x, a2x)
 736 AC_CHECK_PROGS(FOP, fop, fop)
 737
 738 # HTML to text processor
 739 AC_MSG_CHECKING([for an HTML to text processor])
 740 AS_IF([w3m -version >&AS_MESSAGE_LOG_FD 2>&1], [have_a2x_text=w3m],
 741         [lynx -version >&AS_MESSAGE_LOG_FD 2>&1], [have_a2x_text=lynx],
 742         [have_a2x_text=no])
 743 AC_MSG_RESULT([$have_a2x_text])
 744 AM_CONDITIONAL(HAVE_A2X_TEXT, [test "x$have_a2x_text" != xno])
 745 AS_IF([test $have_a2x_text = lynx], [A2X_LYNX="--lynx"])
 746 AC_SUBST(A2X_LYNX)
 747
 748 # Check for packaging utilities
 749 # For now, we check to see if the various packaging utilites are in our
 750 # path.  I'm too lazy to write code to go hunt for them.  -  Gerald
 751
 752 #
 753 # Source packages.
 754 # (Lets you install the desktop files.)
 755 #
 756 AC_PATH_PROG(DESKTOP_FILE_INSTALL, desktop-file-install)
 757
 758 # SVR4/Solaris
 759 AC_CHECK_PROG(HAVE_PKGPROTO, pkgproto, "yes", "no")
 760 AC_CHECK_PROG(HAVE_PKGMK, pkgmk, "yes", "no")
 761 AC_CHECK_PROG(HAVE_PKGTRANS, pkgtrans, "yes", "no")
 762
 763 if test x$HAVE_PKGPROTO = xyes -a x$HAVE_PKGMK = xyes \
 764      -a x$HAVE_PKGTRANS = xyes ; then
 765   HAVE_SVR4_PACKAGING=yes
 766 else
 767   HAVE_SVR4_PACKAGING=no
 768 fi
 769 AC_SUBST(HAVE_SVR4_PACKAGING)
 770
 771 # RPM
 772 #
 773 # Looks for the rpmbuild program, and checks to see if we can redefine "_topdir".
 774 #
 775 AC_CHECK_PROGS(RPMBUILD, [rpmbuild], [false])
 776 if test "x$RPMBUILD" != "xfalse" ; then
 777         AC_MSG_CHECKING([to see if we can redefine _topdir])
 778         rpm --define '_topdir /tmp' > /dev/null 2>&1
 779         if test $? -eq 0 ; then
 780                 AC_MSG_RESULT(yes)
 781                 have_rpm=yes
 782         else
 783                 AC_MSG_RESULT([no, you'll have to build packages manually])
 784                 have_rpm=no
 785         fi
 786 fi
 787 AM_CONDITIONAL(HAVE_RPM, [test "x$have_rpm" = xyes])
 788
 789 # Debian
 790 AC_CHECK_PROG(HAVE_DPKG_BUILDPACKAGE, dpkg-buildpackage, "yes", "no")
 791
 792 # OS X
 793 AC_CHECK_PROG(HAVE_XCODEBUILD, xcodebuild, "yes", "no")
 794 AC_CHECK_PROG(HAVE_HDIUTIL, hdiutil, "yes", "no")
 795 AC_CHECK_PROG(HAVE_BLESS, bless, "yes", "no")
 796
 797 if test x$HAVE_XCODEBUILD = xyes -a x$HAVE_HDIUTIL = xyes \
 798      -a x$HAVE_BLESS = xyes ; then
 799   HAVE_OSX_PACKAGING=yes
 800 else
 801   HAVE_OSX_PACKAGING=no
 802 fi
 803 AC_SUBST(HAVE_OSX_PACKAGING)
 804
 805 #
 806 # Use this as a proxy for "is this OS X" (just in case somebody actually
 807 # built and installed Darwin as an OS, perhaps with some X11-based GUI,
 808 # don't look for Darwin).
 809 #
 810 AC_CHECK_PROG(have_sw_vers, sw_vers, "yes", "no")
 811 AM_CONDITIONAL(NOT_OS_X, test "x$have_sw_vers" = "xno")
 812
 813 #
 814 # Check compiler vendor. For GCC this will be 'gnu' and for Clang 'clang'.
 815 #
 816 AX_COMPILER_VENDOR
 817 if test "x$CXX" != "x" ; then
 818         AC_LANG_PUSH(C++)
 819         AX_COMPILER_VENDOR
 820         AC_LANG_POP
 821 fi
 822
 823 #
 824 # Some compilers have to be told to fail when passed an unknown -W flag;
 825 # make sure we do that.
 826 #
 827 AC_WIRESHARK_CHECK_UNKNOWN_WARNING_OPTION_ERROR
 828
 829 #
 830 # Some C++ compilers have to be told to fail when passed a -W flag that
 831 # they don't think should apply to C++; make sure we do that.
 832 #
 833 AC_WIRESHARK_CHECK_NON_CXX_WARNING_OPTION_ERROR
 834
 835 #
 836 # The following are for C and C++
 837 #
 838 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wall)
 839 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wextra)
 840 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wendif-labels)
 841 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wpointer-arith)
 842 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wformat-security)
 843 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-fwrapv)
 844 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-fno-strict-overflow)
 845 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-fno-delete-null-pointer-checks)
 846 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wvla)
 847 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Waddress)
 848 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wattributes)
 849 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wdiv-by-zero)
 850 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wignored-qualifiers)
 851 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wpragmas)
 852 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wno-overlength-strings)
 853 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wno-long-long)
 854 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wheader-guard)
 855 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wunused-const-variable)
 856 #
 857 # The following are C only, not C++
 858 #
 859 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wc++-compat, C)
 860 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wdeclaration-after-statement, C)
 861
 862 #
 863 # XXX - OK for C++?
 864 #
 865 # Make sure -Wshadow doesn't complain about variables in function and
 866 # function pointer declarations shadowing other variables; if not, don't
 867 # turn it on, as some versions of GCC (including the one in at least
 868 # some Xcode versions that came with Mac OS X 10.5) complain about
 869 # that.
 870 #
 871 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wshadow, C,
 872   [
 873 extern int bar(int a);
 874 extern int foo(int);
 875
 876 int
 877 foo(int a)
 878 {
 879         int (*fptr)(int a) = bar;
 880
 881         return fptr(a) * 2;
 882 }
 883   ],
 884   [warns about variables in function declarations shadowing other variables])
 885
 886 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wno-pointer-sign, C)
 887 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wold-style-definition, C)
 888 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wstrict-prototypes, C)
 889
 890 # Unfortunately some versions of gcc generate logical-op warnings when strchr()
 891 # is given a constant string.
 892 # gcc versions 4.3.2 and 4.4.5 are known to have the problem.
 893 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wlogical-op, C,
 894   [
 895 #include <string.h>
 896
 897 int foo(const char *, int);
 898 int bar(void);
 899
 900 int
 901 foo(const char *sep, int c)
 902 {
 903         if (strchr (sep, c) != NULL)
 904                 return 1;
 905         else
 906                 return 0;
 907 }
 908
 909 int
 910 bar(void)
 911 {
 912         return foo("<", 'a');
 913 }
 914   ],
 915   [generates warnings from strchr()])
 916
 917 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wjump-misses-init, C)
 918 # The Qt headers generate a ton of shortening errors on 64-bit systems
 919 # so only enable this for C for now.
 920 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wshorten-64-to-32, C)
 921
 922 # Clang only. Avoid "argument unused during compilation" warnings
 923 # (for example, when getting the -gsplit-dwarf option or
 924 # when combining -fwrapv with -fno-strict-overflow)
 925 if test x"$ax_cv_c_compiler_vendor" = xclang; then
 926         AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Qunused-arguments, C)
 927 fi
 928 if test x"$ax_cv_cxx_compiler_vendor" = xclang; then
 929         AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Qunused-arguments, CXX)
 930 fi
 931
 932 #
 933 # Use the faster pre gcc 4.5 floating point precision if available.
 934 #
 935 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-fexcess-precision=fast)
 936
 937 #
 938 # Try to have the compiler default to hiding symbols, so that only
 939 # symbols explicitly exported with WS_DLL_PUBLIC will be visible
 940 # outside (shared) libraries; that way, more UN*X builds will catch
 941 # failures to export symbols, rather than having that fail only on
 942 # Windows.
 943 #
 944 # GCC and GCC-compatible compilers
 945 #
 946 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-fvisibility=hidden)
 947 if test "x$can_add_to_cflags" = "xno"
 948 then
 949         #
 950         # Sun^WOracle C.
 951         #
 952         AC_WIRESHARK_COMPILER_FLAGS_CHECK(-xldscope=hidden)
 953         if test "x$can_add_to_cflags" = "xno"
 954         then
 955                 # TODO add other ways of hiding symbols
 956                 AC_MSG_WARN(Compiler will export all symbols from shared libraries)
 957         fi
 958 fi
 959
 960 #
 961 # Try to add some additional checks to CFLAGS.
 962 # These are not enabled by default, because the warnings they produce
 963 # are very hard or impossible to eliminate.
 964 #
 965 AC_ARG_ENABLE(extra-compiler-warnings,
 966   AC_HELP_STRING( [--enable-extra-compiler-warnings],
 967                   [do additional compiler warnings @<:@default=no@:>@]),
 968 [
 969         wireshark_extra_flags=$enableval
 970         if test $enableval != no
 971         then
 972                 #
 973                 # The following are for C and C++
 974                 #
 975                 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wpedantic)
 976                 #
 977                 # As we use variadic macros, we don't want warnings
 978                 # about them, even with -Wpedantic.
 979                 #
 980                 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wno-variadic-macros)
 981                 #
 982                 # Various code blocks this one.
 983                 #
 984                 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Woverflow)
 985                 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-fstrict-overflow -Wstrict-overflow=4)
 986                 #
 987                 # Due to various places where APIs we don't control
 988                 # require us to cast away constness, we can probably
 989                 # never enable this one with -Werror.
 990                 #
 991                 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wcast-qual)
 992                 #
 993                 # Some generated ASN.1 dissectors block this one;
 994                 # multiple function declarations for the same
 995                 # function are being generated.
 996                 #
 997                 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wredundant-decls)
 998                 #
 999                 # Some loops are safe, but it's hard to convince the
1000                 # compiler of that.
1001                 #
1002                 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wunsafe-loop-optimizations)
1003                 #
1004                 # All the registration functions block these for now.
1005                 #
1006                 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wmissing-prototypes)
1007                 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wmissing-declarations)
1008                 #
1009                 # A bunch of "that might not work on SPARC" code blocks
1010                 # this one for now.
1011                 #
1012                 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wcast-align)
1013                 #
1014                 # Works only with Clang
1015                 #
1016                 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wunreachable-code)
1017                 #
1018                 # Works only with Clang but generates a lot of warnings
1019                 # (about glib library not using Doxygen)
1020                 #
1021                 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wdocumentation)
1022
1023                 #
1024                 # The following are C only, not C++
1025                 #
1026                 # Due to various places where APIs we don't control
1027                 # require us to cast away constness, we can probably
1028                 # never enable this one with -Werror.
1029                 #
1030                 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wbad-function-cast, C)
1031         fi
1032 ])
1033
1034 # Try to add ASAN address analyze.
1035 # Only needed for analyse
1036 #
1037 AC_ARG_ENABLE(asan,
1038   AC_HELP_STRING( [--enable-asan],
1039                   [Enable AddressSanitizer (ASAN) for debugging (degrades performance)@<:@default=no@:>@]),
1040 [
1041         #
1042         # With Clang >= 3.5 Leak detection is enable by default
1043         # and no yet all leak is fixed...
1044         # use ASAN_OPTIONS=detect_leaks=0 to disable detect_leaks
1045         #
1046         # XXX shouldn't this also be added to LDFLAGS?
1047         AC_WIRESHARK_COMPILER_FLAGS_CHECK(-fsanitize=address)
1048
1049 ])
1050
1051 # Add check hf conflict..
1052 #
1053 AC_ARG_ENABLE(checkhf-conflict,
1054   AC_HELP_STRING( [--enable-checkhf-conflict],
1055                   [Enable hf conflict check for debugging (start-up may be slower)@<:@default=no@:>@]),
1056 [
1057         AC_DEFINE(ENABLE_CHECK_FILTER, 1, [Enable hf conflict check])
1058 ])
1059
1060 AC_WIRESHARK_LDFLAGS_CHECK([-Wl,--as-needed])
1061 ###AC_WIRESHARK_LDFLAGS_CHECK([-Wl,-M])
1062 ###AC_WIRESHARK_LDFLAGS_CHECK([-Wl,--cref])
1063 # AC_WIRESHARK_LDFLAGS_CHECK([-flto])
1064 # AC_WIRESHARK_LDFLAGS_CHECK([-fwhopr])
1065 # AC_WIRESHARK_LDFLAGS_CHECK([-fwhole-program])
1066
1067 #
1068 # Put -fPIE in PIE_CFLAGS and -pie in PIE_LDFLAGS if we can use them,
1069 # so that we can build dumpcap PIE - it may run with elevated
1070 # privileges, and using PIE means the OS can run it at random locations
1071 # in the address space to make attacks more difficult.
1072 #
1073
1074 WS_CFLAGS_saved="$WS_CFLAGS"
1075 WS_LDFLAGS_saved="$WS_LDFLAGS"
1076 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-fPIE, C)
1077 if test "x$can_add_to_cflags" = "xyes"
1078 then
1079         AC_WIRESHARK_LDFLAGS_CHECK([-fPIE -pie])
1080         if test "x$can_add_to_ldflags" = "xyes"
1081         then
1082                 # We can use PIE
1083                 PIE_CFLAGS="-fPIE"
1084                 PIE_LDFLAGS="-pie"
1085         fi
1086 fi
1087 WS_CFLAGS="$WS_CFLAGS_saved"
1088 WS_LDFLAGS="$WS_LDFLAGS_saved"
1089 AC_SUBST(PIE_CFLAGS)
1090 AC_SUBST(PIE_LDFLAGS)
1091
1092 WS_CFLAGS_saved="$WS_CFLAGS"
1093 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-msse4.2, C)
1094 if test "x$can_add_to_cflags" = "xyes"
1095 then
1096         #
1097         # The compiler supports -msse4.2; use that to enable SSE 4.2.
1098         #
1099         # We only want to apply -msse4.2 to
1100         # wsutil/ws_mempbrk_sse42.c, as the SSE4.2 code there
1101         # is run only if the hardware supports it, but other
1102         # code would do no such checks.
1103         #
1104         ac_sse4_2_flag=-msse4.2
1105 else
1106         #
1107         # Try -xarch=sse4_2; that's the flag for Sun's compiler.
1108         #
1109         AC_WIRESHARK_COMPILER_FLAGS_CHECK(-xarch=sse4_2, C)
1110         if test "x$can_add_to_cflags" = "xyes"
1111         then
1112                 #
1113                 # The compiler supports -xarch=sse4_2; use that to
1114                 # enable SSE 4.2.
1115                 ac_sse4_2_flag=-xarch=sse4_2
1116         fi
1117 fi
1118 WS_CFLAGS="$WS_CFLAGS_saved"
1119
1120 if test "x$ac_sse4_2_flag" != x; then
1121         #
1122         # OK, we have a compiler flag to enable SSE 4.2.
1123         #
1124         # Make sure we have the necessary headers for the SSE4.2 intrinsics
1125         # and that we can use them.
1126         #
1127         # First, check whether we have emmintrin.h and can use it
1128         # *without* the SSE 4.2 flag.
1129         #
1130         AC_MSG_CHECKING([whether there is emmintrin.h header and we can use it])
1131         AC_TRY_COMPILE(
1132                 [#include <emmintrin.h>],
1133                 [return 0;],
1134                 [
1135                         emmintrin_h_works=yes
1136                         AC_MSG_RESULT([yes])
1137                 ],
1138                 [
1139                         emmintrin_h_works=no
1140                         AC_MSG_RESULT([no])
1141                 ]
1142         )
1143
1144         #
1145         # OK, if that works, see whether we have nmmintrin.h and
1146         # can use it *with* the SSE 4.2 flag.
1147         #
1148         if test "x$emmintrin_h_works" = "xyes"; then
1149                 #
1150                 # Add the SSE4.2 flags to the beginning of CFLAGS,
1151                 # in case the user explicitly specified -mno-sse4.2
1152                 # (or in case Gentoo's build tools did so); if they
1153                 # did so, we only want this to work if we can use
1154                 # the #pragma to override that for ws_mempbrk_sse42.c,
1155                 # and putting it at the beginning means that the
1156                 # CFLAGS setting in the environment will come later
1157                 # and override it.
1158                 #
1159                 AC_MSG_CHECKING([whether there is nmmintrin.h header and we can use it])
1160                 saved_CFLAGS="$CFLAGS"
1161                 CFLAGS="$ac_sse4_2_flag $WS_CFLAGS $CFLAGS"
1162                 AC_TRY_COMPILE(
1163                         [#include <nmmintrin.h>],
1164                         [return 0;],
1165                         [
1166                                 have_sse42=yes
1167                                 AC_DEFINE(HAVE_SSE4_2, 1, [Support SSSE4.2 (Streaming SIMD Extensions 4.2) instructions])
1168                                 CFLAGS_SSE42="$ac_sse4_2_flag"
1169                                 AC_MSG_RESULT([yes])
1170                         ],
1171                         [
1172                                 have_sse42=no
1173                                 AC_MSG_RESULT([no])
1174                         ]
1175                 )
1176                 CFLAGS="$saved_CFLAGS"
1177         else
1178                 have_sse42=no
1179         fi
1180 else
1181         have_sse42=no
1182 fi
1183 dnl build libwsutil_sse42 only if there is SSE4.2
1184 AM_CONDITIONAL(SSE42_SUPPORTED, test "x$have_sse42" = "xyes")
1185 AC_SUBST(CFLAGS_SSE42)
1186
1187 #
1188 # If we're running GCC or clang define _U_ to be "__attribute__((unused))"
1189 # so we can use _U_ to flag unused function parameters and not get warnings
1190 # about them. Otherwise, define _U_ to be an empty string so that _U_ used
1191 # to flag an unused function parameters will compile with other compilers.
1192 #
1193 # XXX - similar hints for other compilers?
1194 #
1195 if test "x$GCC" = "xyes" -o "x$CC" = "xclang" ; then
1196   AC_DEFINE(_U_, __attribute__((unused)), [Hint to the compiler that a function parameters is not used])
1197   AC_DEFINE(WS_NORETURN, __attribute((noreturn)), [Hint to the compiler that a function never returns])
1198 else
1199   AC_DEFINE(_U_, , [Hint to the compiler that a function parameters is not used])
1200   AC_DEFINE(WS_NORETURN, , [Hint to the compiler that a function never returns])
1201 fi
1202
1203 # If we're running GCC or CLang, use FORTIFY_SOURCE=2
1204 #  (only if the GCC 'optimization level' > 0).
1205 #
1206 # See: http://gcc.gnu.org/ml/gcc-patches/2004-09/msg02055.html
1207 # See: http://sourceware.org/bugzilla/show_bug.cgi?id=13979
1208 #
1209 # Note: FORTIFY_SOURCE is only effective for gcc optimization level > 0 (-O1, etc)
1210 AC_WIRESHARK_GCC_FORTIFY_SOURCE_CHECK
1211
1212 #
1213 # If the compiler supports GCC-style flags, enable a barrier "stop on
1214 # warning".
1215 # This barrier is set for a very large part of the code. However, it is
1216 # typically not set for "generated" code  (flex, ans2wrs, idl2wrs, ...)
1217 #
1218 warnings_as_errors_default="yes"
1219 AC_MSG_CHECKING(whether we should treat compiler warnings as errors)
1220 AC_ARG_ENABLE(warnings-as-errors,
1221   AC_HELP_STRING( [--enable-warnings-as-errors],
1222                   [treat warnings as errors (only for GCC or clang) @<:@default=yes, unless extra compiler warnings are enabled@:>@]),
1223 [
1224   if test "x$ac_supports_gcc_flags" = "xyes" -a "x$enableval" = "xyes"; then
1225     with_warnings_as_errors="yes"
1226     AC_MSG_RESULT(yes)
1227   else
1228     with_warnings_as_errors="no"
1229     AC_MSG_RESULT(no)
1230   fi
1231 ],
1232 [
1233   if test "x$ac_supports_gcc_flags" = "xyes" -a "x$wireshark_extra_flags" = "x" -a "x$warnings_as_errors_default" = "xyes"; then
1234     with_warnings_as_errors="yes"
1235     AC_MSG_RESULT(yes)
1236   else
1237     with_warnings_as_errors="no"
1238     AC_MSG_RESULT(no)
1239   fi
1240 ])
1241
1242 AS_IF([test "x$with_warnings_as_errors" = "xyes"], [WERROR="-Werror"], [WERROR=""])
1243 AC_SUBST(WERROR)
1244 AM_CONDITIONAL(HAVE_WARNINGS_AS_ERRORS, [test "x$with_warnings_as_errors" = "xyes"])
1245
1246 #
1247 # Add any platform-specific compiler flags needed.
1248 #
1249 AC_MSG_CHECKING(for platform-specific compiler flags)
1250 if test "x$GCC" = "xyes" ; then
1251         #
1252         # GCC - do any platform-specific tweaking necessary.
1253         #
1254         case "$host_os" in
1255         solaris*)
1256                 # the X11 headers don't automatically include prototype info
1257                 # and a lot don't include the return type
1258                 WS_CPPFLAGS="$WS_CPPFLAGS -DFUNCPROTO=15"
1259                 WS_CFLAGS="$WS_CFLAGS -Wno-return-type"
1260                 WS_CXXFLAGS="$WS_CXXFLAGS -Wno-return-type"
1261                 AC_MSG_RESULT(GCC on Solaris - added -Wno-return-type -DFUNCPROTO=15)
1262                 ;;
1263         *)
1264                 AC_MSG_RESULT(none needed)
1265                 ;;
1266         esac
1267 else
1268         #
1269         # Not GCC - assume it's the vendor's compiler.
1270         #
1271         case "$host_os" in
1272         hpux*)
1273                 #
1274                 # AC_PROG_CC_STDC should already have added whatever
1275                 # flags are necessary for ISO C - C99 if available,
1276                 # otherwise C89 - with extensions.
1277                 #
1278                 # Add +O2, for optimization, as suggested by Jost Martin.
1279                 # XXX - works with "-g"?
1280                 #
1281                 # +O2 is supported both by the C and C++ compiler.
1282                 #
1283                 WS_CFLAGS="+O2 $WS_CFLAGS"
1284                 if test "$CC" = "$CC_FOR_BUILD"; then
1285                         #
1286                         # We're building the build tools with the same
1287                         # compiler as the one with which we're building
1288                         # Wireshark, so add the flags to the flags for
1289                         # that compiler as well.
1290                         #
1291                         CFLAGS_FOR_BUILD="-Ae +O2 $CFLAGS"
1292                 fi
1293                 WS_CXXFLAGS="+O2 $WS_CXXFLAGS"
1294                 AC_MSG_RESULT(HP C/C++ compiler - added +O2)
1295                 ;;
1296         solaris*)
1297                 #
1298                 # Crank up the warning level.
1299                 #
1300                 WS_CFLAGS="$WS_CFLAGS -v"
1301                 WS_CXXFLAGS="$WS_CXXFLAGS +w2"
1302                 ;;
1303         *)
1304                 AC_MSG_RESULT(none needed)
1305                 ;;
1306         esac
1307 fi
1308
1309 #
1310 # Add any platform-specific linker flags needed.
1311 #
1312 AC_MSG_CHECKING(for platform-specific linker flags)
1313 case "$host_os" in
1314 darwin*)
1315         #
1316         # Add -Wl,-single_module to the LDFLAGS used with shared
1317         # libraries, to fix some error that show up in some cases;
1318         # some Apple documentation recommends it for most shared
1319         # libraries.
1320         #
1321         LDFLAGS_SHAREDLIB="-Wl,-single_module"
1322         #
1323         # Add -Wl,-headerpad_max_install_names to the LDFLAGS, as
1324         # code-signing issues is running out of padding space.
1325         #
1326         # Add -Wl,-search_paths_first to make sure that if we search
1327         # directories A and B, in that order, for a given library, a
1328         # non-shared version in directory A, rather than a shared
1329         # version in directory B, is chosen (so we can use
1330         # --with-pcap=/usr/local to force all programs to be linked
1331         # with a static version installed in /usr/local/lib rather than
1332         # the system version in /usr/lib).
1333         #
1334         WS_LDFLAGS="-Wl,-headerpad_max_install_names -Wl,-search_paths_first $WS_LDFLAGS"
1335         AC_MSG_RESULT([Apple linker - added -Wl,-single_module to shared library linker flags and -Wl,-headerpad_max_install_names -Wl,-search_paths_first and -Wl,-headerpad_max_install_names to all linker flags])
1336         ;;
1337 cygwin*)
1338         #
1339         # Shared libraries in cygwin/Win32 must never contain
1340         # undefined symbols.
1341         #
1342         WS_LDFLAGS="$WS_LDFLAGS -no-undefined"
1343         AC_MSG_RESULT(CygWin GNU ld - added -no-undefined)
1344         ;;
1345 *)
1346         AC_MSG_RESULT(none needed)
1347         ;;
1348 esac
1349 AC_SUBST(LDFLAGS_SHAREDLIB)
1350
1351 #
1352 # On "Darwin", which we assume to mean "OS X" rather than "iOS" or
1353 # "just Darwin" (as we don't currently support iOS, and as I don't
1354 # think you can build and run "just Darwin" as an OS for PCs), we
1355 # arrange to build some programs with Application Services so they
1356 # can launch Web browsers and Finder windows, arrange to build some
1357 # programs with System Configuration so they can get "friendly names"
1358 # and other information about interfaces, and build any programs that
1359 # use either of those frameworks or that report version information
1360 # with Core Foundation as the frameworks in question use it and as we
1361 # get version information from plists and thus need Core Foundation
1362 # to process those plists.
1363 #
1364 have_os_x_frameworks=no
1365 case "$host_os" in
1366 darwin*)
1367         have_os_x_frameworks=yes
1368         AC_DEFINE(HAVE_OS_X_FRAMEWORKS, 1, [Define to 1 if you have OS X frameworks])
1369         APPLICATIONSERVICES_FRAMEWORKS="-framework ApplicationServices"
1370         SYSTEMCONFIGURATION_FRAMEWORKS="-framework SystemConfiguration"
1371         COREFOUNDATION_FRAMEWORKS="-framework CoreFoundation"
1372
1373         #
1374         # OK, so we have the OS X frameworks; do they include
1375         # CFPropertyListCreateWithStream, or do we have
1376         # to fall back on CFPropertyListCreateFromStream?
1377         # (They only differ in the error return, which we
1378         # don't care about.  And, no, we shouldn't just
1379         # use CFPropertyListCreateFromStream, because it's
1380         # deprecated in newer releases.)
1381         #
1382         ac_save_LIBS="$LIBS"
1383         LIBS="$LIBS $COREFOUNDATION_FRAMEWORKS"
1384         AC_CHECK_FUNCS(CFPropertyListCreateWithStream)
1385         LIBS="$ac_save_LIBS"
1386         ;;
1387 esac
1388 AC_SUBST(APPLICATIONSERVICES_FRAMEWORKS)
1389 AC_SUBST(SYSTEMCONFIGURATION_FRAMEWORKS)
1390 AC_SUBST(COREFOUNDATION_FRAMEWORKS)
1391 AM_CONDITIONAL(HAVE_OS_X_FRAMEWORKS, [test "x$have_os_x_frameworks" = "xyes"])
1392
1393 #
1394 # On Solaris, check whether we have getexecname().
1395 #
1396 case "$host_os" in
1397 solaris*)
1398         AC_CHECK_FUNC(getexecname)
1399         ;;
1400 esac
1401
1402 #
1403 # If we're running Solaris, and LD_LIBRARY_PATH is defined, add it as a
1404 # link directory.
1405 #
1406 case "$host_os" in
1407   solaris*)
1408     AC_MSG_CHECKING(for LD_LIBRARY_PATH, since you appear to be running Solaris)
1409     if test x$LD_LIBRARY_PATH != x ; then
1410       LIBS="$LIBS -R$LD_LIBRARY_PATH"
1411       AC_MSG_RESULT(yes -- added LD_LIBRARY_PATH to run-time linker path)
1412     else
1413       AC_MSG_RESULT(no -- this may be a problem in a few seconds)
1414     fi
1415   ;;
1416 esac
1417
1418 # Enable/disable wireshark
1419 AC_ARG_ENABLE(wireshark,
1420   AC_HELP_STRING( [--enable-wireshark],
1421                   [build the Wireshark GUI (with Gtk+, Qt, or both) @<:@default=yes@:>@]),
1422     enable_wireshark=$enableval,enable_wireshark=yes)
1423 AM_CONDITIONAL(BUILDING_WIRESHARK, test x$enable_wireshark = xyes)
1424
1425 AC_ARG_ENABLE(packet-editor,
1426   AC_HELP_STRING( [--enable-packet-editor],
1427                   [add support for packet editor in Wireshark @<:@default=yes@:>@]),
1428     enable_packet_editor=$enableval,enable_packet_editor=yes)
1429 if test x$enable_packet_editor = xyes; then
1430         AC_DEFINE(WANT_PACKET_EDITOR, 1, [Support for packet editor])
1431 fi
1432
1433 AC_ARG_ENABLE(profile-build,
1434   AC_HELP_STRING( [--enable-profile-build],
1435                   [build profile-ready binaries @<:@default=no@:>@]),
1436     enable_profile_build=$enableval,enable_profile_build=no)
1437 AM_CONDITIONAL(USE_PROFILE_BUILD, test x$enable_profile_build = xyes)
1438 AC_MSG_CHECKING(if profile builds must be generated)
1439 if test "x$enable_profile_build" = "xyes" ; then
1440         if test "x$GCC" = "xyes" -o "x$CLANG" = "xyes" ; then
1441                 AC_MSG_RESULT(yes)
1442                 WS_CFLAGS="-pg $WS_CFLAGS"
1443                 WS_CXXFLAGS="-pg $WS_CXXFLAGS"
1444         else
1445                 AC_MSG_RESULT(no)
1446                 echo "Building profile binaries currently only supported for GCC and clang."
1447         fi
1448 else
1449         AC_MSG_RESULT(no)
1450 fi
1451
1452 GLIB_MIN_VERSION=2.16.0
1453 AC_SUBST(GLIB_MIN_VERSION)
1454 # GLib checks; we require GLib $GLIB_MIN_VERSION or later, and require gmodule
1455 # support, as we need that for dynamically loading plugins.
1456 #
1457 # Release dates for GLib versions:
1458 # 2.14.0: 03 Aug 2007
1459 # 2.16.0: 10 Mar 2008
1460 # 2.18.0: 02 Sep 2008
1461 # 2.20.0: 13 Mar 2009
1462 # 2.22.0: 22 Sep 2009
1463 # 2.24.0: 28 Mar 2010
1464 # 2.26.0: 27 Sep 2010
1465 # 2.28.0: 08 Feb 2011
1466 # 2.30.0: 27 Sep 2011
1467 # 2.32.0: 24 Mar 2012
1468 # 2.34.0: 24 Sep 2012
1469 # 2.36.0: 25 Mar 2013
1470 # 2.38.0: 23 Sep 2013
1471 # 2.40.0: 24 Mar 2014
1472 # 2.42.0: 22 Sep 2014
1473 # 2.44.0: 23 Mar 2014
1474 # 2.46.0: 25 Sep 2015
1475
1476 PKG_WIRESHARK_CHECK_SYSTEM_MODULES([GLIB],
1477         [glib-2.0 >= $GLIB_MIN_VERSION gthread-2.0 >= $GLIB_MIN_VERSION gmodule-2.0 >= $GLIB_MIN_VERSION],
1478         [GLIB_VERSION=`$PKG_CONFIG --modversion glib-2.0`],
1479         [AC_MSG_ERROR([GLib $GLIB_MIN_VERSION or later not found.])])
1480
1481 # Error out if a glib header other than a "top level" header
1482 #  (glib.h, glib-object.h, gio.h) or certain other headers( e.g.,gmodule.h)
1483 #  is used.
1484 AX_APPEND_FLAG([-DG_DISABLE_SINGLE_INCLUDES], [GLIB_CONFIG])
1485
1486 # Error out on the usage of deprecated glib functions
1487 AX_APPEND_FLAG([-DG_DISABLE_DEPRECATED], [GLIB_CONFIG])
1488
1489 GLIB_CFLAGS="$GLIB_CONFIG $GLIB_CFLAGS"
1490 AC_SUBST(GLIB_CFLAGS)
1491 AC_SUBST(GLIB_LIBS)
1492
1493 GTK2_MIN_VERSION=2.12.0
1494 AC_SUBST(GTK2_MIN_VERSION)
1495 GTK3_MIN_VERSION=3.0.0
1496 AC_SUBST(GTK3_MIN_VERSION)
1497 QT_MIN_VERSION=4.7.0
1498 AC_SUBST(QT_MIN_VERSION)
1499 # GTK+ and Qt checks; we require GTK+ $GTK2_MIN_VERSION or later or
1500 # GTK3_MIN_VERSION or later or Qt $QT_MIN_VERSION or later.
1501 #
1502 # We only do those if we're going to be building Wireshark;
1503 # otherwise, we don't have any GUI to build, so we don't use
1504 # GTK+ or Qt.
1505 #
1506 # We don't add $GTK_LIBS or $Qt_LIBS to LIBS, because we don't want to
1507 # force all programs to be built with GTK+ or Qt.
1508 #
1509 # Release dates for GTK+ versions:
1510 # https://en.wikipedia.org/wiki/GTK+#Releases
1511 # 2.12.0: 14 Sep 2007
1512 # 2.14.0: 04 Sep 2008
1513 # 2.16.0: 13 Mar 2009
1514 # 2.18.0: 23 Sep 2009
1515 # 2.20.0: 23 Mar 2010
1516 # 2.22.0: 23 Sep 2010
1517 # 2.24.0: 30 Jan 2011
1518 # 3.0.0:  10 Feb 2011
1519 # 3.2.0:  25 Sep 2011
1520 # 3.4.0:  26 Mar 2012
1521 # 3.6.0:  24 Sep 2012
1522 # 3.8.0:  25 Mar 2013
1523 # 3.10.0: 23 Sep 2013
1524 # 3.12.0: 25 Mar 2014
1525 # 3.14.0: 30 Sep 2014
1526 # 3.16.0: 22 Mar 2015
1527 # 3.18.0  22 Sep 2015
1528 #
1529 # Release dates for Qt versions:
1530 # https://en.wikipedia.org/wiki/List_of_Qt_releases
1531 # 4.6.0:  01 Dec 2009
1532 # 4.7.0:  21 Sep 2010
1533 # 4.8.0:  15 Dec 2011
1534 # 5.0.0:  19 Dec 2012
1535 # 5.1.0:  03 Jul 2013
1536 # 5.2.0:  12 Dec 2013
1537 # 5.3.0:  20 May 2014
1538 # 5.4.0:  10 Dec 2015
1539 # 5.5.0:  01 Jul 2015
1540
1541 have_qt=no
1542 have_gtk=no
1543 if test "x$enable_wireshark" = "xyes"; then
1544         if test "x$with_qt" != "xno"; then
1545                 #
1546                 # Qt was specified; make sure we have a C++ compiler.
1547                 #
1548                 if test -z "$CXX"; then
1549                         AC_MSG_ERROR(Need a working C++ compiler to build Wireshark with Qt)
1550                 fi
1551
1552                 #
1553                 # Now make sure we have Qt and, if so, add the flags
1554                 # for it to CFLAGS and CXXFLAGS.
1555                 #
1556                 AC_WIRESHARK_QT_CHECK($QT_MIN_VERSION, "$with_qt",
1557                 [
1558                         AC_SUBST(Qt_CFLAGS)
1559                         AC_SUBST(Qt_LIBS)
1560                         have_qt=yes
1561                         GUI_CONFIGURE_FLAGS="$GUI_CONFIGURE_FLAGS --with-qt"
1562
1563                         #
1564                         # We're building with Qt, so we need the Qt build
1565                         # tools in order to build the Wireshark GUI.
1566                         # We've found a particular major version of Qt,
1567                         # and we want that version's build tools; for
1568                         # example, the Qt 4 version of uic produces files
1569                         # that include Qt headers with paths that work
1570                         # with Qt 4 but not Qt 5, so we can't use the
1571                         # Qt 4 version of uic if we're building with Qt 5.
1572                         AC_WIRESHARK_QT_TOOL_CHECK(UIC, uic, "$qt_version")
1573                         AC_SUBST(UIC)
1574                         AC_WIRESHARK_QT_TOOL_CHECK(MOC, moc, "$qt_version")
1575                         AC_SUBST(MOC)
1576                         AC_WIRESHARK_QT_TOOL_CHECK(RCC, rcc, "$qt_version")
1577                         AC_SUBST(RCC)
1578
1579                         #
1580                         # On Darwin, find where the Qt frameworks are
1581                         # located, and add that to the rpath, just in
1582                         # case this is Qt 5.5 or later and the frameworks
1583                         # have an install name that begins with @rpath
1584                         # and aren't installed in a frameworks directory
1585                         # that's searched by default.
1586                         #
1587                         case "$host_os" in
1588                         darwin*)
1589                                 if test $qt_version -le 4
1590                                 then
1591                                         Qt_LDFLAGS="-Wl,-rpath,"`$PKG_CONFIG --libs QtCore | sed -e 's/-F//' -e 's/ -framework.*//'`
1592                                 else
1593                                         Qt_LDFLAGS="-Wl,-rpath,"`$PKG_CONFIG --libs Qt${qt_version}Core | sed -e 's/-F//' -e 's/ -framework.*//'`
1594                                 fi
1595                                 ;;
1596                         esac
1597                         AC_SUBST(Qt_LDFLAGS)
1598
1599                         if test -z "${MOC_OPTIONS+1}"
1600                         then
1601                                 if test $qt_version -eq 5
1602                                 then
1603                                         # Squelch moc verbose "nothing to do" output
1604                                         MOC_OPTIONS="-nn"
1605                                 elif test $qt_version -eq 4
1606                                 then
1607                                         qt_minor_version=`echo "$QT_VERSION" | cut -f2 -d.`
1608                                         if test $qt_minor_version -ge 8
1609                                         then
1610                                                 MOC_OPTIONS="-nn"
1611                                         fi
1612                                 fi
1613                         fi
1614                         AC_SUBST(MOC_OPTIONS)
1615                 ],
1616                 [
1617                         case "$with_qt" in
1618
1619                         unspecified)
1620                                 #
1621                                 # They didn't explicitly ask for Qt,
1622                                 # so just don't build with it.
1623                                 #
1624                                 ;;
1625
1626                         yes)
1627                                 AC_MSG_ERROR([Qt is not available])
1628                                 ;;
1629
1630                         4)
1631                                 AC_MSG_ERROR([Qt 4 is not available])
1632                                 ;;
1633
1634                         5)
1635                                 AC_MSG_ERROR([Qt 5 is not available])
1636                                 ;;
1637                         esac
1638                 ])
1639         fi
1640
1641         for want_gtk_version in $with_gtk; do
1642                 AS_CASE([$want_gtk_version],
1643                   [3], [PKG_WIRESHARK_CHECK_SYSTEM_MODULES([GTK],
1644                         [gtk+-3.0 >= $GTK3_MIN_VERSION glib-2.0 >= $GLIB_MIN_VERSION gthread-2.0 >= $GLIB_MIN_VERSION gmodule-2.0 >= $GLIB_MIN_VERSION],
1645                         [
1646                           have_gtk=yes
1647                           GTK_VERSION=`$PKG_CONFIG --modversion gtk+-3.0`
1648                           GUI_CONFIGURE_FLAGS="$GUI_CONFIGURE_FLAGS --with-gtk=3"
1649                         ],
1650                         [
1651                           :
1652                         ])],
1653                   [2], [PKG_WIRESHARK_CHECK_SYSTEM_MODULES([GTK],
1654                         [gtk+-2.0 >= $GTK2_MIN_VERSION glib-2.0 >= $GLIB_MIN_VERSION gthread-2.0 >= $GLIB_MIN_VERSION gmodule-2.0 >= $GLIB_MIN_VERSION],
1655                         [
1656                           have_gtk=yes
1657                           GTK_VERSION=`$PKG_CONFIG --modversion gtk+-2.0`
1658                           GUI_CONFIGURE_FLAGS="$GUI_CONFIGURE_FLAGS --with-gtk=2"
1659                         ],
1660                         [
1661                           :
1662                         ])],
1663                   [fail3], [AC_MSG_ERROR([GTK+ 3 was requested but is not available])],
1664                   [fail2], [AC_MSG_ERROR([GTK+ 2 was requested but is not available])],
1665                   [fail],  [AC_MSG_ERROR([GTK+ was requested but is not available])])
1666
1667                 AS_IF([test "x$have_gtk" = xyes], [break])
1668         done
1669
1670         if test "$have_gtk" = "yes" ; then
1671                 # If we have GTK then add flags for it.
1672                 #
1673                 # GLib flags first
1674                 #
1675                 GTK_CONFIG="$GLIB_CONFIG"
1676
1677                 gtk_major_version=`echo $GTK_VERSION | cut -d. -f1`
1678                 gtk_minor_version=`echo $GTK_VERSION | cut -d. -f2`
1679
1680                 AX_APPEND_FLAG([-DGDK_DISABLE_DEPRECATED], [GTK_CONFIG])
1681                 if test \( $gtk_major_version -eq 3 -a $gtk_minor_version -ge 10 \) ; then
1682                         ## Allow use of deprecated & disable deprecated warnings if Gtk >= 3.10;
1683                         ##  The deprecations in Gtk 3.10 will not be fixed ...
1684                         AX_APPEND_FLAG([-DGDK_DISABLE_DEPRECATION_WARNINGS], [GTK_CONFIG])
1685                 else
1686                         AX_APPEND_FLAG([-DGTK_DISABLE_DEPRECATED], [GTK_CONFIG])
1687                 fi
1688                 AX_APPEND_FLAG([-DGTK_DISABLE_SINGLE_INCLUDES], [GTK_CONFIG])
1689                 if test ! \( $gtk_major_version -eq 2 -a $gtk_minor_version -lt 20 \) ; then
1690                         # Enable GSEAL when building with GTK > 2.20
1691                         # (Versions prior to 2.22 lacked some necessary accessors.)
1692                         AX_APPEND_FLAG([-DGSEAL_ENABLE], [GTK_CONFIG])
1693                 fi
1694
1695                 GTK_CFLAGS="$GTK_CONFIG $GTK_CFLAGS"
1696         fi
1697 fi
1698
1699 AC_SUBST(GTK_CFLAGS)
1700 AC_SUBST(GTK_LIBS)
1701 AC_SUBST(GUI_CONFIGURE_FLAGS)
1702
1703 # Check for GTK GUI support for GResource pixbufs
1704 have_gresource_pixbuf=no
1705 if test "x$have_gtk" = "xyes"; then
1706         AC_MSG_CHECKING(whether GDK-Pixbuf can load data using GResource)
1707         PKG_CHECK_EXISTS([gio-2.0 >= 2.32 gdk-pixbuf-2.0 >= 2.26],
1708           [
1709            AC_MSG_RESULT(yes)
1710            AC_DEFINE(HAVE_GDK_GRESOURCE, 1, [Defined if GResource is supported])
1711            have_gresource_pixbuf=yes
1712           ],
1713           [AC_MSG_RESULT(no)])
1714 fi
1715 AM_CONDITIONAL(HAVE_GRESOURCE_PIXBUF, test "x$have_gresource_pixbuf" = "xyes")
1716
1717 if test "$have_gtk" = "yes" -a "$have_qt" = "yes" ; then
1718         # We have both GTK and Qt and thus will be building both wireshark
1719         # and wireshark-gtk.
1720
1721         wireshark_bin="wireshark\$(EXEEXT) wireshark-gtk\$(EXEEXT)"
1722         wireshark_man="wireshark.1"
1723         wireshark_SUBDIRS="codecs ui/qt ui/gtk"
1724 fi
1725 if test "$have_gtk" = "no" -a "$have_qt" = "yes" ; then
1726         # We don't have GTK+ but we have Qt.
1727
1728         wireshark_bin="wireshark\$(EXEEXT)"
1729         wireshark_man="wireshark.1"
1730         wireshark_SUBDIRS="codecs ui/qt"
1731 fi
1732 if test "$have_gtk" = "yes" -a "$have_qt" = "no" ; then
1733         # We have GTK+ but not Qt.
1734
1735         wireshark_bin="wireshark-gtk\$(EXEEXT)"
1736         wireshark_man="wireshark.1"
1737         wireshark_SUBDIRS="codecs ui/gtk"
1738         OSX_APP_FLAGS="$OSX_APP_FLAGS -gtk"
1739         OSX_DMG_FLAGS="-gtk"
1740 fi
1741 if test "$have_gtk" = "no" -a "$have_qt" = "no" ; then
1742         # We have neither GTK+ nor Qt.
1743         #
1744         # If they didn't explicitly say "--disable-wireshark",
1745         # fail (so that, unless they explicitly indicated that
1746         # they don't want Wireshark, we stop so they know they
1747         # won't be getting Wireshark unless they fix the GTK+/Qt
1748         # problem).
1749         #
1750         if test "x$enable_wireshark" = "xyes"; then
1751                 AC_MSG_ERROR([Neither Qt nor GTK+ are available, so Wireshark can't be compiled])
1752         fi
1753         wireshark_bin=""
1754         wireshark_man=""
1755         wireshark_SUBDIRS=""
1756 fi
1757
1758 #
1759 # Check whether GLib modules are supported, to determine whether we
1760 # can support plugins.
1761 #
1762
1763 AC_CACHE_CHECK([whether GLib supports loadable modules],
1764                [ac_cv_glib_supports_modules], [
1765 ac_save_CFLAGS="$CFLAGS"
1766 ac_save_LIBS="$LIBS"
1767 CFLAGS="$WS_CFLAGS $GLIB_CFLAGS $CFLAGS"
1768 LIBS="$LIBS $GLIB_LIBS"
1769 AC_TRY_RUN([
1770 #include <glib.h>
1771 #include <gmodule.h>
1772 #include <stdio.h>
1773 #include <stdlib.h>
1774
1775 int
1776 main ()
1777 {
1778   if (g_module_supported())
1779     return 0;   /* success */
1780   else
1781     return 1;   /* failure */
1782 }
1783 ], ac_cv_glib_supports_modules=yes, ac_cv_glib_supports_modules=no,
1784    [echo $ac_n "cross compiling; assumed OK... $ac_c"
1785     ac_cv_glib_supports_modules=yes])
1786 CFLAGS="$ac_save_CFLAGS"
1787 LIBS="$ac_save_LIBS"
1788 ])
1789 if test "$ac_cv_glib_supports_modules" = yes ; then
1790   have_plugins=yes
1791   plugins_dir="plugins"
1792 else
1793   have_plugins=no
1794   plugins_dir=""
1795 fi
1796 AC_SUBST(plugins_dir)
1797
1798 #
1799 # If we have <dlfcn.h>, check whether we have dladdr.
1800 #
1801 if test "$ac_cv_header_dlfcn_h" = "yes"
1802 then
1803         #
1804         # Use GLib compiler flags and linker flags; GLib's gmodule
1805         # stuff uses the dl APIs if available, so it might know
1806         # what flags are needed.
1807         #
1808         ac_save_CFLAGS="$CFLAGS"
1809         ac_save_LIBS="$LIBS"
1810         CFLAGS="$WS_CFLAGS $GLIB_CFLAGS $CFLAGS"
1811         LIBS="$LIBS $GLIB_LIBS"
1812         AC_CHECK_FUNCS(dladdr)
1813         if test x$ac_cv_func_dladdr = xno
1814         then
1815                 #
1816                 # OK, try it with -ldl, in case you need that to get
1817                 # dladdr().  For some reason, on Linux, that's not
1818                 # part of the GLib flags; perhaps GLib itself is
1819                 # linked with libdl, so that you can link with
1820                 # Glib and it'll pull libdl in itself.
1821                 #
1822                 LIBS="$LIBS -ldl"
1823                 AC_CHECK_FUNCS(dladdr)
1824         fi
1825         CFLAGS="$ac_save_CFLAGS"
1826         LIBS="$ac_save_LIBS"
1827 fi
1828
1829 #
1830 # Check whether GLib's printf supports thousands grouping. (This might
1831 # be different from the system's printf since GLib can optionally use
1832 # its own printf implementation.)
1833 #
1834 AC_CACHE_CHECK([whether GLib supports POSIX/XSI thousands grouping],
1835                [ac_cv_glib_supports_printf_grouping], [
1836 ac_save_CFLAGS="$CFLAGS"
1837 ac_save_LIBS="$LIBS"
1838 CFLAGS="$WS_CFLAGS $GLIB_CFLAGS $CFLAGS"
1839 LIBS="$LIBS $GLIB_LIBS"
1840 AC_TRY_RUN([
1841 #include <glib.h>
1842 #include <locale.h>
1843 #include <stdio.h>
1844 #include <string.h>
1845
1846 int
1847 main ()
1848 {
1849   gchar *str;
1850   setlocale(LC_ALL, "en_US.UTF-8");
1851   str = g_strdup_printf("%'u", 123456);
1852   return (strcmp (str, "123,456") != 0);
1853 }
1854 ], ac_cv_glib_supports_printf_grouping=yes, ac_cv_glib_supports_printf_grouping=no,
1855    [echo $ac_n "cross compiling; playing it safe... $ac_c"
1856     ac_cv_glib_supports_printf_grouping=no])
1857 CFLAGS="$ac_save_CFLAGS"
1858 LIBS="$ac_save_LIBS"
1859 ])
1860 if test "$ac_cv_glib_supports_printf_grouping" = yes ; then
1861   AC_DEFINE(HAVE_GLIB_PRINTF_GROUPING, 1, [Define if GLib's printf functions support thousands grouping.])
1862 fi
1863
1864 if test "x$have_gtk" = "xyes"
1865 then
1866     #
1867     # We have GTK+; do we want the OS X integration functions and,
1868     # if so, do we have them and, if so, which versions do we have,
1869     # the old Carbon-based ones or the new Cocoa-based ones?
1870     #
1871     AC_MSG_CHECKING(whether to use OS X integration functions)
1872
1873     AC_ARG_WITH(osx-integration,
1874       AC_HELP_STRING( [--with-osx-integration],
1875                       [use OS X integration functions @<:@default=yes, if available@:>@]),
1876     [
1877         if test $withval = no
1878         then
1879             want_osx_integration=no
1880         else
1881             want_osx_integration=yes
1882         fi
1883     ],[
1884         want_osx_integration=yes
1885     ])
1886     if test "x$want_osx_integration" = "xno"; then
1887         AC_MSG_RESULT(no)
1888     else
1889         AC_MSG_RESULT(yes)
1890         AC_WIRESHARK_OSX_INTEGRATION_CHECK
1891     fi
1892 fi
1893
1894 AC_SUBST(wireshark_bin)
1895 AC_SUBST(wireshark_man)
1896 AC_SUBST(wireshark_SUBDIRS)
1897 AM_CONDITIONAL(HAVE_Qt, test "$have_qt" = "yes")
1898 AM_CONDITIONAL(HAVE_GTK, test "$have_gtk" = "yes")
1899 AC_SUBST(OSX_APP_FLAGS)
1900 AC_SUBST(OSX_DMG_FLAGS)
1901
1902 # Enable/disable tshark
1903 AC_ARG_ENABLE(tshark,
1904   AC_HELP_STRING( [--enable-tshark],
1905                   [build tshark @<:@default=yes@:>@]),
1906     tshark=$enableval,enable_tshark=yes)
1907
1908 if test "x$enable_tshark" = "xyes" ; then
1909         tshark_bin="tshark\$(EXEEXT)"
1910         tshark_man="tshark.1"
1911         wiresharkfilter_man="wireshark-filter.4"
1912 else
1913         tshark_bin=""
1914         tshark_man=""
1915 fi
1916 AC_SUBST(tshark_bin)
1917 AC_SUBST(tshark_man)
1918
1919 # Enable/disable editcap
1920
1921 AC_ARG_ENABLE(editcap,
1922   AC_HELP_STRING( [--enable-editcap],
1923                   [build editcap @<:@default=yes@:>@]),
1924     enable_editcap=$enableval,enable_editcap=yes)
1925
1926 if test "x$enable_editcap" = "xyes" ; then
1927         editcap_bin="editcap\$(EXEEXT)"
1928         editcap_man="editcap.1"
1929 else
1930         editcap_bin=""
1931         editcap_man=""
1932 fi
1933 AC_SUBST(editcap_bin)
1934 AC_SUBST(editcap_man)
1935
1936
1937 # Enabling/disabling of dumpcap is done later (after we know if we have PCAP
1938 # or not)
1939
1940 # Enable/disable capinfos
1941
1942 AC_ARG_ENABLE(capinfos,
1943   AC_HELP_STRING( [--enable-capinfos],
1944                   [build capinfos @<:@default=yes@:>@]),
1945     enable_capinfos=$enableval,enable_capinfos=yes)
1946
1947 if test "x$enable_capinfos" = "xyes" ; then
1948         capinfos_bin="capinfos\$(EXEEXT)"
1949         capinfos_man="capinfos.1"
1950 else
1951         capinfos_bin=""
1952         capinfos_man=""
1953 fi
1954 AC_SUBST(capinfos_bin)
1955 AC_SUBST(capinfos_man)
1956
1957 # Enable/disable captype
1958
1959 AC_ARG_ENABLE(captype,
1960   AC_HELP_STRING( [--enable-captype],
1961                   [build captype @<:@default=yes@:>@]),
1962     enable_captype=$enableval,enable_captype=yes)
1963
1964 if test "x$enable_captype" = "xyes" ; then
1965         captype_bin="captype\$(EXEEXT)"
1966         captype_man="captype.1"
1967 else
1968         captype_bin=""
1969         captype_man=""
1970 fi
1971 AC_SUBST(captype_bin)
1972 AC_SUBST(captype_man)
1973
1974 # Enable/disable mergecap
1975
1976 AC_ARG_ENABLE(mergecap,
1977   AC_HELP_STRING( [--enable-mergecap],
1978                   [build mergecap @<:@default=yes@:>@]),
1979     enable_mergecap=$enableval,enable_mergecap=yes)
1980
1981 if test "x$enable_mergecap" = "xyes" ; then
1982         mergecap_bin="mergecap\$(EXEEXT)"
1983         mergecap_man="mergecap.1"
1984 else
1985         mergecap_bin=""
1986         mergecap_man=""
1987 fi
1988 AC_SUBST(mergecap_bin)
1989 AC_SUBST(mergecap_man)
1990
1991 # Enable/disable reordercap
1992
1993 AC_ARG_ENABLE(reordercap,
1994   AC_HELP_STRING( [--enable-reordercap],
1995                   [build reordercap @<:@default=yes@:>@]),
1996     enable_reordercap=$enableval,enable_reordercap=yes)
1997
1998 if test "x$enable_reordercap" = "xyes" ; then
1999         reordercap_bin="reordercap\$(EXEEXT)"
2000         reordercap_man="reordercap.1"
2001 else
2002         reordercap_bin=""
2003         reordercap_man=""
2004 fi
2005 AC_SUBST(reordercap_bin)
2006 AC_SUBST(reordercap_man)
2007
2008 # Enable/disable text2pcap
2009
2010 AC_ARG_ENABLE(text2pcap,
2011   AC_HELP_STRING( [--enable-text2pcap],
2012                   [build text2pcap @<:@default=yes@:>@]),
2013     text2pcap=$enableval,enable_text2pcap=yes)
2014
2015 if test "x$enable_text2pcap" = "xyes" ; then
2016         text2pcap_bin="text2pcap\$(EXEEXT)"
2017         text2pcap_man="text2pcap.1"
2018 else
2019         text2pcap_bin=""
2020         text2pcap_man=""
2021 fi
2022 AC_SUBST(text2pcap_bin)
2023 AC_SUBST(text2pcap_man)
2024
2025 # Enable/disable dftest
2026
2027 AC_ARG_ENABLE(dftest,
2028   AC_HELP_STRING( [--enable-dftest],
2029                   [build dftest @<:@default=yes@:>@]),
2030     enable_dftest=$enableval,enable_dftest=yes)
2031
2032 if test "x$enable_dftest" = "xyes" ; then
2033         dftest_bin="dftest\$(EXEEXT)"
2034         dftest_man="dftest.1"
2035 else
2036         dftest_bin=""
2037         dftest_man=""
2038 fi
2039 AC_SUBST(dftest_bin)
2040 AC_SUBST(dftest_man)
2041
2042 # Enable/disable randpkt
2043
2044 AC_ARG_ENABLE(randpkt,
2045   AC_HELP_STRING( [--enable-randpkt],
2046                   [build randpkt @<:@default=yes@:>@]),
2047     enable_randpkt=$enableval,enable_randpkt=yes)
2048
2049 if test "x$enable_randpkt" = "xyes" ; then
2050         randpkt_bin="randpkt\$(EXEEXT)"
2051         randpkt_man="randpkt.1"
2052 else
2053         randpkt_bin=""
2054         randpkt_man=""
2055 fi
2056 AC_SUBST(randpkt_bin)
2057 AC_SUBST(randpkt_man)
2058
2059 AC_SUBST(wiresharkfilter_man)
2060
2061 dnl pcap check
2062 AC_MSG_CHECKING(whether to use libpcap for packet capture)
2063
2064 AC_ARG_WITH(pcap,
2065   AC_HELP_STRING( [--with-pcap@<:@=DIR@:>@],
2066                   [use libpcap for packet capturing @<:@default=yes@:>@]),
2067 [
2068         if test $withval = no
2069         then
2070                 want_pcap=no
2071         elif test $withval = yes
2072         then
2073                 want_pcap=yes
2074         else
2075                 want_pcap=yes
2076                 pcap_dir=$withval
2077         fi
2078 ],[
2079         want_pcap=yes
2080         pcap_dir=
2081 ])
2082 if test "x$want_pcap" = "xno" ; then
2083         AC_MSG_RESULT(no)
2084 else
2085         AC_MSG_RESULT(yes)
2086         AC_WIRESHARK_PCAP_CHECK
2087 fi
2088
2089 dnl dumpcap check
2090 AC_MSG_CHECKING(whether to build dumpcap)
2091
2092 AC_ARG_ENABLE(dumpcap,
2093   AC_HELP_STRING( [--enable-dumpcap],
2094                   [build dumpcap @<:@default=yes@:>@]),
2095     enable_dumpcap=$enableval,enable_dumpcap=yes)
2096
2097 if test "x$enable_dumpcap" = "xyes" ; then
2098         if test "x$want_pcap" = "xno" ; then
2099                 enable_dumpcap=no
2100                 AC_MSG_RESULT(pcap not available - disabling dumpcap)
2101         else
2102                 AC_MSG_RESULT(yes)
2103         fi
2104 else
2105         AC_MSG_RESULT(no)
2106 fi
2107
2108 if test "x$enable_dumpcap" = "xyes" ; then
2109         dumpcap_bin="dumpcap\$(EXEEXT)"
2110         dumpcap_man="dumpcap.1"
2111 else
2112         dumpcap_bin=""
2113         dumpcap_man=""
2114 fi
2115 AC_SUBST(dumpcap_bin)
2116 AC_SUBST(dumpcap_man)
2117
2118 # Enable/disable rawshark
2119
2120 dnl rawshark check
2121 AC_MSG_CHECKING(whether to build rawshark)
2122
2123 AC_ARG_ENABLE(rawshark,
2124   AC_HELP_STRING( [--enable-rawshark],
2125                   [build rawshark @<:@default=yes@:>@]),
2126     rawshark=$enableval,enable_rawshark=yes)
2127
2128 if test "x$enable_rawshark" = "xyes" ; then
2129         if test "x$want_pcap" = "xno" ; then
2130                 enable_rawshark=no
2131                 AC_MSG_RESULT(pcap not available - disabling rawshark)
2132         else
2133                 AC_MSG_RESULT(yes)
2134         fi
2135 else
2136         AC_MSG_RESULT(no)
2137 fi
2138
2139 if test "x$enable_rawshark" = "xyes" ; then
2140         rawshark_bin="rawshark\$(EXEEXT)"
2141         rawshark_man="rawshark.1"
2142 else
2143         rawshark_bin=""
2144         rawshark_man=""
2145 fi
2146 AC_SUBST(rawshark_bin)
2147 AC_SUBST(rawshark_man)
2148
2149 # Enable/disable echld
2150 AC_ARG_ENABLE(echld,
2151   AC_HELP_STRING( [--enable-echld],
2152                   [support echld (Experimental) @<:@default=no@:>@]),
2153     have_echld=$enableval,have_echld=no)
2154
2155 AM_CONDITIONAL(HAVE_ECHLD, test "x$have_echld" = "xyes")
2156 if test "x$have_echld" = "xyes"
2157 then
2158   AC_DEFINE(HAVE_ECHLD, 1, [Define if echld is enabled])
2159   echld_test_bin="echld_test\$(EXEEXT)"
2160   echld_dir="echld"
2161 else
2162   have_echld="no"
2163   echld_test_bin=""
2164   echld_dir=""
2165 fi
2166 AC_SUBST(echld_test_bin)
2167 AC_SUBST(echld_dir)
2168
2169 # Enable/disable tfshark
2170 AC_ARG_ENABLE(tfshark,
2171   AC_HELP_STRING( [--enable-tfshark],
2172                   [build tfshark (Experimental) @<:@default=no@:>@]),
2173     tfshark=$enableval,enable_tfshark=no)
2174
2175 if test "x$enable_tfshark" = "xyes" ; then
2176         tfshark_bin="tfshark\$(EXEEXT)"
2177         tfshark_man="tfshark.1"
2178         wiresharkfilter_man="wireshark-filter.4"
2179 else
2180         tfshark_bin=""
2181         tfshark_man=""
2182 fi
2183 AC_SUBST(tfshark_bin)
2184 AC_SUBST(tfshark_man)
2185
2186
2187 dnl Use pcap-ng by default
2188 AC_ARG_ENABLE(pcap-ng-default,
2189   AC_HELP_STRING( [--enable-pcap-ng-default],
2190                   [use the pcap-ng file format by default instead of pcap @<:@default=yes@:>@]),
2191     enable_pcap_ng_default=$enableval,enable_pcap_ng_default=yes)
2192 if test x$enable_pcap_ng_default = xyes; then
2193         AC_DEFINE(PCAP_NG_DEFAULT, 1, [Support for pcap-ng])
2194 fi
2195
2196 dnl pcap remote check
2197 AC_MSG_CHECKING(whether to use libpcap remote capturing feature)
2198
2199 AC_ARG_WITH(pcap-remote,
2200     AC_HELP_STRING([--with-pcap-remote],
2201                    [use libpcap remote capturing (requires libpcap)]),
2202 [
2203     if test $withval = no
2204     then
2205         want_pcap_remote=no
2206     else
2207         want_pcap_remote=yes
2208     fi
2209 ],[
2210     want_pcap_remote=no
2211 ])
2212 if test "x$want_pcap_remote" = "xno" -o "x$want_pcap" = "xno" ; then
2213     AC_MSG_RESULT(no)
2214 else
2215     AC_MSG_RESULT(yes)
2216     AC_WIRESHARK_PCAP_REMOTE_CHECK
2217 fi
2218
2219 dnl zlib check
2220 AC_MSG_CHECKING(whether to use zlib for gzip compression and decompression)
2221
2222 AC_ARG_WITH(zlib,
2223   AC_HELP_STRING([--with-zlib@<:@=DIR@:>@],
2224                  [use zlib (located in directory DIR, if supplied) for gzip compression and decompression @<:@default=yes, if available@:>@]),
2225 [
2226         if test "x$withval" = "xno"
2227         then
2228                 want_zlib=no
2229         elif test "x$withval" = "xyes"
2230         then
2231                 want_zlib=yes
2232         else
2233                 want_zlib=yes
2234                 zlib_dir="$withval"
2235         fi
2236 ],[
2237         #
2238         # Use zlib if it's present, otherwise don't.
2239         #
2240         want_zlib=ifavailable
2241         zlib_dir=
2242 ])
2243 if test "x$want_zlib" = "xno" ; then
2244         AC_MSG_RESULT(no)
2245 else
2246         AC_MSG_RESULT(yes)
2247         AC_WIRESHARK_ZLIB_CHECK
2248         if test "x$want_zlib" = "xno" ; then
2249                 AC_MSG_RESULT(zlib not found - disabling gzip compression and decompression)
2250         else
2251                 if test "x$ac_cv_func_inflatePrime" = "xno" ; then
2252                         AC_MSG_RESULT(inflatePrime not found in zlib - disabling gzipped capture file support)
2253                 fi
2254         fi
2255 fi
2256
2257 dnl Lua check
2258 AC_ARG_WITH(lua,
2259   AC_HELP_STRING( [--with-lua@<:@=DIR@:>@],
2260                   [use liblua (located in directory DIR, if supplied) for the Lua scripting plugin @<:@default=yes, if available@:>@]),
2261 [
2262         if test $withval = no
2263         then
2264                 want_lua=no
2265         elif test $withval = yes
2266         then
2267                 want_lua=yes
2268         else
2269                 want_lua=yes
2270                 want_lua_dir=$withval
2271         fi
2272 ],[
2273         # By default use Lua if we can find it
2274         want_lua=ifavailable
2275         lua_dir=
2276 ])
2277 if test "x$want_lua" != "xno" ; then
2278         AC_WIRESHARK_LIBLUA_CHECK
2279
2280         if test "x$want_lua" = "xyes" -a "x$have_lua" = "xno"
2281         then
2282                 AC_MSG_ERROR([Lua support was requested, but is not available])
2283         fi
2284 fi
2285 if test "x$have_lua" = "xyes"
2286 then
2287         AC_DEFINE(HAVE_LUA, 1, [Define to use Lua])
2288 fi
2289 AM_CONDITIONAL(HAVE_LIBLUA, test x$have_lua = xyes)
2290 AC_SUBST(LUA_LIBS)
2291 AC_SUBST(LUA_CFLAGS)
2292
2293
2294 dnl portaudio check
2295 AC_MSG_CHECKING(whether to use libportaudio for the GTK+ RTP player)
2296
2297 AC_ARG_WITH(portaudio,
2298   AC_HELP_STRING( [--with-portaudio@<:@=DIR@:>@],
2299                   [use libportaudio (located in directory DIR, if supplied) for the GTK+ RTP player @<:@default=yes, if available@:>@]),
2300 [
2301         if test $withval = no
2302         then
2303                 want_portaudio=no
2304         elif test $withval = yes
2305         then
2306                 want_portaudio=yes
2307         else
2308                 want_portaudio=yes
2309                 portaudio_dir=$withval
2310         fi
2311 ],[
2312         #
2313         # Use libportaudio by default
2314         #
2315         want_portaudio=ifavailable
2316         portaudio_dir=
2317 ])
2318 if test "x$want_portaudio" = "xno" ; then
2319         AC_MSG_RESULT(no)
2320 else
2321         AC_MSG_RESULT(yes)
2322         AC_WIRESHARK_LIBPORTAUDIO_CHECK
2323         if test "x$want_portaudio" = "xno" ; then
2324                 AC_MSG_RESULT(libportaudio not found - disabling support for the GTK+ RTP player)
2325         fi
2326 fi
2327 AM_CONDITIONAL(HAVE_LIBPORTAUDIO, test x$want_portaudio = xyes)
2328
2329
2330 dnl Check if dumpcap should be installed with filesystem capabilities
2331 AC_PATH_PROG(SETCAP, setcap)
2332 AC_ARG_ENABLE(setcap-install,
2333   AC_HELP_STRING( [--enable-setcap-install],
2334                   [install dumpcap with cap_net_admin and cap_net_raw @<:@default=no@:>@]),
2335     enable_setcap_install=$enableval,enable_setcap_install=no)
2336
2337 AC_MSG_CHECKING(whether to install dumpcap with cap_net_admin and cap_net_raw capabilities)
2338 if test "x$enable_setcap_install" = "xno" ; then
2339         AC_MSG_RESULT(no)
2340 else
2341         if test "x$SETCAP" = "x" ; then
2342                 AC_MSG_RESULT(setcap not found)
2343                 AC_MSG_ERROR([Setcap install was requested, but setcap was not found])
2344         elif test "x$enable_dumpcap" = "xno" ; then
2345                 AC_MSG_RESULT(dumpcap disabled)
2346                 AC_MSG_ERROR([Setcap install works only with dumpcap, but dumpcap is disabled])
2347         else
2348                 AC_MSG_RESULT(yes)
2349         fi
2350 fi
2351
2352 AM_CONDITIONAL(SETCAP_INSTALL, test x$enable_setcap_install = xyes)
2353
2354 dnl Check if dumpcap should be installed setuid
2355 AC_ARG_ENABLE(setuid-install,
2356   AC_HELP_STRING( [--enable-setuid-install],
2357                   [install dumpcap as setuid @<:@default=no@:>@]),
2358     enable_setuid_install=$enableval,enable_setuid_install=no)
2359
2360 AC_MSG_CHECKING(whether to install dumpcap setuid)
2361 if test "x$enable_setuid_install" = "xno" ; then
2362         AC_MSG_RESULT(no)
2363 else
2364         if test "x$enable_setcap_install" = "xyes" ; then
2365                 enable_setuid_install=no
2366                 AC_MSG_RESULT(setcap and setuid both selected)
2367                 AC_MSG_ERROR(You must choose one of setcap install and setuid install)
2368         elif test "x$enable_dumpcap" = "xno" ; then
2369                 AC_MSG_RESULT(dumpcap disabled)
2370                 AC_MSG_ERROR([Setuid install works only with dumpcap, but dumpcap is disabled])
2371         else
2372                 AC_MSG_RESULT(yes)
2373         fi
2374 fi
2375
2376 AM_CONDITIONAL(SETUID_INSTALL, test x$enable_setuid_install = xyes)
2377 AC_CHECK_FUNCS(setresuid setresgid)
2378
2379 dnl ...but our Network Operations group is named "no"!
2380 DUMPCAP_GROUP=''
2381 AC_ARG_WITH(dumpcap-group,
2382   AC_HELP_STRING( [--with-dumpcap-group=GROUP],
2383                   [restrict dumpcap to GROUP]),
2384 [
2385   if test "x$withval" = "xyes"; then
2386       AC_MSG_ERROR([No dumpcap group specified.])
2387   elif test "x$withval" != "xno"; then
2388       if test "x$enable_dumpcap" = "xno" ; then
2389           AC_MSG_ERROR(dumpcap group install works only with dumpcap but dumpcap is disabled)
2390       fi
2391       AC_MSG_RESULT($withval)
2392       DUMPCAP_GROUP="$withval"
2393   fi
2394 ])
2395 AC_SUBST(DUMPCAP_GROUP)
2396 AM_CONDITIONAL(HAVE_DUMPCAP_GROUP, test x$DUMPCAP_GROUP != x)
2397
2398 dnl libcap (not libpcap) check
2399 LIBCAP_LIBS=''
2400 AC_MSG_CHECKING(whether to use the libcap capabilities library)
2401
2402 AC_ARG_WITH(libcap,
2403   AC_HELP_STRING( [--with-libcap@<:@=DIR@:>@],
2404                   [use libcap (located in directory DIR, if supplied) for POSIX.1e capabilities management @<:@default=yes, if present@:>@]),
2405 [
2406 if   test "x$withval" = "xno";  then
2407         want_libcap=no
2408 elif test "x$withval" = "xyes"; then
2409         want_libcap=yes
2410 elif test -d "$withval"; then
2411         want_libcap=yes
2412         AC_WIRESHARK_ADD_DASH_L(WS_LDFLAGS, ${withval}/lib)
2413 fi
2414 ])
2415 if test "x$with_libcap" = "xno" ; then
2416         AC_MSG_RESULT(no)
2417 else
2418         AC_MSG_RESULT(yes)
2419         AC_WIRESHARK_LIBCAP_CHECK
2420 fi
2421 AC_SUBST(LIBCAP_LIBS)
2422
2423 dnl Checks for header files.
2424 dnl Some of these may not be needed: http://hacks.owlfolio.org/header-survey/
2425 dnl Note, however, that, whilst this script is generally run only on UN*Xes:
2426 dnl
2427 dnl     1) we also support building on and for Windows and not all of those
2428 dnl        headers are present on Windows, so the code has to check a
2429 dnl        #define *anyway* to determine whether to include the header
2430 dnl        file
2431 dnl
2432 dnl and
2433 dnl
2434 dnl     2) this might also be run on Windows with a sufficiently UNIXy
2435 dnl        environment such as Cygwin (although Wireshark should be built
2436 dnl        natively rather than using Cygwin).
2437 dnl
2438 AC_CHECK_HEADERS(fcntl.h getopt.h grp.h inttypes.h netdb.h pwd.h unistd.h)
2439 AC_CHECK_HEADERS(sys/ioctl.h sys/param.h sys/socket.h sys/sockio.h sys/stat.h sys/time.h sys/types.h sys/utsname.h sys/wait.h)
2440 AC_CHECK_HEADERS(netinet/in.h)
2441 AC_CHECK_HEADERS(arpa/inet.h arpa/nameser.h)
2442 AC_CHECK_HEADERS(ifaddrs.h)
2443
2444 #
2445 # On Linux, check for some additional headers, which we need as a
2446 # workaround for a bonding driver bug and for libpcap's current lack
2447 # of its own workaround for that bug.
2448 #
2449 case "$host_os" in
2450 linux*)
2451         AC_CHECK_HEADERS(linux/sockios.h linux/if_bonding.h,,,[#include <sys/socket.h>])
2452         ;;
2453 esac
2454
2455 dnl SSL Check
2456 SSL_LIBS=''
2457 AC_MSG_CHECKING(whether to use SSL library)
2458
2459 AC_ARG_WITH(ssl,
2460   AC_HELP_STRING( [--with-ssl@<:@=DIR@:>@],
2461                   [use SSL crypto library (located in directory DIR, if supplied) @<:@default=no@:>@]),
2462 [
2463 if test "x$withval" = "xno";  then
2464         want_ssl=no
2465 elif test "x$withval" = "xyes"; then
2466         want_ssl=yes
2467 elif test -d "$withval"; then
2468         want_ssl=yes
2469         AC_WIRESHARK_ADD_DASH_L(WS_LDFLAGS, ${withval}/lib)
2470 fi
2471 ],[
2472         want_ssl=no
2473 ])
2474 if test "x$want_ssl" = "xyes"; then
2475         AC_MSG_RESULT(yes)
2476         AC_CHECK_LIB(crypto,EVP_md5,
2477             [
2478                 SSL_LIBS=-lcrypto
2479             ],
2480             [
2481                 AC_MSG_ERROR([SSL crypto library was requested, but is not available])
2482             ])
2483 else
2484         AC_MSG_RESULT(no)
2485 fi
2486 AC_SUBST(SSL_LIBS)
2487
2488 dnl kerberos check
2489 AC_MSG_CHECKING(whether to use Kerberos library)
2490
2491 AC_ARG_WITH(krb5,
2492   AC_HELP_STRING( [--with-krb5@<:@=DIR@:>@],
2493                   [use Kerberos library (located in directory DIR, if supplied) to use in Kerberos dissection @<:@default=yes@:>@]),
2494 [
2495         if test $withval = no
2496         then
2497                 want_krb5=no
2498         elif test $withval = yes
2499         then
2500                 want_krb5=yes
2501         else
2502                 want_krb5=yes
2503                 krb5_dir=$withval
2504         fi
2505 ],[
2506         #
2507         # Use Kerberos library if available, otherwise don't.
2508         #
2509         want_krb5=ifavailable
2510         krb5_dir=
2511 ])
2512 if test "x$want_krb5" = "xno" ; then
2513         AC_MSG_RESULT(no)
2514 else
2515         AC_MSG_RESULT(yes)
2516         AC_WIRESHARK_KRB5_CHECK
2517 fi
2518
2519
2520 dnl c-ares Check
2521 C_ARES_LIBS=''
2522 AC_MSG_CHECKING(whether to use the c-ares library if available)
2523
2524 AC_ARG_WITH(c-ares,
2525   AC_HELP_STRING( [--with-c-ares@<:@=DIR@:>@],
2526                   [use c-ares (located in directory DIR, if supplied) @<:@default=yes, if present@:>@]),
2527 [
2528 if   test "x$withval" = "xno";  then
2529         want_c_ares=no
2530 elif test "x$withval" = "xyes"; then
2531         want_c_ares=yes
2532 elif test -d "$withval"; then
2533         want_c_ares=yes
2534         AC_WIRESHARK_ADD_DASH_L(WS_LDFLAGS, ${withval}/lib)
2535 fi
2536 ])
2537 if test "x$want_c_ares" = "xno" ; then
2538         AC_MSG_RESULT(no)
2539 else
2540         AC_MSG_RESULT(yes)
2541         AC_WIRESHARK_C_ARES_CHECK
2542 fi
2543 AC_SUBST(C_ARES_LIBS)
2544
2545 dnl GEOIP Check
2546 GEOIP_LIBS=''
2547 AC_MSG_CHECKING(whether to use the GeoIP IP address mapping library if available)
2548
2549 AC_ARG_WITH(geoip,
2550   AC_HELP_STRING( [--with-geoip@<:@=DIR@:>@],
2551                   [use GeoIP (located in directory DIR, if supplied) @<:@default=yes, if present@:>@]),
2552 [
2553 if   test "x$withval" = "xno";  then
2554         want_geoip=no
2555 elif test "x$withval" = "xyes"; then
2556         want_geoip=yes
2557 elif test -d "$withval"; then
2558         want_geoip=yes
2559         AC_WIRESHARK_ADD_DASH_L(WS_LDFLAGS, ${withval}/lib)
2560 fi
2561 ])
2562 if test "x$want_geoip" = "xno"; then
2563         AC_MSG_RESULT(no)
2564 else
2565         AC_MSG_RESULT(yes)
2566         AC_WIRESHARK_GEOIP_CHECK
2567 fi
2568 AC_SUBST(GEOIP_LIBS)
2569
2570 dnl LIBSSH Check
2571 LIBSSH=''
2572 AC_MSG_CHECKING(whether to use the libssh library if available)
2573
2574 AC_ARG_WITH(ssh,
2575   AC_HELP_STRING( [--with-libssh@<:@=DIR@:>@],
2576                   [use libssh (located in directory DIR, if supplied) @<:@default=yes, if present@:>@]),
2577 [
2578 if   test "x$withval" = "xno";  then
2579         want_libssh=no
2580 elif test "x$withval" = "xyes"; then
2581         want_libssh=yes
2582 elif test -d "$withval"; then
2583         want_libssh=yes
2584         AC_WIRESHARK_ADD_DASH_L(WS_LDFLAGS, ${withval}/lib)
2585 fi
2586 ])
2587 if test "x$want_libssh" = "xno"; then
2588         AC_MSG_RESULT(no)
2589 else
2590         AC_MSG_RESULT(yes)
2591         AC_WIRESHARK_LIBSSH_CHECK
2592 fi
2593 AC_SUBST(LIBSSH_LIBS)
2594
2595 dnl Checks for typedefs, structures, and compiler characteristics.
2596 # AC_C_CONST
2597
2598 # Check how we can get the time zone abbreviation
2599 AC_STRUCT_TIMEZONE
2600
2601 # We need to know whether "struct stat" has an "st_flags" member
2602 # for file_user_immutable().
2603
2604 AC_CHECK_MEMBERS([struct stat.st_flags])
2605
2606 # We need to know whether "struct sockaddr" has an "sa_len" member
2607 # for get_interface_list().
2608
2609 AC_CHECK_MEMBERS([struct sockaddr.sa_len])
2610
2611 # We must know our byte order
2612 AC_C_BIGENDIAN
2613
2614 # Checks whether "-traditional" is needed when using "ioctl".
2615 # XXX - do we need this?
2616 AC_PROG_GCC_TRADITIONAL
2617
2618 AC_REPLACE_FUNCS(getopt_long)
2619 dnl
2620 dnl Do we have optreset?
2621 dnl
2622 if test "x$ac_cv_func_getopt_long" = xyes; then
2623   AC_CACHE_CHECK([whether optreset is defined], ac_cv_have_optreset,
2624     AC_LINK_IFELSE([AC_LANG_SOURCE([[extern int optreset;return optreset;]])],
2625         ac_cv_have_optreset=yes, ac_cv_have_optreset=no))
2626   if test "$ac_cv_have_optreset" = yes ; then
2627     AC_DEFINE(HAVE_OPTRESET, 1, [Define to 1 if you have the optreset variable])
2628   fi
2629 fi
2630
2631 AC_REPLACE_FUNCS(inet_aton)
2632
2633 AC_CHECK_FUNC(inet_pton, [
2634   dnl check for pre-BIND82 inet_pton() bug.
2635   AC_MSG_CHECKING(for broken inet_pton)
2636   AC_TRY_RUN([#include <sys/types.h>
2637 #include <sys/socket.h>
2638 #include <netinet/in.h>
2639 #include <arpa/inet.h>
2640 int main()
2641 {
2642 #ifdef AF_INET6
2643   char buf[16];
2644   /* this should return 0 (error) */
2645   return inet_pton(AF_INET6, "0:1:2:3:4:5:6:7:", buf);
2646 #else
2647   return 1;
2648 #endif
2649 }], [AC_MSG_RESULT(ok);
2650 have_inet_pton=yes], [AC_MSG_RESULT(broken);
2651 have_inet_pton=no], [AC_MSG_RESULT([cross compiling, assume it is broken]);
2652 have_inet_pton=no])],
2653 have_inet_pton=no)
2654 if test "$have_inet_pton" = no; then
2655   AC_LIBOBJ(inet_pton)
2656 else
2657   AC_DEFINE(HAVE_INET_PTON, 1, [Define to 1 if you have the `inet_pton' function.])
2658 fi
2659
2660 AC_REPLACE_FUNCS(inet_ntop)
2661 AC_REPLACE_FUNCS(strptime)
2662 AC_REPLACE_FUNCS(popcount)
2663
2664 AC_CHECK_FUNCS(mkstemp mkdtemp)
2665 AC_CHECK_FUNCS(getprotobynumber)
2666 AC_CHECK_FUNCS(issetugid)
2667 AC_CHECK_FUNCS(sysconf)
2668 AC_CHECK_FUNCS(getifaddrs)
2669
2670 # Check Bluetooth SBC codec for RTP Player
2671 # git://git.kernel.org/pub/scm/bluetooth/sbc.git
2672 AC_ARG_WITH([sbc],
2673   AC_HELP_STRING( [--with-sbc=@<:@yes/no@:>@],
2674                   [use SBC codec to play Bluetooth A2DP stream @<:@default=yes, if available@:>@]),
2675   with_sbc="$withval"; want_sbc="yes", with_sbc="yes")
2676
2677 PKG_CHECK_MODULES(SBC, sbc >= 1.0, [have_sbc=yes], [have_sbc=no])
2678 if test "x$with_sbc" != "xno"; then
2679     if (test "${have_sbc}" = "yes"); then
2680         AC_DEFINE(HAVE_SBC, 1, [Define to support playing SBC by standalone BlueZ SBC library])
2681     elif test "x$want_sbc" = "xyes"; then
2682         # Error out if the user explicitly requested the sbc library
2683         AC_MSG_ERROR([SBC codec library was requested, but is not available])
2684     fi
2685 else
2686     have_sbc=no
2687 fi
2688 AM_CONDITIONAL(HAVE_SBC, test "x$have_sbc" = "xyes")
2689
2690 dnl
2691 dnl check whether plugins should be enabled and, if they should be,
2692 dnl check for plugins directory - stolen from Amanda's configure.ac
2693 dnl
2694 dnl we don't wish to expand ${libdir} yet
2695 plugindir="\${libdir}/wireshark/plugins/${VERSION}"
2696 AC_ARG_WITH(plugins,
2697   AC_HELP_STRING( [--with-plugins@<:@=DIR@:>@],
2698                   [support plugins (installed in DIR, if supplied) @<:@default=yes, if possible@:>@]),
2699 [
2700   if test "x$withval" = "xno"; then
2701     have_plugins=no
2702   elif test "x$have_plugins" = "xno"; then
2703       AC_MSG_ERROR([GLib on this platform doesn't support loadable modules, so you can't enable plugins.])
2704   elif test "x$withval" != "xyes"; then
2705       plugindir="$withval"
2706   fi
2707 ])
2708 AM_CONDITIONAL(HAVE_PLUGINS, test "x$have_plugins" = "xyes")
2709 if test x$have_plugins = xyes
2710 then
2711   AC_DEFINE(HAVE_PLUGINS, 1, [Define if plugins are enabled])
2712 fi
2713 AC_SUBST(plugindir)
2714
2715 #
2716 # The plugin dissectors reside in ./plugins/PROTO/
2717 #
2718 PLUGIN_LIBS=""
2719 AC_SUBST(PLUGIN_LIBS)
2720
2721 dnl
2722 dnl check whether extcap programs should be enabled and, if they should be,
2723 dnl check for extcap directory - stolen from Amanda's configure.ac
2724 dnl
2725 dnl we don't wish to expand ${libdir} yet
2726 extcapdir="\${libdir}/wireshark/extcap"
2727 AC_ARG_WITH(extcap,
2728   AC_HELP_STRING( [--with-extcap@<:@=DIR@:>@],
2729                   [use extcap for external capture sources (installed in DIR, if supplied) @<:@default=yes, if possible@:>@]),
2730 [
2731   if test "x$withval" = "xno"; then
2732       have_extcap=no
2733   elif test "x$withval" = "xyes"; then
2734       have_extcap=yes
2735   elif test "x$withval" != "xyes"; then
2736       have_extcap=yes
2737       extcapdir ="$withval"
2738   fi
2739 ],[
2740     have_extcap=yes
2741 ])
2742 AM_CONDITIONAL(HAVE_EXTCAP, test "x$have_extcap" = "xyes")
2743 if test "x$have_extcap" = "xyes"
2744 then
2745   AC_DEFINE(HAVE_EXTCAP, 1, [Define if external capture sources should be enabled])
2746   extcap_subdir="extcap"
2747   extcap_man="extcap.4"
2748 fi
2749 AC_SUBST(extcap_subdir)
2750 AC_SUBST(extcap_man)
2751 AC_SUBST(extcapdir)
2752
2753 dnl androiddump check
2754 AC_MSG_CHECKING(whether to build androiddump)
2755
2756 AC_ARG_ENABLE(androiddump,
2757   AC_HELP_STRING( [--enable-androiddump],
2758                   [build androiddump @<:@default=yes@:>@]),
2759     androiddump=$enableval,enable_androiddump=yes)
2760
2761 if test "x$have_extcap" != xyes; then
2762         AC_MSG_RESULT([no, extcap disabled])
2763         enable_androiddump=no
2764 elif test "x$enable_androiddump" = "xyes" ; then
2765         AC_MSG_RESULT(yes)
2766 else
2767         AC_MSG_RESULT(no)
2768 fi
2769
2770 AC_ARG_ENABLE(androiddump_use_libpcap,
2771   AC_HELP_STRING( [--enable-androiddump-use-libpcap],
2772                   [build androiddump using libpcap @<:@default=no@:>@]),
2773     androiddump_use_libpcap=$enableval,enable_androiddump_use_libpcap=no)
2774
2775 if test "x$enable_androiddump" = "xyes" -a "x$enable_androiddump_use_libpcap" = "xyes" ; then
2776         AC_DEFINE(ANDROIDDUMP_USE_LIBPCAP, 1, [Androiddump will use Libpcap])
2777 fi
2778
2779 if test "x$enable_androiddump" = "xyes" ; then
2780         androiddump_bin="androiddump\$(EXEEXT)"
2781         androiddump_man="androiddump.1"
2782 else
2783         androiddump_bin=""
2784         androiddump_man=""
2785 fi
2786 AC_SUBST(androiddump_bin)
2787 AC_SUBST(androiddump_man)
2788
2789 dnl sshdump check
2790 AC_MSG_CHECKING(whether to build sshdump)
2791
2792 AC_ARG_ENABLE(sshdump,
2793         AC_HELP_STRING( [--enable-sshdump],
2794                 [build sshdump @<:@default=yes@:>@]),
2795         [],[enable_sshdump=yes])
2796
2797 if test "x$have_extcap" != xyes; then
2798         AC_MSG_RESULT([no, extcap disabled])
2799         enable_sshdump=no
2800 elif test "x$have_good_libssh" != xyes; then
2801         AC_MSG_RESULT([no, libssh not available])
2802         enable_sshdump=no
2803 elif test "x$enable_sshdump" = "xyes" ; then
2804         AC_MSG_RESULT(yes)
2805 else
2806         AC_MSG_RESULT(no)
2807 fi
2808
2809 if test "x$enable_sshdump" = "xyes" ; then
2810         sshdump_bin="sshdump\$(EXEEXT)"
2811         sshdump_man="sshdump.1"
2812 else
2813         sshdump_bin=""
2814         sshdump_man=""
2815 fi
2816 AC_SUBST(sshdump_bin)
2817 AC_SUBST(sshdump_man)
2818
2819 dnl ciscodump check
2820 AC_MSG_CHECKING(whether to build ciscodump)
2821
2822 AC_ARG_ENABLE(ciscodump,
2823         AC_HELP_STRING( [--enable-ciscodump],
2824                 [build ciscodump @<:@default=yes@:>@]),
2825         [],[enable_ciscodump=yes])
2826
2827 if test "x$have_extcap" != xyes; then
2828         AC_MSG_RESULT([no, extcap disabled])
2829         enable_ciscodump=no
2830 elif test "x$have_good_libssh" != xyes; then
2831         AC_MSG_RESULT([no, libssh not available])
2832         enable_ciscodump=no
2833 elif test "x$enable_ciscodump" = "xyes" ; then
2834         AC_MSG_RESULT(yes)
2835 else
2836         AC_MSG_RESULT(no)
2837 fi
2838
2839 if test "x$enable_ciscodump" = "xyes" ; then
2840         ciscodump_bin="ciscodump\$(EXEEXT)"
2841         ciscodump_man="ciscodump.1"
2842 else
2843         ciscodump_bin=""
2844         ciscodump_man=""
2845 fi
2846 AC_SUBST(ciscodump_bin)
2847 AC_SUBST(ciscodump_man)
2848
2849 dnl randpktdump check
2850 AC_MSG_CHECKING(whether to build randpktdump)
2851
2852 AC_ARG_ENABLE(randpktdump,
2853         AC_HELP_STRING( [--enable-randpktdump],
2854                 [build randpktdump @<:@default=yes@:>@]),
2855         randpktdump=$enableval,enable_randpktdump=yes)
2856
2857 if test "x$have_extcap" != xyes; then
2858         AC_MSG_RESULT([no, extcap disabled])
2859         enable_randpktdump=no
2860 elif test "x$enable_randpktdump" = "xyes" ; then
2861         AC_MSG_RESULT(yes)
2862 else
2863         AC_MSG_RESULT(no)
2864 fi
2865
2866 if test "x$enable_randpktdump" = "xyes" ; then
2867         randpktdump_bin="randpktdump\$(EXEEXT)"
2868         randpktdump_man="randpktdump.1"
2869 else
2870         randpktdump_bin=""
2871         randpktdump_man=""
2872 fi
2873 AC_SUBST(randpktdump_bin)
2874 AC_SUBST(randpktdump_man)
2875
2876 AM_CONDITIONAL(ENABLE_STATIC, test x$enable_static = xyes)
2877 if test x$enable_static = xyes -a x$have_plugins = xyes
2878 then
2879   AC_DEFINE(ENABLE_STATIC, 1, [Link plugins statically into Wireshark])
2880 fi
2881 AC_SUBST(ENABLE_STATIC)
2882
2883 # Gather which GUI we're building for rpmbuild
2884 if test "x$have_gtk" = "xyes"; then
2885         if test "x$gtk_major_version" = "x3"; then
2886                 RPMBUILD_WITH_ARGS="--with gtk3 --without gtk2"
2887         else
2888                 RPMBUILD_WITH_ARGS="--without gtk3 --with gtk2"
2889         fi
2890 else
2891         RPMBUILD_WITH_ARGS="--without gtk2 --without gtk3"
2892 fi
2893 if test "x$have_qt" = "xyes" ; then
2894         if test "$qt_version" -eq "5"; then
2895                 RPMBUILD_WITH_ARGS="$RPMBUILD_WITH_ARGS --with qt5"
2896         else
2897                 RPMBUILD_WITH_ARGS="$RPMBUILD_WITH_ARGS --with qt"
2898         fi
2899 else
2900         RPMBUILD_WITH_ARGS="$RPMBUILD_WITH_ARGS --without qt --without qt5"
2901 fi
2902 if test "x$have_lua" = "xyes" ; then
2903         RPMBUILD_WITH_ARGS="$RPMBUILD_WITH_ARGS --with lua"
2904 else
2905         RPMBUILD_WITH_ARGS="$RPMBUILD_WITH_ARGS --without lua"
2906 fi
2907 AC_SUBST(RPMBUILD_WITH_ARGS)
2908 AC_SUBST(RPM_VERSION, version_major.version_minor.version_micro)
2909
2910 AC_SUBST(WS_CPPFLAGS)
2911 AC_SUBST(WS_CFLAGS)
2912 AC_SUBST(WS_CXXFLAGS)
2913 AC_SUBST(WS_LDFLAGS)
2914
2915 AC_SUBST(WS_CFLAGS_FOR_BUILD)
2916
2917 AH_BOTTOM([#include <ws_diag_control.h>])
2918
2919 dnl Save the cacheable configure results to config.cache before recursing
2920 AC_CACHE_SAVE
2921
2922 sinclude(plugins/Custom.m4) dnl
2923 ifdef(_CUSTOM_AC_OUTPUT_,, define(_CUSTOM_AC_OUTPUT_, )) dnl
2924
2925 sinclude(epan/dissectors/asn1/Custom.m4) dnl
2926 ifdef(_CUSTOM_ASN1_AC_OUTPUT_,, define(_CUSTOM_ASN1_AC_OUTPUT_, )) dnl
2927
2928 AC_CONFIG_HEADERS([config.h])
2929
2930 AC_CONFIG_FILES(
2931   Makefile
2932   doxygen.cfg
2933   epan/dissectors/asn1/Makefile
2934   wireshark.pc
2935   _CUSTOM_ASN1_AC_OUTPUT_
2936   epan/dissectors/asn1/acp133/Makefile
2937   epan/dissectors/asn1/acse/Makefile
2938   epan/dissectors/asn1/ansi_map/Makefile
2939   epan/dissectors/asn1/ansi_tcap/Makefile
2940   epan/dissectors/asn1/atn-cm/Makefile
2941   epan/dissectors/asn1/atn-cpdlc/Makefile
2942   epan/dissectors/asn1/atn-ulcs/Makefile
2943   epan/dissectors/asn1/c1222/Makefile
2944   epan/dissectors/asn1/camel/Makefile
2945   epan/dissectors/asn1/cdt/Makefile
2946   epan/dissectors/asn1/charging_ase/Makefile
2947   epan/dissectors/asn1/cmip/Makefile
2948   epan/dissectors/asn1/cmp/Makefile
2949   epan/dissectors/asn1/crmf/Makefile
2950   epan/dissectors/asn1/cms/Makefile
2951   epan/dissectors/asn1/credssp/Makefile
2952   epan/dissectors/asn1/dap/Makefile
2953   epan/dissectors/asn1/disp/Makefile
2954   epan/dissectors/asn1/dop/Makefile
2955   epan/dissectors/asn1/dsp/Makefile
2956   epan/dissectors/asn1/ess/Makefile
2957   epan/dissectors/asn1/ftam/Makefile
2958   epan/dissectors/asn1/goose/Makefile
2959   epan/dissectors/asn1/gprscdr/Makefile
2960   epan/dissectors/asn1/gsm_map/Makefile
2961   epan/dissectors/asn1/h225/Makefile
2962   epan/dissectors/asn1/h235/Makefile
2963   epan/dissectors/asn1/h245/Makefile
2964   epan/dissectors/asn1/h248/Makefile
2965   epan/dissectors/asn1/h282/Makefile
2966   epan/dissectors/asn1/h283/Makefile
2967   epan/dissectors/asn1/h323/Makefile
2968   epan/dissectors/asn1/h450/Makefile
2969   epan/dissectors/asn1/h450-ros/Makefile
2970   epan/dissectors/asn1/h460/Makefile
2971   epan/dissectors/asn1/h501/Makefile
2972   epan/dissectors/asn1/HI2Operations/Makefile
2973   epan/dissectors/asn1/hnbap/Makefile
2974   epan/dissectors/asn1/idmp/Makefile
2975   epan/dissectors/asn1/ilp/Makefile
2976   epan/dissectors/asn1/inap/Makefile
2977   epan/dissectors/asn1/isdn-sup/Makefile
2978   epan/dissectors/asn1/kerberos/Makefile
2979   epan/dissectors/asn1/lcsap/Makefile
2980   epan/dissectors/asn1/ldap/Makefile
2981   epan/dissectors/asn1/logotypecertextn/Makefile
2982   epan/dissectors/asn1/lpp/Makefile
2983   epan/dissectors/asn1/lppa/Makefile
2984   epan/dissectors/asn1/lppe/Makefile
2985   epan/dissectors/asn1/lte-rrc/Makefile
2986   epan/dissectors/asn1/m3ap/Makefile
2987   epan/dissectors/asn1/mms/Makefile
2988   epan/dissectors/asn1/mpeg-audio/Makefile
2989   epan/dissectors/asn1/mpeg-pes/Makefile
2990   epan/dissectors/asn1/nbap/Makefile
2991   epan/dissectors/asn1/ns_cert_exts/Makefile
2992   epan/dissectors/asn1/novell_pkis/Makefile
2993   epan/dissectors/asn1/ocsp/Makefile
2994   epan/dissectors/asn1/p1/Makefile
2995   epan/dissectors/asn1/p22/Makefile
2996   epan/dissectors/asn1/p7/Makefile
2997   epan/dissectors/asn1/p772/Makefile
2998   epan/dissectors/asn1/pcap/Makefile
2999   epan/dissectors/asn1/pkcs1/Makefile
3000   epan/dissectors/asn1/pkcs12/Makefile
3001   epan/dissectors/asn1/pkinit/Makefile
3002   epan/dissectors/asn1/pkixac/Makefile
3003   epan/dissectors/asn1/pkix1explicit/Makefile
3004   epan/dissectors/asn1/pkix1implicit/Makefile
3005   epan/dissectors/asn1/pkixproxy/Makefile
3006   epan/dissectors/asn1/pkixqualified/Makefile
3007   epan/dissectors/asn1/pkixtsp/Makefile
3008   epan/dissectors/asn1/pres/Makefile
3009   epan/dissectors/asn1/q932/Makefile
3010   epan/dissectors/asn1/q932-ros/Makefile
3011   epan/dissectors/asn1/qsig/Makefile
3012   epan/dissectors/asn1/ranap/Makefile
3013   epan/dissectors/asn1/rnsap/Makefile
3014   epan/dissectors/asn1/ros/Makefile
3015   epan/dissectors/asn1/rrc/Makefile
3016   epan/dissectors/asn1/rrlp/Makefile
3017   epan/dissectors/asn1/rtse/Makefile
3018   epan/dissectors/asn1/rua/Makefile
3019   epan/dissectors/asn1/s1ap/Makefile
3020   epan/dissectors/asn1/sabp/Makefile
3021   epan/dissectors/asn1/sbc-ap/Makefile
3022   epan/dissectors/asn1/smrse/Makefile
3023   epan/dissectors/asn1/snmp/Makefile
3024   epan/dissectors/asn1/spnego/Makefile
3025   epan/dissectors/asn1/sv/Makefile
3026   epan/dissectors/asn1/t124/Makefile
3027   epan/dissectors/asn1/t125/Makefile
3028   epan/dissectors/asn1/t38/Makefile
3029   epan/dissectors/asn1/tcap/Makefile
3030   epan/dissectors/asn1/tetra/Makefile
3031   epan/dissectors/asn1/ulp/Makefile
3032   epan/dissectors/asn1/wlancertextn/Makefile
3033   epan/dissectors/asn1/x2ap/Makefile
3034   epan/dissectors/asn1/x509af/Makefile
3035   epan/dissectors/asn1/x509ce/Makefile
3036   epan/dissectors/asn1/x509if/Makefile
3037   epan/dissectors/asn1/x509sat/Makefile
3038   epan/dissectors/asn1/x721/Makefile
3039   capchild/Makefile
3040   capchild/doxygen.cfg
3041   caputils/Makefile
3042   caputils/doxygen.cfg
3043   doc/Makefile
3044   docbook/Makefile
3045   epan/Makefile
3046   epan/compress/Makefile
3047   epan/crypt/Makefile
3048   epan/doxygen.cfg
3049   epan/dfilter/Makefile
3050   epan/dissectors/Makefile
3051   epan/dissectors/dcerpc/Makefile
3052   epan/ftypes/Makefile
3053   epan/nghttp2/Makefile
3054   epan/wmem/Makefile
3055   epan/wslua/Makefile
3056   extcap/Makefile
3057   codecs/Makefile
3058   ui/Makefile
3059   ui/doxygen.cfg
3060   ui/gtk/Makefile
3061   ui/gtk/doxygen.cfg
3062   ui/cli/Makefile
3063   ui/qt/Makefile
3064   ui/qt/doxygen.cfg
3065   help/Makefile
3066   packaging/Makefile
3067   packaging/macosx/Info.plist
3068   packaging/macosx/Makefile
3069   packaging/macosx/osx-dmg.sh
3070   packaging/macosx/Wireshark_package.pmdoc/index.xml
3071   packaging/nsis/Makefile
3072   packaging/rpm/Makefile
3073   packaging/rpm/SPECS/Makefile
3074   packaging/rpm/SPECS/wireshark.spec
3075   packaging/svr4/Makefile
3076   packaging/svr4/checkinstall
3077   packaging/svr4/pkginfo
3078   plugins/Makefile
3079   plugins/docsis/Makefile
3080   plugins/easy_codec/Makefile
3081   plugins/ethercat/Makefile
3082   plugins/gryphon/Makefile
3083   plugins/irda/Makefile
3084   plugins/m2m/Makefile
3085   plugins/mate/Makefile
3086   plugins/opcua/Makefile
3087   plugins/profinet/Makefile
3088   plugins/stats_tree/Makefile
3089   plugins/unistim/Makefile
3090   plugins/wimax/Makefile
3091   plugins/wimaxasncp/Makefile
3092   plugins/wimaxmacphy/Makefile
3093   randpkt_core/doxygen.cfg
3094   randpkt_core/Makefile
3095   tools/Makefile
3096   tools/lemon/Makefile
3097   wiretap/Makefile
3098   writecap/Makefile
3099   writecap/doxygen.cfg
3100   wsutil/Makefile
3101   echld/Makefile
3102   _CUSTOM_AC_OUTPUT_
3103 )
3104
3105 AC_OUTPUT
3106
3107
3108 # Pretty messages
3109
3110 if test "x$have_gtk" = "xyes"; then
3111         gtk_lib_message=" (with GTK+ v$GTK_VERSION"
3112         if test "x$have_ige_mac" = "xyes"; then
3113                 gtk_lib_message="$gtk_lib_message and OS X integration)"
3114         else
3115                 gtk_lib_message="$gtk_lib_message)"
3116         fi
3117 fi
3118
3119 if test "x$have_qt" = "xyes" ; then
3120         enable_wireshark_qt="yes"
3121         qt_lib_message=" (with Qt$qt_version v$QT_VERSION)"
3122 else
3123         enable_wireshark_qt="no"
3124 fi
3125
3126 if test "x$enable_setcap_install" = "xyes" ; then
3127         setcap_message="yes"
3128 else
3129         setcap_message="no"
3130 fi
3131
3132 if test "x$enable_setuid_install" = "xyes" ; then
3133         setuid_message="yes"
3134 else
3135         setuid_message="no"
3136 fi
3137
3138 if test "x$DUMPCAP_GROUP" = "x" ; then
3139         dumpcap_group_message="(none)"
3140 else
3141         dumpcap_group_message="$DUMPCAP_GROUP"
3142 fi
3143
3144 if test "x$want_zlib" = "xno" ; then
3145         zlib_message="no"
3146 else
3147         zlib_message="yes"
3148 fi
3149
3150 if test "x$have_lua" = "xyes" ; then
3151         lua_message="yes"
3152 else
3153         lua_message="no"
3154 fi
3155
3156 if test "x$have_qt_multimedia_lib" = "xyes" ; then
3157         qt_multimedia_message="yes"
3158 else
3159         qt_multimedia_message="no"
3160 fi
3161
3162 if test "x$want_portaudio" = "xyes" ; then
3163         portaudio_message="yes"
3164 else
3165         portaudio_message="no"
3166 fi
3167
3168 if test "x$want_ssl" = "xno" ; then
3169         ssl_message="no"
3170 else
3171         ssl_message="yes"
3172 fi
3173
3174 if test "x$want_krb5" = "xno" ; then
3175         krb5_message="no"
3176 else
3177         krb5_message="yes ($ac_krb5_version)"
3178 fi
3179
3180 if test "x$have_good_c_ares" = "xyes" ; then
3181         c_ares_message="yes"
3182 else
3183         c_ares_message="no (name resolution will be disabled)"
3184 fi
3185
3186 if test "x$have_good_libcap" = "xyes" ; then
3187         libcap_message="yes"
3188 else
3189         libcap_message="no"
3190 fi
3191
3192 if test "x$have_good_geoip" = "xyes" ; then
3193         geoip_message="yes"
3194 else
3195         geoip_message="no"
3196 fi
3197
3198 if test "x$have_good_libssh" = "xyes" ; then
3199         libssh_message="yes"
3200 else
3201         libssh_message="no"
3202 fi
3203
3204 if test "x$have_ssh_userauth_agent" = "xyes" ; then
3205         ssh_userauth_agent_message="yes"
3206 else
3207         ssh_userauth_agent_message="no"
3208 fi
3209
3210 echo ""
3211 echo "  CPPFLAGS: $WS_CPPFLAGS $CPPFLAGS"
3212 echo ""
3213 echo "  CFLAGS: $WS_CFLAGS $CFLAGS"
3214 echo ""
3215 echo "  CXXFLAGS: $WS_CXXFLAGS $CXXFLAGS"
3216 echo ""
3217 echo "  LDFLAGS: $WS_LDFLAGS $LDFLAGS"
3218 echo ""
3219 echo "  LIBS: $LIBS"
3220
3221 echo ""
3222 echo "The Wireshark package has been configured with the following options:"
3223 echo "                       GLib version : v$GLIB_VERSION"
3224 echo "                    Build wireshark : $enable_wireshark_qt$qt_lib_message"
3225 echo "                Build wireshark-gtk : $have_gtk""$gtk_lib_message"
3226 echo "                       Build tshark : $enable_tshark"
3227 echo "                      Build tfshark : $enable_tfshark"
3228 echo "                     Build capinfos : $enable_capinfos"
3229 echo "                      Build captype : $enable_captype"
3230 echo "                      Build editcap : $enable_editcap"
3231 echo "                      Build dumpcap : $enable_dumpcap"
3232 echo "                     Build mergecap : $enable_mergecap"
3233 echo "                   Build reordercap : $enable_reordercap"
3234 echo "                    Build text2pcap : $enable_text2pcap"
3235 echo "                      Build randpkt : $enable_randpkt"
3236 echo "                       Build dftest : $enable_dftest"
3237 echo "                     Build rawshark : $enable_rawshark"
3238 echo "                  Build androiddump : $enable_androiddump"
3239 echo "                      Build sshdump : $enable_sshdump"
3240 echo "                    Build ciscodump : $enable_ciscodump"
3241 echo "                  Build randpktdump : $enable_randpktdump"
3242 echo "                        Build echld : $have_echld"
3243 echo ""
3244 echo "   Save files as pcap-ng by default : $enable_pcap_ng_default"
3245 echo "  Install dumpcap with capabilities : $setcap_message"
3246 echo "             Install dumpcap setuid : $setuid_message"
3247 echo "                  Use dumpcap group : $dumpcap_group_message"
3248 echo "                        Use plugins : $have_plugins"
3249 echo "       Use external capture sources : $have_extcap"
3250 echo "                    Use Lua library : $lua_message"
3251 echo "                Build Qt RTP player : $qt_multimedia_message"
3252 echo "              Build GTK+ RTP player : $portaudio_message"
3253 echo "             Build profile binaries : $enable_profile_build"
3254 echo "                   Use pcap library : $want_pcap"
3255 echo "                   Use zlib library : $zlib_message"
3256 echo "               Use kerberos library : $krb5_message"
3257 echo "                 Use c-ares library : $c_ares_message"
3258 echo "                Use SMI MIB library : $libsmi_message"
3259 echo "             Use GNU gcrypt library : $gcrypt_message"
3260 echo "             Use SSL crypto library : $ssl_message"
3261 echo "                 Use GnuTLS library : $tls_message"
3262 echo "     Use POSIX capabilities library : $libcap_message"
3263 echo "                  Use GeoIP library : $geoip_message"
3264 echo "                 Use libssh library : $libssh_message"
3265 echo "            Have ssh_userauth_agent : $ssh_userauth_agent_message"
3266 echo "                     Use nl library : $libnl_message"
3267 echo "              Use SBC codec library : $have_sbc"
3268 #echo "       Use GDK-Pixbuf with GResource: $have_gresource_pixbuf"