configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([rsync],[3.2.0],[http://rsync.samba.org/bugzilla.html])
   4
   5 AC_CONFIG_MACRO_DIR([m4])
   6 AC_CONFIG_SRCDIR([byteorder.h])
   7 AC_CONFIG_HEADER(config.h)
   8 AC_PREREQ([2.69])
   9
  10 AC_SUBST(RSYNC_VERSION, $PACKAGE_VERSION)
  11 AC_MSG_NOTICE([Configuring rsync $PACKAGE_VERSION])
  12
  13 AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$PACKAGE_VERSION"], [rsync release version])
  14
  15 LDFLAGS=${LDFLAGS-""}
  16
  17 AC_CANONICAL_HOST
  18
  19 dnl define the directory for replacement function since AC_LIBOBJ does not
  20 dnl officially support subdirs and fails with automake
  21 AC_CONFIG_LIBOBJ_DIR([lib])
  22
  23 # We must decide this before testing the compiler.
  24
  25 # Please allow this to default to yes, so that your users have more
  26 # chance of getting a useful stack trace if problems occur.
  27
  28 AC_MSG_CHECKING([whether to include debugging symbols])
  29 AC_ARG_ENABLE(debug,
  30         AS_HELP_STRING([--disable-debug],[disable debugging symbols and features]))
  31
  32 if test x"$enable_debug" = x"no"; then
  33     AC_MSG_RESULT(no)
  34     ac_cv_prog_cc_g=no
  35 else
  36     AC_MSG_RESULT([yes])
  37     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  38     # leave ac_cv_prog_cc_g alone; AC_PROG_CC will try to include -g if it can
  39 fi
  40
  41 dnl Checks for programs.
  42 AC_PROG_CC
  43 AC_PROG_CPP
  44 AC_PROG_CXX
  45 AC_PROG_AWK
  46 AC_PROG_EGREP
  47 AC_PROG_INSTALL
  48 AC_PROG_MKDIR_P
  49 AC_PROG_CC_STDC
  50 AC_SUBST(SHELL)
  51 AC_PATH_PROG([PERL], [perl])
  52 AC_PATH_PROG([PYTHON3], [python3])
  53
  54 AC_DEFINE([_GNU_SOURCE], 1,
  55           [Define _GNU_SOURCE so that we get all necessary prototypes])
  56
  57 if test x"$ac_cv_prog_cc_stdc" = x"no"; then
  58         AC_MSG_WARN([rsync requires an ANSI C compiler and you do not seem to have one])
  59 fi
  60
  61 AC_ARG_ENABLE(profile,
  62         AS_HELP_STRING([--enable-profile],[turn on CPU profiling]))
  63 if test x"$enable_profile" = x"yes"; then
  64         CFLAGS="$CFLAGS -pg"
  65 fi
  66
  67 AC_MSG_CHECKING([if md2man can create man pages])
  68 if test x"$ac_cv_path_PYTHON3" = x; then
  69     AC_MSG_RESULT(no - python3 not found)
  70     md2man_works=no
  71 else
  72     md2man_out=`"$srcdir/md2man" --test "$srcdir/rsync-ssl.1.md" 2>&1`
  73     if test $? = 0; then
  74         AC_MSG_RESULT(yes)
  75         md2man_works=yes
  76     else
  77         AC_MSG_RESULT(no)
  78         md2man_works=no
  79         echo "$md2man_out"
  80     fi
  81 fi
  82
  83 AC_MSG_CHECKING([if we require man-page building])
  84 AC_ARG_ENABLE([md2man],
  85         AS_HELP_STRING([--disable-md2man],[disable md2man for man page creation]))
  86 if test x"$enable_md2man" != x"no"; then
  87     if test -f "$srcdir/rsync.1"; then
  88         AC_MSG_RESULT(optional)
  89     else
  90         AC_MSG_RESULT(required)
  91         if test x"$md2man_works" = x"no"; then
  92             AC_MSG_ERROR(You need python3 and the cmarkgfm OR commonmark python3 lib in order to build man pages.
  93 You can specify --disable-md2man if you want to skip building them.)
  94         fi
  95     fi
  96     MAKE_MAN=man
  97 else
  98     AC_MSG_RESULT(no)
  99     MAKE_MAN=''
 100 fi
 101
 102 # Specifically, this turns on panic_action handling.
 103 AC_ARG_ENABLE(maintainer-mode,
 104         AS_HELP_STRING([--enable-maintainer-mode],[turn on extra debug features]))
 105 if test x"$enable_maintainer_mode" = x"yes"; then
 106         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
 107 fi
 108
 109 # This is needed for our included version of popt.  Kind of silly, but
 110 # I don't want our version too far out of sync.
 111 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
 112
 113 # If GCC, turn on warnings.
 114 if test x"$GCC" = x"yes"; then
 115         CFLAGS="$CFLAGS -Wall -W"
 116 fi
 117
 118 AC_ARG_WITH(included-popt,
 119         AS_HELP_STRING([--with-included-popt],[use bundled popt library, not from system]))
 120
 121 AC_ARG_WITH(included-zlib,
 122         AS_HELP_STRING([--with-included-zlib],[use bundled zlib library, not from system]))
 123
 124 AC_ARG_WITH(protected-args,
 125         AS_HELP_STRING([--with-protected-args],[make --protected-args option the default]))
 126 if test x"$with_protected_args" = x"yes"; then
 127         AC_DEFINE_UNQUOTED(RSYNC_USE_PROTECTED_ARGS, 1, [Define to 1 if --protected-args should be the default])
 128 fi
 129
 130 AC_ARG_WITH(rsync-path,
 131         AS_HELP_STRING([--with-rsync-path=PATH],[set default --rsync-path to PATH (default: rsync)]),
 132         [ RSYNC_PATH="$with_rsync_path" ],
 133         [ RSYNC_PATH="rsync" ])
 134
 135 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
 136
 137 AC_ARG_WITH(rsyncd-conf,
 138         AS_HELP_STRING([--with-rsyncd-conf=PATH],[set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]),
 139         [ if test ! -z "$with_rsyncd_conf" ; then
 140                 case $with_rsyncd_conf in
 141                         yes|no)
 142                                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 143                                 ;;
 144                         /*)
 145                                 RSYNCD_SYSCONF="$with_rsyncd_conf"
 146                                 ;;
 147                         *)
 148                                 AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH)
 149                                 ;;
 150                 esac
 151         else
 152                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 153         fi ],
 154         [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ])
 155
 156 AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server])
 157
 158 AC_ARG_WITH(rsh,
 159         AS_HELP_STRING([--with-rsh=CMD],[set remote shell command to CMD (default: ssh)]))
 160
 161 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
 162 if test x$HAVE_REMSH = x1; then
 163         AC_DEFINE(HAVE_REMSH, 1, [Define to 1 if remote shell is remsh, not rsh])
 164 fi
 165
 166 if test x"$with_rsh" != x; then
 167         RSYNC_RSH="$with_rsh"
 168 else
 169         RSYNC_RSH="ssh"
 170 fi
 171 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
 172
 173 # Some programs on solaris are only found in /usr/xpg4/bin (or work better than others versions).
 174 AC_PATH_PROG(SHELL_PATH, sh, /bin/sh, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 175 AC_PATH_PROG(FAKEROOT_PATH, fakeroot, /usr/bin/fakeroot, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 176
 177 AC_ARG_WITH(nobody-group,
 178     AS_HELP_STRING([--with-nobody-group=GROUP],[set the default unprivileged group (default nobody or nogroup)]),
 179     [ NOBODY_GROUP="$with_nobody_group" ])
 180
 181 if test x"$with_nobody_group" = x; then
 182     AC_MSG_CHECKING([the group for user "nobody"])
 183     if grep '^nobody:' /etc/group >/dev/null 2>&1; then
 184         NOBODY_GROUP=nobody
 185     elif grep '^nogroup:' /etc/group >/dev/null 2>&1; then
 186         NOBODY_GROUP=nogroup
 187     else
 188         NOBODY_GROUP=nobody # test for others?
 189     fi
 190     AC_MSG_RESULT($NOBODY_GROUP)
 191 fi
 192
 193 AC_DEFINE_UNQUOTED(NOBODY_USER, "nobody", [unprivileged user--e.g. nobody])
 194 AC_DEFINE_UNQUOTED(NOBODY_GROUP, "$NOBODY_GROUP", [unprivileged group for unprivileged user])
 195
 196 # SIMD optimizations
 197 SIMD=
 198
 199 AC_MSG_CHECKING([whether to enable SIMD optimizations])
 200 AC_ARG_ENABLE(simd,
 201     AS_HELP_STRING([--disable-simd],[disable SIMD optimizations (requires c++)]))
 202
 203 if test x"$enable_simd" != x"no"; then
 204     # For x86-64 SIMD, g++ >=5 or clang++ >=7 is required
 205     if test x"$build_cpu" = x"x86_64"; then
 206         AC_LANG(C++)
 207         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
 208 #include <immintrin.h>
 209 __attribute__ ((target("default"))) static int testing(int x) { return x; }
 210 __attribute__ ((target("sse3"))) static int testing(int x) { return x; }
 211 __attribute__ ((target("sse2"))) static int testing(int x) { return x; }
 212 ]], [[if (testing(42)) printf("HERE\n");]])],[CXX_OK=yes],[CXX_OK=no])
 213         AC_LANG(C)
 214         if test x"$CXX_OK" = x"yes"; then
 215             # AC_MSG_RESULT() is called below.
 216             SIMD="$SIMD x86_64"
 217         elif test x"$enable_simd" = x"yes"; then
 218             AC_MSG_RESULT(error)
 219             AC_MSG_ERROR(The SIMD compilation test failed.
 220 Omit --enable-simd to continue without it.)
 221         fi
 222     elif test x"$enable_simd" = x"yes"; then
 223         AC_MSG_RESULT(unavailable)
 224         AC_MSG_ERROR(The SIMD optimizations are currently x86_64 only.
 225 Omit --enable-simd to continue without it.)
 226     fi
 227 fi
 228
 229 if test x"$SIMD" != x""; then
 230     SIMD=`echo "$SIMD" | sed 's/^ *//'`
 231     AC_MSG_RESULT([yes ($SIMD)])
 232     AC_DEFINE(HAVE_SIMD, 1, [Define to 1 to enable SIMD optimizations])
 233     SIMD=`echo '$(SIMD_'"$SIMD)" | sed 's/ /) $(SIMD_/g'`
 234     # We only use c++ for its target attribute dispatching, disable unneeded bulky features
 235     CXXFLAGS="$CXXFLAGS -fno-exceptions -fno-rtti"
 236 else
 237     AC_MSG_RESULT(no)
 238 fi
 239
 240 AC_SUBST(SIMD)
 241
 242 # arrgh. libc in some old debian version screwed up the largefile
 243 # stuff, getting byte range locking wrong
 244 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
 245 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 246 #define _FILE_OFFSET_BITS 64
 247 #include <stdio.h>
 248 #include <fcntl.h>
 249 #include <sys/types.h>
 250 #include <sys/wait.h>
 251 #if HAVE_UNISTD_H
 252 #include <unistd.h>
 253 #endif
 254
 255 int main(void)
 256 {
 257         struct flock lock;
 258         int status;
 259         char tpl[32] = "/tmp/locktest.XXXXXX";
 260         int fd = mkstemp(tpl);
 261         if (fd < 0) {
 262                 strcpy(tpl, "conftest.dat");
 263                 fd = open(tpl, O_CREAT|O_RDWR, 0600);
 264         }
 265
 266         lock.l_type = F_WRLCK;
 267         lock.l_whence = SEEK_SET;
 268         lock.l_start = 0;
 269         lock.l_len = 1;
 270         lock.l_pid = 0;
 271         fcntl(fd,F_SETLK,&lock);
 272         if (fork() == 0) {
 273                 lock.l_start = 1;
 274                 _exit(fcntl(fd,F_SETLK,&lock) == 0);
 275         }
 276         wait(&status);
 277         unlink(tpl);
 278         return WEXITSTATUS(status);
 279 }
 280 ]])],[rsync_cv_HAVE_BROKEN_LARGEFILE=yes],[rsync_cv_HAVE_BROKEN_LARGEFILE=no],[rsync_cv_HAVE_BROKEN_LARGEFILE=cross])])
 281 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
 282    AC_SYS_LARGEFILE
 283 fi
 284
 285 ipv6type=unknown
 286 ipv6lib=none
 287 ipv6trylibc=yes
 288
 289 AC_ARG_ENABLE(ipv6,
 290         AS_HELP_STRING([--disable-ipv6],[turn off IPv6 support]))
 291 if test x"$enable_ipv6" != x"no"; then
 292         AC_MSG_CHECKING([ipv6 stack type])
 293         for i in inria kame linux-glibc linux-inet6 solaris toshiba v6d zeta cygwin; do
 294                 case $i in
 295                 inria)
 296                         # http://www.kame.net/
 297                         AC_EGREP_CPP(yes, [
 298 #include <netinet/in.h>
 299 #ifdef IPV6_INRIA_VERSION
 300 yes
 301 #endif],
 302                                 [ipv6type=$i;
 303                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 304                                 ])
 305                         ;;
 306                 kame)
 307                         # http://www.kame.net/
 308                         AC_EGREP_CPP(yes, [
 309 #include <netinet/in.h>
 310 #ifdef __KAME__
 311 yes
 312 #endif],
 313                                 [ipv6type=$i;
 314                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 315                         ;;
 316                 linux-glibc)
 317                         # http://www.v6.linux.or.jp/
 318                         AC_EGREP_CPP(yes, [
 319 #include <features.h>
 320 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 321 yes
 322 #endif],
 323                                 [ipv6type=$i;
 324 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 325                         ;;
 326                 linux-inet6)
 327                         # http://www.v6.linux.or.jp/
 328                         if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
 329                                 ipv6type=$i
 330                                 ipv6lib=inet6
 331                                 ipv6libdir=/usr/inet6/lib
 332                                 ipv6trylibc=yes;
 333                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 334                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 335                         fi
 336                         ;;
 337                 solaris)
 338                         # http://www.sun.com
 339                         AC_EGREP_CPP(yes, [
 340 #include <netinet/ip6.h>
 341 #ifdef __sun
 342 yes
 343 #endif],
 344                                 [ipv6type=$i;
 345                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 346                         ;;
 347                 toshiba)
 348                         AC_EGREP_CPP(yes, [
 349 #include <sys/param.h>
 350 #ifdef _TOSHIBA_INET6
 351 yes
 352 #endif],
 353                                 [ipv6type=$i;
 354                                 ipv6lib=inet6;
 355                                 ipv6libdir=/usr/local/v6/lib;
 356                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 357                         ;;
 358                 v6d)
 359                         AC_EGREP_CPP(yes, [
 360 #include </usr/local/v6/include/sys/v6config.h>
 361 #ifdef __V6D__
 362 yes
 363 #endif],
 364                                 [ipv6type=$i;
 365                                 ipv6lib=v6;
 366                                 ipv6libdir=/usr/local/v6/lib;
 367                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 368                         ;;
 369                 zeta)
 370                         AC_EGREP_CPP(yes, [
 371 #include <sys/param.h>
 372 #ifdef _ZETA_MINAMI_INET6
 373 yes
 374 #endif],
 375                                 [ipv6type=$i;
 376                                 ipv6lib=inet6;
 377                                 ipv6libdir=/usr/local/v6/lib;
 378                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 379                         ;;
 380                 cygwin)
 381                         AC_EGREP_CPP(yes, [
 382 #include <netinet/in.h>
 383 #ifdef _CYGWIN_IN6_H
 384 yes
 385 #endif],
 386                                 [ipv6type=$i;
 387                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 388                         ;;
 389                 esac
 390                 if test "$ipv6type" != "unknown"; then
 391                         break
 392                 fi
 393         done
 394         AC_MSG_RESULT($ipv6type)
 395
 396         AC_SEARCH_LIBS(getaddrinfo, inet6)
 397 fi
 398
 399 dnl Do you want to disable use of locale functions
 400 AC_ARG_ENABLE([locale],
 401         AS_HELP_STRING([--disable-locale],[disable locale features]))
 402 AH_TEMPLATE([CONFIG_LOCALE],
 403 [Undefine if you do not want locale features.  By default this is defined.])
 404 if test x"$enable_locale" != x"no"; then
 405         AC_DEFINE(CONFIG_LOCALE)
 406 fi
 407
 408 AC_MSG_CHECKING([whether to call shutdown on all sockets])
 409 case $host_os in
 410         *cygwin* ) AC_MSG_RESULT(yes)
 411                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
 412                             [Define to 1 if sockets need to be shutdown])
 413                    ;;
 414                * ) AC_MSG_RESULT(no);;
 415 esac
 416
 417 AC_C_BIGENDIAN
 418 AC_HEADER_DIRENT
 419 AC_HEADER_TIME
 420 AC_HEADER_SYS_WAIT
 421 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \
 422     unistd.h utime.h grp.h compat.h sys/param.h ctype.h sys/wait.h \
 423     sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h \
 424     sys/un.h sys/attr.h mcheck.h arpa/inet.h arpa/nameser.h locale.h \
 425     netdb.h malloc.h float.h limits.h iconv.h libcharset.h langinfo.h \
 426     sys/acl.h acl/libacl.h attr/xattr.h sys/xattr.h sys/extattr.h \
 427     popt.h popt/popt.h linux/falloc.h netinet/in_systm.h netinet/ip.h \
 428     zlib.h xxhash.h openssl/md4.h openssl/md5.h zstd.h lz4.h)
 429 AC_HEADER_MAJOR_FIXED
 430
 431 AC_MSG_CHECKING([whether to enable use of openssl crypto library])
 432 AC_ARG_ENABLE([openssl],
 433         AS_HELP_STRING([--disable-openssl],[disable openssl crypto library]))
 434 AH_TEMPLATE([USE_OPENSSL],
 435 [Undefine if you do not want to use openssl crypto library.  By default this is defined.])
 436 if test x"$enable_openssl" != x"no"; then
 437     if test x"$ac_cv_header_openssl_md4_h" = x"yes" && test x"$ac_cv_header_openssl_md5_h" = x"yes"; then
 438       AC_MSG_RESULT(yes)
 439       AC_SEARCH_LIBS(MD5_Init, crypto,
 440           [AC_DEFINE(USE_OPENSSL)],
 441           [AC_MSG_ERROR(Failed to find MD5_Init function in openssl crypto lib.
 442 Use --disable-openssl to continue without openssl crypto lib support.)])
 443     else
 444         AC_MSG_RESULT(no)
 445         AC_MSG_ERROR(Failed to find openssl/md4.h and openssl/md5.h for openssl crypto lib support.
 446 Use --disable-openssl to continue without it.)
 447     fi
 448 else
 449     AC_MSG_RESULT(no)
 450 fi
 451
 452 AC_MSG_CHECKING([whether to enable xxhash checksum support])
 453 AC_ARG_ENABLE([xxhash],
 454         AS_HELP_STRING([--disable-xxhash],[disable xxhash checksums]))
 455 AH_TEMPLATE([SUPPORT_XXHASH],
 456 [Undefine if you do not want xxhash checksums.  By default this is defined.])
 457 if test x"$enable_xxhash" != x"no"; then
 458     if test x"$ac_cv_header_xxhash_h" = x"yes"; then
 459         AC_MSG_RESULT(yes)
 460         AC_SEARCH_LIBS(XXH64_createState, xxhash,
 461             [AC_DEFINE(SUPPORT_XXHASH)],
 462             [AC_MSG_ERROR(Failed to find XXH64_createState function in xxhash lib.
 463 Use --disable-xxhash to continue without xxhash checksums.)])
 464     else
 465         AC_MSG_RESULT(no)
 466         AC_MSG_ERROR(Failed to find xxhash.h for xxhash checksum support.
 467 Use --disable-xxhash to continue without it.)
 468     fi
 469 else
 470     AC_MSG_RESULT(no)
 471 fi
 472
 473 AC_MSG_CHECKING([whether to enable zstd compression])
 474 AC_ARG_ENABLE([zstd],
 475         AC_HELP_STRING([--disable-zstd], [disable zstd compression]))
 476 AH_TEMPLATE([SUPPORT_ZSTD],
 477 [Undefine if you do not want zstd compression.  By default this is defined.])
 478 if test x"$enable_zstd" != x"no"; then
 479     if test x"$ac_cv_header_zstd_h" = x"yes"; then
 480         AC_MSG_RESULT(yes)
 481         AC_SEARCH_LIBS(ZSTD_minCLevel, zstd,
 482             [AC_DEFINE(SUPPORT_ZSTD)],
 483             [AC_MSG_ERROR(Failed to find ZSTD_minCLevel function in zstd lib.
 484 Use --disable-zstd to continue without zstd compression.)])
 485     else
 486         AC_MSG_RESULT(no)
 487         AC_MSG_ERROR(Failed to find zstd.h for zstd compression support.
 488 Use --disable-zstd to continue without it.)
 489     fi
 490 else
 491     AC_MSG_RESULT(no)
 492 fi
 493
 494 AC_MSG_CHECKING([whether to enable LZ4 compression])
 495 AC_ARG_ENABLE([lz4],
 496         AC_HELP_STRING([--disable-lz4], [disable LZ4 compression]))
 497 AH_TEMPLATE([SUPPORT_LZ4],
 498 [Undefine if you do not want LZ4 compression.  By default this is defined.])
 499 if test x"$enable_lz4" != x"no"; then
 500     if test x"$ac_cv_header_lz4_h" = x"yes"; then
 501         AC_MSG_RESULT(yes)
 502         AC_SEARCH_LIBS(LZ4_compress_default, lz4,
 503             [AC_DEFINE(SUPPORT_LZ4)],
 504             [AC_MSG_ERROR(Failed to find LZ4_compress_default function in lz4 lib.
 505 Use --disable-lz4 to continue without lz4 compression.)])
 506     else
 507         AC_MSG_RESULT(no)
 508         AC_MSG_ERROR(Failed to find lz4.h for lz4 compression support.
 509 Use --disable-lz4 to continue without it.)
 510     fi
 511 else
 512     AC_MSG_RESULT(no)
 513 fi
 514
 515 AC_CACHE_CHECK([if makedev takes 3 args],rsync_cv_MAKEDEV_TAKES_3_ARGS,[
 516 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 517 #include <sys/types.h>
 518 #ifdef MAJOR_IN_MKDEV
 519 #include <sys/mkdev.h>
 520 # if !defined makedev && (defined mkdev || defined _WIN32 || defined __WIN32__)
 521 #  define makedev mkdev
 522 # endif
 523 #elif defined MAJOR_IN_SYSMACROS
 524 #include <sys/sysmacros.h>
 525 #endif
 526
 527 int main(void)
 528 {
 529         dev_t dev = makedev(0, 5, 7);
 530         if (major(dev) != 5 || minor(dev) != 7)
 531                 return 1;
 532         return 0;
 533 }
 534 ]])],[rsync_cv_MAKEDEV_TAKES_3_ARGS=yes],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no])])
 535 if test x"$rsync_cv_MAKEDEV_TAKES_3_ARGS" = x"yes"; then
 536    AC_DEFINE(MAKEDEV_TAKES_3_ARGS, 1, [Define to 1 if makedev() takes 3 args])
 537 fi
 538
 539 AC_CHECK_SIZEOF(int)
 540 AC_CHECK_SIZEOF(long)
 541 AC_CHECK_SIZEOF(long long)
 542 AC_CHECK_SIZEOF(short)
 543 AC_CHECK_SIZEOF(int16_t)
 544 AC_CHECK_SIZEOF(uint16_t)
 545 AC_CHECK_SIZEOF(int32_t)
 546 AC_CHECK_SIZEOF(uint32_t)
 547 AC_CHECK_SIZEOF(int64_t)
 548 AC_CHECK_SIZEOF(off_t)
 549 AC_CHECK_SIZEOF(off64_t)
 550 AC_CHECK_SIZEOF(time_t)
 551 AC_CHECK_SIZEOF(char*)
 552
 553 AC_C_INLINE
 554
 555 AC_TYPE_LONG_DOUBLE_WIDER
 556 ac_cv_c_long_double=$ac_cv_type_long_double_wider
 557 if test $ac_cv_c_long_double = yes; then
 558   AC_DEFINE([HAVE_LONG_DOUBLE],[1],[Define to 1 if the type `long double' works and has more range or precision than `double'.])
 559 fi
 560
 561 AC_TYPE_UID_T
 562 AC_CHECK_TYPES([mode_t,off_t,size_t,pid_t,id_t])
 563 AC_TYPE_GETGROUPS
 564 AC_CHECK_MEMBERS([struct stat.st_rdev,
 565                   struct stat.st_mtimensec,
 566                   struct stat.st_mtimespec.tv_nsec,
 567                   struct stat.st_mtim.tv_nsec],,,[
 568 #ifdef HAVE_SYS_TYPES_H
 569 #include <sys/types.h>
 570 #endif
 571 #ifdef HAVE_SYS_STAT_H
 572 #include <sys/stat.h>
 573 #endif
 574 #ifdef HAVE_UNISTD_H
 575 #include <unistd.h>
 576 #endif])
 577
 578 TYPE_SOCKLEN_T
 579
 580 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 581     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]], [[int i = errno]])],[rsync_cv_errno=yes],[rsync_cv_have_errno_decl=no])])
 582 if test x"$rsync_cv_errno" = x"yes"; then
 583    AC_DEFINE(HAVE_ERRNO_DECL, 1, [Define to 1 if errno is declared in errno.h])
 584 fi
 585
 586 # The following test taken from the cvs sources
 587 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 588 # These need checks to be before checks for any other functions that
 589 #    might be in the same libraries.
 590 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 591 # libsocket.so which has a bad implementation of gethostbyname (it
 592 # only looks in /etc/hosts), so we only look for -lsocket if we need
 593 # it.
 594 AC_CHECK_FUNCS(connect)
 595 if test x"$ac_cv_func_connect" = x"no"; then
 596     case "$LIBS" in
 597     *-lnsl*) ;;
 598     *) AC_CHECK_LIB(nsl_s, printf) ;;
 599     esac
 600     case "$LIBS" in
 601     *-lnsl*) ;;
 602     *) AC_CHECK_LIB(nsl, printf) ;;
 603     esac
 604     case "$LIBS" in
 605     *-lsocket*) ;;
 606     *) AC_CHECK_LIB(socket, connect) ;;
 607     esac
 608     case "$LIBS" in
 609     *-linet*) ;;
 610     *) AC_CHECK_LIB(inet, connect) ;;
 611     esac
 612     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 613     dnl has been cached.
 614     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 615        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 616         # ac_cv_func_connect=yes
 617         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 618         AC_DEFINE(HAVE_CONNECT, 1, [Define to 1 if you have the "connect" function])
 619     fi
 620 fi
 621
 622 AC_SEARCH_LIBS(inet_ntop, resolv)
 623
 624 # For OS X, Solaris, HP-UX, etc.: figure out if -liconv is needed.  We'll
 625 # accept either iconv_open or libiconv_open, since some include files map
 626 # the former to the latter.
 627 AC_SEARCH_LIBS(iconv_open, iconv)
 628 AC_SEARCH_LIBS(libiconv_open, iconv)
 629
 630 AC_MSG_CHECKING([for iconv declaration])
 631 AC_CACHE_VAL(am_cv_proto_iconv, [
 632     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 633 #include <stdlib.h>
 634 #include <iconv.h>
 635 extern
 636 #ifdef __cplusplus
 637 "C"
 638 #endif
 639 #if defined(__STDC__) || defined(__cplusplus)
 640 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 641 #else
 642 size_t iconv();
 643 #endif
 644 ]], [[]])],[am_cv_proto_iconv_arg1=""],[am_cv_proto_iconv_arg1="const"])
 645       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
 646     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed 's/( /(/'`
 647 AC_MSG_RESULT([$]{ac_t:-
 648          }[$]am_cv_proto_iconv)
 649 AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
 650                    [Define as const if the declaration of iconv() needs const.])
 651
 652 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
 653
 654 AC_REPLACE_FUNCS([inet_ntop inet_pton])
 655
 656 AC_HAVE_TYPE([struct addrinfo], [#include <netdb.h>])
 657 AC_HAVE_TYPE([struct sockaddr_storage], [#include <sys/types.h>
 658 #include <sys/socket.h>])
 659
 660 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
 661 #   builtin getaddrinfo if one of the defines don't exist
 662 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
 663                rsync_cv_HAVE_GETADDR_DEFINES,[
 664                         AC_EGREP_CPP(yes, [
 665                         #include <sys/types.h>
 666                         #include <sys/socket.h>
 667                         #include <netdb.h>
 668                         #ifdef AI_PASSIVE
 669                         yes
 670                         #endif],
 671                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
 672                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
 673 AS_IF([test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes" -a x"$ac_cv_type_struct_addrinfo" = x"yes"],[
 674         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
 675         # something else so we must include <netdb.h> to get the
 676         # redefinition.
 677         AC_CHECK_FUNCS(getaddrinfo, ,
 678                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
 679                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 680                 #include <sys/socket.h>
 681                 #include <netdb.h>]], [[getaddrinfo(NULL, NULL, NULL, NULL);]])],[AC_MSG_RESULT([yes])
 682                         AC_DEFINE(HAVE_GETADDRINFO, 1,
 683                                 [Define to 1 if you have the "getaddrinfo" function and required types.])],[AC_MSG_RESULT([no])
 684                         AC_LIBOBJ([getaddrinfo])])])
 685     ],[AC_LIBOBJ([getaddrinfo])])
 686
 687 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 688                 [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ],
 689                 [],
 690                 [
 691 #include <sys/types.h>
 692 #include <sys/socket.h>
 693 ])
 694
 695 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
 696                 [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ],
 697                 [],
 698                 [
 699 #include <sys/types.h>
 700 #include <sys/socket.h>
 701 #include <netinet/in.h>
 702 ])
 703
 704 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 705                 [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ],
 706                 [],
 707                 [
 708 #include <sys/types.h>
 709 #include <sys/socket.h>
 710 #include <netinet/in.h>
 711 ])
 712
 713 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
 714                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ],
 715                 [],
 716                 [
 717 #include <sys/types.h>
 718 #include <sys/socket.h>
 719 #include <netinet/in.h>
 720 ])
 721
 722 AC_HAVE_TYPE([struct stat64], [#include <stdio.h>
 723 #if HAVE_SYS_TYPES_H
 724 # include <sys/types.h>
 725 #endif
 726 #if HAVE_SYS_STAT_H
 727 # include <sys/stat.h>
 728 #endif
 729 #if STDC_HEADERS
 730 # include <stdlib.h>
 731 # include <stddef.h>
 732 #else
 733 # if HAVE_STDLIB_H
 734 #  include <stdlib.h>
 735 # endif
 736 #endif
 737 ])
 738
 739 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 740 #
 741 AC_CHECK_FUNCS(strcasecmp)
 742 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 743     AC_CHECK_LIB(resolv, strcasecmp)
 744 fi
 745
 746 AC_CHECK_FUNCS(aclsort)
 747 if test x"$ac_cv_func_aclsort" = x"no"; then
 748     AC_CHECK_LIB(sec, aclsort)
 749 fi
 750
 751 dnl At the moment we don't test for a broken memcmp(), because all we
 752 dnl need to do is test for equality, not comparison, and it seems that
 753 dnl every platform has a memcmp that can do at least that.
 754 dnl AC_FUNC_MEMCMP
 755
 756 AC_FUNC_UTIME_NULL
 757 AC_FUNC_ALLOCA
 758 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup chown chmod lchmod mknod mkfifo \
 759     fchmod fstat ftruncate strchr readlink link utime utimes lutimes strftime \
 760     chflags getattrlist \
 761     memmove lchown vsnprintf snprintf vasprintf asprintf setsid strpbrk \
 762     strlcat strlcpy strtol mallinfo getgroups setgroups geteuid getegid \
 763     setlocale setmode open64 lseek64 mkstemp64 mtrace va_copy __va_copy \
 764     seteuid strerror putenv iconv_open locale_charset nl_langinfo getxattr \
 765     extattr_get_link sigaction sigprocmask setattrlist getgrouplist \
 766     initgroups utimensat posix_fallocate attropen setvbuf nanosleep usleep)
 767
 768 dnl cygwin iconv.h defines iconv_open as libiconv_open
 769 if test x"$ac_cv_func_iconv_open" != x"yes"; then
 770     AC_CHECK_FUNC(libiconv_open, [ac_cv_func_iconv_open=yes; AC_DEFINE(HAVE_ICONV_OPEN, 1)])
 771 fi
 772
 773 dnl Preallocation stuff (also fallocate, posix_fallocate function tests above):
 774
 775 AC_CACHE_CHECK([for useable fallocate],rsync_cv_have_fallocate,[
 776 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <fcntl.h>
 777 #include <sys/types.h>]], [[fallocate(0, 0, 0, 0);]])],[rsync_cv_have_fallocate=yes],[rsync_cv_have_fallocate=no])])
 778 if test x"$rsync_cv_have_fallocate" = x"yes"; then
 779     AC_DEFINE(HAVE_FALLOCATE, 1, [Define to 1 if you have the fallocate function and it compiles and links without error])
 780 fi
 781
 782 AC_MSG_CHECKING([for FALLOC_FL_PUNCH_HOLE])
 783 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 784         #define _GNU_SOURCE 1
 785         #include <linux/falloc.h>
 786         #ifndef FALLOC_FL_PUNCH_HOLE
 787         #error FALLOC_FL_PUNCH_HOLE is missing
 788         #endif
 789     ]])], [
 790         AC_MSG_RESULT([yes])
 791         AC_DEFINE([HAVE_FALLOC_FL_PUNCH_HOLE], [1], [Define if FALLOC_FL_PUNCH_HOLE is available.])
 792     ], [
 793         AC_MSG_RESULT([no])
 794     ]
 795 )
 796
 797 AC_MSG_CHECKING([for FALLOC_FL_ZERO_RANGE])
 798 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 799         #define _GNU_SOURCE 1
 800         #include <linux/falloc.h>
 801         #ifndef FALLOC_FL_ZERO_RANGE
 802         #error FALLOC_FL_ZERO_RANGE is missing
 803         #endif
 804     ]])], [
 805         AC_MSG_RESULT([yes])
 806         AC_DEFINE([HAVE_FALLOC_FL_ZERO_RANGE], [1], [Define if FALLOC_FL_ZERO_RANGE is available.])
 807     ], [
 808         AC_MSG_RESULT([no])
 809     ]
 810 )
 811
 812 AC_CACHE_CHECK([for SYS_fallocate],rsync_cv_have_sys_fallocate,[
 813 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/syscall.h>
 814 #include <unistd.h>
 815 #include <sys/types.h>]], [[syscall(SYS_fallocate, 0, 0, (loff_t)0, (loff_t)0);]])],[rsync_cv_have_sys_fallocate=yes],[rsync_cv_have_sys_fallocate=no])])
 816 if test x"$rsync_cv_have_sys_fallocate" = x"yes"; then
 817     AC_DEFINE(HAVE_SYS_FALLOCATE, 1, [Define to 1 if you have the SYS_fallocate syscall number])
 818 fi
 819
 820 if test x"$ac_cv_func_posix_fallocate" = x"yes"; then
 821     AC_MSG_CHECKING([whether posix_fallocate is efficient])
 822     case $host_os in
 823     *cygwin*)
 824         AC_MSG_RESULT(yes)
 825         AC_DEFINE(HAVE_EFFICIENT_POSIX_FALLOCATE, 1,
 826                   [Define if posix_fallocate is efficient (Cygwin)])
 827         ;;
 828     *)
 829         AC_MSG_RESULT(no)
 830         ;;
 831     esac
 832 fi
 833
 834 dnl End of preallocation stuff
 835
 836 AC_CHECK_FUNCS(getpgrp tcgetpgrp)
 837 if test $ac_cv_func_getpgrp = yes; then
 838     AC_FUNC_GETPGRP
 839 fi
 840
 841 AC_ARG_ENABLE(iconv-open,
 842     AS_HELP_STRING([--disable-iconv-open],[disable all use of iconv_open() function]),
 843     [], [enable_iconv_open=$ac_cv_func_iconv_open])
 844
 845 if test x"$enable_iconv_open" != x"no"; then
 846     AC_DEFINE(USE_ICONV_OPEN, 1, [Define to 1 if you want rsync to make use of iconv_open()])
 847 fi
 848
 849 AC_ARG_ENABLE(iconv,
 850     AS_HELP_STRING([--disable-iconv],[disable rsync's --iconv option]),
 851     [], [enable_iconv=$enable_iconv_open])
 852 AH_TEMPLATE([ICONV_OPTION],
 853 [Define if you want the --iconv option.  Specifying a value will set the
 854 default iconv setting (a NULL means no --iconv processing by default).])
 855 if test x"$enable_iconv" != x"no"; then
 856         if test x"$enable_iconv" = x"yes"; then
 857                 AC_DEFINE(ICONV_OPTION, NULL)
 858         else
 859                 AC_DEFINE_UNQUOTED(ICONV_OPTION, "$enable_iconv")
 860         fi
 861         AC_DEFINE(UTF8_CHARSET, "UTF-8", [String to pass to iconv() for the UTF-8 charset.])
 862 fi
 863
 864 AC_CACHE_CHECK([whether chown() modifies symlinks],rsync_cv_chown_modifies_symlink,[
 865   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 866 #if HAVE_UNISTD_H
 867 # include <unistd.h>
 868 #endif
 869 #include <stdlib.h>
 870 #include <errno.h>
 871 int main(void) {
 872         char const *dangling_symlink = "conftest.dangle";
 873         unlink(dangling_symlink);
 874         if (symlink("conftest.no-such", dangling_symlink) < 0) abort();
 875         if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) return 1;
 876         return 0;
 877     }]])],[rsync_cv_chown_modifies_symlink=yes],[rsync_cv_chown_modifies_symlink=no],[rsync_cv_chown_modifies_symlink=no])])
 878 if test $rsync_cv_chown_modifies_symlink = yes; then
 879   AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define to 1 if chown modifies symlinks.])
 880 fi
 881
 882 AC_CACHE_CHECK([whether link() can hard-link symlinks],rsync_cv_can_hardlink_symlink,[
 883   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 884 #if HAVE_UNISTD_H
 885 # include <unistd.h>
 886 #endif
 887 #include <stdlib.h>
 888 #include <errno.h>
 889 #define FILENAME "conftest.dangle"
 890 int main(void) {
 891         unlink(FILENAME);
 892         if (symlink("conftest.no-such", FILENAME) < 0) abort();
 893         unlink(FILENAME "2");
 894         if (link(FILENAME, FILENAME "2") < 0) return 1;
 895         return 0;
 896     }]])],[rsync_cv_can_hardlink_symlink=yes],[rsync_cv_can_hardlink_symlink=no],[rsync_cv_can_hardlink_symlink=no])])
 897 if test $rsync_cv_can_hardlink_symlink = yes; then
 898   AC_DEFINE(CAN_HARDLINK_SYMLINK, 1, [Define to 1 if link() can hard-link symlinks.])
 899 fi
 900
 901 AC_CACHE_CHECK([whether link() can hard-link special files],rsync_cv_can_hardlink_special,[
 902   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 903 #if HAVE_UNISTD_H
 904 # include <unistd.h>
 905 #endif
 906 #ifdef HAVE_SYS_STAT_H
 907 #include <sys/stat.h>
 908 #endif
 909 #include <stdlib.h>
 910 #include <errno.h>
 911 #define FILENAME "conftest.fifi"
 912 int main(void) {
 913         unlink(FILENAME);
 914         if (mkfifo(FILENAME, 0777) < 0) abort();
 915         unlink(FILENAME "2");
 916         if (link(FILENAME, FILENAME "2") < 0) return 1;
 917         return 0;
 918     }]])],[rsync_cv_can_hardlink_special=yes],[rsync_cv_can_hardlink_special=no],[rsync_cv_can_hardlink_special=no])])
 919 if test $rsync_cv_can_hardlink_special = yes; then
 920     AC_DEFINE(CAN_HARDLINK_SPECIAL, 1, [Define to 1 if link() can hard-link special files.])
 921 fi
 922
 923 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
 924 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 925 #include <sys/types.h>
 926 #include <sys/socket.h>
 927
 928 int main(void) {
 929        int fd[2];
 930        return (socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1;
 931 }]])],[rsync_cv_HAVE_SOCKETPAIR=yes],[rsync_cv_HAVE_SOCKETPAIR=no],[rsync_cv_HAVE_SOCKETPAIR=cross])])
 932 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
 933     AC_DEFINE(HAVE_SOCKETPAIR, 1, [Define to 1 if you have the "socketpair" function])
 934 fi
 935
 936 AC_REPLACE_FUNCS([getpass])
 937
 938 if test x"$with_included_popt" != x"yes"; then
 939     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
 940 fi
 941 if test x"$ac_cv_header_popt_popt_h" = x"yes"; then
 942     # If the system has /usr/include/popt/popt.h, we enable the
 943     # included popt because an attempt to "#include <popt/popt.h>"
 944     # would use our included header file anyway (due to -I.), and
 945     # might conflict with the system popt.
 946     with_included_popt=yes
 947 elif test x"$ac_cv_header_popt_h" != x"yes"; then
 948     with_included_popt=yes
 949 fi
 950
 951 AC_MSG_CHECKING([whether to use included libpopt])
 952 if test x"$with_included_popt" = x"yes"; then
 953     AC_MSG_RESULT($srcdir/popt)
 954     BUILD_POPT='$(popt_OBJS)'
 955     CFLAGS="-I$srcdir/popt $CFLAGS"
 956     if test x"$ALLOCA" != x
 957     then
 958         # this can be removed when/if we add an included alloca.c;
 959         #  see autoconf documentation on AC_FUNC_ALLOCA
 960         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
 961     fi
 962 else
 963     AC_MSG_RESULT(no)
 964 fi
 965
 966 # We default to using our zlib unless --with-included-zlib=no is given.
 967 if test x"$with_included_zlib" != x"no"; then
 968     with_included_zlib=yes
 969 elif test x"$ac_cv_header_zlib_h" != x"yes"; then
 970     with_included_zlib=yes
 971 fi
 972 if test x"$with_included_zlib" != x"yes"; then
 973     AC_CHECK_LIB(z, deflateParams, , [with_included_zlib=yes])
 974 fi
 975
 976 AC_MSG_CHECKING([whether to use included zlib])
 977 if test x"$with_included_zlib" = x"yes"; then
 978     AC_MSG_RESULT($srcdir/zlib)
 979     BUILD_ZLIB='$(zlib_OBJS)'
 980     CFLAGS="-I$srcdir/zlib $CFLAGS"
 981 else
 982     AC_DEFINE(EXTERNAL_ZLIB, 1, [Define to 1 if using external zlib])
 983     AC_MSG_RESULT(no)
 984 fi
 985
 986 AC_CACHE_CHECK([for unsigned char],rsync_cv_SIGNED_CHAR_OK,[
 987 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[signed char *s = ""]])],[rsync_cv_SIGNED_CHAR_OK=yes],[rsync_cv_SIGNED_CHAR_OK=no])])
 988 if test x"$rsync_cv_SIGNED_CHAR_OK" = x"yes"; then
 989     AC_DEFINE(SIGNED_CHAR_OK, 1, [Define to 1 if "signed char" is a valid type])
 990 fi
 991
 992 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
 993 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <sys/types.h>
 994 #include <dirent.h>
 995 int main(void) { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
 996 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
 997 di->d_name[0] == 0) return 0; return 1;} ]])],[rsync_cv_HAVE_BROKEN_READDIR=yes],[rsync_cv_HAVE_BROKEN_READDIR=no],[rsync_cv_HAVE_BROKEN_READDIR=cross])])
 998 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
 999     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [Define to 1 if readdir() is broken])
1000 fi
1001
1002 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_STRUCT_UTIMBUF,[
1003 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1004 #include <utime.h>]], [[struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; return utime("foo.c",&tbuf);]])],[rsync_cv_HAVE_STRUCT_UTIMBUF=yes],[rsync_cv_HAVE_STRUCT_UTIMBUF=no])])
1005 if test x"$rsync_cv_HAVE_STRUCT_UTIMBUF" = x"yes"; then
1006     AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if you have the "struct utimbuf" type])
1007 fi
1008
1009 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
1010 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/time.h>
1011 #include <unistd.h>]], [[struct timeval tv; return gettimeofday(&tv, NULL);]])],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=no])])
1012 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then
1013     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [Define to 1 if gettimeofday() takes a time-zone arg])
1014 fi
1015
1016 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
1017 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1018 #include <sys/types.h>
1019 #include <stdarg.h>
1020 #include <stdio.h>
1021 #include <stdlib.h>
1022 #include <string.h>
1023 void foo(const char *format, ...) {
1024        va_list ap;
1025        int len;
1026        static char buf[] = "12345678901234567890";
1027
1028        va_start(ap, format);
1029        len = vsnprintf(0, 0, format, ap);
1030        va_end(ap);
1031        if (len != 5) exit(1);
1032
1033        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
1034 }
1035 int main(void) { foo("hello"); return 0; }
1036 ]])],[rsync_cv_HAVE_C99_VSNPRINTF=yes],[rsync_cv_HAVE_C99_VSNPRINTF=no],[rsync_cv_HAVE_C99_VSNPRINTF=cross])])
1037 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
1038     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [Define to 1 if vsprintf has a C99-compatible return value])
1039 fi
1040
1041
1042 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
1043 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1044 #include <sys/types.h>
1045 #include <sys/stat.h>
1046 #include <unistd.h>
1047 int main(void) {
1048   struct stat st;
1049   char tpl[20]="/tmp/test.XXXXXX";
1050   int fd = mkstemp(tpl);
1051   if (fd == -1) return 1;
1052   unlink(tpl);
1053   if (fstat(fd, &st) != 0) return 1;
1054   if ((st.st_mode & 0777) != 0600) return 1;
1055   return 0;
1056 }]])],[rsync_cv_HAVE_SECURE_MKSTEMP=yes],[rsync_cv_HAVE_SECURE_MKSTEMP=no],[rsync_cv_HAVE_SECURE_MKSTEMP=cross])])
1057 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
1058     case $host_os in
1059     hpux*)
1060         dnl HP-UX has a broken mkstemp() implementation they refuse to fix,
1061         dnl so we noisily skip using it.  See HP change request JAGaf34426
1062         dnl for details. (sbonds)
1063         AC_MSG_WARN(Skipping broken HP-UX mkstemp() -- using mktemp() instead)
1064         ;;
1065     *)
1066         AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [Define to 1 if mkstemp() is available and works right])
1067         ;;
1068     esac
1069 fi
1070
1071
1072 AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[
1073 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1074 #include <stdio.h>
1075 #include <sys/stat.h>
1076 #include <errno.h>
1077 #if HAVE_UNISTD_H
1078 # include <unistd.h>
1079 #endif
1080 int main(void) { int rc, ec; char *fn = "fifo-test";
1081 unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn);
1082 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
1083 return 0;}]])],[rsync_cv_MKNOD_CREATES_FIFOS=yes],[rsync_cv_MKNOD_CREATES_FIFOS=no],[rsync_cv_MKNOD_CREATES_FIFOS=cross])])
1084 if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then
1085     AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.])
1086 fi
1087
1088 AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[
1089 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1090 #include <stdio.h>
1091 #include <sys/stat.h>
1092 #include <errno.h>
1093 #if HAVE_UNISTD_H
1094 # include <unistd.h>
1095 #endif
1096 int main(void) { int rc, ec; char *fn = "sock-test";
1097 unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn);
1098 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
1099 return 0;}]])],[rsync_cv_MKNOD_CREATES_SOCKETS=yes],[rsync_cv_MKNOD_CREATES_SOCKETS=no],[rsync_cv_MKNOD_CREATES_SOCKETS=cross])])
1100 if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then
1101     AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.])
1102 fi
1103
1104 #
1105 # The following test was mostly taken from the tcl/tk plus patches
1106 #
1107 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
1108 rm -rf conftest*
1109 cat > conftest.$ac_ext <<EOF
1110 int main(void) { return 0; }
1111 EOF
1112 ${CC-cc} -c -o conftest..o conftest.$ac_ext
1113 if test -f conftest..o; then
1114     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
1115 else
1116     rsync_cv_DASHC_WORKS_WITH_DASHO=no
1117 fi
1118 rm -rf conftest*
1119 ])
1120 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
1121     OBJ_SAVE="#"
1122     OBJ_RESTORE="#"
1123     CC_SHOBJ_FLAG='-o $@'
1124 else
1125     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
1126     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
1127     CC_SHOBJ_FLAG=""
1128 fi
1129
1130 AC_SUBST(OBJ_SAVE)
1131 AC_SUBST(OBJ_RESTORE)
1132 AC_SUBST(CC_SHOBJ_FLAG)
1133 AC_SUBST(BUILD_POPT)
1134 AC_SUBST(BUILD_ZLIB)
1135 AC_SUBST(MAKE_MAN)
1136
1137 AC_CHECK_FUNCS(_acl __acl _facl __facl)
1138 #################################################
1139 # check for ACL support
1140
1141 AC_MSG_CHECKING([whether to support ACLs])
1142 AC_ARG_ENABLE(acl-support,
1143         AS_HELP_STRING([--disable-acl-support],[disable ACL support]))
1144
1145 if test x"$enable_acl_support" = x"no"; then
1146     AC_MSG_RESULT(no)
1147 else
1148     case "$host_os" in
1149     *sysv5*)
1150         AC_MSG_RESULT(Using UnixWare ACLs)
1151         AC_DEFINE(HAVE_UNIXWARE_ACLS, 1, [true if you have UnixWare ACLs])
1152         AC_DEFINE(SUPPORT_ACLS, 1, [Define to 1 to add support for ACLs])
1153         ;;
1154     solaris*)
1155         AC_MSG_RESULT(Using solaris ACLs)
1156         AC_DEFINE(HAVE_SOLARIS_ACLS, 1, [true if you have solaris ACLs])
1157         AC_DEFINE(SUPPORT_ACLS, 1)
1158         ;;
1159     *hpux*)
1160         AC_MSG_RESULT(Using HPUX ACLs)
1161         AC_DEFINE(HAVE_HPUX_ACLS, 1, [true if you have HPUX ACLs])
1162         AC_DEFINE(SUPPORT_ACLS, 1)
1163         ;;
1164     *irix*)
1165         AC_MSG_RESULT(Using IRIX ACLs)
1166         AC_DEFINE(HAVE_IRIX_ACLS, 1, [true if you have IRIX ACLs])
1167         AC_DEFINE(SUPPORT_ACLS, 1)
1168         ;;
1169     *aix*)
1170         AC_MSG_RESULT(Using AIX ACLs)
1171         AC_DEFINE(HAVE_AIX_ACLS, 1, [true if you have AIX ACLs])
1172         AC_DEFINE(SUPPORT_ACLS, 1)
1173         ;;
1174     *osf*)
1175         AC_MSG_RESULT(Using Tru64 ACLs)
1176         AC_DEFINE(HAVE_TRU64_ACLS, 1, [true if you have Tru64 ACLs])
1177         AC_DEFINE(SUPPORT_ACLS, 1)
1178         LIBS="$LIBS -lpacl"
1179         ;;
1180     darwin*)
1181         AC_MSG_RESULT(Using OS X ACLs)
1182         AC_DEFINE(HAVE_OSX_ACLS, 1, [true if you have Mac OS X ACLs])
1183         AC_DEFINE(SUPPORT_ACLS, 1)
1184         ;;
1185     *)
1186         AC_MSG_RESULT(running tests:)
1187         AC_CHECK_LIB(acl,acl_get_file)
1188         AC_CACHE_CHECK([for ACL support],samba_cv_HAVE_POSIX_ACLS,[
1189             AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1190 #include <sys/acl.h>]], [[ acl_t acl; int entry_id; acl_entry_t *entry_p; return acl_get_entry( acl, entry_id, entry_p);]])],[samba_cv_HAVE_POSIX_ACLS=yes],[samba_cv_HAVE_POSIX_ACLS=no])])
1191         AC_MSG_CHECKING(ACL test results)
1192         if test x"$samba_cv_HAVE_POSIX_ACLS" = x"yes"; then
1193             AC_MSG_RESULT(Using posix ACLs)
1194             AC_DEFINE(HAVE_POSIX_ACLS, 1, [true if you have posix ACLs])
1195             AC_DEFINE(SUPPORT_ACLS, 1)
1196             AC_CACHE_CHECK([for acl_get_perm_np],samba_cv_HAVE_ACL_GET_PERM_NP,[
1197                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1198 #include <sys/acl.h>]], [[ acl_permset_t permset_d; acl_perm_t perm; return acl_get_perm_np( permset_d, perm);]])],[samba_cv_HAVE_ACL_GET_PERM_NP=yes],[samba_cv_HAVE_ACL_GET_PERM_NP=no])])
1199             if test x"$samba_cv_HAVE_ACL_GET_PERM_NP" = x"yes"; then
1200                 AC_DEFINE(HAVE_ACL_GET_PERM_NP, 1, [true if you have acl_get_perm_np])
1201             fi
1202         else
1203             if test x"$enable_acl_support" = x"yes"; then
1204                 AC_MSG_ERROR(Failed to find ACL support)
1205             else
1206                 AC_MSG_RESULT(No ACL support found)
1207             fi
1208         fi
1209         ;;
1210     esac
1211 fi
1212
1213 #################################################
1214 # check for extended attribute support
1215 AC_MSG_CHECKING(whether to support extended attributes)
1216 AC_ARG_ENABLE(xattr-support,
1217     AS_HELP_STRING([--disable-xattr-support],[disable extended attributes]),
1218     [], [case "$ac_cv_func_getxattr$ac_cv_func_extattr_get_link$ac_cv_func_attropen" in
1219         *yes*) enable_xattr_support=maybe ;;
1220         *) enable_xattr_support=no ;;
1221         esac])
1222 AH_TEMPLATE([SUPPORT_XATTRS],
1223 [Define to 1 to add support for extended attributes])
1224 if test x"$enable_xattr_support" = x"no"; then
1225     AC_MSG_RESULT(no)
1226 else
1227     case "$host_os" in
1228     *linux*|*netbsd*)
1229         AC_MSG_RESULT(Using Linux xattrs)
1230         AC_DEFINE(HAVE_LINUX_XATTRS, 1, [True if you have Linux xattrs (or equivalent)])
1231         AC_DEFINE(SUPPORT_XATTRS, 1)
1232         AC_DEFINE(NO_SYMLINK_USER_XATTRS, 1, [True if symlinks do not support user xattrs])
1233         AC_CHECK_LIB(attr,getxattr)
1234         ;;
1235     darwin*)
1236         AC_MSG_RESULT(Using OS X xattrs)
1237         AC_DEFINE(HAVE_OSX_XATTRS, 1, [True if you have Mac OS X xattrs])
1238         AC_DEFINE(SUPPORT_XATTRS, 1)
1239         AC_DEFINE(NO_DEVICE_XATTRS, 1, [True if device files do not support xattrs])
1240         AC_DEFINE(NO_SPECIAL_XATTRS, 1, [True if special files do not support xattrs])
1241         ;;
1242     freebsd*)
1243         AC_MSG_RESULT(Using FreeBSD extattrs)
1244         AC_DEFINE(HAVE_FREEBSD_XATTRS, 1, [True if you have FreeBSD xattrs])
1245         AC_DEFINE(SUPPORT_XATTRS, 1)
1246         ;;
1247     solaris*)
1248         AC_MSG_RESULT(Using Solaris xattrs)
1249         AC_DEFINE(HAVE_SOLARIS_XATTRS, 1, [True if you have Solaris xattrs])
1250         AC_DEFINE(SUPPORT_XATTRS, 1)
1251         AC_DEFINE(NO_SYMLINK_XATTRS, 1, [True if symlinks do not support xattrs])
1252         ;;
1253     *)
1254         if test x"$enable_xattr_support" = x"yes"; then
1255             AC_MSG_ERROR(Failed to find extended attribute support)
1256         else
1257             AC_MSG_RESULT(No extended attribute support found)
1258         fi
1259         ;;
1260     esac
1261 fi
1262
1263 if test x"$enable_acl_support" = x"no" -o x"$enable_xattr_support" = x"no" -o x"$enable_iconv" = x"no"; then
1264     AC_MSG_CHECKING([whether $CC supports -Wno-unused-parameter])
1265     OLD_CFLAGS="$CFLAGS"
1266     CFLAGS="$CFLAGS -Wno-unused-parameter"
1267     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>]], [[printf("hello\n");]])],[rsync_warn_flag=yes],[rsync_warn_flag=no])
1268     AC_MSG_RESULT([$rsync_warn_flag])
1269     if test x"$rsync_warn_flag" = x"no"; then
1270         CFLAGS="$OLD_CFLAGS"
1271     fi
1272 fi
1273
1274 case "$CC" in
1275 ' checker'*|checker*)
1276     AC_DEFINE(FORCE_FD_ZERO_MEMSET, 1, [Used to make "checker" understand that FD_ZERO() clears memory.])
1277     ;;
1278 esac
1279
1280 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
1281 AC_OUTPUT
1282
1283 AC_MSG_RESULT()
1284 AC_MSG_RESULT([    rsync ${RSYNC_VERSION} configuration successful])
1285 AC_MSG_RESULT()