source4/lib/replace/libreplace_cc.m4

   1
   2 AC_DEFUN_ONCE(AC__LIBREPLACE_ONLY_CC_CHECKS_START,
   3 [
   4 echo "LIBREPLACE_CC_CHECKS: START"
   5 ])
   6
   7 AC_DEFUN_ONCE(AC__LIBREPLACE_ONLY_CC_CHECKS_END,
   8 [
   9 echo "LIBREPLACE_CC_CHECKS: END"
  10 ])
  11
  12 dnl
  13 dnl
  14 dnl AC_LIBREPLACE_CC_CHECKS
  15 dnl
  16 dnl Note: we need to use m4_define instead of AC_DEFUN because
  17 dnl       of the ordering of tests
  18 dnl
  19 dnl
  20 m4_define(AC_LIBREPLACE_CC_CHECKS,
  21 [
  22 AC__LIBREPLACE_ONLY_CC_CHECKS_START
  23
  24 dnl stop the C89 attempt by autoconf - if autoconf detects -Ae it will enable it
  25 dnl which conflicts with C99 on HPUX
  26 ac_cv_prog_cc_Ae=no
  27
  28 savedCFLAGS=$CFLAGS
  29 AC_PROG_CC
  30 CFLAGS=$savedCFLAGS
  31
  32 dnl don't try for C99 if we are using gcc, as otherwise we
  33 dnl lose immediate structure constants
  34 if test x"$GCC" != x"yes" ; then
  35 AC_PROG_CC_C99
  36 fi
  37
  38 if test x"$GCC" = x"yes" ; then
  39         AC_MSG_CHECKING([for version of gcc])
  40         GCC_VERSION=`$CC -dumpversion`
  41         AC_MSG_RESULT(${GCC_VERSION})
  42 fi
  43 AC_USE_SYSTEM_EXTENSIONS
  44 AC_C_BIGENDIAN
  45 AC_C_INLINE
  46 LIBREPLACE_C99_STRUCT_INIT([],[AC_MSG_WARN([c99 structure initializer are not supported])])
  47
  48 AC_PROG_INSTALL
  49
  50 AC_ISC_POSIX
  51 AC_N_DEFINE(_XOPEN_SOURCE_EXTENDED)
  52
  53 AC_SYS_LARGEFILE
  54
  55 dnl Add #include for broken IRIX header files
  56 case "$host_os" in
  57         *irix6*) AC_ADD_INCLUDE(<standards.h>)
  58                 ;;
  59         *hpux*)
  60                 # mmap on HPUX is completely broken...
  61                 AC_DEFINE(MMAP_BLACKLIST, 1, [Whether MMAP is broken])
  62                 if test "`uname -r`" = "B.11.00" -o "`uname -r`" = "B.11.11"; then
  63                         AC_MSG_WARN([Enabling HPUX 11.00/11.11 header bug workaround])
  64                         CFLAGS="$CFLAGS -Dpread=pread64 -Dpwrite=pwrite64"
  65                 fi
  66                 if test "`uname -r`" = "B.11.23"; then
  67                         AC_MSG_WARN([Enabling HPUX 11.23 machine/sys/getppdp.h bug workaround])
  68                         CFLAGS="$CFLAGS -D_MACHINE_SYS_GETPPDP_INCLUDED"
  69                 fi
  70                 ;;
  71         *aix*)
  72                 AC_DEFINE(BROKEN_STRNDUP, 1, [Whether strndup is broken])
  73                 AC_DEFINE(BROKEN_STRNLEN, 1, [Whether strnlen is broken])
  74                 if test "${GCC}" != "yes"; then
  75                         ## for funky AIX compiler using strncpy()
  76                         CFLAGS="$CFLAGS -D_LINUX_SOURCE_COMPAT -qmaxmem=32000"
  77                 fi
  78                 ;;
  79         *osf*)
  80                 # this brings in socklen_t
  81                 AC_N_DEFINE(_XOPEN_SOURCE,600)
  82                 AC_N_DEFINE(_OSF_SOURCE)
  83                 ;;
  84         #
  85         # VOS may need to have POSIX support and System V compatibility enabled.
  86         #
  87         *vos*)
  88                 case "$CFLAGS" in
  89                         *-D_POSIX_C_SOURCE*);;
  90                         *)
  91                                 CFLAGS="$CFLAGS -D_POSIX_C_SOURCE=200112L"
  92                                 AC_DEFINE(_POSIX_C_SOURCE, 200112L, [Whether to enable POSIX support])
  93                                 ;;
  94                 esac
  95                 case "$CFLAGS" in
  96                         *-D_SYSV*|*-D_SVID_SOURCE*);;
  97                         *)
  98                                 CFLAGS="$CFLAGS -D_SYSV"
  99                                 AC_DEFINE(_SYSV, 1, [Whether to enable System V compatibility])
 100                                 ;;
 101                 esac
 102                 ;;
 103 esac
 104
 105
 106
 107 AC_CHECK_HEADERS([standards.h])
 108
 109 # Solaris needs HAVE_LONG_LONG defined
 110 AC_CHECK_TYPES(long long)
 111
 112 AC_CHECK_TYPE(uint_t, unsigned int)
 113 AC_CHECK_TYPE(int8_t, char)
 114 AC_CHECK_TYPE(uint8_t, unsigned char)
 115 AC_CHECK_TYPE(int16_t, short)
 116 AC_CHECK_TYPE(uint16_t, unsigned short)
 117 AC_CHECK_TYPE(int32_t, long)
 118 AC_CHECK_TYPE(uint32_t, unsigned long)
 119 AC_CHECK_TYPE(int64_t, long long)
 120 AC_CHECK_TYPE(uint64_t, unsigned long long)
 121
 122 AC_CHECK_TYPE(size_t, unsigned int)
 123 AC_CHECK_TYPE(ssize_t, int)
 124
 125 AC_CHECK_SIZEOF(int)
 126 AC_CHECK_SIZEOF(char)
 127 AC_CHECK_SIZEOF(short)
 128 AC_CHECK_SIZEOF(long)
 129 AC_CHECK_SIZEOF(long long)
 130
 131 AC_CHECK_SIZEOF(off_t)
 132 AC_CHECK_SIZEOF(size_t)
 133 AC_CHECK_SIZEOF(ssize_t)
 134
 135 AC_CHECK_TYPE(intptr_t, long long)
 136 AC_CHECK_TYPE(uintptr_t, unsigned long long)
 137 AC_CHECK_TYPE(ptrdiff_t, unsigned long long)
 138
 139 if test x"$ac_cv_type_long_long" != x"yes";then
 140         AC_MSG_ERROR([LIBREPLACE needs type 'long long'])
 141 fi
 142 if test $ac_cv_sizeof_long_long -lt 8;then
 143         AC_MSG_ERROR([LIBREPLACE needs sizeof(long long) >= 8])
 144 fi
 145
 146 ############################################
 147 # check if the compiler can do immediate structures
 148 AC_SUBST(libreplace_cv_immediate_structures)
 149 AC_CACHE_CHECK([for immediate structures],libreplace_cv_immediate_structures,[
 150         AC_TRY_COMPILE([
 151                 #include <stdio.h>
 152         ],[
 153                 typedef struct {unsigned x;} FOOBAR;
 154                 #define X_FOOBAR(x) ((FOOBAR) { x })
 155                 #define FOO_ONE X_FOOBAR(1)
 156                 FOOBAR f = FOO_ONE;
 157                 static const struct {
 158                         FOOBAR y;
 159                 } f2[] = {
 160                         {FOO_ONE}
 161                 };
 162         ],
 163         libreplace_cv_immediate_structures=yes,
 164         libreplace_cv_immediate_structures=no,
 165         libreplace_cv_immediate_structures=cross)
 166 ])
 167 if test x"$libreplace_cv_immediate_structures" = x"yes"; then
 168         AC_DEFINE(HAVE_IMMEDIATE_STRUCTURES,1,[Whether the compiler supports immediate structures])
 169 fi
 170
 171 AC__LIBREPLACE_ONLY_CC_CHECKS_END
 172 ]) dnl end AC_LIBREPLACE_CC_CHECKS