configure.ac

   1 #
   2 # Autoconf script for Wireshark
   3 #
   4
   5 #
   6 # Define variables for the components of the Wireshark version number.
   7 #
   8 m4_define([version_major], [1])
   9 m4_define([version_minor], [11])
  10 m4_define([version_micro], [4])
  11 m4_define([version_micro_extra], version_micro)
  12 m4_append([version_micro_extra], [])
  13
  14 AC_INIT(wireshark, [version_major.version_minor.version_micro_extra], http://bugs.wireshark.org/, , http://www.wireshark.org/)
  15 CONFIG_ARGS="$*"
  16 AC_SUBST(CONFIG_ARGS)
  17
  18 # Minimum autoconf version we require.
  19 AC_PREREQ(2.60)
  20 # Variable expansion doesn't work in AC_PREREQ()
  21 AC_MIN_VERSION=2.60
  22 AC_SUBST(AC_MIN_VERSION)
  23
  24 dnl Check for CPU / vendor / OS
  25 dnl The user is encouraged to use either `AC_CANONICAL_BUILD', or
  26 dnl `AC_CANONICAL_HOST', or `AC_CANONICAL_TARGET', depending on the
  27 dnl needs.  Using `AC_CANONICAL_TARGET' is enough to run the two other
  28 dnl macros.
  29 dnl
  30 dnl As nothing in the Wireshark is itself a build tool (we are not,
  31 dnl for example, a compiler that generates machine code), we probably
  32 dnl don't need AC_CANONICAL_TARGET, so, in theory, we should be able
  33 dnl to use AC_CANONICAL_BUILD and AC_CANONICAL_HOST - or perhaps just
  34 dnl AC_CANONICAL_HOST - instead.  Note that we do have tools, such as
  35 dnl lemon, that need to be built for the build machine, not for the
  36 dnl host machine, so we might need both.
  37 dnl
  38 dnl This has to be done *after* AC_INIT, otherwise autogen.sh fails.
  39
  40 dnl AC_CANONICAL_BUILD
  41 dnl AC_CANONICAL_HOST
  42 AC_CANONICAL_TARGET
  43
  44 AM_INIT_AUTOMAKE([1.9 tar-ustar dist-bzip2 no-dist-gzip])
  45
  46 # Make Wireshark's version available in config.h
  47 AC_DEFINE(VERSION_MAJOR, version_major, [Wireshark's major version])
  48 AC_DEFINE(VERSION_MINOR, version_minor, [Wireshark's minor version])
  49 AC_DEFINE(VERSION_MICRO, version_micro, [Wireshark's micro version])
  50
  51 AM_DISABLE_STATIC
  52
  53 #
  54 # Checks for programs used in the main build process.
  55 #
  56 AC_PROG_CC
  57 AM_PROG_CC_C_O
  58 AC_PROG_CXX
  59 AC_PROG_CPP
  60 AC_PROG_MKDIR_P
  61 AC_WIRESHARK_CLANG_CHECK
  62
  63 dnl Work around libtool bug (fixed in the version 1.5a?)
  64 AC_DEFUN([AC_PROVIDE_AC_LIBTOOL_DLOPEN], )
  65 AC_LIBTOOL_DLOPEN
  66 AC_PROG_LIBTOOL
  67 if test ! -z "$CXX"; then
  68         #
  69         # OK, we found something AC_LANG_CXX thinks is a C++ compiler,
  70         # but is it one?
  71         #
  72         # Some UN*Xes have, by default, a case-insensitive file
  73         # system, and AC_PROG_CXX looks for, among other things,
  74         # "CC" as a C++ compiler, and, if you have a case-insensitive
  75         # file system and a C compiler named "cc" (both true, by
  76         # default, on OS X), AC_PROG_CXX may end up thinking it's
  77         # the C++ compiler.
  78         #
  79         # So we check by feeding the purported C++ compiler a
  80         # program using C++ features (iostream).
  81         #
  82         # We do this after AC_PROG_LIBTOOL; if we did so before, and
  83         # cleared CXX if what we had isn't a C++ compiler, that'd
  84         # get undone by AC_PROG_LIBTOOL for some reason.
  85         #
  86         AC_MSG_CHECKING(whether $CXX is a C++ compiler)
  87         AC_LANG_PUSH([C++])
  88         AC_LINK_IFELSE([AC_LANG_PROGRAM(
  89         [
  90 #include <iostream>
  91         ],
  92         [
  93         std::cout << "Hello World! ";
  94         return 0;
  95         ])],
  96                 [AC_MSG_RESULT(yes)],
  97                 [
  98                         AC_MSG_RESULT(no)
  99                         CXX=""
 100                 ])
 101         AC_LANG_POP([C++])
 102 fi
 103 AC_PATH_PROG(PERL, perl)
 104
 105 # Check for Python.
 106 AC_PATH_PROG(PYTHON, python)
 107 if test ! -z "$PYTHON"; then
 108         #
 109         # OK, we found Python; is it Python 2.5 or later?
 110         # Note: we don't use named components for sys.version_info to get
 111         # the major version number, as named components for version_info
 112         # were apparently introduced in Python 2.7.
 113         #
 114         AC_MSG_CHECKING([whether $PYTHON is Python 2.5 or later])
 115         python_major_version=`$PYTHON -c 'import sys; print (sys.version_info[[0]])'`
 116         python_minor_version=`$PYTHON -c 'import sys; print (sys.version_info[[1]])'`
 117         if test "$python_major_version" -eq 2 -a "$python_minor_version" -lt 5 ; then
 118                 AC_MSG_RESULT(no)
 119                 AC_MSG_WARN([Building with Python $python_major_version.$python_minor_version may not work])
 120         else
 121                 AC_MSG_RESULT(yes)
 122         fi
 123 fi
 124
 125 #
 126 # XXX - should autogen.sh check for YACC/Bison and Flex?  A user building
 127 # from a distribution tarball shouldn't have to have YACC/Bison or Flex,
 128 # as the tarball should contain the results of running YACC/Bison on .y
 129 # files and running Flex on .l files, but a user building from SVN
 130 # will have to run YACC/Bison and Flex to process those files.
 131 #
 132 # On the other hand, what about users who use a distribution tarball to
 133 # do development?  They *shouldn't* - that's what the SVN repository is
 134 # for - but they might.  They'd get errors if they modify a .y or .l
 135 # file and try to do a build - but the error should tell them that they
 136 # need to get YACC/Bison and/or Flex.
 137 #
 138 # Then again, getting them shouldn't be too big of a burden.
 139 #
 140 # XXX - is the same true of pod2man and pod2html, or are they needed
 141 # even when building from a distribution tarball?
 142 #
 143 #
 144 AC_PROG_YACC
 145 AC_PATH_PROG(YACCDUMMY, $YACC)
 146 if test "x$YACCDUMMY" = x
 147 then
 148         AC_MSG_ERROR(I couldn't find yacc (or bison or ...); make sure it's installed and in your path)
 149 fi
 150 AM_PROG_LEX
 151 AC_PATH_PROG(LEX, flex)
 152 if test "x$LEX" = x
 153 then
 154         AC_MSG_ERROR(I couldn't find flex; make sure it's installed and in your path)
 155 fi
 156 AC_PATH_PROG(POD2MAN, pod2man)
 157 if test "x$POD2MAN" = x
 158 then
 159         #
 160         # The alternative is not to build the man pages....
 161         #
 162         AC_MSG_ERROR(I couldn't find pod2man; make sure it's installed and in your path)
 163 fi
 164 AC_PATH_PROG(POD2HTML, pod2html)
 165 if test "x$POD2HTML" = x
 166 then
 167         #
 168         # The alternative is not to build the HTML man pages....
 169         #
 170         AC_MSG_ERROR(I couldn't find pod2html; make sure it's installed and in your path)
 171 fi
 172
 173 #
 174 # Checks for programs used by Wireshark/TShark/etc.
 175 #
 176
 177 #
 178 # XXX - this looks for various HTML viewers on the host, not the target;
 179 # we really want to know what's available on the target, for cross-builds.
 180 # That would probably require us to, at run time, look for xdg-open and,
 181 # if we don't find it, look for mozilla, htmlview, etc.
 182 #
 183 AC_PATH_PROG(HTML_VIEWER, xdg-open)
 184 if test "x$HTML_VIEWER" != x
 185 then
 186         #
 187         # XXX - the HTML_VIEWER shell variable is the full path of xdg-open.
 188         # Define some variable to be that, so we just run that?
 189         #
 190         AC_DEFINE(HAVE_XDG_OPEN, 1, [Define if we have xdg-open])
 191
 192         #
 193         # XXX - we have to define HTML_VIEWER for the prefs.c code that
 194         # sets the default value of the Web browser preference, even
 195         # though that preference won't be offered.
 196         #
 197         AC_DEFINE_UNQUOTED(HTML_VIEWER, "xdg-open", [HTML viewer, e.g. mozilla])
 198 else
 199         AC_PATH_PROG(HTML_VIEWER, htmlview)
 200         if test "x$HTML_VIEWER" = x
 201         then
 202                 AC_DEFINE_UNQUOTED(HTML_VIEWER, "mozilla", [HTML viewer, e.g. mozilla])
 203         else
 204                 AC_DEFINE_UNQUOTED(HTML_VIEWER, "htmlview", [HTML viewer, e.g. mozilla])
 205         fi
 206 fi
 207
 208 #
 209 # Set "ac_supports_gcc_flags" if the compiler is known to support GCC-style
 210 # flags such as -pedantic, -W warning flags and -f feature flags.  Currently,
 211 # we assume GCC and clang do; other compilers should be added here.
 212 #
 213 # This is done to avoid getting tripped up by compilers that support
 214 # those flags but give them a different meaning.
 215 #
 216 if test "x$GCC" = "xyes" -o "x$CC" = "xclang" ; then
 217         ac_supports_gcc_flags=yes
 218 fi
 219
 220 #
 221 # Set "ac_supports_W_linker_passthrough" if the compiler is known to
 222 # support "-Wl,{options}" to pass options through to the linker.
 223 # Currently, we assume GCC, xlc, and clang do; other compilers should
 224 # be added here.
 225 #
 226 if test "x$GCC" = "xyes" -o "x$CC" = "xxlc" -o "x$CC" = "xclang" ; then
 227         ac_supports_W_linker_passthrough=yes
 228 fi
 229
 230 #
 231 # Set "ac_supports_attribute_unused" if the compiler is known to
 232 # support "__attribute__(unused)".
 233 # Currently, we assume GCC and clang do; other compilers should
 234 # be added here.
 235 #
 236 # XXX - do this with a compiler test?
 237 #
 238 if test "x$GCC" = "xyes" -o "x$CC" = "xclang" ; then
 239         ac_supports_W_linker_passthrough=yes
 240 fi
 241
 242 if test "x$CC_FOR_BUILD" = x
 243 then
 244        CC_FOR_BUILD=$CC
 245 fi
 246 AC_SUBST(CC_FOR_BUILD)
 247 AC_SUBST(CFLAGS_FOR_BUILD)
 248
 249 # Check for doxygen
 250 AC_PATH_PROG(DOXYGEN, doxygen)
 251 AC_CHECK_PROG(HAVE_DOXYGEN, doxygen, "yes", "no")
 252 AM_CONDITIONAL(HAVE_DOXYGEN, test x$HAVE_DOXYGEN = xyes)
 253
 254 #
 255 # Check for pkg-config and set PKG_CONFIG accordingly.
 256 #
 257 # This is referenced via AC_REQUIRE([PKG_PROG_PKG_CONFIG] in some macros
 258 # like PKG_CHECK_MODULES. If the first call to such a macro is under an
 259 # "if" statement, it's safer to call PKG_PROG_PKG_CONFIG directly, see
 260 # the comments in acolocal.m4
 261 #
 262 PKG_PROG_PKG_CONFIG
 263
 264 AC_ARG_ENABLE(osx-deploy-target,
 265   AC_HELP_STRING( [--enable-osx-deploy-target],
 266     [choose an OS X deployment target @<:@default=major release on which you're building@:>@]),
 267 [
 268         #
 269         # Is this OS X?
 270         #
 271         case "$host_os" in
 272         darwin*)
 273                 #
 274                 # Yes.
 275                 #
 276                 # Let the user specify an OS X release to use as a
 277                 # deplayment target; if they specify that we should
 278                 # have a deployment target but don't specify the
 279                 # deployment target, then, if we have SDKs available,
 280                 # pick the OS version on which the build is being done.
 281                 # This also causes the build to be done against an SDK
 282                 # rather than against the headers and libraries in
 283                 # /usr/include and /usr/lib.
 284                 #
 285                 # Check for an OS X deployment target early, so that
 286                 # as many tests using the compiler are done using the
 287                 # flags that we'll be using when building.
 288                 #
 289                 if test $enableval = no
 290                 then
 291                         #
 292                         # The user explicitly said
 293                         # --disable-osx-deploy-target, so don't build
 294                         # against an SDK.
 295                         #
 296                         deploy_target=
 297                 elif test $enableval = yes
 298                 then
 299                         #
 300                         # The user said --enable-osx-deploy-target, but
 301                         # didn't say what version to target; target the
 302                         # major version number of the version of OS X on
 303                         # which we're running.
 304                         #
 305                         # (We quote the command so that we can use
 306                         # autoconf's M4 quoting characters, [ and ], in
 307                         # the sed expression.)
 308                         #
 309                         [deploy_target=`sw_vers -productVersion | sed 's/\([0-9][0-9]*\)\.\([0-9][0-9]*\)\.[0-9]*/\1.\2/'`]
 310                 else
 311                         deploy_target="$enableval"
 312                 fi
 313                 ;;
 314
 315         *)
 316                 #
 317                 # No.  Fail, because whatever the user intended for us to
 318                 # do, we can't do it.
 319                 #
 320                 AC_MSG_ERROR([--enable-osx-deploy-target specified on an OS other than OS X])
 321                 ;;
 322         esac
 323 ],[
 324         #
 325         # Is this OS X?
 326         #
 327         case "$host_os" in
 328         darwin*)
 329                 #
 330                 # Yes.
 331                 #
 332                 # If we have SDKs available, default to targeting the major
 333                 # version number of the version of OS X on which we're
 334                 # running.
 335                 #
 336                 # (We quote the command so that we can use autoconf's
 337                 # M4 quoting characters, [ and ], in the sed expression.)
 338                 #
 339                 for i in /Developer/SDKs \
 340                     /Applications/Xcode.app/Contents/Developer/Platforms/MacOSX.platform/Developer/SDKs \
 341                     /Library/Developer/CommandLineTools/SDKs
 342                 do
 343                         if test -d "$i"
 344                         then
 345                                 [deploy_target=`sw_vers -productVersion | sed 's/\([0-9][0-9]*\)\.\([0-9][0-9]*\)\.[0-9]*/\1.\2/'`]
 346                                 break
 347                         fi
 348                 done
 349                 ;;
 350
 351         *)
 352                 #
 353                 # No.  There's nothing to do.
 354                 #
 355                 ;;
 356         esac
 357 ])
 358
 359 if test ! -z "$deploy_target"
 360 then
 361         AC_MSG_CHECKING([whether we can build for OS X $deploy_target])
 362         case $deploy_target in
 363
 364         10.0|10.1|10.2)
 365                 #
 366                 # I'm not sure this would even work.
 367                 #
 368                 AC_MSG_RESULT(no)
 369                 AC_ERROR([We don't support building for OS X $deploy_target])
 370                 ;;
 371
 372         10.3)
 373                 #
 374                 # XXX - never tested.
 375                 #
 376                 AC_MSG_RESULT(yes)
 377                 SDKPATH="/Developer/SDKs/MacOSX10.3.9.sdk"
 378                 ;;
 379
 380         *)
 381                 #
 382                 # XXX - for 10.4, do we need 10.4u?  We're
 383                 # not currently doing fat builds (we'd need
 384                 # fat versions of the support libraries for
 385                 # that to be useful), but, if we do, we'd
 386                 # need to use 10.4u.
 387                 #
 388                 for i in /Developer/SDKs \
 389                     /Applications/Xcode.app/Contents/Developer/Platforms/MacOSX.platform/Developer/SDKs \
 390                     /Library/Developer/CommandLineTools/SDKs
 391                 do
 392                         if test -d "$i"/"MacOSX$deploy_target.sdk"
 393                         then
 394                                 SDKPATH="$i"/"MacOSX$deploy_target.sdk"
 395                                 break
 396                         fi
 397                 done
 398                 if test -z "$SDKPATH"
 399                 then
 400                         AC_MSG_RESULT(no)
 401                         AC_MSG_ERROR([We couldn't find the SDK for OS X $deploy_target])
 402                 fi
 403                 AC_MSG_RESULT(yes)
 404                 ;;
 405         esac
 406
 407         #
 408         # Add a -mmacosx-version-min flag to force tests that
 409         # use the compiler, as well as the build itself, not to,
 410         # for example, use compiler or linker features not supported
 411         # by the minimum targeted version of the OS.
 412         #
 413         # Add an -isysroot flag to use the SDK.
 414         #
 415         CFLAGS="-mmacosx-version-min=$deploy_target -isysroot $SDKPATH $CFLAGS"
 416         CXXFLAGS="-mmacosx-version-min=$deploy_target -isysroot $SDKPATH $CXXFLAGS"
 417         LDFLAGS="-mmacosx-version-min=$deploy_target -isysroot $SDKPATH $LDFLAGS"
 418
 419         #
 420         # Add a -sdkroot flag to use with osx-app.sh.
 421         #
 422         OSX_APP_FLAGS="-sdkroot $SDKPATH"
 423
 424         #
 425         # XXX - do we need this to build the Wireshark wrapper?
 426         # XXX - is this still necessary with the -mmacosx-version-min
 427         # flag being set?
 428         #
 429         OSX_DEPLOY_TARGET="MACOSX_DEPLOYMENT_TARGET=$deploy_target"
 430
 431         #
 432         # In the installer package XML file, give the deployment target
 433         # as the minimum version.
 434         #
 435         OSX_MIN_VERSION="$deploy_target"
 436
 437         case $deploy_target in
 438
 439         10.4|10.5)
 440                 #
 441                 # Only 32-bit builds are supported.  10.5
 442                 # (and 10.4?) had a bug that causes some BPF
 443                 # functions not to work with 64-bit userland
 444                 # code, so capturing won't work.
 445                 #
 446                 CFLAGS="-m32 $CFLAGS"
 447                 CXXFLAGS="-m32 $CXXFLAGS"
 448                 LDFLAGS="-m32 $LDFLAGS"
 449                 ;;
 450         esac
 451 else
 452         #
 453         # Is this OS X?
 454         #
 455         case "$host_os" in
 456         darwin*)
 457                 #
 458                 # Yes.
 459                 #
 460                 # In the installer package XML file, give the current OS
 461                 # version, minor version and all, as the minimum version.
 462                 # We can't guarantee that the resulting binary will work
 463                 # on older OS versions, not even older minor versions
 464                 # (original release or earlier software updates).
 465                 #
 466                 OSX_MIN_VERSION=`sw_vers -productVersion`
 467                 ;;
 468         esac
 469 fi
 470 AC_SUBST(OSX_MIN_VERSION)
 471
 472 #
 473 # Try to arrange for large file support.
 474 #
 475 AC_SYS_LARGEFILE
 476
 477 #
 478 # GUI toolkit options
 479 #
 480 AC_ARG_WITH([qt],
 481   AC_HELP_STRING( [--with-qt=@<:@yes/no@:>@],
 482                   [use Qt @<:@default=yes@:>@]),
 483   with_qt="$withval", with_qt="unspecified")
 484
 485 AC_ARG_WITH([gtk2],
 486   AC_HELP_STRING( [--with-gtk2=@<:@yes/no@:>@],
 487                   [use GTK+ 2.0 @<:@default=no@:>@]),
 488   with_gtk2="$withval", with_gtk2="unspecified")
 489
 490 AC_ARG_WITH([gtk3],
 491   AC_HELP_STRING( [--with-gtk3=@<:@yes/no@:>@],
 492                   [use GTK+ 3.0 instead of 2.0 @<:@default=yes@:>@]),
 493   with_gtk3="$withval", with_gtk3="unspecified")
 494
 495 # GnuTLS
 496 # Version 3.0 switched from LGPLv2.1+ to LGPLv3+, then switched back to
 497 # LGPLv2.1+ in version 3.1.10.
 498 # GnuTLS depends on GMP which switched from LGPLv2.1+ to LGPLv3+ in
 499 # version 4.2.2, the switched to LGPLv3+ / GPLv2+ in version 6.0.0.
 500
 501 tls_message="no"
 502 AC_ARG_WITH([gnutls],
 503   AC_HELP_STRING( [--with-gnutls=@<:@yes/no@:>@],
 504                   [use GnuTLS library @<:@default=yes@:>@]),
 505   with_gnutls="$withval", with_gnutls="yes")
 506 if test "x$with_gnutls" = "xyes"; then
 507   have_license_compatible_gnutls="no"
 508   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 3.1.10 ],
 509     [ have_license_compatible_gnutls="yes" ], [ echo "GnuTLS >= 3.1.10 not found " ]
 510   )
 511
 512   if test "x$have_license_compatible_gnutls" != "xyes"; then
 513     PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 1.2.0 gnutls < 3],
 514       [ have_license_compatible_gnutls="yes" ] , [ echo "GnuTLS >= 1.2.0, < 3.0 not found " ]
 515     )
 516   fi
 517
 518   if test "x$have_license_compatible_gnutls" = "xyes"; then
 519     echo "GnuTLS found, enabling SSL decryption"
 520     AC_DEFINE(HAVE_LIBGNUTLS, 1, [Define to use GnuTLS library])
 521     tls_message="yes"
 522   else
 523     echo "GnuTLS with compatible license not found, disabling SSL decryption"
 524     tls_message="no"
 525   fi
 526 fi
 527
 528 # libgrypt
 529 gcrypt_message="no"
 530 AC_ARG_WITH([gcrypt],
 531   AC_HELP_STRING( [--with-gcrypt=@<:@yes/no@:>@],
 532                   [use gcrypt library @<:@default=yes@:>@]),
 533   with_gcrypt="$withval", with_gcrypt="yes")
 534 if test "x$with_gcrypt" = "xyes"; then
 535   AM_PATH_LIBGCRYPT(1.1.92,
 536         [
 537                 echo "libgcrypt found, enabling ipsec decryption"
 538                 AC_DEFINE(HAVE_LIBGCRYPT, 1, [Define to use libgcrypt])
 539                 gcrypt_message="yes"
 540         ]
 541         , [
 542                 if test x$libgcrypt_config_prefix != x ; then
 543                         AC_MSG_ERROR([[libgcrypt not found; install libgcrypt-devel package for your system]])
 544                 else
 545                         echo "libgcrypt not found, disabling ipsec decryption"
 546                         gcrypt_message="no"
 547                 fi
 548         ]
 549   )
 550 fi
 551
 552 AC_ARG_WITH(libnl,
 553   AC_HELP_STRING([--with-libnl@<:@=VERSION@:>@],
 554                  [use libnl (force version VERSION, if supplied) @<:@default: yes, if available@:>@]),
 555 [
 556         if test "x$withval" = "xno"
 557         then
 558                 want_libnl=no
 559         elif test "x$withval" = "xyes"
 560         then
 561                 want_libnl=yes
 562                 libnl_version=any
 563         elif test "x$withval" = "x1"
 564         then
 565                 want_libnl=yes
 566                 libnl_version=1
 567         elif test "x$withval" = "x2"
 568         then
 569                 want_libnl=yes
 570                 libnl_version=2
 571         elif test "x$withval" = "x3"
 572         then
 573                 want_libnl=yes
 574                 libnl_version=3
 575         else
 576                 AC_MSG_ERROR(["$withval" is not a valid argument to --with-libnl])
 577         fi
 578 ],[
 579         #
 580         # Use libnl if it's present, otherwise don't.
 581         #
 582         want_libnl=ifavailable
 583         libnl_version=any
 584 ])
 585 #
 586 # Libnl is Linux-specific.
 587 #
 588 libnl_message="no"
 589 case "$host_os" in
 590 linux*)
 591         AC_MSG_CHECKING(whether to use libnl for various network interface purposes)
 592
 593         if test x$want_libnl = "xno"; then
 594                 AC_MSG_RESULT(no)
 595         else
 596                 AC_MSG_RESULT(yes)
 597                 #
 598                 # Test for specific libnl versions only if no version
 599                 # was specified by the user or if the version in question
 600                 # was requested by the user.
 601                 #
 602                 if test x$libnl_version = "xany" -o x$libnl_version = "x3"; then
 603                         PKG_CHECK_MODULES(LIBNL3, [libnl-route-3.0 >= 3.0 libnl-genl-3.0] >= 3.0, [have_libnl3=yes], [have_libnl3=no])
 604                 fi
 605                 if test x$libnl_version = "xany" -o x$libnl_version = "x2"; then
 606                         PKG_CHECK_MODULES(LIBNL2, libnl-2.0 >= 2.0, [have_libnl2=yes], [have_libnl2=no])
 607                 fi
 608                 if test x$libnl_version = "xany" -o x$libnl_version = "x1"; then
 609                         PKG_CHECK_MODULES(LIBNL1, libnl-1 >= 1.0, [have_libnl1=yes], [have_libnl1=no])
 610                 fi
 611                 if (test "${have_libnl3}" = "yes"); then
 612                         CFLAGS="$CFLAGS $LIBNL3_CFLAGS"
 613                         LIBS="$LIBS $LIBNL3_LIBS"
 614                         AC_DEFINE(HAVE_LIBNL, 1, [Enable libnl support])
 615                         AC_DEFINE(HAVE_LIBNL3, 1, [libnl version 3])
 616                         libnl_message="yes (v3)"
 617                         enable_airpcap=no
 618                 elif (test "${have_libnl2}" = "yes"); then
 619                         CFLAGS="$CFLAGS $LIBNL2_CFLAGS"
 620                         LIBS="$LIBS $LIBNL2_LIBS"
 621                         AC_DEFINE(HAVE_LIBNL, 1, [Enable libnl support])
 622                         AC_DEFINE(HAVE_LIBNL2, 1, [libnl version 2])
 623                         libnl_message="yes (v2)"
 624                         enable_airpcap=no
 625                 elif (test "${have_libnl1}" = "yes"); then
 626                         CFLAGS="$CFLAGS $LIBNL1_CFLAGS"
 627                         LIBS="$LIBS $LIBNL1_LIBS"
 628                         AC_DEFINE(HAVE_LIBNL, 1, [Enable libnl support])
 629                         AC_DEFINE(HAVE_LIBNL1, 1, [libnl version 1])
 630                         libnl_message="yes (v1)"
 631                         enable_airpcap=no
 632                 else
 633                         if test x$want_libnl = "xyes"; then
 634                                 case "$libnl_version" in
 635
 636                                 any)
 637                                         AC_MSG_ERROR("I couldn't find libnl even though you manually enabled it.")
 638                                         ;;
 639
 640                                 *)
 641                                         AC_MSG_ERROR("I couldn't find libnl version $libnl_version even though you manually enabled it.")
 642                                         ;;
 643                                 esac
 644                         fi
 645                 fi
 646         fi
 647
 648         AC_MSG_CHECKING([if nl80211.h is new enough])
 649           AC_TRY_COMPILE([#include <linux/nl80211.h>],
 650             [int x = NL80211_FREQUENCY_ATTR_MAX_TX_POWER;
 651                 x = NL80211_ATTR_SUPPORTED_IFTYPES;
 652                 x = NL80211_ATTR_SUPPORTED_COMMANDS;
 653                 x = NL80211_ATTR_WIPHY_FREQ;
 654                 x = NL80211_CHAN_NO_HT;],
 655             [AC_MSG_RESULT(yes) AC_DEFINE(HAVE_NL80211, 1, [nl80211.h is new enough])],
 656             [AC_MSG_RESULT(no)])
 657
 658         AC_MSG_CHECKING([for NL80211_SET_CHANNEL])
 659           AC_TRY_COMPILE([#include <linux/nl80211.h>],
 660             [enum nl80211_commands x = NL80211_CMD_SET_CHANNEL;],
 661             [AC_MSG_RESULT(yes) AC_DEFINE(HAVE_NL80211_CMD_SET_CHANNEL, 1, [SET_CHANNEL is supported])],
 662             [AC_MSG_RESULT(no)])
 663         ;;
 664
 665 *)
 666         if test x$want_libnl != "xno" -a x$want_libnl != "xifavailable"; then
 667                 AC_MSG_WARN([libnl is Linux-specific, ignoring --with-libnl])
 668         fi
 669 esac
 670
 671 # libsmi
 672 # FIXME: currently the path argument to with-libsmi is being ignored
 673 AX_LIBSMI
 674
 675 #
 676 # Check for programs used when building DocBook documentation.
 677 #
 678
 679 # Check for a2x (convert asciidoc to another format)
 680 AC_PATH_PROG(A2X, a2x)
 681 AC_CHECK_PROG(HAVE_A2X, a2x, "yes", "no")
 682 AM_CONDITIONAL(HAVE_A2X, test x$HAVE_A2X = xyes)
 683
 684 # Want to control a tape drive? Use mt. Want to convert HTML to text?
 685 # Uhhhhh... elinks? lynx? w3m? pandoc? html2text?
 686 AC_PATH_PROG(ELINKS, elinks)
 687 AC_CHECK_PROG(HAVE_ELINKS, elinks, "yes", "no")
 688 AM_CONDITIONAL(HAVE_ELINKS, test x$HAVE_ELINKS = xyes)
 689
 690 # Check for fop (translate .fo to e.g. pdf)
 691 AC_PATH_PROG(FOP, fop)
 692 AC_CHECK_PROG(HAVE_FOP, fop, "yes", "no")
 693 AM_CONDITIONAL(HAVE_FOP, test x$HAVE_FOP = xyes)
 694
 695 # Check for lynx (html -> text)
 696 AC_PATH_PROG(LYNX, lynx)
 697 AC_CHECK_PROG(HAVE_LYNX, lynx, "yes", "no")
 698 AM_CONDITIONAL(HAVE_LYNX, test x$HAVE_LYNX = xyes)
 699
 700 # Check for w3m (html -> text)
 701 AC_PATH_PROG(W3M, w3m)
 702 AC_CHECK_PROG(HAVE_W3M, w3m, "yes", "no")
 703 AM_CONDITIONAL(HAVE_W3M, test x$HAVE_W3M = xyes)
 704
 705 # Check for xmllint
 706 AC_PATH_PROG(XMLLINT, xmllint)
 707 AC_CHECK_PROG(HAVE_XMLLINT, xmllint, "yes", "no")
 708 AM_CONDITIONAL(HAVE_XMLLINT, test x$HAVE_XMLLINT = xyes)
 709
 710 # Check for xsltproc
 711 AC_PATH_PROG(XSLTPROC, xsltproc)
 712 AC_CHECK_PROG(HAVE_XSLTPROC, xsltproc, "yes", "no")
 713 AM_CONDITIONAL(HAVE_XSLTPROC, test x$HAVE_XSLTPROC = xyes)
 714
 715
 716 # Check for packaging utilities
 717 # For now, we check to see if the various packaging utilites are in our
 718 # path.  I'm too lazy to write code to go hunt for them.  -  Gerald
 719
 720 #
 721 # Source packages.
 722 # (Lets you install the desktop files.)
 723 #
 724 AC_PATH_PROG(DESKTOP_FILE_INSTALL, desktop-file-install)
 725
 726 # SVR4/Solaris
 727 AC_CHECK_PROG(HAVE_PKGPROTO, pkgproto, "yes", "no")
 728 AC_CHECK_PROG(HAVE_PKGMK, pkgmk, "yes", "no")
 729 AC_CHECK_PROG(HAVE_PKGTRANS, pkgtrans, "yes", "no")
 730
 731 if test x$HAVE_PKGPROTO = xyes -a x$HAVE_PKGMK = xyes \
 732      -a x$HAVE_PKGTRANS = xyes ; then
 733   HAVE_SVR4_PACKAGING=yes
 734 else
 735   HAVE_SVR4_PACKAGING=no
 736 fi
 737 AC_SUBST(HAVE_SVR4_PACKAGING)
 738
 739 # RPM
 740 AC_WIRESHARK_RPM_CHECK
 741 AC_SUBST(HAVE_RPM)
 742
 743 # Debian
 744 AC_CHECK_PROG(HAVE_DPKG_BUILDPACKAGE, dpkg-buildpackage, "yes", "no")
 745
 746 # Mac OS X
 747 AC_CHECK_PROG(HAVE_XCODEBUILD, xcodebuild, "yes", "no")
 748 AC_CHECK_PROG(HAVE_HDIUTIL, hdiutil, "yes", "no")
 749 AC_CHECK_PROG(HAVE_BLESS, bless, "yes", "no")
 750
 751 if test x$HAVE_XCODEBUILD = xyes -a x$HAVE_HDIUTIL = xyes \
 752      -a x$HAVE_BLESS = xyes ; then
 753   HAVE_OSX_PACKAGING=yes
 754 else
 755   HAVE_OSX_PACKAGING=no
 756 fi
 757 AC_SUBST(HAVE_OSX_PACKAGING)
 758
 759 #
 760 # Some compilers have to be told to fail when passed an unknown -W flag;
 761 # make sure we do that.
 762 #
 763 AC_WIRESHARK_CHECK_UNKNOWN_WARNING_OPTION_ERROR
 764
 765 #
 766 # Some C++ compilers have to be told to fail when passed a -W flag that
 767 # they don't think should apply to C++; make sure we do that.
 768 #
 769 AC_WIRESHARK_CHECK_NON_CXX_WARNING_OPTION_ERROR
 770
 771 #
 772 # Try to add some additional checks to CFLAGS.
 773 # These are not enabled by default, because the warnings they produce
 774 # are very hard or impossible to eliminate.
 775 #
 776 AC_ARG_ENABLE(extra-warnings,
 777   AC_HELP_STRING( [--enable-extra-warnings],
 778                   [do additional compiler warnings @<:@default=no@:>@]),
 779 [
 780         wireshark_extra_flags=$enableval
 781         if test $enableval != no
 782         then
 783                 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-pedantic)
 784                 #
 785                 # Various code blocks this one.
 786                 #
 787                 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Woverflow)
 788                 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-fstrict-overflow -Wstrict-overflow=4)
 789                 #
 790                 # Due to various places where APIs we don't control
 791                 # require us to cast away constness, we can probably
 792                 # never enable these ones with -Werror.
 793                 #
 794                 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wcast-qual)
 795                 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wbad-function-cast, C)
 796                 #
 797                 # Some generated ASN.1 dissectors block this one;
 798                 # multiple function declarations for the same
 799                 # function are being generated.
 800                 #
 801                 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wredundant-decls)
 802                 #
 803                 # Some loops are safe, but it's hard to convince the
 804                 # compiler of that.
 805                 #
 806                 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wunsafe-loop-optimizations)
 807                 #
 808                 # All the registration functions block these for now.
 809                 #
 810                 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wmissing-prototypes)
 811                 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wmissing-declarations)
 812                 #
 813                 # A bunch of "that might not work on SPARC" code blocks
 814                 # this one for now.
 815                 #
 816                 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wcast-align)
 817                 #
 818                 # Some code blocks this for now.
 819                 #
 820                 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wunreachable-code)
 821                 #
 822                 # Some code blocks this for now.
 823                 #
 824                 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wdocumentation)
 825         fi
 826 ],)
 827
 828 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wall -W) # -W is now known as -Wextra
 829 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wextra) # -W is now known as -Wextra
 830 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wdeclaration-after-statement, C)
 831 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wendif-labels)
 832 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wpointer-arith)
 833 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wno-pointer-sign, C)
 834 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Warray-bounds)
 835 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wformat-security)
 836 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-fwrapv)
 837 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-fno-strict-overflow)
 838 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-fno-delete-null-pointer-checks)
 839 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wold-style-definition, C)
 840 # The Qt headers generate a ton of shortening errors on 64-bit systems
 841 # so only enable this for C for now.
 842 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wshorten-64-to-32, C)
 843 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wstrict-prototypes, C)
 844 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wjump-misses-init, C)
 845 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wvla)
 846 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Waddress)
 847 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wattributes)
 848 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wdiv-by-zero)
 849 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wignored-qualifiers)
 850 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wpragmas)
 851 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wno-overlength-strings)
 852 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wwrite-strings)
 853 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wno-long-long)
 854 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wc++-compat, C)
 855 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wheader-guard)
 856
 857 #
 858 # XXX - OK for C++?
 859 #
 860 # Make sure -Wshadow doesn't complain about variables in function and
 861 # function pointer declarations shadowing other variables; if not, don't
 862 # turn it on, as some versions of GCC (including the one in at least
 863 # some Xcode versions that came with Mac OS X 10.5) complain about
 864 # that.
 865 #
 866 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wshadow, C,
 867   [
 868 extern int bar(int a);
 869 extern int foo(int);
 870
 871 int
 872 foo(int a)
 873 {
 874         int (*fptr)(int a) = bar;
 875
 876         return fptr(a) * 2;
 877 }
 878   ],
 879   [warns about variables in function declarations shadowing other variables])
 880
 881 # Unfortunately some versions of gcc generate logical-op warnings when strchr()
 882 # is given a constant string.
 883 # gcc versions 4.3.2 and 4.4.5 are known to have the problem.
 884 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wlogical-op, C,
 885   [
 886 #include <string.h>
 887
 888 int foo(const char *, int);
 889 int bar(void);
 890
 891 int
 892 foo(const char *sep, int c)
 893 {
 894         if (strchr (sep, c) != NULL)
 895                 return 1;
 896         else
 897                 return 0;
 898 }
 899
 900 int
 901 bar(void)
 902 {
 903         return foo("<", 'a');
 904 }
 905   ],
 906   [generates warnings from strchr()])
 907
 908
 909 #
 910 # On OS X, suppress warnings about deprecated declarations, because
 911 # they apparently think everything on OS X is Shiny Happy Apple-
 912 # Framework-Based Apps and are deprecating some perfectly OK
 913 # multi-platform open-source libraries that we use in our multi-platform
 914 # open-source application in favor of various frameworks that are
 915 # OS X-only.
 916 #
 917 case "$host_os" in
 918 darwin*)
 919         AC_WIRESHARK_COMPILER_FLAGS_CHECK(-Wno-deprecated-declarations)
 920         ;;
 921 esac
 922
 923 #
 924 # Use the faster pre gcc 4.5 floating point precision if available.
 925 #
 926 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-fexcess-precision=fast)
 927
 928 CFLAGS_before_fvhidden="$CFLAGS"
 929 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-fvisibility=hidden)
 930 if test "x$CFLAGS" = "x$CFLAGS_before_fvhidden"
 931 then
 932         # TODO add other ways of hiding symbols
 933         AC_MSG_WARN(Compiler will export all symbols from shared libraries)
 934 fi
 935
 936 AC_WIRESHARK_LDFLAGS_CHECK([-Wl,--as-needed])
 937 ###AC_WIRESHARK_LDFLAGS_CHECK([-Wl,-M])
 938 ###AC_WIRESHARK_LDFLAGS_CHECK([-Wl,--cref])
 939 # AC_WIRESHARK_LDFLAGS_CHECK([-flto])
 940 # AC_WIRESHARK_LDFLAGS_CHECK([-fwhopr])
 941 # AC_WIRESHARK_LDFLAGS_CHECK([-fwhole-program])
 942
 943 #
 944 # Put -fPIE in PIE_CFLAGS and -pie in PIE_LDFLAGS if we can use them,
 945 # so that we can build dumpcap PIE - it may run with elevated
 946 # privileges, and using PIE means the OS can run it at random locations
 947 # in the address space to make attacks more difficult.
 948 #
 949 CFLAGS_before_pie="$CFLAGS"
 950 AC_WIRESHARK_COMPILER_FLAGS_CHECK(-fPIE)
 951 if test "x$CFLAGS" != "x$CFLAGS_before_pie"
 952 then
 953         # Restore CFLAGS
 954         CFLAGS="$CFLAGS_before_pie"
 955
 956         LDFLAGS_before_pie="$LDFLAGS"
 957         AC_WIRESHARK_LDFLAGS_CHECK([-fPIE -pie])
 958         if test "x$LDFLAGS" != "x$LDFLAGS_before_pie"
 959         then
 960                 # We can use PIE
 961                 PIE_CFLAGS="-fPIE"
 962                 PIE_LDFLAGS="-pie"
 963
 964                 # Restore LDFLAGS
 965                 LDFLAGS="$LDFLAGS_before_pie"
 966         fi
 967
 968 fi
 969 AC_SUBST(PIE_CFLAGS)
 970 AC_SUBST(PIE_LDFLAGS)
 971
 972 #
 973 # If we're running GCC or clang define _U_ to be "__attribute__((unused))"
 974 # so we can use _U_ to flag unused function parameters and not get warnings
 975 # about them. Otherwise, define _U_ to be an empty string so that _U_ used
 976 # to flag an unused function parameters will compile with other compilers.
 977 #
 978 # XXX - similar hints for other compilers?
 979 #
 980 if test "x$GCC" = "xyes" -o "x$CC" = "xclang" ; then
 981   AC_DEFINE(_U_, __attribute__((unused)), [Hint to the compiler that a function parameters is not used])
 982 else
 983   AC_DEFINE(_U_, , [Hint to the compiler that a function parameters is not used])
 984 fi
 985
 986 # If we're running GCC or CLang, use FORTIFY_SOURCE=2
 987 #  (only if the GCC 'optimization level' > 0).
 988 #
 989 # See: http://gcc.gnu.org/ml/gcc-patches/2004-09/msg02055.html
 990 # See: http://sourceware.org/bugzilla/show_bug.cgi?id=13979
 991 #
 992 # Note: FORTIFY_SOURCE is only effective for gcc optimization level > 0 (-O1, etc)
 993 AC_WIRESHARK_GCC_FORTIFY_SOURCE_CHECK
 994
 995 #
 996 # If the compiler supports GCC-style flags, enable a barrier "stop on
 997 # warning".
 998 # This barrier is set for a very large part of the code. However, it is
 999 # typically not set for "generated" code  (flex, ans2wrs, idl2wrs, ...)
1000 #
1001 warnings_as_errors_default="yes"
1002 AC_MSG_CHECKING(whether we should treat compiler warnings as errors)
1003 AC_ARG_ENABLE(warnings-as-errors,
1004   AC_HELP_STRING( [--enable-warnings-as-errors],
1005                   [treat warnings as errors (only for GCC or clang) @<:@default=yes, unless extra warnings are enabled@:>@]),
1006 [
1007   if test "x$ac_supports_gcc_flags" = "xyes" -a "x$enableval" = "xyes"; then
1008     with_warnings_as_errors="yes"
1009     AC_MSG_RESULT(yes)
1010   else
1011     with_warnings_as_errors="no"
1012     AC_MSG_RESULT(no)
1013   fi
1014 ],
1015 [
1016   if test "x$ac_supports_gcc_flags" = "xyes" -a "x$wireshark_extra_flags" = "x" -a "x$warnings_as_errors_default" = "xyes"; then
1017     with_warnings_as_errors="yes"
1018     AC_MSG_RESULT(yes)
1019   else
1020     with_warnings_as_errors="no"
1021     AC_MSG_RESULT(no)
1022   fi
1023 ]
1024 )
1025 AM_CONDITIONAL(HAVE_WARNINGS_AS_ERRORS, test "x$with_warnings_as_errors" = "xyes")
1026
1027 #
1028 # Add any platform-specific compiler flags needed.
1029 #
1030 AC_MSG_CHECKING(for platform-specific compiler flags)
1031 if test "x$GCC" = "xyes" ; then
1032         #
1033         # GCC - do any platform-specific tweaking necessary.
1034         #
1035         case "$host_os" in
1036         solaris*)
1037                 # the X11 headers don't automatically include prototype info
1038                 # and a lot don't include the return type
1039                 CPPFLAGS="$CPPFLAGS -DFUNCPROTO=15"
1040                 CFLAGS="$CFLAGS -Wno-return-type"
1041                 CXXFLAGS="$CXXFLAGS -Wno-return-type"
1042                 AC_MSG_RESULT(GCC on Solaris - added -Wno-return-type -DFUNCPROTO=15)
1043                 ;;
1044         *)
1045                 AC_MSG_RESULT(none needed)
1046                 ;;
1047         esac
1048 else
1049         #
1050         # Not GCC - assume it's the vendor's compiler.
1051         #
1052         case "$host_os" in
1053         hpux*)
1054                 #
1055                 # HP's ANSI C compiler; flags suggested by Jost Martin.
1056                 # "-Ae" for ANSI C plus extensions such as "long long".
1057                 # "+O2", for optimization.  XXX - works with "-g"?
1058                 #
1059                 # HP's ANSI C++ compiler doesn't support "-Ae", but
1060                 # does support "+O2", at least according to the
1061                 # documentation I can find online.
1062                 #
1063                 CFLAGS="-Ae +O2 $CFLAGS"
1064                 CFLAGS_FOR_BUILD="-Ae +O2 $CFLAGS"
1065                 CXXFLAGS="+O2 $CFLAGS"
1066                 AC_MSG_RESULT(HP ANSI C compiler - added -Ae +O2)
1067                 ;;
1068         *)
1069                 AC_MSG_RESULT(none needed)
1070                 ;;
1071         esac
1072 fi
1073
1074 #
1075 # Add any platform-specific linker flags needed.
1076 #
1077 AC_MSG_CHECKING(for platform-specific linker flags)
1078 case "$host_os" in
1079 darwin*)
1080         #
1081         # Add -Wl,-single_module to the LDFLAGS used with shared
1082         # libraries, to fix some error that show up in some cases;
1083         # some Apple documentation recommends it for most shared
1084         # libraries.
1085         #
1086         LDFLAGS_SHAREDLIB="-Wl,-single_module"
1087         #
1088         # Add -Wl,-search_paths_first to make sure that if we search
1089         # directories A and B, in that order, for a given library, a
1090         # non-shared version in directory A, rather than a shared
1091         # version in directory B, is chosen (so we can use
1092         # --with-pcap=/usr/local to force all programs to be linked
1093         # with a static version installed in /usr/local/lib rather than
1094         # the system version in /usr/lib).
1095         #
1096         # Also add -Wl,-rpath,@executable_path/../lib and
1097         # -Wl,-rpath,/usr/local/lib, so that, if we build an app
1098         # bundle, we can tweak all the executable images, shared
1099         # libraries, and plugins in the bundle to look for non-system
1100         # libraries in the rpath, rather than having a script tweak
1101         # DYLD_LIBRARY_PATH.
1102         #
1103         LDFLAGS="-Wl,-search_paths_first -Wl,-rpath,@executable_path/../lib -Wl,-rpath,@executable_path/../Frameworks -Wl,-rpath,/usr/local/lib $LDFLAGS"
1104         AC_MSG_RESULT([Apple linker - added -Wl,-single_module and -Wl,-search_paths_first, and rpaths])
1105         ;;
1106 cygwin*)
1107         #
1108         # Shared libraries in cygwin/Win32 must never contain
1109         # undefined symbols.
1110         #
1111         LDFLAGS="$LDFLAGS -no-undefined"
1112         AC_MSG_RESULT(CygWin GNU ld - added -no-undefined)
1113         ;;
1114 *)
1115         AC_MSG_RESULT(none needed)
1116         ;;
1117 esac
1118 AC_SUBST(LDFLAGS_SHAREDLIB)
1119
1120 # Enable silent builds by default
1121 # Verbose builds can be enabled with "./configure
1122 # --enable-silent-rules ..." or "make V=1 ..."
1123 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
1124   [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
1125
1126 #
1127 # On "Darwin", which we assume to mean "OS X" rather than "iOS" or
1128 # "just Darwin" (as we don't currently support iOS, and as I don't
1129 # think you can build and run "just Darwin" as an OS for PCs), we
1130 # arrange to build some programs with Application Services so they
1131 # can launch Web browsers and Finder windows, arrange to build some
1132 # programs with System Configuration so they can get "friendly names"
1133 # and other information about interfaces, and build any programs that
1134 # use either of those frameworks or that report version information
1135 # with Core Foundation as the frameworks in question use it and as we
1136 # get version information from plists and thus need Core Foundation
1137 # to process those plists.
1138 #
1139 case "$host_os" in
1140
1141 darwin*)
1142         AC_DEFINE(HAVE_OS_X_FRAMEWORKS, 1, [Define to 1 if you have OS X frameworks])
1143         APPLICATIONSERVICES_FRAMEWORKS="-framework ApplicationServices"
1144         SYSTEMCONFIGURATION_FRAMEWORKS="-framework SystemConfiguration"
1145         COREFOUNDATION_FRAMEWORKS="-framework CoreFoundation"
1146
1147         #
1148         # OK, so we have the OS X frameworks; do they include
1149         # CFPropertyListCreateWithStream, or do we have
1150         # to fall back on CFPropertyListCreateFromStream?
1151         # (They only differ in the error return, which we
1152         # don't care about.  And, no, we shouldn't just
1153         # use CFPropertyListCreateFromStream, because it's
1154         # deprecated in newer releases.)
1155         #
1156         ac_save_LIBS="$LIBS"
1157         LIBS="$LIBS $COREFOUNDATION_FRAMEWORKS"
1158         AC_CHECK_FUNCS(CFPropertyListCreateWithStream)
1159         LIBS="$ac_save_LIBS"
1160         ;;
1161 esac
1162 AC_SUBST(APPLICATIONSERVICES_FRAMEWORKS)
1163 AC_SUBST(SYSTEMCONFIGURATION_FRAMEWORKS)
1164 AC_SUBST(COREFOUNDATION_FRAMEWORKS)
1165
1166 #
1167 # On Solaris, check whether we have getexecname().
1168 #
1169 case "$host_os" in
1170 solaris*)
1171         AC_CHECK_FUNC(getexecname)
1172         ;;
1173 esac
1174
1175 dnl Look in /usr/local for header files and libraries ?
1176 dnl XXX FIXME don't include /usr/local if it is already in the system
1177 dnl search path as this causes gcc 3.2 on Linux to complain about a change
1178 dnl of the system search order for includes
1179 AC_ARG_ENABLE(usr-local,
1180   AC_HELP_STRING( [--enable-usr-local],
1181                   [look for headers and libs in /usr/local tree @<:@default=yes@:>@]),
1182     ac_cv_enable_usr_local=$enableval,ac_cv_enable_usr_local=yes)
1183
1184 AC_MSG_CHECKING(whether to use /usr/local for headers and libraries)
1185 if test "x$ac_cv_enable_usr_local" = "xyes" ; then
1186         if test -d "/usr/local"; then
1187                 AC_MSG_RESULT(yes)
1188                 #
1189                 # Arrange that we search for header files in the source directory
1190                 # and in its "wiretap" subdirectory, as well as in "/usr/local/include",
1191                 # as various packages we use ("libpcap", "zlib", "adns")
1192                 # may have been installed under "/usr/local/include".
1193                 #
1194                 CPPFLAGS="$CPPFLAGS -I/usr/local/include"
1195
1196                 #
1197                 # Arrange that we search for libraries in "/usr/local/lib".
1198                 #
1199                 AC_WIRESHARK_ADD_DASH_L(LDFLAGS, /usr/local/lib)
1200         else
1201                 AC_MSG_RESULT(no)
1202         fi
1203 else
1204         AC_MSG_RESULT(no)
1205 fi
1206
1207 #
1208 # If we're running Solaris, and LD_LIBRARY_PATH is defined, add it as a
1209 # link directory.
1210 #
1211 case "$host_os" in
1212   solaris*)
1213     AC_MSG_CHECKING(for LD_LIBRARY_PATH, since you appear to be running Solaris)
1214     if test x$LD_LIBRARY_PATH != x ; then
1215       LIBS="$LIBS -R$LD_LIBRARY_PATH"
1216       AC_MSG_RESULT(yes -- added LD_LIBRARY_PATH to run-time linker path)
1217     else
1218       AC_MSG_RESULT(no -- this may be a problem in a few seconds)
1219     fi
1220   ;;
1221 esac
1222
1223 #
1224 # Check for versions of "sed" inadequate to handle, in libtool, a list
1225 # of object files as large as the list in Wireshark.
1226 #
1227 # On Solaris, we check for "/bin/sed", "/usr/bin/sed", and "/usr/ucb/sed",
1228 # as both "/usr/bin/sed" (which is also "/bin/sed", as "/bin" is just a
1229 # symlink to "/usr/bin", but people may have "/bin" before "/usr/bin" in
1230 # their search path) and "/usr/ucb/sed" are inadequate; "/usr/xpg4/bin/sed"
1231 # is the only "sed" that comes with Solaris that can handle Wireshark.
1232 #
1233 # Add any checks here that are necessary for other OSes.
1234 #
1235 AC_PATH_PROG(SED, sed)
1236 if test "x$SED" = x
1237 then
1238         AC_MSG_ERROR(I couldn't find sed; make sure it's installed and in your path)
1239 fi
1240 AC_WIRESHARK_GNU_SED_CHECK
1241 if test "$HAVE_GNU_SED" = no ; then
1242         case "$host_os" in
1243         solaris*)
1244                 AC_MSG_CHECKING(whether one of /usr/bin/sed or /bin/sed or /usr/ucb/sed will be used)
1245                 case `which sed` in
1246                         /bin/sed|/usr/bin/sed|/usr/ucb/sed)
1247                         AC_MSG_RESULT(yes)
1248                         AC_MSG_ERROR([change your path to search /usr/xpg4/bin or directory containing GNU sed before /usr/bin (and /bin and /usr/ucb)])
1249                         ;;
1250
1251                         *)
1252                         AC_MSG_RESULT(no)
1253                         ;;
1254                 esac
1255                 ;;
1256
1257         *)
1258                 :
1259                 ;;
1260         esac
1261 fi
1262
1263 # Enable/disable wireshark
1264 AC_ARG_ENABLE(wireshark,
1265   AC_HELP_STRING( [--enable-wireshark],
1266                   [build the Wireshark GUI (with Gtk+, Qt, or both) @<:@default=yes@:>@]),
1267     enable_wireshark=$enableval,enable_wireshark=yes)
1268
1269 AC_ARG_ENABLE(packet-editor,
1270   AC_HELP_STRING( [--enable-packet-editor],
1271                   [add support for packet editor in Wireshark @<:@default=yes@:>@]),
1272     enable_packet_editor=$enableval,enable_packet_editor=yes)
1273 if test x$enable_packet_editor = xyes; then
1274         AC_DEFINE(WANT_PACKET_EDITOR, 1, [Support for packet editor])
1275 fi
1276
1277 AC_ARG_ENABLE(profile-build,
1278   AC_HELP_STRING( [--enable-profile-build],
1279                   [build profile-ready binaries @<:@default=no@:>@]),
1280     enable_profile_build=$enableval,enable_profile_build=no)
1281 AM_CONDITIONAL(USE_PROFILE_BUILD, test x$enable_profile_build = xyes)
1282 AC_MSG_CHECKING(if profile builds must be generated)
1283 if test "x$enable_profile_build" = "xyes" ; then
1284         if test "x$GCC" = "xyes" -o "x$CLANG" = "xyes" ; then
1285                 AC_MSG_RESULT(yes)
1286                 CFLAGS=" -pg $CFLAGS"
1287                 CXXFLAGS=" -pg $CXXFLAGS"
1288         else
1289                 AC_MSG_RESULT(no)
1290                 echo "Building profile binaries currently only supported for GCC and clang."
1291         fi
1292 else
1293         AC_MSG_RESULT(no)
1294 fi
1295
1296 # Create DATAFILE_DIR #define for config.h
1297 datafiledir=$datadir/wireshark
1298 datafiledir=`(
1299     test "x$prefix" = xNONE && prefix=$ac_default_prefix
1300     test "x$exec_prefix" = xNONE && exec_prefix=${prefix}
1301     # Ugly hack, but I don't see how this problem can be solved
1302     # properly that DATAFILE_DIR had a value starting with
1303     # "${prefix}/" instead of e.g. "/usr/local/"
1304     eval eval echo "$datafiledir"
1305 )`
1306 AC_DEFINE_UNQUOTED(DATAFILE_DIR,"$datafiledir", [Directory for data])
1307
1308 # Create DOC_DIR #define for config.h
1309 docdir=`(
1310     test "x$prefix" = xNONE && prefix=$ac_default_prefix
1311     test "x$exec_prefix" = xNONE && exec_prefix=${prefix}
1312     # Ugly hack, but I don't see how this problem can be solved
1313     # properly that DOC_DIR had a value starting with
1314     # "${prefix}/" instead of e.g. "/usr/local/"
1315     eval eval echo "$docdir"
1316 )`
1317 AC_DEFINE_UNQUOTED(DOC_DIR, "$docdir", [Directory for docs])
1318
1319 GTK2_MIN_VERSION=2.12.0
1320 AC_SUBST(GTK2_MIN_VERSION)
1321 GTK3_MIN_VERSION=3.0.0
1322 AC_SUBST(GTK3_MIN_VERSION)
1323 QT_MIN_VERSION=4.6.0
1324 AC_SUBST(QT_MIN_VERSION)
1325 # GTK+ and Qt checks; we require GTK+ $GTK2_MIN_VERSION or later or
1326 # GTK3_MIN_VERSION or later or Qt $QT_MIN_VERSION or later.
1327 #
1328 # We only do those if we're going to be building Wireshark;
1329 # otherwise, we don't have any GUI to build, so we don't use
1330 # GTK+ or Qt.
1331 #
1332 # We don't add $GTK_LIBS or $Qt_LIBS to LIBS, because we don't want to
1333 # force all programs to be built with GTK+ or Qt.
1334 #
1335 # Release dates for GTK+ versions:
1336 # http://en.wikipedia.org/wiki/GTK+#Releases
1337 # 2.12.0: 14 Sep 2007
1338 # 2.14.0: 04 Sep 2008
1339 # 2.16.0: 13 Mar 2009
1340 # 2.18.0: 23 Sep 2009
1341 # 2.20.0: 23 Mar 2010
1342 # 2.22.0: 23 Sep 2010
1343 # 2.24.0: 30 Jan 2011
1344 # 3.0.0:  10 Feb 2011
1345 # 3.2.0:  25 Sep 2011
1346 # 3.4.0:  26 Mar 2012
1347 # 3.6.0:  24 Sep 2012
1348 # 3.8.0:  25 Mar 2013
1349 # 3.10.0: 23 Sep 2013
1350 # 3.12.0: 25 Mar 2014
1351 #
1352 # Release dates for Qt versions:
1353 # http://en.wikipedia.org/wiki/List_of_Qt_releases
1354 # 4.6.0:  01 Dec 2009
1355 # 4.7.0:  21 Sep 2010
1356 # 4.8.0:  15 Dec 2011
1357 # 5.0.0:  19 Dec 2012
1358 # 5.1.0:  03 Jul 2013
1359 # 5.2.0:  12 Dec 2013
1360
1361 have_qt=no
1362 have_gtk=no
1363 if test "x$enable_wireshark" = "xyes"; then
1364         if test "x$with_gtk2" = "xunspecified" -a \
1365                 "x$with_gtk3" = "xunspecified" -a \
1366                 "x$with_qt" = "xunspecified"; then
1367                 #
1368                 # No GUI toolkit was explicitly specified; pick Qt and GTK+ 3.
1369                 #
1370                 with_qt=yes
1371                 with_gtk3=yes
1372         fi
1373         if test "x$with_qt" = "xyes"; then
1374                 #
1375                 # Qt was specified; Make sure we have a C++ compiler.
1376                 #
1377                 if test -z "$CXX"; then
1378                         AC_MSG_ERROR(Need a working C++ compiler to build Wireshark with Qt)
1379                 fi
1380
1381                 #
1382                 # Now make sure we have Qt and, if so, add the flags
1383                 # for it to CFLAGS and CXXFLAGS.
1384                 #
1385                 AC_WIRESHARK_QT_CHECK($QT_MIN_VERSION,
1386                 [
1387                         CFLAGS="$CFLAGS $Qt_CFLAGS"
1388                         CXXFLAGS="$CXXFLAGS $Qt_CFLAGS"
1389                         have_qt=yes
1390                         GUI_CONFIGURE_FLAGS="$GUI_CONFIGURE_FLAGS --with-qt"
1391                         OSX_APP_FLAGS="$OSX_APP_FLAGS -qt"
1392                         OSX_DMG_FLAGS="-qt"
1393                 ],
1394                 [AC_MSG_ERROR([Qt is not available])])
1395
1396                 #
1397                 # XXX - greasy hack to make ui/gtk/recent.c
1398                 # compile.
1399                 #
1400                 CPPFLAGS="-DQT_GUI_LIB"
1401         fi
1402
1403         if test "x$with_gtk3" = "xyes"; then
1404                 #
1405                 # GTK+ 3 was specified; make sure they didn't also
1406                 # specify GTK+ 2, as we don't support building both
1407                 # GTK+ 2 and GTK+ 3 versions at the same time.
1408                 #
1409                 if test "x$with_gtk2" = "xyes"; then
1410                         AC_MSG_ERROR([Both GTK+ 2 and GTK+ 3 were specified; choose one but not both])
1411                 fi
1412
1413                 #
1414                 # Make sure we have GTK+ 3.
1415                 #
1416                 AM_PATH_GTK_3_0(3.0.0,
1417                 [
1418                         CFLAGS="$CFLAGS $GTK_CFLAGS"
1419                         CXXFLAGS="$CXXFLAGS $GTK_CFLAGS"
1420                         have_gtk=yes
1421                         GUI_CONFIGURE_FLAGS="$GUI_CONFIGURE_FLAGS --with-gtk3"
1422                 ],
1423                 [AC_MSG_ERROR([GTK+ 3 is not available])])
1424         elif test "x$with_gtk2" = "xyes"; then
1425                 #
1426                 # GTK+ 3 wasn't specified, and GTK+ 2 was specified;
1427                 # make sure we have GTK+ 2.
1428                 #
1429                 AM_PATH_GTK_2_0($GTK2_MIN_VERSION,
1430                 [
1431                         CFLAGS="$CFLAGS $GTK_CFLAGS"
1432                         CXXFLAGS="$CXXFLAGS $GTK_CFLAGS"
1433                         have_gtk=yes
1434                         GUI_CONFIGURE_FLAGS="$GUI_CONFIGURE_FLAGS --with-gtk2"
1435                 ],
1436                 [AC_MSG_ERROR([GTK+ 2 is not available])])
1437         fi
1438 fi
1439 AC_SUBST(GUI_CONFIGURE_FLAGS)
1440
1441 GLIB_MIN_VERSION=2.16.0
1442 AC_SUBST(GLIB_MIN_VERSION)
1443 # GLib checks; we require GLib $GLIB_MIN_VERSION or later, and require gmodule
1444 # support, as we need that for dynamically loading plugins.
1445 # If we found GTK+, this doesn't add GLIB_CFLAGS to CFLAGS, because
1446 # AM_PATH_GTK will add GTK_CFLAGS to CFLAGS, and GTK_CFLAGS is a
1447 # superset of GLIB_CFLAGS.  If we didn't find GTK+, it does add
1448 # GLIB_CFLAGS to CFLAGS.
1449 # However, this means that both @GLIB_LIBS@ and @GTK_LIBS@ will be
1450 # set when generating the Makefile, so we can make programs that require
1451 # only GLib link with @GLIB_LIBS@ and make programs that require GTK+
1452 # link with @GTK_LIBS@ (which includes @GLIB_LIBS@).
1453 # We don't add $GLIB_LIBS to LIBS, because we don't want to force all
1454 # programs to be built with GLib.
1455 #
1456 # Release dates for GLib versions:
1457 # 2.14.0: 03 Aug 2007
1458 # 2.16.0: 10 Mar 2008
1459 # 2.18.0: 02 Sep 2008
1460 # 2.20.0: 13 Mar 2009
1461 # 2.22.0: 22 Sep 2009
1462 # 2.24.0: 28 Mar 2010
1463 # 2.26.0: 27 Sep 2010
1464 # 2.28.0: 08 Feb 2011
1465 # 2.30.0: 27 Sep 2011
1466 # 2.32.0: 24 Mar 2012
1467 # 2.34.0: 24 Sep 2012
1468 # 2.36.0: 25 Mar 2013
1469 # 2.38.0: 23 Sep 2013
1470 # 2.40.0: 24 Mar 2014
1471
1472 use_glib_cflags="true"
1473 if test "$have_gtk" = "yes" -a "$have_qt" = "yes" ; then
1474         # We have both GTK and Qt and thus will be building both wireshark
1475         # and wireshark-qt.
1476
1477         wireshark_bin="wireshark\$(EXEEXT) wireshark-qt\$(EXEEXT)"
1478         wireshark_man="wireshark.1"
1479         wireshark_SUBDIRS="codecs ui/qt ui/gtk"
1480 fi
1481 if test "$have_gtk" = "no" -a "$have_qt" = "yes" ; then
1482         # We don't have GTK+ but we have Qt.
1483
1484         wireshark_bin="wireshark-qt\$(EXEEXT)"
1485         wireshark_man="wireshark.1"
1486         wireshark_SUBDIRS="codecs ui/qt"
1487 fi
1488 if test "$have_gtk" = "yes" -a "$have_qt" = "no" ; then
1489         # We have GTK+ but not Qt.
1490
1491         wireshark_bin="wireshark\$(EXEEXT)"
1492         wireshark_man="wireshark.1"
1493         wireshark_SUBDIRS="codecs ui/gtk"
1494         use_glib_cflags="false"
1495 fi
1496 if test "$have_gtk" = "no" -a "$have_qt" = "no" ; then
1497         # We have neither GTK+ nor Qt.
1498         #
1499         # If they didn't explicitly say "--disable-wireshark",
1500         # fail (so that, unless they explicitly indicated that
1501         # they don't want Wireshark, we stop so they know they
1502         # won't be getting Wireshark unless they fix the GTK+/Qt
1503         # problem).
1504         #
1505         if test "x$enable_wireshark" = "xyes"; then
1506                 if test "x$with_gtk3" = "xyes"; then
1507                         AC_MSG_ERROR([Neither Qt nor GTK+ $GTK3_MIN_VERSION or later are available, so Wireshark can't be compiled])
1508                 else
1509                         AC_MSG_ERROR([Neither Qt nor GTK+ $GTK2_MIN_VERSION or later are available, so Wireshark can't be compiled])
1510                 fi
1511         fi
1512         wireshark_bin=""
1513         wireshark_man=""
1514 fi
1515
1516 if test "$have_gtk" = "yes" ; then
1517         # If we have GTK then add flags for it.
1518
1519         CPPFLAGS="-DGDK_PIXBUF_DISABLE_DEPRECATED $CPPFLAGS"
1520         CPPFLAGS="-DGDK_DISABLE_DEPRECATED $CPPFLAGS"
1521         if test \( $gtk_config_major_version -eq 3 -a $gtk_config_minor_version -ge 10 \) ; then
1522                 ## Allow use of deprecated & disable deprecated warnings if Gtk >= 3.10;
1523                 ##  The deprecations in Gtk 3.10 will not be fixed ...
1524                 CPPFLAGS="-DGDK_DISABLE_DEPRECATION_WARNINGS $CPPFLAGS"
1525         else
1526                 CPPFLAGS="-DGTK_DISABLE_DEPRECATED $CPPFLAGS"
1527         fi
1528         CPPFLAGS="-DGTK_DISABLE_SINGLE_INCLUDES $CPPFLAGS"
1529         if test ! \( $gtk_config_major_version -eq 2 -a $gtk_config_minor_version -lt 20 \) ; then
1530                 # Enable GSEAL when building with GTK > 2.20
1531                 # (Versions prior to 2.22 lacked some necessary accessors.)
1532                 CPPFLAGS="-DGSEAL_ENABLE $CPPFLAGS"
1533         fi
1534 fi
1535
1536 # XXX - Is this really necessary?  When we build with both Gtk+ and Qt it works...
1537 if test "$use_glib_cflags" = "true"; then
1538         # Use GLIB_CFLAGS
1539         AM_PATH_GLIB_2_0($GLIB_MIN_VERSION,
1540         [
1541                 CFLAGS="$CFLAGS $GLIB_CFLAGS"
1542                 CXXFLAGS="$CXXFLAGS $GLIB_CFLAGS"
1543         ], AC_MSG_ERROR(GLib $GLIB_MIN_VERSION or later distribution not found.), gthread gmodule)
1544 else
1545         # Don't use GLIB_CFLAGS
1546         AM_PATH_GLIB_2_0($GLIB_MIN_VERSION, , AC_MSG_ERROR(GLib $GLIB_MIN_VERSION or later distribution not found.), gthread gmodule)
1547 fi
1548
1549 #
1550 # "make dist" requires that we have the Qt build tools.
1551 #
1552 # Annoyingly, at least on Fedora 16, uic and moc are named XXX-qt4
1553 # rather than just XXX, perhaps to allow Qt 3 and Qt 4 tools to be
1554 # installed; if they're still doing that in current Fedora releases,
1555 # perhaps there will also be XXX-qt5 when they pick up Qt 5.
1556 #
1557 AC_PATH_PROG(UIC, uic)
1558 if test "x$UIC" = x
1559 then
1560         AC_PATH_PROG(UIC, uic-qt4)
1561         if test "x$UIC" = x
1562         then
1563                 if test "x$with_qt" = "xyes"; then
1564                         #
1565                         # If you want to build with Qt, you'd better
1566                         # have uic.
1567                         #
1568                         AC_MSG_ERROR(I couldn't find uic or uic-qt4; make sure it's installed and in your path)
1569                 else
1570                         #
1571                         # We shouldn't fail here, as the user's not
1572                         # building with Qt, and we shouldn't force them
1573                         # to have Qt installed if they're not doing so.
1574                         # "make dist" will fail if they do that, but
1575                         # we don't know whether they'll be doing that,
1576                         # so this is the best we can do.
1577                         #
1578                         UIC=uic
1579                 fi
1580         fi
1581 fi
1582 AC_SUBST(UIC)
1583 AC_PATH_PROG(MOC, moc)
1584 if test "x$MOC" = x
1585 then
1586         AC_PATH_PROG(MOC, moc-qt4)
1587         if test "x$MOC" = x
1588         then
1589                 if test "x$with_qt" = "xyes"; then
1590                         #
1591                         # If you want to build with Qt, you'd better
1592                         # have moc.
1593                         #
1594                         AC_MSG_ERROR(I couldn't find moc or moc-qt4; make sure it's installed and in your path)
1595                 else
1596                         #
1597                         # We shouldn't fail here, as the user's not
1598                         # building with Qt, and we shouldn't force them
1599                         # to have Qt installed if they're not doing so.
1600                         # "make dist" will fail if they do that, but
1601                         # we don't know whether they'll be doing that,
1602                         # so this is the best we can do.
1603                         #
1604                         MIC=moc
1605                 fi
1606         fi
1607 fi
1608 AC_SUBST(MOC)
1609
1610 # Error out if a glib header other than a "top level" header
1611 #  (glib.h, glib-object.h, gio.h) or certain other headers( e.g.,gmodule.h)
1612 #  is used.
1613 CPPFLAGS="-DG_DISABLE_SINGLE_INCLUDES $CPPFLAGS"
1614
1615 # Error out on the usage of deprecated glib functions
1616 CPPFLAGS="-DG_DISABLE_DEPRECATED $CPPFLAGS"
1617
1618 #
1619 # Check whether GLib modules are supported, to determine whether we
1620 # can support plugins.
1621 #
1622 AC_MSG_CHECKING(whether GLib supports loadable modules)
1623 ac_save_CFLAGS="$CFLAGS"
1624 ac_save_LIBS="$LIBS"
1625 CFLAGS="$CFLAGS $GLIB_CFLAGS"
1626 LIBS="$GLIB_LIBS $LIBS"
1627 AC_TRY_RUN([
1628 #include <glib.h>
1629 #include <gmodule.h>
1630 #include <stdio.h>
1631 #include <stdlib.h>
1632
1633 int
1634 main ()
1635 {
1636   if (g_module_supported())
1637     return 0;   /* success */
1638   else
1639     return 1;   /* failure */
1640 }
1641 ], ac_cv_glib_supports_modules=yes, ac_cv_glib_supports_modules=no,
1642    [echo $ac_n "cross compiling; assumed OK... $ac_c"
1643     ac_cv_glib_supports_modules=yes])
1644 CFLAGS="$ac_save_CFLAGS"
1645 LIBS="$ac_save_LIBS"
1646 if test "$ac_cv_glib_supports_modules" = yes ; then
1647   AC_MSG_RESULT(yes)
1648   have_plugins=yes
1649 else
1650   AC_MSG_RESULT(no)
1651   have_plugins=no
1652 fi
1653
1654 #
1655 # If we have <dlfcn.h>, check whether we have dladdr.
1656 #
1657 if test "$ac_cv_header_dlfcn_h" = "yes"
1658 then
1659         #
1660         # Use GLib compiler flags and linker flags; GLib's gmodule
1661         # stuff uses the dl APIs if available, so it might know
1662         # what flags are needed.
1663         #
1664         ac_save_CFLAGS="$CFLAGS"
1665         ac_save_LIBS="$LIBS"
1666         CFLAGS="$CFLAGS $GLIB_CFLAGS"
1667         LIBS="$GLIB_LIBS $LIBS"
1668         AC_CHECK_FUNCS(dladdr)
1669         if test x$ac_cv_func_dladdr = xno
1670         then
1671                 #
1672                 # OK, try it with -ldl, in case you need that to get
1673                 # dladdr().  For some reason, on Linux, that's not
1674                 # part of the GLib flags; perhaps GLib itself is
1675                 # linked with libdl, so that you can link with
1676                 # Glib and it'll pull libdl in itself.
1677                 #
1678                 LIBS="$LIBS -ldl"
1679                 AC_CHECK_FUNCS(dladdr)
1680         fi
1681         CFLAGS="$ac_save_CFLAGS"
1682         LIBS="$ac_save_LIBS"
1683 fi
1684
1685 #
1686 # Check whether GLib's printf supports thousands grouping. (This might
1687 # be different from the system's printf since GLib can optionally use
1688 # its own printf implementation.)
1689 #
1690 AC_MSG_CHECKING(whether GLib supports POSIX/XSI thousands grouping)
1691 ac_save_CFLAGS="$CFLAGS"
1692 ac_save_LIBS="$LIBS"
1693 CFLAGS="$CFLAGS $GLIB_CFLAGS"
1694 LIBS="$GLIB_LIBS $LIBS"
1695 AC_TRY_RUN([
1696 #include <glib.h>
1697 #include <locale.h>
1698 #include <stdio.h>
1699 #include <string.h>
1700
1701 int
1702 main ()
1703 {
1704   gchar *str;
1705   setlocale(LC_ALL, "en_US.UTF-8");
1706   str = g_strdup_printf("%'u", 123456);
1707   return (strcmp (str, "123,456") != 0);
1708 }
1709 ], ac_cv_glib_supports_printf_grouping=yes, ac_cv_glib_supports_printf_grouping=no,
1710    [echo $ac_n "cross compiling; playing it safe... $ac_c"
1711     ac_cv_glib_supports_printf_grouping=no])
1712 CFLAGS="$ac_save_CFLAGS"
1713 LIBS="$ac_save_LIBS"
1714 if test "$ac_cv_glib_supports_printf_grouping" = yes ; then
1715   AC_MSG_RESULT(yes)
1716   AC_DEFINE(HAVE_GLIB_PRINTF_GROUPING, 1, [Define if your printf() function supports thousands grouping.])
1717 else
1718   AC_MSG_RESULT(no)
1719 fi
1720
1721 if test "x$have_gtk" = "xyes"
1722 then
1723     #
1724     # We have GTK+; do we want the OS X integration functions and,
1725     # if so, do we have them and, if so, which versions do we have,
1726     # the old Carbon-based ones or the new Cocoa-based ones?
1727     #
1728     AC_MSG_CHECKING(whether to use OS X integration functions)
1729
1730     AC_ARG_WITH(osx-integration,
1731       AC_HELP_STRING( [--with-osx-integration],
1732                       [use OS X integration functions @<:@default=yes, if available@:>@]),
1733     [
1734         if test $withval = no
1735         then
1736             want_osx_integration=no
1737         else
1738             want_osx_integration=yes
1739         fi
1740     ],[
1741         want_osx_integration=yes
1742     ])
1743     if test "x$want_osx_integration" = "xno"; then
1744         AC_MSG_RESULT(no)
1745     else
1746         AC_MSG_RESULT(yes)
1747         AC_WIRESHARK_OSX_INTEGRATION_CHECK
1748     fi
1749 fi
1750
1751 AC_SUBST(wireshark_bin)
1752 AC_SUBST(wireshark_man)
1753 AM_CONDITIONAL(HAVE_Qt, test "$have_qt" = "yes")
1754 AM_CONDITIONAL(HAVE_GTK, test "$have_gtk" = "yes")
1755 AC_SUBST(OSX_APP_FLAGS)
1756 AC_SUBST(OSX_DMG_FLAGS)
1757
1758 # Enable/disable tshark
1759 AC_ARG_ENABLE(tshark,
1760   AC_HELP_STRING( [--enable-tshark],
1761                   [build TShark @<:@default=yes@:>@]),
1762     tshark=$enableval,enable_tshark=yes)
1763
1764 if test "x$enable_tshark" = "xyes" ; then
1765         tshark_bin="tshark\$(EXEEXT)"
1766         tshark_man="tshark.1"
1767         wiresharkfilter_man="wireshark-filter.4"
1768 else
1769         tshark_bin=""
1770         tshark_man=""
1771 fi
1772 AC_SUBST(tshark_bin)
1773 AC_SUBST(tshark_man)
1774
1775 # Enable/disable tfshark
1776 AC_ARG_ENABLE(tfshark,
1777   AC_HELP_STRING( [--enable-tfshark],
1778                   [build TFShark @<:@default=no@:>@]),
1779     tfshark=$enableval,enable_tfshark=no)
1780
1781 if test "x$enable_tfshark" = "xyes" ; then
1782         tfshark_bin="tfshark\$(EXEEXT)"
1783         tfshark_man="tfshark.1"
1784         wiresharkfilter_man="wireshark-filter.4"
1785 else
1786         tfshark_bin=""
1787         tfshark_man=""
1788 fi
1789 AC_SUBST(tfshark_bin)
1790 AC_SUBST(tfshark_man)
1791
1792 # Enable/disable editcap
1793
1794 AC_ARG_ENABLE(editcap,
1795   AC_HELP_STRING( [--enable-editcap],
1796                   [build editcap @<:@default=yes@:>@]),
1797     enable_editcap=$enableval,enable_editcap=yes)
1798
1799 if test "x$enable_editcap" = "xyes" ; then
1800         editcap_bin="editcap\$(EXEEXT)"
1801         editcap_man="editcap.1"
1802 else
1803         editcap_bin=""
1804         editcap_man=""
1805 fi
1806 AC_SUBST(editcap_bin)
1807 AC_SUBST(editcap_man)
1808
1809 # Enable/disable echld
1810
1811 AC_ARG_ENABLE(echld,
1812   AC_HELP_STRING( [--enable-echld],
1813                   [support echld]),
1814     have_echld=$enableval,have_echld=no)
1815
1816 AM_CONDITIONAL(HAVE_ECHLD, test "x$have_echld" = "xyes")
1817 if test "x$have_echld" = "xyes"
1818 then
1819   AC_DEFINE(HAVE_ECHLD, 1, [Define if echld is enabled])
1820   echld_test_bin="echld_test\$(EXEEXT)"
1821   echld_dir="echld"
1822 else
1823   have_echld="no"
1824   echld_test_bin=""
1825   echld_dir=""
1826 fi
1827 AC_SUBST(echld_test_bin)
1828 AC_SUBST(echld_dir)
1829
1830 # Enabling/disabling of dumpcap is done later (after we know if we have PCAP
1831 # or not)
1832
1833 # Enable/disable capinfos
1834
1835 AC_ARG_ENABLE(capinfos,
1836   AC_HELP_STRING( [--enable-capinfos],
1837                   [build capinfos @<:@default=yes@:>@]),
1838     enable_capinfos=$enableval,enable_capinfos=yes)
1839
1840 if test "x$enable_capinfos" = "xyes" ; then
1841         capinfos_bin="capinfos\$(EXEEXT)"
1842         capinfos_man="capinfos.1"
1843 else
1844         capinfos_bin=""
1845         capinfos_man=""
1846 fi
1847 AC_SUBST(capinfos_bin)
1848 AC_SUBST(capinfos_man)
1849
1850 # Enable/disable captype
1851
1852 AC_ARG_ENABLE(captype,
1853   AC_HELP_STRING( [--enable-captype],
1854                   [build captype @<:@default=yes@:>@]),
1855     enable_captype=$enableval,enable_captype=yes)
1856
1857 if test "x$enable_captype" = "xyes" ; then
1858         captype_bin="captype\$(EXEEXT)"
1859         captype_man="captype.1"
1860 else
1861         captype_bin=""
1862         captype_man=""
1863 fi
1864 AC_SUBST(captype_bin)
1865 AC_SUBST(captype_man)
1866
1867 # Enable/disable mergecap
1868
1869 AC_ARG_ENABLE(mergecap,
1870   AC_HELP_STRING( [--enable-mergecap],
1871                   [build mergecap @<:@default=yes@:>@]),
1872     enable_mergecap=$enableval,enable_mergecap=yes)
1873
1874 if test "x$enable_mergecap" = "xyes" ; then
1875         mergecap_bin="mergecap\$(EXEEXT)"
1876         mergecap_man="mergecap.1"
1877 else
1878         mergecap_bin=""
1879         mergecap_man=""
1880 fi
1881 AC_SUBST(mergecap_bin)
1882 AC_SUBST(mergecap_man)
1883
1884 # Enable/disable reordercap
1885
1886 AC_ARG_ENABLE(reordercap,
1887   AC_HELP_STRING( [--enable-reordercap],
1888                   [build reordercap @<:@default=yes@:>@]),
1889     enable_reordercap=$enableval,enable_reordercap=yes)
1890
1891 if test "x$enable_reordercap" = "xyes" ; then
1892         reordercap_bin="reordercap\$(EXEEXT)"
1893         reordercap_man="reordercap.1"
1894 else
1895         reordercap_bin=""
1896         reordercap_man=""
1897 fi
1898 AC_SUBST(reordercap_bin)
1899 AC_SUBST(reordercap_man)
1900
1901 # Enable/disable text2pcap
1902
1903 AC_ARG_ENABLE(text2pcap,
1904   AC_HELP_STRING( [--enable-text2pcap],
1905                   [build text2pcap @<:@default=yes@:>@]),
1906     text2pcap=$enableval,enable_text2pcap=yes)
1907
1908 if test "x$enable_text2pcap" = "xyes" ; then
1909         text2pcap_bin="text2pcap\$(EXEEXT)"
1910         text2pcap_man="text2pcap.1"
1911 else
1912         text2pcap_bin=""
1913         text2pcap_man=""
1914 fi
1915 AC_SUBST(text2pcap_bin)
1916 AC_SUBST(text2pcap_man)
1917
1918 # Enable/disable dftest
1919
1920 AC_ARG_ENABLE(dftest,
1921   AC_HELP_STRING( [--enable-dftest],
1922                   [build dftest @<:@default=yes@:>@]),
1923     enable_dftest=$enableval,enable_dftest=yes)
1924
1925 if test "x$enable_dftest" = "xyes" ; then
1926         dftest_bin="dftest\$(EXEEXT)"
1927         dftest_man="dftest.1"
1928 else
1929         dftest_bin=""
1930         dftest_man=""
1931 fi
1932 AC_SUBST(dftest_bin)
1933 AC_SUBST(dftest_man)
1934
1935 # Enable/disable randpkt
1936
1937 AC_ARG_ENABLE(randpkt,
1938   AC_HELP_STRING( [--enable-randpkt],
1939                   [build randpkt @<:@default=yes@:>@]),
1940     enable_randpkt=$enableval,enable_randpkt=yes)
1941
1942 if test "x$enable_randpkt" = "xyes" ; then
1943         randpkt_bin="randpkt\$(EXEEXT)"
1944         randpkt_man="randpkt.1"
1945 else
1946         randpkt_bin=""
1947         randpkt_man=""
1948 fi
1949 AC_SUBST(randpkt_bin)
1950 AC_SUBST(randpkt_man)
1951
1952 AC_SUBST(wiresharkfilter_man)
1953
1954 dnl Checks for "gethostbyname()" - and "-lnsl", if we need it to get
1955 dnl "gethostbyname()".
1956 AC_WIRESHARK_GETHOSTBY_LIB_CHECK
1957
1958 dnl Checks for "connect()", used as a proxy for "socket()" - and
1959 dnl "-lsocket", if we need it to get "connect()".
1960 AC_WIRESHARK_SOCKET_LIB_CHECK
1961
1962 dnl pcap check
1963 AC_MSG_CHECKING(whether to use libpcap for packet capture)
1964
1965 AC_ARG_WITH(pcap,
1966   AC_HELP_STRING( [--with-pcap@<:@=DIR@:>@],
1967                   [use libpcap for packet capturing @<:@default=yes@:>@]),
1968 [
1969         if test $withval = no
1970         then
1971                 want_pcap=no
1972         elif test $withval = yes
1973         then
1974                 want_pcap=yes
1975         else
1976                 want_pcap=yes
1977                 pcap_dir=$withval
1978         fi
1979 ],[
1980         want_pcap=yes
1981         pcap_dir=
1982 ])
1983 if test "x$want_pcap" = "xno" ; then
1984         AC_MSG_RESULT(no)
1985 else
1986         AC_MSG_RESULT(yes)
1987         AC_WIRESHARK_PCAP_CHECK
1988 fi
1989
1990
1991 dnl Check for airpcap
1992 AC_MSG_CHECKING(whether to include airpcap support)
1993 AC_ARG_ENABLE(airpcap,
1994   AC_HELP_STRING( [--enable-airpcap],
1995                   [use AirPcap in Wireshark @<:@default=yes@:>@]),
1996   enable_airpcap=$enableval, enable_airpcap=yes)
1997
1998 if test x$enable_airpcap = xyes; then
1999         if test "x$want_pcap" = "xno" ; then
2000                 enable_airpcap=no
2001                 AC_MSG_RESULT(pcap not available - disabling airpcap)
2002         else
2003                 AC_MSG_RESULT(yes)
2004                 AC_DEFINE(HAVE_AIRPCAP, 1, [Enable AirPcap])
2005         fi
2006 else
2007         AC_MSG_RESULT(no)
2008 fi
2009
2010
2011 dnl dumpcap check
2012 AC_MSG_CHECKING(whether to build dumpcap)
2013
2014 AC_ARG_ENABLE(dumpcap,
2015   AC_HELP_STRING( [--enable-dumpcap],
2016                   [build dumpcap @<:@default=yes@:>@]),
2017     enable_dumpcap=$enableval,enable_dumpcap=yes)
2018
2019 if test "x$enable_dumpcap" = "xyes" ; then
2020         if test "x$want_pcap" = "xno" ; then
2021                 enable_dumpcap=no
2022                 AC_MSG_RESULT(pcap not available - disabling dumpcap)
2023         else
2024                 AC_MSG_RESULT(yes)
2025         fi
2026 else
2027         AC_MSG_RESULT(no)
2028 fi
2029
2030 if test "x$enable_dumpcap" = "xyes" ; then
2031         dumpcap_bin="dumpcap\$(EXEEXT)"
2032         dumpcap_man="dumpcap.1"
2033 else
2034         dumpcap_bin=""
2035         dumpcap_man=""
2036 fi
2037 AC_SUBST(dumpcap_bin)
2038 AC_SUBST(dumpcap_man)
2039
2040 # Enable/disable rawshark
2041
2042 dnl rawshark check
2043 AC_MSG_CHECKING(whether to build rawshark)
2044
2045 AC_ARG_ENABLE(rawshark,
2046   AC_HELP_STRING( [--enable-rawshark],
2047                   [build rawshark @<:@default=yes@:>@]),
2048     rawshark=$enableval,enable_rawshark=yes)
2049
2050 if test "x$enable_rawshark" = "xyes" ; then
2051         if test "x$want_pcap" = "xno" ; then
2052                 enable_rawshark=no
2053                 AC_MSG_RESULT(pcap not available - disabling rawshark)
2054         else
2055                 AC_MSG_RESULT(yes)
2056         fi
2057 else
2058         AC_MSG_RESULT(no)
2059 fi
2060
2061 if test "x$enable_rawshark" = "xyes" ; then
2062         rawshark_bin="rawshark\$(EXEEXT)"
2063         rawshark_man="rawshark.1"
2064 else
2065         rawshark_bin=""
2066         rawshark_man=""
2067 fi
2068 AC_SUBST(rawshark_bin)
2069 AC_SUBST(rawshark_man)
2070
2071 dnl Use pcap-ng by default
2072 AC_ARG_ENABLE(pcap-ng-default,
2073   AC_HELP_STRING( [--enable-pcap-ng-default],
2074                   [use the pcap-ng file format by default instead of pcap @<:@default=yes@:>@]),
2075     enable_pcap_ng_default=$enableval,enable_pcap_ng_default=yes)
2076 if test x$enable_pcap_ng_default = xyes; then
2077         AC_DEFINE(PCAP_NG_DEFAULT, 1, [Support for pcap-ng])
2078 fi
2079
2080 dnl pcap remote check
2081 AC_MSG_CHECKING(whether to use libpcap remote capturing feature)
2082
2083 AC_ARG_WITH(pcap-remote,
2084     AC_HELP_STRING([--with-pcap-remote],
2085                    [use libpcap remote capturing (requires libpcap)]),
2086 [
2087     if test $withval = no
2088     then
2089         want_pcap_remote=no
2090     else
2091         want_pcap_remote=yes
2092     fi
2093 ],[
2094     want_pcap_remote=no
2095 ])
2096 if test "x$want_pcap_remote" = "xno" -o "x$want_pcap" = "xno" ; then
2097     AC_MSG_RESULT(no)
2098 else
2099     AC_MSG_RESULT(yes)
2100     AC_WIRESHARK_PCAP_REMOTE_CHECK
2101 fi
2102
2103 dnl zlib check
2104 AC_MSG_CHECKING(whether to use zlib for gzip compression and decompression)
2105
2106 AC_ARG_WITH(zlib,
2107   AC_HELP_STRING([--with-zlib@<:@=DIR@:>@],
2108                  [use zlib (located in directory DIR, if supplied) for gzip compression and decompression @<:@default=yes, if available@:>@]),
2109 [
2110         if test "x$withval" = "xno"
2111         then
2112                 want_zlib=no
2113         elif test "x$withval" = "xyes"
2114         then
2115                 want_zlib=yes
2116         else
2117                 want_zlib=yes
2118                 zlib_dir="$withval"
2119         fi
2120 ],[
2121         #
2122         # Use zlib if it's present, otherwise don't.
2123         #
2124         want_zlib=ifavailable
2125         zlib_dir=
2126 ])
2127 if test "x$want_zlib" = "xno" ; then
2128         AC_MSG_RESULT(no)
2129 else
2130         AC_MSG_RESULT(yes)
2131         AC_WIRESHARK_ZLIB_CHECK
2132         if test "x$want_zlib" = "xno" ; then
2133                 AC_MSG_RESULT(zlib not found - disabling gzip compression and decompression)
2134         else
2135                 if test "x$ac_cv_func_inflatePrime" = "xno" ; then
2136                         AC_MSG_RESULT(inflatePrime not found in zlib - disabling gzipped capture file support)
2137                 fi
2138         fi
2139 fi
2140
2141 dnl Lua check
2142 AC_MSG_CHECKING(whether to use liblua for the Lua scripting plugin)
2143
2144 AC_ARG_WITH(lua,
2145   AC_HELP_STRING( [--with-lua@<:@=DIR@:>@],
2146                   [use liblua (located in directory DIR, if supplied) for the Lua scripting plugin @<:@default=yes, if available@:>@]),
2147 [
2148         if test $withval = no
2149         then
2150                 want_lua=no
2151         elif test $withval = yes
2152         then
2153                 want_lua=yes
2154         else
2155                 want_lua=yes
2156                 lua_dir=$withval
2157         fi
2158 ],[
2159         #
2160         # Use liblua by default
2161         #
2162         want_lua=ifavailable
2163         lua_dir=
2164 ])
2165 if test "x$want_lua" = "xno" ; then
2166         AC_MSG_RESULT(no)
2167 else
2168         AC_MSG_RESULT(yes)
2169         AC_WIRESHARK_LIBLUA_CHECK
2170         if test "x$want_lua" = "xno" ; then
2171                 AC_MSG_RESULT(liblua not found - disabling support for the lua scripting plugin)
2172         fi
2173 fi
2174 AM_CONDITIONAL(HAVE_LIBLUA, test x$want_lua = xyes)
2175
2176
2177 dnl portaudio check
2178 AC_MSG_CHECKING(whether to use libportaudio for the rtp_player)
2179
2180 AC_ARG_WITH(portaudio,
2181   AC_HELP_STRING( [--with-portaudio@<:@=DIR@:>@],
2182                   [use libportaudio (located in directory DIR, if supplied) for the rtp_player @<:@default=yes, if available@:>@]),
2183 [
2184         if test $withval = no
2185         then
2186                 want_portaudio=no
2187         elif test $withval = yes
2188         then
2189                 want_portaudio=yes
2190         else
2191                 want_portaudio=yes
2192                 portaudio_dir=$withval
2193         fi
2194 ],[
2195         #
2196         # Use libportaudio by default
2197         #
2198         want_portaudio=ifavailable
2199         portaudio_dir=
2200 ])
2201 if test "x$want_portaudio" = "xno" ; then
2202         AC_MSG_RESULT(no)
2203 else
2204         AC_MSG_RESULT(yes)
2205         AC_WIRESHARK_LIBPORTAUDIO_CHECK
2206         if test "x$want_portaudio" = "xno" ; then
2207                 AC_MSG_RESULT(libportaudio not found - disabling support for the rtp_player)
2208         fi
2209 fi
2210 AM_CONDITIONAL(HAVE_LIBPORTAUDIO, test x$want_portaudio = xyes)
2211
2212
2213 dnl ipv6 check
2214 AC_ARG_ENABLE(ipv6,
2215   AC_HELP_STRING( [--enable-ipv6],
2216                   [use IPv6 name resolution, if available @<:@default=yes@:>@]),
2217     enable_ipv6=$enableval,enable_ipv6=yes)
2218
2219 AC_MSG_CHECKING(whether to enable ipv6 name resolution if available)
2220 if test "x$enable_ipv6" = "xno" ; then
2221         AC_MSG_RESULT(no)
2222 else
2223         AC_MSG_RESULT(yes)
2224         AC_WIRESHARK_IPV6_STACK
2225 fi
2226
2227
2228 dnl Check if dumpcap should be installed with filesystem capabilities
2229 AC_PATH_PROG(SETCAP, setcap)
2230 AC_ARG_ENABLE(setcap-install,
2231   AC_HELP_STRING( [--enable-setcap-install],
2232                   [install dumpcap with cap_net_admin and cap_net_raw @<:@default=no@:>@]),
2233     enable_setcap_install=$enableval,enable_setcap_install=no)
2234
2235 AC_MSG_CHECKING(whether to install dumpcap with cap_net_admin and cap_net_raw capabilities)
2236 if test "x$enable_setcap_install" = "xno" ; then
2237         AC_MSG_RESULT(no)
2238 else
2239         if test "x$SETCAP" = "x" ; then
2240                 AC_MSG_RESULT(no. Setcap not found)
2241         elif test "x$enable_dumpcap" = "xno" ; then
2242                 AC_MSG_ERROR(Setcap install works only with dumpcap but dumpcap is disabled)
2243         else
2244                 AC_MSG_RESULT(yes)
2245         fi
2246 fi
2247
2248 AM_CONDITIONAL(SETCAP_INSTALL, test x$enable_setcap_install = xyes)
2249
2250 dnl Check if dumpcap should be installed setuid
2251 AC_ARG_ENABLE(setuid-install,
2252   AC_HELP_STRING( [--enable-setuid-install],
2253                   [install dumpcap as setuid @<:@default=no@:>@]),
2254     enable_setuid_install=$enableval,enable_setuid_install=no)
2255
2256 AC_MSG_CHECKING(whether to install dumpcap setuid)
2257 if test "x$enable_setuid_install" = "xno" ; then
2258         AC_MSG_RESULT(no)
2259 else
2260         if test "x$enable_setcap_install" = "xyes" ; then
2261                 enable_setuid_install=no
2262                 AC_MSG_RESULT(no; using setcap instead)
2263         elif test "x$enable_dumpcap" = "xno" ; then
2264                 AC_MSG_ERROR(Setuid install works only with dumpcap but dumpcap is disabled)
2265         else
2266                 AC_MSG_RESULT(yes)
2267         fi
2268 fi
2269
2270 AM_CONDITIONAL(SETUID_INSTALL, test x$enable_setuid_install = xyes)
2271 AC_CHECK_FUNCS(setresuid setresgid)
2272
2273 dnl ...but our Network Operations group is named "no"!
2274 DUMPCAP_GROUP=''
2275 AC_ARG_WITH(dumpcap-group,
2276   AC_HELP_STRING( [--with-dumpcap-group=GROUP],
2277                   [restrict dumpcap to GROUP]),
2278 [
2279   if test "x$withval" = "xyes"; then
2280       AC_MSG_ERROR([No dumpcap group specified.])
2281   elif test "x$withval" != "xno"; then
2282       if test "x$enable_dumpcap" = "xno" ; then
2283           AC_MSG_ERROR(dumpcap group install works only with dumpcap but dumpcap is disabled)
2284       fi
2285       AC_MSG_RESULT($withval)
2286       DUMPCAP_GROUP="$withval"
2287   fi
2288 ])
2289 AC_SUBST(DUMPCAP_GROUP)
2290 AM_CONDITIONAL(HAVE_DUMPCAP_GROUP, test x$DUMPCAP_GROUP != x)
2291
2292 dnl libcap (not libpcap) check
2293 LIBCAP_LIBS=''
2294 AC_MSG_CHECKING(whether to use the libcap capabilities library)
2295
2296 AC_ARG_WITH(libcap,
2297   AC_HELP_STRING( [--with-libcap@<:@=DIR@:>@],
2298                   [use libcap (located in directory DIR, if supplied) for POSIX.1e capabilities management @<:@default=yes, if present@:>@]),
2299 [
2300 if   test "x$withval" = "xno";  then
2301         want_libcap=no
2302 elif test "x$withval" = "xyes"; then
2303         want_libcap=yes
2304 elif test -d "$withval"; then
2305         want_libcap=yes
2306         AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
2307 fi
2308 ])
2309 if test "x$with_libcap" = "xno" ; then
2310         AC_MSG_RESULT(no)
2311 else
2312         AC_MSG_RESULT(yes)
2313         AC_WIRESHARK_LIBCAP_CHECK
2314 fi
2315 AC_SUBST(LIBCAP_LIBS)
2316
2317 dnl Checks for header files.
2318 dnl Some of these may not be needed: http://hacks.owlfolio.org/header-survey/
2319 AC_CHECK_HEADERS(direct.h dirent.h fcntl.h getopt.h grp.h inttypes.h netdb.h pwd.h stdarg.h stddef.h unistd.h)
2320 AC_CHECK_HEADERS(sys/ioctl.h sys/param.h sys/socket.h sys/sockio.h sys/stat.h sys/time.h sys/types.h sys/utsname.h sys/wait.h)
2321 AC_CHECK_HEADERS(netinet/in.h)
2322 AC_CHECK_HEADERS(arpa/inet.h arpa/nameser.h)
2323
2324 dnl SSL Check
2325 SSL_LIBS=''
2326 AC_MSG_CHECKING(whether to use SSL library)
2327
2328 AC_ARG_WITH(ssl,
2329   AC_HELP_STRING( [--with-ssl@<:@=DIR@:>@],
2330                   [use SSL crypto library (located in directory DIR, if supplied) @<:@default=no@:>@]),
2331 [
2332 if test "x$withval" = "xno";  then
2333         want_ssl=no
2334 elif test "x$withval" = "xyes"; then
2335         want_ssl=yes
2336 elif test -d "$withval"; then
2337         want_ssl=yes
2338         AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
2339 fi
2340 ],[
2341         want_ssl=no
2342 ])
2343 if test "x$want_ssl" = "xyes"; then
2344         AC_MSG_RESULT(yes)
2345         AC_CHECK_LIB(crypto,EVP_md5,
2346             [
2347                 SSL_LIBS=-lcrypto
2348             ],
2349             [
2350                 AC_MSG_ERROR([SSL crypto library was requested, but is not available])
2351             ])
2352 else
2353         AC_MSG_RESULT(no)
2354 fi
2355 AC_SUBST(SSL_LIBS)
2356
2357 dnl kerberos check
2358 AC_MSG_CHECKING(whether to use Kerberos library)
2359
2360 AC_ARG_WITH(krb5,
2361   AC_HELP_STRING( [--with-krb5@<:@=DIR@:>@],
2362                   [use Kerberos library (located in directory DIR, if supplied) to use in Kerberos dissection @<:@default=yes@:>@]),
2363 [
2364         if test $withval = no
2365         then
2366                 want_krb5=no
2367         elif test $withval = yes
2368         then
2369                 want_krb5=yes
2370         else
2371                 want_krb5=yes
2372                 krb5_dir=$withval
2373         fi
2374 ],[
2375         #
2376         # Use Kerberos library if available, otherwise don't.
2377         #
2378         want_krb5=ifavailable
2379         krb5_dir=
2380 ])
2381 if test "x$want_krb5" = "xno" ; then
2382         AC_MSG_RESULT(no)
2383 else
2384         AC_MSG_RESULT(yes)
2385         AC_WIRESHARK_KRB5_CHECK
2386 fi
2387
2388
2389 dnl c-ares Check
2390 C_ARES_LIBS=''
2391 AC_MSG_CHECKING(whether to use the c-ares library if available)
2392
2393 AC_ARG_WITH(c-ares,
2394   AC_HELP_STRING( [--with-c-ares@<:@=DIR@:>@],
2395                   [use c-ares (located in directory DIR, if supplied) - supersedes --with-adns @<:@default=yes, if present@:>@]),
2396 [
2397 if   test "x$withval" = "xno";  then
2398         want_c_ares=no
2399 elif test "x$withval" = "xyes"; then
2400         want_c_ares=yes
2401 elif test -d "$withval"; then
2402         want_c_ares=yes
2403         AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
2404 fi
2405 ])
2406 if test "x$want_c_ares" = "xno" ; then
2407         AC_MSG_RESULT(no)
2408 else
2409         AC_MSG_RESULT(yes)
2410         AC_WIRESHARK_C_ARES_CHECK
2411 fi
2412 AC_SUBST(C_ARES_LIBS)
2413
2414 dnl ADNS Check
2415 ADNS_LIBS=''
2416 AC_MSG_CHECKING(whether to use the GNU ADNS library if available)
2417
2418 AC_ARG_WITH(adns,
2419   AC_HELP_STRING( [--with-adns@<:@=DIR@:>@],
2420                   [use GNU ADNS (located in directory DIR, if supplied) @<:@default=yes, if present@:>@]),
2421 [
2422 if   test "x$withval" = "xno";  then
2423         want_adns=no
2424 elif test "x$withval" = "xyes"; then
2425         want_adns=yes
2426 elif test -d "$withval"; then
2427         want_adns=yes
2428         AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
2429 fi
2430 ])
2431 if test "x$want_adns" = "xno" -o "x$have_good_c_ares" = "xyes" ; then
2432         AC_MSG_RESULT(no)
2433 else
2434         AC_MSG_RESULT(yes)
2435         AC_WIRESHARK_ADNS_CHECK
2436 fi
2437 AC_SUBST(ADNS_LIBS)
2438
2439 dnl GEOIP Check
2440 GEOIP_LIBS=''
2441 AC_MSG_CHECKING(whether to use the GeoIP IP address mapping library if available)
2442
2443 AC_ARG_WITH(geoip,
2444   AC_HELP_STRING( [--with-geoip@<:@=DIR@:>@],
2445                   [use GeoIP (located in directory DIR, if supplied) @<:@default=yes, if present@:>@]),
2446 [
2447 if   test "x$withval" = "xno";  then
2448         want_geoip=no
2449 elif test "x$withval" = "xyes"; then
2450         want_geoip=yes
2451 elif test -d "$withval"; then
2452         want_geoip=yes
2453         AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
2454 fi
2455 ])
2456 if test "x$want_geoip" = "xno"; then
2457         AC_MSG_RESULT(no)
2458 else
2459         AC_MSG_RESULT(yes)
2460         AC_WIRESHARK_GEOIP_CHECK
2461 fi
2462 AC_SUBST(GEOIP_LIBS)
2463
2464 # Warning: this Python scripting appears to be broken (does not work at all).
2465 # Running it also causes Valgrind to complain about all sorts of memory errors.
2466 # Suggestion: do not enable it unless you are working on fixing it.
2467 #
2468 # An alternative might be https://code.google.com/p/pyreshark/
2469 #
2470 dnl Python devel Check
2471 AC_MSG_CHECKING(whether to use the Python interpreter for scripting)
2472
2473 AC_ARG_WITH(broken-python,
2474     AC_HELP_STRING( [--with-broken-python@<:@=DIR@:>@],
2475                     [use the (BROKEN) Python interpreter (installed in DIR, if supplied) @<:@default=no@:>@]),
2476 [
2477         pythondir='${libdir}/wireshark/python/${VERSION}'
2478         if test "x$withval" = "xno"
2479         then
2480                 want_python=no
2481         elif test "x$withval" = "xyes"
2482         then
2483                 want_python=yes
2484         else
2485                 want_python=yes
2486                 pythondir="$withval"
2487         fi
2488 ],[
2489         # By default (user didn't explicitly enable Python), don't enable
2490         # Python support.
2491         #
2492         want_python=no
2493         #pythondir='${libdir}/wireshark/python/${VERSION}'
2494 ])
2495 if test "x$want_python" = "xno" ; then
2496         AC_MSG_RESULT(no)
2497 else
2498         AC_MSG_RESULT(yes)
2499         AC_WIRESHARK_PYTHON_CHECK
2500 fi
2501 AM_CONDITIONAL(HAVE_LIBPY, test x$want_python != xno)
2502 AC_SUBST(pythondir)
2503
2504 #
2505 # Define WS_MSVC_NORETURN appropriately for declarations of routines that
2506 # never return (just like Charlie on the MTA).
2507 #
2508 # Note that MSVC++ expects __declspec(noreturn) to precede the function
2509 # name and GCC, as far as I know, expects __attribute__((noreturn)) to
2510 # follow the function name, so we need two different flavors of
2511 # noreturn tag.
2512 #
2513 AC_DEFINE(WS_MSVC_NORETURN,, [Define as the string to precede declarations of routines that never return])
2514
2515 dnl Checks for typedefs, structures, and compiler characteristics.
2516 # AC_C_CONST
2517
2518 # Check how we can get the time zone abbreviation
2519 AC_WIRESHARK_TIMEZONE_ABBREV
2520
2521 # We need to know whether "struct stat" has an "st_flags" member
2522 # for file_user_immutable().
2523
2524 AC_WIRESHARK_STRUCT_ST_FLAGS
2525
2526 # We need to know whether "struct sockaddr" has an "sa_len" member
2527 # for get_interface_list().
2528
2529 AC_WIRESHARK_STRUCT_SA_LEN
2530
2531 # We must know our byte order
2532 AC_C_BIGENDIAN
2533
2534 # Checks whether "-traditional" is needed when using "ioctl".
2535 # XXX - do we need this?
2536 AC_PROG_GCC_TRADITIONAL
2537
2538 GETOPT_LO=""
2539 AC_CHECK_FUNC(getopt,
2540   [GETOPT_LO=""
2541    AC_DEFINE(HAVE_GETOPT, 1, [Define to 1 if you have the getopt function.])
2542   ],
2543   GETOPT_LO="wsgetopt.lo"
2544 )
2545 if test "$ac_cv_func_getopt" = no ; then
2546   GETOPT_LO="wsgetopt.lo"
2547 fi
2548 AM_CONDITIONAL(NEED_GETOPT_LO, test "x$ac_cv_func_getopt" = "xno")
2549 AC_SUBST(GETOPT_LO)
2550
2551 AC_CHECK_FUNC(strncasecmp, STRNCASECMP_LO="",
2552   STRNCASECMP_LO="strncasecmp.lo")
2553 if test "$ac_cv_func_strncasecmp" = no ; then
2554   STRNCASECMP_LO="strncasecmp.lo"
2555 fi
2556 AM_CONDITIONAL(NEED_STRNCASECMP_LO, test "x$ac_cv_func_strncasecmp" = "xno")
2557 AC_SUBST(STRNCASECMP_LO)
2558
2559 AC_CHECK_FUNCS(mkstemp mkdtemp)
2560
2561 AC_SEARCH_LIBS(inet_aton, [socket nsl], have_inet_aton=yes,
2562     have_inet_aton=no)
2563 if test "$have_inet_aton" = no; then
2564   INET_ATON_LO="inet_aton.lo"
2565   AC_DEFINE(HAVE_INET_ATON_H, 0, [Define unless inet/aton.h needs to be included])
2566 else
2567   INET_ATON_LO=""
2568 fi
2569 AM_CONDITIONAL(NEED_INET_ATON_LO, test "x$have_inet_aton" = "xno")
2570 AC_SUBST(INET_ATON_LO)
2571
2572 AC_SEARCH_LIBS(inet_pton, [socket nsl], [
2573   dnl check for pre-BIND82 inet_pton() bug.
2574   AC_MSG_CHECKING(for broken inet_pton)
2575   AC_TRY_RUN([#include <sys/types.h>
2576 #include <sys/socket.h>
2577 #include <netinet/in.h>
2578 #include <arpa/inet.h>
2579 int main()
2580 {
2581 #ifdef AF_INET6
2582   char buf[16];
2583   /* this should return 0 (error) */
2584   return inet_pton(AF_INET6, "0:1:2:3:4:5:6:7:", buf);
2585 #else
2586   return 1;
2587 #endif
2588 }], [AC_MSG_RESULT(ok);
2589 have_inet_pton=yes], [AC_MSG_RESULT(broken);
2590 have_inet_pton=no], [AC_MSG_RESULT(cross compiling, assume it is broken);
2591 have_inet_pton=no])],
2592 have_inet_pton=no)
2593 if test "$have_inet_pton" = no; then
2594   INET_PTON_LO="inet_pton.lo"
2595 else
2596   INET_PTON_LO=""
2597 fi
2598 AM_CONDITIONAL(NEED_INET_PTON_LO, test "x$have_inet_pton" = "xno")
2599 AC_SUBST(INET_PTON_LO)
2600
2601 AC_SEARCH_LIBS(inet_ntop, [socket nsl], [
2602   AC_MSG_CHECKING([for inet_ntop prototype])
2603   AC_TRY_COMPILE([#include <stdio.h>
2604 #include <sys/types.h>
2605 #include <sys/socket.h>
2606 #include <netinet/in.h>
2607 #include <arpa/inet.h>
2608
2609 extern const char *inet_ntop(int, const void *, char *, size_t);],, [
2610     AC_MSG_RESULT(yes)
2611     AC_DEFINE(HAVE_INET_NTOP_PROTO, 1,
2612     [Define if inet_ntop() prototype exists])], [
2613     AC_TRY_COMPILE([#include <stdio.h>
2614 #include <sys/types.h>
2615 #include <sys/socket.h>
2616 #include <netinet/in.h>
2617 #include <arpa/inet.h>
2618
2619 extern const char *inet_ntop(int, const void *, char *, socklen_t);],, [
2620       AC_MSG_RESULT(yes)
2621       AC_DEFINE(HAVE_INET_NTOP_PROTO, 1,
2622       [Define if inet_ntop() prototype exists])], [
2623       AC_MSG_RESULT(no)])])
2624   INET_NTOP_LO=""], [
2625   INET_NTOP_LO="inet_ntop.lo"
2626   AC_DEFINE(NEED_INET_V6DEFS_H, 1,
2627   [Define if inet/v6defs.h needs to be included])])
2628 AM_CONDITIONAL(NEED_INET_NTOP_LO, test "x$INET_NTOP_LO" != "x")
2629 AC_SUBST(INET_NTOP_LO)
2630
2631 AC_CHECK_FUNC(strptime, STRPTIME_LO="",
2632   [STRPTIME_LO="strptime.lo"
2633    AC_DEFINE(NEED_STRPTIME_H, 1, [Define if strptime.h needs to be included])
2634 ])
2635 if test "$ac_cv_func_strptime" = no ; then
2636   STRPTIME_LO="strptime.lo"
2637 fi
2638 AC_SUBST(STRPTIME_C)
2639 AM_CONDITIONAL(NEED_STRPTIME_LO, test "x$ac_cv_func_strptime" = "no")
2640 AC_SUBST(STRPTIME_LO)
2641
2642 AC_CHECK_FUNCS(getprotobynumber gethostbyname2)
2643 AC_CHECK_FUNCS(issetugid)
2644 AC_CHECK_FUNCS(mmap mprotect sysconf)
2645
2646 dnl blank for now, but will be used in future
2647 AC_SUBST(wireshark_SUBDIRS)
2648
2649 # Check Bluetooth SBC codec for RTP Player
2650 # git://git.kernel.org/pub/scm/bluetooth/sbc.git
2651 PKG_CHECK_MODULES(SBC, sbc >= 1.0, [have_sbc=yes], [have_sbc=no])
2652 if (test "${have_sbc}" = "yes"); then
2653     AC_DEFINE(HAVE_SBC, 1, [Define to support playing SBC by standalone BlueZ SBC library])
2654     CFLAGS="$CFLAGS $(pkg-config sbc --cflags)"
2655     LIBS="$LIBS $(pkg-config sbc --libs)"
2656 fi
2657
2658 dnl
2659 dnl check whether plugins should be enabled and, if they should be,
2660 dnl check for plugins directory - stolen from Amanda's configure.ac
2661 dnl
2662 dnl we don't wish to expand ${libdir} yet
2663 plugindir='${libdir}/wireshark/plugins/${VERSION}'
2664 AC_ARG_WITH(plugins,
2665   AC_HELP_STRING( [--with-plugins@<:@=DIR@:>@],
2666                   [support plugins (installed in DIR, if supplied) @<:@default=yes, if possible@:>@]),
2667 [
2668   if test "x$withval" = "xno"; then
2669     have_plugins=no
2670   elif test "x$have_plugins" = "xno"; then
2671       AC_MSG_ERROR([GLib on this platform doesn't support loadable modules, so you can't enable plugins.])
2672   elif test "x$withval" != "xyes"; then
2673       plugindir="$withval"
2674   fi
2675 ])
2676 AM_CONDITIONAL(HAVE_PLUGINS, test "x$have_plugins" = "xyes")
2677 if test x$have_plugins = xyes
2678 then
2679   AC_DEFINE(HAVE_PLUGINS, 1, [Define if plugins are enabled])
2680 fi
2681 AC_SUBST(plugindir)
2682 CPPFLAGS="$CPPFLAGS '-DPLUGIN_DIR=\"\$(plugindir)\"'"
2683
2684 #
2685 # The plugin dissectors reside in ./plugins/PROTO/
2686 #
2687 PLUGIN_LIBS=""
2688 AC_SUBST(PLUGIN_LIBS)
2689
2690 #
2691 # Check if (emem) memory allocations must be 8-byte aligned.
2692 # I haven't been able to write C code that reliably makes that determination
2693 # (different versions of GCC with or without optimization give different
2694 # results) so just assume everything except (32-bit) x86 needs 8-byte
2695 # alignment (64-bit platforms either require 8-byte alignment for pointers
2696 # and 64-bit integral data types or may get better performance from that;
2697 # 64-bit x86 will get 8-byte alignment from G_MEM_ALIGN anyway.  32-bit
2698 # platforms would only require it, or get better performance from it,
2699 # for 64-bit floating-point values.).
2700 #
2701 AC_MSG_CHECKING(whether we need memory allocations to be 8-byte aligned)
2702 case $host_cpu in
2703         i386|i486|i586|i686)
2704                 AC_MSG_RESULT(no)
2705                 ;;
2706         *)
2707                 AC_MSG_RESULT(yes)
2708                 AC_DEFINE(NEED_8_BYTE_ALIGNMENT, 1, [Define if we need memory allocations to be 8-byte aligned])
2709                 ;;
2710 esac
2711
2712 # Gather only the "--with*" arguments and also a list of --with arguments for rpmbuild
2713 for f in $CONFIG_ARGS
2714 do
2715         case $f in
2716         --with-gtk2*)
2717                 CONFIG_WITH_ARGS="$CONFIG_WITH_ARGS $f"
2718                 RPMBUILD_WITH_ARGS="$RPMBUILD_WITH_ARGS --with gtk2"
2719                 ;;
2720         --without-gtk2*)
2721                 CONFIG_WITH_ARGS="$CONFIG_WITH_ARGS $f"
2722                 RPMBUILD_WITH_ARGS="$RPMBUILD_WITH_ARGS --without gtk2"
2723                 ;;
2724         --with-gtk3*)
2725                 CONFIG_WITH_ARGS="$CONFIG_WITH_ARGS $f"
2726                 RPMBUILD_WITH_ARGS="$RPMBUILD_WITH_ARGS --with gtk3"
2727                 ;;
2728         --without-gtk3*)
2729                 CONFIG_WITH_ARGS="$CONFIG_WITH_ARGS $f"
2730                 RPMBUILD_WITH_ARGS="$RPMBUILD_WITH_ARGS --without gtk3"
2731                 ;;
2732         --with-qt*)
2733                 CONFIG_WITH_ARGS="$CONFIG_WITH_ARGS $f"
2734                 RPMBUILD_WITH_ARGS="$RPMBUILD_WITH_ARGS --with qt"
2735                 ;;
2736         --without-qt*)
2737                 CONFIG_WITH_ARGS="$CONFIG_WITH_ARGS $f"
2738                 RPMBUILD_WITH_ARGS="$RPMBUILD_WITH_ARGS --without qt"
2739                 ;;
2740         --with*)
2741                 CONFIG_WITH_ARGS="$CONFIG_WITH_ARGS $f"
2742                 ;;
2743         esac
2744
2745 done
2746 AC_SUBST(CONFIG_WITH_ARGS)
2747 AC_SUBST(RPMBUILD_WITH_ARGS)
2748
2749 dnl libtool defs
2750 #
2751 # Yes, AM_PROG_LIBTOOL is redundant with newer version(s) of some tool(s)
2752 # (autoconf?  automake?  libtool?) - with the newer version(s), it's
2753 # just an alias for AC_PROG_LIBTOOL, which is called earlier.
2754 #
2755 # With older version(s) of those tool(s), however, it's not just an
2756 # alias, and the configure scripts don't work without it.
2757 #
2758 AM_PROG_LIBTOOL
2759 AC_SUBST(LIBTOOL_DEPS)
2760
2761 AM_CONDITIONAL(ENABLE_STATIC, test x$enable_static = xyes)
2762 if test x$enable_static = xyes -a x$have_plugins = xyes
2763 then
2764   AC_DEFINE(ENABLE_STATIC, 1, [Link plugins statically into Wireshark])
2765 fi
2766 AC_SUBST(ENABLE_STATIC)
2767
2768 dnl Save the cacheable configure results to config.cache before recursing
2769 AC_CACHE_SAVE
2770
2771 sinclude(plugins/Custom.m4) dnl
2772 ifdef(_CUSTOM_AC_OUTPUT_,, define(_CUSTOM_AC_OUTPUT_, )) dnl
2773
2774 sinclude(asn1/Custom.m4) dnl
2775 ifdef(_CUSTOM_ASN1_AC_OUTPUT_,, define(_CUSTOM_ASN1_AC_OUTPUT_, )) dnl
2776
2777 AC_CONFIG_HEADERS(config.h)
2778 AC_OUTPUT(
2779   Makefile
2780   doxygen.cfg
2781   asn1/Makefile
2782   _CUSTOM_ASN1_AC_OUTPUT_
2783   asn1/acp133/Makefile
2784   asn1/acse/Makefile
2785   asn1/ansi_map/Makefile
2786   asn1/ansi_tcap/Makefile
2787   asn1/atn-cm/Makefile
2788   asn1/atn-cpdlc/Makefile
2789   asn1/atn-ulcs/Makefile
2790   asn1/c1222/Makefile
2791   asn1/camel/Makefile
2792   asn1/cdt/Makefile
2793   asn1/charging_ase/Makefile
2794   asn1/cmip/Makefile
2795   asn1/cmp/Makefile
2796   asn1/crmf/Makefile
2797   asn1/cms/Makefile
2798   asn1/credssp/Makefile
2799   asn1/dap/Makefile
2800   asn1/disp/Makefile
2801   asn1/dop/Makefile
2802   asn1/dsp/Makefile
2803   asn1/ess/Makefile
2804   asn1/ftam/Makefile
2805   asn1/goose/Makefile
2806   asn1/gprscdr/Makefile
2807   asn1/gsm_map/Makefile
2808   asn1/h225/Makefile
2809   asn1/h235/Makefile
2810   asn1/h245/Makefile
2811   asn1/h248/Makefile
2812   asn1/h282/Makefile
2813   asn1/h283/Makefile
2814   asn1/h323/Makefile
2815   asn1/h450/Makefile
2816   asn1/h450-ros/Makefile
2817   asn1/h460/Makefile
2818   asn1/h501/Makefile
2819   asn1/HI2Operations/Makefile
2820   asn1/hnbap/Makefile
2821   asn1/idmp/Makefile
2822   asn1/ilp/Makefile
2823   asn1/inap/Makefile
2824   asn1/isdn-sup/Makefile
2825   asn1/kerberos/Makefile
2826   asn1/lcsap/Makefile
2827   asn1/ldap/Makefile
2828   asn1/logotypecertextn/Makefile
2829   asn1/lpp/Makefile
2830   asn1/lppa/Makefile
2831   asn1/lppe/Makefile
2832   asn1/lte-rrc/Makefile
2833   asn1/m3ap/Makefile
2834   asn1/mms/Makefile
2835   asn1/mpeg-audio/Makefile
2836   asn1/mpeg-pes/Makefile
2837   asn1/nbap/Makefile
2838   asn1/ns_cert_exts/Makefile
2839   asn1/novell_pkis/Makefile
2840   asn1/ocsp/Makefile
2841   asn1/p1/Makefile
2842   asn1/p22/Makefile
2843   asn1/p7/Makefile
2844   asn1/p772/Makefile
2845   asn1/pcap/Makefile
2846   asn1/pkcs1/Makefile
2847   asn1/pkcs12/Makefile
2848   asn1/pkinit/Makefile
2849   asn1/pkixac/Makefile
2850   asn1/pkix1explicit/Makefile
2851   asn1/pkix1implicit/Makefile
2852   asn1/pkixproxy/Makefile
2853   asn1/pkixqualified/Makefile
2854   asn1/pkixtsp/Makefile
2855   asn1/pres/Makefile
2856   asn1/q932/Makefile
2857   asn1/q932-ros/Makefile
2858   asn1/qsig/Makefile
2859   asn1/ranap/Makefile
2860   asn1/rnsap/Makefile
2861   asn1/ros/Makefile
2862   asn1/rrc/Makefile
2863   asn1/rrlp/Makefile
2864   asn1/rtse/Makefile
2865   asn1/rua/Makefile
2866   asn1/s1ap/Makefile
2867   asn1/sabp/Makefile
2868   asn1/sbc-ap/Makefile
2869   asn1/smrse/Makefile
2870   asn1/snmp/Makefile
2871   asn1/spnego/Makefile
2872   asn1/sv/Makefile
2873   asn1/t124/Makefile
2874   asn1/t125/Makefile
2875   asn1/t38/Makefile
2876   asn1/tcap/Makefile
2877   asn1/tetra/Makefile
2878   asn1/ulp/Makefile
2879   asn1/wlancertextn/Makefile
2880   asn1/x2ap/Makefile
2881   asn1/x509af/Makefile
2882   asn1/x509ce/Makefile
2883   asn1/x509if/Makefile
2884   asn1/x509sat/Makefile
2885   asn1/x721/Makefile
2886   doc/Makefile
2887   docbook/Makefile
2888   epan/Makefile
2889   epan/crypt/Makefile
2890   epan/doxygen.cfg
2891   epan/dfilter/Makefile
2892   epan/dissectors/Makefile
2893   epan/dissectors/dcerpc/Makefile
2894   epan/dissectors/pidl/Makefile
2895   epan/ftypes/Makefile
2896   epan/wmem/Makefile
2897   epan/wslua/Makefile
2898   epan/wspython/Makefile
2899   filetap/Makefile
2900   codecs/Makefile
2901   ui/Makefile
2902   ui/doxygen.cfg
2903   ui/gtk/Makefile
2904   ui/gtk/doxygen.cfg
2905   ui/cli/Makefile
2906   ui/qt/Makefile
2907   ui/qt/doxygen.cfg
2908   help/Makefile
2909   packaging/Makefile
2910   packaging/macosx/Info.plist
2911   packaging/macosx/Makefile
2912   packaging/macosx/osx-dmg.sh
2913   packaging/macosx/Wireshark_package.pmdoc/index.xml
2914   packaging/nsis/Makefile
2915   packaging/rpm/Makefile
2916   packaging/rpm/SPECS/Makefile
2917   packaging/rpm/SPECS/wireshark.spec
2918   packaging/svr4/Makefile
2919   packaging/svr4/checkinstall
2920   packaging/svr4/pkginfo
2921   plugins/Makefile
2922   plugins/docsis/Makefile
2923   plugins/ethercat/Makefile
2924   plugins/gryphon/Makefile
2925   plugins/irda/Makefile
2926   plugins/m2m/Makefile
2927   plugins/mate/Makefile
2928   plugins/opcua/Makefile
2929   plugins/profinet/Makefile
2930   plugins/stats_tree/Makefile
2931   plugins/unistim/Makefile
2932   plugins/wimax/Makefile
2933   plugins/wimaxasncp/Makefile
2934   plugins/wimaxmacphy/Makefile
2935   tools/Makefile
2936   tools/lemon/Makefile
2937   wiretap/Makefile
2938   wsutil/Makefile
2939   echld/Makefile
2940   _CUSTOM_AC_OUTPUT_
2941   ,)
2942 dnl AC_CONFIG_FILES([tools/setuid-root.pl], [chmod +x tools/setuid-root.pl])
2943
2944
2945 # Pretty messages
2946
2947 if test "x$have_gtk" = "xyes"; then
2948         if test "x$with_gtk3" = "xyes"; then
2949                 gtk_lib_message=" (with GTK+ 3"
2950         else
2951                 gtk_lib_message=" (with GTK+ 2"
2952         fi
2953         if test "x$have_ige_mac" = "xyes"; then
2954                 gtk_lib_message="$gtk_lib_message and Mac OS X integration)"
2955         else
2956                 gtk_lib_message="$gtk_lib_message)"
2957         fi
2958 fi
2959
2960 if test "x$have_qt" = "xyes" ; then
2961         enable_qtshark="yes"
2962 else
2963         enable_qtshark="no"
2964 fi
2965
2966 if test "x$enable_setcap_install" = "xyes" ; then
2967         setcap_message="yes"
2968 else
2969         setcap_message="no"
2970 fi
2971
2972 if test "x$enable_setuid_install" = "xyes" ; then
2973         setuid_message="yes"
2974 else
2975         setuid_message="no"
2976 fi
2977
2978 if test "x$DUMPCAP_GROUP" = "x" ; then
2979         dumpcap_group_message="(none)"
2980 else
2981         dumpcap_group_message="$DUMPCAP_GROUP"
2982 fi
2983
2984 if test "x$want_zlib" = "xno" ; then
2985         zlib_message="no"
2986 else
2987         zlib_message="yes"
2988 fi
2989
2990 if test "x$want_lua" = "xyes" ; then
2991         lua_message="yes"
2992 else
2993         lua_message="no"
2994 fi
2995
2996 if test "x$want_python" = "xno"; then
2997         python_message="no"
2998 else
2999         python_message="yes"
3000 fi
3001
3002 if test "x$want_portaudio" = "xyes" ; then
3003         portaudio_message="yes"
3004 else
3005         portaudio_message="no"
3006 fi
3007
3008 if test "x$want_ssl" = "xno" ; then
3009         ssl_message="no"
3010 else
3011         ssl_message="yes"
3012 fi
3013
3014 if test "x$want_krb5" = "xno" ; then
3015         krb5_message="no"
3016 else
3017         krb5_message="yes ($ac_krb5_version)"
3018 fi
3019
3020 if test "x$have_good_c_ares" = "xyes" ; then
3021         c_ares_message="yes"
3022 else
3023         c_ares_message="no"
3024 fi
3025
3026 if test "x$have_good_adns" = "xyes" ; then
3027         adns_message="yes"
3028 else
3029         if test "x$have_good_c_ares" = "xyes" ; then
3030                 adns_message="no (using c-ares instead)"
3031         else
3032                 adns_message="no"
3033         fi
3034 fi
3035
3036 if test "x$have_good_libcap" = "xyes" ; then
3037         libcap_message="yes"
3038 else
3039         libcap_message="no"
3040 fi
3041
3042 if test "x$have_good_geoip" = "xyes" ; then
3043         geoip_message="yes"
3044 else
3045         geoip_message="no"
3046 fi
3047
3048 echo ""
3049 echo "The Wireshark package has been configured with the following options."
3050 echo "             Build wireshark (Gtk+) : $have_gtk""$gtk_lib_message"
3051 echo "                 Build wireshark-qt : $enable_qtshark"
3052 echo "                       Build tshark : $enable_tshark"
3053 echo "                      Build tfshark : $enable_tfshark"
3054 echo "                     Build capinfos : $enable_capinfos"
3055 echo "                      Build captype : $enable_captype"
3056 echo "                      Build editcap : $enable_editcap"
3057 echo "                      Build dumpcap : $enable_dumpcap"
3058 echo "                     Build mergecap : $enable_mergecap"
3059 echo "                   Build reordercap : $enable_reordercap"
3060 echo "                    Build text2pcap : $enable_text2pcap"
3061 echo "                      Build randpkt : $enable_randpkt"
3062 echo "                       Build dftest : $enable_dftest"
3063 echo "                     Build rawshark : $enable_rawshark"
3064 echo "                        Build echld : $have_echld"
3065 echo ""
3066 echo "   Save files as pcap-ng by default : $enable_pcap_ng_default"
3067 echo "  Install dumpcap with capabilities : $setcap_message"
3068 echo "             Install dumpcap setuid : $setuid_message"
3069 echo "                  Use dumpcap group : $dumpcap_group_message"
3070 echo "                        Use plugins : $have_plugins"
3071 echo "                    Use Lua library : $lua_message"
3072 echo "                 Use Python binding : $python_message"
3073 echo "                   Build rtp_player : $portaudio_message"
3074 echo "             Build profile binaries : $enable_profile_build"
3075 echo "                   Use pcap library : $want_pcap"
3076 echo "                   Use zlib library : $zlib_message"
3077 echo "               Use kerberos library : $krb5_message"
3078 echo "                 Use c-ares library : $c_ares_message"
3079 echo "               Use GNU ADNS library : $adns_message"
3080 echo "                Use SMI MIB library : $libsmi_message"
3081 echo "             Use GNU crypto library : $gcrypt_message"
3082 echo "             Use SSL crypto library : $ssl_message"
3083 echo "           Use IPv6 name resolution : $enable_ipv6"
3084 echo "                 Use gnutls library : $tls_message"
3085 echo "     Use POSIX capabilities library : $libcap_message"
3086 echo "                  Use GeoIP library : $geoip_message"
3087 echo "                     Use nl library : $libnl_message"
3088 echo "              Use SBC codec library : $have_sbc"