pidl/lib/Parse/Pidl/Samba4/NDR/Parser.pm

   1 ###################################################
   2 # Samba4 NDR parser generator for IDL structures
   3 # Copyright tridge@samba.org 2000-2003
   4 # Copyright tpot@samba.org 2001
   5 # Copyright jelmer@samba.org 2004-2006
   6 # released under the GNU GPL
   7
   8 package Parse::Pidl::Samba4::NDR::Parser;
   9 use parent Parse::Pidl::Base;
  10
  11 require Exporter;
  12 push @ISA, qw(Exporter);
  13 @EXPORT_OK = qw(check_null_pointer NeededFunction NeededElement NeededType $res NeededInterface TypeFunctionName ParseElementPrint);
  14
  15 use strict;
  16 use warnings;
  17 use Parse::Pidl::Typelist qw(hasType getType mapTypeName mapTypeSpecifier typeHasBody);
  18 use Parse::Pidl::Util qw(has_property
  19                          ParseExpr
  20                          ParseExprExt
  21                          print_uuid
  22                          unmake_str
  23                          parse_int
  24                          parse_range);
  25 use Parse::Pidl::CUtil qw(get_pointer_to get_value_of get_array_element);
  26 use Parse::Pidl::NDR qw(GetPrevLevel GetNextLevel ContainsDeferred ContainsPipe is_charset_array);
  27 use Parse::Pidl::Samba4 qw(is_intree choose_header ArrayDynamicallyAllocated);
  28 use Parse::Pidl::Samba4::Header qw(GenerateFunctionInEnv GenerateFunctionOutEnv EnvSubstituteValue GenerateStructEnv);
  29 use Parse::Pidl qw(warning);
  30
  31 use vars qw($VERSION);
  32 $VERSION = '0.01';
  33
  34 # list of known types
  35 my %typefamily;
  36
  37 sub new($$) {
  38         my ($class) = @_;
  39         my $self = { res => "", res_hdr => "", deferred => [], tabs => "", defer_tabs => "" };
  40         bless($self, $class);
  41 }
  42
  43 sub get_typefamily($)
  44 {
  45         my $n = shift;
  46         return $typefamily{$n};
  47 }
  48
  49 sub append_prefix($$)
  50 {
  51         my ($e, $var_name) = @_;
  52         my $pointers = 0;
  53         my $arrays = 0;
  54
  55         foreach my $l (@{$e->{LEVELS}}) {
  56                 if ($l->{TYPE} eq "POINTER") {
  57                         $pointers++;
  58                 } elsif ($l->{TYPE} eq "ARRAY") {
  59                         $arrays++;
  60                         if (($pointers == 0) and
  61                             (not $l->{IS_FIXED}) and
  62                             (not $l->{IS_INLINE})) {
  63                                 return get_value_of($var_name);
  64                         }
  65                 } elsif ($l->{TYPE} eq "DATA") {
  66                         if (Parse::Pidl::Typelist::scalar_is_reference($l->{DATA_TYPE})) {
  67                                 return get_value_of($var_name) unless ($pointers or $arrays);
  68                         }
  69                 }
  70         }
  71
  72         return $var_name;
  73 }
  74
  75 sub has_fast_array($$)
  76 {
  77         my ($e,$l) = @_;
  78
  79         return 0 if ($l->{TYPE} ne "ARRAY");
  80
  81         my $nl = GetNextLevel($e,$l);
  82         return 0 unless ($nl->{TYPE} eq "DATA");
  83         return 0 unless (hasType($nl->{DATA_TYPE}));
  84
  85         my $t = getType($nl->{DATA_TYPE});
  86
  87         # Only uint8 has a fast array function at the moment
  88         return ($t->{NAME} eq "uint8");
  89 }
  90
  91 sub is_public_struct
  92 {
  93         my ($d) = @_;
  94         if (!has_property($d, "public")) {
  95                 return 0;
  96         }
  97         my $t = $d;
  98         if ($d->{TYPE} eq "TYPEDEF") {
  99                 $t = $d->{DATA};
 100         }
 101         return $t->{TYPE} eq "STRUCT";
 102 }
 103
 104 ####################################
 105 # defer() is like pidl(), but adds to
 106 # a deferred buffer which is then added to the
 107 # output buffer at the end of the structure/union/function
 108 # This is needed to cope with code that must be pushed back
 109 # to the end of a block of elements
 110 sub defer_indent($) { my ($self) = @_; $self->{defer_tabs}.="\t"; }
 111 sub defer_deindent($) { my ($self) = @_; $self->{defer_tabs}=substr($self->{defer_tabs}, 0, -1); }
 112
 113 sub defer($$)
 114 {
 115         my ($self, $d) = @_;
 116         if ($d) {
 117                 push(@{$self->{deferred}}, $self->{defer_tabs}.$d);
 118         }
 119 }
 120
 121 ########################################
 122 # add the deferred content to the current
 123 # output
 124 sub add_deferred($)
 125 {
 126         my ($self) = @_;
 127         $self->pidl($_) foreach (@{$self->{deferred}});
 128         $self->{deferred} = [];
 129         $self->{defer_tabs} = "";
 130 }
 131
 132 #####################################################################
 133 # declare a function public or static, depending on its attributes
 134 sub fn_declare($$$$)
 135 {
 136         my ($self,$type,$fn,$decl) = @_;
 137
 138         if (has_property($fn, "no$type")) {
 139                 $self->pidl_hdr("$decl;");
 140                 return 0;
 141         }
 142
 143         if (has_property($fn, "public")) {
 144                 $self->pidl_hdr("$decl;");
 145                 $self->pidl("_PUBLIC_ $decl");
 146         } else {
 147                 $self->pidl("static $decl");
 148         }
 149
 150         return 1;
 151 }
 152
 153 ###################################################################
 154 # setup any special flags for an element or structure
 155 sub start_flags($$$)
 156 {
 157         my ($self, $e, $ndr) = @_;
 158         my $flags = has_property($e, "flag");
 159         if (defined $flags) {
 160                 $self->pidl("{");
 161                 $self->indent;
 162                 $self->pidl("libndr_flags _flags_save_$e->{TYPE} = $ndr->flags;");
 163                 $self->pidl("ndr_set_flags(&$ndr->flags, $flags);");
 164         }
 165 }
 166
 167 ###################################################################
 168 # end any special flags for an element or structure
 169 sub end_flags($$$)
 170 {
 171         my ($self, $e, $ndr) = @_;
 172         my $flags = has_property($e, "flag");
 173         if (defined $flags) {
 174                 $self->pidl("$ndr->flags = _flags_save_$e->{TYPE};");
 175                 $self->deindent;
 176                 $self->pidl("}");
 177         }
 178 }
 179
 180 #####################################################################
 181 # parse the data of an array - push side
 182 sub ParseArrayPushHeader($$$$$$)
 183 {
 184         my ($self,$e,$l,$ndr,$var_name,$env) = @_;
 185
 186         my $size;
 187         my $length;
 188
 189         if ($l->{IS_ZERO_TERMINATED}) {
 190                 if (has_property($e, "charset")) {
 191                         $size = $length = "ndr_charset_length($var_name, CH_$e->{PROPERTIES}->{charset})";
 192                 } else {
 193                         $size = $length = "ndr_string_length($var_name, sizeof(*$var_name))";
 194                 }
 195                 if (defined($l->{SIZE_IS})) {
 196                         $size = ParseExpr($l->{SIZE_IS}, $env, $e);
 197                 }
 198                 if (defined($l->{LENGTH_IS})) {
 199                         $length = ParseExpr($l->{LENGTH_IS}, $env, $e);
 200                 }
 201         } else {
 202                 $size = ParseExpr($l->{SIZE_IS}, $env, $e);
 203                 $length = ParseExpr($l->{LENGTH_IS}, $env, $e);
 204         }
 205
 206         if ((!$l->{IS_SURROUNDING}) and $l->{IS_CONFORMANT}) {
 207                 $self->pidl("NDR_CHECK(ndr_push_uint3264($ndr, NDR_SCALARS, $size));");
 208         }
 209
 210         if ($l->{IS_VARYING}) {
 211                 $self->pidl("NDR_CHECK(ndr_push_uint3264($ndr, NDR_SCALARS, 0));");  # array offset
 212                 $self->pidl("NDR_CHECK(ndr_push_uint3264($ndr, NDR_SCALARS, $length));");
 213         }
 214
 215         return $length;
 216 }
 217
 218 sub check_fully_dereferenced($$)
 219 {
 220         my ($element, $env) = @_;
 221
 222         return sub ($) {
 223                 my $origvar = shift;
 224                 my $check = 0;
 225
 226                 # Figure out the number of pointers in $ptr
 227                 my $expandedvar = $origvar;
 228                 $expandedvar =~ s/^(\**)//;
 229                 my $ptr = $1;
 230
 231                 my $var = undef;
 232                 foreach (keys %$env) {
 233                         if ($env->{$_} eq $expandedvar) {
 234                                 $var = $_;
 235                                 last;
 236                         }
 237                 }
 238
 239                 return($origvar) unless (defined($var));
 240                 my $e;
 241                 foreach (@{$element->{PARENT}->{ELEMENTS}}) {
 242                         if ($_->{NAME} eq $var) {
 243                                 $e = $_;
 244                                 last;
 245                         }
 246                 }
 247
 248                 $e or die("Environment doesn't match siblings");
 249
 250                 # See if pointer at pointer level $level
 251                 # needs to be checked.
 252                 my $nump = 0;
 253                 foreach (@{$e->{LEVELS}}) {
 254                         if ($_->{TYPE} eq "POINTER") {
 255                                 $nump = $_->{POINTER_INDEX}+1;
 256                         }
 257                 }
 258                 warning($element->{ORIGINAL}, "Got pointer for `$e->{NAME}', expected fully dereferenced variable") if ($nump > length($ptr));
 259                 return ($origvar);
 260         }
 261 }
 262
 263 sub check_null_pointer($$$$)
 264 {
 265         my ($element, $env, $print_fn, $return) = @_;
 266
 267         return sub ($) {
 268                 my $expandedvar = shift;
 269                 my $check = 0;
 270
 271                 # Figure out the number of pointers in $ptr
 272                 $expandedvar =~ s/^(\**)//;
 273                 my $ptr = $1;
 274
 275                 my $var = undef;
 276                 foreach (keys %$env) {
 277                         if ($env->{$_} eq $expandedvar) {
 278                                 $var = $_;
 279                                 last;
 280                         }
 281                 }
 282
 283                 if (defined($var)) {
 284                         my $e;
 285                         # lookup ptr in $e
 286                         foreach (@{$element->{PARENT}->{ELEMENTS}}) {
 287                                 if ($_->{NAME} eq $var) {
 288                                         $e = $_;
 289                                         last;
 290                                 }
 291                         }
 292
 293                         $e or die("Environment doesn't match siblings");
 294
 295                         # See if pointer at pointer level $level
 296                         # needs to be checked.
 297                         foreach my $l (@{$e->{LEVELS}}) {
 298                                 if ($l->{TYPE} eq "POINTER" and
 299                                         $l->{POINTER_INDEX} == length($ptr)) {
 300                                         # No need to check ref pointers
 301                                         $check = ($l->{POINTER_TYPE} ne "ref");
 302                                         last;
 303                                 }
 304
 305                                 if ($l->{TYPE} eq "DATA") {
 306                                         warning($element, "too much dereferences for `$var'");
 307                                 }
 308                         }
 309                 } else {
 310                         warning($element, "unknown dereferenced expression `$expandedvar'");
 311                         $check = 1;
 312                 }
 313
 314                 $print_fn->("if ($ptr$expandedvar == NULL) $return") if $check;
 315         }
 316 }
 317
 318 sub is_deferred_switch_non_empty($)
 319 {
 320         # 1 if there needs to be a deferred branch in an ndr_pull/push,
 321         # 0 otherwise.
 322         my ($e) = @_;
 323         my $have_default = 0;
 324         foreach my $el (@{$e->{ELEMENTS}}) {
 325                 if ($el->{CASE} eq "default") {
 326                         $have_default = 1;
 327                 }
 328                 if ($el->{TYPE} ne "EMPTY") {
 329                         if (ContainsDeferred($el, $el->{LEVELS}[0])) {
 330                                 return 1;
 331                         }
 332                 }
 333         }
 334         return ! $have_default;
 335 }
 336
 337 sub ParseArrayPullGetSize($$$$$$)
 338 {
 339         my ($self,$e,$l,$ndr,$var_name,$env) = @_;
 340
 341         my $size;
 342
 343         my $array_size = "size_$e->{NAME}_$l->{LEVEL_INDEX}";
 344
 345         if ($l->{IS_CONFORMANT} and (defined($l->{SIZE_IS}) or not $l->{IS_ZERO_TERMINATED})) {
 346                 $self->pidl("NDR_CHECK(ndr_get_array_size($ndr, (void*)" . get_pointer_to($var_name) . ", &$array_size));");
 347
 348         } elsif ($l->{IS_CONFORMANT}) {
 349                 # This will be the last use of the array_size token
 350                 $self->pidl("NDR_CHECK(ndr_steal_array_size($ndr, (void*)" . get_pointer_to($var_name) . ", &$array_size));");
 351
 352         } elsif ($l->{IS_ZERO_TERMINATED} and $l->{SIZE_IS} == 0 and $l->{LENGTH_IS} == 0) { # Noheader arrays
 353                 $size = "ndr_get_string_size($ndr, sizeof(*$var_name))";
 354                 $self->pidl("$array_size = $size;");
 355
 356         } else {
 357                 $size = ParseExprExt($l->{SIZE_IS}, $env, $e->{ORIGINAL},
 358                         check_null_pointer($e, $env, sub { $self->pidl(shift); },
 359                                            "return ndr_pull_error($ndr, NDR_ERR_INVALID_POINTER, \"NULL Pointer for size_is()\");"),
 360                         check_fully_dereferenced($e, $env));
 361                 $self->pidl("$array_size = $size;");
 362         }
 363
 364         if (my $range = has_property($e, "range")) {
 365                 my ($low, $high) = parse_range($range);
 366                 if ($low < 0) {
 367                         warning(0, "$low is invalid for the range of an array size");
 368                 }
 369                 if ($low == 0) {
 370                         $self->pidl("if ($array_size > $high) {");
 371                 } else {
 372                         $self->pidl("if ($array_size < $low || $array_size > $high) {");
 373                 }
 374                 $self->pidl("\treturn ndr_pull_error($ndr, NDR_ERR_RANGE, \"value (%\"PRIu32\") out of range (%\"PRIu32\" - %\"PRIu32\")\", $array_size, (uint32_t)($low), (uint32_t)($high));");
 375
 376                 $self->pidl("}");
 377         }
 378
 379         return $array_size;
 380 }
 381
 382 #####################################################################
 383 # parse an array - pull side
 384 sub ParseArrayPullGetLength($$$$$$;$)
 385 {
 386         my ($self,$e,$l,$ndr,$var_name,$env,$array_size) = @_;
 387
 388         if (not defined($array_size)) {
 389                 $array_size = $self->ParseArrayPullGetSize($e, $l, $ndr, $var_name, $env);
 390         }
 391
 392         if (not $l->{IS_VARYING}) {
 393                 return $array_size;
 394         }
 395
 396         my $array_length = "length_$e->{NAME}_$l->{LEVEL_INDEX}";
 397         if ($l->{IS_VARYING} and (defined($l->{LENGTH_IS}) or not $l->{IS_ZERO_TERMINATED})) {
 398                 $self->pidl("NDR_CHECK(ndr_get_array_length($ndr, (void*)" . get_pointer_to($var_name) . ", &$array_length));");
 399         } else {
 400                 # This will be the last use of the array_length token
 401                 $self->pidl("NDR_CHECK(ndr_steal_array_length($ndr, (void*)" . get_pointer_to($var_name) . ", &$array_length));");
 402         }
 403
 404         if (my $range = has_property($e, "range")) {
 405                 my ($low, $high) = parse_range($range);
 406                 if ($low < 0) {
 407                         warning(0, "$low is invalid for the range of an array size");
 408                 }
 409                 if ($low == 0) {
 410                         $self->pidl("if ($array_length > $high) {");
 411                 } else {
 412                         $self->pidl("if ($array_length < $low || $array_length > $high) {");
 413                 }
 414                 $self->pidl("\treturn ndr_pull_error($ndr, NDR_ERR_RANGE, \"value (%\"PRIu32\") out of range (%\"PRIu32\" - %\"PRIu32\")\", $array_length, (uint32_t)($low), (uint32_t)($high));");
 415                 $self->pidl("}");
 416         }
 417
 418         return $array_length;
 419 }
 420
 421 #####################################################################
 422 # parse an array - pull side
 423 sub ParseArrayPullHeader($$$$$$)
 424 {
 425         my ($self,$e,$l,$ndr,$var_name,$env) = @_;
 426
 427         if ((!$l->{IS_SURROUNDING}) and $l->{IS_CONFORMANT}) {
 428                 $self->pidl("NDR_CHECK(ndr_pull_array_size($ndr, " . get_pointer_to($var_name) . "));");
 429         }
 430
 431         if ($l->{IS_VARYING}) {
 432                 $self->pidl("NDR_CHECK(ndr_pull_array_length($ndr, " . get_pointer_to($var_name) . "));");
 433         }
 434
 435         my $array_size = $self->ParseArrayPullGetSize($e, $l, $ndr, $var_name, $env);
 436         my $array_length = $self->ParseArrayPullGetLength($e, $l, $ndr, $var_name, $env, $array_size);
 437
 438         if ($array_length ne $array_size) {
 439                 $self->pidl("if ($array_length > $array_size) {");
 440                 $self->indent;
 441                 $self->pidl("return ndr_pull_error($ndr, NDR_ERR_ARRAY_SIZE, \"Bad array size %\"PRIu32\": should exceed array length %\"PRIu32\"\", $array_size, $array_length);");
 442                 $self->deindent;
 443                 $self->pidl("}");
 444         }
 445
 446         if ($l->{IS_CONFORMANT} and (defined($l->{SIZE_IS}) or not $l->{IS_ZERO_TERMINATED})) {
 447                 $self->defer("if ($var_name) {");
 448                 $self->defer_indent;
 449                 my $size = ParseExprExt($l->{SIZE_IS}, $env, $e->{ORIGINAL},
 450                         check_null_pointer($e, $env, sub { $self->defer(shift); },
 451                                            "return ndr_pull_error($ndr, NDR_ERR_INVALID_POINTER, \"NULL Pointer for size_is()\");"),
 452                         check_fully_dereferenced($e, $env));
 453                 if (ContainsDeferred($e, $l)) {
 454                         # We will be needing the array_size token in
 455                         # the NDR_BUFFERS call, so don't steal it now
 456                         $self->defer("NDR_CHECK(ndr_check_array_size($ndr, (void*)" . get_pointer_to($var_name) . ", $size));");
 457                 } else {
 458                         # This will be deferred until after the last ndr_get_array_size()
 459                         $self->defer("NDR_CHECK(ndr_check_steal_array_size($ndr, (void*)" . get_pointer_to($var_name) . ", $size));");
 460                 }
 461                 $self->defer_deindent;
 462                 $self->defer("}");
 463         }
 464
 465         if ($l->{IS_VARYING} and (defined($l->{LENGTH_IS}) or not $l->{IS_ZERO_TERMINATED})) {
 466                 $self->defer("if ($var_name) {");
 467                 $self->defer_indent;
 468                 my $length = ParseExprExt($l->{LENGTH_IS}, $env, $e->{ORIGINAL},
 469                         check_null_pointer($e, $env, sub { $self->defer(shift); },
 470                                            "return ndr_pull_error($ndr, NDR_ERR_INVALID_POINTER, \"NULL Pointer for length_is()\");"),
 471                         check_fully_dereferenced($e, $env));
 472                 # This will be deferred until after the last ndr_get_array_length()
 473                 $self->defer("NDR_CHECK(ndr_check_steal_array_length($ndr, (void*)" . get_pointer_to($var_name) . ", $length));");
 474                 $self->defer_deindent;
 475                 $self->defer("}");
 476         }
 477
 478         if (ArrayDynamicallyAllocated($e,$l) and not is_charset_array($e,$l)) {
 479                 $self->AllocateArrayLevel($e,$l,$ndr,$var_name,$array_size);
 480         }
 481
 482         return $array_length;
 483 }
 484
 485 sub compression_alg($$$)
 486 {
 487         my ($e, $l, $env) = @_;
 488         my ($alg, $clen, $dlen) = split(/,/, $l->{COMPRESSION});
 489
 490         return ParseExpr($alg, $env, $e->{ORIGINAL});
 491 }
 492
 493 sub compression_clen($$$)
 494 {
 495         my ($e, $l, $env) = @_;
 496         my ($alg, $clen, $dlen) = split(/,/, $l->{COMPRESSION});
 497
 498         return ParseExpr($clen, $env, $e->{ORIGINAL});
 499 }
 500
 501 sub compression_dlen($$$)
 502 {
 503         my ($e,$l,$env) = @_;
 504         my ($alg, $clen, $dlen) = split(/,/, $l->{COMPRESSION});
 505
 506         return ParseExpr($dlen, $env, $e->{ORIGINAL});
 507 }
 508
 509 sub ParseCompressionPushStart($$$$$)
 510 {
 511         my ($self,$e,$l,$ndr,$env) = @_;
 512         my $comndr = "$ndr\_compressed";
 513         my $alg = compression_alg($e, $l, $env);
 514
 515         $self->pidl("{");
 516         $self->indent;
 517         $self->pidl("struct ndr_push *$comndr;");
 518         $self->pidl("NDR_CHECK(ndr_push_compression_state_init($ndr, $alg));");
 519         $self->pidl("NDR_CHECK(ndr_push_compression_start($ndr, &$comndr));");
 520
 521         return $comndr;
 522 }
 523
 524 sub ParseCompressionPushEnd($$$$$)
 525 {
 526         my ($self,$e,$l,$ndr,$env) = @_;
 527         my $comndr = "$ndr\_compressed";
 528         my $alg = compression_alg($e, $l, $env);
 529
 530         $self->pidl("NDR_CHECK(ndr_push_compression_end($ndr, $comndr));");
 531         $self->pidl("TALLOC_FREE($ndr->cstate);");
 532         $self->deindent;
 533         $self->pidl("}");
 534 }
 535
 536 sub ParseCompressionPullStart($$$$$)
 537 {
 538         my ($self,$e,$l,$ndr,$env) = @_;
 539         my $comndr = "$ndr\_compressed";
 540         my $alg = compression_alg($e, $l, $env);
 541         my $dlen = compression_dlen($e, $l, $env);
 542         my $clen = compression_clen($e, $l, $env);
 543
 544         $self->pidl("{");
 545         $self->indent;
 546         $self->pidl("struct ndr_pull *$comndr;");
 547         $self->pidl("NDR_CHECK(ndr_pull_compression_start($ndr, &$comndr, $alg, $dlen, $clen));");
 548
 549         return $comndr;
 550 }
 551
 552 sub ParseCompressionPullEnd($$$$$)
 553 {
 554         my ($self,$e,$l,$ndr,$env) = @_;
 555         my $comndr = "$ndr\_compressed";
 556         my $alg = compression_alg($e, $l, $env);
 557         my $dlen = compression_dlen($e, $l, $env);
 558
 559         $self->pidl("NDR_CHECK(ndr_pull_compression_end($ndr, $comndr, $alg, $dlen));");
 560         $self->deindent;
 561         $self->pidl("}");
 562 }
 563
 564 sub ParseSubcontextPushStart($$$$$)
 565 {
 566         my ($self,$e,$l,$ndr,$env) = @_;
 567         my $subndr = "_ndr_$e->{NAME}";
 568         my $subcontext_size = ParseExpr($l->{SUBCONTEXT_SIZE}, $env, $e->{ORIGINAL});
 569
 570         $self->pidl("{");
 571         $self->indent;
 572         $self->pidl("struct ndr_push *$subndr;");
 573         $self->pidl("NDR_CHECK(ndr_push_subcontext_start($ndr, &$subndr, $l->{HEADER_SIZE}, $subcontext_size));");
 574
 575         if (defined $l->{COMPRESSION}) {
 576                 $subndr = $self->ParseCompressionPushStart($e, $l, $subndr, $env);
 577         }
 578
 579         return $subndr;
 580 }
 581
 582 sub ParseSubcontextPushEnd($$$$$)
 583 {
 584         my ($self,$e,$l,$ndr,$env) = @_;
 585         my $subndr = "_ndr_$e->{NAME}";
 586         my $subcontext_size = ParseExpr($l->{SUBCONTEXT_SIZE}, $env, $e->{ORIGINAL});
 587
 588         if (defined $l->{COMPRESSION}) {
 589                 $self->ParseCompressionPushEnd($e, $l, $subndr, $env);
 590         }
 591
 592         $self->pidl("NDR_CHECK(ndr_push_subcontext_end($ndr, $subndr, $l->{HEADER_SIZE}, $subcontext_size));");
 593         $self->deindent;
 594         $self->pidl("}");
 595 }
 596
 597 sub ParseSubcontextPullStart($$$$$)
 598 {
 599         my ($self,$e,$l,$ndr,$env) = @_;
 600         my $subndr = "_ndr_$e->{NAME}";
 601         my $subcontext_size = ParseExpr($l->{SUBCONTEXT_SIZE}, $env, $e->{ORIGINAL});
 602
 603         $self->pidl("{");
 604         $self->indent;
 605         $self->pidl("struct ndr_pull *$subndr;");
 606         $self->pidl("NDR_CHECK(ndr_pull_subcontext_start($ndr, &$subndr, $l->{HEADER_SIZE}, $subcontext_size));");
 607
 608         if (defined $l->{COMPRESSION}) {
 609                 $subndr = $self->ParseCompressionPullStart($e, $l, $subndr, $env);
 610         }
 611
 612         return $subndr;
 613 }
 614
 615 sub ParseSubcontextPullEnd($$$$$)
 616 {
 617         my ($self,$e,$l,$ndr,$env) = @_;
 618         my $subndr = "_ndr_$e->{NAME}";
 619         my $subcontext_size = ParseExpr($l->{SUBCONTEXT_SIZE}, $env, $e->{ORIGINAL});
 620
 621         if (defined $l->{COMPRESSION}) {
 622                 $self->ParseCompressionPullEnd($e, $l, $subndr, $env);
 623         }
 624
 625         $self->pidl("NDR_CHECK(ndr_pull_subcontext_end($ndr, $subndr, $l->{HEADER_SIZE}, $subcontext_size));");
 626         $self->deindent;
 627         $self->pidl("}");
 628 }
 629
 630 sub ParseElementPushLevel
 631 {
 632         my ($self,$e,$l,$ndr,$var_name,$env,$primitives,$deferred) = @_;
 633
 634         my $ndr_flags = CalcNdrFlags($l, $primitives, $deferred);
 635
 636         if ($l->{TYPE} eq "ARRAY" and ($l->{IS_CONFORMANT} or $l->{IS_VARYING})) {
 637                 $var_name = get_pointer_to($var_name);
 638         }
 639
 640         if (defined($ndr_flags)) {
 641                 if ($l->{TYPE} eq "SUBCONTEXT") {
 642                         my $subndr = $self->ParseSubcontextPushStart($e, $l, $ndr, $env);
 643                         $self->ParseElementPushLevel($e, GetNextLevel($e, $l), $subndr, $var_name, $env, 1, 1);
 644                         $self->ParseSubcontextPushEnd($e, $l, $ndr, $env);
 645                 } elsif ($l->{TYPE} eq "POINTER") {
 646                         $self->ParsePtrPush($e, $l, $ndr, $var_name);
 647                 } elsif ($l->{TYPE} eq "ARRAY") {
 648                         my $length = $self->ParseArrayPushHeader($e, $l, $ndr, $var_name, $env);
 649
 650                         my $nl = GetNextLevel($e, $l);
 651
 652                         # Allow speedups for arrays of scalar types
 653                         if (is_charset_array($e,$l)) {
 654                                 if ($l->{IS_TO_NULL}) {
 655                                         $self->pidl("NDR_CHECK(ndr_push_charset_to_null($ndr, $ndr_flags, $var_name, $length, sizeof(" . mapTypeName($nl->{DATA_TYPE}) . "), CH_$e->{PROPERTIES}->{charset}));");
 656                                 } else {
 657                                         $self->pidl("NDR_CHECK(ndr_push_charset($ndr, $ndr_flags, $var_name, $length, sizeof(" . mapTypeName($nl->{DATA_TYPE}) . "), CH_$e->{PROPERTIES}->{charset}));");
 658                                 }
 659                                 return;
 660                         } elsif (has_fast_array($e,$l)) {
 661                                 $self->pidl("NDR_CHECK(ndr_push_array_$nl->{DATA_TYPE}($ndr, $ndr_flags, $var_name, $length));");
 662                                 return;
 663                         }
 664                 } elsif ($l->{TYPE} eq "DATA") {
 665                         $self->ParseDataPush($e, $l, $ndr, $var_name, $primitives, $deferred);
 666                 } elsif ($l->{TYPE} eq "TYPEDEF") {
 667                         $typefamily{$e->{DATA}->{TYPE}}->{PUSH_FN_BODY}->($self, $e->{DATA}, $ndr, $var_name);
 668                 }
 669         }
 670
 671         if ($l->{TYPE} eq "POINTER" and $l->{POINTER_TYPE} eq "ignore") {
 672                 $self->pidl("/* [ignore] '$e->{NAME}' */");
 673         } elsif ($l->{TYPE} eq "POINTER" and $deferred) {
 674                 my $rel_var_name = $var_name;
 675                 if ($l->{POINTER_TYPE} ne "ref") {
 676                         $self->pidl("if ($var_name) {");
 677                         $self->indent;
 678                         if ($l->{POINTER_TYPE} eq "relative") {
 679                                 $self->pidl("NDR_CHECK(ndr_push_relative_ptr2_start($ndr, $rel_var_name));");
 680                         }
 681                         if ($l->{POINTER_TYPE} eq "relative_short") {
 682                                 $self->pidl("NDR_CHECK(ndr_push_short_relative_ptr2($ndr, $var_name));");
 683                         }
 684                 }
 685                 $var_name = get_value_of($var_name);
 686                 $self->ParseElementPushLevel($e, GetNextLevel($e, $l), $ndr, $var_name, $env, 1, 1);
 687
 688                 if ($l->{POINTER_TYPE} ne "ref") {
 689                         if ($l->{POINTER_TYPE} eq "relative") {
 690                                 $self->pidl("NDR_CHECK(ndr_push_relative_ptr2_end($ndr, $rel_var_name));");
 691                         }
 692                         $self->deindent;
 693                         $self->pidl("}");
 694                 }
 695         } elsif ($l->{TYPE} eq "ARRAY" and not has_fast_array($e,$l) and
 696                 not is_charset_array($e, $l)) {
 697                 my $length = ParseExpr($l->{LENGTH_IS}, $env, $e->{ORIGINAL});
 698                 my $counter = "cntr_$e->{NAME}_$l->{LEVEL_INDEX}";
 699
 700                 my $array_pointless = ($length eq "0");
 701
 702                 if ($array_pointless) {
 703                         warning($e->{ORIGINAL}, "pointless array `$e->{NAME}' will always have size 0");
 704                 }
 705
 706                 $var_name = get_array_element($var_name, $counter);
 707
 708                 if ((($primitives and not $l->{IS_DEFERRED}) or ($deferred and $l->{IS_DEFERRED})) and not $array_pointless) {
 709                         $self->pidl("for ($counter = 0; $counter < ($length); $counter++) {");
 710                         $self->indent;
 711                         $self->ParseElementPushLevel($e, GetNextLevel($e, $l), $ndr, $var_name, $env, 1, 0);
 712                         $self->deindent;
 713                         $self->pidl("}");
 714                 }
 715
 716                 if ($deferred and ContainsDeferred($e, $l) and not $array_pointless) {
 717                         $self->pidl("for ($counter = 0; $counter < ($length); $counter++) {");
 718                         $self->indent;
 719                         $self->ParseElementPushLevel($e, GetNextLevel($e, $l), $ndr, $var_name, $env, 0, 1);
 720                         $self->deindent;
 721                         $self->pidl("}");
 722                 }
 723         } elsif ($l->{TYPE} eq "SWITCH") {
 724                 my $nl = GetNextLevel($e,$l);
 725                 my $needs_deferred_switch = is_deferred_switch_non_empty($nl);
 726
 727                 # Avoid setting a switch value if it will not be
 728                 # consumed again in the NDR_BUFFERS pull
 729                 if ($needs_deferred_switch or !$deferred) {
 730                         $self->ParseSwitchPush($e, $l, $ndr, $var_name, $env);
 731                 }
 732                 $self->ParseElementPushLevel($e, GetNextLevel($e, $l), $ndr, $var_name, $env, $primitives, $deferred);
 733         }
 734 }
 735
 736 #####################################################################
 737 # parse scalars in a structure element
 738 sub ParseElementPush($$$$$$)
 739 {
 740         my ($self,$e,$ndr,$env,$primitives,$deferred) = @_;
 741         my $subndr = undef;
 742
 743         my $var_name = $env->{$e->{NAME}};
 744
 745         if (has_property($e, "skip") or has_property($e, "skip_noinit")) {
 746                 $self->pidl("/* [skip] '$var_name' */");
 747                 return;
 748         }
 749
 750         return if ContainsPipe($e, $e->{LEVELS}[0]);
 751
 752         return unless $primitives or ($deferred and ContainsDeferred($e, $e->{LEVELS}[0]));
 753
 754         # Representation type is different from transmit_as
 755         if ($e->{REPRESENTATION_TYPE} ne $e->{TYPE}) {
 756                 $self->pidl("{");
 757                 $self->indent;
 758                 my $transmit_name = "_transmit_$e->{NAME}";
 759                 $self->pidl(mapTypeName($e->{TYPE}) ." $transmit_name;");
 760                 $self->pidl("NDR_CHECK(ndr_$e->{REPRESENTATION_TYPE}_to_$e->{TYPE}($var_name, " . get_pointer_to($transmit_name) . "));");
 761                 $var_name = $transmit_name;
 762         }
 763
 764         $var_name = append_prefix($e, $var_name);
 765
 766         $self->start_flags($e, $ndr);
 767
 768         if (defined(my $value = has_property($e, "value"))) {
 769                 $var_name = ParseExpr($value, $env, $e->{ORIGINAL});
 770         }
 771
 772         $self->ParseElementPushLevel($e, $e->{LEVELS}[0], $ndr, $var_name, $env, $primitives, $deferred);
 773
 774         $self->end_flags($e, $ndr);
 775
 776         if ($e->{REPRESENTATION_TYPE} ne $e->{TYPE}) {
 777                 $self->deindent;
 778                 $self->pidl("}");
 779         }
 780 }
 781
 782 #####################################################################
 783 # parse a pointer in a struct element or function
 784 sub ParsePtrPush($$$$$)
 785 {
 786         my ($self,$e,$l,$ndr,$var_name) = @_;
 787
 788         if ($l->{POINTER_TYPE} eq "ref") {
 789                 if ($l->{LEVEL_INDEX} > 0) {
 790                         $self->pidl("if ($var_name == NULL) {");
 791                         $self->indent;
 792                         $self->pidl("return ndr_push_error($ndr, NDR_ERR_INVALID_POINTER, \"NULL [ref] pointer\");");
 793                         $self->deindent;
 794                         $self->pidl("}");
 795                 }
 796                 if ($l->{LEVEL} eq "EMBEDDED") {
 797                         $self->pidl("NDR_CHECK(ndr_push_ref_ptr(ndr)); /* $var_name */");
 798                 }
 799         } elsif ($l->{POINTER_TYPE} eq "relative") {
 800                 $self->pidl("NDR_CHECK(ndr_push_relative_ptr1($ndr, $var_name));");
 801         } elsif ($l->{POINTER_TYPE} eq "relative_short") {
 802                 $self->pidl("NDR_CHECK(ndr_push_short_relative_ptr1($ndr, $var_name));");
 803         } elsif ($l->{POINTER_TYPE} eq "unique") {
 804                 $self->pidl("NDR_CHECK(ndr_push_unique_ptr($ndr, $var_name));");
 805         } elsif ($l->{POINTER_TYPE} eq "full") {
 806                 $self->pidl("NDR_CHECK(ndr_push_full_ptr($ndr, $var_name));");
 807         } elsif ($l->{POINTER_TYPE} eq "ignore") {
 808                 # We don't want this pointer to appear on the wire at all
 809                 $self->pidl("NDR_CHECK(ndr_push_uint3264(ndr, NDR_SCALARS, 0));");
 810         } else {
 811                 die("Unhandled pointer type $l->{POINTER_TYPE}");
 812         }
 813 }
 814
 815 sub need_pointer_to($$$)
 816 {
 817         my ($e, $l, $scalar_only) = @_;
 818
 819         my $t;
 820         if (ref($l->{DATA_TYPE})) {
 821                 $t = "$l->{DATA_TYPE}->{TYPE}_$l->{DATA_TYPE}->{NAME}";
 822         } else {
 823                 $t = $l->{DATA_TYPE};
 824         }
 825
 826         if (not Parse::Pidl::Typelist::is_scalar($t)) {
 827                 return 1 if $scalar_only;
 828         }
 829
 830         my $arrays = 0;
 831
 832         foreach my $tl (@{$e->{LEVELS}}) {
 833                 last if $l == $tl;
 834                 if ($tl->{TYPE} eq "ARRAY") {
 835                         $arrays++;
 836                 }
 837         }
 838
 839         if (Parse::Pidl::Typelist::scalar_is_reference($t)) {
 840                 return 1 unless $arrays;
 841         }
 842
 843         return 0;
 844 }
 845
 846 sub ParseDataPrint($$$$$)
 847 {
 848         my ($self, $e, $l, $ndr, $var_name) = @_;
 849
 850         if (not ref($l->{DATA_TYPE}) or defined($l->{DATA_TYPE}->{NAME})) {
 851
 852                 if (need_pointer_to($e, $l, 1)) {
 853                         $var_name = get_pointer_to($var_name);
 854                 }
 855
 856                 $self->pidl(TypeFunctionName("ndr_print", $l->{DATA_TYPE})."($ndr, \"$e->{NAME}\", $var_name);");
 857         } else {
 858                 $self->ParseTypePrint($l->{DATA_TYPE}, $ndr, $var_name);
 859         }
 860 }
 861
 862 #####################################################################
 863 # print scalars in a structure element
 864 sub ParseElementPrint($$$$$)
 865 {
 866         my($self, $e, $ndr, $var_name, $env) = @_;
 867
 868         return if (has_property($e, "noprint"));
 869         my $cur_depth = 0;
 870         my $ignore_depth = 0xFFFF;
 871
 872         $self->start_flags($e, $ndr);
 873         if ($e->{REPRESENTATION_TYPE} ne $e->{TYPE}) {
 874                 $self->pidl("ndr_print_$e->{REPRESENTATION_TYPE}($ndr, \"$e->{NAME}\", $var_name);");
 875                 $self->end_flags($e, $ndr);
 876                 return;
 877         }
 878
 879         $var_name = append_prefix($e, $var_name);
 880
 881         if (defined(my $value = has_property($e, "value"))) {
 882                 $var_name = "($ndr->flags & LIBNDR_PRINT_SET_VALUES)?" . ParseExpr($value,$env, $e->{ORIGINAL}) . ":$var_name";
 883         }
 884
 885         foreach my $l (@{$e->{LEVELS}}) {
 886                 $cur_depth += 1;
 887
 888                 if ($cur_depth > $ignore_depth) {
 889                         next;
 890                 }
 891
 892                 if ($l->{TYPE} eq "POINTER") {
 893                         $self->pidl("ndr_print_ptr($ndr, \"$e->{NAME}\", $var_name);");
 894                         if ($l->{POINTER_TYPE} eq "ignore") {
 895                                 $self->pidl("/* [ignore] '$e->{NAME}' */");
 896                                 $ignore_depth = $cur_depth;
 897                                 last;
 898                         }
 899                         $self->pidl("$ndr->depth++;");
 900                         if ($l->{POINTER_TYPE} ne "ref") {
 901                                 $self->pidl("if ($var_name) {");
 902                                 $self->indent;
 903                         }
 904                         $var_name = get_value_of($var_name);
 905                 } elsif ($l->{TYPE} eq "ARRAY") {
 906                         my $length;
 907
 908                         if ($l->{IS_CONFORMANT} or $l->{IS_VARYING}) {
 909                                 $var_name = get_pointer_to($var_name);
 910                         }
 911
 912                         if ($l->{IS_ZERO_TERMINATED} and not defined($l->{LENGTH_IS})) {
 913                                 $length = "ndr_string_length($var_name, sizeof(*$var_name))";
 914                         } else {
 915                                 $length = ParseExprExt($l->{LENGTH_IS}, $env, $e->{ORIGINAL},
 916                                                         check_null_pointer($e, $env, sub { $self->pidl(shift); }, "return;"), check_fully_dereferenced($e, $env));
 917                         }
 918
 919                         if (is_charset_array($e,$l)) {
 920                                 $self->pidl("ndr_print_string($ndr, \"$e->{NAME}\", $var_name);");
 921                                 last;
 922                         } elsif (has_fast_array($e, $l)) {
 923                                 my $nl = GetNextLevel($e, $l);
 924                                 $self->pidl("ndr_print_array_$nl->{DATA_TYPE}($ndr, \"$e->{NAME}\", $var_name, $length);");
 925                                 last;
 926                         } else {
 927                                 my $counter = "cntr_$e->{NAME}_$l->{LEVEL_INDEX}";
 928
 929                                 $self->pidl("$ndr->print($ndr, \"%s: ARRAY(%\"PRIu32\")\", \"$e->{NAME}\", (uint32_t)($length));");
 930                                 $self->pidl("$ndr->depth++;");
 931                                 $self->pidl("for ($counter = 0; $counter < ($length); $counter++) {");
 932                                 $self->indent;
 933
 934                                 $var_name = get_array_element($var_name, $counter);
 935                         }
 936                 } elsif ($l->{TYPE} eq "DATA") {
 937                         $self->ParseDataPrint($e, $l, $ndr, $var_name);
 938                 } elsif ($l->{TYPE} eq "SWITCH") {
 939                         my $switch_var = ParseExprExt($l->{SWITCH_IS}, $env, $e->{ORIGINAL},
 940                                                 check_null_pointer($e, $env, sub { $self->pidl(shift); }, "return;"), check_fully_dereferenced($e, $env));
 941                         $self->pidl("ndr_print_set_switch_value($ndr, " . get_pointer_to($var_name) . ", $switch_var);");
 942                 }
 943         }
 944
 945         foreach my $l (reverse @{$e->{LEVELS}}) {
 946                 $cur_depth -= 1;
 947
 948                 if ($cur_depth > $ignore_depth) {
 949                         next;
 950                 }
 951
 952                 if ($l->{TYPE} eq "POINTER") {
 953                         if ($l->{POINTER_TYPE} eq "ignore") {
 954                                 next;
 955                         }
 956
 957                         if ($l->{POINTER_TYPE} ne "ref") {
 958                                 $self->deindent;
 959                                 $self->pidl("}");
 960                         }
 961                         $self->pidl("$ndr->depth--;");
 962                 } elsif (($l->{TYPE} eq "ARRAY")
 963                         and not is_charset_array($e,$l)
 964                         and not has_fast_array($e,$l)) {
 965                         $self->deindent;
 966                         $self->pidl("}");
 967                         $self->pidl("$ndr->depth--;");
 968                 }
 969         }
 970
 971         $self->end_flags($e, $ndr);
 972 }
 973
 974 #####################################################################
 975 # parse scalars in a structure element - pull size
 976 sub ParseSwitchPull($$$$$$)
 977 {
 978         my($self,$e,$l,$ndr,$var_name,$env) = @_;
 979         my $switch_var = ParseExprExt($l->{SWITCH_IS}, $env, $e->{ORIGINAL},
 980                 check_null_pointer($e, $env, sub { $self->pidl(shift); },
 981                                    "return ndr_pull_error($ndr, NDR_ERR_INVALID_POINTER, \"NULL Pointer for switch_is()\");"),
 982                 check_fully_dereferenced($e, $env));
 983
 984         $var_name = get_pointer_to($var_name);
 985         $self->pidl("NDR_CHECK(ndr_pull_set_switch_value($ndr, $var_name, $switch_var));");
 986 }
 987
 988 #####################################################################
 989 # push switch element
 990 sub ParseSwitchPush($$$$$$)
 991 {
 992         my($self,$e,$l,$ndr,$var_name,$env) = @_;
 993         my $switch_var = ParseExprExt($l->{SWITCH_IS}, $env, $e->{ORIGINAL},
 994                 check_null_pointer($e, $env, sub { $self->pidl(shift); },
 995                                    "return ndr_push_error($ndr, NDR_ERR_INVALID_POINTER, \"NULL Pointer for switch_is()\");"),
 996                 check_fully_dereferenced($e, $env));
 997
 998         $var_name = get_pointer_to($var_name);
 999         $self->pidl("NDR_CHECK(ndr_push_set_switch_value($ndr, $var_name, $switch_var));");
1000 }
1001
1002 sub ParseDataPull($$$$$$$)
1003 {
1004         my ($self,$e,$l,$ndr,$var_name,$primitives,$deferred) = @_;
1005
1006         if (not ref($l->{DATA_TYPE}) or defined($l->{DATA_TYPE}->{NAME})) {
1007
1008                 my $ndr_flags = CalcNdrFlags($l, $primitives, $deferred);
1009
1010                 if (need_pointer_to($e, $l, 0)) {
1011                         $var_name = get_pointer_to($var_name);
1012                 }
1013
1014                 $var_name = get_pointer_to($var_name);
1015
1016                 if (my $depth = has_property($e, "max_recursion")) {
1017                         my $d = parse_int($depth);
1018                         $self->pidl("NDR_RECURSION_CHECK($ndr, $d);");
1019                 }
1020                 $self->pidl("NDR_CHECK(".TypeFunctionName("ndr_pull", $l->{DATA_TYPE})."($ndr, $ndr_flags, $var_name));");
1021                 if (has_property($e, "max_recursion")) {
1022                         $self->pidl("NDR_RECURSION_UNWIND($ndr);");
1023                 }
1024
1025                 my $pl = GetPrevLevel($e, $l);
1026
1027                 my $range = has_property($e, "range");
1028                 if ($range and (not $pl or $pl->{TYPE} ne "ARRAY")) {
1029                         $var_name = get_value_of($var_name);
1030                         my $signed = Parse::Pidl::Typelist::is_signed($l->{DATA_TYPE});
1031                         my ($low, $high) = parse_range($range);
1032                         if ($low < 0 and not $signed) {
1033                                 warning(0, "$low is invalid for the range of an unsigned type");
1034                         }
1035                         if ($low == 0 and not $signed) {
1036                                 $self->pidl("if ($var_name > $high) {");
1037                         } else {
1038                                 $self->pidl("if ($var_name < $low || $var_name > $high) {");
1039                         }
1040
1041                         my $data_type = mapTypeName($l->{DATA_TYPE});
1042                         my $fmt = mapTypeSpecifier($data_type);
1043
1044                         if (!defined($fmt)) {
1045                                 if (getType($l->{DATA_TYPE})->{DATA}->{TYPE} eq "ENUM") {
1046                                         $data_type = "int";
1047                                         $fmt = "d";
1048                                 } else {
1049                                         die("Format ($data_type) not supported");
1050                                 }
1051                         }
1052
1053                         $self->pidl("\treturn ndr_pull_error($ndr, NDR_ERR_RANGE, \"value (%$fmt) out of range (%$fmt - %$fmt)\", ($data_type)($var_name), ($data_type)($low), ($data_type)($high));");
1054                         $self->pidl("}");
1055                 }
1056         } else {
1057                 $self->ParseTypePull($l->{DATA_TYPE}, $ndr, $var_name, $primitives, $deferred);
1058         }
1059 }
1060
1061 sub ParseDataPush($$$$$$$)
1062 {
1063         my ($self,$e,$l,$ndr,$var_name,$primitives,$deferred) = @_;
1064
1065         if (not ref($l->{DATA_TYPE}) or defined($l->{DATA_TYPE}->{NAME})) {
1066
1067                 my $ndr_flags = CalcNdrFlags($l, $primitives, $deferred);
1068
1069                 # strings are passed by value rather than reference
1070                 if (need_pointer_to($e, $l, 1)) {
1071                         $var_name = get_pointer_to($var_name);
1072                 }
1073
1074                 $self->pidl("NDR_CHECK(".TypeFunctionName("ndr_push", $l->{DATA_TYPE})."($ndr, $ndr_flags, $var_name));");
1075         } else {
1076                 $self->ParseTypePush($l->{DATA_TYPE}, $ndr, $var_name, $primitives, $deferred);
1077         }
1078 }
1079
1080 sub CalcNdrFlags($$$)
1081 {
1082         my ($l,$primitives,$deferred) = @_;
1083
1084         my $scalars = 0;
1085         my $buffers = 0;
1086
1087         # Add NDR_SCALARS if this one is deferred
1088         # and deferreds may be pushed
1089         $scalars = 1 if ($l->{IS_DEFERRED} and $deferred);
1090
1091         # Add NDR_SCALARS if this one is not deferred and
1092         # primitives may be pushed
1093         $scalars = 1 if (!$l->{IS_DEFERRED} and $primitives);
1094
1095         # Add NDR_BUFFERS if this one contains deferred stuff
1096         # and deferreds may be pushed
1097         $buffers = 1 if ($l->{CONTAINS_DEFERRED} and $deferred);
1098
1099         return "NDR_SCALARS|NDR_BUFFERS" if ($scalars and $buffers);
1100         return "NDR_SCALARS" if ($scalars);
1101         return "NDR_BUFFERS" if ($buffers);
1102         return undef;
1103 }
1104
1105 sub ParseMemCtxPullFlags($$$$)
1106 {
1107         my ($self, $e, $l) = @_;
1108
1109         return undef unless ($l->{TYPE} eq "POINTER" or $l->{TYPE} eq "ARRAY");
1110         return undef if (($l->{TYPE} eq "POINTER") and ($l->{POINTER_TYPE} eq "ignore"));
1111
1112         return undef unless ($l->{TYPE} ne "ARRAY" or ArrayDynamicallyAllocated($e,$l));
1113         return undef if has_fast_array($e, $l);
1114         return undef if is_charset_array($e, $l);
1115
1116         my $mem_flags = "0";
1117
1118         if (($l->{TYPE} eq "POINTER") and ($l->{POINTER_TYPE} eq "ref")) {
1119                 my $nl = GetNextLevel($e, $l);
1120                 return undef if ($nl->{TYPE} eq "PIPE");
1121                 return undef if ($nl->{TYPE} eq "ARRAY");
1122                 return undef if (($nl->{TYPE} eq "DATA") and ($nl->{DATA_TYPE} eq "string"));
1123
1124                 if ($l->{LEVEL} eq "TOP") {
1125                         $mem_flags = "LIBNDR_FLAG_REF_ALLOC";
1126                 }
1127         }
1128
1129         return $mem_flags;
1130 }
1131
1132 sub ParseMemCtxPullStart($$$$$)
1133 {
1134         my ($self, $e, $l, $ndr, $ptr_name) = @_;
1135
1136         my $mem_r_ctx = "_mem_save_$e->{NAME}_$l->{LEVEL_INDEX}";
1137         my $mem_c_ctx = $ptr_name;
1138         my $mem_c_flags = $self->ParseMemCtxPullFlags($e, $l);
1139
1140         return unless defined($mem_c_flags);
1141
1142         $self->pidl("$mem_r_ctx = NDR_PULL_GET_MEM_CTX($ndr);");
1143         $self->pidl("NDR_PULL_SET_MEM_CTX($ndr, $mem_c_ctx, $mem_c_flags);");
1144 }
1145
1146 sub ParseMemCtxPullEnd($$$$)
1147 {
1148         my ($self, $e, $l, $ndr) = @_;
1149
1150         my $mem_r_ctx = "_mem_save_$e->{NAME}_$l->{LEVEL_INDEX}";
1151         my $mem_r_flags = $self->ParseMemCtxPullFlags($e, $l);
1152
1153         return unless defined($mem_r_flags);
1154
1155         $self->pidl("NDR_PULL_SET_MEM_CTX($ndr, $mem_r_ctx, $mem_r_flags);");
1156 }
1157
1158 sub CheckStringTerminator($$$$$)
1159 {
1160         my ($self,$ndr,$e,$l,$length) = @_;
1161         my $nl = GetNextLevel($e, $l);
1162
1163         # Make sure last element is zero!
1164         $self->pidl("NDR_CHECK(ndr_check_string_terminator($ndr, $length, sizeof($nl->{DATA_TYPE}_t)));");
1165 }
1166
1167 sub ParseElementPullLevel
1168 {
1169         my($self,$e,$l,$ndr,$var_name,$env,$primitives,$deferred) = @_;
1170
1171         my $ndr_flags = CalcNdrFlags($l, $primitives, $deferred);
1172         my $array_length = undef;
1173
1174         if (has_property($e, "skip") or has_property($e, "skip_noinit")) {
1175                 $self->pidl("/* [skip] '$var_name' */");
1176                 if (not has_property($e, "skip_noinit")) {
1177                         $self->pidl("NDR_ZERO_STRUCT($var_name);");
1178                 }
1179                 return;
1180         }
1181
1182         if ($l->{TYPE} eq "ARRAY" and ($l->{IS_VARYING} or $l->{IS_CONFORMANT})) {
1183                 $var_name = get_pointer_to($var_name);
1184         }
1185
1186         # Only pull something if there's actually something to be pulled
1187         if (defined($ndr_flags)) {
1188                 if ($l->{TYPE} eq "SUBCONTEXT") {
1189                         my $subndr = $self->ParseSubcontextPullStart($e, $l, $ndr, $env);
1190                         $self->ParseElementPullLevel($e, GetNextLevel($e,$l), $subndr, $var_name, $env, 1, 1);
1191                         $self->ParseSubcontextPullEnd($e, $l, $ndr, $env);
1192                 } elsif ($l->{TYPE} eq "ARRAY") {
1193                         my $length = $self->ParseArrayPullHeader($e, $l, $ndr, $var_name, $env);
1194                         $array_length = $length;
1195
1196                         my $nl = GetNextLevel($e, $l);
1197
1198                         if (is_charset_array($e,$l)) {
1199                                 if ($l->{IS_ZERO_TERMINATED}) {
1200                                         $self->CheckStringTerminator($ndr, $e, $l, $length);
1201                                 }
1202                                 if ($l->{IS_TO_NULL}) {
1203                                         $self->pidl("NDR_CHECK(ndr_pull_charset_to_null($ndr, $ndr_flags, ".get_pointer_to($var_name).", $length, sizeof(" . mapTypeName($nl->{DATA_TYPE}) . "), CH_$e->{PROPERTIES}->{charset}));");
1204                                 } else {
1205                                         $self->pidl("NDR_CHECK(ndr_pull_charset($ndr, $ndr_flags, ".get_pointer_to($var_name).", $length, sizeof(" . mapTypeName($nl->{DATA_TYPE}) . "), CH_$e->{PROPERTIES}->{charset}));");
1206                                 }
1207                                 return;
1208                         } elsif (has_fast_array($e, $l)) {
1209                                 if ($l->{IS_ZERO_TERMINATED}) {
1210                                         $self->CheckStringTerminator($ndr,$e,$l,$length);
1211                                 }
1212                                 $self->pidl("NDR_CHECK(ndr_pull_array_$nl->{DATA_TYPE}($ndr, $ndr_flags, $var_name, $length));");
1213                                 return;
1214                         }
1215                 } elsif ($l->{TYPE} eq "POINTER") {
1216                         $self->ParsePtrPull($e, $l, $ndr, $var_name);
1217                 } elsif ($l->{TYPE} eq "DATA") {
1218                         $self->ParseDataPull($e, $l, $ndr, $var_name, $primitives, $deferred);
1219                 } elsif ($l->{TYPE} eq "TYPEDEF") {
1220                         $typefamily{$e->{DATA}->{TYPE}}->{PULL_FN_BODY}->($self, $e->{DATA}, $ndr, $var_name);
1221                 }
1222         }
1223
1224         # add additional constructions
1225         if ($l->{TYPE} eq "POINTER" and $l->{POINTER_TYPE} eq "ignore") {
1226                 $self->pidl("/* [ignore] '$e->{NAME}' */");
1227         } elsif ($l->{TYPE} eq "POINTER" and $deferred) {
1228                 if ($l->{POINTER_TYPE} ne "ref") {
1229                         $self->pidl("if ($var_name) {");
1230                         $self->indent;
1231
1232                         if ($l->{POINTER_TYPE} eq "relative" or $l->{POINTER_TYPE} eq "relative_short") {
1233                                 $self->pidl("uint32_t _relative_save_offset;");
1234                                 $self->pidl("_relative_save_offset = $ndr->offset;");
1235                                 $self->pidl("NDR_CHECK(ndr_pull_relative_ptr2($ndr, $var_name));");
1236                         }
1237                 }
1238
1239                 $self->ParseMemCtxPullStart($e, $l, $ndr, $var_name);
1240
1241                 $var_name = get_value_of($var_name);
1242                 $self->ParseElementPullLevel($e, GetNextLevel($e,$l), $ndr, $var_name, $env, 1, 1);
1243
1244                 $self->ParseMemCtxPullEnd($e, $l, $ndr);
1245
1246                 if ($l->{POINTER_TYPE} ne "ref") {
1247                         if ($l->{POINTER_TYPE} eq "relative" or $l->{POINTER_TYPE} eq "relative_short") {
1248                                 $self->pidl("if ($ndr->offset > $ndr->relative_highest_offset) {");
1249                                 $self->indent;
1250                                 $self->pidl("$ndr->relative_highest_offset = $ndr->offset;");
1251                                 $self->deindent;
1252                                 $self->pidl("}");
1253                                 $self->pidl("$ndr->offset = _relative_save_offset;");
1254                         }
1255                         $self->deindent;
1256                         $self->pidl("}");
1257                 }
1258         } elsif ($l->{TYPE} eq "ARRAY" and
1259                         not has_fast_array($e,$l) and not is_charset_array($e, $l)) {
1260                 my $length = $array_length;
1261                 my $counter = "cntr_$e->{NAME}_$l->{LEVEL_INDEX}";
1262                 my $array_name = $var_name;
1263
1264                 if (not defined($length)) {
1265                         $length = $self->ParseArrayPullGetLength($e, $l, $ndr, $var_name, $env);
1266                 }
1267
1268                 $var_name = get_array_element($var_name, $counter);
1269
1270                 $self->ParseMemCtxPullStart($e, $l, $ndr, $array_name);
1271
1272                 if (($primitives and not $l->{IS_DEFERRED}) or ($deferred and $l->{IS_DEFERRED})) {
1273                         my $nl = GetNextLevel($e,$l);
1274
1275                         if ($l->{IS_ZERO_TERMINATED}) {
1276                                 $self->CheckStringTerminator($ndr,$e,$l,$length);
1277                         }
1278
1279                         $self->pidl("for ($counter = 0; $counter < ($length); $counter++) {");
1280                         $self->indent;
1281                         $self->ParseElementPullLevel($e, $nl, $ndr, $var_name, $env, 1, 0);
1282                         $self->deindent;
1283                         $self->pidl("}");
1284                 }
1285
1286                 if ($deferred and ContainsDeferred($e, $l)) {
1287                         $self->pidl("for ($counter = 0; $counter < ($length); $counter++) {");
1288                         $self->defer("for ($counter = 0; $counter < ($length); $counter++) {");
1289                         $self->defer_indent;
1290                         $self->indent;
1291                         $self->ParseElementPullLevel($e,GetNextLevel($e,$l), $ndr, $var_name, $env, 0, 1);
1292                         $self->deindent;
1293                         $self->defer_deindent;
1294                         $self->pidl("}");
1295                         $self->defer("}");
1296                 }
1297
1298                 $self->ParseMemCtxPullEnd($e, $l, $ndr);
1299
1300         } elsif ($l->{TYPE} eq "SWITCH") {
1301                 my $nl = GetNextLevel($e,$l);
1302                 my $needs_deferred_switch = is_deferred_switch_non_empty($nl);
1303
1304                 # Avoid setting a switch value if it will not be
1305                 # consumed again in the NDR_BUFFERS pull
1306                 if ($needs_deferred_switch or !$deferred) {
1307                         $self->ParseSwitchPull($e, $l, $ndr, $var_name, $env);
1308                 }
1309                 $self->ParseElementPullLevel($e, $nl, $ndr, $var_name, $env, $primitives, $deferred);
1310         }
1311 }
1312
1313 #####################################################################
1314 # parse scalars in a structure element - pull size
1315 sub ParseElementPull($$$$$$)
1316 {
1317         my($self,$e,$ndr,$env,$primitives,$deferred) = @_;
1318
1319         my $var_name = $env->{$e->{NAME}};
1320         my $represent_name;
1321         my $transmit_name;
1322
1323         return if ContainsPipe($e, $e->{LEVELS}[0]);
1324
1325         return unless $primitives or ($deferred and ContainsDeferred($e, $e->{LEVELS}[0]));
1326
1327         if ($e->{REPRESENTATION_TYPE} ne $e->{TYPE}) {
1328                 $self->pidl("{");
1329                 $self->indent;
1330                 $represent_name = $var_name;
1331                 $transmit_name = "_transmit_$e->{NAME}";
1332                 $var_name = $transmit_name;
1333                 $self->pidl(mapTypeName($e->{TYPE})." $var_name;");
1334         }
1335
1336         $var_name = append_prefix($e, $var_name);
1337
1338         $self->start_flags($e, $ndr);
1339
1340         $self->ParseElementPullLevel($e,$e->{LEVELS}[0],$ndr,$var_name,$env,$primitives,$deferred);
1341
1342         $self->end_flags($e, $ndr);
1343
1344         # Representation type is different from transmit_as
1345         if ($e->{REPRESENTATION_TYPE} ne $e->{TYPE}) {
1346                 $self->pidl("NDR_CHECK(ndr_$e->{TYPE}_to_$e->{REPRESENTATION_TYPE}($transmit_name, ".get_pointer_to($represent_name)."));");
1347                 $self->deindent;
1348                 $self->pidl("}");
1349         }
1350 }
1351
1352 #####################################################################
1353 # parse a pointer in a struct element or function
1354 sub ParsePtrPull($$$$$)
1355 {
1356         my($self, $e,$l,$ndr,$var_name) = @_;
1357
1358         my $nl = GetNextLevel($e, $l);
1359         my $next_is_array = ($nl->{TYPE} eq "ARRAY");
1360         my $next_is_string = (($nl->{TYPE} eq "DATA") and
1361                                                  ($nl->{DATA_TYPE} eq "string"));
1362
1363         if ($l->{POINTER_TYPE} eq "ref" and $l->{LEVEL} eq "TOP") {
1364
1365                 if (!$next_is_array and !$next_is_string) {
1366                         $self->pidl("if ($ndr->flags & LIBNDR_FLAG_REF_ALLOC) {");
1367                         $self->pidl("\tNDR_PULL_ALLOC($ndr, $var_name);");
1368                         $self->pidl("}");
1369                 }
1370
1371                 return;
1372         } elsif ($l->{POINTER_TYPE} eq "ref" and $l->{LEVEL} eq "EMBEDDED") {
1373                 $self->pidl("NDR_CHECK(ndr_pull_ref_ptr($ndr, &_ptr_$e->{NAME}));");
1374         } elsif (($l->{POINTER_TYPE} eq "unique") or
1375                  ($l->{POINTER_TYPE} eq "relative") or
1376                  ($l->{POINTER_TYPE} eq "full")) {
1377                 $self->pidl("NDR_CHECK(ndr_pull_generic_ptr($ndr, &_ptr_$e->{NAME}));");
1378         } elsif ($l->{POINTER_TYPE} eq "relative_short") {
1379                 $self->pidl("NDR_CHECK(ndr_pull_relative_ptr_short($ndr, &_ptr_$e->{NAME}));");
1380         } elsif ($l->{POINTER_TYPE} eq "ignore") {
1381                 #We want to consume the pointer bytes, but ignore the pointer value
1382                 $self->pidl("NDR_CHECK(ndr_pull_uint3264(ndr, NDR_SCALARS, &_ptr_$e->{NAME}));");
1383                 $self->pidl("_ptr_$e->{NAME} = 0;");
1384         } else {
1385                 die("Unhandled pointer type $l->{POINTER_TYPE}");
1386         }
1387
1388         $self->pidl("if (_ptr_$e->{NAME}) {");
1389         $self->indent;
1390
1391         if ($l->{POINTER_TYPE} eq "ignore") {
1392                 # Don't do anything, we don't want to do the
1393                 # allocation, as we forced it to NULL just above, and
1394                 # we may not know the declared type anyway.
1395         } else {
1396                 # Don't do this for arrays, they're allocated at the actual level
1397                 # of the array
1398                 unless ($next_is_array or $next_is_string) {
1399                        $self->pidl("NDR_PULL_ALLOC($ndr, $var_name);");
1400                 } else {
1401                        # FIXME: Yes, this is nasty.
1402                        # We allocate an array twice
1403                        # - once just to indicate that it's there,
1404                        # - then the real allocation...
1405                        $self->pidl("NDR_PULL_ALLOC($ndr, $var_name);");
1406                 }
1407         }
1408
1409         #$self->pidl("memset($var_name, 0, sizeof($var_name));");
1410         if ($l->{POINTER_TYPE} eq "relative" or $l->{POINTER_TYPE} eq "relative_short") {
1411                 $self->pidl("NDR_CHECK(ndr_pull_relative_ptr1($ndr, $var_name, _ptr_$e->{NAME}));");
1412         }
1413         $self->deindent;
1414         $self->pidl("} else {");
1415         $self->pidl("\t$var_name = NULL;");
1416         $self->pidl("}");
1417 }
1418
1419 sub CheckRefPtrs($$$$)
1420 {
1421         my ($self,$e,$ndr,$env) = @_;
1422
1423         return if ContainsPipe($e, $e->{LEVELS}[0]);
1424         return if ($e->{LEVELS}[0]->{TYPE} ne "POINTER");
1425         return if ($e->{LEVELS}[0]->{POINTER_TYPE} ne "ref");
1426
1427         my $var_name = $env->{$e->{NAME}};
1428         $var_name = append_prefix($e, $var_name);
1429
1430         $self->pidl("if ($var_name == NULL) {");
1431         $self->indent;
1432         $self->pidl("return ndr_push_error($ndr, NDR_ERR_INVALID_POINTER, \"NULL [ref] pointer\");");
1433         $self->deindent;
1434         $self->pidl("}");
1435 }
1436
1437 sub ParseStructPushPrimitives($$$$$)
1438 {
1439         my ($self, $struct, $ndr, $varname, $env) = @_;
1440
1441         $self->CheckRefPtrs($_, $ndr, $env) foreach (@{$struct->{ELEMENTS}});
1442
1443         # see if the structure contains a conformant array. If it
1444         # does, then it must be the last element of the structure, and
1445         # we need to push the conformant length early, as it fits on
1446         # the wire before the structure (and even before the structure
1447         # alignment)
1448         if (defined($struct->{SURROUNDING_ELEMENT})) {
1449                 my $e = $struct->{SURROUNDING_ELEMENT};
1450
1451                 if (defined($e->{LEVELS}[0]) and
1452                         $e->{LEVELS}[0]->{TYPE} eq "ARRAY") {
1453                         my $size;
1454
1455                         if ($e->{LEVELS}[0]->{IS_ZERO_TERMINATED}) {
1456                                 if (has_property($e, "charset")) {
1457                                         $size = "ndr_charset_length($varname->$e->{NAME}, CH_$e->{PROPERTIES}->{charset})";
1458                                 } else {
1459                                         $size = "ndr_string_length($varname->$e->{NAME}, sizeof(*$varname->$e->{NAME}))";
1460                                 }
1461                                 if (defined($e->{LEVELS}[0]->{SIZE_IS})) {
1462                                         $size = ParseExpr($e->{LEVELS}[0]->{SIZE_IS}, $env, $e->{ORIGINAL});
1463                                 }
1464                         } else {
1465                                 $size = ParseExpr($e->{LEVELS}[0]->{SIZE_IS}, $env, $e->{ORIGINAL});
1466                         }
1467
1468                         $self->pidl("NDR_CHECK(ndr_push_uint3264($ndr, NDR_SCALARS, $size));");
1469                 } else {
1470                         $self->pidl("NDR_CHECK(ndr_push_uint3264($ndr, NDR_SCALARS, ndr_string_array_size($ndr, $varname->$e->{NAME})));");
1471                 }
1472         }
1473
1474         $self->pidl("NDR_CHECK(ndr_push_align($ndr, $struct->{ALIGN}));");
1475
1476         if (defined($struct->{PROPERTIES}{relative_base})) {
1477                 # set the current offset as base for relative pointers
1478                 # and store it based on the toplevel struct/union
1479                 $self->pidl("NDR_CHECK(ndr_push_setup_relative_base_offset1($ndr, $varname, $ndr->offset));");
1480         }
1481
1482         $self->ParseElementPush($_, $ndr, $env, 1, 0) foreach (@{$struct->{ELEMENTS}});
1483
1484         $self->pidl("NDR_CHECK(ndr_push_trailer_align($ndr, $struct->{ALIGN}));");
1485 }
1486
1487 sub ParseStructPushDeferred($$$$)
1488 {
1489         my ($self, $struct, $ndr, $varname, $env) = @_;
1490         if (defined($struct->{PROPERTIES}{relative_base})) {
1491                 # retrieve the current offset as base for relative pointers
1492                 # based on the toplevel struct/union
1493                 $self->pidl("NDR_CHECK(ndr_push_setup_relative_base_offset2($ndr, $varname));");
1494         }
1495         $self->ParseElementPush($_, $ndr, $env, 0, 1) foreach (@{$struct->{ELEMENTS}});
1496 }
1497
1498 #####################################################################
1499 # parse a struct
1500 sub ParseStructPush($$$$)
1501 {
1502         my ($self, $struct, $ndr, $varname) = @_;
1503
1504         return unless defined($struct->{ELEMENTS});
1505
1506         my $env = GenerateStructEnv($struct, $varname);
1507
1508         EnvSubstituteValue($env, $struct);
1509
1510         $self->DeclareArrayVariablesNoZero($_, $env) foreach (@{$struct->{ELEMENTS}});
1511
1512         $self->start_flags($struct, $ndr);
1513
1514         $self->pidl("NDR_PUSH_CHECK_FLAGS(ndr, ndr_flags);");
1515         $self->pidl("if (ndr_flags & NDR_SCALARS) {");
1516         $self->indent;
1517         $self->ParseStructPushPrimitives($struct, $ndr, $varname, $env);
1518         $self->deindent;
1519         $self->pidl("}");
1520
1521         $self->pidl("if (ndr_flags & NDR_BUFFERS) {");
1522         $self->indent;
1523         $self->ParseStructPushDeferred($struct, $ndr, $varname, $env);
1524         $self->deindent;
1525         $self->pidl("}");
1526
1527         $self->end_flags($struct, $ndr);
1528 }
1529
1530 #####################################################################
1531 # generate a push function for an enum
1532 sub ParseEnumPush($$$$)
1533 {
1534         my($self,$enum,$ndr,$varname) = @_;
1535         my($type_fn) = $enum->{BASE_TYPE};
1536
1537         $self->start_flags($enum, $ndr);
1538         $self->pidl("NDR_CHECK(ndr_push_enum_$type_fn($ndr, NDR_SCALARS, $varname));");
1539         $self->end_flags($enum, $ndr);
1540 }
1541
1542 #####################################################################
1543 # generate a pull function for an enum
1544 sub ParseEnumPull($$$$)
1545 {
1546         my($self,$enum,$ndr,$varname) = @_;
1547         my($type_fn) = $enum->{BASE_TYPE};
1548         my($type_v_decl) = mapTypeName($type_fn);
1549
1550         $self->pidl("$type_v_decl v;");
1551         $self->start_flags($enum, $ndr);
1552         $self->pidl("NDR_CHECK(ndr_pull_enum_$type_fn($ndr, NDR_SCALARS, &v));");
1553         $self->pidl("*$varname = v;");
1554
1555         $self->end_flags($enum, $ndr);
1556 }
1557
1558 #####################################################################
1559 # generate a print function for an enum
1560 sub ParseEnumPrint($$$$$)
1561 {
1562         my($self,$enum,$ndr,$name,$varname) = @_;
1563
1564         $self->pidl("const char *val = NULL;");
1565         $self->pidl("");
1566
1567         $self->start_flags($enum, $ndr);
1568
1569         $self->pidl("switch ($varname) {");
1570         $self->indent;
1571         my $els = \@{$enum->{ELEMENTS}};
1572         foreach my $i (0 .. $#{$els}) {
1573                 my $e = ${$els}[$i];
1574                 chomp $e;
1575                 if ($e =~ /^(.*)=/) {
1576                         $e = $1;
1577                 }
1578                 $self->pidl("case $e: val = \"$e\"; break;");
1579         }
1580
1581         $self->deindent;
1582         $self->pidl("}");
1583
1584         $self->pidl("ndr_print_enum($ndr, name, \"$enum->{TYPE}\", val, $varname);");
1585
1586         $self->end_flags($enum, $ndr);
1587 }
1588
1589 sub DeclEnum($$$$)
1590 {
1591         my ($e,$t,$name,$varname) = @_;
1592         return "enum $name " .
1593                 ($t eq "pull"?"*":"") . $varname;
1594 }
1595
1596 $typefamily{ENUM} = {
1597         DECL => \&DeclEnum,
1598         PUSH_FN_BODY => \&ParseEnumPush,
1599         PULL_FN_BODY => \&ParseEnumPull,
1600         PRINT_FN_BODY => \&ParseEnumPrint,
1601 };
1602
1603 #####################################################################
1604 # generate a push function for a bitmap
1605 sub ParseBitmapPush($$$$)
1606 {
1607         my($self,$bitmap,$ndr,$varname) = @_;
1608         my($type_fn) = $bitmap->{BASE_TYPE};
1609
1610         $self->start_flags($bitmap, $ndr);
1611
1612         $self->pidl("NDR_CHECK(ndr_push_$type_fn($ndr, NDR_SCALARS, $varname));");
1613
1614         $self->end_flags($bitmap, $ndr);
1615 }
1616
1617 #####################################################################
1618 # generate a pull function for an bitmap
1619 sub ParseBitmapPull($$$$)
1620 {
1621         my($self,$bitmap,$ndr,$varname) = @_;
1622         my $type_fn = $bitmap->{BASE_TYPE};
1623         my($type_decl) = mapTypeName($bitmap->{BASE_TYPE});
1624
1625         $self->pidl("$type_decl v;");
1626         $self->start_flags($bitmap, $ndr);
1627         $self->pidl("NDR_CHECK(ndr_pull_$type_fn($ndr, NDR_SCALARS, &v));");
1628         $self->pidl("*$varname = v;");
1629
1630         $self->end_flags($bitmap, $ndr);
1631 }
1632
1633 #####################################################################
1634 # generate a print function for an bitmap
1635 sub ParseBitmapPrintElement($$$$$$)
1636 {
1637         my($self,$e,$bitmap,$ndr,$name,$varname) = @_;
1638         my($type_decl) = mapTypeName($bitmap->{BASE_TYPE});
1639         my($type_fn) = $bitmap->{BASE_TYPE};
1640         my($flag);
1641
1642         if ($e =~ /^(\w+) .*$/) {
1643                 $flag = "$1";
1644         } else {
1645                 die "Bitmap: \"$name\" invalid Flag: \"$e\"";
1646         }
1647
1648         $self->pidl("ndr_print_bitmap_flag($ndr, sizeof($type_decl), \"$flag\", $flag, $varname);");
1649 }
1650
1651 #####################################################################
1652 # generate a print function for an bitmap
1653 sub ParseBitmapPrint($$$$$)
1654 {
1655         my($self,$bitmap,$ndr,$name,$varname) = @_;
1656         my($type_decl) = mapTypeName($bitmap->{TYPE});
1657         my($type_fn) = $bitmap->{BASE_TYPE};
1658
1659         $self->start_flags($bitmap, $ndr);
1660
1661         $self->pidl("ndr_print_$type_fn($ndr, name, $varname);");
1662
1663         $self->pidl("$ndr->depth++;");
1664         foreach my $e (@{$bitmap->{ELEMENTS}}) {
1665                 $self->ParseBitmapPrintElement($e, $bitmap, $ndr, $name, $varname);
1666         }
1667         $self->pidl("$ndr->depth--;");
1668
1669         $self->end_flags($bitmap, $ndr);
1670 }
1671
1672 sub DeclBitmap($$$$)
1673 {
1674         my ($e,$t,$name,$varname) = @_;
1675         return mapTypeName(Parse::Pidl::Typelist::bitmap_type_fn($e)) .
1676                 ($t eq "pull"?" *":" ") . $varname;
1677 }
1678
1679 $typefamily{BITMAP} = {
1680         DECL => \&DeclBitmap,
1681         PUSH_FN_BODY => \&ParseBitmapPush,
1682         PULL_FN_BODY => \&ParseBitmapPull,
1683         PRINT_FN_BODY => \&ParseBitmapPrint,
1684 };
1685
1686 #####################################################################
1687 # generate a struct print function
1688 sub ParseStructPrint($$$$$)
1689 {
1690         my($self,$struct,$ndr,$name,$varname) = @_;
1691
1692         return unless defined $struct->{ELEMENTS};
1693
1694         my $env = GenerateStructEnv($struct, $varname);
1695
1696         $self->DeclareArrayVariables($_) foreach (@{$struct->{ELEMENTS}});
1697
1698         $self->pidl("ndr_print_struct($ndr, name, \"$name\");");
1699         $self->pidl("if (r == NULL) { ndr_print_null($ndr); return; }");
1700
1701         $self->start_flags($struct, $ndr);
1702
1703         $self->pidl("$ndr->depth++;");
1704
1705         $self->ParseElementPrint($_, $ndr, $env->{$_->{NAME}}, $env)
1706                 foreach (@{$struct->{ELEMENTS}});
1707         $self->pidl("$ndr->depth--;");
1708
1709         $self->end_flags($struct, $ndr);
1710 }
1711
1712 sub DeclarePtrVariables($$)
1713 {
1714         my ($self,$e) = @_;
1715
1716         if (has_property($e, "skip") or has_property($e, "skip_noinit")) {
1717                 return;
1718         }
1719
1720         foreach my $l (@{$e->{LEVELS}}) {
1721                 my $size = 32;
1722                 if ($l->{TYPE} eq "POINTER" and
1723                         not ($l->{POINTER_TYPE} eq "ref" and $l->{LEVEL} eq "TOP")) {
1724                         if ($l->{POINTER_TYPE} eq "relative_short") {
1725                                 $size = 16;
1726                         }
1727                         $self->pidl("uint${size}_t _ptr_$e->{NAME};");
1728                         last;
1729                 }
1730         }
1731 }
1732
1733 sub DeclareArrayVariables($$;$)
1734 {
1735         my ($self,$e,$pull) = @_;
1736
1737         if (has_property($e, "skip") or has_property($e, "skip_noinit")) {
1738                 return;
1739         }
1740
1741         foreach my $l (@{$e->{LEVELS}}) {
1742                 next if ($l->{TYPE} ne "ARRAY");
1743                 if (defined($pull)) {
1744                         $self->pidl("uint32_t size_$e->{NAME}_$l->{LEVEL_INDEX} = 0;");
1745                         if ($l->{IS_VARYING}) {
1746                                 $self->pidl("uint32_t length_$e->{NAME}_$l->{LEVEL_INDEX} = 0;");
1747                         }
1748                 }
1749                 next if has_fast_array($e,$l);
1750                 next if is_charset_array($e,$l);
1751                 $self->pidl("uint32_t cntr_$e->{NAME}_$l->{LEVEL_INDEX};");
1752         }
1753 }
1754
1755 sub DeclareArrayVariablesNoZero($$$)
1756 {
1757         my ($self,$e,$env) = @_;
1758
1759         if (has_property($e, "skip") or has_property($e, "skip_noinit")) {
1760                 return;
1761         }
1762
1763         foreach my $l (@{$e->{LEVELS}}) {
1764                 next if ($l->{TYPE} ne "ARRAY");
1765                 next if has_fast_array($e,$l);
1766                 next if is_charset_array($e,$l);
1767                 my $length = ParseExpr($l->{LENGTH_IS}, $env, $e->{ORIGINAL});
1768                 if ($length eq "0") {
1769                         warning($e->{ORIGINAL}, "pointless array cntr: 'cntr_$e->{NAME}_$l->{LEVEL_INDEX}': length=$length");
1770                 } else {
1771                         $self->pidl("uint32_t cntr_$e->{NAME}_$l->{LEVEL_INDEX};");
1772                 }
1773         }
1774 }
1775
1776 sub DeclareMemCtxVariables($$)
1777 {
1778         my ($self,$e) = @_;
1779
1780         if (has_property($e, "skip") or has_property($e, "skip_noinit")) {
1781                 return;
1782         }
1783
1784         foreach my $l (@{$e->{LEVELS}}) {
1785                 my $mem_flags = $self->ParseMemCtxPullFlags($e, $l);
1786
1787                 if (($l->{TYPE} eq "POINTER") and ($l->{POINTER_TYPE} eq "ignore")) {
1788                         last;
1789                 }
1790
1791                 if (defined($mem_flags)) {
1792                         $self->pidl("TALLOC_CTX *_mem_save_$e->{NAME}_$l->{LEVEL_INDEX} = NULL;");
1793                 }
1794         }
1795 }
1796
1797 sub ParseStructPullPrimitives($$$$$)
1798 {
1799         my($self,$struct,$ndr,$varname,$env) = @_;
1800
1801         if (defined $struct->{SURROUNDING_ELEMENT}) {
1802                 $self->pidl("NDR_CHECK(ndr_pull_array_size($ndr, &$varname->$struct->{SURROUNDING_ELEMENT}->{NAME}));");
1803         }
1804
1805         $self->pidl("NDR_CHECK(ndr_pull_align($ndr, $struct->{ALIGN}));");
1806
1807         if (defined($struct->{PROPERTIES}{relative_base})) {
1808                 # set the current offset as base for relative pointers
1809                 # and store it based on the toplevel struct/union
1810                 $self->pidl("NDR_CHECK(ndr_pull_setup_relative_base_offset1($ndr, $varname, $ndr->offset));");
1811         }
1812
1813         $self->ParseElementPull($_, $ndr, $env, 1, 0) foreach (@{$struct->{ELEMENTS}});
1814
1815         $self->add_deferred();
1816
1817         $self->pidl("NDR_CHECK(ndr_pull_trailer_align($ndr, $struct->{ALIGN}));");
1818 }
1819
1820 sub ParseStructPullDeferred($$$$$)
1821 {
1822         my ($self,$struct,$ndr,$varname,$env) = @_;
1823
1824         if (defined($struct->{PROPERTIES}{relative_base})) {
1825                 # retrieve the current offset as base for relative pointers
1826                 # based on the toplevel struct/union
1827                 $self->pidl("NDR_CHECK(ndr_pull_setup_relative_base_offset2($ndr, $varname));");
1828         }
1829         foreach my $e (@{$struct->{ELEMENTS}}) {
1830                 $self->ParseElementPull($e, $ndr, $env, 0, 1);
1831         }
1832
1833         $self->add_deferred();
1834 }
1835
1836 #####################################################################
1837 # parse a struct - pull side
1838 sub ParseStructPull($$$$)
1839 {
1840         my($self,$struct,$ndr,$varname) = @_;
1841
1842         return unless defined $struct->{ELEMENTS};
1843
1844         # declare any internal pointers we need
1845         foreach my $e (@{$struct->{ELEMENTS}}) {
1846                 $self->DeclarePtrVariables($e);
1847                 $self->DeclareArrayVariables($e, "pull");
1848                 $self->DeclareMemCtxVariables($e);
1849         }
1850
1851         $self->start_flags($struct, $ndr);
1852
1853         my $env = GenerateStructEnv($struct, $varname);
1854
1855         $self->pidl("NDR_PULL_CHECK_FLAGS(ndr, ndr_flags);");
1856         $self->pidl("if (ndr_flags & NDR_SCALARS) {");
1857         $self->indent;
1858         $self->ParseStructPullPrimitives($struct,$ndr,$varname,$env);
1859         $self->deindent;
1860         $self->pidl("}");
1861         $self->pidl("if (ndr_flags & NDR_BUFFERS) {");
1862         $self->indent;
1863         $self->ParseStructPullDeferred($struct,$ndr,$varname,$env);
1864         $self->deindent;
1865         $self->pidl("}");
1866
1867         $self->end_flags($struct, $ndr);
1868 }
1869
1870 #####################################################################
1871 # calculate size of ndr struct
1872 sub ParseStructNdrSize($$$$)
1873 {
1874         my ($self,$t, $name, $varname) = @_;
1875         my $sizevar;
1876
1877         if (my $flags = has_property($t, "flag")) {
1878                 $self->pidl("flags |= $flags;");
1879         }
1880         $self->pidl("return ndr_size_struct($varname, flags, (ndr_push_flags_fn_t)ndr_push_$name);");
1881 }
1882
1883 sub DeclStruct($$$$)
1884 {
1885         my ($e,$t,$name,$varname) = @_;
1886         if ($t eq "base") {
1887                 return "struct $name $varname";
1888         }
1889         return ($t ne "pull"?"const ":"") . "struct $name *$varname";
1890 }
1891
1892 sub ArgsStructNdrSize($$$)
1893 {
1894         my ($d, $name, $varname) = @_;
1895         return "const struct $name *$varname, libndr_flags flags";
1896 }
1897
1898 $typefamily{STRUCT} = {
1899         PUSH_FN_BODY => \&ParseStructPush,
1900         DECL => \&DeclStruct,
1901         PULL_FN_BODY => \&ParseStructPull,
1902         PRINT_FN_BODY => \&ParseStructPrint,
1903         SIZE_FN_BODY => \&ParseStructNdrSize,
1904         SIZE_FN_ARGS => \&ArgsStructNdrSize,
1905 };
1906
1907 #####################################################################
1908 # calculate size of ndr struct
1909 sub ParseUnionNdrSize($$$)
1910 {
1911         my ($self, $t, $name, $varname) = @_;
1912         my $sizevar;
1913
1914         if (my $flags = has_property($t, "flag")) {
1915                 $self->pidl("flags |= $flags;");
1916         }
1917
1918         $self->pidl("return ndr_size_union($varname, flags, level, (ndr_push_flags_fn_t)ndr_push_$name);");
1919 }
1920
1921 sub ParseUnionPushPrimitives($$$$)
1922 {
1923         my ($self, $e, $ndr ,$varname) = @_;
1924
1925         my $have_default = 0;
1926
1927         if (defined($e->{SWITCH_TYPE})) {
1928                 if (defined($e->{ALIGN})) {
1929                         $self->pidl("NDR_CHECK(ndr_push_union_align($ndr, $e->{ALIGN}));");
1930                 }
1931
1932                 $self->pidl("NDR_CHECK(ndr_push_$e->{SWITCH_TYPE}($ndr, NDR_SCALARS, level));");
1933         }
1934
1935         if (defined($e->{ALIGN})) {
1936                 if ($e->{IS_MS_UNION}) {
1937                         $self->pidl("/* ms_union is always aligned to the largest union arm*/");
1938                         $self->pidl("NDR_CHECK(ndr_push_align($ndr, $e->{ALIGN}));");
1939                 } else {
1940                         $self->pidl("NDR_CHECK(ndr_push_union_align($ndr, $e->{ALIGN}));");
1941                 }
1942         }
1943
1944         $self->pidl("switch (level) {");
1945         $self->indent;
1946         foreach my $el (@{$e->{ELEMENTS}}) {
1947                 if ($el->{CASE} eq "default") {
1948                         $have_default = 1;
1949                 }
1950                 $self->pidl("$el->{CASE}: {");
1951
1952                 if ($el->{TYPE} ne "EMPTY") {
1953                         $self->indent;
1954                         if (defined($e->{PROPERTIES}{relative_base})) {
1955                                 $self->pidl("NDR_CHECK(ndr_push_align($ndr, $el->{ALIGN}));");
1956                                 # set the current offset as base for relative pointers
1957                                 # and store it based on the toplevel struct/union
1958                                 $self->pidl("NDR_CHECK(ndr_push_setup_relative_base_offset1($ndr, $varname, $ndr->offset));");
1959                         }
1960                         $self->DeclareArrayVariables($el);
1961                         my $el_env = {$el->{NAME} => "$varname->$el->{NAME}"};
1962                         $self->CheckRefPtrs($el, $ndr, $el_env);
1963                         $self->ParseElementPush($el, $ndr, $el_env, 1, 0);
1964                         $self->deindent;
1965                 }
1966                 $self->pidl("break; }");
1967                 $self->pidl("");
1968         }
1969         if (! $have_default) {
1970                 $self->pidl("default:");
1971                 $self->pidl("\treturn ndr_push_error($ndr, NDR_ERR_BAD_SWITCH, \"Bad switch value %\"PRIu32, level);");
1972         }
1973         $self->deindent;
1974         $self->pidl("}");
1975 }
1976
1977 sub ParseUnionPushDeferred($$$$)
1978 {
1979         my ($self,$e,$ndr,$varname) = @_;
1980
1981         my $have_default = 0;
1982
1983         if (defined($e->{PROPERTIES}{relative_base})) {
1984                 # retrieve the current offset as base for relative pointers
1985                 # based on the toplevel struct/union
1986                 $self->pidl("NDR_CHECK(ndr_push_setup_relative_base_offset2($ndr, $varname));");
1987         }
1988         $self->pidl("switch (level) {");
1989         $self->indent;
1990         foreach my $el (@{$e->{ELEMENTS}}) {
1991                 if ($el->{CASE} eq "default") {
1992                         $have_default = 1;
1993                 }
1994
1995                 $self->pidl("$el->{CASE}:");
1996                 if ($el->{TYPE} ne "EMPTY") {
1997                         $self->indent;
1998                         $self->ParseElementPush($el, $ndr, {$el->{NAME} => "$varname->$el->{NAME}"}, 0, 1);
1999                         $self->deindent;
2000                 }
2001                 $self->pidl("break;");
2002                 $self->pidl("");
2003         }
2004         if (! $have_default) {
2005                 $self->pidl("default:");
2006                 $self->pidl("\treturn ndr_push_error($ndr, NDR_ERR_BAD_SWITCH, \"Bad switch value %\"PRIu32, level);");
2007         }
2008         $self->deindent;
2009         $self->pidl("}");
2010 }
2011
2012 #####################################################################
2013 # parse a union - push side
2014 sub ParseUnionPush($$$$)
2015 {
2016         my ($self,$e,$ndr,$varname) = @_;
2017         my $have_default = 0;
2018
2019         $self->pidl("uint32_t level;");
2020         $self->start_flags($e, $ndr);
2021
2022         $self->pidl("NDR_PUSH_CHECK_FLAGS(ndr, ndr_flags);");
2023         $self->pidl("if (ndr_flags & NDR_SCALARS) {");
2024         $self->indent;
2025         $self->pidl("/* This token is not used again (except perhaps below in the NDR_BUFFERS case) */");
2026         $self->pidl("NDR_CHECK(ndr_push_steal_switch_value($ndr, $varname, &level));");
2027
2028         $self->ParseUnionPushPrimitives($e, $ndr, $varname);
2029         $self->deindent;
2030         $self->pidl("}");
2031         if (is_deferred_switch_non_empty($e)) {
2032                 $self->pidl("if (ndr_flags & NDR_BUFFERS) {");
2033                 $self->indent;
2034                 # In case we had ndr_flags of NDR_SCALERS|NDR_BUFFERS
2035                 $self->pidl("if (!(ndr_flags & NDR_SCALARS)) {");
2036                 $self->indent;
2037                 $self->pidl("/* We didn't get it above, and the token is not needed after this. */");
2038                 $self->pidl("NDR_CHECK(ndr_push_steal_switch_value($ndr, $varname, &level));");
2039                 $self->deindent;
2040                 $self->pidl("}");
2041                 $self->ParseUnionPushDeferred($e, $ndr, $varname);
2042                 $self->deindent;
2043                 $self->pidl("}");
2044         }
2045         $self->end_flags($e, $ndr);
2046 }
2047
2048 #####################################################################
2049 # print a union
2050 sub ParseUnionPrint($$$$$)
2051 {
2052         my ($self,$e,$ndr,$name,$varname) = @_;
2053         my $have_default = 0;
2054
2055         $self->pidl("uint32_t level;");
2056         foreach my $el (@{$e->{ELEMENTS}}) {
2057                 $self->DeclareArrayVariables($el);
2058         }
2059
2060         $self->start_flags($e, $ndr);
2061
2062         $self->pidl("level = ndr_print_steal_switch_value($ndr, $varname);");
2063
2064         $self->pidl("ndr_print_union($ndr, name, level, \"$name\");");
2065
2066         $self->pidl("switch (level) {");
2067         $self->indent;
2068         foreach my $el (@{$e->{ELEMENTS}}) {
2069                 if ($el->{CASE} eq "default") {
2070                         $have_default = 1;
2071                 }
2072                 $self->pidl("$el->{CASE}:");
2073                 if ($el->{TYPE} ne "EMPTY") {
2074                         $self->indent;
2075                         $self->ParseElementPrint($el, $ndr, "$varname->$el->{NAME}", {});
2076                         $self->deindent;
2077                 }
2078                 $self->pidl("break;");
2079                 $self->pidl("");
2080         }
2081         if (! $have_default) {
2082                 $self->pidl("default:");
2083                 $self->pidl("\tndr_print_bad_level($ndr, name, level);");
2084         }
2085         $self->deindent;
2086         $self->pidl("}");
2087
2088         $self->end_flags($e, $ndr);
2089 }
2090
2091 sub ParseUnionPullPrimitives($$$$$)
2092 {
2093         my ($self,$e,$ndr,$varname,$switch_type) = @_;
2094         my $have_default = 0;
2095
2096
2097         if (defined($switch_type)) {
2098                 if (defined($e->{ALIGN})) {
2099                         $self->pidl("NDR_CHECK(ndr_pull_union_align($ndr, $e->{ALIGN}));");
2100                 }
2101
2102                 my $data_type = mapTypeName($switch_type);
2103                 my $fmt = mapTypeSpecifier($data_type);
2104
2105                 if (!defined($fmt)) {
2106                         $data_type = "int";
2107                         $fmt = "%d";
2108                 }
2109
2110                 $self->pidl("NDR_CHECK(ndr_pull_$switch_type($ndr, NDR_SCALARS, &_level));");
2111                 $self->pidl("if (_level != level) {");
2112                 $self->pidl("\treturn ndr_pull_error($ndr, NDR_ERR_BAD_SWITCH, \"Bad switch value %$fmt for $varname at \%s\", ($data_type)_level, __location__);");
2113                 $self->pidl("}");
2114         }
2115
2116         if (defined($e->{ALIGN})) {
2117                 if ($e->{IS_MS_UNION}) {
2118                         $self->pidl("/* ms_union is always aligned to the largest union arm*/");
2119                         $self->pidl("NDR_CHECK(ndr_pull_align($ndr, $e->{ALIGN}));");
2120                 } else {
2121                         $self->pidl("NDR_CHECK(ndr_pull_union_align($ndr, $e->{ALIGN}));");
2122                 }
2123         }
2124
2125         $self->pidl("switch (level) {");
2126         $self->indent;
2127         foreach my $el (@{$e->{ELEMENTS}}) {
2128                 if ($el->{CASE} eq "default") {
2129                         $have_default = 1;
2130                 }
2131                 $self->pidl("$el->{CASE}: {");
2132
2133                 if ($el->{TYPE} ne "EMPTY") {
2134                         $self->indent;
2135                         if (defined($e->{PROPERTIES}{relative_base})) {
2136                                 $self->pidl("NDR_CHECK(ndr_pull_align($ndr, $el->{ALIGN}));");
2137                                 # set the current offset as base for relative pointers
2138                                 # and store it based on the toplevel struct/union
2139                                 $self->pidl("NDR_CHECK(ndr_pull_setup_relative_base_offset1($ndr, $varname, $ndr->offset));");
2140                         }
2141                         $self->ParseElementPull($el, $ndr, {$el->{NAME} => "$varname->$el->{NAME}"}, 1, 0);
2142                         $self->deindent;
2143                 }
2144                 $self->pidl("break; }");
2145                 $self->pidl("");
2146         }
2147         if (! $have_default) {
2148                 $self->pidl("default:");
2149                 $self->pidl("\treturn ndr_pull_error($ndr, NDR_ERR_BAD_SWITCH, \"Bad switch value %\"PRIu32\" at %s\", level, __location__);");
2150         }
2151         $self->deindent;
2152         $self->pidl("}");
2153 }
2154
2155 sub ParseUnionPullDeferred($$$$)
2156 {
2157         my ($self,$e,$ndr,$varname) = @_;
2158         my $have_default = 0;
2159
2160         $self->pidl("switch (level) {");
2161         $self->indent;
2162         foreach my $el (@{$e->{ELEMENTS}}) {
2163                 if ($el->{CASE} eq "default") {
2164                         $have_default = 1;
2165                 }
2166
2167                 $self->pidl("$el->{CASE}:");
2168                 if ($el->{TYPE} ne "EMPTY") {
2169                         $self->indent;
2170                         if (defined($e->{PROPERTIES}{relative_base})) {
2171                                 # retrieve the current offset as base for relative pointers
2172                                 # based on the toplevel struct/union
2173                                 $self->pidl("NDR_CHECK(ndr_pull_setup_relative_base_offset2($ndr, $varname));");
2174                         }
2175                         $self->ParseElementPull($el, $ndr, {$el->{NAME} => "$varname->$el->{NAME}"}, 0, 1);
2176                         $self->deindent;
2177                 }
2178                 $self->pidl("break;");
2179                 $self->pidl("");
2180         }
2181         if (! $have_default) {
2182                 $self->pidl("default:");
2183                 $self->pidl("\treturn ndr_pull_error($ndr, NDR_ERR_BAD_SWITCH, \"Bad switch value %\"PRIu32\" at %s\", level, __location__);");
2184         }
2185         $self->deindent;
2186         $self->pidl("}");
2187
2188
2189 }
2190
2191 #####################################################################
2192 # parse a union - pull side
2193 sub ParseUnionPull($$$$)
2194 {
2195         my ($self,$e,$ndr,$varname) = @_;
2196         my $switch_type = $e->{SWITCH_TYPE};
2197         my $needs_deferred_switch = is_deferred_switch_non_empty($e);
2198         $self->pidl("uint32_t level;");
2199         if (defined($switch_type)) {
2200                 if (Parse::Pidl::Typelist::typeIs($switch_type, "ENUM")) {
2201                         $switch_type = Parse::Pidl::Typelist::enum_type_fn(getType($switch_type)->{DATA});
2202                 }
2203                 $self->pidl(mapTypeName($switch_type) . " _level;");
2204         }
2205
2206         my %double_cases = ();
2207         foreach my $el (@{$e->{ELEMENTS}}) {
2208                 next if ($el->{TYPE} eq "EMPTY");
2209                 next if ($double_cases{"$el->{NAME}"});
2210                 $self->DeclareMemCtxVariables($el);
2211                 $self->DeclarePtrVariables($el);
2212                 $self->DeclareArrayVariables($el, "pull");
2213                 $double_cases{"$el->{NAME}"} = 1;
2214         }
2215
2216         $self->start_flags($e, $ndr);
2217
2218         $self->pidl("NDR_PULL_CHECK_FLAGS(ndr, ndr_flags);");
2219         $self->pidl("if (ndr_flags & NDR_SCALARS) {");
2220         $self->indent;
2221         $self->pidl("/* This token is not used again (except perhaps below in the NDR_BUFFERS case) */");
2222         $self->pidl("NDR_CHECK(ndr_pull_steal_switch_value($ndr, $varname, &level));");
2223         $self->ParseUnionPullPrimitives($e,$ndr,$varname,$switch_type);
2224         $self->deindent;
2225         $self->pidl("}");
2226         if ($needs_deferred_switch) {
2227                 $self->pidl("if (ndr_flags & NDR_BUFFERS) {");
2228                 $self->indent;
2229                 # In case we had ndr_flags of NDR_SCALERS|NDR_BUFFERS
2230                 $self->pidl("if (!(ndr_flags & NDR_SCALARS)) {");
2231                 $self->indent;
2232                 $self->pidl("/* We didn't get it above, and the token is not needed after this. */");
2233                 $self->pidl("NDR_CHECK(ndr_pull_steal_switch_value($ndr, $varname, &level));");
2234                 $self->deindent;
2235                 $self->pidl("}");
2236                 $self->ParseUnionPullDeferred($e,$ndr,$varname);
2237                 $self->deindent;
2238                 $self->pidl("}");
2239         }
2240         $self->add_deferred();
2241
2242         $self->end_flags($e, $ndr);
2243 }
2244
2245 sub DeclUnion($$$$)
2246 {
2247         my ($e,$t,$name,$varname) = @_;
2248         if ($t eq "base") {
2249                 return "union $name $varname";
2250         }
2251         return ($t ne "pull"?"const ":"") . "union $name *$varname";
2252 }
2253
2254 sub ArgsUnionNdrSize($$)
2255 {
2256         my ($d,$name) = @_;
2257         return "const union $name *r, uint32_t level, libndr_flags flags";
2258 }
2259
2260 $typefamily{UNION} = {
2261         PUSH_FN_BODY => \&ParseUnionPush,
2262         DECL => \&DeclUnion,
2263         PULL_FN_BODY => \&ParseUnionPull,
2264         PRINT_FN_BODY => \&ParseUnionPrint,
2265         SIZE_FN_ARGS => \&ArgsUnionNdrSize,
2266         SIZE_FN_BODY => \&ParseUnionNdrSize,
2267 };
2268
2269 #####################################################################
2270 # parse a typedef - push side
2271 sub ParseTypedefPush($$$$)
2272 {
2273         my($self,$e,$ndr,$varname) = @_;
2274
2275         my $env;
2276
2277         $env->{$e->{NAME}} = $varname;
2278
2279         $self->ParseElementPushLevel($e, $e->{LEVELS}[0], $ndr, $varname, $env, 1, 1);
2280 }
2281
2282 #####################################################################
2283 # parse a typedef - pull side
2284 sub ParseTypedefPull($$$$)
2285 {
2286         my($self,$e,$ndr,$varname) = @_;
2287
2288         my $env;
2289
2290         $env->{$e->{NAME}} = $varname;
2291
2292         $self->ParseElementPullLevel($e, $e->{LEVELS}[0], $ndr, $varname, $env, 1, 1);
2293 }
2294
2295 #####################################################################
2296 # parse a typedef - print side
2297 sub ParseTypedefPrint($$$$$)
2298 {
2299         my($self,$e,$ndr,$name,$varname) = @_;
2300
2301         $typefamily{$e->{DATA}->{TYPE}}->{PRINT_FN_BODY}->($self, $e->{DATA}, $ndr, $name, $varname);
2302 }
2303
2304 #####################################################################
2305 ## calculate the size of a structure
2306 sub ParseTypedefNdrSize($$$$)
2307 {
2308         my($self,$t,$name,$varname) = @_;
2309
2310         $typefamily{$t->{DATA}->{TYPE}}->{SIZE_FN_BODY}->($self, $t->{DATA}, $name, $varname);
2311 }
2312
2313 sub DeclTypedef($$$$)
2314 {
2315         my ($e, $t, $name, $varname) = @_;
2316
2317         return $typefamily{$e->{DATA}->{TYPE}}->{DECL}->($e->{DATA}, $t, $name, $varname);
2318 }
2319
2320 sub ArgsTypedefNdrSize($$$)
2321 {
2322         my ($d, $name, $varname) = @_;
2323         return $typefamily{$d->{DATA}->{TYPE}}->{SIZE_FN_ARGS}->($d->{DATA}, $name, $varname);
2324 }
2325
2326 $typefamily{TYPEDEF} = {
2327         PUSH_FN_BODY => \&ParseTypedefPush,
2328         DECL => \&DeclTypedef,
2329         PULL_FN_BODY => \&ParseTypedefPull,
2330         PRINT_FN_BODY => \&ParseTypedefPrint,
2331         SIZE_FN_ARGS => \&ArgsTypedefNdrSize,
2332         SIZE_FN_BODY => \&ParseTypedefNdrSize,
2333 };
2334
2335 sub ParsePipePushChunk($$)
2336 {
2337         my ($self, $t) = @_;
2338
2339         my $pipe = $t;
2340         $pipe = $t->{DATA} if ($t->{TYPE} eq "TYPEDEF");
2341         my $struct = $pipe->{DATA};
2342
2343         my $name = "$struct->{NAME}";
2344         my $ndr = "ndr";
2345         my $varname = "r";
2346
2347         my $args = $typefamily{$struct->{TYPE}}->{DECL}->($struct, "push", $name, $varname);
2348
2349         $self->fn_declare("push", $struct, "enum ndr_err_code ndr_push_$name(struct ndr_push *$ndr, int ndr_flags, $args)") or return;
2350
2351         return if has_property($t, "nopush");
2352
2353         $self->pidl("{");
2354         $self->indent;
2355
2356         $self->ParseStructPush($struct, $ndr, $varname);
2357         $self->pidl("");
2358
2359         $self->pidl("NDR_CHECK(ndr_push_pipe_chunk_trailer(ndr, ndr_flags, $varname->count));");
2360         $self->pidl("");
2361
2362         $self->pidl("return NDR_ERR_SUCCESS;");
2363         $self->deindent;
2364         $self->pidl("}");
2365         $self->pidl("");
2366 }
2367
2368 sub ParsePipePullChunk($$)
2369 {
2370         my ($self, $t) = @_;
2371
2372         my $pipe = $t;
2373         $pipe = $t->{DATA} if ($t->{TYPE} eq "TYPEDEF");
2374         my $struct = $pipe->{DATA};
2375
2376         my $name = "$struct->{NAME}";
2377         my $ndr = "ndr";
2378         my $varname = "r";
2379
2380         my $args = $typefamily{$struct->{TYPE}}->{DECL}->($struct, "pull", $name, $varname);
2381
2382         $self->fn_declare("pull", $struct, "enum ndr_err_code ndr_pull_$name(struct ndr_pull *$ndr, int ndr_flags, $args)") or return;
2383
2384         return if has_property($struct, "nopull");
2385
2386         $self->pidl("{");
2387         $self->indent;
2388
2389         $self->ParseStructPull($struct, $ndr, $varname);
2390         $self->pidl("");
2391
2392         $self->pidl("NDR_CHECK(ndr_check_pipe_chunk_trailer($ndr, ndr_flags, $varname->count));");
2393         $self->pidl("");
2394
2395         $self->pidl("return NDR_ERR_SUCCESS;");
2396         $self->deindent;
2397         $self->pidl("}");
2398         $self->pidl("");
2399 }
2400
2401 sub ParsePipePrintChunk($$)
2402 {
2403         my ($self, $t) = @_;
2404
2405         my $pipe = $t;
2406         $pipe = $t->{DATA} if ($t->{TYPE} eq "TYPEDEF");
2407         my $struct = $pipe->{DATA};
2408
2409         my $name = "$struct->{NAME}";
2410         my $ndr = "ndr";
2411         my $varname = "r";
2412
2413         my $args = $typefamily{$struct->{TYPE}}->{DECL}->($struct, "print", $name, $varname);
2414
2415         $self->pidl_hdr("void ndr_print_$name(struct ndr_print *ndr, const char *name, $args);");
2416
2417         return if (has_property($t, "noprint"));
2418
2419         $self->pidl("_PUBLIC_ void ndr_print_$name(struct ndr_print *$ndr, const char *name, $args)");
2420         $self->pidl("{");
2421         $self->indent;
2422         $self->ParseTypePrint($struct, $ndr, $varname);
2423         $self->deindent;
2424         $self->pidl("}");
2425         $self->pidl("");
2426 }
2427
2428 #####################################################################
2429 # parse a function - print side
2430 sub ParseFunctionPrint($$)
2431 {
2432         my($self, $fn) = @_;
2433         my $ndr = "ndr";
2434
2435         $self->pidl_hdr("void ndr_print_$fn->{NAME}(struct ndr_print *$ndr, const char *name, int flags, const struct $fn->{NAME} *r);");
2436
2437         return if has_property($fn, "noprint");
2438
2439         $self->pidl("_PUBLIC_ void ndr_print_$fn->{NAME}(struct ndr_print *$ndr, const char *name, int flags, const struct $fn->{NAME} *r)");
2440         $self->pidl("{");
2441         $self->indent;
2442
2443         foreach my $e (@{$fn->{ELEMENTS}}) {
2444                 $self->DeclareArrayVariables($e);
2445         }
2446
2447         $self->pidl("ndr_print_struct($ndr, name, \"$fn->{NAME}\");");
2448         $self->pidl("if (r == NULL) { ndr_print_null($ndr); return; }");
2449         $self->pidl("$ndr->depth++;");
2450
2451         $self->pidl("if (flags & NDR_SET_VALUES) {");
2452         $self->pidl("\t$ndr->flags |= LIBNDR_PRINT_SET_VALUES;");
2453         $self->pidl("}");
2454
2455         $self->pidl("if (flags & NDR_IN) {");
2456         $self->indent;
2457         $self->pidl("ndr_print_struct($ndr, \"in\", \"$fn->{NAME}\");");
2458         $self->pidl("$ndr->depth++;");
2459
2460         my $env = GenerateFunctionInEnv($fn);
2461
2462         foreach my $e (@{$fn->{ELEMENTS}}) {
2463                 if (grep(/in/,@{$e->{DIRECTION}})) {
2464                         $self->ParseElementPrint($e, $ndr, $env->{$e->{NAME}}, $env);
2465                 }
2466         }
2467         $self->pidl("$ndr->depth--;");
2468         $self->deindent;
2469         $self->pidl("}");
2470
2471         $self->pidl("if (flags & NDR_OUT) {");
2472         $self->indent;
2473         $self->pidl("ndr_print_struct($ndr, \"out\", \"$fn->{NAME}\");");
2474         $self->pidl("$ndr->depth++;");
2475
2476         $env = GenerateFunctionOutEnv($fn);
2477         foreach my $e (@{$fn->{ELEMENTS}}) {
2478                 if (grep(/out/,@{$e->{DIRECTION}})) {
2479                         $self->ParseElementPrint($e, $ndr, $env->{$e->{NAME}}, $env);
2480                 }
2481         }
2482         if ($fn->{RETURN_TYPE}) {
2483                 $self->pidl("ndr_print_$fn->{RETURN_TYPE}($ndr, \"result\", r->out.result);");
2484         }
2485         $self->pidl("$ndr->depth--;");
2486         $self->deindent;
2487         $self->pidl("}");
2488
2489         $self->pidl("$ndr->depth--;");
2490         $self->deindent;
2491         $self->pidl("}");
2492         $self->pidl("");
2493 }
2494
2495 #####################################################################
2496 # parse a function
2497 sub ParseFunctionPush($$)
2498 {
2499         my($self, $fn) = @_;
2500         my $ndr = "ndr";
2501
2502         $self->fn_declare("push", $fn, "enum ndr_err_code ndr_push_$fn->{NAME}(struct ndr_push *$ndr, int flags, const struct $fn->{NAME} *r)") or return;
2503
2504         return if has_property($fn, "nopush");
2505
2506         $self->pidl("{");
2507         $self->indent;
2508
2509         foreach my $e (@{$fn->{ELEMENTS}}) {
2510                 $self->DeclareArrayVariables($e);
2511         }
2512
2513         $self->pidl("NDR_PUSH_CHECK_FN_FLAGS(ndr, flags);");
2514
2515         $self->pidl("if (flags & NDR_IN) {");
2516         $self->indent;
2517
2518         my $env = GenerateFunctionInEnv($fn);
2519
2520         EnvSubstituteValue($env, $fn);
2521
2522         foreach my $e (@{$fn->{ELEMENTS}}) {
2523                 if (grep(/in/,@{$e->{DIRECTION}})) {
2524                         $self->CheckRefPtrs($e, $ndr, $env);
2525                 }
2526         }
2527
2528         foreach my $e (@{$fn->{ELEMENTS}}) {
2529                 if (grep(/in/,@{$e->{DIRECTION}})) {
2530                         $self->ParseElementPush($e, $ndr, $env, 1, 1);
2531                 }
2532         }
2533
2534         $self->deindent;
2535         $self->pidl("}");
2536
2537         $self->pidl("if (flags & NDR_OUT) {");
2538         $self->indent;
2539
2540         $env = GenerateFunctionOutEnv($fn);
2541         EnvSubstituteValue($env, $fn);
2542
2543         foreach my $e (@{$fn->{ELEMENTS}}) {
2544                 if (grep(/out/,@{$e->{DIRECTION}})) {
2545                         $self->CheckRefPtrs($e, $ndr, $env);
2546                 }
2547         }
2548
2549         foreach my $e (@{$fn->{ELEMENTS}}) {
2550                 if (grep(/out/,@{$e->{DIRECTION}})) {
2551                         $self->ParseElementPush($e, $ndr, $env, 1, 1);
2552                 }
2553         }
2554
2555         if ($fn->{RETURN_TYPE}) {
2556                 $self->pidl("NDR_CHECK(ndr_push_$fn->{RETURN_TYPE}($ndr, NDR_SCALARS, r->out.result));");
2557         }
2558
2559         $self->deindent;
2560         $self->pidl("}");
2561         $self->pidl("return NDR_ERR_SUCCESS;");
2562         $self->deindent;
2563         $self->pidl("}");
2564         $self->pidl("");
2565 }
2566
2567 sub AllocateArrayLevel($$$$$$)
2568 {
2569         my ($self,$e,$l,$ndr,$var,$size) = @_;
2570
2571         my $pl = GetPrevLevel($e, $l);
2572         if (defined($pl) and
2573             $pl->{TYPE} eq "POINTER" and
2574             $pl->{POINTER_TYPE} eq "ref"
2575             and not $l->{IS_ZERO_TERMINATED}) {
2576                 $self->pidl("if ($ndr->flags & LIBNDR_FLAG_REF_ALLOC) {");
2577                 $self->pidl("\tNDR_PULL_ALLOC_N($ndr, $var, $size);");
2578                 $self->pidl("}");
2579                 if (grep(/in/,@{$e->{DIRECTION}}) and
2580                     grep(/out/,@{$e->{DIRECTION}})) {
2581                         $self->pidl("memcpy(r->out.$e->{NAME}, r->in.$e->{NAME}, ($size) * sizeof(*r->in.$e->{NAME}));");
2582                 }
2583                 return;
2584         }
2585
2586         $self->pidl("NDR_PULL_ALLOC_N($ndr, $var, $size);");
2587 }
2588
2589 #####################################################################
2590 # parse a function
2591 sub ParseFunctionPull($$)
2592 {
2593         my($self,$fn) = @_;
2594         my $ndr = "ndr";
2595
2596         # pull function args
2597         $self->fn_declare("pull", $fn, "enum ndr_err_code ndr_pull_$fn->{NAME}(struct ndr_pull *$ndr, int flags, struct $fn->{NAME} *r)") or return;
2598
2599         $self->pidl("{");
2600         $self->indent;
2601
2602         # declare any internal pointers we need
2603         foreach my $e (@{$fn->{ELEMENTS}}) {
2604                 $self->DeclarePtrVariables($e);
2605                 $self->DeclareArrayVariables($e, "pull");
2606         }
2607
2608         my %double_cases = ();
2609         foreach my $e (@{$fn->{ELEMENTS}}) {
2610                 next if ($e->{TYPE} eq "EMPTY");
2611                 next if ($double_cases{"$e->{NAME}"});
2612                 $self->DeclareMemCtxVariables($e);
2613                 $double_cases{"$e->{NAME}"} = 1;
2614         }
2615
2616         $self->pidl("NDR_PULL_CHECK_FN_FLAGS(ndr, flags);");
2617
2618         $self->pidl("if (flags & NDR_IN) {");
2619         $self->indent;
2620
2621         # auto-init the out section of a structure. I originally argued that
2622         # this was a bad idea as it hides bugs, but coping correctly
2623         # with initialisation and not wiping ref vars is turning
2624         # out to be too tricky (tridge)
2625         foreach my $e (@{$fn->{ELEMENTS}}) {
2626                 next unless grep(/out/, @{$e->{DIRECTION}});
2627                 $self->pidl("NDR_ZERO_STRUCT(r->out);");
2628                 $self->pidl("");
2629                 last;
2630         }
2631
2632         my $env = GenerateFunctionInEnv($fn);
2633
2634         foreach my $e (@{$fn->{ELEMENTS}}) {
2635                 next unless (grep(/in/, @{$e->{DIRECTION}}));
2636                 $self->ParseElementPull($e, $ndr, $env, 1, 1);
2637         }
2638
2639         # allocate the "simple" out ref variables. FIXME: Shouldn't this have it's
2640         # own flag rather than be in NDR_IN ?
2641
2642         foreach my $e (@{$fn->{ELEMENTS}}) {
2643                 next unless (grep(/out/, @{$e->{DIRECTION}}));
2644                 next unless ($e->{LEVELS}[0]->{TYPE} eq "POINTER" and
2645                              $e->{LEVELS}[0]->{POINTER_TYPE} eq "ref");
2646                 next if (($e->{LEVELS}[1]->{TYPE} eq "DATA") and
2647                                  ($e->{LEVELS}[1]->{DATA_TYPE} eq "string"));
2648                 next if ($e->{LEVELS}[1]->{TYPE} eq "PIPE");
2649                 next if (($e->{LEVELS}[1]->{TYPE} eq "ARRAY")
2650                         and   $e->{LEVELS}[1]->{IS_ZERO_TERMINATED});
2651
2652                 if ($e->{LEVELS}[1]->{TYPE} eq "ARRAY") {
2653                         my $size = ParseExprExt($e->{LEVELS}[1]->{SIZE_IS}, $env, $e->{ORIGINAL},
2654                                 check_null_pointer($e, $env, sub { $self->pidl(shift); },
2655                                                    "return ndr_pull_error($ndr, NDR_ERR_INVALID_POINTER, \"NULL Pointer for size_is()\");"),
2656                                 check_fully_dereferenced($e, $env));
2657                         $self->pidl("NDR_PULL_ALLOC_N($ndr, r->out.$e->{NAME}, $size);");
2658
2659                         if (grep(/in/, @{$e->{DIRECTION}})) {
2660                                 $self->pidl("memcpy(r->out.$e->{NAME}, r->in.$e->{NAME}, ($size) * sizeof(*r->in.$e->{NAME}));");
2661                         } else {
2662                                 $self->pidl("memset(r->out.$e->{NAME}, 0, ($size) * sizeof(*r->out.$e->{NAME}));");
2663                         }
2664                 } elsif ($e->{LEVELS}[1]->{TYPE} eq "ARRAY") {
2665                         if (grep(/in/, @{$e->{DIRECTION}})) {
2666                                 $self->pidl("r->out.$e->{NAME} = r->in.$e->{NAME};");
2667                         } else {
2668                                 $self->pidl("r->out.$e->{NAME} = NULL;");
2669                         }
2670                 } else {
2671                         $self->pidl("NDR_PULL_ALLOC($ndr, r->out.$e->{NAME});");
2672
2673                         if (grep(/in/, @{$e->{DIRECTION}})) {
2674                                 $self->pidl("*r->out.$e->{NAME} = *r->in.$e->{NAME};");
2675                         } else {
2676                                 $self->pidl("NDR_ZERO_STRUCTP(r->out.$e->{NAME});");
2677                         }
2678                 }
2679         }
2680
2681         $self->add_deferred();
2682         $self->deindent;
2683         $self->pidl("}");
2684
2685         $self->pidl("if (flags & NDR_OUT) {");
2686         $self->indent;
2687
2688         $self->pidl("#ifdef FUZZING_BUILD_MODE_UNSAFE_FOR_PRODUCTION");
2689
2690         # This is for fuzzers of ndr_pull where the out elements refer to
2691         # in elements in size_is or length_is.
2692         #
2693         # Not actually very harmful but also not useful outside a fuzzer
2694         foreach my $e (@{$fn->{ELEMENTS}}) {
2695                 next unless (grep(/in/, @{$e->{DIRECTION}}));
2696                 next unless ($e->{LEVELS}[0]->{TYPE} eq "POINTER" and
2697                              $e->{LEVELS}[0]->{POINTER_TYPE} eq "ref");
2698                 next if (($e->{LEVELS}[1]->{TYPE} eq "DATA") and
2699                                  ($e->{LEVELS}[1]->{DATA_TYPE} eq "string"));
2700                 next if ($e->{LEVELS}[1]->{TYPE} eq "PIPE");
2701                 next if ($e->{LEVELS}[1]->{TYPE} eq "ARRAY");
2702
2703                 $self->pidl("if (r->in.$e->{NAME} == NULL) {");
2704                 $self->indent;
2705                 $self->pidl("NDR_PULL_ALLOC($ndr, r->in.$e->{NAME});");
2706                 $self->pidl("NDR_ZERO_STRUCTP(r->in.$e->{NAME});");
2707                 $self->deindent;
2708                 $self->pidl("}");
2709         }
2710
2711         $self->pidl("#endif /* FUZZING_BUILD_MODE_UNSAFE_FOR_PRODUCTION */");
2712
2713         $env = GenerateFunctionOutEnv($fn);
2714         foreach my $e (@{$fn->{ELEMENTS}}) {
2715                 next unless grep(/out/, @{$e->{DIRECTION}});
2716                 $self->ParseElementPull($e, $ndr, $env, 1, 1);
2717         }
2718
2719         if ($fn->{RETURN_TYPE}) {
2720                 $self->pidl("NDR_CHECK(ndr_pull_$fn->{RETURN_TYPE}($ndr, NDR_SCALARS, &r->out.result));");
2721         }
2722
2723         $self->add_deferred();
2724         $self->deindent;
2725         $self->pidl("}");
2726
2727         $self->pidl("return NDR_ERR_SUCCESS;");
2728         $self->deindent;
2729         $self->pidl("}");
2730         $self->pidl("");
2731 }
2732
2733 sub AuthServiceStruct($$$)
2734 {
2735         my ($self, $ifacename, $authservice) = @_;
2736         my @a = split /,/, $authservice;
2737         my $authservice_count = $#a + 1;
2738
2739         $self->pidl("static const char * const $ifacename\_authservice_strings[] = {");
2740         foreach my $ap (@a) {
2741                 $self->pidl("\t$ap, ");
2742         }
2743         $self->pidl("};");
2744         $self->pidl("");
2745
2746         $self->pidl("static const struct ndr_interface_string_array $ifacename\_authservices = {");
2747         $self->pidl("\t.count\t= $authservice_count,");
2748         $self->pidl("\t.names\t= $ifacename\_authservice_strings");
2749         $self->pidl("};");
2750         $self->pidl("");
2751 }
2752
2753 sub ParseGeneratePipeArray($$$)
2754 {
2755         my ($self, $fn, $direction) = @_;
2756
2757         $self->pidl("static const struct ndr_interface_call_pipe $fn->{NAME}\_$direction\_pipes[] = {");
2758         $self->indent;
2759
2760         foreach my $e (@{$fn->{ELEMENTS}}) {
2761                 next unless ContainsPipe($e, $e->{LEVELS}[0]);
2762                 next unless (grep(/$direction/, @{$e->{DIRECTION}}));
2763
2764                 my $cname = "$e->{TYPE}_chunk";
2765
2766                 $self->pidl("{");
2767                 $self->indent;
2768                 $self->pidl("\"$direction.$e->{NAME}\",");
2769                 $self->pidl("\"$cname\",");
2770                 $self->pidl("sizeof(struct $cname),");
2771                 $self->pidl("(ndr_push_flags_fn_t) ndr_push_$cname,");
2772                 $self->pidl("(ndr_pull_flags_fn_t) ndr_pull_$cname,");
2773                 $self->pidl("(ndr_print_fn_t) ndr_print_$cname,");
2774                 $self->deindent;
2775                 $self->pidl("},");
2776         }
2777         $self->pidl("{ .name = NULL }");
2778         $self->deindent;
2779         $self->pidl("};");
2780         $self->pidl("");
2781 }
2782
2783 sub FunctionCallPipes($$)
2784 {
2785         my ($self, $d) = @_;
2786         return if not defined($d->{OPNUM});
2787
2788         my $in_pipes = 0;
2789         my $out_pipes = 0;
2790
2791         foreach my $e (@{$d->{ELEMENTS}}) {
2792                 next unless ContainsPipe($e, $e->{LEVELS}[0]);
2793
2794                 if (grep(/in/, @{$e->{DIRECTION}})) {
2795                         $in_pipes++;
2796                 }
2797                 if (grep(/out/, @{$e->{DIRECTION}})) {
2798                         $out_pipes++;
2799                 }
2800         }
2801
2802         if ($in_pipes) {
2803                 $self->ParseGeneratePipeArray($d, "in");
2804         }
2805
2806         if ($out_pipes) {
2807                 $self->ParseGeneratePipeArray($d, "out");
2808         }
2809 }
2810
2811 sub FunctionCallEntry($$)
2812 {
2813         my ($self, $d) = @_;
2814         return 0 if not defined($d->{OPNUM});
2815
2816         my $in_pipes = 0;
2817         my $out_pipes = 0;
2818
2819         foreach my $e (@{$d->{ELEMENTS}}) {
2820                 next unless ContainsPipe($e, $e->{LEVELS}[0]);
2821
2822                 if (grep(/in/, @{$e->{DIRECTION}})) {
2823                         $in_pipes++;
2824                 }
2825                 if (grep(/out/, @{$e->{DIRECTION}})) {
2826                         $out_pipes++;
2827                 }
2828         }
2829
2830         my $in_pipes_ptr = "NULL";
2831         my $out_pipes_ptr = "NULL";
2832
2833         if ($in_pipes) {
2834                 $in_pipes_ptr = "$d->{NAME}_in_pipes";
2835         }
2836
2837         if ($out_pipes) {
2838                 $out_pipes_ptr = "$d->{NAME}_out_pipes";
2839         }
2840
2841         $self->pidl("\t{");
2842         $self->pidl("\t\t\"$d->{NAME}\",");
2843         $self->pidl("\t\tsizeof(struct $d->{NAME}),");
2844         $self->pidl("\t\t(ndr_push_flags_fn_t) ndr_push_$d->{NAME},");
2845         $self->pidl("\t\t(ndr_pull_flags_fn_t) ndr_pull_$d->{NAME},");
2846         $self->pidl("\t\t(ndr_print_function_t) ndr_print_$d->{NAME},");
2847         $self->pidl("\t\t{ $in_pipes, $in_pipes_ptr },");
2848         $self->pidl("\t\t{ $out_pipes, $out_pipes_ptr },");
2849         $self->pidl("\t},");
2850         return 1;
2851 }
2852
2853 sub StructEntry($$)
2854 {
2855         my ($self, $d) = @_;
2856         my $type_decl = $typefamily{$d->{TYPE}}->{DECL}->($d, "base", $d->{NAME}, "");
2857
2858         $self->pidl("\t{");
2859         $self->pidl("\t\t.name = \"$d->{NAME}\",");
2860         $self->pidl("\t\t.struct_size = sizeof($type_decl),");
2861         $self->pidl("\t\t.ndr_push = (ndr_push_flags_fn_t) ndr_push_$d->{NAME},");
2862         $self->pidl("\t\t.ndr_pull = (ndr_pull_flags_fn_t) ndr_pull_$d->{NAME},");
2863         $self->pidl("\t\t.ndr_print = (ndr_print_function_t) ndr_print_flags_$d->{NAME},");
2864         $self->pidl("\t},");
2865         return 1;
2866 }
2867
2868 #####################################################################
2869 # produce a function call table
2870 sub FunctionTable($$)
2871 {
2872         my($self,$interface) = @_;
2873         my $count = 0;
2874         my $count_public_structs = 0;
2875         my $uname = uc $interface->{NAME};
2876
2877         foreach my $d (@{$interface->{TYPES}}) {
2878                 next unless (is_public_struct($d));
2879                 $count_public_structs += 1;
2880         }
2881         return if ($#{$interface->{FUNCTIONS}}+1 == 0 and
2882                    $count_public_structs == 0);
2883
2884         foreach my $d (@{$interface->{INHERITED_FUNCTIONS}},@{$interface->{FUNCTIONS}}) {
2885                 $self->FunctionCallPipes($d);
2886         }
2887
2888         $self->pidl("static const struct ndr_interface_public_struct $interface->{NAME}\_public_structs[] = {");
2889
2890         foreach my $d (@{$interface->{TYPES}}) {
2891                 next unless (is_public_struct($d));
2892                 $self->StructEntry($d);
2893         }
2894         $self->pidl("\t{ .name = NULL }");
2895         $self->pidl("};");
2896         $self->pidl("");
2897
2898         $self->pidl("static const struct ndr_interface_call $interface->{NAME}\_calls[] = {");
2899
2900         foreach my $d (@{$interface->{INHERITED_FUNCTIONS}},@{$interface->{FUNCTIONS}}) {
2901                 $count += $self->FunctionCallEntry($d);
2902         }
2903         $self->pidl("\t{ .name = NULL }");
2904         $self->pidl("};");
2905         $self->pidl("");
2906
2907         $self->pidl("static const char * const $interface->{NAME}\_endpoint_strings[] = {");
2908         foreach my $ep (@{$interface->{ENDPOINTS}}) {
2909                 $self->pidl("\t$ep, ");
2910         }
2911         my $endpoint_count = $#{$interface->{ENDPOINTS}}+1;
2912
2913         $self->pidl("};");
2914         $self->pidl("");
2915
2916         $self->pidl("static const struct ndr_interface_string_array $interface->{NAME}\_endpoints = {");
2917         $self->pidl("\t.count\t= $endpoint_count,");
2918         $self->pidl("\t.names\t= $interface->{NAME}\_endpoint_strings");
2919         $self->pidl("};");
2920         $self->pidl("");
2921
2922         if (! defined $interface->{PROPERTIES}->{authservice}) {
2923                 $interface->{PROPERTIES}->{authservice} = "\"host\"";
2924         }
2925
2926         $self->AuthServiceStruct($interface->{NAME},
2927                                      $interface->{PROPERTIES}->{authservice});
2928
2929         $self->pidl("\nconst struct ndr_interface_table ndr_table_$interface->{NAME} = {");
2930         $self->pidl("\t.name\t\t= \"$interface->{NAME}\",");
2931         if (defined $interface->{PROPERTIES}->{uuid}) {
2932                 $self->pidl("\t.syntax_id\t= {");
2933                 $self->pidl("\t\t" . print_uuid($interface->{UUID}) .",");
2934                 $self->pidl("\t\tNDR_$uname\_VERSION");
2935                 $self->pidl("\t},");
2936                 $self->pidl("\t.helpstring\t= NDR_$uname\_HELPSTRING,");
2937         }
2938         $self->pidl("\t.num_calls\t= $count,");
2939         $self->pidl("\t.calls\t\t= $interface->{NAME}\_calls,");
2940         $self->pidl("\t.num_public_structs\t= $count_public_structs,");
2941         $self->pidl("\t.public_structs\t\t= $interface->{NAME}\_public_structs,");
2942         $self->pidl("\t.endpoints\t= &$interface->{NAME}\_endpoints,");
2943         $self->pidl("\t.authservices\t= &$interface->{NAME}\_authservices");
2944         $self->pidl("};");
2945         $self->pidl("");
2946
2947 }
2948
2949 #####################################################################
2950 # generate include statements for imported idl files
2951 sub HeaderImport
2952 {
2953         my $self = shift;
2954         my @imports = @_;
2955         foreach (@imports) {
2956                 $_ = unmake_str($_);
2957                 s/\.idl$//;
2958                 $self->pidl(choose_header("librpc/gen_ndr/ndr_$_\.h", "gen_ndr/ndr_$_.h"));
2959         }
2960 }
2961
2962 #####################################################################
2963 # generate include statements for included header files
2964 sub HeaderInclude
2965 {
2966         my $self = shift;
2967         my @includes = @_;
2968         foreach (@includes) {
2969                 $self->pidl_hdr("#include $_");
2970         }
2971 }
2972
2973 #####################################################################
2974 # generate prototypes and defines for the interface definitions
2975 # FIXME: these prototypes are for the DCE/RPC client functions, not the
2976 # NDR parser and so do not belong here, technically speaking
2977 sub HeaderInterface($$$)
2978 {
2979         my($self,$interface,$needed) = @_;
2980
2981         my $count = 0;
2982
2983         if ($needed->{"compression"}) {
2984                 $self->pidl(choose_header("librpc/ndr/ndr_compression.h", "ndr/compression.h"));
2985         }
2986
2987         if (has_property($interface, "object")) {
2988                 $self->pidl(choose_header("librpc/gen_ndr/ndr_orpc.h", "ndr/orpc.h"));
2989         }
2990
2991         if (defined $interface->{PROPERTIES}->{helper}) {
2992                 $self->HeaderInclude(split /,/, $interface->{PROPERTIES}->{helper});
2993         }
2994
2995         if (defined $interface->{PROPERTIES}->{uuid}) {
2996                 my $name = uc $interface->{NAME};
2997                 $self->pidl_hdr("#define NDR_$name\_UUID " .
2998                 Parse::Pidl::Util::make_str(lc($interface->{UUID})));
2999
3000                 $self->pidl_hdr("#define NDR_$name\_VERSION $interface->{VERSION}");
3001
3002                 $self->pidl_hdr("#define NDR_$name\_NAME \"$interface->{NAME}\"");
3003
3004                 if(!defined $interface->{PROPERTIES}->{helpstring}) { $interface->{PROPERTIES}->{helpstring} = "NULL"; }
3005                 $self->pidl_hdr("#define NDR_$name\_HELPSTRING $interface->{PROPERTIES}->{helpstring}");
3006         }
3007
3008         my $count_public_structs = 0;
3009         foreach my $d (@{$interface->{TYPES}}) {
3010                 next unless (has_property($d, "public"));
3011                 $count_public_structs += 1;
3012         }
3013         if ($#{$interface->{FUNCTIONS}}+1 > 0 or
3014                    $count_public_structs > 0) {
3015                 $self->pidl_hdr("extern const struct ndr_interface_table ndr_table_$interface->{NAME};");
3016         }
3017
3018         foreach (@{$interface->{FUNCTIONS}}) {
3019                 next if has_property($_, "noopnum");
3020                 next if grep(/^$_->{NAME}$/,@{$interface->{INHERITED_FUNCTIONS}});
3021                 my $u_name = uc $_->{NAME};
3022
3023                 my $val = sprintf("0x%02x", $count);
3024                 if (defined($interface->{BASE})) {
3025                         $val .= " + NDR_" . uc $interface->{BASE} . "_CALL_COUNT";
3026                 }
3027
3028                 $self->pidl_hdr("#define NDR_$u_name ($val)");
3029
3030                 $self->pidl_hdr("");
3031                 $count++;
3032         }
3033
3034         my $val = $count;
3035
3036         if (defined($interface->{BASE})) {
3037                 $val .= " + NDR_" . uc $interface->{BASE} . "_CALL_COUNT";
3038         }
3039
3040         $self->pidl_hdr("#define NDR_" . uc $interface->{NAME} . "_CALL_COUNT ($val)");
3041
3042 }
3043
3044 sub ParseTypePush($$$$$$)
3045 {
3046         my ($self,$e, $ndr, $varname, $primitives, $deferred) = @_;
3047
3048         # save the old relative_base_offset
3049         $self->pidl("uint32_t _save_relative_base_offset = ndr_push_get_relative_base_offset($ndr);") if defined(has_property($e, "relative_base"));
3050         $typefamily{$e->{TYPE}}->{PUSH_FN_BODY}->($self, $e, $ndr, $varname);
3051         # restore the old relative_base_offset
3052         $self->pidl("ndr_push_restore_relative_base_offset($ndr, _save_relative_base_offset);") if defined(has_property($e, "relative_base"));
3053 }
3054
3055 sub ParseTypePushFunction($$$)
3056 {
3057         my ($self, $e, $varname) = @_;
3058         my $ndr = "ndr";
3059
3060         my $args = $typefamily{$e->{TYPE}}->{DECL}->($e, "push", $e->{NAME}, $varname);
3061
3062         $self->fn_declare("push", $e, "enum ndr_err_code ".TypeFunctionName("ndr_push", $e)."(struct ndr_push *$ndr, int ndr_flags, $args)") or return;
3063
3064         $self->pidl("{");
3065         $self->indent;
3066         $self->ParseTypePush($e, $ndr, $varname, 1, 1);
3067         $self->pidl("return NDR_ERR_SUCCESS;");
3068         $self->deindent;
3069         $self->pidl("}");
3070         $self->pidl("");;
3071 }
3072
3073 sub ParseTypePull($$$$$$)
3074 {
3075         my ($self, $e, $ndr, $varname, $primitives, $deferred) = @_;
3076
3077         # save the old relative_base_offset
3078         $self->pidl("uint32_t _save_relative_base_offset = ndr_pull_get_relative_base_offset($ndr);") if defined(has_property($e, "relative_base"));
3079         $typefamily{$e->{TYPE}}->{PULL_FN_BODY}->($self, $e, $ndr, $varname);
3080         # restore the old relative_base_offset
3081         $self->pidl("ndr_pull_restore_relative_base_offset($ndr, _save_relative_base_offset);") if defined(has_property($e, "relative_base"));
3082 }
3083
3084 sub ParseTypePullFunction($$)
3085 {
3086         my ($self, $e, $varname) = @_;
3087         my $ndr = "ndr";
3088
3089         my $args = $typefamily{$e->{TYPE}}->{DECL}->($e, "pull", $e->{NAME}, $varname);
3090
3091         $self->fn_declare("pull", $e, "enum ndr_err_code ".TypeFunctionName("ndr_pull", $e)."(struct ndr_pull *$ndr, int ndr_flags, $args)") or return;
3092
3093         $self->pidl("{");
3094         $self->indent;
3095         $self->ParseTypePull($e, $ndr, $varname, 1, 1);
3096         $self->pidl("return NDR_ERR_SUCCESS;");
3097         $self->deindent;
3098         $self->pidl("}");
3099         $self->pidl("");
3100 }
3101
3102 sub ParseTypePrint($$$$)
3103 {
3104         my ($self, $e, $ndr, $varname) = @_;
3105
3106         $typefamily{$e->{TYPE}}->{PRINT_FN_BODY}->($self, $e, $ndr, $e->{NAME}, $varname);
3107 }
3108
3109 sub ParseTypePrintFunction($$$)
3110 {
3111         my ($self, $e, $varname) = @_;
3112         my $ndr = "ndr";
3113
3114         my $args = $typefamily{$e->{TYPE}}->{DECL}->($e, "print", $e->{NAME}, $varname);
3115
3116         $self->pidl_hdr("void ".TypeFunctionName("ndr_print", $e)."(struct ndr_print *ndr, const char *name, $args);");
3117
3118         if (is_public_struct($e)) {
3119                 $self->pidl("static void ".TypeFunctionName("ndr_print_flags", $e).
3120                              "(struct ndr_print *$ndr, const char *name, int unused, $args)"
3121                              );
3122                 $self->pidl("{");
3123                 $self->indent;
3124                 $self->pidl(TypeFunctionName("ndr_print", $e)."($ndr, name, $varname);");
3125                 $self->deindent;
3126                 $self->pidl("}");
3127                 $self->pidl("");
3128         }
3129
3130         return if (has_property($e, "noprint"));
3131
3132         $self->pidl("_PUBLIC_ void ".TypeFunctionName("ndr_print", $e)."(struct ndr_print *$ndr, const char *name, $args)");
3133         $self->pidl("{");
3134         $self->indent;
3135         $self->ParseTypePrint($e, $ndr, $varname);
3136         $self->deindent;
3137         $self->pidl("}");
3138         $self->pidl("");
3139 }
3140
3141 sub ParseTypeNdrSize($$)
3142 {
3143         my ($self,$t) = @_;
3144
3145         my $varname = "r";
3146         my $tf = $typefamily{$t->{TYPE}};
3147         my $args = $tf->{SIZE_FN_ARGS}->($t, $t->{NAME}, $varname);
3148
3149         $self->fn_declare("size", $t, "size_t ndr_size_$t->{NAME}($args)") or return;
3150
3151         $self->pidl("{");
3152         $self->indent;
3153         $typefamily{$t->{TYPE}}->{SIZE_FN_BODY}->($self,$t, $t->{NAME}, $varname);
3154         $self->deindent;
3155         $self->pidl("}");
3156         $self->pidl("");
3157 }
3158
3159 #####################################################################
3160 # parse the interface definitions
3161 sub ParseInterface($$$)
3162 {
3163         my($self,$interface,$needed) = @_;
3164
3165         $self->pidl_hdr("#ifndef _HEADER_NDR_$interface->{NAME}");
3166         $self->pidl_hdr("#define _HEADER_NDR_$interface->{NAME}");
3167
3168         $self->pidl_hdr("");
3169
3170         $self->HeaderInterface($interface, $needed);
3171
3172         # Typedefs
3173         foreach my $d (@{$interface->{TYPES}}) {
3174                 if (Parse::Pidl::Typelist::typeIs($d, "PIPE")) {
3175                         ($needed->{TypeFunctionName("ndr_push", $d)}) &&
3176                                 $self->ParsePipePushChunk($d);
3177                         ($needed->{TypeFunctionName("ndr_pull", $d)}) &&
3178                                 $self->ParsePipePullChunk($d);
3179                         ($needed->{TypeFunctionName("ndr_print", $d)}) &&
3180                                 $self->ParsePipePrintChunk($d);
3181
3182                         $needed->{TypeFunctionName("ndr_pull", $d)} = 0;
3183                         $needed->{TypeFunctionName("ndr_push", $d)} = 0;
3184                         $needed->{TypeFunctionName("ndr_print", $d)} = 0;
3185                         next;
3186                 }
3187
3188                 next unless(typeHasBody($d));
3189
3190                 ($needed->{TypeFunctionName("ndr_push", $d)}) && $self->ParseTypePushFunction($d, "r");
3191                 ($needed->{TypeFunctionName("ndr_pull", $d)}) && $self->ParseTypePullFunction($d, "r");
3192                 ($needed->{TypeFunctionName("ndr_print", $d)}) && $self->ParseTypePrintFunction($d, "r");
3193
3194                 # Make sure we don't generate a function twice...
3195                 $needed->{TypeFunctionName("ndr_push", $d)} =
3196                     $needed->{TypeFunctionName("ndr_pull", $d)} =
3197                         $needed->{TypeFunctionName("ndr_print", $d)} = 0;
3198
3199                 ($needed->{"ndr_size_$d->{NAME}"}) && $self->ParseTypeNdrSize($d);
3200         }
3201
3202         # Functions
3203         foreach my $d (@{$interface->{FUNCTIONS}}) {
3204                 ($needed->{"ndr_push_$d->{NAME}"}) && $self->ParseFunctionPush($d);
3205                 ($needed->{"ndr_pull_$d->{NAME}"}) && $self->ParseFunctionPull($d);
3206                 ($needed->{"ndr_print_$d->{NAME}"}) && $self->ParseFunctionPrint($d);
3207         }
3208
3209         # Allow compilation of generated files where replacement functions
3210         # for structures declared nopull/nopush have not been provided.
3211         #
3212         # This makes sense when only the print functions are used
3213         #
3214         # Otherwise the ndr_table XXX will reference these
3215
3216         $self->pidl("#ifndef SKIP_NDR_TABLE_$interface->{NAME}");
3217         $self->FunctionTable($interface);
3218         $self->pidl("#endif /* SKIP_NDR_TABLE_$interface->{NAME} */");
3219
3220         $self->pidl_hdr("#endif /* _HEADER_NDR_$interface->{NAME} */");
3221 }
3222
3223 sub GenerateIncludes($)
3224 {
3225         my ($self) = @_;
3226         if (is_intree()) {
3227                 $self->pidl("#include \"includes.h\"");
3228         } else {
3229                 $self->pidl("#ifndef _GNU_SOURCE");
3230                 $self->pidl("#define _GNU_SOURCE");
3231                 $self->pidl("#endif");
3232                 $self->pidl("#include <stdint.h>");
3233                 $self->pidl("#include <stdlib.h>");
3234                 $self->pidl("#include <stdio.h>");
3235                 $self->pidl("#include <stdbool.h>");
3236                 $self->pidl("#include <stdarg.h>");
3237                 $self->pidl("#include <string.h>");
3238         }
3239 }
3240
3241 #####################################################################
3242 # parse a parsed IDL structure back into an IDL file
3243 sub Parse($$$$)
3244 {
3245         my($self, $ndr,$gen_header,$ndr_header) = @_;
3246
3247         $self->pidl_hdr("/* header auto-generated by pidl */");
3248         $self->pidl_hdr("");
3249         $self->pidl_hdr(choose_header("librpc/ndr/libndr.h", "ndr.h"));
3250         $self->pidl_hdr("#include \"$gen_header\"") if ($gen_header);
3251         $self->pidl_hdr("");
3252
3253         $self->pidl("/* parser auto-generated by pidl */");
3254         $self->pidl("");
3255         $self->GenerateIncludes();
3256         $self->pidl("#include \"$ndr_header\"") if ($ndr_header);
3257         $self->pidl("");
3258
3259         my %needed = ();
3260
3261         foreach (@{$ndr}) {
3262                 ($_->{TYPE} eq "INTERFACE") && NeededInterface($_, \%needed);
3263         }
3264
3265         foreach (@{$ndr}) {
3266                 ($_->{TYPE} eq "INTERFACE") && $self->ParseInterface($_, \%needed);
3267                 ($_->{TYPE} eq "IMPORT") && $self->HeaderImport(@{$_->{PATHS}});
3268                 ($_->{TYPE} eq "INCLUDE") && $self->HeaderInclude(@{$_->{PATHS}});
3269         }
3270
3271         return ($self->{res_hdr}, $self->{res});
3272 }
3273
3274 sub NeededElement($$$)
3275 {
3276         my ($e, $dir, $needed) = @_;
3277
3278         return if ($e->{TYPE} eq "EMPTY");
3279
3280         return if (ref($e->{TYPE}) eq "HASH" and
3281                        not defined($e->{TYPE}->{NAME}));
3282
3283         my ($t, $rt);
3284         if (ref($e->{TYPE}) eq "HASH") {
3285                 $t = $e->{TYPE}->{TYPE}."_".$e->{TYPE}->{NAME};
3286         } else {
3287                 $t = $e->{TYPE};
3288         }
3289
3290         if (ref($e->{REPRESENTATION_TYPE}) eq "HASH") {
3291                 $rt = $e->{REPRESENTATION_TYPE}->{TYPE}."_".$e->{REPRESENTATION_TYPE}->{NAME};
3292         } else {
3293                 $rt = $e->{REPRESENTATION_TYPE};
3294         }
3295
3296         die ("$e->{NAME} $t, $rt FOO") unless ($rt ne "");
3297
3298         my @fn = ();
3299         if ($dir eq "print") {
3300                 push(@fn, TypeFunctionName("ndr_print", $e->{REPRESENTATION_TYPE}));
3301         } elsif ($dir eq "pull") {
3302                 push (@fn, TypeFunctionName("ndr_pull", $e->{TYPE}));
3303                 push (@fn, "ndr_$t\_to_$rt")
3304                         if ($rt ne $t);
3305         } elsif ($dir eq "push") {
3306                 push (@fn, TypeFunctionName("ndr_push", $e->{TYPE}));
3307                 push (@fn, "ndr_$rt\_to_$t")
3308                         if ($rt ne $t);
3309         } else {
3310                 die("invalid direction `$dir'");
3311         }
3312
3313         foreach (@fn) {
3314                 unless (defined($needed->{$_})) {
3315                         $needed->{$_} = 1;
3316                 }
3317         }
3318 }
3319
3320 sub NeededFunction($$)
3321 {
3322         my ($fn,$needed) = @_;
3323         $needed->{"ndr_pull_$fn->{NAME}"} = 1;
3324         $needed->{"ndr_push_$fn->{NAME}"} = 1;
3325         $needed->{"ndr_print_$fn->{NAME}"} = 1;
3326         foreach my $e (@{$fn->{ELEMENTS}}) {
3327                 $e->{PARENT} = $fn;
3328                 NeededElement($e, $_, $needed) foreach ("pull", "push", "print");
3329         }
3330 }
3331
3332 sub NeededType($$$)
3333 {
3334         sub NeededType($$$);
3335         my ($t,$needed,$req) = @_;
3336
3337         NeededType($t->{DATA}, $needed, $req) if ($t->{TYPE} eq "TYPEDEF");
3338         NeededType($t->{DATA}, $needed, $req) if ($t->{TYPE} eq "PIPE");
3339
3340         if ($t->{TYPE} eq "STRUCT" or $t->{TYPE} eq "UNION") {
3341                 return unless defined($t->{ELEMENTS});
3342                 for my $e (@{$t->{ELEMENTS}}) {
3343                         $e->{PARENT} = $t;
3344                         if (has_property($e, "compression")) {
3345                                 $needed->{"compression"} = 1;
3346                         }
3347                         NeededElement($e, $req, $needed);
3348                         NeededType($e->{TYPE}, $needed, $req) if (ref($e->{TYPE}) eq "HASH");
3349                 }
3350         }
3351 }
3352
3353 #####################################################################
3354 # work out what parse functions are needed
3355 sub NeededInterface($$)
3356 {
3357         my ($interface,$needed) = @_;
3358         NeededFunction($_, $needed) foreach (@{$interface->{FUNCTIONS}});
3359         foreach (reverse @{$interface->{TYPES}}) {
3360
3361                 if (has_property($_, "public")) {
3362                         $needed->{TypeFunctionName("ndr_pull", $_)} = $needed->{TypeFunctionName("ndr_push", $_)} =
3363                                 $needed->{TypeFunctionName("ndr_print", $_)} = 1;
3364                 }
3365
3366                 NeededType($_, $needed, "pull") if ($needed->{TypeFunctionName("ndr_pull", $_)});
3367                 NeededType($_, $needed, "push") if ($needed->{TypeFunctionName("ndr_push", $_)});
3368                 NeededType($_, $needed, "print") if ($needed->{TypeFunctionName("ndr_print", $_)});
3369                 if (has_property($_, "gensize")) {
3370                         $needed->{"ndr_size_$_->{NAME}"} = 1;
3371                 }
3372         }
3373 }
3374
3375 sub TypeFunctionName($$)
3376 {
3377         my ($prefix, $t) = @_;
3378
3379         return "$prefix\_$t->{NAME}" if (ref($t) eq "HASH" and
3380                         $t->{TYPE} eq "TYPEDEF");
3381         return "$prefix\_$t->{TYPE}_$t->{NAME}" if (ref($t) eq "HASH");
3382         return "$prefix\_$t";
3383 }
3384
3385 1;