selftest/target/Samba3.pm

   1 #!/usr/bin/perl
   2 # Bootstrap Samba and run a number of tests against it.
   3 # Copyright (C) 2005-2007 Jelmer Vernooij <jelmer@samba.org>
   4 # Published under the GNU GPL, v3 or later.
   5
   6 package Samba3;
   7
   8 use strict;
   9 use Cwd qw(abs_path);
  10 use FindBin qw($RealBin);
  11 use POSIX;
  12
  13 sub binpath($$)
  14 {
  15         my ($self, $binary) = @_;
  16
  17         if (defined($self->{bindir})) {
  18                 my $path = "$self->{bindir}/$binary";
  19                 -f $path or die("File $path doesn't exist");
  20                 return $path;
  21         }
  22
  23         return $binary;
  24 }
  25
  26 sub new($$) {
  27         my ($classname, $bindir) = @_;
  28         my $self = { bindir => $bindir };
  29         bless $self;
  30         return $self;
  31 }
  32
  33 sub teardown_env($$)
  34 {
  35         my ($self, $envvars) = @_;
  36
  37         my $smbdpid = read_pid($envvars, "smbd");
  38         my $nmbdpid = read_pid($envvars, "nmbd");
  39         my $winbinddpid = read_pid($envvars, "winbindd");
  40
  41         $self->stop_sig_term($smbdpid);
  42         $self->stop_sig_term($nmbdpid);
  43         $self->stop_sig_term($winbinddpid);
  44
  45         sleep(2);
  46
  47         $self->stop_sig_kill($smbdpid);
  48         $self->stop_sig_kill($nmbdpid);
  49         $self->stop_sig_kill($winbinddpid);
  50
  51         return 0;
  52 }
  53
  54 sub getlog_env_app($$$)
  55 {
  56         my ($self, $envvars, $name) = @_;
  57
  58         my $title = "$name LOG of: $envvars->{NETBIOSNAME}\n";
  59         my $out = $title;
  60
  61         open(LOG, "<".$envvars->{$name."_TEST_LOG"});
  62
  63         seek(LOG, $envvars->{$name."_TEST_LOG_POS"}, SEEK_SET);
  64         while (<LOG>) {
  65                 $out .= $_;
  66         }
  67         $envvars->{$name."_TEST_LOG_POS"} = tell(LOG);
  68         close(LOG);
  69
  70         return "" if $out eq $title;
  71
  72         return $out;
  73 }
  74
  75 sub getlog_env($$)
  76 {
  77         my ($self, $envvars) = @_;
  78         my $ret = "";
  79
  80         $ret .= $self->getlog_env_app($envvars, "SMBD");
  81         $ret .= $self->getlog_env_app($envvars, "NMBD");
  82         $ret .= $self->getlog_env_app($envvars, "WINBINDD");
  83
  84         return $ret;
  85 }
  86
  87 sub check_env($$)
  88 {
  89         my ($self, $envvars) = @_;
  90
  91         # TODO ...
  92         return 1;
  93 }
  94
  95 sub setup_env($$$)
  96 {
  97         my ($self, $envname, $path) = @_;
  98
  99         if ($envname eq "dc") {
 100                 return $self->setup_dc("$path/dc");
 101         } elsif ($envname eq "member") {
 102                 if (not defined($self->{vars}->{dc})) {
 103                         $self->setup_dc("$path/dc");
 104                 }
 105                 return $self->setup_member("$path/member", $self->{vars}->{dc});
 106         } else {
 107                 return undef;
 108         }
 109 }
 110
 111 sub setup_dc($$)
 112 {
 113         my ($self, $path) = @_;
 114
 115         print "PROVISIONING DC...";
 116
 117         my $dc_options = "
 118         domain master = yes
 119         domain logons = yes
 120         lanman auth = yes
 121 ";
 122
 123         my $vars = $self->provision($path,
 124                                     "LOCALDC2",
 125                                     2,
 126                                     "localdc2pass",
 127                                     $dc_options);
 128
 129         $self->check_or_start($vars,
 130                               ($ENV{SMBD_MAXTIME} or 2700),
 131                                "yes", "yes", "yes");
 132
 133         $self->wait_for_start($vars);
 134
 135         $self->{vars}->{dc} = $vars;
 136
 137         return $vars;
 138 }
 139
 140 sub setup_member($$$)
 141 {
 142         my ($self, $prefix, $dcvars) = @_;
 143
 144         print "PROVISIONING MEMBER...";
 145
 146         my $member_options = "
 147         security = domain
 148         server signing = on
 149 ";
 150         my $ret = $self->provision($prefix,
 151                                    "LOCALMEMBER3",
 152                                    3,
 153                                    "localmember3pass",
 154                                    $member_options);
 155
 156         $ret or die("Unable to provision");
 157
 158         my $net = $self->binpath("net");
 159         my $cmd = "";
 160         $cmd .= "SOCKET_WRAPPER_DEFAULT_IFACE=\"$ret->{SOCKET_WRAPPER_DEFAULT_IFACE}\" ";
 161         $cmd .= "$net join $ret->{CONFIGURATION} $dcvars->{DOMAIN} member";
 162         $cmd .= " -U$dcvars->{USERNAME}\%$dcvars->{PASSWORD}";
 163
 164         system($cmd) == 0 or die("Join failed\n$cmd");
 165
 166         $self->check_or_start($ret,
 167                               ($ENV{SMBD_MAXTIME} or 2700),
 168                                "yes", "yes", "yes");
 169
 170         $self->wait_for_start($ret);
 171
 172         $ret->{DC_SERVER} = $dcvars->{SERVER};
 173         $ret->{DC_SERVER_IP} = $dcvars->{SERVER_IP};
 174         $ret->{DC_NETBIOSNAME} = $dcvars->{NETBIOSNAME};
 175         $ret->{DC_USERNAME} = $dcvars->{USERNAME};
 176         $ret->{DC_PASSWORD} = $dcvars->{PASSWORD};
 177
 178         return $ret;
 179 }
 180
 181 sub stop($)
 182 {
 183         my ($self) = @_;
 184 }
 185
 186 sub stop_sig_term($$) {
 187         my ($self, $pid) = @_;
 188         kill("USR1", $pid) or kill("ALRM", $pid) or warn("Unable to kill $pid: $!");
 189 }
 190
 191 sub stop_sig_kill($$) {
 192         my ($self, $pid) = @_;
 193         kill("ALRM", $pid) or warn("Unable to kill $pid: $!");
 194 }
 195
 196 sub write_pid($$$)
 197 {
 198         my ($env_vars, $app, $pid) = @_;
 199
 200         open(PID, ">$env_vars->{PIDDIR}/timelimit.$app.pid");
 201         print PID $pid;
 202         close(PID);
 203 }
 204
 205 sub read_pid($$)
 206 {
 207         my ($env_vars, $app) = @_;
 208
 209         open(PID, "<$env_vars->{PIDDIR}/timelimit.$app.pid");
 210         my $pid = <PID>;
 211         close(PID);
 212         return $pid;
 213 }
 214
 215 sub check_or_start($$$$$) {
 216         my ($self, $env_vars, $maxtime, $nmbd, $winbindd, $smbd) = @_;
 217
 218         unlink($env_vars->{NMBD_TEST_LOG});
 219         print "STARTING NMBD...";
 220         my $pid = fork();
 221         if ($pid == 0) {
 222                 open STDOUT, ">$env_vars->{NMBD_TEST_LOG}";
 223                 open STDERR, '>&STDOUT';
 224
 225                 SocketWrapper::set_default_iface($env_vars->{SOCKET_WRAPPER_DEFAULT_IFACE});
 226
 227                 $ENV{WINBINDD_SOCKET_DIR} = $env_vars->{WINBINDD_SOCKET_DIR};
 228
 229                 $ENV{NSS_WRAPPER_PASSWD} = $env_vars->{NSS_WRAPPER_PASSWD};
 230                 $ENV{NSS_WRAPPER_GROUP} = $env_vars->{NSS_WRAPPER_GROUP};
 231                 $ENV{NSS_WRAPPER_WINBIND_SO_PATH} = $env_vars->{NSS_WRAPPER_WINBIND_SO_PATH};
 232
 233                 if ($nmbd ne "yes") {
 234                         $SIG{USR1} = $SIG{ALRM} = $SIG{INT} = $SIG{QUIT} = $SIG{TERM} = sub {
 235                                 my $signame = shift;
 236                                 print("Skip nmbd received signal $signame");
 237                                 exit 0;
 238                         };
 239                         sleep($maxtime);
 240                         exit 0;
 241                 }
 242
 243                 my @optargs = ("-d0");
 244                 if (defined($ENV{NMBD_OPTIONS})) {
 245                         @optargs = split(/ /, $ENV{NMBD_OPTIONS});
 246                 }
 247
 248                 $ENV{MAKE_TEST_BINARY} = $self->binpath("nmbd");
 249
 250                 my @preargs = ($self->binpath("timelimit"), $maxtime);
 251                 if(defined($ENV{NMBD_VALGRIND})) {
 252                         @preargs = split(/ /, $ENV{NMBD_VALGRIND});
 253                 }
 254
 255                 exec(@preargs, $self->binpath("nmbd"), "-F", "--no-process-group", "-s", $env_vars->{SERVERCONFFILE}, @optargs) or die("Unable to start nmbd: $!");
 256         }
 257         write_pid($env_vars, "nmbd", $pid);
 258         print "DONE\n";
 259
 260         unlink($env_vars->{WINBINDD_TEST_LOG});
 261         print "STARTING WINBINDD...";
 262         $pid = fork();
 263         if ($pid == 0) {
 264                 open STDOUT, ">$env_vars->{WINBINDD_TEST_LOG}";
 265                 open STDERR, '>&STDOUT';
 266
 267                 SocketWrapper::set_default_iface($env_vars->{SOCKET_WRAPPER_DEFAULT_IFACE});
 268
 269                 $ENV{WINBINDD_SOCKET_DIR} = $env_vars->{WINBINDD_SOCKET_DIR};
 270
 271                 $ENV{NSS_WRAPPER_PASSWD} = $env_vars->{NSS_WRAPPER_PASSWD};
 272                 $ENV{NSS_WRAPPER_GROUP} = $env_vars->{NSS_WRAPPER_GROUP};
 273                 $ENV{NSS_WRAPPER_WINBIND_SO_PATH} = $env_vars->{NSS_WRAPPER_WINBIND_SO_PATH};
 274
 275                 if ($winbindd ne "yes") {
 276                         $SIG{USR1} = $SIG{ALRM} = $SIG{INT} = $SIG{QUIT} = $SIG{TERM} = sub {
 277                                 my $signame = shift;
 278                                 print("Skip winbindd received signal $signame");
 279                                 exit 0;
 280                         };
 281                         sleep($maxtime);
 282                         exit 0;
 283                 }
 284
 285                 my @optargs = ("-d0");
 286                 if (defined($ENV{WINBINDD_OPTIONS})) {
 287                         @optargs = split(/ /, $ENV{WINBINDD_OPTIONS});
 288                 }
 289
 290                 $ENV{MAKE_TEST_BINARY} = $self->binpath("winbindd");
 291
 292                 my @preargs = ($self->binpath("timelimit"), $maxtime);
 293                 if(defined($ENV{WINBINDD_VALGRIND})) {
 294                         @preargs = split(/ /, $ENV{WINBINDD_VALGRIND});
 295                 }
 296
 297                 exec(@preargs, $self->binpath("winbindd"), "-F", "--no-process-group", "-s", $env_vars->{SERVERCONFFILE}, @optargs) or die("Unable to start winbindd: $!");
 298         }
 299         write_pid($env_vars, "winbindd", $pid);
 300         print "DONE\n";
 301
 302         unlink($env_vars->{SMBD_TEST_LOG});
 303         print "STARTING SMBD...";
 304         $pid = fork();
 305         if ($pid == 0) {
 306                 open STDOUT, ">$env_vars->{SMBD_TEST_LOG}";
 307                 open STDERR, '>&STDOUT';
 308
 309                 SocketWrapper::set_default_iface($env_vars->{SOCKET_WRAPPER_DEFAULT_IFACE});
 310
 311                 $ENV{WINBINDD_SOCKET_DIR} = $env_vars->{WINBINDD_SOCKET_DIR};
 312
 313                 $ENV{NSS_WRAPPER_PASSWD} = $env_vars->{NSS_WRAPPER_PASSWD};
 314                 $ENV{NSS_WRAPPER_GROUP} = $env_vars->{NSS_WRAPPER_GROUP};
 315                 $ENV{NSS_WRAPPER_WINBIND_SO_PATH} = $env_vars->{NSS_WRAPPER_WINBIND_SO_PATH};
 316
 317                 if ($smbd ne "yes") {
 318                         $SIG{USR1} = $SIG{ALRM} = $SIG{INT} = $SIG{QUIT} = $SIG{TERM} = sub {
 319                                 my $signame = shift;
 320                                 print("Skip smbd received signal $signame");
 321                                 exit 0;
 322                         };
 323                         sleep($maxtime);
 324                         exit 0;
 325                 }
 326
 327                 $ENV{MAKE_TEST_BINARY} = $self->binpath("smbd");
 328                 my @optargs = ("-d0");
 329                 if (defined($ENV{SMBD_OPTIONS})) {
 330                         @optargs = split(/ /, $ENV{SMBD_OPTIONS});
 331                 }
 332                 my @preargs = ($self->binpath("timelimit"), $maxtime);
 333                 if(defined($ENV{SMBD_VALGRIND})) {
 334                         @preargs = split(/ /,$ENV{SMBD_VALGRIND});
 335                 }
 336                 exec(@preargs, $self->binpath("smbd"), "-F", "--no-process-group", "-s", $env_vars->{SERVERCONFFILE}, @optargs) or die("Unable to start smbd: $!");
 337         }
 338         write_pid($env_vars, "smbd", $pid);
 339         print "DONE\n";
 340
 341         return 0;
 342 }
 343
 344 sub provision($$$$$$)
 345 {
 346         my ($self, $prefix, $server, $swiface, $password, $extra_options) = @_;
 347
 348         ##
 349         ## setup the various environment variables we need
 350         ##
 351
 352         my %ret = ();
 353         my $server_ip = "127.0.0.$swiface";
 354         my $domain = "SAMBA-TEST";
 355
 356         my $unix_name = ($ENV{USER} or $ENV{LOGNAME} or `PATH=/usr/ucb:$ENV{PATH} whoami`);
 357         chomp $unix_name;
 358         my $unix_uid = $>;
 359         my $unix_gids_str = $);
 360         my @unix_gids = split(" ", $unix_gids_str);
 361
 362         my $prefix_abs = abs_path($prefix);
 363         my $bindir_abs = abs_path($self->{bindir});
 364
 365         my @dirs = ();
 366
 367         my $shrdir="$prefix_abs/share";
 368         push(@dirs,$shrdir);
 369
 370         my $libdir="$prefix_abs/lib";
 371         push(@dirs,$libdir);
 372
 373         my $piddir="$prefix_abs/pid";
 374         push(@dirs,$piddir);
 375
 376         my $privatedir="$prefix_abs/private";
 377         push(@dirs,$privatedir);
 378
 379         my $lockdir="$prefix_abs/lockdir";
 380         push(@dirs,$lockdir);
 381
 382         my $eventlogdir="$prefix_abs/lockdir/eventlog";
 383         push(@dirs,$eventlogdir);
 384
 385         my $logdir="$prefix_abs/logs";
 386         push(@dirs,$logdir);
 387
 388         my $driver32dir="$shrdir/W32X86";
 389         push(@dirs,$driver32dir);
 390
 391         my $driver64dir="$shrdir/x64";
 392         push(@dirs,$driver64dir);
 393
 394         my $ro_shrdir="$shrdir/root-tmp";
 395         push(@dirs,$ro_shrdir);
 396
 397         my $msdfs_shrdir="$shrdir/msdfsshare";
 398         push(@dirs,$msdfs_shrdir);
 399
 400         my $msdfs_deeppath="$msdfs_shrdir/deeppath";
 401         push(@dirs,$msdfs_deeppath);
 402
 403         # this gets autocreated by winbindd
 404         my $wbsockdir="$prefix_abs/winbindd";
 405         my $wbsockprivdir="$lockdir/winbindd_privileged";
 406
 407         ##
 408         ## create the test directory layout
 409         ##
 410         die ("prefix_abs = ''") if $prefix_abs eq "";
 411         die ("prefix_abs = '/'") if $prefix_abs eq "/";
 412
 413         mkdir($prefix_abs, 0777);
 414         print "CREATE TEST ENVIRONMENT IN '$prefix'...";
 415         system("rm -rf $prefix_abs/*");
 416         mkdir($_, 0777) foreach(@dirs);
 417
 418         ##
 419         ## create ro and msdfs share layout
 420         ##
 421
 422         chmod 0755, $ro_shrdir;
 423         my $unreadable_file = "$ro_shrdir/unreadable_file";
 424         open(UNREADABLE_FILE, ">$unreadable_file") or die("Unable to open $unreadable_file");
 425         close(UNREADABLE_FILE);
 426         chmod 0600, $unreadable_file;
 427
 428         my $msdfs_target = "$ro_shrdir/msdfs-target";
 429         open(MSDFS_TARGET, ">$msdfs_target") or die("Unable to open $msdfs_target");
 430         close(MSDFS_TARGET);
 431         chmod 0666, $msdfs_target;
 432         symlink "msdfs:$server_ip\\ro-tmp", "$msdfs_shrdir/msdfs-src1";
 433         symlink "msdfs:$server_ip\\ro-tmp", "$msdfs_shrdir/deeppath/msdfs-src2";
 434
 435         my $conffile="$libdir/server.conf";
 436
 437         my $nss_wrapper_pl = "$ENV{PERL} $RealBin/../lib/nss_wrapper/nss_wrapper.pl";
 438         my $nss_wrapper_passwd = "$privatedir/passwd";
 439         my $nss_wrapper_group = "$privatedir/group";
 440
 441         my $mod_printer_pl = "$ENV{PERL} $RealBin/../source3/script/tests/printing/modprinter.pl";
 442
 443         my @eventlog_list = ("dns server", "application");
 444
 445         ##
 446         ## calculate uids and gids
 447         ##
 448
 449         my ($max_uid, $max_gid);
 450         my ($uid_nobody, $uid_root);
 451         my ($gid_nobody, $gid_nogroup, $gid_root);
 452
 453         if ($unix_uid < 0xffff - 2) {
 454                 $max_uid = 0xffff;
 455         } else {
 456                 $max_uid = $unix_uid;
 457         }
 458
 459         $uid_root = $max_uid - 1;
 460         $uid_nobody = $max_uid - 2;
 461
 462         if ($unix_gids[0] < 0xffff - 3) {
 463                 $max_gid = 0xffff;
 464         } else {
 465                 $max_gid = $unix_gids[0];
 466         }
 467
 468         $gid_nobody = $max_gid - 1;
 469         $gid_nogroup = $max_gid - 2;
 470         $gid_root = $max_gid - 3;
 471
 472         ##
 473         ## create conffile
 474         ##
 475
 476         open(CONF, ">$conffile") or die("Unable to open $conffile");
 477         print CONF "
 478 [global]
 479         netbios name = $server
 480         interfaces = $server_ip/8
 481         bind interfaces only = yes
 482         panic action = $RealBin/gdb_backtrace %d %\$(MAKE_TEST_BINARY)
 483
 484         workgroup = $domain
 485
 486         private dir = $privatedir
 487         pid directory = $piddir
 488         lock directory = $lockdir
 489         log file = $logdir/log.\%m
 490         log level = 0
 491
 492         name resolve order = bcast
 493
 494         state directory = $lockdir
 495         cache directory = $lockdir
 496
 497         passdb backend = tdbsam
 498
 499         time server = yes
 500
 501         add user script =               $nss_wrapper_pl --passwd_path $nss_wrapper_passwd --type passwd --action add --name %u --gid $gid_nogroup
 502         add group script =              $nss_wrapper_pl --group_path  $nss_wrapper_group  --type group  --action add --name %g
 503         add machine script =            $nss_wrapper_pl --passwd_path $nss_wrapper_passwd --type passwd --action add --name %u --gid $gid_nogroup
 504         add user to group script =      $nss_wrapper_pl --passwd_path $nss_wrapper_passwd --type member --action add --member %u --name %g --group_path $nss_wrapper_group
 505         delete user script =            $nss_wrapper_pl --passwd_path $nss_wrapper_passwd --type passwd --action delete --name %u
 506         delete group script =           $nss_wrapper_pl --group_path  $nss_wrapper_group  --type group  --action delete --name %g
 507         delete user from group script = $nss_wrapper_pl --passwd_path $nss_wrapper_passwd --type member --action delete --member %u --name %g --group_path $nss_wrapper_group
 508
 509         addprinter command =            $mod_printer_pl -a -s $conffile --
 510         deleteprinter command =         $mod_printer_pl -d -s $conffile --
 511
 512         eventlog list = application \"dns server\"
 513
 514         kernel oplocks = no
 515         kernel change notify = no
 516
 517         syslog = no
 518         printing = bsd
 519         printcap name = /dev/null
 520
 521         winbindd:socket dir = $wbsockdir
 522         idmap uid = 100000-200000
 523         idmap gid = 100000-200000
 524         winbind enum users = yes
 525         winbind enum groups = yes
 526
 527 #       min receivefile size = 4000
 528
 529         read only = no
 530         smbd:sharedelay = 100000
 531 #       smbd:writetimeupdatedelay = 500000
 532         map hidden = no
 533         map system = no
 534         map readonly = no
 535         store dos attributes = yes
 536         create mask = 755
 537         vfs objects = $bindir_abs/xattr_tdb.so $bindir_abs/streams_depot.so
 538
 539         printing = vlp
 540         print command = $bindir_abs/vlp tdbfile=$lockdir/vlp.tdb print %p %s
 541         lpq command = $bindir_abs/vlp tdbfile=$lockdir/vlp.tdb lpq %p
 542         lp rm command = $bindir_abs/vlp tdbfile=$lockdir/vlp.tdb lprm %p %j
 543         lp pause command = $bindir_abs/vlp tdbfile=$lockdir/vlp.tdb lppause %p %j
 544         lp resume command = $bindir_abs/vlp tdbfile=$lockdir/vlp.tdb lpresume %p %j
 545         queue pause command = $bindir_abs/vlp tdbfile=$lockdir/vlp.tdb queuepause %p
 546         queue resume command = $bindir_abs/vlp tdbfile=$lockdir/vlp.tdb queueresume %p
 547         lpq cache time = 0
 548
 549         # Begin extra options
 550         $extra_options
 551         # End extra options
 552
 553         #Include user defined custom parameters if set
 554 ";
 555
 556         if (defined($ENV{INCLUDE_CUSTOM_CONF})) {
 557                 print CONF "\t$ENV{INCLUDE_CUSTOM_CONF}\n";
 558         }
 559
 560         print CONF "
 561 [tmp]
 562         path = $shrdir
 563 [ro-tmp]
 564         path = $ro_shrdir
 565         guest ok = yes
 566 [msdfs-share]
 567         path = $msdfs_shrdir
 568         msdfs root = yes
 569         guest ok = yes
 570 [hideunread]
 571         copy = tmp
 572         hide unreadable = yes
 573 [tmpcase]
 574         copy = tmp
 575         case sensitive = yes
 576 [hideunwrite]
 577         copy = tmp
 578         hide unwriteable files = yes
 579 [print1]
 580         copy = tmp
 581         printable = yes
 582
 583 [print2]
 584         copy = print1
 585 [print3]
 586         copy = print1
 587 [print4]
 588         copy = print1
 589 [print\$]
 590         copy = tmp
 591         ";
 592         close(CONF);
 593
 594         ##
 595         ## create a test account
 596         ##
 597
 598         open(PASSWD, ">$nss_wrapper_passwd") or die("Unable to open $nss_wrapper_passwd");
 599         print PASSWD "nobody:x:$uid_nobody:$gid_nobody:nobody gecos:$prefix_abs:/bin/false
 600 $unix_name:x:$unix_uid:$unix_gids[0]:$unix_name gecos:$prefix_abs:/bin/false
 601 ";
 602         if ($unix_uid != 0) {
 603                 print PASSWD "root:x:$uid_root:$gid_root:root gecos:$prefix_abs:/bin/false";
 604         }
 605         close(PASSWD);
 606
 607         open(GROUP, ">$nss_wrapper_group") or die("Unable to open $nss_wrapper_group");
 608         print GROUP "nobody:x:$gid_nobody:
 609 nogroup:x:$gid_nogroup:nobody
 610 $unix_name-group:x:$unix_gids[0]:
 611 ";
 612         if ($unix_gids[0] != 0) {
 613                 print GROUP "root:x:$gid_root:";
 614         }
 615
 616         close(GROUP);
 617
 618         foreach my $evlog (@eventlog_list) {
 619                 my $evlogtdb = "$eventlogdir/$evlog.tdb";
 620                 open(EVENTLOG, ">$evlogtdb") or die("Unable to open $evlogtdb");
 621                 close(EVENTLOG);
 622         }
 623
 624         $ENV{NSS_WRAPPER_PASSWD} = $nss_wrapper_passwd;
 625         $ENV{NSS_WRAPPER_GROUP} = $nss_wrapper_group;
 626
 627         open(PWD, "|".$self->binpath("smbpasswd")." -c $conffile -L -s -a $unix_name >/dev/null");
 628         print PWD "$password\n$password\n";
 629         close(PWD) or die("Unable to set password for test account");
 630
 631         delete $ENV{NSS_WRAPPER_PASSWD};
 632         delete $ENV{NSS_WRAPPER_GROUP};
 633
 634         print "DONE\n";
 635
 636         $ret{SERVER_IP} = $server_ip;
 637         $ret{NMBD_TEST_LOG} = "$prefix/nmbd_test.log";
 638         $ret{NMBD_TEST_LOG_POS} = 0;
 639         $ret{WINBINDD_TEST_LOG} = "$prefix/winbindd_test.log";
 640         $ret{WINBINDD_TEST_LOG_POS} = 0;
 641         $ret{SMBD_TEST_LOG} = "$prefix/smbd_test.log";
 642         $ret{SMBD_TEST_LOG_POS} = 0;
 643         $ret{SERVERCONFFILE} = $conffile;
 644         $ret{CONFIGURATION} ="-s $conffile";
 645         $ret{SERVER} = $server;
 646         $ret{USERNAME} = $unix_name;
 647         $ret{USERID} = $unix_uid;
 648         $ret{DOMAIN} = $domain;
 649         $ret{NETBIOSNAME} = $server;
 650         $ret{PASSWORD} = $password;
 651         $ret{PIDDIR} = $piddir;
 652         $ret{WINBINDD_SOCKET_DIR} = $wbsockdir;
 653         $ret{WINBINDD_PRIV_PIPE_DIR} = $wbsockprivdir;
 654         $ret{SOCKET_WRAPPER_DEFAULT_IFACE} = $swiface;
 655         $ret{NSS_WRAPPER_PASSWD} = $nss_wrapper_passwd;
 656         $ret{NSS_WRAPPER_GROUP} = $nss_wrapper_group;
 657         $ret{NSS_WRAPPER_WINBIND_SO_PATH} = $ENV{NSS_WRAPPER_WINBIND_SO_PATH};
 658         $ret{LOCAL_PATH} = "$shrdir";
 659
 660         return \%ret;
 661 }
 662
 663 sub wait_for_start($$)
 664 {
 665         my ($self, $envvars) = @_;
 666
 667         # give time for nbt server to register its names
 668         print "delaying for nbt name registration\n";
 669         sleep(10);
 670         # This will return quickly when things are up, but be slow if we need to wait for (eg) SSL init
 671         system($self->binpath("nmblookup") ." $envvars->{CONFIGURATION} -U $envvars->{SERVER_IP} __SAMBA__");
 672         system($self->binpath("nmblookup") ." $envvars->{CONFIGURATION} __SAMBA__");
 673         system($self->binpath("nmblookup") ." $envvars->{CONFIGURATION} -U 127.255.255.255 __SAMBA__");
 674         system($self->binpath("nmblookup") ." $envvars->{CONFIGURATION} -U $envvars->{SERVER_IP} $envvars->{SERVER}");
 675         system($self->binpath("nmblookup") ." $envvars->{CONFIGURATION} $envvars->{SERVER}");
 676         # make sure smbd is also up set
 677         print "wait for smbd\n";
 678         system($self->binpath("smbclient") ." $envvars->{CONFIGURATION} -L $envvars->{SERVER_IP} -U% -p 139 | head -2");
 679         system($self->binpath("smbclient") ." $envvars->{CONFIGURATION} -L $envvars->{SERVER_IP} -U% -p 139 | head -2");
 680
 681         print $self->getlog_env($envvars);
 682 }
 683
 684 1;