source4/scripting/python/config.m4

   1 m4_include(scripting/python/ac_pkg_swig.m4)
   2
   3 AC_ARG_VAR([PYTHON_VERSION],[The installed Python
   4         version to use, for example '2.3'. This string
   5         will be appended to the Python interpreter
   6         canonical name.])
   7
   8 AC_PROG_SWIG(1.3.31)
   9
  10 AC_PATH_PROG([PYTHON],[python[$PYTHON_VERSION]])
  11 if test -z "$PYTHON"; then
  12         working_python=no
  13         AC_MSG_WARN([No python found])
  14 fi
  15
  16 AC_DEFUN([TRY_LINK_PYTHON],
  17 [
  18         if test $working_python = no; then
  19                 ac_save_LIBS="$LIBS"
  20                 ac_save_CFLAGS="$CFLAGS"
  21                 LIBS="$LIBS $1"
  22                 CFLAGS="$CFLAGS $2"
  23
  24                 AC_TRY_LINK([
  25                                 /* we have our own configure tests */
  26                                 #define Py_PYCONFIG_H 1
  27                                 #include <Python.h>
  28                                 #include <stdlib.h>
  29                         ],[
  30                                 Py_InitModule(NULL, NULL);
  31                         ],[
  32                                 PYTHON_LDFLAGS="$1"
  33                                 PYTHON_CFLAGS="$2"
  34                                 working_python=yes
  35                         ])
  36                 LIBS="$ac_save_LIBS"
  37                 CFLAGS="$ac_save_CFLAGS"
  38         fi
  39 ])
  40
  41 dnl assume no working python
  42 working_python=no
  43
  44 if test -z "$PYTHON_VERSION"; then
  45         AC_PATH_PROGS([PYTHON_CONFIG], [python2.6-config python2.5-config python2.4-config python-config])
  46 else
  47         AC_PATH_PROG([PYTHON_CONFIG], [python[$PYTHON_VERSION]-config])
  48 fi
  49
  50 if test -z "$PYTHON_CONFIG"; then
  51         AC_MSG_WARN([No python-config found])
  52 else
  53         TRY_LINK_PYTHON([`$PYTHON_CONFIG --ldflags`], [`$PYTHON_CONFIG --includes`])
  54         TRY_LINK_PYTHON([`$PYTHON_CONFIG --ldflags`], [`$PYTHON_CONFIG --cflags`])
  55 fi
  56
  57 if test x$PYTHON != x
  58 then
  59         DISTUTILS_CFLAGS=`$PYTHON -c "from distutils import sysconfig; print '-I%s -I%s %s' % (sysconfig.get_python_inc(), sysconfig.get_python_inc(plat_specific=1), sysconfig.get_config_var('CFLAGS'))"`
  60         DISTUTILS_LDFLAGS=`$PYTHON -c "from distutils import sysconfig; print '%s %s -lpython%s -L%s' % (sysconfig.get_config_var('LIBS'), sysconfig.get_config_var('SYSLIBS'), sysconfig.get_config_var('VERSION'), sysconfig.get_config_var('LIBPL'))"`
  61         TRY_LINK_PYTHON($DISTUTILS_LDFLAGS, $DISTUTILS_CFLAGS)
  62 fi
  63
  64 SMB_EXT_LIB(EXT_LIB_PYTHON, [$PYTHON_LDFLAGS], [$PYTHON_CFLAGS])
  65
  66 AC_MSG_CHECKING(working python module support)
  67 if test $working_python = yes; then
  68         SMB_ENABLE(EXT_LIB_PYTHON,YES)
  69         SMB_ENABLE(smbpython,YES)
  70         SMB_ENABLE(LIBPYTHON,YES)
  71         AC_MSG_RESULT([yes])
  72 else
  73         AC_MSG_ERROR([Python not found. Please install Python 2.x and its development headers/libraries.])
  74 fi
  75