source4/configure.ac

   1 dnl -*- mode: m4-mode -*-
   2 dnl Process this file with autoconf to produce a configure script.
   3
   4 dnl disabled 2.53 requirement - we do work with 2.52 on suse 7.3 for example
   5 dnl AC_PREREQ(2.53)
   6
   7 AC_INIT([samba],[],[samba-technical@samba.org])
   8
   9 AC_CONFIG_SRCDIR([include/includes.h])
  10 AC_CONFIG_HEADER(include/config_tmp.h)
  11 AC_DEFINE(CONFIG_H_IS_FROM_SAMBA,1,[Marker for samba's config.h])
  12
  13 # Configuration rules.
  14 m4_include(build/m4/env.m4)
  15 m4_include(lib/replace/samba.m4)
  16 m4_include(lib/smbreadline/readline.m4)
  17 m4_include(heimdal_build/config.m4)
  18 m4_include(lib/util/fault.m4)
  19 m4_include(lib/util/signal.m4)
  20 m4_include(lib/util/util.m4)
  21 m4_include(lib/util/fsusage.m4)
  22 m4_include(lib/util/xattr.m4)
  23 m4_include(lib/util/capability.m4)
  24 m4_include(lib/util/time.m4)
  25 m4_include(lib/popt/samba.m4)
  26 m4_include(lib/charset/config.m4)
  27 m4_include(lib/socket/config.m4)
  28 m4_include(lib/talloc/libtalloc.m4)
  29 m4_include(lib/tdb/libtdb.m4)
  30 m4_include(lib/ldb/sqlite3.m4)
  31 m4_include(lib/ldb/libldb.m4)
  32 m4_include(lib/tls/config.m4)
  33 m4_include(lib/events/config.m4)
  34
  35 dnl m4_include(auth/kerberos/config.m4)
  36
  37 m4_include(auth/gensec/config.m4)
  38 m4_include(smbd/process_model.m4)
  39 m4_include(lib/registry/config.m4)
  40 m4_include(scripting/swig/config.m4)
  41 m4_include(ntvfs/posix/config.m4)
  42 m4_include(ntvfs/unixuid/config.m4)
  43 m4_include(lib/socket_wrapper/config.m4)
  44 m4_include(auth/config.m4)
  45 m4_include(kdc/config.m4)
  46 m4_include(ntvfs/sysdep/config.m4)
  47 m4_include(lib/appweb/config.m4)
  48 m4_include(nsswitch/config.m4)
  49 m4_include(libcli/config.m4)
  50
  51 #################################################
  52 # add *_CFLAGS only for the real build
  53 CFLAGS="${CFLAGS} ${DEVELOPER_CFLAGS}"
  54
  55 #################################################
  56 # final configure stuff
  57
  58 AC_MSG_CHECKING([configure summary])
  59 AC_TRY_RUN([#include "${srcdir-.}/build/tests/summary.c"],
  60            AC_MSG_RESULT(yes),
  61            AC_MSG_ERROR([summary failure. Aborting config]); exit 1;,
  62            AC_MSG_WARN([cannot run when cross-compiling]))
  63
  64 LIBS=`echo $LIBS | sed -e 's/ *//g'`
  65 if test x"$LIBS" != x""; then
  66         echo "LIBS: $LIBS"
  67         AC_MSG_WARN([the global \$LIBS variable contains some libraries!])
  68         AC_MSG_WARN([this should not happen, please report to samba-technical@lists.samba.org!])
  69         AC_MSG_ERROR([only _EXT macros from aclocal.m4 should be used!])
  70 fi
  71
  72 dnl Remove -L/usr/lib/? from LDFLAGS and LIBS
  73 LIB_REMOVE_USR_LIB(LDFLAGS)
  74 LIB_REMOVE_USR_LIB(LIBS)
  75
  76 dnl Remove -I/usr/include/? from CFLAGS and CPPFLAGS
  77 CFLAGS_REMOVE_USR_INCLUDE(CFLAGS)
  78 CFLAGS_REMOVE_USR_INCLUDE(CPPFLAGS)
  79
  80 AC_SUBST(ac_default_prefix)
  81
  82 echo "configure: creating build/smb_build/config.pm"
  83 cat >build/smb_build/config.pm<<CEOF
  84 # config.pm - Autogenerate by configure. DO NOT EDIT!
  85
  86 package config;
  87 require Exporter;
  88 @ISA = qw(Exporter);
  89 @EXPORT_OK = qw(%enabled %config);
  90 use strict;
  91
  92 use vars qw(%enabled %config);
  93
  94 %config = (AC_FOREACH([AC_Var], m4_defn([_AC_SUBST_VARS]), [
  95         AC_Var => '$AC_Var',])
  96 );
  97
  98 $SMB_INFO_ENABLES
  99 1;
 100 CEOF
 101
 102 echo "configure: creating config.mk"
 103 cat >config.mk<<CEOF
 104 # config.mk - Autogenerated by configure, DO NOT EDIT!
 105 $SMB_INFO_EXT_LIBS
 106 $SMB_INFO_SUBSYSTEMS
 107 $SMB_INFO_LIBRARIES
 108 CEOF
 109
 110 AC_OUTPUT_COMMANDS(
 111 [test "x$ac_abs_srcdir" != "x$ac_abs_builddir" &&
 112  (cd $builddir;
 113         test -d heimdal || cp -r $srcdir/heimdal $builddir/
 114         test -d heimdal_build || cp -r $srcdir/heimdal_build $builddir/
 115         test -d build || samba_builddir="$builddir" samba_srcdir="$srcdir" $PERL $srcdir/script/buildtree.pl
 116         test -f $builddir/include/smb.h || cp $srcdir/include/smb.h $builddir/include
 117  )
 118 $PERL -I${builddir} -I${srcdir} -I${srcdir}/build ${srcdir}/build/smb_build/main.pl || exit $?],[
 119 PERL="$PERL";export PERL;export srcdir; export builddir;
 120 ])
 121 AC_OUTPUT
 122
 123 cmp include/config_tmp.h include/config.h >/dev/null 2>&1
 124 CMP_RET=$?
 125 if test $CMP_RET != 0; then
 126         cp include/config_tmp.h include/config.h
 127 fi