arch/x86_64/ia32/ia32entry.S

   1 /*
   2  * Compatibility mode system call entry point for x86-64.
   3  *
   4  * Copyright 2000-2002 Andi Kleen, SuSE Labs.
   5  */
   6
   7 #include <asm/dwarf2.h>
   8 #include <asm/calling.h>
   9 #include <asm/asm-offsets.h>
  10 #include <asm/current.h>
  11 #include <asm/errno.h>
  12 #include <asm/ia32_unistd.h>
  13 #include <asm/thread_info.h>
  14 #include <asm/segment.h>
  15 #include <asm/vsyscall32.h>
  16 #include <asm/irqflags.h>
  17 #include <linux/linkage.h>
  18
  19 #define IA32_NR_syscalls ((ia32_syscall_end - ia32_sys_call_table)/8)
  20
  21         .macro IA32_ARG_FIXUP noebp=0
  22         movl    %edi,%r8d
  23         .if \noebp
  24         .else
  25         movl    %ebp,%r9d
  26         .endif
  27         xchg    %ecx,%esi
  28         movl    %ebx,%edi
  29         movl    %edx,%edx       /* zero extension */
  30         .endm
  31
  32         /* clobbers %eax */
  33         .macro  CLEAR_RREGS
  34         xorl    %eax,%eax
  35         movq    %rax,R11(%rsp)
  36         movq    %rax,R10(%rsp)
  37         movq    %rax,R9(%rsp)
  38         movq    %rax,R8(%rsp)
  39         .endm
  40
  41         .macro CFI_STARTPROC32 simple
  42         CFI_STARTPROC   \simple
  43         CFI_UNDEFINED   r8
  44         CFI_UNDEFINED   r9
  45         CFI_UNDEFINED   r10
  46         CFI_UNDEFINED   r11
  47         CFI_UNDEFINED   r12
  48         CFI_UNDEFINED   r13
  49         CFI_UNDEFINED   r14
  50         CFI_UNDEFINED   r15
  51         .endm
  52
  53 /*
  54  * 32bit SYSENTER instruction entry.
  55  *
  56  * Arguments:
  57  * %eax System call number.
  58  * %ebx Arg1
  59  * %ecx Arg2
  60  * %edx Arg3
  61  * %esi Arg4
  62  * %edi Arg5
  63  * %ebp user stack
  64  * 0(%ebp) Arg6
  65  *
  66  * Interrupts off.
  67  *
  68  * This is purely a fast path. For anything complicated we use the int 0x80
  69  * path below.  Set up a complete hardware stack frame to share code
  70  * with the int 0x80 path.
  71  */
  72 ENTRY(ia32_sysenter_target)
  73         CFI_STARTPROC32 simple
  74         CFI_SIGNAL_FRAME
  75         CFI_DEF_CFA     rsp,0
  76         CFI_REGISTER    rsp,rbp
  77         swapgs
  78         movq    %gs:pda_kernelstack, %rsp
  79         addq    $(PDA_STACKOFFSET),%rsp
  80         /*
  81          * No need to follow this irqs on/off section: the syscall
  82          * disabled irqs, here we enable it straight after entry:
  83          */
  84         sti
  85         movl    %ebp,%ebp               /* zero extension */
  86         pushq   $__USER32_DS
  87         CFI_ADJUST_CFA_OFFSET 8
  88         /*CFI_REL_OFFSET ss,0*/
  89         pushq   %rbp
  90         CFI_ADJUST_CFA_OFFSET 8
  91         CFI_REL_OFFSET rsp,0
  92         pushfq
  93         CFI_ADJUST_CFA_OFFSET 8
  94         /*CFI_REL_OFFSET rflags,0*/
  95         movl    $VSYSCALL32_SYSEXIT, %r10d
  96         CFI_REGISTER rip,r10
  97         pushq   $__USER32_CS
  98         CFI_ADJUST_CFA_OFFSET 8
  99         /*CFI_REL_OFFSET cs,0*/
 100         movl    %eax, %eax
 101         pushq   %r10
 102         CFI_ADJUST_CFA_OFFSET 8
 103         CFI_REL_OFFSET rip,0
 104         pushq   %rax
 105         CFI_ADJUST_CFA_OFFSET 8
 106         cld
 107         SAVE_ARGS 0,0,1
 108         /* no need to do an access_ok check here because rbp has been
 109            32bit zero extended */
 110 1:      movl    (%rbp),%r9d
 111         .section __ex_table,"a"
 112         .quad 1b,ia32_badarg
 113         .previous
 114         GET_THREAD_INFO(%r10)
 115         orl    $TS_COMPAT,threadinfo_status(%r10)
 116         testl  $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SECCOMP),threadinfo_flags(%r10)
 117         CFI_REMEMBER_STATE
 118         jnz  sysenter_tracesys
 119 sysenter_do_call:
 120         cmpl    $(IA32_NR_syscalls-1),%eax
 121         ja      ia32_badsys
 122         IA32_ARG_FIXUP 1
 123         call    *ia32_sys_call_table(,%rax,8)
 124         movq    %rax,RAX-ARGOFFSET(%rsp)
 125         GET_THREAD_INFO(%r10)
 126         cli
 127         TRACE_IRQS_OFF
 128         testl   $_TIF_ALLWORK_MASK,threadinfo_flags(%r10)
 129         jnz     int_ret_from_sys_call
 130         andl    $~TS_COMPAT,threadinfo_status(%r10)
 131         /* clear IF, that popfq doesn't enable interrupts early */
 132         andl  $~0x200,EFLAGS-R11(%rsp)
 133         RESTORE_ARGS 1,24,1,1,1,1
 134         popfq
 135         CFI_ADJUST_CFA_OFFSET -8
 136         /*CFI_RESTORE rflags*/
 137         popq    %rcx                            /* User %esp */
 138         CFI_ADJUST_CFA_OFFSET -8
 139         CFI_REGISTER rsp,rcx
 140         movl    $VSYSCALL32_SYSEXIT,%edx        /* User %eip */
 141         CFI_REGISTER rip,rdx
 142         TRACE_IRQS_ON
 143         swapgs
 144         sti             /* sti only takes effect after the next instruction */
 145         /* sysexit */
 146         .byte   0xf, 0x35
 147
 148 sysenter_tracesys:
 149         CFI_RESTORE_STATE
 150         SAVE_REST
 151         CLEAR_RREGS
 152         movq    $-ENOSYS,RAX(%rsp)      /* really needed? */
 153         movq    %rsp,%rdi        /* &pt_regs -> arg1 */
 154         call    syscall_trace_enter
 155         LOAD_ARGS ARGOFFSET  /* reload args from stack in case ptrace changed it */
 156         RESTORE_REST
 157         movl    %ebp, %ebp
 158         /* no need to do an access_ok check here because rbp has been
 159            32bit zero extended */
 160 1:      movl    (%rbp),%r9d
 161         .section __ex_table,"a"
 162         .quad 1b,ia32_badarg
 163         .previous
 164         jmp     sysenter_do_call
 165         CFI_ENDPROC
 166 ENDPROC(ia32_sysenter_target)
 167
 168 /*
 169  * 32bit SYSCALL instruction entry.
 170  *
 171  * Arguments:
 172  * %eax System call number.
 173  * %ebx Arg1
 174  * %ecx return EIP
 175  * %edx Arg3
 176  * %esi Arg4
 177  * %edi Arg5
 178  * %ebp Arg2    [note: not saved in the stack frame, should not be touched]
 179  * %esp user stack
 180  * 0(%esp) Arg6
 181  *
 182  * Interrupts off.
 183  *
 184  * This is purely a fast path. For anything complicated we use the int 0x80
 185  * path below.  Set up a complete hardware stack frame to share code
 186  * with the int 0x80 path.
 187  */
 188 ENTRY(ia32_cstar_target)
 189         CFI_STARTPROC32 simple
 190         CFI_SIGNAL_FRAME
 191         CFI_DEF_CFA     rsp,PDA_STACKOFFSET
 192         CFI_REGISTER    rip,rcx
 193         /*CFI_REGISTER  rflags,r11*/
 194         swapgs
 195         movl    %esp,%r8d
 196         CFI_REGISTER    rsp,r8
 197         movq    %gs:pda_kernelstack,%rsp
 198         /*
 199          * No need to follow this irqs on/off section: the syscall
 200          * disabled irqs and here we enable it straight after entry:
 201          */
 202         sti
 203         SAVE_ARGS 8,1,1
 204         movl    %eax,%eax       /* zero extension */
 205         movq    %rax,ORIG_RAX-ARGOFFSET(%rsp)
 206         movq    %rcx,RIP-ARGOFFSET(%rsp)
 207         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 208         movq    %rbp,RCX-ARGOFFSET(%rsp) /* this lies slightly to ptrace */
 209         movl    %ebp,%ecx
 210         movq    $__USER32_CS,CS-ARGOFFSET(%rsp)
 211         movq    $__USER32_DS,SS-ARGOFFSET(%rsp)
 212         movq    %r11,EFLAGS-ARGOFFSET(%rsp)
 213         /*CFI_REL_OFFSET rflags,EFLAGS-ARGOFFSET*/
 214         movq    %r8,RSP-ARGOFFSET(%rsp)
 215         CFI_REL_OFFSET rsp,RSP-ARGOFFSET
 216         /* no need to do an access_ok check here because r8 has been
 217            32bit zero extended */
 218         /* hardware stack frame is complete now */
 219 1:      movl    (%r8),%r9d
 220         .section __ex_table,"a"
 221         .quad 1b,ia32_badarg
 222         .previous
 223         GET_THREAD_INFO(%r10)
 224         orl   $TS_COMPAT,threadinfo_status(%r10)
 225         testl $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SECCOMP),threadinfo_flags(%r10)
 226         CFI_REMEMBER_STATE
 227         jnz   cstar_tracesys
 228 cstar_do_call:
 229         cmpl $IA32_NR_syscalls-1,%eax
 230         ja  ia32_badsys
 231         IA32_ARG_FIXUP 1
 232         call *ia32_sys_call_table(,%rax,8)
 233         movq %rax,RAX-ARGOFFSET(%rsp)
 234         GET_THREAD_INFO(%r10)
 235         cli
 236         TRACE_IRQS_OFF
 237         testl $_TIF_ALLWORK_MASK,threadinfo_flags(%r10)
 238         jnz  int_ret_from_sys_call
 239         andl $~TS_COMPAT,threadinfo_status(%r10)
 240         RESTORE_ARGS 1,-ARG_SKIP,1,1,1
 241         movl RIP-ARGOFFSET(%rsp),%ecx
 242         CFI_REGISTER rip,rcx
 243         movl EFLAGS-ARGOFFSET(%rsp),%r11d
 244         /*CFI_REGISTER rflags,r11*/
 245         TRACE_IRQS_ON
 246         movl RSP-ARGOFFSET(%rsp),%esp
 247         CFI_RESTORE rsp
 248         swapgs
 249         sysretl
 250
 251 cstar_tracesys:
 252         CFI_RESTORE_STATE
 253         SAVE_REST
 254         CLEAR_RREGS
 255         movq $-ENOSYS,RAX(%rsp) /* really needed? */
 256         movq %rsp,%rdi        /* &pt_regs -> arg1 */
 257         call syscall_trace_enter
 258         LOAD_ARGS ARGOFFSET  /* reload args from stack in case ptrace changed it */
 259         RESTORE_REST
 260         movl RSP-ARGOFFSET(%rsp), %r8d
 261         /* no need to do an access_ok check here because r8 has been
 262            32bit zero extended */
 263 1:      movl    (%r8),%r9d
 264         .section __ex_table,"a"
 265         .quad 1b,ia32_badarg
 266         .previous
 267         jmp cstar_do_call
 268 END(ia32_cstar_target)
 269
 270 ia32_badarg:
 271         movq $-EFAULT,%rax
 272         jmp ia32_sysret
 273         CFI_ENDPROC
 274
 275 /*
 276  * Emulated IA32 system calls via int 0x80.
 277  *
 278  * Arguments:
 279  * %eax System call number.
 280  * %ebx Arg1
 281  * %ecx Arg2
 282  * %edx Arg3
 283  * %esi Arg4
 284  * %edi Arg5
 285  * %ebp Arg6    [note: not saved in the stack frame, should not be touched]
 286  *
 287  * Notes:
 288  * Uses the same stack frame as the x86-64 version.
 289  * All registers except %eax must be saved (but ptrace may violate that)
 290  * Arguments are zero extended. For system calls that want sign extension and
 291  * take long arguments a wrapper is needed. Most calls can just be called
 292  * directly.
 293  * Assumes it is only called from user space and entered with interrupts off.
 294  */
 295
 296 ENTRY(ia32_syscall)
 297         CFI_STARTPROC32 simple
 298         CFI_SIGNAL_FRAME
 299         CFI_DEF_CFA     rsp,SS+8-RIP
 300         /*CFI_REL_OFFSET        ss,SS-RIP*/
 301         CFI_REL_OFFSET  rsp,RSP-RIP
 302         /*CFI_REL_OFFSET        rflags,EFLAGS-RIP*/
 303         /*CFI_REL_OFFSET        cs,CS-RIP*/
 304         CFI_REL_OFFSET  rip,RIP-RIP
 305         swapgs
 306         /*
 307          * No need to follow this irqs on/off section: the syscall
 308          * disabled irqs and here we enable it straight after entry:
 309          */
 310         sti
 311         movl %eax,%eax
 312         pushq %rax
 313         CFI_ADJUST_CFA_OFFSET 8
 314         cld
 315         /* note the registers are not zero extended to the sf.
 316            this could be a problem. */
 317         SAVE_ARGS 0,0,1
 318         GET_THREAD_INFO(%r10)
 319         orl   $TS_COMPAT,threadinfo_status(%r10)
 320         testl $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SECCOMP),threadinfo_flags(%r10)
 321         jnz ia32_tracesys
 322 ia32_do_syscall:
 323         cmpl $(IA32_NR_syscalls-1),%eax
 324         ja  ia32_badsys
 325         IA32_ARG_FIXUP
 326         call *ia32_sys_call_table(,%rax,8) # xxx: rip relative
 327 ia32_sysret:
 328         movq %rax,RAX-ARGOFFSET(%rsp)
 329         jmp int_ret_from_sys_call
 330
 331 ia32_tracesys:
 332         SAVE_REST
 333         CLEAR_RREGS
 334         movq $-ENOSYS,RAX(%rsp) /* really needed? */
 335         movq %rsp,%rdi        /* &pt_regs -> arg1 */
 336         call syscall_trace_enter
 337         LOAD_ARGS ARGOFFSET  /* reload args from stack in case ptrace changed it */
 338         RESTORE_REST
 339         jmp ia32_do_syscall
 340 END(ia32_syscall)
 341
 342 ia32_badsys:
 343         movq $0,ORIG_RAX-ARGOFFSET(%rsp)
 344         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 345         jmp int_ret_from_sys_call
 346
 347 quiet_ni_syscall:
 348         movq $-ENOSYS,%rax
 349         ret
 350         CFI_ENDPROC
 351
 352         .macro PTREGSCALL label, func, arg
 353         .globl \label
 354 \label:
 355         leaq \func(%rip),%rax
 356         leaq -ARGOFFSET+8(%rsp),\arg    /* 8 for return address */
 357         jmp  ia32_ptregs_common
 358         .endm
 359
 360         CFI_STARTPROC32
 361
 362         PTREGSCALL stub32_rt_sigreturn, sys32_rt_sigreturn, %rdi
 363         PTREGSCALL stub32_sigreturn, sys32_sigreturn, %rdi
 364         PTREGSCALL stub32_sigaltstack, sys32_sigaltstack, %rdx
 365         PTREGSCALL stub32_sigsuspend, sys32_sigsuspend, %rcx
 366         PTREGSCALL stub32_execve, sys32_execve, %rcx
 367         PTREGSCALL stub32_fork, sys_fork, %rdi
 368         PTREGSCALL stub32_clone, sys32_clone, %rdx
 369         PTREGSCALL stub32_vfork, sys_vfork, %rdi
 370         PTREGSCALL stub32_iopl, sys_iopl, %rsi
 371         PTREGSCALL stub32_rt_sigsuspend, sys_rt_sigsuspend, %rdx
 372
 373 ENTRY(ia32_ptregs_common)
 374         popq %r11
 375         CFI_ENDPROC
 376         CFI_STARTPROC32 simple
 377         CFI_SIGNAL_FRAME
 378         CFI_DEF_CFA     rsp,SS+8-ARGOFFSET
 379         CFI_REL_OFFSET  rax,RAX-ARGOFFSET
 380         CFI_REL_OFFSET  rcx,RCX-ARGOFFSET
 381         CFI_REL_OFFSET  rdx,RDX-ARGOFFSET
 382         CFI_REL_OFFSET  rsi,RSI-ARGOFFSET
 383         CFI_REL_OFFSET  rdi,RDI-ARGOFFSET
 384         CFI_REL_OFFSET  rip,RIP-ARGOFFSET
 385 /*      CFI_REL_OFFSET  cs,CS-ARGOFFSET*/
 386 /*      CFI_REL_OFFSET  rflags,EFLAGS-ARGOFFSET*/
 387         CFI_REL_OFFSET  rsp,RSP-ARGOFFSET
 388 /*      CFI_REL_OFFSET  ss,SS-ARGOFFSET*/
 389         SAVE_REST
 390         call *%rax
 391         RESTORE_REST
 392         jmp  ia32_sysret        /* misbalances the return cache */
 393         CFI_ENDPROC
 394 END(ia32_ptregs_common)
 395
 396         .section .rodata,"a"
 397         .align 8
 398 ia32_sys_call_table:
 399         .quad sys_restart_syscall
 400         .quad sys_exit
 401         .quad stub32_fork
 402         .quad sys_read
 403         .quad sys_write
 404         .quad compat_sys_open           /* 5 */
 405         .quad sys_close
 406         .quad sys32_waitpid
 407         .quad sys_creat
 408         .quad sys_link
 409         .quad sys_unlink                /* 10 */
 410         .quad stub32_execve
 411         .quad sys_chdir
 412         .quad compat_sys_time
 413         .quad sys_mknod
 414         .quad sys_chmod         /* 15 */
 415         .quad sys_lchown16
 416         .quad quiet_ni_syscall                  /* old break syscall holder */
 417         .quad sys_stat
 418         .quad sys32_lseek
 419         .quad sys_getpid                /* 20 */
 420         .quad compat_sys_mount  /* mount  */
 421         .quad sys_oldumount     /* old_umount  */
 422         .quad sys_setuid16
 423         .quad sys_getuid16
 424         .quad compat_sys_stime  /* stime */             /* 25 */
 425         .quad sys32_ptrace      /* ptrace */
 426         .quad sys_alarm
 427         .quad sys_fstat /* (old)fstat */
 428         .quad sys_pause
 429         .quad compat_sys_utime  /* 30 */
 430         .quad quiet_ni_syscall  /* old stty syscall holder */
 431         .quad quiet_ni_syscall  /* old gtty syscall holder */
 432         .quad sys_access
 433         .quad sys_nice
 434         .quad quiet_ni_syscall  /* 35 */        /* old ftime syscall holder */
 435         .quad sys_sync
 436         .quad sys32_kill
 437         .quad sys_rename
 438         .quad sys_mkdir
 439         .quad sys_rmdir         /* 40 */
 440         .quad sys_dup
 441         .quad sys32_pipe
 442         .quad compat_sys_times
 443         .quad quiet_ni_syscall                  /* old prof syscall holder */
 444         .quad sys_brk           /* 45 */
 445         .quad sys_setgid16
 446         .quad sys_getgid16
 447         .quad sys_signal
 448         .quad sys_geteuid16
 449         .quad sys_getegid16     /* 50 */
 450         .quad sys_acct
 451         .quad sys_umount                        /* new_umount */
 452         .quad quiet_ni_syscall                  /* old lock syscall holder */
 453         .quad compat_sys_ioctl
 454         .quad compat_sys_fcntl64                /* 55 */
 455         .quad quiet_ni_syscall                  /* old mpx syscall holder */
 456         .quad sys_setpgid
 457         .quad quiet_ni_syscall                  /* old ulimit syscall holder */
 458         .quad sys32_olduname
 459         .quad sys_umask         /* 60 */
 460         .quad sys_chroot
 461         .quad sys32_ustat
 462         .quad sys_dup2
 463         .quad sys_getppid
 464         .quad sys_getpgrp               /* 65 */
 465         .quad sys_setsid
 466         .quad sys32_sigaction
 467         .quad sys_sgetmask
 468         .quad sys_ssetmask
 469         .quad sys_setreuid16    /* 70 */
 470         .quad sys_setregid16
 471         .quad stub32_sigsuspend
 472         .quad compat_sys_sigpending
 473         .quad sys_sethostname
 474         .quad compat_sys_setrlimit      /* 75 */
 475         .quad compat_sys_old_getrlimit  /* old_getrlimit */
 476         .quad compat_sys_getrusage
 477         .quad sys32_gettimeofday
 478         .quad sys32_settimeofday
 479         .quad sys_getgroups16   /* 80 */
 480         .quad sys_setgroups16
 481         .quad sys32_old_select
 482         .quad sys_symlink
 483         .quad sys_lstat
 484         .quad sys_readlink              /* 85 */
 485         .quad sys_uselib
 486         .quad sys_swapon
 487         .quad sys_reboot
 488         .quad compat_sys_old_readdir
 489         .quad sys32_mmap                /* 90 */
 490         .quad sys_munmap
 491         .quad sys_truncate
 492         .quad sys_ftruncate
 493         .quad sys_fchmod
 494         .quad sys_fchown16              /* 95 */
 495         .quad sys_getpriority
 496         .quad sys_setpriority
 497         .quad quiet_ni_syscall                  /* old profil syscall holder */
 498         .quad compat_sys_statfs
 499         .quad compat_sys_fstatfs                /* 100 */
 500         .quad sys_ioperm
 501         .quad compat_sys_socketcall
 502         .quad sys_syslog
 503         .quad compat_sys_setitimer
 504         .quad compat_sys_getitimer      /* 105 */
 505         .quad compat_sys_newstat
 506         .quad compat_sys_newlstat
 507         .quad compat_sys_newfstat
 508         .quad sys32_uname
 509         .quad stub32_iopl               /* 110 */
 510         .quad sys_vhangup
 511         .quad quiet_ni_syscall  /* old "idle" system call */
 512         .quad sys32_vm86_warning        /* vm86old */
 513         .quad compat_sys_wait4
 514         .quad sys_swapoff               /* 115 */
 515         .quad compat_sys_sysinfo
 516         .quad sys32_ipc
 517         .quad sys_fsync
 518         .quad stub32_sigreturn
 519         .quad stub32_clone              /* 120 */
 520         .quad sys_setdomainname
 521         .quad sys_uname
 522         .quad sys_modify_ldt
 523         .quad compat_sys_adjtimex
 524         .quad sys32_mprotect            /* 125 */
 525         .quad compat_sys_sigprocmask
 526         .quad quiet_ni_syscall          /* create_module */
 527         .quad sys_init_module
 528         .quad sys_delete_module
 529         .quad quiet_ni_syscall          /* 130  get_kernel_syms */
 530         .quad sys32_quotactl
 531         .quad sys_getpgid
 532         .quad sys_fchdir
 533         .quad quiet_ni_syscall  /* bdflush */
 534         .quad sys_sysfs         /* 135 */
 535         .quad sys_personality
 536         .quad quiet_ni_syscall  /* for afs_syscall */
 537         .quad sys_setfsuid16
 538         .quad sys_setfsgid16
 539         .quad sys_llseek                /* 140 */
 540         .quad compat_sys_getdents
 541         .quad compat_sys_select
 542         .quad sys_flock
 543         .quad sys_msync
 544         .quad compat_sys_readv          /* 145 */
 545         .quad compat_sys_writev
 546         .quad sys_getsid
 547         .quad sys_fdatasync
 548         .quad sys32_sysctl      /* sysctl */
 549         .quad sys_mlock         /* 150 */
 550         .quad sys_munlock
 551         .quad sys_mlockall
 552         .quad sys_munlockall
 553         .quad sys_sched_setparam
 554         .quad sys_sched_getparam   /* 155 */
 555         .quad sys_sched_setscheduler
 556         .quad sys_sched_getscheduler
 557         .quad sys_sched_yield
 558         .quad sys_sched_get_priority_max
 559         .quad sys_sched_get_priority_min  /* 160 */
 560         .quad sys32_sched_rr_get_interval
 561         .quad compat_sys_nanosleep
 562         .quad sys_mremap
 563         .quad sys_setresuid16
 564         .quad sys_getresuid16   /* 165 */
 565         .quad sys32_vm86_warning        /* vm86 */
 566         .quad quiet_ni_syscall  /* query_module */
 567         .quad sys_poll
 568         .quad compat_sys_nfsservctl
 569         .quad sys_setresgid16   /* 170 */
 570         .quad sys_getresgid16
 571         .quad sys_prctl
 572         .quad stub32_rt_sigreturn
 573         .quad sys32_rt_sigaction
 574         .quad sys32_rt_sigprocmask      /* 175 */
 575         .quad sys32_rt_sigpending
 576         .quad compat_sys_rt_sigtimedwait
 577         .quad sys32_rt_sigqueueinfo
 578         .quad stub32_rt_sigsuspend
 579         .quad sys32_pread               /* 180 */
 580         .quad sys32_pwrite
 581         .quad sys_chown16
 582         .quad sys_getcwd
 583         .quad sys_capget
 584         .quad sys_capset
 585         .quad stub32_sigaltstack
 586         .quad sys32_sendfile
 587         .quad quiet_ni_syscall          /* streams1 */
 588         .quad quiet_ni_syscall          /* streams2 */
 589         .quad stub32_vfork            /* 190 */
 590         .quad compat_sys_getrlimit
 591         .quad sys32_mmap2
 592         .quad sys32_truncate64
 593         .quad sys32_ftruncate64
 594         .quad sys32_stat64              /* 195 */
 595         .quad sys32_lstat64
 596         .quad sys32_fstat64
 597         .quad sys_lchown
 598         .quad sys_getuid
 599         .quad sys_getgid                /* 200 */
 600         .quad sys_geteuid
 601         .quad sys_getegid
 602         .quad sys_setreuid
 603         .quad sys_setregid
 604         .quad sys_getgroups     /* 205 */
 605         .quad sys_setgroups
 606         .quad sys_fchown
 607         .quad sys_setresuid
 608         .quad sys_getresuid
 609         .quad sys_setresgid     /* 210 */
 610         .quad sys_getresgid
 611         .quad sys_chown
 612         .quad sys_setuid
 613         .quad sys_setgid
 614         .quad sys_setfsuid              /* 215 */
 615         .quad sys_setfsgid
 616         .quad sys_pivot_root
 617         .quad sys_mincore
 618         .quad sys_madvise
 619         .quad compat_sys_getdents64     /* 220 getdents64 */
 620         .quad compat_sys_fcntl64
 621         .quad quiet_ni_syscall          /* tux */
 622         .quad quiet_ni_syscall          /* security */
 623         .quad sys_gettid
 624         .quad sys32_readahead   /* 225 */
 625         .quad sys_setxattr
 626         .quad sys_lsetxattr
 627         .quad sys_fsetxattr
 628         .quad sys_getxattr
 629         .quad sys_lgetxattr     /* 230 */
 630         .quad sys_fgetxattr
 631         .quad sys_listxattr
 632         .quad sys_llistxattr
 633         .quad sys_flistxattr
 634         .quad sys_removexattr   /* 235 */
 635         .quad sys_lremovexattr
 636         .quad sys_fremovexattr
 637         .quad sys_tkill
 638         .quad sys_sendfile64
 639         .quad compat_sys_futex          /* 240 */
 640         .quad compat_sys_sched_setaffinity
 641         .quad compat_sys_sched_getaffinity
 642         .quad sys32_set_thread_area
 643         .quad sys32_get_thread_area
 644         .quad compat_sys_io_setup       /* 245 */
 645         .quad sys_io_destroy
 646         .quad compat_sys_io_getevents
 647         .quad compat_sys_io_submit
 648         .quad sys_io_cancel
 649         .quad sys32_fadvise64           /* 250 */
 650         .quad quiet_ni_syscall  /* free_huge_pages */
 651         .quad sys_exit_group
 652         .quad sys32_lookup_dcookie
 653         .quad sys_epoll_create
 654         .quad sys_epoll_ctl             /* 255 */
 655         .quad sys_epoll_wait
 656         .quad sys_remap_file_pages
 657         .quad sys_set_tid_address
 658         .quad compat_sys_timer_create
 659         .quad compat_sys_timer_settime  /* 260 */
 660         .quad compat_sys_timer_gettime
 661         .quad sys_timer_getoverrun
 662         .quad sys_timer_delete
 663         .quad compat_sys_clock_settime
 664         .quad compat_sys_clock_gettime  /* 265 */
 665         .quad compat_sys_clock_getres
 666         .quad compat_sys_clock_nanosleep
 667         .quad compat_sys_statfs64
 668         .quad compat_sys_fstatfs64
 669         .quad sys_tgkill                /* 270 */
 670         .quad compat_sys_utimes
 671         .quad sys32_fadvise64_64
 672         .quad quiet_ni_syscall  /* sys_vserver */
 673         .quad sys_mbind
 674         .quad compat_sys_get_mempolicy  /* 275 */
 675         .quad sys_set_mempolicy
 676         .quad compat_sys_mq_open
 677         .quad sys_mq_unlink
 678         .quad compat_sys_mq_timedsend
 679         .quad compat_sys_mq_timedreceive        /* 280 */
 680         .quad compat_sys_mq_notify
 681         .quad compat_sys_mq_getsetattr
 682         .quad compat_sys_kexec_load     /* reserved for kexec */
 683         .quad compat_sys_waitid
 684         .quad quiet_ni_syscall          /* 285: sys_altroot */
 685         .quad sys_add_key
 686         .quad sys_request_key
 687         .quad sys_keyctl
 688         .quad sys_ioprio_set
 689         .quad sys_ioprio_get            /* 290 */
 690         .quad sys_inotify_init
 691         .quad sys_inotify_add_watch
 692         .quad sys_inotify_rm_watch
 693         .quad sys_migrate_pages
 694         .quad compat_sys_openat         /* 295 */
 695         .quad sys_mkdirat
 696         .quad sys_mknodat
 697         .quad sys_fchownat
 698         .quad compat_sys_futimesat
 699         .quad sys32_fstatat             /* 300 */
 700         .quad sys_unlinkat
 701         .quad sys_renameat
 702         .quad sys_linkat
 703         .quad sys_symlinkat
 704         .quad sys_readlinkat            /* 305 */
 705         .quad sys_fchmodat
 706         .quad sys_faccessat
 707         .quad compat_sys_pselect6
 708         .quad compat_sys_ppoll
 709         .quad sys_unshare               /* 310 */
 710         .quad compat_sys_set_robust_list
 711         .quad compat_sys_get_robust_list
 712         .quad sys_splice
 713         .quad sys32_sync_file_range
 714         .quad sys_tee                   /* 315 */
 715         .quad compat_sys_vmsplice
 716         .quad compat_sys_move_pages
 717         .quad sys_getcpu
 718         .quad sys_epoll_pwait
 719         .quad compat_sys_utimensat      /* 320 */
 720         .quad compat_sys_signalfd
 721         .quad compat_sys_timerfd
 722         .quad sys_eventfd
 723         .quad sys32_fallocate
 724 ia32_syscall_end: