source4/build/smb_build/input.pm

   1 # Samba Build System
   2 # - the input checking functions
   3 #
   4 #  Copyright (C) Stefan (metze) Metzmacher 2004
   5 #  Copyright (C) Jelmer Vernooij 2004
   6 #  Released under the GNU GPL
   7
   8 use strict;
   9 package smb_build::input;
  10
  11 my $srcdir = ".";
  12
  13 sub strtrim($)
  14 {
  15         $_ = shift;
  16         s/^[\t\n ]*//g;
  17         s/[\t\n ]*$//g;
  18         return $_;
  19 }
  20
  21 sub str2array($)
  22 {
  23         $_ = shift;
  24         s/^[\t\n ]*//g;
  25         s/[\t\n ]*$//g;
  26         s/([\t\n ]+)/ /g;
  27
  28         return () if (length($_)==0);
  29         return split /[ \t\n]/;
  30 }
  31
  32 sub check_subsystem($$$)
  33 {
  34         my ($INPUT, $subsys, $default_ot) = @_;
  35         if ($subsys->{ENABLE} ne "YES") {
  36                 printf("Subsystem `%s' disabled\n",$subsys->{NAME});
  37                 return;
  38         }
  39
  40         unless(defined($subsys->{OUTPUT_TYPE})) {
  41                 $subsys->{OUTPUT_TYPE} = $default_ot;
  42         }
  43 }
  44
  45 sub check_module($$$)
  46 {
  47         my ($INPUT, $mod, $default_ot) = @_;
  48
  49         die("Module $mod->{NAME} does not have a SUBSYSTEM set") if not defined($mod->{SUBSYSTEM});
  50
  51         my $use_default = 0;
  52
  53         if (not exists($INPUT->{$mod->{SUBSYSTEM}}{INIT_FUNCTIONS})) {
  54                 $INPUT->{$mod->{SUBSYSTEM}}{INIT_FUNCTIONS} = [];
  55         }
  56
  57         if (!(defined($INPUT->{$mod->{SUBSYSTEM}}))) {
  58                 $mod->{ENABLE} = "NO";
  59                 return;
  60         }
  61
  62         if ($mod->{ENABLE} ne "YES")
  63         {
  64                 printf("Module `%s' disabled\n",$mod->{NAME});
  65                 return;
  66         }
  67
  68         if (defined($mod->{CHOSEN_BUILD}) and $mod->{CHOSEN_BUILD} ne "DEFAULT")
  69         {
  70                 $mod->{OUTPUT_TYPE} = $mod->{CHOSEN_BUILD};
  71         } else {
  72                 $mod->{OUTPUT_TYPE} = $default_ot;
  73         }
  74
  75         if ($mod->{OUTPUT_TYPE} eq "SHARED_LIBRARY") {
  76                 $mod->{INSTALLDIR} = "LIBDIR/$mod->{SUBSYSTEM}";
  77                 push (@{$mod->{REQUIRED_SUBSYSTEMS}}, $mod->{SUBSYSTEM});
  78         } else {
  79                 push (@{$INPUT->{$mod->{SUBSYSTEM}}{REQUIRED_SUBSYSTEMS}}, $mod->{NAME});
  80                 push (@{$INPUT->{$mod->{SUBSYSTEM}}{INIT_FUNCTIONS}}, $mod->{INIT_FUNCTION}) if defined($mod->{INIT_FUNCTION});
  81         }
  82 }
  83
  84 sub check_library($$$)
  85 {
  86         my ($INPUT, $lib, $default_ot) = @_;
  87
  88         if ($lib->{ENABLE} ne "YES") {
  89                 printf("Library `%s' disabled\n",$lib->{NAME});
  90                 return;
  91         }
  92
  93         $lib->{OUTPUT_TYPE} = $default_ot;
  94
  95         unless (defined($lib->{MAJOR_VERSION})) {
  96                 print "$lib->{NAME}: Please specify MAJOR_VERSION\n";
  97                 return;
  98         }
  99
 100         $lib->{INSTALLDIR} = "LIBDIR";
 101 }
 102
 103 sub check_binary($$)
 104 {
 105         my ($INPUT, $bin) = @_;
 106
 107         if ($bin->{ENABLE} ne "YES") {
 108                 printf("Binary `%s' disabled\n",$bin->{NAME});
 109                 return;
 110         }
 111
 112         ($bin->{BINARY} = (lc $bin->{NAME})) if not defined($bin->{BINARY});
 113
 114         $bin->{OUTPUT_TYPE} = "BINARY";
 115 }
 116
 117 sub calc_unique_deps($$)
 118 {
 119         sub calc_unique_deps($$);
 120         my ($deps, $udeps) = @_;
 121
 122         foreach my $dep (@{$deps}) {
 123                 if (not defined($udeps->{$$dep->{NAME}})) {
 124                    if (defined ($$dep->{OUTPUT_TYPE}) && (($$dep->{OUTPUT_TYPE} eq "OBJ_LIST")
 125                             or ($$dep->{OUTPUT_TYPE} eq "MERGEDOBJ"))) {
 126                                 $udeps->{$$dep->{NAME}} = "BUSY";
 127                                 calc_unique_deps($$dep->{DEPENDENCIES}, $udeps);
 128                         }
 129                         $udeps->{$$dep->{NAME}} = $$dep;
 130                 }
 131         }
 132 }
 133
 134 sub check($$$$$)
 135 {
 136         my ($INPUT, $enabled, $subsys_ot, $lib_ot, $module_ot) = @_;
 137
 138         foreach my $part (values %$INPUT) {
 139                 unless(defined($part->{NOPROTO})) {
 140                         $part->{NOPROTO} = "NO";
 141                 }
 142
 143                 if (defined($enabled->{$part->{NAME}})) {
 144                         $part->{ENABLE} = $enabled->{$part->{NAME}};
 145                         next;
 146                 }
 147
 148                 unless(defined($part->{ENABLE})) {
 149                         $part->{ENABLE} = "YES";
 150                 }
 151         }
 152
 153         foreach my $k (keys %$INPUT) {
 154                 my $part = $INPUT->{$k};
 155
 156                 check_subsystem($INPUT, $part, $subsys_ot) if ($part->{TYPE} eq "SUBSYSTEM");
 157                 check_module($INPUT, $part, $module_ot) if ($part->{TYPE} eq "MODULE");
 158                 check_library($INPUT, $part, $lib_ot) if ($part->{TYPE} eq "LIBRARY");
 159                 check_binary($INPUT, $part) if ($part->{TYPE} eq "BINARY");
 160         }
 161
 162         my %depend = %$INPUT;
 163
 164         foreach my $part (values %depend) {
 165
 166                 # Generate list of dependencies
 167                 $part->{DEPENDENCIES} = [];
 168
 169                 foreach my $key (@{$part->{REQUIRED_SUBSYSTEMS}}) {
 170                         die("$part->{NAME} has undefined dependency $key\n") if not defined($depend{$key});
 171                         push (@{$part->{DEPENDENCIES}}, \$depend{$key});
 172                 }
 173
 174                 delete ($part->{REQUIRED_SUBSYSTEMS});
 175         }
 176
 177         foreach my $part (values %depend) {
 178                 $part->{UNIQUE_DEPENDENCIES} = {};
 179                 calc_unique_deps($part->{DEPENDENCIES}, $part->{UNIQUE_DEPENDENCIES});
 180         }
 181
 182         return \%depend;
 183 }
 184
 185 1;