source4/lib/events/libevents.m4

   1 dnl find the events sources. This is meant to work both for
   2 dnl standalone builds, and builds of packages using libevents
   3 if test x"$eventsdir" = "x"; then
   4         eventsdir=""
   5         eventspaths="$srcdir $srcdir/../samba4/source/lib/events $srcdir/lib/events $srcdir/events $srcdir/../events"
   6         for d in $eventspaths; do
   7                 if test -f "$d/events.c"; then
   8                         eventsdir="$d"
   9                         AC_SUBST(eventsdir)
  10                         break;
  11                 fi
  12         done
  13         if test x"$eventsdir" = "x"; then
  14            AC_MSG_ERROR([cannot find libevents source in $eventspaths])
  15         fi
  16 fi
  17
  18 EVENTS_OBJ="events.o events_select.o events_signal.o events_timed.o events_standard.o events_debug.o events_util.o"
  19 AC_LIBREPLACE_NETWORK_CHECKS
  20
  21 SMB_ENABLE(EVENTS_EPOLL, NO)
  22 SMB_ENABLE(EVENTS_AIO, NO)
  23 AC_CHECK_HEADERS(sys/epoll.h)
  24 AC_CHECK_FUNCS(epoll_create)
  25 if test x"$ac_cv_header_sys_epoll_h" = x"yes" -a x"$ac_cv_func_epoll_create" = x"yes"; then
  26    EVENTS_OBJ="$EVENTS_OBJ events_epoll.o"
  27    SMB_ENABLE(EVENTS_EPOLL,YES)
  28    AC_DEFINE(HAVE_EVENTS_EPOLL, 1, [Whether epoll available])
  29
  30    # check for native Linux AIO interface
  31    AC_CHECK_HEADERS(libaio.h)
  32    AC_CHECK_LIB_EXT(aio, AIO_LIBS, io_getevents)
  33    if test x"$ac_cv_header_libaio_h" = x"yes" -a x"$ac_cv_lib_ext_aio_io_getevents" = x"yes";then
  34       EVENTS_OBJ="$EVENTS_OBJ events_aio.o"
  35       SMB_ENABLE(EVENTS_AIO,YES)
  36       AC_DEFINE(HAVE_LINUX_AIO, 1, [Whether Linux AIO is available])
  37    fi
  38 fi
  39
  40 AC_SUBST(EVENTS_OBJ)
  41 SMB_EXT_LIB(LIBAIO_LINUX, $AIO_LIBS)
  42
  43 EVENTS_CFLAGS="-I$eventsdir"
  44 AC_SUBST(EVENTS_CFLAGS)
  45
  46 EVENTS_LIBS="$AIO_LIBS"
  47 AC_SUBST(EVENTS_LIBS)
  48
  49