configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([rsync],[3.2.0pre2],[http://rsync.samba.org/bugzilla.html])
   4
   5 AC_CONFIG_MACRO_DIR([m4])
   6 AC_CONFIG_SRCDIR([byteorder.h])
   7 AC_CONFIG_HEADER(config.h)
   8 AC_PREREQ([2.69])
   9
  10 AC_SUBST(RSYNC_VERSION, $PACKAGE_VERSION)
  11 AC_MSG_NOTICE([Configuring rsync $PACKAGE_VERSION])
  12
  13 AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$PACKAGE_VERSION"], [rsync release version])
  14
  15 LDFLAGS=${LDFLAGS-""}
  16
  17 AC_CANONICAL_HOST
  18
  19 dnl define the directory for replacement function since AC_LIBOBJ does not
  20 dnl officially support subdirs and fails with automake
  21 AC_CONFIG_LIBOBJ_DIR([lib])
  22
  23 # We must decide this before testing the compiler.
  24
  25 # Please allow this to default to yes, so that your users have more
  26 # chance of getting a useful stack trace if problems occur.
  27
  28 AC_MSG_CHECKING([whether to include debugging symbols])
  29 AC_ARG_ENABLE(debug,
  30         AS_HELP_STRING([--disable-debug],[disable debugging symbols and features]))
  31
  32 if test x"$enable_debug" = x"no"; then
  33     AC_MSG_RESULT(no)
  34     ac_cv_prog_cc_g=no
  35 else
  36     AC_MSG_RESULT([yes])
  37     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  38     # leave ac_cv_prog_cc_g alone; AC_PROG_CC will try to include -g if it can
  39 fi
  40
  41 dnl Checks for programs.
  42 AC_PROG_CC
  43 AC_PROG_CPP
  44 AC_PROG_CXX
  45 AC_PROG_EGREP
  46 AC_PROG_INSTALL
  47 AC_PROG_MKDIR_P
  48 AC_PROG_CC_STDC
  49 AC_SUBST(SHELL)
  50 AC_PATH_PROG([PERL], [perl])
  51 AC_PATH_PROG([PYTHON3], [python3])
  52
  53 AC_DEFINE([_GNU_SOURCE], 1,
  54           [Define _GNU_SOURCE so that we get all necessary prototypes])
  55
  56 if test x"$ac_cv_prog_cc_stdc" = x"no"; then
  57         AC_MSG_WARN([rsync requires an ANSI C compiler and you do not seem to have one])
  58 fi
  59
  60 AC_ARG_ENABLE(profile,
  61         AS_HELP_STRING([--enable-profile],[turn on CPU profiling]))
  62 if test x"$enable_profile" = x"yes"; then
  63         CFLAGS="$CFLAGS -pg"
  64 fi
  65
  66 AC_MSG_CHECKING([if md2man can create man pages])
  67 if test x"$ac_cv_path_PYTHON3" = x; then
  68     AC_MSG_RESULT(no - python3 not found)
  69     md2man_works=no
  70 elif "$srcdir/md2man" --test "$srcdir/rsync.1.md" >/dev/null 2>&1; then
  71     AC_MSG_RESULT(yes)
  72     md2man_works=yes
  73 else
  74     AC_MSG_RESULT(no - need cmarkgfm or commonmark python3 lib installed)
  75     md2man_works=no
  76 fi
  77
  78 AC_MSG_CHECKING([if we require man-page building])
  79 AC_ARG_ENABLE([md2man],
  80         AS_HELP_STRING([--disable-md2man],[disable md2man for man page creation]))
  81 if test x"$enable_md2man" != x"no"; then
  82     if test -f "$srcdir/rsync.1"; then
  83         AC_MSG_RESULT(optional)
  84     else
  85         AC_MSG_RESULT(required)
  86         if test x"$md2man_works" = x"no"; then
  87             AC_MSG_ERROR(You need python3 and the cmarkgfm OR commonmark python3 lib in order to build man pages.
  88 You can specify --disable-md2man if you want to skip building them.)
  89         fi
  90     fi
  91 else
  92     AC_MSG_RESULT(no)
  93 fi
  94
  95 # Specifically, this turns on panic_action handling.
  96 AC_ARG_ENABLE(maintainer-mode,
  97         AS_HELP_STRING([--enable-maintainer-mode],[turn on extra debug features]))
  98 if test x"$enable_maintainer_mode" = x"yes"; then
  99         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
 100 fi
 101
 102 # This is needed for our included version of popt.  Kind of silly, but
 103 # I don't want our version too far out of sync.
 104 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
 105
 106 # If GCC, turn on warnings.
 107 if test x"$GCC" = x"yes"; then
 108         CFLAGS="$CFLAGS -Wall -W"
 109 fi
 110
 111 AC_ARG_WITH(included-popt,
 112         AS_HELP_STRING([--with-included-popt],[use bundled popt library, not from system]))
 113
 114 AC_ARG_WITH(included-zlib,
 115         AS_HELP_STRING([--with-included-zlib],[use bundled zlib library, not from system]))
 116
 117 AC_ARG_WITH(protected-args,
 118         AS_HELP_STRING([--with-protected-args],[make --protected-args option the default]))
 119 if test x"$with_protected_args" = x"yes"; then
 120         AC_DEFINE_UNQUOTED(RSYNC_USE_PROTECTED_ARGS, 1, [Define to 1 if --protected-args should be the default])
 121 fi
 122
 123 AC_ARG_WITH(rsync-path,
 124         AS_HELP_STRING([--with-rsync-path=PATH],[set default --rsync-path to PATH (default: rsync)]),
 125         [ RSYNC_PATH="$with_rsync_path" ],
 126         [ RSYNC_PATH="rsync" ])
 127
 128 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
 129
 130 AC_ARG_WITH(rsyncd-conf,
 131         AS_HELP_STRING([--with-rsyncd-conf=PATH],[set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]),
 132         [ if test ! -z "$with_rsyncd_conf" ; then
 133                 case $with_rsyncd_conf in
 134                         yes|no)
 135                                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 136                                 ;;
 137                         /*)
 138                                 RSYNCD_SYSCONF="$with_rsyncd_conf"
 139                                 ;;
 140                         *)
 141                                 AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH)
 142                                 ;;
 143                 esac
 144         else
 145                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 146         fi ],
 147         [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ])
 148
 149 AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server])
 150
 151 AC_ARG_WITH(rsh,
 152         AS_HELP_STRING([--with-rsh=CMD],[set remote shell command to CMD (default: ssh)]))
 153
 154 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
 155 if test x$HAVE_REMSH = x1; then
 156         AC_DEFINE(HAVE_REMSH, 1, [Define to 1 if remote shell is remsh, not rsh])
 157 fi
 158
 159 if test x"$with_rsh" != x; then
 160         RSYNC_RSH="$with_rsh"
 161 else
 162         RSYNC_RSH="ssh"
 163 fi
 164 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
 165
 166 # Some programs on solaris are only found in /usr/xpg4/bin (or work better than others versions).
 167 AC_PATH_PROG(SHELL_PATH, sh, /bin/sh, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 168 AC_PATH_PROG(FAKEROOT_PATH, fakeroot, /usr/bin/fakeroot, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 169
 170 AC_ARG_WITH(nobody-group,
 171     AS_HELP_STRING([--with-nobody-group=GROUP],[set the default unprivileged group (default nobody or nogroup)]),
 172     [ NOBODY_GROUP="$with_nobody_group" ])
 173
 174 if test x"$with_nobody_group" = x; then
 175     AC_MSG_CHECKING([the group for user "nobody"])
 176     if grep '^nobody:' /etc/group >/dev/null 2>&1; then
 177         NOBODY_GROUP=nobody
 178     elif grep '^nogroup:' /etc/group >/dev/null 2>&1; then
 179         NOBODY_GROUP=nogroup
 180     else
 181         NOBODY_GROUP=nobody # test for others?
 182     fi
 183     AC_MSG_RESULT($NOBODY_GROUP)
 184 fi
 185
 186 AC_DEFINE_UNQUOTED(NOBODY_USER, "nobody", [unprivileged user--e.g. nobody])
 187 AC_DEFINE_UNQUOTED(NOBODY_GROUP, "$NOBODY_GROUP", [unprivileged group for unprivileged user])
 188
 189 # SIMD optimizations
 190 SIMD=
 191
 192 AC_MSG_CHECKING([whether to enable SIMD optimizations])
 193 AC_ARG_ENABLE(simd,
 194     AS_HELP_STRING([--disable-simd],[disable SIMD optimizations (requires g++)]))
 195
 196 if test x"$enable_simd" != x"no"; then
 197     # For x86-64 SIMD, g++ is also required
 198     if test x"$build_cpu" = x"x86_64"; then
 199         if test x"$CXX" = x"g++"; then
 200             # AC_MSG_RESULT() called below
 201             SIMD="$SIMD x86_64"
 202         else
 203             AC_MSG_RESULT(no)
 204             case "$host_os" in
 205             *linux*)
 206                 AC_MSG_ERROR(Failed to find g++ for SIMD speedups. Use --disable-simd to continue without it.)
 207                 ;;
 208             *)
 209                 ;;
 210             esac
 211         fi
 212     fi
 213 fi
 214
 215 if test x"$SIMD" != x""; then
 216     SIMD=`echo "$SIMD" | sed -e 's/^ *//'`
 217     AC_MSG_RESULT([yes ($SIMD)])
 218     AC_DEFINE(HAVE_SIMD, 1, [Define to 1 to enable SIMD optimizations])
 219     SIMD=`echo "$SIMD" | sed -e 's/[[^ ]]\+/$(SIMD_&)/g'`
 220     # We only use g++ for its target attribute dispatching, disable unneeded bulky features
 221     CXXFLAGS="$CXXFLAGS -fno-exceptions -fno-rtti"
 222 else
 223     AC_MSG_RESULT(no)
 224 fi
 225
 226 AC_SUBST(SIMD)
 227
 228 # arrgh. libc in some old debian version screwed up the largefile
 229 # stuff, getting byte range locking wrong
 230 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
 231 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 232 #define _FILE_OFFSET_BITS 64
 233 #include <stdio.h>
 234 #include <fcntl.h>
 235 #include <sys/types.h>
 236 #include <sys/wait.h>
 237 #if HAVE_UNISTD_H
 238 #include <unistd.h>
 239 #endif
 240
 241 int main(void)
 242 {
 243         struct flock lock;
 244         int status;
 245         char tpl[32] = "/tmp/locktest.XXXXXX";
 246         int fd = mkstemp(tpl);
 247         if (fd < 0) {
 248                 strcpy(tpl, "conftest.dat");
 249                 fd = open(tpl, O_CREAT|O_RDWR, 0600);
 250         }
 251
 252         lock.l_type = F_WRLCK;
 253         lock.l_whence = SEEK_SET;
 254         lock.l_start = 0;
 255         lock.l_len = 1;
 256         lock.l_pid = 0;
 257         fcntl(fd,F_SETLK,&lock);
 258         if (fork() == 0) {
 259                 lock.l_start = 1;
 260                 _exit(fcntl(fd,F_SETLK,&lock) == 0);
 261         }
 262         wait(&status);
 263         unlink(tpl);
 264         return WEXITSTATUS(status);
 265 }
 266 ]])],[rsync_cv_HAVE_BROKEN_LARGEFILE=yes],[rsync_cv_HAVE_BROKEN_LARGEFILE=no],[rsync_cv_HAVE_BROKEN_LARGEFILE=cross])])
 267 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
 268    AC_SYS_LARGEFILE
 269 fi
 270
 271 ipv6type=unknown
 272 ipv6lib=none
 273 ipv6trylibc=yes
 274
 275 AC_ARG_ENABLE(ipv6,
 276         AS_HELP_STRING([--disable-ipv6],[turn off IPv6 support]))
 277 if test x"$enable_ipv6" != x"no"; then
 278         AC_MSG_CHECKING([ipv6 stack type])
 279         for i in inria kame linux-glibc linux-inet6 solaris toshiba v6d zeta cygwin; do
 280                 case $i in
 281                 inria)
 282                         # http://www.kame.net/
 283                         AC_EGREP_CPP(yes, [
 284 #include <netinet/in.h>
 285 #ifdef IPV6_INRIA_VERSION
 286 yes
 287 #endif],
 288                                 [ipv6type=$i;
 289                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 290                                 ])
 291                         ;;
 292                 kame)
 293                         # http://www.kame.net/
 294                         AC_EGREP_CPP(yes, [
 295 #include <netinet/in.h>
 296 #ifdef __KAME__
 297 yes
 298 #endif],
 299                                 [ipv6type=$i;
 300                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 301                         ;;
 302                 linux-glibc)
 303                         # http://www.v6.linux.or.jp/
 304                         AC_EGREP_CPP(yes, [
 305 #include <features.h>
 306 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 307 yes
 308 #endif],
 309                                 [ipv6type=$i;
 310 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 311                         ;;
 312                 linux-inet6)
 313                         # http://www.v6.linux.or.jp/
 314                         if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
 315                                 ipv6type=$i
 316                                 ipv6lib=inet6
 317                                 ipv6libdir=/usr/inet6/lib
 318                                 ipv6trylibc=yes;
 319                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 320                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 321                         fi
 322                         ;;
 323                 solaris)
 324                         # http://www.sun.com
 325                         AC_EGREP_CPP(yes, [
 326 #include <netinet/ip6.h>
 327 #ifdef __sun
 328 yes
 329 #endif],
 330                                 [ipv6type=$i;
 331                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 332                         ;;
 333                 toshiba)
 334                         AC_EGREP_CPP(yes, [
 335 #include <sys/param.h>
 336 #ifdef _TOSHIBA_INET6
 337 yes
 338 #endif],
 339                                 [ipv6type=$i;
 340                                 ipv6lib=inet6;
 341                                 ipv6libdir=/usr/local/v6/lib;
 342                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 343                         ;;
 344                 v6d)
 345                         AC_EGREP_CPP(yes, [
 346 #include </usr/local/v6/include/sys/v6config.h>
 347 #ifdef __V6D__
 348 yes
 349 #endif],
 350                                 [ipv6type=$i;
 351                                 ipv6lib=v6;
 352                                 ipv6libdir=/usr/local/v6/lib;
 353                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 354                         ;;
 355                 zeta)
 356                         AC_EGREP_CPP(yes, [
 357 #include <sys/param.h>
 358 #ifdef _ZETA_MINAMI_INET6
 359 yes
 360 #endif],
 361                                 [ipv6type=$i;
 362                                 ipv6lib=inet6;
 363                                 ipv6libdir=/usr/local/v6/lib;
 364                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 365                         ;;
 366                 cygwin)
 367                         AC_EGREP_CPP(yes, [
 368 #include <netinet/in.h>
 369 #ifdef _CYGWIN_IN6_H
 370 yes
 371 #endif],
 372                                 [ipv6type=$i;
 373                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 374                         ;;
 375                 esac
 376                 if test "$ipv6type" != "unknown"; then
 377                         break
 378                 fi
 379         done
 380         AC_MSG_RESULT($ipv6type)
 381
 382         AC_SEARCH_LIBS(getaddrinfo, inet6)
 383 fi
 384
 385 dnl Do you want to disable use of locale functions
 386 AC_ARG_ENABLE([locale],
 387         AS_HELP_STRING([--disable-locale],[disable locale features]))
 388 AH_TEMPLATE([CONFIG_LOCALE],
 389 [Undefine if you do not want locale features.  By default this is defined.])
 390 if test x"$enable_locale" != x"no"; then
 391         AC_DEFINE(CONFIG_LOCALE)
 392 fi
 393
 394 AC_MSG_CHECKING([whether to call shutdown on all sockets])
 395 case $host_os in
 396         *cygwin* ) AC_MSG_RESULT(yes)
 397                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
 398                             [Define to 1 if sockets need to be shutdown])
 399                    ;;
 400                * ) AC_MSG_RESULT(no);;
 401 esac
 402
 403 AC_C_BIGENDIAN
 404 AC_HEADER_DIRENT
 405 AC_HEADER_TIME
 406 AC_HEADER_SYS_WAIT
 407 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \
 408     unistd.h utime.h grp.h compat.h sys/param.h ctype.h sys/wait.h \
 409     sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h \
 410     sys/un.h sys/attr.h mcheck.h arpa/inet.h arpa/nameser.h locale.h \
 411     netdb.h malloc.h float.h limits.h iconv.h libcharset.h langinfo.h \
 412     sys/acl.h acl/libacl.h attr/xattr.h sys/xattr.h sys/extattr.h \
 413     popt.h popt/popt.h linux/falloc.h netinet/in_systm.h netinet/ip.h \
 414     zlib.h xxhash.h openssl/md4.h openssl/md5.h zstd.h lz4.h)
 415 AC_HEADER_MAJOR_FIXED
 416
 417 AC_MSG_CHECKING([whether to enable use of openssl crypto library])
 418 AC_ARG_ENABLE([openssl],
 419         AS_HELP_STRING([--disable-openssl],[disable openssl crypto library]))
 420 AH_TEMPLATE([USE_OPENSSL],
 421 [Undefine if you do not want to use openssl crypto library.  By default this is defined.])
 422 if test x"$enable_openssl" != x"no" && test x"$ac_cv_header_openssl_md4_h" = x"yes" && test x"$ac_cv_header_openssl_md5_h" = x"yes"; then
 423     AC_MSG_RESULT(yes)
 424     AC_SEARCH_LIBS(MD5_Init, crypto, [AC_DEFINE(USE_OPENSSL)])
 425 else
 426     AC_MSG_RESULT(no)
 427 fi
 428
 429 AC_MSG_CHECKING([whether to enable xxhash checksum support])
 430 AC_ARG_ENABLE([xxhash],
 431         AS_HELP_STRING([--disable-xxhash],[disable xxhash checksums]))
 432 AH_TEMPLATE([SUPPORT_XXHASH],
 433 [Undefine if you do not want xxhash checksums.  By default this is defined.])
 434 if test x"$enable_xxhash" != x"no"; then
 435     if test x"$ac_cv_header_xxhash_h" = x"yes"; then
 436         AC_MSG_RESULT(yes)
 437         AC_SEARCH_LIBS(XXH64_createState, xxhash,
 438             [AC_DEFINE(SUPPORT_XXHASH)],
 439             [AC_MSG_ERROR(Failed to find XXH64_createState function in xxhash lib.
 440 Use --disable-xxhash to continue without xxhash checksums.)])
 441     else
 442         AC_MSG_RESULT(no)
 443         AC_MSG_ERROR(Failed to find xxhash.h for xxhash checksum support.
 444 Use --disable-xxhash to continue without it.)
 445     fi
 446 else
 447     AC_MSG_RESULT(no)
 448 fi
 449
 450 AC_MSG_CHECKING([whether to enable zstd compression])
 451 AC_ARG_ENABLE([zstd],
 452         AC_HELP_STRING([--disable-zstd], [disable zstd compression]))
 453 AH_TEMPLATE([SUPPORT_ZSTD],
 454 [Undefine if you do not want zstd compression.  By default this is defined.])
 455 if test x"$enable_zstd" != x"no"; then
 456     if test x"$ac_cv_header_zstd_h" = x"yes"; then
 457         AC_MSG_RESULT(yes)
 458         AC_SEARCH_LIBS(ZSTD_minCLevel, zstd,
 459             [AC_DEFINE(SUPPORT_ZSTD)],
 460             [AC_MSG_ERROR(Failed to find ZSTD_minCLevel function in zstd lib.
 461 Use --disable-zstd to continue without zstd compression.)])
 462     else
 463         AC_MSG_RESULT(no)
 464         AC_MSG_ERROR(Failed to find zstd.h for zstd compression support.
 465 Use --disable-zstd to continue without it.)
 466     fi
 467 else
 468     AC_MSG_RESULT(no)
 469 fi
 470
 471 AC_MSG_CHECKING([whether to enable LZ4 compression])
 472 AC_ARG_ENABLE([lz4],
 473         AC_HELP_STRING([--disable-lz4], [disable LZ4 compression]))
 474 AH_TEMPLATE([SUPPORT_LZ4],
 475 [Undefine if you do not want LZ4 compression.  By default this is defined.])
 476 if test x"$enable_lz4" != x"no"; then
 477     if test x"$ac_cv_header_lz4_h" = x"yes"; then
 478         AC_MSG_RESULT(yes)
 479         AC_SEARCH_LIBS(LZ4_compress_default, lz4,
 480             [AC_DEFINE(SUPPORT_LZ4)],
 481             [AC_MSG_ERROR(Failed to find LZ4_compress_default function in lz4 lib.
 482 Use --disable-lz4 to continue without lz4 compression.)])
 483     else
 484         AC_MSG_RESULT(no)
 485         AC_MSG_ERROR(Failed to find lz4.h for lz4 compression support.
 486 Use --disable-lz4 to continue without it.)
 487     fi
 488 else
 489     AC_MSG_RESULT(no)
 490 fi
 491
 492 AC_CACHE_CHECK([if makedev takes 3 args],rsync_cv_MAKEDEV_TAKES_3_ARGS,[
 493 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 494 #include <sys/types.h>
 495 #ifdef MAJOR_IN_MKDEV
 496 #include <sys/mkdev.h>
 497 # if !defined makedev && (defined mkdev || defined _WIN32 || defined __WIN32__)
 498 #  define makedev mkdev
 499 # endif
 500 #elif defined MAJOR_IN_SYSMACROS
 501 #include <sys/sysmacros.h>
 502 #endif
 503
 504 int main(void)
 505 {
 506         dev_t dev = makedev(0, 5, 7);
 507         if (major(dev) != 5 || minor(dev) != 7)
 508                 return 1;
 509         return 0;
 510 }
 511 ]])],[rsync_cv_MAKEDEV_TAKES_3_ARGS=yes],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no])])
 512 if test x"$rsync_cv_MAKEDEV_TAKES_3_ARGS" = x"yes"; then
 513    AC_DEFINE(MAKEDEV_TAKES_3_ARGS, 1, [Define to 1 if makedev() takes 3 args])
 514 fi
 515
 516 AC_CHECK_SIZEOF(int)
 517 AC_CHECK_SIZEOF(long)
 518 AC_CHECK_SIZEOF(long long)
 519 AC_CHECK_SIZEOF(short)
 520 AC_CHECK_SIZEOF(int16_t)
 521 AC_CHECK_SIZEOF(uint16_t)
 522 AC_CHECK_SIZEOF(int32_t)
 523 AC_CHECK_SIZEOF(uint32_t)
 524 AC_CHECK_SIZEOF(int64_t)
 525 AC_CHECK_SIZEOF(off_t)
 526 AC_CHECK_SIZEOF(off64_t)
 527 AC_CHECK_SIZEOF(time_t)
 528 AC_CHECK_SIZEOF(char*)
 529
 530 AC_C_INLINE
 531
 532 AC_TYPE_LONG_DOUBLE_WIDER
 533 ac_cv_c_long_double=$ac_cv_type_long_double_wider
 534 if test $ac_cv_c_long_double = yes; then
 535   AC_DEFINE([HAVE_LONG_DOUBLE],[1],[Define to 1 if the type `long double' works and has more range or precision than `double'.])
 536 fi
 537
 538 AC_TYPE_UID_T
 539 AC_CHECK_TYPES([mode_t,off_t,size_t,pid_t,id_t])
 540 AC_TYPE_GETGROUPS
 541 AC_CHECK_MEMBERS([struct stat.st_rdev,
 542                   struct stat.st_mtimensec,
 543                   struct stat.st_mtimespec.tv_nsec,
 544                   struct stat.st_mtim.tv_nsec],,,[
 545 #ifdef HAVE_SYS_TYPES_H
 546 #include <sys/types.h>
 547 #endif
 548 #ifdef HAVE_SYS_STAT_H
 549 #include <sys/stat.h>
 550 #endif
 551 #ifdef HAVE_UNISTD_H
 552 #include <unistd.h>
 553 #endif])
 554
 555 TYPE_SOCKLEN_T
 556
 557 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 558     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]], [[int i = errno]])],[rsync_cv_errno=yes],[rsync_cv_have_errno_decl=no])])
 559 if test x"$rsync_cv_errno" = x"yes"; then
 560    AC_DEFINE(HAVE_ERRNO_DECL, 1, [Define to 1 if errno is declared in errno.h])
 561 fi
 562
 563 # The following test taken from the cvs sources
 564 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 565 # These need checks to be before checks for any other functions that
 566 #    might be in the same libraries.
 567 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 568 # libsocket.so which has a bad implementation of gethostbyname (it
 569 # only looks in /etc/hosts), so we only look for -lsocket if we need
 570 # it.
 571 AC_CHECK_FUNCS(connect)
 572 if test x"$ac_cv_func_connect" = x"no"; then
 573     case "$LIBS" in
 574     *-lnsl*) ;;
 575     *) AC_CHECK_LIB(nsl_s, printf) ;;
 576     esac
 577     case "$LIBS" in
 578     *-lnsl*) ;;
 579     *) AC_CHECK_LIB(nsl, printf) ;;
 580     esac
 581     case "$LIBS" in
 582     *-lsocket*) ;;
 583     *) AC_CHECK_LIB(socket, connect) ;;
 584     esac
 585     case "$LIBS" in
 586     *-linet*) ;;
 587     *) AC_CHECK_LIB(inet, connect) ;;
 588     esac
 589     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 590     dnl has been cached.
 591     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 592        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 593         # ac_cv_func_connect=yes
 594         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 595         AC_DEFINE(HAVE_CONNECT, 1, [Define to 1 if you have the "connect" function])
 596     fi
 597 fi
 598
 599 AC_SEARCH_LIBS(inet_ntop, resolv)
 600
 601 # For OS X, Solaris, HP-UX, etc.: figure out if -liconv is needed.  We'll
 602 # accept either iconv_open or libiconv_open, since some include files map
 603 # the former to the latter.
 604 AC_SEARCH_LIBS(iconv_open, iconv)
 605 AC_SEARCH_LIBS(libiconv_open, iconv)
 606
 607 AC_MSG_CHECKING([for iconv declaration])
 608 AC_CACHE_VAL(am_cv_proto_iconv, [
 609     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 610 #include <stdlib.h>
 611 #include <iconv.h>
 612 extern
 613 #ifdef __cplusplus
 614 "C"
 615 #endif
 616 #if defined(__STDC__) || defined(__cplusplus)
 617 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 618 #else
 619 size_t iconv();
 620 #endif
 621 ]], [[]])],[am_cv_proto_iconv_arg1=""],[am_cv_proto_iconv_arg1="const"])
 622       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
 623     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed -e 's/( /(/'`
 624 AC_MSG_RESULT([$]{ac_t:-
 625          }[$]am_cv_proto_iconv)
 626 AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
 627                    [Define as const if the declaration of iconv() needs const.])
 628
 629 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
 630
 631 AC_REPLACE_FUNCS([inet_ntop inet_pton])
 632
 633 AC_HAVE_TYPE([struct addrinfo], [#include <netdb.h>])
 634 AC_HAVE_TYPE([struct sockaddr_storage], [#include <sys/types.h>
 635 #include <sys/socket.h>])
 636
 637 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
 638 #   builtin getaddrinfo if one of the defines don't exist
 639 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
 640                rsync_cv_HAVE_GETADDR_DEFINES,[
 641                         AC_EGREP_CPP(yes, [
 642                         #include <sys/types.h>
 643                         #include <sys/socket.h>
 644                         #include <netdb.h>
 645                         #ifdef AI_PASSIVE
 646                         yes
 647                         #endif],
 648                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
 649                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
 650 AS_IF([test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes" -a x"$ac_cv_type_struct_addrinfo" = x"yes"],[
 651         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
 652         # something else so we must include <netdb.h> to get the
 653         # redefinition.
 654         AC_CHECK_FUNCS(getaddrinfo, ,
 655                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
 656                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 657                 #include <sys/socket.h>
 658                 #include <netdb.h>]], [[getaddrinfo(NULL, NULL, NULL, NULL);]])],[AC_MSG_RESULT([yes])
 659                         AC_DEFINE(HAVE_GETADDRINFO, 1,
 660                                 [Define to 1 if you have the "getaddrinfo" function and required types.])],[AC_MSG_RESULT([no])
 661                         AC_LIBOBJ([getaddrinfo])])])
 662     ],[AC_LIBOBJ([getaddrinfo])])
 663
 664 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 665                 [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ],
 666                 [],
 667                 [
 668 #include <sys/types.h>
 669 #include <sys/socket.h>
 670 ])
 671
 672 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
 673                 [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ],
 674                 [],
 675                 [
 676 #include <sys/types.h>
 677 #include <sys/socket.h>
 678 #include <netinet/in.h>
 679 ])
 680
 681 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 682                 [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ],
 683                 [],
 684                 [
 685 #include <sys/types.h>
 686 #include <sys/socket.h>
 687 #include <netinet/in.h>
 688 ])
 689
 690 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
 691                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ],
 692                 [],
 693                 [
 694 #include <sys/types.h>
 695 #include <sys/socket.h>
 696 #include <netinet/in.h>
 697 ])
 698
 699 AC_HAVE_TYPE([struct stat64], [#include <stdio.h>
 700 #if HAVE_SYS_TYPES_H
 701 # include <sys/types.h>
 702 #endif
 703 #if HAVE_SYS_STAT_H
 704 # include <sys/stat.h>
 705 #endif
 706 #if STDC_HEADERS
 707 # include <stdlib.h>
 708 # include <stddef.h>
 709 #else
 710 # if HAVE_STDLIB_H
 711 #  include <stdlib.h>
 712 # endif
 713 #endif
 714 ])
 715
 716 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 717 #
 718 AC_CHECK_FUNCS(strcasecmp)
 719 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 720     AC_CHECK_LIB(resolv, strcasecmp)
 721 fi
 722
 723 AC_CHECK_FUNCS(aclsort)
 724 if test x"$ac_cv_func_aclsort" = x"no"; then
 725     AC_CHECK_LIB(sec, aclsort)
 726 fi
 727
 728 dnl At the moment we don't test for a broken memcmp(), because all we
 729 dnl need to do is test for equality, not comparison, and it seems that
 730 dnl every platform has a memcmp that can do at least that.
 731 dnl AC_FUNC_MEMCMP
 732
 733 AC_FUNC_UTIME_NULL
 734 AC_FUNC_ALLOCA
 735 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup chown chmod lchmod mknod mkfifo \
 736     fchmod fstat ftruncate strchr readlink link utime utimes lutimes strftime \
 737     chflags getattrlist \
 738     memmove lchown vsnprintf snprintf vasprintf asprintf setsid strpbrk \
 739     strlcat strlcpy strtol mallinfo getgroups setgroups geteuid getegid \
 740     setlocale setmode open64 lseek64 mkstemp64 mtrace va_copy __va_copy \
 741     seteuid strerror putenv iconv_open locale_charset nl_langinfo getxattr \
 742     extattr_get_link sigaction sigprocmask setattrlist getgrouplist \
 743     initgroups utimensat posix_fallocate attropen setvbuf nanosleep usleep)
 744
 745 dnl cygwin iconv.h defines iconv_open as libiconv_open
 746 if test x"$ac_cv_func_iconv_open" != x"yes"; then
 747     AC_CHECK_FUNC(libiconv_open, [ac_cv_func_iconv_open=yes; AC_DEFINE(HAVE_ICONV_OPEN, 1)])
 748 fi
 749
 750 dnl Preallocation stuff (also fallocate, posix_fallocate function tests above):
 751
 752 AC_CACHE_CHECK([for useable fallocate],rsync_cv_have_fallocate,[
 753 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <fcntl.h>
 754 #include <sys/types.h>]], [[fallocate(0, 0, 0, 0);]])],[rsync_cv_have_fallocate=yes],[rsync_cv_have_fallocate=no])])
 755 if test x"$rsync_cv_have_fallocate" = x"yes"; then
 756     AC_DEFINE(HAVE_FALLOCATE, 1, [Define to 1 if you have the fallocate function and it compiles and links without error])
 757 fi
 758
 759 AC_MSG_CHECKING([for FALLOC_FL_PUNCH_HOLE])
 760 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 761         #define _GNU_SOURCE 1
 762         #include <linux/falloc.h>
 763         #ifndef FALLOC_FL_PUNCH_HOLE
 764         #error FALLOC_FL_PUNCH_HOLE is missing
 765         #endif
 766     ]])], [
 767         AC_MSG_RESULT([yes])
 768         AC_DEFINE([HAVE_FALLOC_FL_PUNCH_HOLE], [1], [Define if FALLOC_FL_PUNCH_HOLE is available.])
 769     ], [
 770         AC_MSG_RESULT([no])
 771     ]
 772 )
 773
 774 AC_MSG_CHECKING([for FALLOC_FL_ZERO_RANGE])
 775 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 776         #define _GNU_SOURCE 1
 777         #include <linux/falloc.h>
 778         #ifndef FALLOC_FL_ZERO_RANGE
 779         #error FALLOC_FL_ZERO_RANGE is missing
 780         #endif
 781     ]])], [
 782         AC_MSG_RESULT([yes])
 783         AC_DEFINE([HAVE_FALLOC_FL_ZERO_RANGE], [1], [Define if FALLOC_FL_ZERO_RANGE is available.])
 784     ], [
 785         AC_MSG_RESULT([no])
 786     ]
 787 )
 788
 789 AC_CACHE_CHECK([for SYS_fallocate],rsync_cv_have_sys_fallocate,[
 790 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/syscall.h>
 791 #include <unistd.h>
 792 #include <sys/types.h>]], [[syscall(SYS_fallocate, 0, 0, (loff_t)0, (loff_t)0);]])],[rsync_cv_have_sys_fallocate=yes],[rsync_cv_have_sys_fallocate=no])])
 793 if test x"$rsync_cv_have_sys_fallocate" = x"yes"; then
 794     AC_DEFINE(HAVE_SYS_FALLOCATE, 1, [Define to 1 if you have the SYS_fallocate syscall number])
 795 fi
 796
 797 if test x"$ac_cv_func_posix_fallocate" = x"yes"; then
 798     AC_MSG_CHECKING([whether posix_fallocate is efficient])
 799     case $host_os in
 800     *cygwin*)
 801         AC_MSG_RESULT(yes)
 802         AC_DEFINE(HAVE_EFFICIENT_POSIX_FALLOCATE, 1,
 803                   [Define if posix_fallocate is efficient (Cygwin)])
 804         ;;
 805     *)
 806         AC_MSG_RESULT(no)
 807         ;;
 808     esac
 809 fi
 810
 811 dnl End of preallocation stuff
 812
 813 AC_CHECK_FUNCS(getpgrp tcgetpgrp)
 814 if test $ac_cv_func_getpgrp = yes; then
 815     AC_FUNC_GETPGRP
 816 fi
 817
 818 AC_ARG_ENABLE(iconv-open,
 819     AS_HELP_STRING([--disable-iconv-open],[disable all use of iconv_open() function]),
 820     [], [enable_iconv_open=$ac_cv_func_iconv_open])
 821
 822 if test x"$enable_iconv_open" != x"no"; then
 823     AC_DEFINE(USE_ICONV_OPEN, 1, [Define to 1 if you want rsync to make use of iconv_open()])
 824 fi
 825
 826 AC_ARG_ENABLE(iconv,
 827     AS_HELP_STRING([--disable-iconv],[disable rsync's --iconv option]),
 828     [], [enable_iconv=$enable_iconv_open])
 829 AH_TEMPLATE([ICONV_OPTION],
 830 [Define if you want the --iconv option.  Specifying a value will set the
 831 default iconv setting (a NULL means no --iconv processing by default).])
 832 if test x"$enable_iconv" != x"no"; then
 833         if test x"$enable_iconv" = x"yes"; then
 834                 AC_DEFINE(ICONV_OPTION, NULL)
 835         else
 836                 AC_DEFINE_UNQUOTED(ICONV_OPTION, "$enable_iconv")
 837         fi
 838         AC_DEFINE(UTF8_CHARSET, "UTF-8", [String to pass to iconv() for the UTF-8 charset.])
 839 fi
 840
 841 AC_CACHE_CHECK([whether chown() modifies symlinks],rsync_cv_chown_modifies_symlink,[
 842   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 843 #if HAVE_UNISTD_H
 844 # include <unistd.h>
 845 #endif
 846 #include <stdlib.h>
 847 #include <errno.h>
 848 int main(void) {
 849         char const *dangling_symlink = "conftest.dangle";
 850         unlink(dangling_symlink);
 851         if (symlink("conftest.no-such", dangling_symlink) < 0) abort();
 852         if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) return 1;
 853         return 0;
 854     }]])],[rsync_cv_chown_modifies_symlink=yes],[rsync_cv_chown_modifies_symlink=no],[rsync_cv_chown_modifies_symlink=no])])
 855 if test $rsync_cv_chown_modifies_symlink = yes; then
 856   AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define to 1 if chown modifies symlinks.])
 857 fi
 858
 859 AC_CACHE_CHECK([whether link() can hard-link symlinks],rsync_cv_can_hardlink_symlink,[
 860   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 861 #if HAVE_UNISTD_H
 862 # include <unistd.h>
 863 #endif
 864 #include <stdlib.h>
 865 #include <errno.h>
 866 #define FILENAME "conftest.dangle"
 867 int main(void) {
 868         unlink(FILENAME);
 869         if (symlink("conftest.no-such", FILENAME) < 0) abort();
 870         unlink(FILENAME "2");
 871         if (link(FILENAME, FILENAME "2") < 0) return 1;
 872         return 0;
 873     }]])],[rsync_cv_can_hardlink_symlink=yes],[rsync_cv_can_hardlink_symlink=no],[rsync_cv_can_hardlink_symlink=no])])
 874 if test $rsync_cv_can_hardlink_symlink = yes; then
 875   AC_DEFINE(CAN_HARDLINK_SYMLINK, 1, [Define to 1 if link() can hard-link symlinks.])
 876 fi
 877
 878 AC_CACHE_CHECK([whether link() can hard-link special files],rsync_cv_can_hardlink_special,[
 879   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 880 #if HAVE_UNISTD_H
 881 # include <unistd.h>
 882 #endif
 883 #ifdef HAVE_SYS_STAT_H
 884 #include <sys/stat.h>
 885 #endif
 886 #include <stdlib.h>
 887 #include <errno.h>
 888 #define FILENAME "conftest.fifi"
 889 int main(void) {
 890         unlink(FILENAME);
 891         if (mkfifo(FILENAME, 0777) < 0) abort();
 892         unlink(FILENAME "2");
 893         if (link(FILENAME, FILENAME "2") < 0) return 1;
 894         return 0;
 895     }]])],[rsync_cv_can_hardlink_special=yes],[rsync_cv_can_hardlink_special=no],[rsync_cv_can_hardlink_special=no])])
 896 if test $rsync_cv_can_hardlink_special = yes; then
 897     AC_DEFINE(CAN_HARDLINK_SPECIAL, 1, [Define to 1 if link() can hard-link special files.])
 898 fi
 899
 900 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
 901 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 902 #include <sys/types.h>
 903 #include <sys/socket.h>
 904
 905 int main(void) {
 906        int fd[2];
 907        return (socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1;
 908 }]])],[rsync_cv_HAVE_SOCKETPAIR=yes],[rsync_cv_HAVE_SOCKETPAIR=no],[rsync_cv_HAVE_SOCKETPAIR=cross])])
 909 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
 910     AC_DEFINE(HAVE_SOCKETPAIR, 1, [Define to 1 if you have the "socketpair" function])
 911 fi
 912
 913 AC_REPLACE_FUNCS([getpass])
 914
 915 if test x"$with_included_popt" != x"yes"; then
 916     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
 917 fi
 918 if test x"$ac_cv_header_popt_popt_h" = x"yes"; then
 919     # If the system has /usr/include/popt/popt.h, we enable the
 920     # included popt because an attempt to "#include <popt/popt.h>"
 921     # would use our included header file anyway (due to -I.), and
 922     # might conflict with the system popt.
 923     with_included_popt=yes
 924 elif test x"$ac_cv_header_popt_h" != x"yes"; then
 925     with_included_popt=yes
 926 fi
 927
 928 AC_MSG_CHECKING([whether to use included libpopt])
 929 if test x"$with_included_popt" = x"yes"; then
 930     AC_MSG_RESULT($srcdir/popt)
 931     BUILD_POPT='$(popt_OBJS)'
 932     CFLAGS="-I$srcdir/popt $CFLAGS"
 933     if test x"$ALLOCA" != x
 934     then
 935         # this can be removed when/if we add an included alloca.c;
 936         #  see autoconf documentation on AC_FUNC_ALLOCA
 937         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
 938     fi
 939 else
 940     AC_MSG_RESULT(no)
 941 fi
 942
 943 # We default to using our zlib unless --with-included-zlib=no is given.
 944 if test x"$with_included_zlib" != x"no"; then
 945     with_included_zlib=yes
 946 elif test x"$ac_cv_header_zlib_h" != x"yes"; then
 947     with_included_zlib=yes
 948 fi
 949 if test x"$with_included_zlib" != x"yes"; then
 950     AC_CHECK_LIB(z, deflateParams, , [with_included_zlib=yes])
 951 fi
 952
 953 AC_MSG_CHECKING([whether to use included zlib])
 954 if test x"$with_included_zlib" = x"yes"; then
 955     AC_MSG_RESULT($srcdir/zlib)
 956     BUILD_ZLIB='$(zlib_OBJS)'
 957     CFLAGS="-I$srcdir/zlib $CFLAGS"
 958 else
 959     AC_DEFINE(EXTERNAL_ZLIB, 1, [Define to 1 if using external zlib])
 960     AC_MSG_RESULT(no)
 961 fi
 962
 963 AC_CACHE_CHECK([for unsigned char],rsync_cv_SIGNED_CHAR_OK,[
 964 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[signed char *s = ""]])],[rsync_cv_SIGNED_CHAR_OK=yes],[rsync_cv_SIGNED_CHAR_OK=no])])
 965 if test x"$rsync_cv_SIGNED_CHAR_OK" = x"yes"; then
 966     AC_DEFINE(SIGNED_CHAR_OK, 1, [Define to 1 if "signed char" is a valid type])
 967 fi
 968
 969 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
 970 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <sys/types.h>
 971 #include <dirent.h>
 972 int main(void) { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
 973 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
 974 di->d_name[0] == 0) return 0; return 1;} ]])],[rsync_cv_HAVE_BROKEN_READDIR=yes],[rsync_cv_HAVE_BROKEN_READDIR=no],[rsync_cv_HAVE_BROKEN_READDIR=cross])])
 975 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
 976     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [Define to 1 if readdir() is broken])
 977 fi
 978
 979 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_STRUCT_UTIMBUF,[
 980 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 981 #include <utime.h>]], [[struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; return utime("foo.c",&tbuf);]])],[rsync_cv_HAVE_STRUCT_UTIMBUF=yes],[rsync_cv_HAVE_STRUCT_UTIMBUF=no])])
 982 if test x"$rsync_cv_HAVE_STRUCT_UTIMBUF" = x"yes"; then
 983     AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if you have the "struct utimbuf" type])
 984 fi
 985
 986 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
 987 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/time.h>
 988 #include <unistd.h>]], [[struct timeval tv; return gettimeofday(&tv, NULL);]])],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=no])])
 989 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then
 990     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [Define to 1 if gettimeofday() takes a time-zone arg])
 991 fi
 992
 993 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
 994 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 995 #include <sys/types.h>
 996 #include <stdarg.h>
 997 #include <stdio.h>
 998 #include <stdlib.h>
 999 #include <string.h>
1000 void foo(const char *format, ...) {
1001        va_list ap;
1002        int len;
1003        static char buf[] = "12345678901234567890";
1004
1005        va_start(ap, format);
1006        len = vsnprintf(0, 0, format, ap);
1007        va_end(ap);
1008        if (len != 5) exit(1);
1009
1010        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
1011 }
1012 int main(void) { foo("hello"); return 0; }
1013 ]])],[rsync_cv_HAVE_C99_VSNPRINTF=yes],[rsync_cv_HAVE_C99_VSNPRINTF=no],[rsync_cv_HAVE_C99_VSNPRINTF=cross])])
1014 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
1015     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [Define to 1 if vsprintf has a C99-compatible return value])
1016 fi
1017
1018
1019 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
1020 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1021 #include <sys/types.h>
1022 #include <sys/stat.h>
1023 #include <unistd.h>
1024 int main(void) {
1025   struct stat st;
1026   char tpl[20]="/tmp/test.XXXXXX";
1027   int fd = mkstemp(tpl);
1028   if (fd == -1) return 1;
1029   unlink(tpl);
1030   if (fstat(fd, &st) != 0) return 1;
1031   if ((st.st_mode & 0777) != 0600) return 1;
1032   return 0;
1033 }]])],[rsync_cv_HAVE_SECURE_MKSTEMP=yes],[rsync_cv_HAVE_SECURE_MKSTEMP=no],[rsync_cv_HAVE_SECURE_MKSTEMP=cross])])
1034 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
1035     case $host_os in
1036     hpux*)
1037         dnl HP-UX has a broken mkstemp() implementation they refuse to fix,
1038         dnl so we noisily skip using it.  See HP change request JAGaf34426
1039         dnl for details. (sbonds)
1040         AC_MSG_WARN(Skipping broken HP-UX mkstemp() -- using mktemp() instead)
1041         ;;
1042     *)
1043         AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [Define to 1 if mkstemp() is available and works right])
1044         ;;
1045     esac
1046 fi
1047
1048
1049 AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[
1050 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1051 #include <stdio.h>
1052 #include <sys/stat.h>
1053 #include <errno.h>
1054 #if HAVE_UNISTD_H
1055 # include <unistd.h>
1056 #endif
1057 int main(void) { int rc, ec; char *fn = "fifo-test";
1058 unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn);
1059 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
1060 return 0;}]])],[rsync_cv_MKNOD_CREATES_FIFOS=yes],[rsync_cv_MKNOD_CREATES_FIFOS=no],[rsync_cv_MKNOD_CREATES_FIFOS=cross])])
1061 if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then
1062     AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.])
1063 fi
1064
1065 AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[
1066 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1067 #include <stdio.h>
1068 #include <sys/stat.h>
1069 #include <errno.h>
1070 #if HAVE_UNISTD_H
1071 # include <unistd.h>
1072 #endif
1073 int main(void) { int rc, ec; char *fn = "sock-test";
1074 unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn);
1075 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
1076 return 0;}]])],[rsync_cv_MKNOD_CREATES_SOCKETS=yes],[rsync_cv_MKNOD_CREATES_SOCKETS=no],[rsync_cv_MKNOD_CREATES_SOCKETS=cross])])
1077 if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then
1078     AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.])
1079 fi
1080
1081 #
1082 # The following test was mostly taken from the tcl/tk plus patches
1083 #
1084 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
1085 rm -rf conftest*
1086 cat > conftest.$ac_ext <<EOF
1087 int main(void) { return 0; }
1088 EOF
1089 ${CC-cc} -c -o conftest..o conftest.$ac_ext
1090 if test -f conftest..o; then
1091     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
1092 else
1093     rsync_cv_DASHC_WORKS_WITH_DASHO=no
1094 fi
1095 rm -rf conftest*
1096 ])
1097 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
1098     OBJ_SAVE="#"
1099     OBJ_RESTORE="#"
1100     CC_SHOBJ_FLAG='-o $@'
1101 else
1102     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
1103     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
1104     CC_SHOBJ_FLAG=""
1105 fi
1106
1107 AC_SUBST(OBJ_SAVE)
1108 AC_SUBST(OBJ_RESTORE)
1109 AC_SUBST(CC_SHOBJ_FLAG)
1110 AC_SUBST(BUILD_POPT)
1111 AC_SUBST(BUILD_ZLIB)
1112 AC_SUBST(MAKE_MAN)
1113
1114 AC_CHECK_FUNCS(_acl __acl _facl __facl)
1115 #################################################
1116 # check for ACL support
1117
1118 AC_MSG_CHECKING([whether to support ACLs])
1119 AC_ARG_ENABLE(acl-support,
1120         AS_HELP_STRING([--disable-acl-support],[disable ACL support]))
1121
1122 if test x"$enable_acl_support" = x"no"; then
1123     AC_MSG_RESULT(no)
1124 else
1125     case "$host_os" in
1126     *sysv5*)
1127         AC_MSG_RESULT(Using UnixWare ACLs)
1128         AC_DEFINE(HAVE_UNIXWARE_ACLS, 1, [true if you have UnixWare ACLs])
1129         AC_DEFINE(SUPPORT_ACLS, 1, [Define to 1 to add support for ACLs])
1130         ;;
1131     solaris*)
1132         AC_MSG_RESULT(Using solaris ACLs)
1133         AC_DEFINE(HAVE_SOLARIS_ACLS, 1, [true if you have solaris ACLs])
1134         AC_DEFINE(SUPPORT_ACLS, 1)
1135         ;;
1136     *hpux*)
1137         AC_MSG_RESULT(Using HPUX ACLs)
1138         AC_DEFINE(HAVE_HPUX_ACLS, 1, [true if you have HPUX ACLs])
1139         AC_DEFINE(SUPPORT_ACLS, 1)
1140         ;;
1141     *irix*)
1142         AC_MSG_RESULT(Using IRIX ACLs)
1143         AC_DEFINE(HAVE_IRIX_ACLS, 1, [true if you have IRIX ACLs])
1144         AC_DEFINE(SUPPORT_ACLS, 1)
1145         ;;
1146     *aix*)
1147         AC_MSG_RESULT(Using AIX ACLs)
1148         AC_DEFINE(HAVE_AIX_ACLS, 1, [true if you have AIX ACLs])
1149         AC_DEFINE(SUPPORT_ACLS, 1)
1150         ;;
1151     *osf*)
1152         AC_MSG_RESULT(Using Tru64 ACLs)
1153         AC_DEFINE(HAVE_TRU64_ACLS, 1, [true if you have Tru64 ACLs])
1154         AC_DEFINE(SUPPORT_ACLS, 1)
1155         LIBS="$LIBS -lpacl"
1156         ;;
1157     darwin*)
1158         AC_MSG_RESULT(Using OS X ACLs)
1159         AC_DEFINE(HAVE_OSX_ACLS, 1, [true if you have Mac OS X ACLs])
1160         AC_DEFINE(SUPPORT_ACLS, 1)
1161         ;;
1162     *)
1163         AC_MSG_RESULT(running tests:)
1164         AC_CHECK_LIB(acl,acl_get_file)
1165         AC_CACHE_CHECK([for ACL support],samba_cv_HAVE_POSIX_ACLS,[
1166             AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1167 #include <sys/acl.h>]], [[ acl_t acl; int entry_id; acl_entry_t *entry_p; return acl_get_entry( acl, entry_id, entry_p);]])],[samba_cv_HAVE_POSIX_ACLS=yes],[samba_cv_HAVE_POSIX_ACLS=no])])
1168         AC_MSG_CHECKING(ACL test results)
1169         if test x"$samba_cv_HAVE_POSIX_ACLS" = x"yes"; then
1170             AC_MSG_RESULT(Using posix ACLs)
1171             AC_DEFINE(HAVE_POSIX_ACLS, 1, [true if you have posix ACLs])
1172             AC_DEFINE(SUPPORT_ACLS, 1)
1173             AC_CACHE_CHECK([for acl_get_perm_np],samba_cv_HAVE_ACL_GET_PERM_NP,[
1174                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1175 #include <sys/acl.h>]], [[ acl_permset_t permset_d; acl_perm_t perm; return acl_get_perm_np( permset_d, perm);]])],[samba_cv_HAVE_ACL_GET_PERM_NP=yes],[samba_cv_HAVE_ACL_GET_PERM_NP=no])])
1176             if test x"$samba_cv_HAVE_ACL_GET_PERM_NP" = x"yes"; then
1177                 AC_DEFINE(HAVE_ACL_GET_PERM_NP, 1, [true if you have acl_get_perm_np])
1178             fi
1179         else
1180             if test x"$enable_acl_support" = x"yes"; then
1181                 AC_MSG_ERROR(Failed to find ACL support)
1182             else
1183                 AC_MSG_RESULT(No ACL support found)
1184             fi
1185         fi
1186         ;;
1187     esac
1188 fi
1189
1190 #################################################
1191 # check for extended attribute support
1192 AC_MSG_CHECKING(whether to support extended attributes)
1193 AC_ARG_ENABLE(xattr-support,
1194     AS_HELP_STRING([--disable-xattr-support],[disable extended attributes]),
1195     [], [case "$ac_cv_func_getxattr$ac_cv_func_extattr_get_link$ac_cv_func_attropen" in
1196         *yes*) enable_xattr_support=maybe ;;
1197         *) enable_xattr_support=no ;;
1198         esac])
1199 AH_TEMPLATE([SUPPORT_XATTRS],
1200 [Define to 1 to add support for extended attributes])
1201 if test x"$enable_xattr_support" = x"no"; then
1202     AC_MSG_RESULT(no)
1203 else
1204     case "$host_os" in
1205     *linux*|*netbsd*)
1206         AC_MSG_RESULT(Using Linux xattrs)
1207         AC_DEFINE(HAVE_LINUX_XATTRS, 1, [True if you have Linux xattrs (or equivalent)])
1208         AC_DEFINE(SUPPORT_XATTRS, 1)
1209         AC_DEFINE(NO_SYMLINK_USER_XATTRS, 1, [True if symlinks do not support user xattrs])
1210         AC_CHECK_LIB(attr,getxattr)
1211         ;;
1212     darwin*)
1213         AC_MSG_RESULT(Using OS X xattrs)
1214         AC_DEFINE(HAVE_OSX_XATTRS, 1, [True if you have Mac OS X xattrs])
1215         AC_DEFINE(SUPPORT_XATTRS, 1)
1216         AC_DEFINE(NO_DEVICE_XATTRS, 1, [True if device files do not support xattrs])
1217         AC_DEFINE(NO_SPECIAL_XATTRS, 1, [True if special files do not support xattrs])
1218         ;;
1219     freebsd*)
1220         AC_MSG_RESULT(Using FreeBSD extattrs)
1221         AC_DEFINE(HAVE_FREEBSD_XATTRS, 1, [True if you have FreeBSD xattrs])
1222         AC_DEFINE(SUPPORT_XATTRS, 1)
1223         ;;
1224     solaris*)
1225         AC_MSG_RESULT(Using Solaris xattrs)
1226         AC_DEFINE(HAVE_SOLARIS_XATTRS, 1, [True if you have Solaris xattrs])
1227         AC_DEFINE(SUPPORT_XATTRS, 1)
1228         AC_DEFINE(NO_SYMLINK_XATTRS, 1, [True if symlinks do not support xattrs])
1229         ;;
1230     *)
1231         if test x"$enable_xattr_support" = x"yes"; then
1232             AC_MSG_ERROR(Failed to find extended attribute support)
1233         else
1234             AC_MSG_RESULT(No extended attribute support found)
1235         fi
1236         ;;
1237     esac
1238 fi
1239
1240 if test x"$enable_acl_support" = x"no" -o x"$enable_xattr_support" = x"no" -o x"$enable_iconv" = x"no"; then
1241     AC_MSG_CHECKING([whether $CC supports -Wno-unused-parameter])
1242     OLD_CFLAGS="$CFLAGS"
1243     CFLAGS="$CFLAGS -Wno-unused-parameter"
1244     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>]], [[printf("hello\n");]])],[rsync_warn_flag=yes],[rsync_warn_flag=no])
1245     AC_MSG_RESULT([$rsync_warn_flag])
1246     if test x"$rsync_warn_flag" = x"no"; then
1247         CFLAGS="$OLD_CFLAGS"
1248     fi
1249 fi
1250
1251 case "$CC" in
1252 ' checker'*|checker*)
1253     AC_DEFINE(FORCE_FD_ZERO_MEMSET, 1, [Used to make "checker" understand that FD_ZERO() clears memory.])
1254     ;;
1255 esac
1256
1257 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
1258 AC_OUTPUT
1259
1260 AC_MSG_RESULT()
1261 AC_MSG_RESULT([    rsync ${RSYNC_VERSION} configuration successful])
1262 AC_MSG_RESULT()