configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([rsync],[ ],[https://rsync.samba.org/bug-tracking.html])
   4
   5 AC_C_BIGENDIAN
   6 AC_HEADER_DIRENT
   7 AC_HEADER_TIME
   8 AC_HEADER_SYS_WAIT
   9 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \
  10     unistd.h utime.h compat.h sys/param.h ctype.h sys/wait.h sys/stat.h \
  11     sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h grp.h \
  12     sys/un.h sys/attr.h arpa/inet.h arpa/nameser.h locale.h sys/types.h \
  13     netdb.h malloc.h float.h limits.h iconv.h libcharset.h langinfo.h mcheck.h \
  14     sys/acl.h acl/libacl.h attr/xattr.h sys/xattr.h sys/extattr.h dl.h \
  15     popt.h popt/popt.h linux/falloc.h netinet/in_systm.h netgroup.h \
  16     zlib.h xxhash.h openssl/md4.h openssl/md5.h zstd.h lz4.h sys/file.h \
  17     bsd/string.h)
  18 AC_CHECK_HEADERS([netinet/ip.h], [], [], [[#include <netinet/in.h>]])
  19 AC_HEADER_MAJOR_FIXED
  20
  21 AC_CONFIG_MACRO_DIR([m4])
  22 AC_CONFIG_SRCDIR([byteorder.h])
  23 AC_CONFIG_HEADER(config.h)
  24 AC_PREREQ([2.69])
  25
  26 PACKAGE_VERSION=`sed -n 's/.*RSYNC_VERSION.*"\(.*\)".*/\1/p' <$srcdir/version.h`
  27
  28 AC_MSG_NOTICE([Configuring rsync $PACKAGE_VERSION])
  29
  30 LDFLAGS=${LDFLAGS-""}
  31
  32 AC_CANONICAL_HOST
  33
  34 dnl define the directory for replacement function since AC_LIBOBJ does not
  35 dnl officially support subdirs and fails with automake
  36 AC_CONFIG_LIBOBJ_DIR([lib])
  37
  38 # We must decide this before testing the compiler.
  39
  40 # Please allow this to default to yes, so that your users have more
  41 # chance of getting a useful stack trace if problems occur.
  42
  43 AC_MSG_CHECKING([whether to include debugging symbols])
  44 AC_ARG_ENABLE(debug,
  45         AS_HELP_STRING([--disable-debug],[disable to omit debugging symbols and features]))
  46
  47 if test x"$enable_debug" = x"no"; then
  48     AC_MSG_RESULT(no)
  49     ac_cv_prog_cc_g=no
  50 else
  51     AC_MSG_RESULT([yes])
  52     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  53     # leave ac_cv_prog_cc_g alone; AC_PROG_CC will try to include -g if it can
  54 fi
  55
  56 dnl Checks for programs.
  57 AC_PROG_CC
  58 AC_PROG_CPP
  59 AC_PROG_CXX
  60 AC_PROG_AWK
  61 AC_PROG_EGREP
  62 AC_PROG_INSTALL
  63 AC_PROG_MKDIR_P
  64 AC_PROG_CC_STDC
  65 AC_SUBST(SHELL)
  66 AC_PATH_PROG([PERL], [perl])
  67 AC_PATH_PROG([PYTHON3], [python3])
  68
  69 AC_DEFINE([_GNU_SOURCE], 1,
  70           [Define _GNU_SOURCE so that we get all necessary prototypes])
  71
  72 if test x"$ac_cv_prog_cc_stdc" = x"no"; then
  73         AC_MSG_WARN([rsync requires an ANSI C compiler and you do not seem to have one])
  74 fi
  75
  76 no_lib=''
  77 err_msg=''
  78 nl='
  79 '
  80
  81 AC_ARG_ENABLE(profile,
  82         AS_HELP_STRING([--enable-profile],[enable to turn on CPU profiling]))
  83 if test x"$enable_profile" = x"yes"; then
  84         CFLAGS="$CFLAGS -pg"
  85 fi
  86
  87 AC_MSG_CHECKING([if md2man can create manpages])
  88 if test x"$ac_cv_path_PYTHON3" = x; then
  89     AC_MSG_RESULT(no - python3 not found)
  90     md2man_works=no
  91 else
  92     md2man_out=`"$srcdir/md2man" --test "$srcdir/rsync-ssl.1.md" 2>&1`
  93     if test $? = 0; then
  94         AC_MSG_RESULT(yes)
  95         md2man_works=yes
  96     else
  97         AC_MSG_RESULT(no)
  98         md2man_works=no
  99         echo "$md2man_out"
 100     fi
 101 fi
 102
 103 AC_MSG_CHECKING([if we require man-page building])
 104 AC_ARG_ENABLE([md2man],
 105         AS_HELP_STRING([--disable-md2man],[disable to omit manpage creation]))
 106 if test x"$enable_md2man" != x"no"; then
 107     if test -f "$srcdir/rsync.1"; then
 108         AC_MSG_RESULT(optional)
 109     else
 110         AC_MSG_RESULT(required)
 111         if test x"$md2man_works" = x"no"; then
 112             err_msg="$err_msg$nl- You need python3 and either the cmarkgfm OR commonmark python3 lib in order"
 113             err_msg="$err_msg$nl  to build manpages based on the git source (manpages are included in the"
 114             err_msg="$err_msg$nl  official release tar files)."
 115             no_lib="$no_lib md2man"
 116         fi
 117     fi
 118     MAKE_MAN=man
 119 else
 120     AC_MSG_RESULT(no)
 121 fi
 122
 123 # Specifically, this turns on panic_action handling.
 124 AC_ARG_ENABLE(maintainer-mode,
 125         AS_HELP_STRING([--enable-maintainer-mode],[enable to turn on extra debug features]))
 126 if test x"$enable_maintainer_mode" = x"yes"; then
 127         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
 128 fi
 129
 130 # This is needed for our included version of popt.  Kind of silly, but
 131 # I don't want our version too far out of sync.
 132 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
 133
 134 # If GCC, turn on warnings.
 135 if test x"$GCC" = x"yes"; then
 136         CFLAGS="$CFLAGS -Wall -W"
 137 fi
 138
 139 AC_ARG_WITH(rrsync,
 140         AS_HELP_STRING([--with-rrsync],[also install the rrsync script and its manpage]))
 141 if test x"$with_rrsync" != x"yes"; then
 142     with_rrsync=no
 143 else
 144     MAKE_RRSYNC='rrsync'
 145     MAKE_RRSYNC_1='rrsync.1'
 146     GEN_RRSYNC='rrsync.1 rrsync.1.html'
 147 fi
 148 AC_SUBST(with_rrsync)
 149
 150 AC_ARG_WITH(included-popt,
 151         AS_HELP_STRING([--with-included-popt],[use bundled popt library, not from system]))
 152
 153 AC_ARG_WITH(included-zlib,
 154         AS_HELP_STRING([--with-included-zlib],[use bundled zlib library, not from system]))
 155
 156 AC_ARG_WITH(secluded-args,
 157         AS_HELP_STRING([--with-secluded-args],[make --secluded-args option the default]))
 158 if test x"$with_secluded_args" = x"yes"; then
 159         AC_DEFINE_UNQUOTED(RSYNC_USE_SECLUDED_ARGS, 1, [Define to 1 if --secluded-args should be the default])
 160 fi
 161
 162 AC_ARG_WITH(rsync-path,
 163         AS_HELP_STRING([--with-rsync-path=PATH],[set default --rsync-path to PATH (default: rsync)]),
 164         [ RSYNC_PATH="$with_rsync_path" ],
 165         [ RSYNC_PATH="rsync" ])
 166
 167 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
 168
 169 AC_ARG_WITH(rsyncd-conf,
 170         AS_HELP_STRING([--with-rsyncd-conf=PATH],[set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]),
 171         [ if test ! -z "$with_rsyncd_conf" ; then
 172                 case $with_rsyncd_conf in
 173                         yes|no)
 174                                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 175                                 ;;
 176                         /*)
 177                                 RSYNCD_SYSCONF="$with_rsyncd_conf"
 178                                 ;;
 179                         *)
 180                                 AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH)
 181                                 ;;
 182                 esac
 183         else
 184                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 185         fi ],
 186         [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ])
 187
 188 AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server])
 189
 190 AC_ARG_WITH(rsh,
 191         AS_HELP_STRING([--with-rsh=CMD],[set remote shell command to CMD (default: ssh)]))
 192
 193 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
 194 if test x$HAVE_REMSH = x1; then
 195         AC_DEFINE(HAVE_REMSH, 1, [Define to 1 if remote shell is remsh, not rsh])
 196 fi
 197
 198 if test x"$with_rsh" != x; then
 199         RSYNC_RSH="$with_rsh"
 200 else
 201         RSYNC_RSH="ssh"
 202 fi
 203 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
 204
 205 # Some programs on solaris are only found in /usr/xpg4/bin (or work better than others versions).
 206 AC_PATH_PROG(SHELL_PATH, sh, /bin/sh, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 207 AC_PATH_PROG(FAKEROOT_PATH, fakeroot, /usr/bin/fakeroot, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 208
 209 AC_ARG_WITH(nobody-user,
 210     AS_HELP_STRING([--with-nobody-user=USER],[set the default unprivileged user (default nobody)]),
 211     [ NOBODY_USER="$with_nobody_user" ],
 212     [ NOBODY_USER="nobody" ])
 213
 214 AC_ARG_WITH(nobody-group,
 215     AS_HELP_STRING([--with-nobody-group=GROUP],[set the default unprivileged group (default nobody or nogroup)]),
 216     [ NOBODY_GROUP="$with_nobody_group" ])
 217
 218 if test x"$with_nobody_group" = x; then
 219     AC_MSG_CHECKING([the group for user "nobody"])
 220     if grep '^nobody:' /etc/group >/dev/null 2>&1; then
 221         NOBODY_GROUP=nobody
 222     elif grep '^nogroup:' /etc/group >/dev/null 2>&1; then
 223         NOBODY_GROUP=nogroup
 224     else
 225         NOBODY_GROUP=nobody # test for others?
 226     fi
 227     AC_MSG_RESULT($NOBODY_GROUP)
 228 fi
 229
 230 AC_DEFINE_UNQUOTED(NOBODY_USER, "$NOBODY_USER", [unprivileged user--e.g. nobody])
 231 AC_DEFINE_UNQUOTED(NOBODY_GROUP, "$NOBODY_GROUP", [unprivileged group for unprivileged user])
 232
 233 # rolling-checksum SIMD optimizations
 234 ROLL_SIMD=
 235
 236 AC_MSG_CHECKING([whether to enable rolling-checksum SIMD optimizations])
 237 AC_ARG_ENABLE(roll-simd,
 238     AS_HELP_STRING([--enable-roll-simd],[enable/disable to control rolling-checksum SIMD optimizations (requires c++)]))
 239
 240 # Clag is crashing with -g -O2, so we'll get rid of -g for now.
 241 CXXFLAGS=`echo "$CXXFLAGS" | sed 's/-g //'`
 242 m4_define(SIMD_X86_64_TEST, [[#include <stdio.h>
 243 #if HAVE_STDLIB_H
 244 #include <stdlib.h>
 245 #endif
 246 #include <immintrin.h>
 247 __attribute__ ((target("default"))) int test_ssse3(int x) { return x; }
 248 __attribute__ ((target("default"))) int test_sse2(int x) { return x; }
 249 __attribute__ ((target("default"))) int test_avx2(int x) { return x; }
 250 __attribute__ ((target("ssse3"))) int test_ssse3(int x) { return x; }
 251 __attribute__ ((target("sse2"))) int test_sse2(int x) { return x; }
 252 __attribute__ ((target("avx2"))) int test_avx2(int x) { return x; }
 253 typedef long long __m128i_u __attribute__((__vector_size__(16), __may_alias__, __aligned__(1)));
 254 typedef long long __m256i_u __attribute__((__vector_size__(32), __may_alias__, __aligned__(1)));
 255 __attribute__ ((target("default"))) void more_testing(char* buf, int len) { }
 256 __attribute__ ((target("ssse3"))) void more_testing(char* buf, int len)
 257 {
 258     int i;
 259     for (i = 0; i < (len-32); i+=32) {
 260         __m128i in8_1, in8_2;
 261         in8_1 = _mm_lddqu_si128((__m128i_u*)&buf[i]);
 262         in8_2 = _mm_lddqu_si128((__m128i_u*)&buf[i + 16]);
 263     }
 264 }
 265 ]])
 266
 267 if test x"$enable_roll_simd" = x""; then
 268     case "$host_os" in
 269         *linux*) ;;
 270         *) enable_roll_simd=no ;;
 271     esac
 272 fi
 273
 274 if test x"$enable_roll_simd" != x"no"; then
 275     # For x86-64 SIMD, g++ >=5 or clang++ >=7 is required
 276     if test x"$host_cpu" = x"x86_64" || test x"$host_cpu" = x"amd64"; then
 277         AC_LANG(C++)
 278         if test x"$host" = x"$build"; then
 279             AC_RUN_IFELSE([AC_LANG_PROGRAM([SIMD_X86_64_TEST],[[if (test_ssse3(42) != 42 || test_sse2(42) != 42 || test_avx2(42) != 42) exit(1);]])],
 280                 [CXX_OK=yes],[CXX_OK=no])
 281         else
 282             AC_COMPILE_IFELSE([AC_LANG_PROGRAM([SIMD_X86_64_TEST])],[CXX_OK=yes],[CXX_OK=no])
 283         fi
 284         AC_LANG(C)
 285         if test x"$CXX_OK" = x"yes"; then
 286             # AC_MSG_RESULT() is called below.
 287             ROLL_SIMD="$host_cpu"
 288         elif test x"$enable_roll_simd" = x"yes"; then
 289             AC_MSG_RESULT(error)
 290             AC_MSG_ERROR(The rolling-checksum SIMD compilation test failed.
 291 Omit --enable-roll-simd to continue without it.)
 292         fi
 293     elif test x"$enable_roll_simd" = x"yes"; then
 294         AC_MSG_RESULT(unavailable)
 295         AC_MSG_ERROR(The rolling-checksum SIMD optimizations are currently x86_64|amd64 only.
 296 Omit --enable-roll-simd to continue without it.)
 297     fi
 298 fi
 299
 300 if test x"$ROLL_SIMD" != x""; then
 301     AC_MSG_RESULT([yes ($ROLL_SIMD)])
 302     AC_DEFINE(USE_ROLL_SIMD, 1, [Define to 1 to enable rolling-checksum SIMD optimizations])
 303     ROLL_SIMD='$(ROLL_SIMD_'"$ROLL_SIMD)"
 304     # We only use c++ for its target attribute dispatching, disable unneeded bulky features
 305     CXXFLAGS="$CXXFLAGS -fno-exceptions -fno-rtti"
 306     # Apple often has "g++" as a symlink for clang. Try to find out the truth.
 307     CXX_VERSION=`$CXX --version 2>/dev/null | head -n 2`
 308     case "$CXX_VERSION" in
 309     *clang*) CXXFLAGS="$CXXFLAGS -fno-slp-vectorize" ;; # avoid a performance hit
 310     esac
 311 else
 312     AC_MSG_RESULT(no)
 313 fi
 314
 315 AC_SUBST(ROLL_SIMD)
 316
 317 AC_MSG_CHECKING([if assembler accepts noexecstack])
 318 OLD_CFLAGS="$CFLAGS"
 319 CFLAGS="$CFLAGS -Wa,--noexecstack"
 320 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ ]], [[return 0;]])],
 321 [ NOEXECSTACK='-Wa,--noexecstack' ; AC_MSG_RESULT(yes) ],
 322 [ NOEXECSTACK='' ; AC_MSG_RESULT(no) ])
 323 CFLAGS="$OLD_CFLAGS"
 324 AC_SUBST(NOEXECSTACK)
 325
 326 # arrgh. libc in some old debian version screwed up the largefile
 327 # stuff, getting byte range locking wrong
 328 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
 329 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 330 #define _FILE_OFFSET_BITS 64
 331 $ac_includes_default
 332 #ifdef HAVE_FCNTL_H
 333 # include <fcntl.h>
 334 #elif defined HAVE_SYS_FCNTL_H
 335 # include <sys/fcntl.h>
 336 #endif
 337 #ifdef HAVE_SYS_WAIT_H
 338 #include <sys/wait.h>
 339 #endif
 340
 341 int main(void)
 342 {
 343         struct flock lock;
 344         int status;
 345         char tpl[32] = "/tmp/locktest.XXXXXX";
 346         int fd = mkstemp(tpl);
 347         if (fd < 0) {
 348                 strcpy(tpl, "conftest.dat");
 349                 fd = open(tpl, O_CREAT|O_RDWR, 0600);
 350         }
 351
 352         lock.l_type = F_WRLCK;
 353         lock.l_whence = SEEK_SET;
 354         lock.l_start = 0;
 355         lock.l_len = 1;
 356         lock.l_pid = 0;
 357         fcntl(fd,F_SETLK,&lock);
 358         if (fork() == 0) {
 359                 lock.l_start = 1;
 360                 _exit(fcntl(fd,F_SETLK,&lock) == 0);
 361         }
 362         wait(&status);
 363         unlink(tpl);
 364         return WEXITSTATUS(status);
 365 }
 366 ]])],[rsync_cv_HAVE_BROKEN_LARGEFILE=yes],[rsync_cv_HAVE_BROKEN_LARGEFILE=no],[rsync_cv_HAVE_BROKEN_LARGEFILE=cross])])
 367 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
 368    AC_SYS_LARGEFILE
 369 fi
 370
 371 AC_MSG_CHECKING([whether to enable ipv6])
 372 AC_ARG_ENABLE(ipv6,
 373 AS_HELP_STRING([--disable-ipv6],[disable to omit ipv6 support]),
 374 [ case "$enableval" in
 375   no)
 376         AC_MSG_RESULT(no)
 377         ;;
 378   *)    AC_MSG_RESULT(yes)
 379         AC_DEFINE(INET6, 1, [true if you have IPv6])
 380         ;;
 381   esac ],
 382
 383   AC_TRY_RUN([ /* AF_INET6 availability check */
 384 #include <stdlib.h>
 385 #include <sys/types.h>
 386 #include <sys/socket.h>
 387 main()
 388 {
 389    if (socket(AF_INET6, SOCK_STREAM, 0) < 0)
 390      exit(1);
 391    else
 392      exit(0);
 393 }
 394 ],
 395   AC_MSG_RESULT(yes)
 396   AC_DEFINE(INET6, 1, [true if you have IPv6]),
 397   AC_MSG_RESULT(no),
 398   AC_MSG_RESULT(no)
 399 ))
 400
 401 dnl Do you want to disable use of locale functions
 402 AC_ARG_ENABLE([locale],
 403         AS_HELP_STRING([--disable-locale],[disable to omit locale features]))
 404 AH_TEMPLATE([CONFIG_LOCALE],
 405 [Undefine if you do not want locale features.  By default this is defined.])
 406 if test x"$enable_locale" != x"no"; then
 407         AC_DEFINE(CONFIG_LOCALE)
 408 fi
 409
 410 AC_MSG_CHECKING([whether to call shutdown on all sockets])
 411 case $host_os in
 412         *cygwin* ) AC_MSG_RESULT(yes)
 413                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
 414                             [Define to 1 if sockets need to be shutdown])
 415                    ;;
 416                * ) AC_MSG_RESULT(no);;
 417 esac
 418
 419 AC_MSG_CHECKING([whether to enable use of openssl crypto library])
 420 AC_ARG_ENABLE([openssl],
 421         AS_HELP_STRING([--disable-openssl],[disable to omit openssl crypto library]))
 422 AH_TEMPLATE([USE_OPENSSL],
 423 [Undefine if you do not want to use openssl crypto library.  By default this is defined.])
 424 if test x"$enable_openssl" != x"no"; then
 425     if test x"$ac_cv_header_openssl_md4_h" = x"yes" && test x"$ac_cv_header_openssl_md5_h" = x"yes"; then
 426       AC_MSG_RESULT(yes)
 427       AC_SEARCH_LIBS(MD5_Init, crypto,
 428           [AC_DEFINE(USE_OPENSSL)
 429            enable_openssl=yes],
 430           [err_msg="$err_msg$nl- Failed to find MD5_Init function in openssl crypto lib.";
 431            no_lib="$no_lib openssl"])
 432     else
 433         AC_MSG_RESULT(no)
 434         err_msg="$err_msg$nl- Failed to find openssl/md4.h and openssl/md5.h for openssl crypto lib support."
 435         no_lib="$no_lib openssl"
 436     fi
 437     if test x"$enable_md5_asm" != x"yes"; then
 438         enable_md5_asm=no
 439     fi
 440 else
 441     AC_MSG_RESULT(no)
 442 fi
 443
 444 MD5_ASM=
 445
 446 AC_MSG_CHECKING([whether to enable MD5 ASM optimizations])
 447 AC_ARG_ENABLE(md5-asm,
 448     AS_HELP_STRING([--enable-md5-asm],[enable/disable to control MD5 ASM optimizations]))
 449
 450 if test x"$enable_md5_asm" = x""; then
 451     case "$host_os" in
 452         *linux*) ;;
 453         *) enable_md5_asm=no ;;
 454     esac
 455 fi
 456
 457 if test x"$enable_md5_asm" != x"no"; then
 458     if test x"$host_cpu" = x"x86_64" || test x"$host_cpu" = x"amd64"; then
 459         MD5_ASM="$host_cpu"
 460     elif test x"$enable_md5_asm" = x"yes"; then
 461         AC_MSG_RESULT(unavailable)
 462         AC_MSG_ERROR(The ASM optimizations are currently x86_64|amd64 only.
 463 Omit --enable-md5-asm to continue without it.)
 464     fi
 465 fi
 466
 467 if test x"$MD5_ASM" != x""; then
 468     AC_MSG_RESULT([yes ($MD5_ASM)])
 469     AC_DEFINE(USE_MD5_ASM, 1, [Define to 1 to enable MD5 ASM optimizations])
 470     MD5_ASM='$(MD5_ASM_'"$MD5_ASM)"
 471 else
 472     AC_MSG_RESULT(no)
 473 fi
 474
 475 AC_SUBST(MD5_ASM)
 476
 477 ROLL_ASM=
 478
 479 AC_MSG_CHECKING([whether to enable rolling-checksum ASM optimizations])
 480 AC_ARG_ENABLE(roll-asm,
 481     AS_HELP_STRING([--enable-roll-asm],[enable/disable to control rolling-checksum ASM optimizations (requires --enable-roll-simd)]))
 482
 483 if test x"$ROLL_SIMD" = x""; then
 484     enable_roll_asm=no
 485 fi
 486
 487 if test x"$enable_roll_asm" = x"yes"; then
 488     ROLL_ASM="$host_cpu"
 489     AC_MSG_RESULT([yes ($ROLL_ASM)])
 490     AC_DEFINE(USE_ROLL_ASM, 1, [Define to 1 to enable rolling-checksum ASM optimizations (requires --enable-roll-simd)])
 491     ROLL_ASM='$(ROLL_ASM_'"$ROLL_ASM)"
 492 else
 493     AC_MSG_RESULT(no)
 494 fi
 495
 496 AC_SUBST(ROLL_ASM)
 497
 498 AC_MSG_CHECKING([whether to enable xxhash checksum support])
 499 AC_ARG_ENABLE([xxhash],
 500         AS_HELP_STRING([--disable-xxhash],[disable to omit xxhash checksums]))
 501 AH_TEMPLATE([SUPPORT_XXHASH],
 502 [Undefine if you do not want xxhash checksums.  By default this is defined.])
 503 if test x"$enable_xxhash" != x"no"; then
 504     if test x"$ac_cv_header_xxhash_h" = x"yes"; then
 505         AC_MSG_RESULT(yes)
 506         AC_SEARCH_LIBS(XXH64_createState, xxhash,
 507             [AC_DEFINE(SUPPORT_XXHASH)],
 508             [err_msg="$err_msg$nl- Failed to find XXH64_createState function in xxhash lib.";
 509              no_lib="$no_lib xxhash"])
 510     else
 511         AC_MSG_RESULT(no)
 512         err_msg="$err_msg$nl- Failed to find xxhash.h for xxhash checksum support.";
 513         no_lib="$no_lib xxhash"
 514     fi
 515 else
 516     AC_MSG_RESULT(no)
 517 fi
 518
 519 AC_MSG_CHECKING([whether to enable zstd compression])
 520 AC_ARG_ENABLE([zstd],
 521         AC_HELP_STRING([--disable-zstd], [disable to omit zstd compression]))
 522 AH_TEMPLATE([SUPPORT_ZSTD],
 523 [Undefine if you do not want zstd compression.  By default this is defined.])
 524 if test x"$enable_zstd" != x"no"; then
 525     if test x"$ac_cv_header_zstd_h" = x"yes"; then
 526         AC_MSG_RESULT(yes)
 527         AC_SEARCH_LIBS(ZSTD_minCLevel, zstd,
 528             [AC_DEFINE(SUPPORT_ZSTD)],
 529             [err_msg="$err_msg$nl- Failed to find ZSTD_minCLevel function in zstd lib.";
 530              no_lib="$no_lib zstd"])
 531     else
 532         AC_MSG_RESULT(no)
 533         err_msg="$err_msg$nl- Failed to find zstd.h for zstd compression support.";
 534         no_lib="$no_lib zstd"
 535     fi
 536 else
 537     AC_MSG_RESULT(no)
 538 fi
 539
 540 AC_MSG_CHECKING([whether to enable LZ4 compression])
 541 AC_ARG_ENABLE([lz4],
 542         AC_HELP_STRING([--disable-lz4], [disable to omit LZ4 compression]))
 543 AH_TEMPLATE([SUPPORT_LZ4],
 544 [Undefine if you do not want LZ4 compression.  By default this is defined.])
 545 if test x"$enable_lz4" != x"no"; then
 546     if test x"$ac_cv_header_lz4_h" = x"yes"; then
 547         AC_MSG_RESULT(yes)
 548         AC_SEARCH_LIBS(LZ4_compress_default, lz4,
 549             [AC_DEFINE(SUPPORT_LZ4)],
 550             [err_msg="$err_msg$nl- Failed to find LZ4_compress_default function in lz4 lib.";
 551              no_lib="$no_lib lz4"])
 552     else
 553         AC_MSG_RESULT(no)
 554         err_msg="$err_msg$nl- Failed to find lz4.h for lz4 compression support."
 555         no_lib="$no_lib lz4"
 556     fi
 557 else
 558     AC_MSG_RESULT(no)
 559 fi
 560
 561 if test x"$no_lib" != x; then
 562     echo ""
 563     echo "Configure found the following issues:"
 564     echo "$err_msg"
 565     echo ""
 566     echo "See the INSTALL file for hints on how to install the missing libraries and/or"
 567     echo "how to generate (or fetch) manpages:"
 568     echo "    https://github.com/WayneD/rsync/blob/master/INSTALL.md"
 569     echo ""
 570     echo "To disable one or more features, the relevant configure options are:"
 571     for lib in $no_lib; do
 572         echo "    --disable-$lib"
 573     done
 574     echo ""
 575     AC_MSG_ERROR(Aborting configure run)
 576 fi
 577
 578 AC_CACHE_CHECK([if makedev takes 3 args],rsync_cv_MAKEDEV_TAKES_3_ARGS,[
 579 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 580 #ifdef HAVE_SYS_TYPES_H
 581 #include <sys/types.h>
 582 #endif
 583 #ifdef MAJOR_IN_MKDEV
 584 #include <sys/mkdev.h>
 585 # if !defined makedev && (defined mkdev || defined _WIN32 || defined __WIN32__)
 586 #  define makedev mkdev
 587 # endif
 588 #elif defined MAJOR_IN_SYSMACROS
 589 #include <sys/sysmacros.h>
 590 #endif
 591
 592 int main(void)
 593 {
 594         dev_t dev = makedev(0, 5, 7);
 595         if (major(dev) != 5 || minor(dev) != 7)
 596                 return 1;
 597         return 0;
 598 }
 599 ]])],[rsync_cv_MAKEDEV_TAKES_3_ARGS=yes],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no])])
 600 if test x"$rsync_cv_MAKEDEV_TAKES_3_ARGS" = x"yes"; then
 601    AC_DEFINE(MAKEDEV_TAKES_3_ARGS, 1, [Define to 1 if makedev() takes 3 args])
 602 fi
 603
 604 AC_CHECK_SIZEOF(int)
 605 AC_CHECK_SIZEOF(long)
 606 AC_CHECK_SIZEOF(long long)
 607 AC_CHECK_SIZEOF(short)
 608 AC_CHECK_SIZEOF(int16_t)
 609 AC_CHECK_SIZEOF(uint16_t)
 610 AC_CHECK_SIZEOF(int32_t)
 611 AC_CHECK_SIZEOF(uint32_t)
 612 AC_CHECK_SIZEOF(int64_t)
 613 AC_CHECK_SIZEOF(off_t)
 614 AC_CHECK_SIZEOF(off64_t)
 615 AC_CHECK_SIZEOF(time_t)
 616 AC_CHECK_SIZEOF(char*)
 617
 618 AC_C_INLINE
 619
 620 AC_TYPE_LONG_DOUBLE_WIDER
 621 ac_cv_c_long_double=$ac_cv_type_long_double_wider
 622 if test $ac_cv_c_long_double = yes; then
 623   AC_DEFINE([HAVE_LONG_DOUBLE],[1],[Define to 1 if the type `long double' works and has more range or precision than `double'.])
 624 fi
 625
 626 AC_TYPE_UID_T
 627 AC_CHECK_TYPES([mode_t,off_t,size_t,pid_t,id_t])
 628 if test "$cross_compiling" = no; then
 629     AC_TYPE_GETGROUPS
 630 else
 631     AC_DEFINE([GETGROUPS_T],[gid_t],[Define to the type of elements in the array set by `getgroups'. Usually this is either `int' or `gid_t'.])
 632 fi
 633 AC_CHECK_MEMBERS([struct stat.st_rdev,
 634                   struct stat.st_mtimensec,
 635                   struct stat.st_mtimespec.tv_nsec,
 636                   struct stat.st_mtim.tv_nsec],,,[
 637 #ifdef HAVE_SYS_TYPES_H
 638 #include <sys/types.h>
 639 #endif
 640 #ifdef HAVE_SYS_STAT_H
 641 #include <sys/stat.h>
 642 #endif
 643 #ifdef HAVE_UNISTD_H
 644 #include <unistd.h>
 645 #endif])
 646
 647 TYPE_SOCKLEN_T
 648
 649 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 650     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]], [[int i = errno]])],[rsync_cv_errno=yes],[rsync_cv_have_errno_decl=no])])
 651 if test x"$rsync_cv_errno" = x"yes"; then
 652    AC_DEFINE(HAVE_ERRNO_DECL, 1, [Define to 1 if errno is declared in errno.h])
 653 fi
 654
 655 # The following test taken from the cvs sources
 656 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 657 # These need checks to be before checks for any other functions that
 658 #    might be in the same libraries.
 659 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 660 # libsocket.so which has a bad implementation of gethostbyname (it
 661 # only looks in /etc/hosts), so we only look for -lsocket if we need
 662 # it.
 663 AC_CHECK_FUNCS(connect)
 664 if test x"$ac_cv_func_connect" = x"no"; then
 665     case "$LIBS" in
 666     *-lnsl*) ;;
 667     *) AC_CHECK_LIB(nsl_s, printf) ;;
 668     esac
 669     case "$LIBS" in
 670     *-lnsl*) ;;
 671     *) AC_CHECK_LIB(nsl, printf) ;;
 672     esac
 673     case "$LIBS" in
 674     *-lsocket*) ;;
 675     *) AC_CHECK_LIB(socket, connect) ;;
 676     esac
 677     case "$LIBS" in
 678     *-linet*) ;;
 679     *) AC_CHECK_LIB(inet, connect) ;;
 680     esac
 681     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 682     dnl has been cached.
 683     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 684        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 685         # ac_cv_func_connect=yes
 686         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 687         AC_DEFINE(HAVE_CONNECT, 1, [Define to 1 if you have the "connect" function])
 688     fi
 689 fi
 690
 691 AC_SEARCH_LIBS(inet_ntop, resolv)
 692
 693 # For OS X, Solaris, HP-UX, etc.: figure out if -liconv is needed.  We'll
 694 # accept either iconv_open or libiconv_open, since some include files map
 695 # the former to the latter.
 696 AC_SEARCH_LIBS(iconv_open, iconv)
 697 AC_SEARCH_LIBS(libiconv_open, iconv)
 698
 699 AC_MSG_CHECKING([for iconv declaration])
 700 AC_CACHE_VAL(am_cv_proto_iconv, [
 701     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 702 #if HAVE_STDLIB_H
 703 #include <stdlib.h>
 704 #endif
 705 #include <iconv.h>
 706 extern
 707 #ifdef __cplusplus
 708 "C"
 709 #endif
 710 #if defined(__STDC__) || defined(__cplusplus)
 711 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 712 #else
 713 size_t iconv();
 714 #endif
 715 ]], [[]])],[am_cv_proto_iconv_arg1=""],[am_cv_proto_iconv_arg1="const"])
 716       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
 717     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed 's/( /(/'`
 718 AC_MSG_RESULT([$]{ac_t:-
 719          }[$]am_cv_proto_iconv)
 720 AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
 721                    [Define as const if the declaration of iconv() needs const.])
 722
 723 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
 724
 725 AC_REPLACE_FUNCS([inet_ntop inet_pton])
 726
 727 AC_HAVE_TYPE([struct addrinfo], [#include <netdb.h>])
 728 AC_HAVE_TYPE([struct sockaddr_storage], [
 729 #ifdef HAVE_SYS_TYPES_H
 730 #include <sys/types.h>
 731 #endif
 732 #ifdef HAVE_SYS_SOCKET_H
 733 #include <sys/socket.h>
 734 #endif])
 735
 736 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
 737 #   builtin getaddrinfo if one of the defines don't exist
 738 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
 739                rsync_cv_HAVE_GETADDR_DEFINES,[
 740                         AC_EGREP_CPP(yes, [
 741 #ifdef HAVE_SYS_TYPES_H
 742 #include <sys/types.h>
 743 #endif
 744 #ifdef HAVE_SYS_SOCKET_H
 745 #include <sys/socket.h>
 746 #endif
 747 #ifdef HAVE_NETDB_H
 748 #include <netdb.h>
 749 #endif
 750 #ifdef AI_PASSIVE
 751 yes
 752 #endif],
 753                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
 754                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
 755 AS_IF([test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes" && test x"$ac_cv_type_struct_addrinfo" = x"yes"],[
 756         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
 757         # something else so we must include <netdb.h> to get the
 758         # redefinition.
 759         AC_CHECK_FUNCS(getaddrinfo, ,
 760                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
 761                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 762 #ifdef HAVE_SYS_TYPES_H
 763 #include <sys/types.h>
 764 #endif
 765 #ifdef HAVE_SYS_SOCKET_H
 766 #include <sys/socket.h>
 767 #endif
 768 #include <netdb.h>]], [[getaddrinfo(NULL, NULL, NULL, NULL);]])],[AC_MSG_RESULT([yes])
 769                         AC_DEFINE(HAVE_GETADDRINFO, 1,
 770                                 [Define to 1 if you have the "getaddrinfo" function and required types.])],[AC_MSG_RESULT([no])
 771                         AC_LIBOBJ([getaddrinfo])])])
 772     ],[AC_LIBOBJ([getaddrinfo])])
 773
 774 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 775                 [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ],
 776                 [],
 777                 [
 778 #ifdef HAVE_SYS_TYPES_H
 779 #include <sys/types.h>
 780 #endif
 781 #ifdef HAVE_SYS_SOCKET_H
 782 #include <sys/socket.h>
 783 #endif
 784 ])
 785
 786 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
 787                 [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ],
 788                 [],
 789                 [
 790 #ifdef HAVE_SYS_TYPES_H
 791 #include <sys/types.h>
 792 #endif
 793 #ifdef HAVE_SYS_SOCKET_H
 794 #include <sys/socket.h>
 795 #endif
 796 #include <netinet/in.h>
 797 ])
 798
 799 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 800                 [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ],
 801                 [],
 802                 [
 803 #ifdef HAVE_SYS_TYPES_H
 804 #include <sys/types.h>
 805 #endif
 806 #ifdef HAVE_SYS_SOCKET_H
 807 #include <sys/socket.h>
 808 #endif
 809 #include <netinet/in.h>
 810 ])
 811
 812 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
 813                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ],
 814                 [],
 815                 [
 816 #ifdef HAVE_SYS_TYPES_H
 817 #include <sys/types.h>
 818 #endif
 819 #ifdef HAVE_SYS_SOCKET_H
 820 #include <sys/socket.h>
 821 #endif
 822 #include <netinet/in.h>
 823 ])
 824
 825 AC_HAVE_TYPE([struct stat64], [#include <stdio.h>
 826 #if HAVE_SYS_TYPES_H
 827 # include <sys/types.h>
 828 #endif
 829 #if HAVE_SYS_STAT_H
 830 # include <sys/stat.h>
 831 #endif
 832 #if STDC_HEADERS
 833 # include <stdlib.h>
 834 # include <stddef.h>
 835 #else
 836 # if HAVE_STDLIB_H
 837 #  include <stdlib.h>
 838 # endif
 839 #endif
 840 ])
 841
 842 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 843 #
 844 AC_CHECK_FUNCS(strcasecmp)
 845 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 846     AC_CHECK_LIB(resolv, strcasecmp)
 847 fi
 848
 849 AC_CHECK_FUNCS(aclsort)
 850 if test x"$ac_cv_func_aclsort" = x"no"; then
 851     AC_CHECK_LIB(sec, aclsort)
 852 fi
 853
 854 dnl At the moment we don't test for a broken memcmp(), because all we
 855 dnl need to do is test for equality, not comparison, and it seems that
 856 dnl every platform has a memcmp that can do at least that.
 857 dnl AC_FUNC_MEMCMP
 858
 859 AC_FUNC_UTIME_NULL
 860 AC_FUNC_ALLOCA
 861 AC_CHECK_FUNCS(waitpid wait4 getcwd chown chmod lchmod mknod mkfifo \
 862     fchmod fstat ftruncate strchr readlink link utime utimes lutimes strftime \
 863     chflags getattrlist mktime innetgr linkat \
 864     memmove lchown vsnprintf snprintf vasprintf asprintf setsid strpbrk \
 865     strlcat strlcpy strtol mallinfo mallinfo2 getgroups setgroups geteuid getegid \
 866     setlocale setmode open64 lseek64 mkstemp64 mtrace va_copy __va_copy \
 867     seteuid strerror putenv iconv_open locale_charset nl_langinfo getxattr \
 868     extattr_get_link sigaction sigprocmask setattrlist getgrouplist \
 869     initgroups utimensat posix_fallocate attropen setvbuf nanosleep usleep \
 870     setenv unsetenv)
 871
 872 dnl cygwin iconv.h defines iconv_open as libiconv_open
 873 if test x"$ac_cv_func_iconv_open" != x"yes"; then
 874     AC_CHECK_FUNC(libiconv_open, [ac_cv_func_iconv_open=yes; AC_DEFINE(HAVE_ICONV_OPEN, 1)])
 875 fi
 876
 877 dnl Preallocation stuff (also fallocate, posix_fallocate function tests above):
 878
 879 AC_CACHE_CHECK([for useable fallocate],rsync_cv_have_fallocate,[
 880 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <fcntl.h>
 881 #ifdef HAVE_SYS_TYPES_H
 882 #include <sys/types.h>
 883 #endif]], [[fallocate(0, 0, 0, 0);]])],[rsync_cv_have_fallocate=yes],[rsync_cv_have_fallocate=no])])
 884 if test x"$rsync_cv_have_fallocate" = x"yes"; then
 885     AC_DEFINE(HAVE_FALLOCATE, 1, [Define to 1 if you have the fallocate function and it compiles and links without error])
 886 fi
 887
 888 AC_MSG_CHECKING([for FALLOC_FL_PUNCH_HOLE])
 889 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 890         #define _GNU_SOURCE 1
 891         #include <linux/falloc.h>
 892         #ifndef FALLOC_FL_PUNCH_HOLE
 893         #error FALLOC_FL_PUNCH_HOLE is missing
 894         #endif
 895     ]])], [
 896         AC_MSG_RESULT([yes])
 897         AC_DEFINE([HAVE_FALLOC_FL_PUNCH_HOLE], [1], [Define if FALLOC_FL_PUNCH_HOLE is available.])
 898     ], [
 899         AC_MSG_RESULT([no])
 900     ]
 901 )
 902
 903 AC_MSG_CHECKING([for FALLOC_FL_ZERO_RANGE])
 904 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 905         #define _GNU_SOURCE 1
 906         #include <linux/falloc.h>
 907         #ifndef FALLOC_FL_ZERO_RANGE
 908         #error FALLOC_FL_ZERO_RANGE is missing
 909         #endif
 910     ]])], [
 911         AC_MSG_RESULT([yes])
 912         AC_DEFINE([HAVE_FALLOC_FL_ZERO_RANGE], [1], [Define if FALLOC_FL_ZERO_RANGE is available.])
 913     ], [
 914         AC_MSG_RESULT([no])
 915     ]
 916 )
 917
 918 AC_CACHE_CHECK([for SYS_fallocate],rsync_cv_have_sys_fallocate,[
 919 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/syscall.h>
 920 #ifdef HAVE_UNISTD_H
 921 #include <unistd.h>
 922 #endif
 923 #ifdef HAVE_SYS_TYPES_H
 924 #include <sys/types.h>
 925 #endif]], [[syscall(SYS_fallocate, 0, 0, (loff_t)0, (loff_t)0);]])],[rsync_cv_have_sys_fallocate=yes],[rsync_cv_have_sys_fallocate=no])])
 926 if test x"$rsync_cv_have_sys_fallocate" = x"yes"; then
 927     AC_DEFINE(HAVE_SYS_FALLOCATE, 1, [Define to 1 if you have the SYS_fallocate syscall number])
 928 fi
 929
 930 if test x"$ac_cv_func_posix_fallocate" = x"yes"; then
 931     AC_MSG_CHECKING([whether posix_fallocate is efficient])
 932     case $host_os in
 933     *cygwin*)
 934         AC_MSG_RESULT(yes)
 935         AC_DEFINE(HAVE_EFFICIENT_POSIX_FALLOCATE, 1,
 936                   [Define if posix_fallocate is efficient (Cygwin)])
 937         ;;
 938     *)
 939         AC_MSG_RESULT(no)
 940         ;;
 941     esac
 942 fi
 943
 944 dnl End of preallocation stuff
 945
 946 AC_CHECK_FUNCS(getpgrp tcgetpgrp)
 947 if test $ac_cv_func_getpgrp = yes; then
 948     AC_FUNC_GETPGRP
 949 fi
 950
 951 AC_ARG_ENABLE(iconv-open,
 952     AS_HELP_STRING([--disable-iconv-open],[disable to avoid all use of iconv_open()]),
 953     [], [enable_iconv_open=$ac_cv_func_iconv_open])
 954
 955 if test x"$enable_iconv_open" != x"no"; then
 956     AC_DEFINE(USE_ICONV_OPEN, 1, [Define to 1 if you want rsync to make use of iconv_open()])
 957 fi
 958
 959 AC_ARG_ENABLE(iconv,
 960     AS_HELP_STRING([--disable-iconv],[disable to omit the --iconv option]),
 961     [], [enable_iconv=$enable_iconv_open])
 962 AH_TEMPLATE([ICONV_OPTION],
 963 [Define if you want the --iconv option.  Specifying a value will set the
 964 default iconv setting (a NULL means no --iconv processing by default).])
 965 if test x"$enable_iconv" != x"no"; then
 966         if test x"$enable_iconv" = x"yes"; then
 967                 AC_DEFINE(ICONV_OPTION, NULL)
 968         else
 969                 AC_DEFINE_UNQUOTED(ICONV_OPTION, "$enable_iconv")
 970         fi
 971         AC_DEFINE(UTF8_CHARSET, "UTF-8", [String to pass to iconv() for the UTF-8 charset.])
 972 fi
 973
 974 AC_CACHE_CHECK([whether chown() modifies symlinks],rsync_cv_chown_modifies_symlink,[
 975   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 976 #if HAVE_UNISTD_H
 977 # include <unistd.h>
 978 #endif
 979 #include <stdlib.h>
 980 #include <errno.h>
 981 int main(void) {
 982         char const *dangling_symlink = "conftest.dangle";
 983         unlink(dangling_symlink);
 984         if (symlink("conftest.no-such", dangling_symlink) < 0) abort();
 985         if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) return 1;
 986         return 0;
 987     }]])],[rsync_cv_chown_modifies_symlink=yes],[rsync_cv_chown_modifies_symlink=no],[rsync_cv_chown_modifies_symlink=no])])
 988 if test $rsync_cv_chown_modifies_symlink = yes; then
 989   AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define to 1 if chown modifies symlinks.])
 990 fi
 991
 992 AC_CACHE_CHECK([whether link() can hard-link symlinks],rsync_cv_can_hardlink_symlink,[
 993   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 994 #ifdef HAVE_FCNTL_H
 995 # include <fcntl.h>
 996 #elif defined HAVE_SYS_FCNTL_H
 997 # include <sys/fcntl.h>
 998 #endif
 999 #if HAVE_UNISTD_H
1000 # include <unistd.h>
1001 #endif
1002 #include <stdlib.h>
1003 #include <errno.h>
1004 #define FILENAME "conftest.dangle"
1005 int main(void) {
1006         unlink(FILENAME);
1007         if (symlink("conftest.no-such", FILENAME) < 0) abort();
1008         unlink(FILENAME "2");
1009 #ifdef HAVE_LINKAT
1010         if (linkat(AT_FDCWD, FILENAME, AT_FDCWD, FILENAME "2", 0) < 0) return 1;
1011 #else
1012         if (link(FILENAME, FILENAME "2") < 0) return 1;
1013 #endif
1014         return 0;
1015     }]])],[rsync_cv_can_hardlink_symlink=yes],[rsync_cv_can_hardlink_symlink=no],[rsync_cv_can_hardlink_symlink=no])])
1016 if test $rsync_cv_can_hardlink_symlink = yes; then
1017   AC_DEFINE(CAN_HARDLINK_SYMLINK, 1, [Define to 1 if link() can hard-link symlinks.])
1018 fi
1019
1020 AC_CACHE_CHECK([whether link() can hard-link special files],rsync_cv_can_hardlink_special,[
1021   AC_RUN_IFELSE([AC_LANG_SOURCE([[
1022 #if HAVE_UNISTD_H
1023 # include <unistd.h>
1024 #endif
1025 #ifdef HAVE_SYS_STAT_H
1026 #include <sys/stat.h>
1027 #endif
1028 #include <stdlib.h>
1029 #include <errno.h>
1030 #define FILENAME "conftest.fifi"
1031 int main(void) {
1032         unlink(FILENAME);
1033         if (mkfifo(FILENAME, 0777) < 0) abort();
1034         unlink(FILENAME "2");
1035         if (link(FILENAME, FILENAME "2") < 0) return 1;
1036         return 0;
1037     }]])],[rsync_cv_can_hardlink_special=yes],[rsync_cv_can_hardlink_special=no],[rsync_cv_can_hardlink_special=no])])
1038 if test $rsync_cv_can_hardlink_special = yes; then
1039     AC_DEFINE(CAN_HARDLINK_SPECIAL, 1, [Define to 1 if link() can hard-link special files.])
1040 fi
1041
1042 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
1043 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1044 #ifdef HAVE_SYS_TYPES_H
1045 #include <sys/types.h>
1046 #endif
1047 #ifdef HAVE_SYS_SOCKET_H
1048 #include <sys/socket.h>
1049 #endif
1050
1051 int main(void) {
1052        int fd[2];
1053        return (socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1;
1054 }]])],[rsync_cv_HAVE_SOCKETPAIR=yes],[rsync_cv_HAVE_SOCKETPAIR=no],[rsync_cv_HAVE_SOCKETPAIR=cross])])
1055 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
1056     AC_DEFINE(HAVE_SOCKETPAIR, 1, [Define to 1 if you have the "socketpair" function])
1057 fi
1058
1059 AC_REPLACE_FUNCS([getpass])
1060
1061 if test x"$with_included_popt" != x"yes"; then
1062     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
1063 fi
1064 if test x"$ac_cv_header_popt_popt_h" = x"yes"; then
1065     # If the system has /usr/include/popt/popt.h, we enable the
1066     # included popt because an attempt to "#include <popt/popt.h>"
1067     # would use our included header file anyway (due to -I.), and
1068     # might conflict with the system popt.
1069     with_included_popt=yes
1070 elif test x"$ac_cv_header_popt_h" != x"yes"; then
1071     with_included_popt=yes
1072 fi
1073
1074 AC_MSG_CHECKING([whether to use included libpopt])
1075 if test x"$with_included_popt" = x"yes"; then
1076     AC_MSG_RESULT($srcdir/popt)
1077     BUILD_POPT='$(popt_OBJS)'
1078     CFLAGS="-I$srcdir/popt $CFLAGS"
1079     if test x"$ALLOCA" != x
1080     then
1081         # this can be removed when/if we add an included alloca.c;
1082         #  see autoconf documentation on AC_FUNC_ALLOCA
1083         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
1084     fi
1085 else
1086     AC_MSG_RESULT(no)
1087 fi
1088
1089 # We default to using our zlib unless --with-included-zlib=no is given.
1090 if test x"$with_included_zlib" != x"no"; then
1091     with_included_zlib=yes
1092 elif test x"$ac_cv_header_zlib_h" != x"yes"; then
1093     with_included_zlib=yes
1094 fi
1095 if test x"$with_included_zlib" != x"yes"; then
1096     AC_CHECK_LIB(z, deflateParams, , [with_included_zlib=yes])
1097 fi
1098
1099 AC_MSG_CHECKING([whether to use included zlib])
1100 if test x"$with_included_zlib" = x"yes"; then
1101     AC_MSG_RESULT($srcdir/zlib)
1102     BUILD_ZLIB='$(zlib_OBJS)'
1103     CFLAGS="-I$srcdir/zlib $CFLAGS"
1104 else
1105     AC_DEFINE(EXTERNAL_ZLIB, 1, [Define to 1 if using external zlib])
1106     AC_MSG_RESULT(no)
1107 fi
1108
1109 AC_CACHE_CHECK([for unsigned char],rsync_cv_SIGNED_CHAR_OK,[
1110 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[signed char *s = (signed char *)""]])],[rsync_cv_SIGNED_CHAR_OK=yes],[rsync_cv_SIGNED_CHAR_OK=no])])
1111 if test x"$rsync_cv_SIGNED_CHAR_OK" = x"yes"; then
1112     AC_DEFINE(SIGNED_CHAR_OK, 1, [Define to 1 if "signed char" is a valid type])
1113 fi
1114
1115 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
1116 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1117 #ifdef HAVE_SYS_TYPES_H
1118 #include <sys/types.h>
1119 #endif
1120 #include <dirent.h>
1121 int main(void) { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
1122 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
1123 di->d_name[0] == 0) return 0; return 1;} ]])],[rsync_cv_HAVE_BROKEN_READDIR=yes],[rsync_cv_HAVE_BROKEN_READDIR=no],[rsync_cv_HAVE_BROKEN_READDIR=cross])])
1124 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
1125     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [Define to 1 if readdir() is broken])
1126 fi
1127
1128 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_STRUCT_UTIMBUF,[
1129 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1130 #ifdef HAVE_SYS_TYPES_H
1131 #include <sys/types.h>
1132 #endif
1133 #include <utime.h>]], [[struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; return utime("foo.c",&tbuf);]])],[rsync_cv_HAVE_STRUCT_UTIMBUF=yes],[rsync_cv_HAVE_STRUCT_UTIMBUF=no])])
1134 if test x"$rsync_cv_HAVE_STRUCT_UTIMBUF" = x"yes"; then
1135     AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if you have the "struct utimbuf" type])
1136 fi
1137
1138 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
1139 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/time.h>
1140 #ifdef HAVE_UNISTD_H
1141 #include <unistd.h>
1142 #endif]], [[struct timeval tv; return gettimeofday(&tv, NULL);]])],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=no])])
1143 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then
1144     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [Define to 1 if gettimeofday() takes a time-zone arg])
1145 fi
1146
1147 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
1148 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1149 #ifdef HAVE_SYS_TYPES_H
1150 #include <sys/types.h>
1151 #endif
1152 #include <stdarg.h>
1153 #include <stdio.h>
1154 #if HAVE_STDLIB_H
1155 #include <stdlib.h>
1156 #endif
1157 #include <string.h>
1158 void foo(const char *format, ...) {
1159        va_list ap;
1160        int len;
1161        static char buf[] = "12345678901234567890";
1162
1163        va_start(ap, format);
1164        len = vsnprintf(0, 0, format, ap);
1165        va_end(ap);
1166        if (len != 5) exit(1);
1167
1168        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
1169 }
1170 int main(void) { foo("hello"); return 0; }
1171 ]])],[rsync_cv_HAVE_C99_VSNPRINTF=yes],[rsync_cv_HAVE_C99_VSNPRINTF=no],[rsync_cv_HAVE_C99_VSNPRINTF=cross])])
1172 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
1173     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [Define to 1 if vsprintf has a C99-compatible return value])
1174 fi
1175
1176
1177 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
1178 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1179 #ifdef HAVE_SYS_TYPES_H
1180 #include <sys/types.h>
1181 #endif
1182 #include <sys/stat.h>
1183 #ifdef HAVE_UNISTD_H
1184 #include <unistd.h>
1185 #endif
1186 int main(void) {
1187   struct stat st;
1188   char tpl[20]="/tmp/test.XXXXXX";
1189   int fd = mkstemp(tpl);
1190   if (fd == -1) return 1;
1191   unlink(tpl);
1192   if (fstat(fd, &st) != 0) return 1;
1193   if ((st.st_mode & 0777) != 0600) return 1;
1194   return 0;
1195 }]])],[rsync_cv_HAVE_SECURE_MKSTEMP=yes],[rsync_cv_HAVE_SECURE_MKSTEMP=no],[rsync_cv_HAVE_SECURE_MKSTEMP=cross])])
1196 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
1197     case $host_os in
1198     hpux*)
1199         dnl HP-UX has a broken mkstemp() implementation they refuse to fix,
1200         dnl so we noisily skip using it.  See HP change request JAGaf34426
1201         dnl for details. (sbonds)
1202         AC_MSG_WARN(Skipping broken HP-UX mkstemp() -- using mktemp() instead)
1203         ;;
1204     *)
1205         AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [Define to 1 if mkstemp() is available and works right])
1206         ;;
1207     esac
1208 fi
1209
1210
1211 AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[
1212 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1213 #include <stdio.h>
1214 #include <sys/stat.h>
1215 #include <errno.h>
1216 #if HAVE_UNISTD_H
1217 # include <unistd.h>
1218 #endif
1219 int main(void) { int rc, ec; char *fn = "fifo-test";
1220 unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn);
1221 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
1222 return 0;}]])],[rsync_cv_MKNOD_CREATES_FIFOS=yes],[rsync_cv_MKNOD_CREATES_FIFOS=no],[rsync_cv_MKNOD_CREATES_FIFOS=cross])])
1223 if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then
1224     AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.])
1225 fi
1226
1227 AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[
1228 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1229 #include <stdio.h>
1230 #include <sys/stat.h>
1231 #include <errno.h>
1232 #if HAVE_UNISTD_H
1233 # include <unistd.h>
1234 #endif
1235 int main(void) { int rc, ec; char *fn = "sock-test";
1236 unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn);
1237 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
1238 return 0;}]])],[rsync_cv_MKNOD_CREATES_SOCKETS=yes],[rsync_cv_MKNOD_CREATES_SOCKETS=no],[rsync_cv_MKNOD_CREATES_SOCKETS=cross])])
1239 if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then
1240     AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.])
1241 fi
1242
1243 #
1244 # The following test was mostly taken from the tcl/tk plus patches
1245 #
1246 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
1247 rm -rf conftest*
1248 cat > conftest.$ac_ext <<EOF
1249 int main(void) { return 0; }
1250 EOF
1251 ${CC-cc} -c -o conftest..o conftest.$ac_ext
1252 if test -f conftest..o; then
1253     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
1254 else
1255     rsync_cv_DASHC_WORKS_WITH_DASHO=no
1256 fi
1257 rm -rf conftest*
1258 ])
1259 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
1260     OBJ_SAVE="#"
1261     OBJ_RESTORE="#"
1262     CC_SHOBJ_FLAG='-o $@'
1263 else
1264     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
1265     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
1266     CC_SHOBJ_FLAG=""
1267 fi
1268
1269 AC_SUBST(OBJ_SAVE)
1270 AC_SUBST(OBJ_RESTORE)
1271 AC_SUBST(CC_SHOBJ_FLAG)
1272 AC_SUBST(BUILD_POPT)
1273 AC_SUBST(BUILD_ZLIB)
1274 AC_SUBST(MAKE_RRSYNC)
1275 AC_SUBST(MAKE_RRSYNC_1)
1276 AC_SUBST(GEN_RRSYNC)
1277 AC_SUBST(MAKE_MAN)
1278
1279 AC_CHECK_FUNCS(_acl __acl _facl __facl)
1280 #################################################
1281 # check for ACL support
1282
1283 AC_MSG_CHECKING([whether to support ACLs])
1284 AC_ARG_ENABLE(acl-support,
1285         AS_HELP_STRING([--disable-acl-support],[disable to omit ACL support]))
1286
1287 if test x"$enable_acl_support" = x"no"; then
1288     AC_MSG_RESULT(no)
1289 else
1290     case "$host_os" in
1291     *sysv5*)
1292         AC_MSG_RESULT(Using UnixWare ACLs)
1293         AC_DEFINE(HAVE_UNIXWARE_ACLS, 1, [true if you have UnixWare ACLs])
1294         AC_DEFINE(SUPPORT_ACLS, 1, [Define to 1 to add support for ACLs])
1295         ;;
1296     solaris*)
1297         AC_MSG_RESULT(Using solaris ACLs)
1298         AC_DEFINE(HAVE_SOLARIS_ACLS, 1, [true if you have solaris ACLs])
1299         AC_DEFINE(SUPPORT_ACLS, 1)
1300         ;;
1301     *irix*)
1302         AC_MSG_RESULT(Using IRIX ACLs)
1303         AC_DEFINE(HAVE_IRIX_ACLS, 1, [true if you have IRIX ACLs])
1304         AC_DEFINE(SUPPORT_ACLS, 1)
1305         ;;
1306     *aix*)
1307         AC_MSG_RESULT(Using AIX ACLs)
1308         AC_DEFINE(HAVE_AIX_ACLS, 1, [true if you have AIX ACLs])
1309         AC_DEFINE(SUPPORT_ACLS, 1)
1310         ;;
1311     *osf*)
1312         AC_MSG_RESULT(Using Tru64 ACLs)
1313         AC_DEFINE(HAVE_TRU64_ACLS, 1, [true if you have Tru64 ACLs])
1314         AC_DEFINE(SUPPORT_ACLS, 1)
1315         LIBS="$LIBS -lpacl"
1316         ;;
1317     darwin*)
1318         AC_MSG_RESULT(Using OS X ACLs)
1319         AC_DEFINE(HAVE_OSX_ACLS, 1, [true if you have Mac OS X ACLs])
1320         AC_DEFINE(SUPPORT_ACLS, 1)
1321         ;;
1322     *hpux*|*nsk*)
1323         AC_MSG_RESULT(Using HPUX ACLs)
1324         AC_DEFINE(HAVE_HPUX_ACLS, 1, [true if you have HPUX ACLs])
1325         AC_DEFINE(SUPPORT_ACLS, 1)
1326         ;;
1327     *)
1328         AC_MSG_RESULT(running tests:)
1329         AC_CHECK_LIB(acl,acl_get_file)
1330         AC_CACHE_CHECK([for ACL support],samba_cv_HAVE_POSIX_ACLS,[
1331             AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1332 #ifdef HAVE_SYS_TYPES_H
1333 #include <sys/types.h>
1334 #endif
1335 #ifdef HAVE_SYS_ACL_H
1336 #include <sys/acl.h>
1337 #endif]], [[ acl_t acl; int entry_id; acl_entry_t *entry_p; return acl_get_entry( acl, entry_id, entry_p);]])],[samba_cv_HAVE_POSIX_ACLS=yes],[samba_cv_HAVE_POSIX_ACLS=no])])
1338         AC_MSG_CHECKING(ACL test results)
1339         if test x"$samba_cv_HAVE_POSIX_ACLS" = x"yes"; then
1340             AC_MSG_RESULT(Using posix ACLs)
1341             AC_DEFINE(HAVE_POSIX_ACLS, 1, [true if you have posix ACLs])
1342             AC_DEFINE(SUPPORT_ACLS, 1)
1343             AC_CACHE_CHECK([for acl_get_perm_np],samba_cv_HAVE_ACL_GET_PERM_NP,[
1344                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1345 #ifdef HAVE_SYS_TYPES_H
1346 #include <sys/types.h>
1347 #endif
1348 #ifdef HAVE_SYS_ACL_H
1349 #include <sys/acl.h>
1350 #endif]], [[ acl_permset_t permset_d; acl_perm_t perm; return acl_get_perm_np( permset_d, perm);]])],[samba_cv_HAVE_ACL_GET_PERM_NP=yes],[samba_cv_HAVE_ACL_GET_PERM_NP=no])])
1351             if test x"$samba_cv_HAVE_ACL_GET_PERM_NP" = x"yes"; then
1352                 AC_DEFINE(HAVE_ACL_GET_PERM_NP, 1, [true if you have acl_get_perm_np])
1353             fi
1354         else
1355             if test x"$enable_acl_support" = x"yes"; then
1356                 AC_MSG_ERROR(Failed to find ACL support)
1357             else
1358                 AC_MSG_RESULT(No ACL support found)
1359             fi
1360         fi
1361         ;;
1362     esac
1363 fi
1364
1365 #################################################
1366 # check for extended attribute support
1367 AC_MSG_CHECKING(whether to support extended attributes)
1368 AC_ARG_ENABLE(xattr-support,
1369     AS_HELP_STRING([--disable-xattr-support],[disable to omit extended attributes]),
1370     [], [case "$ac_cv_func_getxattr$ac_cv_func_extattr_get_link$ac_cv_func_attropen" in
1371         *yes*) enable_xattr_support=maybe ;;
1372         *) enable_xattr_support=no ;;
1373         esac])
1374 AH_TEMPLATE([SUPPORT_XATTRS],
1375 [Define to 1 to add support for extended attributes])
1376 if test x"$enable_xattr_support" = x"no"; then
1377     AC_MSG_RESULT(no)
1378 else
1379     case "$host_os" in
1380     *linux*|*netbsd*|*cygwin*)
1381         AC_MSG_RESULT(Using Linux xattrs)
1382         AC_DEFINE(HAVE_LINUX_XATTRS, 1, [True if you have Linux xattrs (or equivalent)])
1383         AC_DEFINE(SUPPORT_XATTRS, 1)
1384         AC_DEFINE(NO_SYMLINK_USER_XATTRS, 1, [True if symlinks do not support user xattrs])
1385         AC_CHECK_LIB(attr,getxattr)
1386         ;;
1387     darwin*)
1388         AC_MSG_RESULT(Using OS X xattrs)
1389         AC_DEFINE(HAVE_OSX_XATTRS, 1, [True if you have Mac OS X xattrs])
1390         AC_DEFINE(SUPPORT_XATTRS, 1)
1391         AC_DEFINE(NO_DEVICE_XATTRS, 1, [True if device files do not support xattrs])
1392         AC_DEFINE(NO_SPECIAL_XATTRS, 1, [True if special files do not support xattrs])
1393         ;;
1394     freebsd*)
1395         AC_MSG_RESULT(Using FreeBSD extattrs)
1396         AC_DEFINE(HAVE_FREEBSD_XATTRS, 1, [True if you have FreeBSD xattrs])
1397         AC_DEFINE(SUPPORT_XATTRS, 1)
1398         ;;
1399     solaris*)
1400         AC_MSG_RESULT(Using Solaris xattrs)
1401         AC_DEFINE(HAVE_SOLARIS_XATTRS, 1, [True if you have Solaris xattrs])
1402         AC_DEFINE(SUPPORT_XATTRS, 1)
1403         AC_DEFINE(NO_SYMLINK_XATTRS, 1, [True if symlinks do not support xattrs])
1404         ;;
1405     *)
1406         if test x"$enable_xattr_support" = x"yes"; then
1407             AC_MSG_ERROR(Failed to find extended attribute support)
1408         else
1409             AC_MSG_RESULT(No extended attribute support found)
1410         fi
1411         ;;
1412     esac
1413 fi
1414
1415 if test x"$enable_acl_support" = x"no" || test x"$enable_xattr_support" = x"no" || test x"$enable_iconv" = x"no"; then
1416     AC_MSG_CHECKING([whether $CC supports -Wno-unused-parameter])
1417     OLD_CFLAGS="$CFLAGS"
1418     CFLAGS="$CFLAGS -Wno-unused-parameter"
1419     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>]], [[printf("hello\n");]])],[rsync_warn_flag=yes],[rsync_warn_flag=no])
1420     AC_MSG_RESULT([$rsync_warn_flag])
1421     if test x"$rsync_warn_flag" = x"no"; then
1422         CFLAGS="$OLD_CFLAGS"
1423     fi
1424 fi
1425
1426 case "$CC" in
1427 ' checker'*|checker*)
1428     AC_DEFINE(FORCE_FD_ZERO_MEMSET, 1, [Used to make "checker" understand that FD_ZERO() clears memory.])
1429     ;;
1430 esac
1431
1432 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
1433 AC_OUTPUT
1434
1435 AC_MSG_RESULT()
1436 AC_MSG_RESULT([    rsync $PACKAGE_VERSION configuration successful])
1437 AC_MSG_RESULT()