CMakeLists.txt

   1 # CMakeLists.txt
   2 #
   3 # $Id$
   4 #
   5 # Wireshark - Network traffic analyzer
   6 # By Gerald Combs <gerald@wireshark.org>
   7 # Copyright 1998 Gerald Combs
   8 #
   9 # This program is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU General Public License
  11 # as published by the Free Software Foundation; either version 2
  12 # of the License, or (at your option) any later version.
  13 #
  14 # This program is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 # GNU General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with this program; if not, write to the Free Software
  21 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
  22 #
  23
  24 project(Wireshark C)
  25
  26 cmake_minimum_required(VERSION 2.6)
  27 set(CMAKE_BACKWARDS_COMPATIBILITY 2.6)
  28
  29 # Needs to be set after cmake_minimum_required or cmake_policy(VERSION)
  30 #if(COMMAND cmake_policy)
  31 #       cmake_policy(SET CMP0015 NEW)
  32 #endif(COMMAND cmake_policy)
  33
  34 # set(PROJECT_VERSION "1.3.4-rc5")
  35 # set(PROJECT_VERSION "1.3.4rc5")
  36 # set(PROJECT_VERSION "1.3.4")
  37 # If not set, copy over Wireshark version from configure.in AC_INIT
  38 if(NOT PROJECT_VERSION)
  39         file(STRINGS
  40                 ${CMAKE_SOURCE_DIR}/configure.in
  41                 VERSIONLINE
  42                 REGEX "\\(wireshark, .*\\)"
  43         )
  44         string(REGEX REPLACE ".*\\(wireshark, (.*)\\).*"
  45                 "\\1"
  46                 PROJECT_VERSION
  47                 ${VERSIONLINE}
  48         )
  49 endif()
  50 string(REGEX REPLACE "([0-9]+)\\..*"
  51         "\\1"
  52         PROJECT_MAJOR_VERSION
  53         ${PROJECT_VERSION}
  54 )
  55 string(REGEX REPLACE ".*\\.([0-9]+)\\..*"
  56         "\\1"
  57         PROJECT_MINOR_VERSION
  58         ${PROJECT_VERSION}
  59 )
  60 string(REGEX REPLACE ".*\\..*\\.([0-9]+).*"
  61         "\\1"
  62         PROJECT_PATCH_VERSION
  63         ${PROJECT_VERSION}
  64 )
  65 string(REGEX REPLACE ".*\\..*\\.[0-9]+(.*)"
  66         "\\1"
  67         PROJECT_VERSION_EXTENSION
  68         ${PROJECT_VERSION}
  69 )
  70 message(STATUS "V: ${PROJECT_VERSION}, MaV: ${PROJECT_MAJOR_VERSION}, MiV: ${PROJECT_MINOR_VERSION}, PL: ${PROJECT_PATCH_VERSION}, EV: ${PROJECT_VERSION_EXTENSION}.")
  71
  72 #Where to find local cmake scripts
  73 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules)
  74 INCLUDE(UseLemon)
  75 INCLUDE(UseMakeDissectorReg)
  76 INCLUDE(UseMakeTapReg)
  77
  78 # Under linux the release mode (CMAKE_BUILD_TYPE=release) defines NDEBUG
  79
  80 # Disable this later. Alternative: "make VERBOSE=1"
  81 set(CMAKE_VERBOSE_MAKEFILE ON)
  82
  83 #Defines CMAKE_INSTALL_BINDIR, CMAKE_INSTALL_DATADIR, etc ...
  84 include(CMakeInstallDirs)
  85
  86 include_directories(
  87         ${CMAKE_BINARY_DIR}
  88         ${CMAKE_SOURCE_DIR}
  89         ${CMAKE_SOURCE_DIR}/epan
  90         ${CMAKE_SOURCE_DIR}/tools/lemon
  91         ${CMAKE_SOURCE_DIR}/wiretap
  92 )
  93
  94 #Where to put libraries
  95 if(NOT LIBRARY_OUTPUT_PATH)
  96         set(LIBRARY_OUTPUT_PATH ${Wireshark_BINARY_DIR}/lib CACHE INTERNAL
  97                    "Single output directory for building all libraries.")
  98 endif()
  99
 100
 101 include(CMakeOptions.txt)
 102
 103
 104 set(WIRESHARK_C_FLAGS
 105         -O2
 106         -Wall
 107         -W
 108         -Wextra
 109         -Wdeclaration-after-statement
 110         -Wendif-labels
 111         -Wpointer-arith
 112         -Wno-pointer-sign
 113         -Warray-bounds
 114         -Wcast-align
 115         -Wformat-security
 116         -Wold-style-definition
 117         -fexcess-precision=fast
 118 )
 119
 120 set(WIRESHARK_EXTRA_C_FLAGS
 121         -pedantic
 122         -Woverflow
 123         -Wlogical-op
 124         -Wno-overlength-strings
 125         -fstrict-overflow -Wstrict-overflow=4
 126         -Wunreachable-code
 127         -Wunsafe-loop-optimizations
 128         -Wno-long-long
 129         -Wbad-function-cast
 130         -Wcast-qual
 131         -Waddress
 132         -Warray-bounds
 133         -Wattributes
 134         -Wdiv-by-zero
 135         -Wformat-security
 136         -Wignored-qualifiers
 137         -Wpragmas
 138         -Wredundant-decls
 139         -Wvla
 140         -Wc++-compat
 141         -Wjump-misses-init
 142         # packet-ncp2222.inc prevents this from going into all warnings
 143         -Wwrite-strings
 144         # GLib blocks this for now.
 145         -Wstrict-prototypes
 146         # All the registration functions block these for now.
 147         -Wmissing-prototypes
 148         -Wmissing-declarations
 149         # Problem with packet-afs.c
 150         -Wshadow
 151         # More cleanup needed for this on LP64
 152         -Wshorten-64-to-32
 153 )
 154
 155 if(ENABLE_EXTRA_GCC_CHECKS)   # This overrides -Werror
 156         set(WIRESHARK_C_FLAGS ${WIRESHARK_C_FLAGS} ${WIRESHARK_EXTRA_C_FLAGS})
 157 endif()
 158
 159 add_definitions(
 160         -DHAVE_CONFIG_H
 161         -DPACKAGE=\"wireshark\"
 162 )
 163
 164 # Counterhack to work around some cache magic in CHECK_C_SOURCE_COMPILES
 165 include(CheckCCompilerFlag)
 166 set(C 0)
 167 # Sigh: Have to use THIS_FLAG instead of ${F} for some reason
 168 foreach(THIS_FLAG ${WIRESHARK_C_FLAGS})
 169         set(F WS_C_FLAG_${C})
 170         set(${F} ${THIS_FLAG})
 171         set(V WS_C_FLAG_VALID${C})
 172         check_c_compiler_flag(${${F}} ${V})
 173         if (${${V}})
 174                 add_definitions(${${F}})
 175         endif()
 176         math(EXPR C "${C} + 1")
 177 endforeach()
 178
 179 if(NOT DISABLE_WERROR AND NOT ENABLE_EXTRA_GCC_CHECKS)
 180         check_c_compiler_flag(-Werror WERROR)
 181 else()
 182         set(WERROR 0)
 183 endif()
 184
 185 if(CMAKE_COMPILER_IS_GNUCC)
 186         add_definitions( -D_U_=__attribute__\(\(unused\)\) )
 187 else()
 188         add_definitions( -D_U_=\"\" )
 189 endif()
 190
 191 set(WIRESHARK_LD_FLAGS
 192         -Wl,--as-needed
 193         # -flto
 194         # -fwhopr
 195         # -fwhole-program
 196 )
 197
 198 include(CheckCLinkerFlag)
 199 set(C 0)
 200 # Sigh: Have to use THIS_FLAG instead of ${F} for some reason
 201 foreach(THIS_FLAG ${WIRESHARK_LD_FLAGS})
 202         set(F WS_LD_FLAG_${C})
 203         set(${F} ${THIS_FLAG})
 204         set(V WS_LD_FLAG_VALID${C})
 205         check_c_linker_flag(${${F}} ${V})
 206         if (${${V}})
 207                 set(WS_LINK_FLAGS ${WS_LINK_FLAGS} ${${F}})
 208         endif()
 209         math(EXPR C "${C} + 1")
 210 endforeach()
 211
 212 if(ENABLE_STATIC)
 213   set(LINK_MODE_LIB STATIC)
 214   set(LINK_MODE_MODULE STATIC)
 215 else()
 216   set(LINK_MODE_LIB SHARED)
 217   set(LINK_MODE_MODULE MODULE)
 218 endif()
 219
 220 # The packagelist is doing some magic:  If we add XXX to the packagelist, we
 221 # - may optionally set XXX_OPTIONS to pass to the find_package command
 222 # - will call FindXXX.cmake
 223 # - return found libraries in XXX_LIBRARIES
 224 # - return found include in XXX_INCLUDE_DIRS
 225 # - set HAVE_XXX
 226
 227 #The minimum package list
 228 set(PACKAGELIST GLIB2 GMODULE2 PCAP M LEX YACC Perl SH PythonInterp)
 229 set(GLIB2_FIND_REQUIRED)
 230 set(GLIB2_MIN_VERSION 2.4.0)
 231 set(PCAP_REQUIRED)
 232 set(M_REQUIRED)
 233
 234 set(PACKAGELIST ${PACKAGELIST} HtmlViewer)
 235
 236 #Build the gui ?
 237 if(BUILD_wireshark)
 238         if(ENABLE_GTK3)
 239                 set(PACKAGELIST ${PACKAGELIST} GTK3)
 240                 set(UI_MANAGER ON)
 241         else()
 242                 set(PACKAGELIST ${PACKAGELIST} GTK2)
 243                 set(GTK2_OPTIONS COMPONENTS gtk)
 244                 set(GTK2_DEBUG false)
 245         endif()
 246 endif()
 247
 248 if(BUILD_dumpcap)
 249         set(PACKAGELIST ${PACKAGELIST} GTHREAD2)
 250         set(GHTREAD2_REQUIRED)
 251 endif()
 252
 253 # SMI SNMP
 254 if(ENABLE_SMI)
 255         set(PACKAGELIST ${PACKAGELIST} SMI)
 256 endif()
 257
 258 # GNU crypto
 259 if(ENABLE_GCRYPT)
 260         set(PACKAGELIST ${PACKAGELIST} GCRYPT)
 261 endif()
 262
 263 # GNU SSL/TLS support
 264 if(ENABLE_GNUTLS)
 265         set(PACKAGELIST ${PACKAGELIST} GNUTLS)
 266 endif()
 267
 268 # Regular expressions lib
 269 if(ENABLE_PCRE)
 270         set(PACKAGELIST ${PACKAGELIST} PCRE)
 271 endif()
 272
 273 # Kerberos
 274 if(ENABLE_KERBEROS)
 275         set(PACKAGELIST ${PACKAGELIST} KERBEROS)
 276 endif()
 277
 278 # Portable audio
 279 if(ENABLE_PORTAUDIO)
 280         set(PACKAGELIST ${PACKAGELIST} PORTAUDIO)
 281 endif()
 282
 283
 284 # Prefer c-ares over adns
 285 if(ENABLE_CARES)        # C Asynchronouse resolver
 286         set(PACKAGELIST ${PACKAGELIST} CARES)
 287 elseif(ENABLE_ADNS)     # Gnu asynchronous DNS
 288         set(PACKAGELIST ${PACKAGELIST} ADNS)
 289 endif()
 290
 291 # Zlib compression
 292 if(ENABLE_ZLIB)
 293         set(PACKAGELIST ${PACKAGELIST} ZLIB)
 294 endif()
 295
 296 # Lua 5.1 dissectors
 297 if(ENABLE_LUA)
 298         set(PACKAGELIST ${PACKAGELIST} LUA)
 299 endif()
 300
 301 # GeoIP address resolving
 302 if(ENABLE_GEOIP)
 303         set(PACKAGELIST ${PACKAGELIST} GEOIP)
 304 endif()
 305
 306 # Capabilities
 307 if(ENABLE_CAP)
 308         set(PACKAGELIST ${PACKAGELIST} CAP)
 309 endif()
 310
 311 if(ENABLE_PYTHON)
 312         set(PACKAGELIST ${PACKAGELIST} PYTHON)
 313 endif()
 314
 315 set(PACKAGELIST ${PACKAGELIST} YAPP)
 316
 317 set(PACKAGELIST ${PACKAGELIST} POD)
 318
 319
 320 set(PROGLIST text2pcap mergecap capinfos editcap dumpcap)
 321
 322 #Let's loop the package list
 323 foreach(PACKAGE ${PACKAGELIST})
 324         if(${PACKAGE}_OPTIONS)
 325                 find_package(${PACKAGE} ${${PACKAGE}_OPTIONS})
 326         elseif(${PACKAGE}_REQUIRED)
 327                 find_package(${PACKAGE} REQUIRED)
 328         else()
 329                 find_package(${PACKAGE})
 330         endif()
 331         message(${PACKAGE}_FOUND)
 332         if (${PACKAGE}_FOUND)
 333                 set(HAVE_LIB${PACKAGE} 1)
 334                 include_directories(${${PACKAGE}_INCLUDE_DIRS})
 335                 message(STATUS "${PACKAGE} includes: ${${PACKAGE}_INCLUDE_DIRS}")
 336                 message(STATUS "${PACKAGE} libs: ${${PACKAGE}_LIBRARIES}")
 337         endif()
 338 endforeach()
 339
 340 #packaging
 341 include(CPackConfig.txt)
 342
 343 if(HAVE_LIBPYTHON)
 344         set(HAVE_PYTHON 1)
 345         set(PYTHON_DIR "${CMAKE_INSTALL_PREFIX}/lib/wireshark/python/${CPACK_PACKAGE_VERSION}")
 346 endif()
 347 if(HAVE_LIBLUA)
 348         set(HAVE_LUA_H 1)
 349         set(HAVE_LUA_5_1 1)
 350 endif()
 351 if(HAVE_LIBKERBEROS)
 352         set(HAVE_KERBEROS 1)
 353         # HAVE_HEIMDAL_KERBEROS
 354         set(HAVE_MIT_KERBEROS 1)
 355         set(HAVE_KEYTYPE_ARCFOUR_56 1)
 356 endif()
 357 if(HAVE_LIBGEOIP)
 358         set(HAVE_GEOIP 1)
 359 endif()
 360 if(HAVE_LIBCARES)
 361         set(HAVE_C_ARES 1)
 362 endif()
 363 if(HAVE_LIBADNS)
 364         set(HAVE_GNU_ADNS 1)
 365 endif()
 366 if(ENABLE_AIRPCAP)
 367         set(HAVE_AIRPCAP 1)
 368 endif()
 369 # No matter which version of GTK is present
 370 if(GTK2_FOUND OR GTK3_FOUND)
 371         set(GTK_FOUND ON)
 372 endif()
 373 # That's the name autofoo uses
 374 if(HAVE_LIBZLIB)
 375         set(HAVE_LIBZ 1)
 376 endif()
 377
 378 include(ConfigureChecks.cmake)
 379
 380 #Big or little endian ?
 381 include(TestBigEndian)
 382 test_big_endian(WORDS_BIGENDIAN)
 383
 384 set(DATAFILE_DIR "${CMAKE_INSTALL_PREFIX}/share/${CPACK_PACKAGE_NAME}")
 385
 386 if(ENABLE_PLUGINS)
 387         set(HAVE_PLUGINS 1)
 388         set(PLUGIN_DIR="${DATAFILE_DIR}/plugins/${CPACK_PACKAGE_VERSION}")
 389         set(PLUGIN_SRC_DIRS
 390                 plugins/asn1
 391                 plugins/docsis
 392                 plugins/ethercat
 393                 plugins/giop
 394                 plugins/gryphon
 395                 plugins/irda
 396                 plugins/m2m
 397                 plugins/mate
 398                 plugins/opcua
 399                 plugins/profinet
 400                 plugins/stats_tree
 401                 plugins/unistim
 402                 plugins/wimax
 403                 plugins/wimaxasncp
 404         )
 405 # It seems this stuff doesn't build with autofoo either...
 406 #       if(YAPP_FOUND)
 407 #               set(PLUGIN_SRC_DIRS
 408 #                       ${PLUGIN_SRC_DIRS}
 409 #                       plugins/tpg
 410 #               )
 411 #       endif()
 412 else()
 413         set(PLUGIN_SRC_DIRS )
 414 endif()
 415
 416 foreach(PLUGIN_DIR ${PLUGIN_SRC_DIRS})
 417         add_subdirectory( ${PLUGIN_DIR} )
 418 endforeach()
 419
 420 add_subdirectory( codecs )
 421 add_subdirectory( epan )
 422 add_subdirectory( tools/lemon )
 423 add_subdirectory( wiretap )
 424 add_subdirectory( wsutil )
 425
 426 if(BUILD_wireshark AND GTK_FOUND)
 427         add_subdirectory( gtk )
 428 endif()
 429
 430 # Basedir where to install guides
 431 set(DOC_DIR "$ENV{docdir}")
 432 message(STATUS "docdir: ${DOC_DIR}")
 433
 434 if(ENABLE_GUIDES)
 435         add_subdirectory( docbook )
 436 endif()
 437
 438 #Platform specific
 439 if(UNIX)
 440         set(WS_VAR_IMPORT "extern")
 441 endif()
 442
 443 if(APPLE)
 444 #TODO verify that APPLE implies HAVE_OS_X_FRAMEWORKS
 445         set(HAVE_OS_X_FRAMEWORKS 1)
 446         FIND_LIBRARY (APPLE_CORE_SERVICES_LIBRARY CoreServices)
 447         FIND_LIBRARY (APPLE_COCOA_LIBRARY Cocoa)
 448 endif()
 449
 450 if(WIN32)
 451         add_definitions(-D_NEED_VAR_IMPORT_)
 452         set(WS_VAR_IMPORT "__declspec(dllimport) extern")
 453         set(WS_MSVC_NORETURN "__declspec(noreturn)")
 454
 455         # Disable deprecation
 456         if(MSVC80 OR MSVC90)
 457                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE)
 458         endif()
 459 else()
 460         set(WS_MSVC_NORETURN " ")
 461 endif()
 462
 463 configure_file(${CMAKE_SOURCE_DIR}/cmakeconfig.h.in ${CMAKE_BINARY_DIR}/config.h)
 464
 465 include(FeatureSummary)
 466 #SET_FEATURE_INFO(NAME DESCRIPTION [URL [COMMENT] ]
 467 PRINT_ENABLED_FEATURES()
 468 PRINT_DISABLED_FEATURES()
 469
 470 link_directories(
 471         ${CMAKE_BINARY_DIR}/gtk
 472         ${CMAKE_BINARY_DIR}/codecs
 473         ${CMAKE_BINARY_DIR}/epan
 474         ${CMAKE_BINARY_DIR}/wiretap
 475         ${CMAKE_BINARY_DIR}/wsutil
 476 )
 477
 478 ADD_CUSTOM_TARGET(
 479         svnversion ALL
 480         COMMAND ${PERL}
 481                 ${CMAKE_CURRENT_SOURCE_DIR}/make-version.pl
 482                 ${CMAKE_CURRENT_SOURCE_DIR}
 483         DEPENDS
 484                 ${CMAKE_CURRENT_SOURCE_DIR}/make-version.pl
 485 )
 486
 487 ADD_CUSTOM_COMMAND(
 488         OUTPUT  svnversion.h
 489         COMMAND ${PERL}
 490                 ${CMAKE_CURRENT_SOURCE_DIR}/make-version.pl
 491                 ${CMAKE_CURRENT_SOURCE_DIR}
 492         DEPENDS
 493                 ${CMAKE_CURRENT_SOURCE_DIR}/make-version.pl
 494 )
 495
 496 register_tap_files(tshark-tap-register.c
 497         ${TSHARK_TAP_SRC}
 498 )
 499
 500 ADD_CUSTOM_COMMAND(
 501         OUTPUT  ps.c
 502         COMMAND ${PYTHON_EXECUTABLE}
 503                 ${CMAKE_CURRENT_SOURCE_DIR}/tools/rdps.py
 504                 ${CMAKE_CURRENT_SOURCE_DIR}/print.ps
 505                 ps.c
 506         DEPENDS
 507                 ${CMAKE_CURRENT_SOURCE_DIR}/tools/rdps.py
 508                 ${CMAKE_CURRENT_SOURCE_DIR}/print.ps
 509 )
 510
 511 if(UNIX)
 512         set(PLATFORM_SRC
 513                 capture-pcap-util-unix.c
 514         )
 515 endif()
 516
 517 if(WIN32)
 518         set(PLATFORM_SRC
 519                 capture-wpcap.c capture_wpcap_packet.c
 520         )
 521 endif()
 522
 523 set(WTAP_PLUGIN_SOURCES
 524         epan/plugins.c
 525         epan/report_err.c
 526         epan/filesystem.c
 527 )
 528
 529 set(SHARK_COMMON_CAPTURE_SRC
 530         capture_errs.c
 531         capture_ifinfo.c
 532         capture_ui_utils.c
 533 )
 534
 535 set(WIRESHARK_COMMON_SRC
 536         ${PLATFORM_SRC}
 537         capture-pcap-util.c
 538         cfile.c
 539         clopts_common.c
 540         disabled_protos.c
 541         frame_data_sequence.c
 542         packet-range.c
 543         print.c
 544         ps.c
 545         svnversion.h
 546         sync_pipe_write.c
 547         timestats.c
 548         util.c
 549         tap-megaco-common.c
 550         tap-rtp-common.c
 551         version_info.c
 552 )
 553
 554 set(TSHARK_TAP_SRC
 555         tap-afpstat.c
 556         tap-ansi_astat.c
 557         tap-bootpstat.c
 558         tap-camelcounter.c
 559         tap-camelsrt.c
 560         tap-comparestat.c
 561         tap-dcerpcstat.c
 562         tap-diameter-avp.c
 563         tap-funnel.c
 564         tap-gsm_astat.c
 565         tap-h225counter.c
 566         tap-h225rassrt.c
 567         tap-httpstat.c
 568         tap-icmpstat.c
 569         tap-icmpv6stat.c
 570         tap-iostat.c
 571         tap-iousers.c
 572         tap-mgcpstat.c
 573         tap-megacostat.c
 574         tap-protocolinfo.c
 575         tap-protohierstat.c
 576         tap-radiusstat.c
 577         tap-rpcstat.c
 578         tap-rpcprogs.c
 579         tap-rtp.c
 580         tap-scsistat.c
 581         tap-sctpchunkstat.c
 582         tap-sipstat.c
 583         tap-smbsids.c
 584         tap-smbstat.c
 585         tap-stats_tree.c
 586         tap-sv.c
 587         tap-wspstat.c
 588 )
 589
 590 set(INSTALL_DIRS
 591         diameter
 592         docbook
 593         dtds
 594         help
 595         radius
 596         tpncp
 597         wimaxasncp
 598 )
 599
 600 set(INSTALL_FILES
 601         ${CMAKE_BINARY_DIR}/AUTHORS-SHORT
 602         COPYING
 603         ${CMAKE_BINARY_DIR}/capinfos.html
 604         cfilters
 605         colorfilters
 606         dfilters
 607         ${CMAKE_BINARY_DIR}/dftest.html
 608         ${CMAKE_BINARY_DIR}/dumpcap.html
 609         ${CMAKE_BINARY_DIR}/editcap.html
 610         ${CMAKE_BINARY_DIR}/idl2wrs.html
 611         ipmap.html
 612         manuf
 613         ${CMAKE_BINARY_DIR}/mergecap.html
 614         pdml2html.xsl
 615         ${CMAKE_BINARY_DIR}/randpkt.html
 616         ${CMAKE_BINARY_DIR}/rawshark.html
 617         services
 618         smi_modules
 619         ${CMAKE_BINARY_DIR}/text2pcap.html
 620         ${CMAKE_BINARY_DIR}/tshark.html
 621         ${CMAKE_BINARY_DIR}/wireshark-filter.html
 622         ${CMAKE_BINARY_DIR}/wireshark.html
 623         docbook/ws.css
 624 )
 625
 626 set(LIBEPAN_LIBS
 627 #               @NSL_LIBS@      # -lnsl
 628 #               @SOCKET_LIBS@   # -lsocket
 629 #               @SSL_LIBS@      # -lcrypto
 630                 epan
 631 #               $(plugin_ldadd) # in case of static
 632                 ${PCRE_LIBRARIES}
 633                 ${PCAP_LIBRARIES}
 634                 ${CARES_LIBRARIES}
 635                 ${ADNS_LIBRARIES}
 636                 ${KERBEROS_LIBRARIES}
 637                 ${LUA_LIBRARIES}
 638                 ${PYTHON_LIBRARIES}
 639                 ${GEOIP_LIBRARIES}
 640                 ${GCRYPT_LIBRARIES}
 641                 ${GNUTLS_LIBRARIES}
 642                 ${SMI_LIBRARIES}
 643                 ${ZLIB_LIBRARIES}
 644                 ${M_LIBRARIES}
 645 )
 646
 647 if(BUILD_wireshark AND GTK_FOUND)
 648         set(wireshark_LIBS
 649                 ui
 650                 ${GTK2_LIBRARIES}
 651                 ${GTK3_LIBRARIES}
 652                 codecs
 653                 ${PORTAUDIO_LIBRARIES}
 654                 ${LIBEPAN_LIBS}
 655                 ${APPLE_CORE_SERVICES_LIBRARY}
 656                 ${APPLE_COCOA_LIBRARY}
 657         )
 658         set(wireshark_FILES
 659                 airpcap_loader.c
 660                 alert_box.c
 661                 capture.c
 662                 capture_info.c
 663                 capture_opts.c
 664                 capture_sync.c
 665                 color_filters.c
 666                 file.c
 667                 fileset.c
 668                 filters.c
 669                 g711.c
 670                 merge.c
 671                 proto_hier_stats.c
 672                 summary.c
 673                 tempfile.c
 674                 u3.c
 675                 ${SHARK_COMMON_CAPTURE_SRC}
 676                 ${WIRESHARK_COMMON_SRC}
 677         )
 678         add_executable(wireshark ${wireshark_FILES})
 679         add_dependencies(wireshark svnversion)
 680         set_target_properties(wireshark PROPERTIES LINK_FLAGS "${WS_LINK_FLAGS}")
 681         target_link_libraries(wireshark ${wireshark_LIBS})
 682         install(TARGETS wireshark RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 683 endif()
 684
 685 if(BUILD_tshark)
 686         set(tshark_LIBS
 687                 ${LIBEPAN_LIBS}
 688                 ${APPLE_COCOA_LIBRARY}
 689         )
 690         set(tshark_FILES
 691                 capture_opts.c
 692                 capture_sync.c
 693                 tempfile.c
 694                 tshark-tap-register.c
 695                 tshark.c
 696                 ${TSHARK_TAP_SRC}
 697                 ${SHARK_COMMON_CAPTURE_SRC}
 698                 ${WIRESHARK_COMMON_SRC}
 699         )
 700         add_executable(tshark ${tshark_FILES})
 701         add_dependencies(tshark svnversion)
 702         set_target_properties(tshark PROPERTIES LINK_FLAGS "${WS_LINK_FLAGS}")
 703         target_link_libraries(tshark ${tshark_LIBS})
 704         install(TARGETS tshark RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 705 endif()
 706
 707 if(BUILD_rawshark)
 708         set(rawshark_LIBS
 709                 ${LIBEPAN_LIBS}
 710                 ${APPLE_COCOA_LIBRARY}
 711         )
 712         set(rawshark_FILES
 713                 ${WIRESHARK_COMMON_SRC}
 714                 rawshark.c
 715         )
 716         add_executable(rawshark ${rawshark_FILES})
 717         add_dependencies(rawshark svnversion)
 718         set_target_properties(rawshark PROPERTIES LINK_FLAGS "${WS_LINK_FLAGS}")
 719         target_link_libraries(rawshark ${rawshark_LIBS})
 720         install(TARGETS rawshark RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 721 endif()
 722
 723 if(BUILD_dftest)
 724         set(dftest_LIBS
 725                 ${LIBEPAN_LIBS}
 726         )
 727         set(dftest_FILES
 728                 dftest.c
 729                 util.c
 730         )
 731         add_executable(dftest ${dftest_FILES})
 732         set_target_properties(dftest PROPERTIES LINK_FLAGS "${WS_LINK_FLAGS}")
 733         target_link_libraries(dftest ${dftest_LIBS})
 734         install(TARGETS dftest RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 735 endif()
 736
 737 if(BUILD_randpkt)
 738         set(randpkt_LIBS
 739                 wiretap
 740                 ${M_LIBRARIES}
 741                 ${PCAP_LIBRARIES}
 742 #               @SOCKET_LIBS@
 743 #               @NSL_LIBS@
 744                 ${CARES_LIBRARIES}
 745                 ${ADNS_LIBRARIES}
 746                 ${ZLIB_LIBRARIES}
 747         )
 748         set(randpkt_FILES
 749                 randpkt.c
 750         )
 751         add_executable(randpkt ${randpkt_FILES})
 752         set_target_properties(randpkt PROPERTIES LINK_FLAGS "${WS_LINK_FLAGS}")
 753         target_link_libraries(randpkt ${randpkt_LIBS})
 754         install(TARGETS randpkt RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 755 endif()
 756
 757 if(BUILD_text2pcap)
 758         set(text2pcap_LIBS
 759                 wiretap
 760                 ${M_LIBRARIES}
 761                 ${ZLIB_LIBRARIES}
 762         )
 763         set(text2pcap_CLEAN_FILES
 764                 text2pcap.c
 765         )
 766         set(text2pcap_FILES
 767                 ${text2pcap_CLEAN_FILES}
 768         )
 769         add_lex_files(text2pcap_FILES
 770                 text2pcap-scanner.l
 771         )
 772         add_executable(text2pcap ${text2pcap_FILES})
 773         add_dependencies(text2pcap svnversion)
 774         set_target_properties(text2pcap PROPERTIES LINK_FLAGS "${WS_LINK_FLAGS}")
 775         target_link_libraries(text2pcap ${text2pcap_LIBS})
 776         install(TARGETS text2pcap RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 777 endif()
 778
 779 if(BUILD_mergecap)
 780         set(mergecap_LIBS
 781                 wiretap
 782                 ${ZLIB_LIBRARIES}
 783         )
 784         set(mergecap_FILES
 785                 mergecap.c
 786                 merge.c
 787                 svnversion.h
 788         )
 789         add_executable(mergecap ${mergecap_FILES})
 790         add_dependencies(mergecap svnversion)
 791         set_target_properties(mergecap PROPERTIES LINK_FLAGS "${WS_LINK_FLAGS}")
 792         target_link_libraries(mergecap ${mergecap_LIBS})
 793         install(TARGETS mergecap RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 794 endif()
 795
 796 if(BUILD_capinfos)
 797         set(capinfos_LIBS
 798                 wiretap
 799                 ${ZLIB_LIBRARIES}
 800                 ${GCRYPT_LIBRARIES}
 801                 ${APPLE_COCOA_LIBRARY}
 802         )
 803         set(capinfos_FILES
 804                 capinfos.c
 805                 ${WTAP_PLUGIN_SOURCES}
 806         )
 807         add_executable(capinfos ${capinfos_FILES})
 808         add_dependencies(capinfos svnversion)
 809         set_target_properties(capinfos PROPERTIES LINK_FLAGS "${WS_LINK_FLAGS}")
 810         target_link_libraries(capinfos ${capinfos_LIBS})
 811         install(TARGETS capinfos RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 812 endif()
 813
 814 if(BUILD_editcap)
 815         set(editcap_LIBS
 816                 wiretap
 817                 ${ZLIB_LIBRARIES}
 818         )
 819         set(editcap_FILES
 820                 editcap.c
 821                 epan/crypt/crypt-md5.c
 822                 epan/nstime.c
 823                 ${WTAP_PLUGIN_SOURCES}
 824         )
 825         add_executable(editcap ${editcap_FILES})
 826         add_dependencies(editcap svnversion)
 827         set_target_properties(editcap PROPERTIES LINK_FLAGS "${WS_LINK_FLAGS}")
 828         target_link_libraries(editcap ${editcap_LIBS})
 829         install(TARGETS editcap RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 830 endif()
 831
 832 if(BUILD_dumpcap)
 833         set(dumpcap_LIBS
 834 #               @INET_NTOP_LO@
 835                 wsutil
 836                 ${PCAP_LIBRARIES}
 837                 ${CAP_LIBRARIES}
 838 #               @SOCKET_LIBS@
 839 #               @NSL_LIBS@
 840                 ${GLIB2_LIBRARIES}
 841                 ${GTHREAD2_LIBRARIES}
 842                 ${ZLIB_LIBRARIES}
 843                 ${APPLE_COCOA_LIBRARY}
 844         )
 845         set(dumpcap_FILES
 846                 svnversion.h
 847                 capture_opts.c
 848                 capture-pcap-util.c
 849                 capture_stop_conditions.c
 850                 clopts_common.c
 851                 conditions.c
 852                 dumpcap.c
 853                 pcapio.c
 854                 ringbuffer.c
 855                 sync_pipe_write.c
 856                 tempfile.c
 857                 version_info.c
 858                 ${PLATFORM_SRC}
 859         )
 860         add_executable(dumpcap ${dumpcap_FILES})
 861         add_dependencies(dumpcap svnversion)
 862         set_target_properties(dumpcap PROPERTIES LINK_FLAGS "${WS_LINK_FLAGS}")
 863         target_link_libraries(dumpcap ${dumpcap_LIBS})
 864         install(TARGETS dumpcap RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 865 endif()
 866
 867 ADD_CUSTOM_COMMAND(
 868         OUTPUT  ${CMAKE_BINARY_DIR}/AUTHORS-SHORT
 869         COMMAND ${PERL}
 870                 ${CMAKE_SOURCE_DIR}/doc/perlnoutf.pl
 871                 ${CMAKE_SOURCE_DIR}/doc/make-authors-short.pl
 872                 < ${CMAKE_SOURCE_DIR}/AUTHORS
 873                 > ${CMAKE_BINARY_DIR}/AUTHORS-SHORT
 874         DEPENDS
 875                 ${CMAKE_SOURCE_DIR}/doc/perlnoutf.pl
 876                 ${CMAKE_SOURCE_DIR}/doc/make-authors-short.pl
 877                 ${CMAKE_SOURCE_DIR}/AUTHORS
 878 )
 879
 880 ADD_CUSTOM_COMMAND(
 881         OUTPUT  ${CMAKE_BINARY_DIR}/AUTHORS-SHORT-FORMAT
 882                 ${CMAKE_BINARY_DIR}/wireshark.pod
 883         COMMAND ${PERL}
 884                 ${CMAKE_SOURCE_DIR}/doc/perlnoutf.pl
 885                 ${CMAKE_SOURCE_DIR}/doc/make-authors-format.pl
 886                 < ${CMAKE_BINARY_DIR}/AUTHORS-SHORT
 887                 > ${CMAKE_BINARY_DIR}/AUTHORS-SHORT-FORMAT
 888         COMMAND cat
 889                 ${CMAKE_SOURCE_DIR}/doc/wireshark.pod.template
 890                 ${CMAKE_BINARY_DIR}/AUTHORS-SHORT-FORMAT
 891                 > ${CMAKE_BINARY_DIR}/wireshark.pod
 892         DEPENDS
 893                 ${CMAKE_SOURCE_DIR}/doc/perlnoutf.pl
 894                 ${CMAKE_SOURCE_DIR}/doc/make-authors-format.pl
 895                 ${CMAKE_BINARY_DIR}/AUTHORS-SHORT
 896                 ${CMAKE_SOURCE_DIR}/doc/wireshark.pod.template
 897 )
 898
 899 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/capinfos 1 )
 900 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/dftest 1 )
 901 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/dumpcap 1 )
 902 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/editcap 1 )
 903 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/idl2wrs 1 )
 904 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/mergecap 1 )
 905 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/randpkt 1 )
 906 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/rawshark 1 )
 907 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/text2pcap 1 )
 908 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/tshark 1 )
 909 pod2manhtml( wireshark 1 )
 910 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/wireshark-filter 4 )
 911
 912 add_custom_target(
 913         auxiliary ALL
 914         DEPENDS
 915                 AUTHORS-SHORT
 916                 capinfos.html
 917                 dftest.html
 918                 dumpcap.html
 919                 editcap.html
 920                 idl2wrs.html
 921                 mergecap.html
 922                 randpkt.html
 923                 rawshark.html
 924                 text2pcap.html
 925                 tshark.html
 926                 wireshark.html
 927                 wireshark-filter.html
 928 )
 929
 930 set(MAN1_FILES
 931         ${CMAKE_BINARY_DIR}/capinfos.1
 932         ${CMAKE_BINARY_DIR}/dftest.1
 933         ${CMAKE_BINARY_DIR}/dumpcap.1
 934         ${CMAKE_BINARY_DIR}/editcap.1
 935         ${CMAKE_BINARY_DIR}/idl2wrs.1
 936         ${CMAKE_BINARY_DIR}/mergecap.1
 937         ${CMAKE_BINARY_DIR}/randpkt.1
 938         ${CMAKE_BINARY_DIR}/rawshark.1
 939         ${CMAKE_BINARY_DIR}/text2pcap.1
 940         ${CMAKE_BINARY_DIR}/tshark.1
 941         ${CMAKE_BINARY_DIR}/wireshark.1
 942 )
 943
 944 set(MAN4_FILES
 945         ${CMAKE_BINARY_DIR}/wireshark-filter.4
 946 )
 947
 948 set(CLEAN_FILES
 949         ${wireshark_FILES}
 950         ${tshark_FILES}
 951         ${rawshark_FILES}
 952         ${dftest_FILES}
 953         ${randpkt_FILES}
 954         ${text2pcap_CLEAN_FILES}
 955         ${mergecap_FILES}
 956         ${capinfos_FILES}
 957         ${editcap_FILES}
 958         ${dumpcap_FILES}
 959 )
 960
 961 if (WERROR)
 962         set_source_files_properties(
 963                 ${CLEAN_FILES}
 964                 PROPERTIES
 965                 COMPILE_FLAGS -Werror
 966         )
 967 endif()
 968
 969 install(
 970         FILES
 971                 ${INSTALL_FILES}
 972         DESTINATION
 973                 ${CMAKE_INSTALL_DATADIR}/${CPACK_PACKAGE_NAME}
 974 )
 975
 976 install(
 977         FILES
 978                 ${MAN1_FILES}
 979         DESTINATION
 980                 ${CMAKE_INSTALL_MANDIR}/man1
 981 )
 982
 983 install(
 984         FILES
 985                 ${MAN4_FILES}
 986         DESTINATION
 987                 ${CMAKE_INSTALL_MANDIR}/man4
 988 )
 989
 990 install(
 991         DIRECTORY
 992                 ${INSTALL_DIRS}
 993         DIRECTORY_PERMISSIONS
 994                 OWNER_EXECUTE OWNER_WRITE OWNER_READ
 995                 GROUP_EXECUTE GROUP_READ
 996                 WORLD_EXECUTE WORLD_READ
 997         DESTINATION
 998                 ${CMAKE_INSTALL_DATADIR}/${CPACK_PACKAGE_NAME}
 999         PATTERN ".svn" EXCLUDE
1000         PATTERN "Makefile.*" EXCLUDE
1001         PATTERN "faq.py" EXCLUDE
1002 )