sysdeps/unix/sysv/linux/mips/vfork.S

   1 /* Copyright (C) 2005-2014 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3
   4    The GNU C Library is free software; you can redistribute it and/or
   5    modify it under the terms of the GNU Lesser General Public
   6    License as published by the Free Software Foundation; either
   7    version 2.1 of the License, or (at your option) any later version.
   8
   9    The GNU C Library is distributed in the hope that it will be useful,
  10    but WITHOUT ANY WARRANTY; without even the implied warranty of
  11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12    Lesser General Public License for more details.
  13
  14    You should have received a copy of the GNU Lesser General Public
  15    License along with the GNU C Library.  If not, see
  16    <http://www.gnu.org/licenses/>.  */
  17
  18 /* vfork() is just a special case of clone().  */
  19
  20 #include <sys/asm.h>
  21 #include <sysdep.h>
  22 #include <asm/unistd.h>
  23 #include <sgidefs.h>
  24
  25 #ifndef SAVE_PID
  26 #define SAVE_PID
  27 #endif
  28
  29 #ifndef RESTORE_PID
  30 #define RESTORE_PID
  31 #endif
  32
  33
  34 /* int vfork() */
  35
  36         .text
  37         .set            nomips16
  38 LOCALSZ= 1
  39 FRAMESZ= (((NARGSAVE+LOCALSZ)*SZREG)+ALSZ)&ALMASK
  40 GPOFF= FRAMESZ-(1*SZREG)
  41 NESTED(__vfork,FRAMESZ,sp)
  42 #ifdef __PIC__
  43         SETUP_GP
  44 #endif
  45         PTR_SUBU sp, FRAMESZ
  46         cfi_adjust_cfa_offset (FRAMESZ)
  47         SETUP_GP64_REG (a5, __vfork)
  48 #ifdef __PIC__
  49         SAVE_GP (GPOFF)
  50 #endif
  51 #ifdef PROF
  52 # if (_MIPS_SIM != _ABIO32)
  53         PTR_S           a5, GPOFF(sp)
  54 # endif
  55         .set            noat
  56         move            $1, ra
  57 # if (_MIPS_SIM == _ABIO32)
  58         subu            sp,sp,8
  59 # endif
  60         jal             _mcount
  61         .set            at
  62 # if (_MIPS_SIM != _ABIO32)
  63         PTR_L           a5, GPOFF(sp)
  64 # endif
  65 #endif
  66
  67         PTR_ADDU        sp, FRAMESZ
  68         cfi_adjust_cfa_offset (-FRAMESZ)
  69
  70         SAVE_PID
  71
  72         li              a0, 0x4112      /* CLONE_VM | CLONE_VFORK | SIGCHLD */
  73         move            a1, sp
  74
  75         /* Do the system call */
  76         li              v0,__NR_clone
  77         syscall
  78
  79         RESTORE_PID
  80
  81         cfi_remember_state
  82         bnez            a3,L(error)
  83
  84         /* Successful return from the parent or child.  */
  85         RESTORE_GP64_REG
  86         ret
  87
  88         /* Something bad happened -- no child created.  */
  89 L(error):
  90         cfi_restore_state
  91 #ifdef __PIC__
  92         PTR_LA          t9, __syscall_error
  93         RESTORE_GP64_REG
  94         jr              t9
  95 #else
  96         RESTORE_GP64_REG
  97         j               __syscall_error
  98 #endif
  99         END(__vfork)
 100
 101 libc_hidden_def(__vfork)
 102 weak_alias (__vfork, vfork)