arch/x86/kernel/entry_64.S

   1 /*
   2  *  linux/arch/x86_64/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  *  Copyright (C) 2000, 2001, 2002  Andi Kleen SuSE Labs
   6  *  Copyright (C) 2000  Pavel Machek <pavel@suse.cz>
   7  */
   8
   9 /*
  10  * entry.S contains the system-call and fault low-level handling routines.
  11  *
  12  * Some of this is documented in Documentation/x86/entry_64.txt
  13  *
  14  * NOTE: This code handles signal-recognition, which happens every time
  15  * after an interrupt and after each system call.
  16  *
  17  * Normal syscalls and interrupts don't save a full stack frame, this is
  18  * only done for syscall tracing, signals or fork/exec et.al.
  19  *
  20  * A note on terminology:
  21  * - top of stack: Architecture defined interrupt frame from SS to RIP
  22  * at the top of the kernel process stack.
  23  * - partial stack frame: partially saved registers up to R11.
  24  * - full stack frame: Like partial stack frame, but all register saved.
  25  *
  26  * Some macro usage:
  27  * - CFI macros are used to generate dwarf2 unwind information for better
  28  * backtraces. They don't change any code.
  29  * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
  30  * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
  31  * There are unfortunately lots of special cases where some registers
  32  * not touched. The macro is a big mess that should be cleaned up.
  33  * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
  34  * Gives a full stack frame.
  35  * - ENTRY/END Define functions in the symbol table.
  36  * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
  37  * frame that is otherwise undefined after a SYSCALL
  38  * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
  39  * - idtentry - Define exception entry points.
  40  */
  41
  42 #include <linux/linkage.h>
  43 #include <asm/segment.h>
  44 #include <asm/cache.h>
  45 #include <asm/errno.h>
  46 #include <asm/dwarf2.h>
  47 #include <asm/calling.h>
  48 #include <asm/asm-offsets.h>
  49 #include <asm/msr.h>
  50 #include <asm/unistd.h>
  51 #include <asm/thread_info.h>
  52 #include <asm/hw_irq.h>
  53 #include <asm/page_types.h>
  54 #include <asm/irqflags.h>
  55 #include <asm/paravirt.h>
  56 #include <asm/percpu.h>
  57 #include <asm/asm.h>
  58 #include <asm/context_tracking.h>
  59 #include <asm/smap.h>
  60 #include <asm/pgtable_types.h>
  61 #include <linux/err.h>
  62
  63 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  64 #include <linux/elf-em.h>
  65 #define AUDIT_ARCH_X86_64       (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
  66 #define __AUDIT_ARCH_64BIT 0x80000000
  67 #define __AUDIT_ARCH_LE    0x40000000
  68
  69         .code64
  70         .section .entry.text, "ax"
  71
  72
  73 #ifndef CONFIG_PREEMPT
  74 #define retint_kernel retint_restore_args
  75 #endif
  76
  77 #ifdef CONFIG_PARAVIRT
  78 ENTRY(native_usergs_sysret64)
  79         swapgs
  80         sysretq
  81 ENDPROC(native_usergs_sysret64)
  82 #endif /* CONFIG_PARAVIRT */
  83
  84
  85 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
  86 #ifdef CONFIG_TRACE_IRQFLAGS
  87         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
  88         jnc  1f
  89         TRACE_IRQS_ON
  90 1:
  91 #endif
  92 .endm
  93
  94 /*
  95  * When dynamic function tracer is enabled it will add a breakpoint
  96  * to all locations that it is about to modify, sync CPUs, update
  97  * all the code, sync CPUs, then remove the breakpoints. In this time
  98  * if lockdep is enabled, it might jump back into the debug handler
  99  * outside the updating of the IST protection. (TRACE_IRQS_ON/OFF).
 100  *
 101  * We need to change the IDT table before calling TRACE_IRQS_ON/OFF to
 102  * make sure the stack pointer does not get reset back to the top
 103  * of the debug stack, and instead just reuses the current stack.
 104  */
 105 #if defined(CONFIG_DYNAMIC_FTRACE) && defined(CONFIG_TRACE_IRQFLAGS)
 106
 107 .macro TRACE_IRQS_OFF_DEBUG
 108         call debug_stack_set_zero
 109         TRACE_IRQS_OFF
 110         call debug_stack_reset
 111 .endm
 112
 113 .macro TRACE_IRQS_ON_DEBUG
 114         call debug_stack_set_zero
 115         TRACE_IRQS_ON
 116         call debug_stack_reset
 117 .endm
 118
 119 .macro TRACE_IRQS_IRETQ_DEBUG offset=ARGOFFSET
 120         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 121         jnc  1f
 122         TRACE_IRQS_ON_DEBUG
 123 1:
 124 .endm
 125
 126 #else
 127 # define TRACE_IRQS_OFF_DEBUG           TRACE_IRQS_OFF
 128 # define TRACE_IRQS_ON_DEBUG            TRACE_IRQS_ON
 129 # define TRACE_IRQS_IRETQ_DEBUG         TRACE_IRQS_IRETQ
 130 #endif
 131
 132 /*
 133  * C code is not supposed to know about undefined top of stack. Every time
 134  * a C function with an pt_regs argument is called from the SYSCALL based
 135  * fast path FIXUP_TOP_OF_STACK is needed.
 136  * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
 137  * manipulation.
 138  */
 139
 140         /* %rsp:at FRAMEEND */
 141         .macro FIXUP_TOP_OF_STACK tmp offset=0
 142         movq PER_CPU_VAR(old_rsp),\tmp
 143         movq \tmp,RSP+\offset(%rsp)
 144         movq $__USER_DS,SS+\offset(%rsp)
 145         movq $__USER_CS,CS+\offset(%rsp)
 146         movq $-1,RCX+\offset(%rsp)
 147         movq R11+\offset(%rsp),\tmp  /* get eflags */
 148         movq \tmp,EFLAGS+\offset(%rsp)
 149         .endm
 150
 151         .macro RESTORE_TOP_OF_STACK tmp offset=0
 152         movq RSP+\offset(%rsp),\tmp
 153         movq \tmp,PER_CPU_VAR(old_rsp)
 154         movq EFLAGS+\offset(%rsp),\tmp
 155         movq \tmp,R11+\offset(%rsp)
 156         .endm
 157
 158         .macro FAKE_STACK_FRAME child_rip
 159         /* push in order ss, rsp, eflags, cs, rip */
 160         xorl %eax, %eax
 161         pushq_cfi $__KERNEL_DS /* ss */
 162         /*CFI_REL_OFFSET        ss,0*/
 163         pushq_cfi %rax /* rsp */
 164         CFI_REL_OFFSET  rsp,0
 165         pushq_cfi $(X86_EFLAGS_IF|X86_EFLAGS_FIXED) /* eflags - interrupts on */
 166         /*CFI_REL_OFFSET        rflags,0*/
 167         pushq_cfi $__KERNEL_CS /* cs */
 168         /*CFI_REL_OFFSET        cs,0*/
 169         pushq_cfi \child_rip /* rip */
 170         CFI_REL_OFFSET  rip,0
 171         pushq_cfi %rax /* orig rax */
 172         .endm
 173
 174         .macro UNFAKE_STACK_FRAME
 175         addq $8*6, %rsp
 176         CFI_ADJUST_CFA_OFFSET   -(6*8)
 177         .endm
 178
 179 /*
 180  * initial frame state for interrupts (and exceptions without error code)
 181  */
 182         .macro EMPTY_FRAME start=1 offset=0
 183         .if \start
 184         CFI_STARTPROC simple
 185         CFI_SIGNAL_FRAME
 186         CFI_DEF_CFA rsp,8+\offset
 187         .else
 188         CFI_DEF_CFA_OFFSET 8+\offset
 189         .endif
 190         .endm
 191
 192 /*
 193  * initial frame state for interrupts (and exceptions without error code)
 194  */
 195         .macro INTR_FRAME start=1 offset=0
 196         EMPTY_FRAME \start, SS+8+\offset-RIP
 197         /*CFI_REL_OFFSET ss, SS+\offset-RIP*/
 198         CFI_REL_OFFSET rsp, RSP+\offset-RIP
 199         /*CFI_REL_OFFSET rflags, EFLAGS+\offset-RIP*/
 200         /*CFI_REL_OFFSET cs, CS+\offset-RIP*/
 201         CFI_REL_OFFSET rip, RIP+\offset-RIP
 202         .endm
 203
 204 /*
 205  * initial frame state for exceptions with error code (and interrupts
 206  * with vector already pushed)
 207  */
 208         .macro XCPT_FRAME start=1 offset=0
 209         INTR_FRAME \start, RIP+\offset-ORIG_RAX
 210         /*CFI_REL_OFFSET orig_rax, ORIG_RAX-ORIG_RAX*/
 211         .endm
 212
 213 /*
 214  * frame that enables calling into C.
 215  */
 216         .macro PARTIAL_FRAME start=1 offset=0
 217         XCPT_FRAME \start, ORIG_RAX+\offset-ARGOFFSET
 218         CFI_REL_OFFSET rdi, RDI+\offset-ARGOFFSET
 219         CFI_REL_OFFSET rsi, RSI+\offset-ARGOFFSET
 220         CFI_REL_OFFSET rdx, RDX+\offset-ARGOFFSET
 221         CFI_REL_OFFSET rcx, RCX+\offset-ARGOFFSET
 222         CFI_REL_OFFSET rax, RAX+\offset-ARGOFFSET
 223         CFI_REL_OFFSET r8, R8+\offset-ARGOFFSET
 224         CFI_REL_OFFSET r9, R9+\offset-ARGOFFSET
 225         CFI_REL_OFFSET r10, R10+\offset-ARGOFFSET
 226         CFI_REL_OFFSET r11, R11+\offset-ARGOFFSET
 227         .endm
 228
 229 /*
 230  * frame that enables passing a complete pt_regs to a C function.
 231  */
 232         .macro DEFAULT_FRAME start=1 offset=0
 233         PARTIAL_FRAME \start, R11+\offset-R15
 234         CFI_REL_OFFSET rbx, RBX+\offset
 235         CFI_REL_OFFSET rbp, RBP+\offset
 236         CFI_REL_OFFSET r12, R12+\offset
 237         CFI_REL_OFFSET r13, R13+\offset
 238         CFI_REL_OFFSET r14, R14+\offset
 239         CFI_REL_OFFSET r15, R15+\offset
 240         .endm
 241
 242 /* save partial stack frame */
 243         .macro SAVE_ARGS_IRQ
 244         cld
 245         /* start from rbp in pt_regs and jump over */
 246         movq_cfi rdi, (RDI-RBP)
 247         movq_cfi rsi, (RSI-RBP)
 248         movq_cfi rdx, (RDX-RBP)
 249         movq_cfi rcx, (RCX-RBP)
 250         movq_cfi rax, (RAX-RBP)
 251         movq_cfi  r8,  (R8-RBP)
 252         movq_cfi  r9,  (R9-RBP)
 253         movq_cfi r10, (R10-RBP)
 254         movq_cfi r11, (R11-RBP)
 255
 256         /* Save rbp so that we can unwind from get_irq_regs() */
 257         movq_cfi rbp, 0
 258
 259         /* Save previous stack value */
 260         movq %rsp, %rsi
 261
 262         leaq -RBP(%rsp),%rdi    /* arg1 for handler */
 263         testl $3, CS-RBP(%rsi)
 264         je 1f
 265         SWAPGS
 266         /*
 267          * irq_count is used to check if a CPU is already on an interrupt stack
 268          * or not. While this is essentially redundant with preempt_count it is
 269          * a little cheaper to use a separate counter in the PDA (short of
 270          * moving irq_enter into assembly, which would be too much work)
 271          */
 272 1:      incl PER_CPU_VAR(irq_count)
 273         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
 274         CFI_DEF_CFA_REGISTER    rsi
 275
 276         /* Store previous stack value */
 277         pushq %rsi
 278         CFI_ESCAPE      0x0f /* DW_CFA_def_cfa_expression */, 6, \
 279                         0x77 /* DW_OP_breg7 */, 0, \
 280                         0x06 /* DW_OP_deref */, \
 281                         0x08 /* DW_OP_const1u */, SS+8-RBP, \
 282                         0x22 /* DW_OP_plus */
 283         /* We entered an interrupt context - irqs are off: */
 284         TRACE_IRQS_OFF
 285         .endm
 286
 287 /* save complete stack frame */
 288         .pushsection .kprobes.text, "ax"
 289 ENTRY(save_paranoid)
 290         XCPT_FRAME 1 RDI+8
 291         cld
 292         movq_cfi rdi, RDI+8
 293         movq_cfi rsi, RSI+8
 294         movq_cfi rdx, RDX+8
 295         movq_cfi rcx, RCX+8
 296         movq_cfi rax, RAX+8
 297         movq_cfi r8, R8+8
 298         movq_cfi r9, R9+8
 299         movq_cfi r10, R10+8
 300         movq_cfi r11, R11+8
 301         movq_cfi rbx, RBX+8
 302         movq_cfi rbp, RBP+8
 303         movq_cfi r12, R12+8
 304         movq_cfi r13, R13+8
 305         movq_cfi r14, R14+8
 306         movq_cfi r15, R15+8
 307         movl $1,%ebx
 308         movl $MSR_GS_BASE,%ecx
 309         rdmsr
 310         testl %edx,%edx
 311         js 1f   /* negative -> in kernel */
 312         SWAPGS
 313         xorl %ebx,%ebx
 314 1:      ret
 315         CFI_ENDPROC
 316 END(save_paranoid)
 317         .popsection
 318
 319 /*
 320  * A newly forked process directly context switches into this address.
 321  *
 322  * rdi: prev task we switched from
 323  */
 324 ENTRY(ret_from_fork)
 325         DEFAULT_FRAME
 326
 327         LOCK ; btr $TIF_FORK,TI_flags(%r8)
 328
 329         pushq_cfi $0x0002
 330         popfq_cfi                               # reset kernel eflags
 331
 332         call schedule_tail                      # rdi: 'prev' task parameter
 333
 334         GET_THREAD_INFO(%rcx)
 335
 336         RESTORE_REST
 337
 338         testl $3, CS-ARGOFFSET(%rsp)            # from kernel_thread?
 339         jz   1f
 340
 341         testl $_TIF_IA32, TI_flags(%rcx)        # 32-bit compat task needs IRET
 342         jnz  int_ret_from_sys_call
 343
 344         RESTORE_TOP_OF_STACK %rdi, -ARGOFFSET
 345         jmp ret_from_sys_call                   # go to the SYSRET fastpath
 346
 347 1:
 348         subq $REST_SKIP, %rsp   # leave space for volatiles
 349         CFI_ADJUST_CFA_OFFSET   REST_SKIP
 350         movq %rbp, %rdi
 351         call *%rbx
 352         movl $0, RAX(%rsp)
 353         RESTORE_REST
 354         jmp int_ret_from_sys_call
 355         CFI_ENDPROC
 356 END(ret_from_fork)
 357
 358 /*
 359  * System call entry. Up to 6 arguments in registers are supported.
 360  *
 361  * SYSCALL does not save anything on the stack and does not change the
 362  * stack pointer.  However, it does mask the flags register for us, so
 363  * CLD and CLAC are not needed.
 364  */
 365
 366 /*
 367  * Register setup:
 368  * rax  system call number
 369  * rdi  arg0
 370  * rcx  return address for syscall/sysret, C arg3
 371  * rsi  arg1
 372  * rdx  arg2
 373  * r10  arg3    (--> moved to rcx for C)
 374  * r8   arg4
 375  * r9   arg5
 376  * r11  eflags for syscall/sysret, temporary for C
 377  * r12-r15,rbp,rbx saved by C code, not touched.
 378  *
 379  * Interrupts are off on entry.
 380  * Only called from user space.
 381  *
 382  * XXX  if we had a free scratch register we could save the RSP into the stack frame
 383  *      and report it properly in ps. Unfortunately we haven't.
 384  *
 385  * When user can change the frames always force IRET. That is because
 386  * it deals with uncanonical addresses better. SYSRET has trouble
 387  * with them due to bugs in both AMD and Intel CPUs.
 388  */
 389
 390 ENTRY(system_call)
 391         CFI_STARTPROC   simple
 392         CFI_SIGNAL_FRAME
 393         CFI_DEF_CFA     rsp,KERNEL_STACK_OFFSET
 394         CFI_REGISTER    rip,rcx
 395         /*CFI_REGISTER  rflags,r11*/
 396         SWAPGS_UNSAFE_STACK
 397         /*
 398          * A hypervisor implementation might want to use a label
 399          * after the swapgs, so that it can do the swapgs
 400          * for the guest and jump here on syscall.
 401          */
 402 GLOBAL(system_call_after_swapgs)
 403
 404         movq    %rsp,PER_CPU_VAR(old_rsp)
 405         movq    PER_CPU_VAR(kernel_stack),%rsp
 406         /*
 407          * No need to follow this irqs off/on section - it's straight
 408          * and short:
 409          */
 410         ENABLE_INTERRUPTS(CLBR_NONE)
 411         SAVE_ARGS 8,0
 412         movq  %rax,ORIG_RAX-ARGOFFSET(%rsp)
 413         movq  %rcx,RIP-ARGOFFSET(%rsp)
 414         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 415         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 416         jnz tracesys
 417 system_call_fastpath:
 418 #if __SYSCALL_MASK == ~0
 419         cmpq $__NR_syscall_max,%rax
 420 #else
 421         andl $__SYSCALL_MASK,%eax
 422         cmpl $__NR_syscall_max,%eax
 423 #endif
 424         ja badsys
 425         movq %r10,%rcx
 426         call *sys_call_table(,%rax,8)  # XXX:    rip relative
 427         movq %rax,RAX-ARGOFFSET(%rsp)
 428 /*
 429  * Syscall return path ending with SYSRET (fast path)
 430  * Has incomplete stack frame and undefined top of stack.
 431  */
 432 ret_from_sys_call:
 433         movl $_TIF_ALLWORK_MASK,%edi
 434         /* edi: flagmask */
 435 sysret_check:
 436         LOCKDEP_SYS_EXIT
 437         DISABLE_INTERRUPTS(CLBR_NONE)
 438         TRACE_IRQS_OFF
 439         movl TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET),%edx
 440         andl %edi,%edx
 441         jnz  sysret_careful
 442         CFI_REMEMBER_STATE
 443         /*
 444          * sysretq will re-enable interrupts:
 445          */
 446         TRACE_IRQS_ON
 447         movq RIP-ARGOFFSET(%rsp),%rcx
 448         CFI_REGISTER    rip,rcx
 449         RESTORE_ARGS 1,-ARG_SKIP,0
 450         /*CFI_REGISTER  rflags,r11*/
 451         movq    PER_CPU_VAR(old_rsp), %rsp
 452         USERGS_SYSRET64
 453
 454         CFI_RESTORE_STATE
 455         /* Handle reschedules */
 456         /* edx: work, edi: workmask */
 457 sysret_careful:
 458         bt $TIF_NEED_RESCHED,%edx
 459         jnc sysret_signal
 460         TRACE_IRQS_ON
 461         ENABLE_INTERRUPTS(CLBR_NONE)
 462         pushq_cfi %rdi
 463         SCHEDULE_USER
 464         popq_cfi %rdi
 465         jmp sysret_check
 466
 467         /* Handle a signal */
 468 sysret_signal:
 469         TRACE_IRQS_ON
 470         ENABLE_INTERRUPTS(CLBR_NONE)
 471 #ifdef CONFIG_AUDITSYSCALL
 472         bt $TIF_SYSCALL_AUDIT,%edx
 473         jc sysret_audit
 474 #endif
 475         /*
 476          * We have a signal, or exit tracing or single-step.
 477          * These all wind up with the iret return path anyway,
 478          * so just join that path right now.
 479          */
 480         FIXUP_TOP_OF_STACK %r11, -ARGOFFSET
 481         jmp int_check_syscall_exit_work
 482
 483 badsys:
 484         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 485         jmp ret_from_sys_call
 486
 487 #ifdef CONFIG_AUDITSYSCALL
 488         /*
 489          * Fast path for syscall audit without full syscall trace.
 490          * We just call __audit_syscall_entry() directly, and then
 491          * jump back to the normal fast path.
 492          */
 493 auditsys:
 494         movq %r10,%r9                   /* 6th arg: 4th syscall arg */
 495         movq %rdx,%r8                   /* 5th arg: 3rd syscall arg */
 496         movq %rsi,%rcx                  /* 4th arg: 2nd syscall arg */
 497         movq %rdi,%rdx                  /* 3rd arg: 1st syscall arg */
 498         movq %rax,%rsi                  /* 2nd arg: syscall number */
 499         movl $AUDIT_ARCH_X86_64,%edi    /* 1st arg: audit arch */
 500         call __audit_syscall_entry
 501         LOAD_ARGS 0             /* reload call-clobbered registers */
 502         jmp system_call_fastpath
 503
 504         /*
 505          * Return fast path for syscall audit.  Call __audit_syscall_exit()
 506          * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
 507          * masked off.
 508          */
 509 sysret_audit:
 510         movq RAX-ARGOFFSET(%rsp),%rsi   /* second arg, syscall return value */
 511         cmpq $-MAX_ERRNO,%rsi   /* is it < -MAX_ERRNO? */
 512         setbe %al               /* 1 if so, 0 if not */
 513         movzbl %al,%edi         /* zero-extend that into %edi */
 514         call __audit_syscall_exit
 515         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
 516         jmp sysret_check
 517 #endif  /* CONFIG_AUDITSYSCALL */
 518
 519         /* Do syscall tracing */
 520 tracesys:
 521 #ifdef CONFIG_AUDITSYSCALL
 522         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 523         jz auditsys
 524 #endif
 525         SAVE_REST
 526         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 527         FIXUP_TOP_OF_STACK %rdi
 528         movq %rsp,%rdi
 529         call syscall_trace_enter
 530         /*
 531          * Reload arg registers from stack in case ptrace changed them.
 532          * We don't reload %rax because syscall_trace_enter() returned
 533          * the value it wants us to use in the table lookup.
 534          */
 535         LOAD_ARGS ARGOFFSET, 1
 536         RESTORE_REST
 537 #if __SYSCALL_MASK == ~0
 538         cmpq $__NR_syscall_max,%rax
 539 #else
 540         andl $__SYSCALL_MASK,%eax
 541         cmpl $__NR_syscall_max,%eax
 542 #endif
 543         ja   int_ret_from_sys_call      /* RAX(%rsp) set to -ENOSYS above */
 544         movq %r10,%rcx  /* fixup for C */
 545         call *sys_call_table(,%rax,8)
 546         movq %rax,RAX-ARGOFFSET(%rsp)
 547         /* Use IRET because user could have changed frame */
 548
 549 /*
 550  * Syscall return path ending with IRET.
 551  * Has correct top of stack, but partial stack frame.
 552  */
 553 GLOBAL(int_ret_from_sys_call)
 554         DISABLE_INTERRUPTS(CLBR_NONE)
 555         TRACE_IRQS_OFF
 556         movl $_TIF_ALLWORK_MASK,%edi
 557         /* edi: mask to check */
 558 GLOBAL(int_with_check)
 559         LOCKDEP_SYS_EXIT_IRQ
 560         GET_THREAD_INFO(%rcx)
 561         movl TI_flags(%rcx),%edx
 562         andl %edi,%edx
 563         jnz   int_careful
 564         andl    $~TS_COMPAT,TI_status(%rcx)
 565         jmp   retint_swapgs
 566
 567         /* Either reschedule or signal or syscall exit tracking needed. */
 568         /* First do a reschedule test. */
 569         /* edx: work, edi: workmask */
 570 int_careful:
 571         bt $TIF_NEED_RESCHED,%edx
 572         jnc  int_very_careful
 573         TRACE_IRQS_ON
 574         ENABLE_INTERRUPTS(CLBR_NONE)
 575         pushq_cfi %rdi
 576         SCHEDULE_USER
 577         popq_cfi %rdi
 578         DISABLE_INTERRUPTS(CLBR_NONE)
 579         TRACE_IRQS_OFF
 580         jmp int_with_check
 581
 582         /* handle signals and tracing -- both require a full stack frame */
 583 int_very_careful:
 584         TRACE_IRQS_ON
 585         ENABLE_INTERRUPTS(CLBR_NONE)
 586 int_check_syscall_exit_work:
 587         SAVE_REST
 588         /* Check for syscall exit trace */
 589         testl $_TIF_WORK_SYSCALL_EXIT,%edx
 590         jz int_signal
 591         pushq_cfi %rdi
 592         leaq 8(%rsp),%rdi       # &ptregs -> arg1
 593         call syscall_trace_leave
 594         popq_cfi %rdi
 595         andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
 596         jmp int_restore_rest
 597
 598 int_signal:
 599         testl $_TIF_DO_NOTIFY_MASK,%edx
 600         jz 1f
 601         movq %rsp,%rdi          # &ptregs -> arg1
 602         xorl %esi,%esi          # oldset -> arg2
 603         call do_notify_resume
 604 1:      movl $_TIF_WORK_MASK,%edi
 605 int_restore_rest:
 606         RESTORE_REST
 607         DISABLE_INTERRUPTS(CLBR_NONE)
 608         TRACE_IRQS_OFF
 609         jmp int_with_check
 610         CFI_ENDPROC
 611 END(system_call)
 612
 613         .macro FORK_LIKE func
 614 ENTRY(stub_\func)
 615         CFI_STARTPROC
 616         popq    %r11                    /* save return address */
 617         PARTIAL_FRAME 0
 618         SAVE_REST
 619         pushq   %r11                    /* put it back on stack */
 620         FIXUP_TOP_OF_STACK %r11, 8
 621         DEFAULT_FRAME 0 8               /* offset 8: return address */
 622         call sys_\func
 623         RESTORE_TOP_OF_STACK %r11, 8
 624         ret $REST_SKIP          /* pop extended registers */
 625         CFI_ENDPROC
 626 END(stub_\func)
 627         .endm
 628
 629         .macro FIXED_FRAME label,func
 630 ENTRY(\label)
 631         CFI_STARTPROC
 632         PARTIAL_FRAME 0 8               /* offset 8: return address */
 633         FIXUP_TOP_OF_STACK %r11, 8-ARGOFFSET
 634         call \func
 635         RESTORE_TOP_OF_STACK %r11, 8-ARGOFFSET
 636         ret
 637         CFI_ENDPROC
 638 END(\label)
 639         .endm
 640
 641         FORK_LIKE  clone
 642         FORK_LIKE  fork
 643         FORK_LIKE  vfork
 644         FIXED_FRAME stub_iopl, sys_iopl
 645
 646 ENTRY(ptregscall_common)
 647         DEFAULT_FRAME 1 8       /* offset 8: return address */
 648         RESTORE_TOP_OF_STACK %r11, 8
 649         movq_cfi_restore R15+8, r15
 650         movq_cfi_restore R14+8, r14
 651         movq_cfi_restore R13+8, r13
 652         movq_cfi_restore R12+8, r12
 653         movq_cfi_restore RBP+8, rbp
 654         movq_cfi_restore RBX+8, rbx
 655         ret $REST_SKIP          /* pop extended registers */
 656         CFI_ENDPROC
 657 END(ptregscall_common)
 658
 659 ENTRY(stub_execve)
 660         CFI_STARTPROC
 661         addq $8, %rsp
 662         PARTIAL_FRAME 0
 663         SAVE_REST
 664         FIXUP_TOP_OF_STACK %r11
 665         call sys_execve
 666         movq %rax,RAX(%rsp)
 667         RESTORE_REST
 668         jmp int_ret_from_sys_call
 669         CFI_ENDPROC
 670 END(stub_execve)
 671
 672 /*
 673  * sigreturn is special because it needs to restore all registers on return.
 674  * This cannot be done with SYSRET, so use the IRET return path instead.
 675  */
 676 ENTRY(stub_rt_sigreturn)
 677         CFI_STARTPROC
 678         addq $8, %rsp
 679         PARTIAL_FRAME 0
 680         SAVE_REST
 681         FIXUP_TOP_OF_STACK %r11
 682         call sys_rt_sigreturn
 683         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 684         RESTORE_REST
 685         jmp int_ret_from_sys_call
 686         CFI_ENDPROC
 687 END(stub_rt_sigreturn)
 688
 689 #ifdef CONFIG_X86_X32_ABI
 690 ENTRY(stub_x32_rt_sigreturn)
 691         CFI_STARTPROC
 692         addq $8, %rsp
 693         PARTIAL_FRAME 0
 694         SAVE_REST
 695         FIXUP_TOP_OF_STACK %r11
 696         call sys32_x32_rt_sigreturn
 697         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 698         RESTORE_REST
 699         jmp int_ret_from_sys_call
 700         CFI_ENDPROC
 701 END(stub_x32_rt_sigreturn)
 702
 703 ENTRY(stub_x32_execve)
 704         CFI_STARTPROC
 705         addq $8, %rsp
 706         PARTIAL_FRAME 0
 707         SAVE_REST
 708         FIXUP_TOP_OF_STACK %r11
 709         call compat_sys_execve
 710         RESTORE_TOP_OF_STACK %r11
 711         movq %rax,RAX(%rsp)
 712         RESTORE_REST
 713         jmp int_ret_from_sys_call
 714         CFI_ENDPROC
 715 END(stub_x32_execve)
 716
 717 #endif
 718
 719 /*
 720  * Build the entry stubs and pointer table with some assembler magic.
 721  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 722  * single cache line on all modern x86 implementations.
 723  */
 724         .section .init.rodata,"a"
 725 ENTRY(interrupt)
 726         .section .entry.text
 727         .p2align 5
 728         .p2align CONFIG_X86_L1_CACHE_SHIFT
 729 ENTRY(irq_entries_start)
 730         INTR_FRAME
 731 vector=FIRST_EXTERNAL_VECTOR
 732 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 733         .balign 32
 734   .rept 7
 735     .if vector < NR_VECTORS
 736       .if vector <> FIRST_EXTERNAL_VECTOR
 737         CFI_ADJUST_CFA_OFFSET -8
 738       .endif
 739 1:      pushq_cfi $(~vector+0x80)       /* Note: always in signed byte range */
 740       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 741         jmp 2f
 742       .endif
 743       .previous
 744         .quad 1b
 745       .section .entry.text
 746 vector=vector+1
 747     .endif
 748   .endr
 749 2:      jmp common_interrupt
 750 .endr
 751         CFI_ENDPROC
 752 END(irq_entries_start)
 753
 754 .previous
 755 END(interrupt)
 756 .previous
 757
 758 /*
 759  * Interrupt entry/exit.
 760  *
 761  * Interrupt entry points save only callee clobbered registers in fast path.
 762  *
 763  * Entry runs with interrupts off.
 764  */
 765
 766 /* 0(%rsp): ~(interrupt number) */
 767         .macro interrupt func
 768         /* reserve pt_regs for scratch regs and rbp */
 769         subq $ORIG_RAX-RBP, %rsp
 770         CFI_ADJUST_CFA_OFFSET ORIG_RAX-RBP
 771         SAVE_ARGS_IRQ
 772         call \func
 773         .endm
 774
 775 /*
 776  * Interrupt entry/exit should be protected against kprobes
 777  */
 778         .pushsection .kprobes.text, "ax"
 779         /*
 780          * The interrupt stubs push (~vector+0x80) onto the stack and
 781          * then jump to common_interrupt.
 782          */
 783         .p2align CONFIG_X86_L1_CACHE_SHIFT
 784 common_interrupt:
 785         XCPT_FRAME
 786         ASM_CLAC
 787         addq $-0x80,(%rsp)              /* Adjust vector to [-256,-1] range */
 788         interrupt do_IRQ
 789         /* 0(%rsp): old_rsp-ARGOFFSET */
 790 ret_from_intr:
 791         DISABLE_INTERRUPTS(CLBR_NONE)
 792         TRACE_IRQS_OFF
 793         decl PER_CPU_VAR(irq_count)
 794
 795         /* Restore saved previous stack */
 796         popq %rsi
 797         CFI_DEF_CFA rsi,SS+8-RBP        /* reg/off reset after def_cfa_expr */
 798         leaq ARGOFFSET-RBP(%rsi), %rsp
 799         CFI_DEF_CFA_REGISTER    rsp
 800         CFI_ADJUST_CFA_OFFSET   RBP-ARGOFFSET
 801
 802 exit_intr:
 803         GET_THREAD_INFO(%rcx)
 804         testl $3,CS-ARGOFFSET(%rsp)
 805         je retint_kernel
 806
 807         /* Interrupt came from user space */
 808         /*
 809          * Has a correct top of stack, but a partial stack frame
 810          * %rcx: thread info. Interrupts off.
 811          */
 812 retint_with_reschedule:
 813         movl $_TIF_WORK_MASK,%edi
 814 retint_check:
 815         LOCKDEP_SYS_EXIT_IRQ
 816         movl TI_flags(%rcx),%edx
 817         andl %edi,%edx
 818         CFI_REMEMBER_STATE
 819         jnz  retint_careful
 820
 821 retint_swapgs:          /* return to user-space */
 822         /*
 823          * The iretq could re-enable interrupts:
 824          */
 825         DISABLE_INTERRUPTS(CLBR_ANY)
 826         TRACE_IRQS_IRETQ
 827         SWAPGS
 828         jmp restore_args
 829
 830 retint_restore_args:    /* return to kernel space */
 831         DISABLE_INTERRUPTS(CLBR_ANY)
 832         /*
 833          * The iretq could re-enable interrupts:
 834          */
 835         TRACE_IRQS_IRETQ
 836 restore_args:
 837         RESTORE_ARGS 1,8,1
 838
 839 irq_return:
 840         /*
 841          * Are we returning to a stack segment from the LDT?  Note: in
 842          * 64-bit mode SS:RSP on the exception stack is always valid.
 843          */
 844 #ifdef CONFIG_X86_ESPFIX64
 845         testb $4,(SS-RIP)(%rsp)
 846         jnz irq_return_ldt
 847 #endif
 848
 849 irq_return_iret:
 850         INTERRUPT_RETURN
 851         _ASM_EXTABLE(irq_return_iret, bad_iret)
 852
 853 #ifdef CONFIG_PARAVIRT
 854 ENTRY(native_iret)
 855         iretq
 856         _ASM_EXTABLE(native_iret, bad_iret)
 857 #endif
 858
 859 #ifdef CONFIG_X86_ESPFIX64
 860 irq_return_ldt:
 861         pushq_cfi %rax
 862         pushq_cfi %rdi
 863         SWAPGS
 864         movq PER_CPU_VAR(espfix_waddr),%rdi
 865         movq %rax,(0*8)(%rdi)   /* RAX */
 866         movq (2*8)(%rsp),%rax   /* RIP */
 867         movq %rax,(1*8)(%rdi)
 868         movq (3*8)(%rsp),%rax   /* CS */
 869         movq %rax,(2*8)(%rdi)
 870         movq (4*8)(%rsp),%rax   /* RFLAGS */
 871         movq %rax,(3*8)(%rdi)
 872         movq (6*8)(%rsp),%rax   /* SS */
 873         movq %rax,(5*8)(%rdi)
 874         movq (5*8)(%rsp),%rax   /* RSP */
 875         movq %rax,(4*8)(%rdi)
 876         andl $0xffff0000,%eax
 877         popq_cfi %rdi
 878         orq PER_CPU_VAR(espfix_stack),%rax
 879         SWAPGS
 880         movq %rax,%rsp
 881         popq_cfi %rax
 882         jmp irq_return_iret
 883 #endif
 884
 885         .section .fixup,"ax"
 886 bad_iret:
 887         /*
 888          * The iret traps when the %cs or %ss being restored is bogus.
 889          * We've lost the original trap vector and error code.
 890          * #GPF is the most likely one to get for an invalid selector.
 891          * So pretend we completed the iret and took the #GPF in user mode.
 892          *
 893          * We are now running with the kernel GS after exception recovery.
 894          * But error_entry expects us to have user GS to match the user %cs,
 895          * so swap back.
 896          */
 897         pushq $0
 898
 899         SWAPGS
 900         jmp general_protection
 901
 902         .previous
 903
 904         /* edi: workmask, edx: work */
 905 retint_careful:
 906         CFI_RESTORE_STATE
 907         bt    $TIF_NEED_RESCHED,%edx
 908         jnc   retint_signal
 909         TRACE_IRQS_ON
 910         ENABLE_INTERRUPTS(CLBR_NONE)
 911         pushq_cfi %rdi
 912         SCHEDULE_USER
 913         popq_cfi %rdi
 914         GET_THREAD_INFO(%rcx)
 915         DISABLE_INTERRUPTS(CLBR_NONE)
 916         TRACE_IRQS_OFF
 917         jmp retint_check
 918
 919 retint_signal:
 920         testl $_TIF_DO_NOTIFY_MASK,%edx
 921         jz    retint_swapgs
 922         TRACE_IRQS_ON
 923         ENABLE_INTERRUPTS(CLBR_NONE)
 924         SAVE_REST
 925         movq $-1,ORIG_RAX(%rsp)
 926         xorl %esi,%esi          # oldset
 927         movq %rsp,%rdi          # &pt_regs
 928         call do_notify_resume
 929         RESTORE_REST
 930         DISABLE_INTERRUPTS(CLBR_NONE)
 931         TRACE_IRQS_OFF
 932         GET_THREAD_INFO(%rcx)
 933         jmp retint_with_reschedule
 934
 935 #ifdef CONFIG_PREEMPT
 936         /* Returning to kernel space. Check if we need preemption */
 937         /* rcx:  threadinfo. interrupts off. */
 938 ENTRY(retint_kernel)
 939         cmpl $0,PER_CPU_VAR(__preempt_count)
 940         jnz  retint_restore_args
 941         bt   $9,EFLAGS-ARGOFFSET(%rsp)  /* interrupts off? */
 942         jnc  retint_restore_args
 943         call preempt_schedule_irq
 944         jmp exit_intr
 945 #endif
 946         CFI_ENDPROC
 947 END(common_interrupt)
 948
 949         /*
 950          * If IRET takes a fault on the espfix stack, then we
 951          * end up promoting it to a doublefault.  In that case,
 952          * modify the stack to make it look like we just entered
 953          * the #GP handler from user space, similar to bad_iret.
 954          */
 955 #ifdef CONFIG_X86_ESPFIX64
 956         ALIGN
 957 __do_double_fault:
 958         XCPT_FRAME 1 RDI+8
 959         movq RSP(%rdi),%rax             /* Trap on the espfix stack? */
 960         sarq $PGDIR_SHIFT,%rax
 961         cmpl $ESPFIX_PGD_ENTRY,%eax
 962         jne do_double_fault             /* No, just deliver the fault */
 963         cmpl $__KERNEL_CS,CS(%rdi)
 964         jne do_double_fault
 965         movq RIP(%rdi),%rax
 966         cmpq $irq_return_iret,%rax
 967 #ifdef CONFIG_PARAVIRT
 968         je 1f
 969         cmpq $native_iret,%rax
 970 #endif
 971         jne do_double_fault             /* This shouldn't happen... */
 972 1:
 973         movq PER_CPU_VAR(kernel_stack),%rax
 974         subq $(6*8-KERNEL_STACK_OFFSET),%rax    /* Reset to original stack */
 975         movq %rax,RSP(%rdi)
 976         movq $0,(%rax)                  /* Missing (lost) #GP error code */
 977         movq $general_protection,RIP(%rdi)
 978         retq
 979         CFI_ENDPROC
 980 END(__do_double_fault)
 981 #else
 982 # define __do_double_fault do_double_fault
 983 #endif
 984
 985 /*
 986  * End of kprobes section
 987  */
 988        .popsection
 989
 990 /*
 991  * APIC interrupts.
 992  */
 993 .macro apicinterrupt3 num sym do_sym
 994 ENTRY(\sym)
 995         INTR_FRAME
 996         ASM_CLAC
 997         pushq_cfi $~(\num)
 998 .Lcommon_\sym:
 999         interrupt \do_sym
1000         jmp ret_from_intr
1001         CFI_ENDPROC
1002 END(\sym)
1003 .endm
1004
1005 #ifdef CONFIG_TRACING
1006 #define trace(sym) trace_##sym
1007 #define smp_trace(sym) smp_trace_##sym
1008
1009 .macro trace_apicinterrupt num sym
1010 apicinterrupt3 \num trace(\sym) smp_trace(\sym)
1011 .endm
1012 #else
1013 .macro trace_apicinterrupt num sym do_sym
1014 .endm
1015 #endif
1016
1017 .macro apicinterrupt num sym do_sym
1018 apicinterrupt3 \num \sym \do_sym
1019 trace_apicinterrupt \num \sym
1020 .endm
1021
1022 #ifdef CONFIG_SMP
1023 apicinterrupt3 IRQ_MOVE_CLEANUP_VECTOR \
1024         irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
1025 apicinterrupt3 REBOOT_VECTOR \
1026         reboot_interrupt smp_reboot_interrupt
1027 #endif
1028
1029 #ifdef CONFIG_X86_UV
1030 apicinterrupt3 UV_BAU_MESSAGE \
1031         uv_bau_message_intr1 uv_bau_message_interrupt
1032 #endif
1033 apicinterrupt LOCAL_TIMER_VECTOR \
1034         apic_timer_interrupt smp_apic_timer_interrupt
1035 apicinterrupt X86_PLATFORM_IPI_VECTOR \
1036         x86_platform_ipi smp_x86_platform_ipi
1037
1038 #ifdef CONFIG_HAVE_KVM
1039 apicinterrupt3 POSTED_INTR_VECTOR \
1040         kvm_posted_intr_ipi smp_kvm_posted_intr_ipi
1041 #endif
1042
1043 #ifdef CONFIG_X86_MCE_THRESHOLD
1044 apicinterrupt THRESHOLD_APIC_VECTOR \
1045         threshold_interrupt smp_threshold_interrupt
1046 #endif
1047
1048 #ifdef CONFIG_X86_THERMAL_VECTOR
1049 apicinterrupt THERMAL_APIC_VECTOR \
1050         thermal_interrupt smp_thermal_interrupt
1051 #endif
1052
1053 #ifdef CONFIG_SMP
1054 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
1055         call_function_single_interrupt smp_call_function_single_interrupt
1056 apicinterrupt CALL_FUNCTION_VECTOR \
1057         call_function_interrupt smp_call_function_interrupt
1058 apicinterrupt RESCHEDULE_VECTOR \
1059         reschedule_interrupt smp_reschedule_interrupt
1060 #endif
1061
1062 apicinterrupt ERROR_APIC_VECTOR \
1063         error_interrupt smp_error_interrupt
1064 apicinterrupt SPURIOUS_APIC_VECTOR \
1065         spurious_interrupt smp_spurious_interrupt
1066
1067 #ifdef CONFIG_IRQ_WORK
1068 apicinterrupt IRQ_WORK_VECTOR \
1069         irq_work_interrupt smp_irq_work_interrupt
1070 #endif
1071
1072 /*
1073  * Exception entry points.
1074  */
1075 #define INIT_TSS_IST(x) PER_CPU_VAR(init_tss) + (TSS_ist + ((x) - 1) * 8)
1076
1077 .macro idtentry sym do_sym has_error_code:req paranoid=0 shift_ist=-1
1078 ENTRY(\sym)
1079         /* Sanity check */
1080         .if \shift_ist != -1 && \paranoid == 0
1081         .error "using shift_ist requires paranoid=1"
1082         .endif
1083
1084         .if \has_error_code
1085         XCPT_FRAME
1086         .else
1087         INTR_FRAME
1088         .endif
1089
1090         ASM_CLAC
1091         PARAVIRT_ADJUST_EXCEPTION_FRAME
1092
1093         .ifeq \has_error_code
1094         pushq_cfi $-1                   /* ORIG_RAX: no syscall to restart */
1095         .endif
1096
1097         subq $ORIG_RAX-R15, %rsp
1098         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1099
1100         .if \paranoid
1101         call save_paranoid
1102         .else
1103         call error_entry
1104         .endif
1105
1106         DEFAULT_FRAME 0
1107
1108         .if \paranoid
1109         .if \shift_ist != -1
1110         TRACE_IRQS_OFF_DEBUG            /* reload IDT in case of recursion */
1111         .else
1112         TRACE_IRQS_OFF
1113         .endif
1114         .endif
1115
1116         movq %rsp,%rdi                  /* pt_regs pointer */
1117
1118         .if \has_error_code
1119         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1120         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1121         .else
1122         xorl %esi,%esi                  /* no error code */
1123         .endif
1124
1125         .if \shift_ist != -1
1126         subq $EXCEPTION_STKSZ, INIT_TSS_IST(\shift_ist)
1127         .endif
1128
1129         call \do_sym
1130
1131         .if \shift_ist != -1
1132         addq $EXCEPTION_STKSZ, INIT_TSS_IST(\shift_ist)
1133         .endif
1134
1135         .if \paranoid
1136         jmp paranoid_exit               /* %ebx: no swapgs flag */
1137         .else
1138         jmp error_exit                  /* %ebx: no swapgs flag */
1139         .endif
1140
1141         CFI_ENDPROC
1142 END(\sym)
1143 .endm
1144
1145 #ifdef CONFIG_TRACING
1146 .macro trace_idtentry sym do_sym has_error_code:req
1147 idtentry trace(\sym) trace(\do_sym) has_error_code=\has_error_code
1148 idtentry \sym \do_sym has_error_code=\has_error_code
1149 .endm
1150 #else
1151 .macro trace_idtentry sym do_sym has_error_code:req
1152 idtentry \sym \do_sym has_error_code=\has_error_code
1153 .endm
1154 #endif
1155
1156 idtentry divide_error do_divide_error has_error_code=0
1157 idtentry overflow do_overflow has_error_code=0
1158 idtentry bounds do_bounds has_error_code=0
1159 idtentry invalid_op do_invalid_op has_error_code=0
1160 idtentry device_not_available do_device_not_available has_error_code=0
1161 idtentry double_fault __do_double_fault has_error_code=1 paranoid=1
1162 idtentry coprocessor_segment_overrun do_coprocessor_segment_overrun has_error_code=0
1163 idtentry invalid_TSS do_invalid_TSS has_error_code=1
1164 idtentry segment_not_present do_segment_not_present has_error_code=1
1165 idtentry spurious_interrupt_bug do_spurious_interrupt_bug has_error_code=0
1166 idtentry coprocessor_error do_coprocessor_error has_error_code=0
1167 idtentry alignment_check do_alignment_check has_error_code=1
1168 idtentry simd_coprocessor_error do_simd_coprocessor_error has_error_code=0
1169
1170
1171         /* Reload gs selector with exception handling */
1172         /* edi:  new selector */
1173 ENTRY(native_load_gs_index)
1174         CFI_STARTPROC
1175         pushfq_cfi
1176         DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
1177         SWAPGS
1178 gs_change:
1179         movl %edi,%gs
1180 2:      mfence          /* workaround */
1181         SWAPGS
1182         popfq_cfi
1183         ret
1184         CFI_ENDPROC
1185 END(native_load_gs_index)
1186
1187         _ASM_EXTABLE(gs_change,bad_gs)
1188         .section .fixup,"ax"
1189         /* running with kernelgs */
1190 bad_gs:
1191         SWAPGS                  /* switch back to user gs */
1192         xorl %eax,%eax
1193         movl %eax,%gs
1194         jmp  2b
1195         .previous
1196
1197 /* Call softirq on interrupt stack. Interrupts are off. */
1198 ENTRY(do_softirq_own_stack)
1199         CFI_STARTPROC
1200         pushq_cfi %rbp
1201         CFI_REL_OFFSET rbp,0
1202         mov  %rsp,%rbp
1203         CFI_DEF_CFA_REGISTER rbp
1204         incl PER_CPU_VAR(irq_count)
1205         cmove PER_CPU_VAR(irq_stack_ptr),%rsp
1206         push  %rbp                      # backlink for old unwinder
1207         call __do_softirq
1208         leaveq
1209         CFI_RESTORE             rbp
1210         CFI_DEF_CFA_REGISTER    rsp
1211         CFI_ADJUST_CFA_OFFSET   -8
1212         decl PER_CPU_VAR(irq_count)
1213         ret
1214         CFI_ENDPROC
1215 END(do_softirq_own_stack)
1216
1217 #ifdef CONFIG_XEN
1218 idtentry xen_hypervisor_callback xen_do_hypervisor_callback has_error_code=0
1219
1220 /*
1221  * A note on the "critical region" in our callback handler.
1222  * We want to avoid stacking callback handlers due to events occurring
1223  * during handling of the last event. To do this, we keep events disabled
1224  * until we've done all processing. HOWEVER, we must enable events before
1225  * popping the stack frame (can't be done atomically) and so it would still
1226  * be possible to get enough handler activations to overflow the stack.
1227  * Although unlikely, bugs of that kind are hard to track down, so we'd
1228  * like to avoid the possibility.
1229  * So, on entry to the handler we detect whether we interrupted an
1230  * existing activation in its critical region -- if so, we pop the current
1231  * activation and restart the handler using the previous one.
1232  */
1233 ENTRY(xen_do_hypervisor_callback)   # do_hypervisor_callback(struct *pt_regs)
1234         CFI_STARTPROC
1235 /*
1236  * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1237  * see the correct pointer to the pt_regs
1238  */
1239         movq %rdi, %rsp            # we don't return, adjust the stack frame
1240         CFI_ENDPROC
1241         DEFAULT_FRAME
1242 11:     incl PER_CPU_VAR(irq_count)
1243         movq %rsp,%rbp
1244         CFI_DEF_CFA_REGISTER rbp
1245         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
1246         pushq %rbp                      # backlink for old unwinder
1247         call xen_evtchn_do_upcall
1248         popq %rsp
1249         CFI_DEF_CFA_REGISTER rsp
1250         decl PER_CPU_VAR(irq_count)
1251         jmp  error_exit
1252         CFI_ENDPROC
1253 END(xen_do_hypervisor_callback)
1254
1255 /*
1256  * Hypervisor uses this for application faults while it executes.
1257  * We get here for two reasons:
1258  *  1. Fault while reloading DS, ES, FS or GS
1259  *  2. Fault while executing IRET
1260  * Category 1 we do not need to fix up as Xen has already reloaded all segment
1261  * registers that could be reloaded and zeroed the others.
1262  * Category 2 we fix up by killing the current process. We cannot use the
1263  * normal Linux return path in this case because if we use the IRET hypercall
1264  * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1265  * We distinguish between categories by comparing each saved segment register
1266  * with its current contents: any discrepancy means we in category 1.
1267  */
1268 ENTRY(xen_failsafe_callback)
1269         INTR_FRAME 1 (6*8)
1270         /*CFI_REL_OFFSET gs,GS*/
1271         /*CFI_REL_OFFSET fs,FS*/
1272         /*CFI_REL_OFFSET es,ES*/
1273         /*CFI_REL_OFFSET ds,DS*/
1274         CFI_REL_OFFSET r11,8
1275         CFI_REL_OFFSET rcx,0
1276         movw %ds,%cx
1277         cmpw %cx,0x10(%rsp)
1278         CFI_REMEMBER_STATE
1279         jne 1f
1280         movw %es,%cx
1281         cmpw %cx,0x18(%rsp)
1282         jne 1f
1283         movw %fs,%cx
1284         cmpw %cx,0x20(%rsp)
1285         jne 1f
1286         movw %gs,%cx
1287         cmpw %cx,0x28(%rsp)
1288         jne 1f
1289         /* All segments match their saved values => Category 2 (Bad IRET). */
1290         movq (%rsp),%rcx
1291         CFI_RESTORE rcx
1292         movq 8(%rsp),%r11
1293         CFI_RESTORE r11
1294         addq $0x30,%rsp
1295         CFI_ADJUST_CFA_OFFSET -0x30
1296         pushq_cfi $0    /* RIP */
1297         pushq_cfi %r11
1298         pushq_cfi %rcx
1299         jmp general_protection
1300         CFI_RESTORE_STATE
1301 1:      /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1302         movq (%rsp),%rcx
1303         CFI_RESTORE rcx
1304         movq 8(%rsp),%r11
1305         CFI_RESTORE r11
1306         addq $0x30,%rsp
1307         CFI_ADJUST_CFA_OFFSET -0x30
1308         pushq_cfi $-1 /* orig_ax = -1 => not a system call */
1309         SAVE_ALL
1310         jmp error_exit
1311         CFI_ENDPROC
1312 END(xen_failsafe_callback)
1313
1314 apicinterrupt3 HYPERVISOR_CALLBACK_VECTOR \
1315         xen_hvm_callback_vector xen_evtchn_do_upcall
1316
1317 #endif /* CONFIG_XEN */
1318
1319 #if IS_ENABLED(CONFIG_HYPERV)
1320 apicinterrupt3 HYPERVISOR_CALLBACK_VECTOR \
1321         hyperv_callback_vector hyperv_vector_handler
1322 #endif /* CONFIG_HYPERV */
1323
1324 /*
1325  * Some functions should be protected against kprobes
1326  */
1327         .pushsection .kprobes.text, "ax"
1328
1329 idtentry debug do_debug has_error_code=0 paranoid=1 shift_ist=DEBUG_STACK
1330 idtentry int3 do_int3 has_error_code=0 paranoid=1 shift_ist=DEBUG_STACK
1331 idtentry stack_segment do_stack_segment has_error_code=1 paranoid=1
1332 #ifdef CONFIG_XEN
1333 idtentry xen_debug do_debug has_error_code=0
1334 idtentry xen_int3 do_int3 has_error_code=0
1335 idtentry xen_stack_segment do_stack_segment has_error_code=1
1336 #endif
1337 idtentry general_protection do_general_protection has_error_code=1
1338 trace_idtentry page_fault do_page_fault has_error_code=1
1339 #ifdef CONFIG_KVM_GUEST
1340 idtentry async_page_fault do_async_page_fault has_error_code=1
1341 #endif
1342 #ifdef CONFIG_X86_MCE
1343 idtentry machine_check has_error_code=0 paranoid=1 do_sym=*machine_check_vector(%rip)
1344 #endif
1345
1346         /*
1347          * "Paranoid" exit path from exception stack.
1348          * Paranoid because this is used by NMIs and cannot take
1349          * any kernel state for granted.
1350          * We don't do kernel preemption checks here, because only
1351          * NMI should be common and it does not enable IRQs and
1352          * cannot get reschedule ticks.
1353          *
1354          * "trace" is 0 for the NMI handler only, because irq-tracing
1355          * is fundamentally NMI-unsafe. (we cannot change the soft and
1356          * hard flags at once, atomically)
1357          */
1358
1359         /* ebx: no swapgs flag */
1360 ENTRY(paranoid_exit)
1361         DEFAULT_FRAME
1362         DISABLE_INTERRUPTS(CLBR_NONE)
1363         TRACE_IRQS_OFF_DEBUG
1364         testl %ebx,%ebx                         /* swapgs needed? */
1365         jnz paranoid_restore
1366         testl $3,CS(%rsp)
1367         jnz   paranoid_userspace
1368 paranoid_swapgs:
1369         TRACE_IRQS_IRETQ 0
1370         SWAPGS_UNSAFE_STACK
1371         RESTORE_ALL 8
1372         jmp irq_return
1373 paranoid_restore:
1374         TRACE_IRQS_IRETQ_DEBUG 0
1375         RESTORE_ALL 8
1376         jmp irq_return
1377 paranoid_userspace:
1378         GET_THREAD_INFO(%rcx)
1379         movl TI_flags(%rcx),%ebx
1380         andl $_TIF_WORK_MASK,%ebx
1381         jz paranoid_swapgs
1382         movq %rsp,%rdi                  /* &pt_regs */
1383         call sync_regs
1384         movq %rax,%rsp                  /* switch stack for scheduling */
1385         testl $_TIF_NEED_RESCHED,%ebx
1386         jnz paranoid_schedule
1387         movl %ebx,%edx                  /* arg3: thread flags */
1388         TRACE_IRQS_ON
1389         ENABLE_INTERRUPTS(CLBR_NONE)
1390         xorl %esi,%esi                  /* arg2: oldset */
1391         movq %rsp,%rdi                  /* arg1: &pt_regs */
1392         call do_notify_resume
1393         DISABLE_INTERRUPTS(CLBR_NONE)
1394         TRACE_IRQS_OFF
1395         jmp paranoid_userspace
1396 paranoid_schedule:
1397         TRACE_IRQS_ON
1398         ENABLE_INTERRUPTS(CLBR_ANY)
1399         SCHEDULE_USER
1400         DISABLE_INTERRUPTS(CLBR_ANY)
1401         TRACE_IRQS_OFF
1402         jmp paranoid_userspace
1403         CFI_ENDPROC
1404 END(paranoid_exit)
1405
1406 /*
1407  * Exception entry point. This expects an error code/orig_rax on the stack.
1408  * returns in "no swapgs flag" in %ebx.
1409  */
1410 ENTRY(error_entry)
1411         XCPT_FRAME
1412         CFI_ADJUST_CFA_OFFSET 15*8
1413         /* oldrax contains error code */
1414         cld
1415         movq_cfi rdi, RDI+8
1416         movq_cfi rsi, RSI+8
1417         movq_cfi rdx, RDX+8
1418         movq_cfi rcx, RCX+8
1419         movq_cfi rax, RAX+8
1420         movq_cfi  r8,  R8+8
1421         movq_cfi  r9,  R9+8
1422         movq_cfi r10, R10+8
1423         movq_cfi r11, R11+8
1424         movq_cfi rbx, RBX+8
1425         movq_cfi rbp, RBP+8
1426         movq_cfi r12, R12+8
1427         movq_cfi r13, R13+8
1428         movq_cfi r14, R14+8
1429         movq_cfi r15, R15+8
1430         xorl %ebx,%ebx
1431         testl $3,CS+8(%rsp)
1432         je error_kernelspace
1433 error_swapgs:
1434         SWAPGS
1435 error_sti:
1436         TRACE_IRQS_OFF
1437         ret
1438
1439 /*
1440  * There are two places in the kernel that can potentially fault with
1441  * usergs. Handle them here. The exception handlers after iret run with
1442  * kernel gs again, so don't set the user space flag. B stepping K8s
1443  * sometimes report an truncated RIP for IRET exceptions returning to
1444  * compat mode. Check for these here too.
1445  */
1446 error_kernelspace:
1447         incl %ebx
1448         leaq irq_return_iret(%rip),%rcx
1449         cmpq %rcx,RIP+8(%rsp)
1450         je error_swapgs
1451         movl %ecx,%eax  /* zero extend */
1452         cmpq %rax,RIP+8(%rsp)
1453         je bstep_iret
1454         cmpq $gs_change,RIP+8(%rsp)
1455         je error_swapgs
1456         jmp error_sti
1457
1458 bstep_iret:
1459         /* Fix truncated RIP */
1460         movq %rcx,RIP+8(%rsp)
1461         jmp error_swapgs
1462         CFI_ENDPROC
1463 END(error_entry)
1464
1465
1466 /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1467 ENTRY(error_exit)
1468         DEFAULT_FRAME
1469         movl %ebx,%eax
1470         RESTORE_REST
1471         DISABLE_INTERRUPTS(CLBR_NONE)
1472         TRACE_IRQS_OFF
1473         GET_THREAD_INFO(%rcx)
1474         testl %eax,%eax
1475         jne retint_kernel
1476         LOCKDEP_SYS_EXIT_IRQ
1477         movl TI_flags(%rcx),%edx
1478         movl $_TIF_WORK_MASK,%edi
1479         andl %edi,%edx
1480         jnz retint_careful
1481         jmp retint_swapgs
1482         CFI_ENDPROC
1483 END(error_exit)
1484
1485 /*
1486  * Test if a given stack is an NMI stack or not.
1487  */
1488         .macro test_in_nmi reg stack nmi_ret normal_ret
1489         cmpq %\reg, \stack
1490         ja \normal_ret
1491         subq $EXCEPTION_STKSZ, %\reg
1492         cmpq %\reg, \stack
1493         jb \normal_ret
1494         jmp \nmi_ret
1495         .endm
1496
1497         /* runs on exception stack */
1498 ENTRY(nmi)
1499         INTR_FRAME
1500         PARAVIRT_ADJUST_EXCEPTION_FRAME
1501         /*
1502          * We allow breakpoints in NMIs. If a breakpoint occurs, then
1503          * the iretq it performs will take us out of NMI context.
1504          * This means that we can have nested NMIs where the next
1505          * NMI is using the top of the stack of the previous NMI. We
1506          * can't let it execute because the nested NMI will corrupt the
1507          * stack of the previous NMI. NMI handlers are not re-entrant
1508          * anyway.
1509          *
1510          * To handle this case we do the following:
1511          *  Check the a special location on the stack that contains
1512          *  a variable that is set when NMIs are executing.
1513          *  The interrupted task's stack is also checked to see if it
1514          *  is an NMI stack.
1515          *  If the variable is not set and the stack is not the NMI
1516          *  stack then:
1517          *    o Set the special variable on the stack
1518          *    o Copy the interrupt frame into a "saved" location on the stack
1519          *    o Copy the interrupt frame into a "copy" location on the stack
1520          *    o Continue processing the NMI
1521          *  If the variable is set or the previous stack is the NMI stack:
1522          *    o Modify the "copy" location to jump to the repeate_nmi
1523          *    o return back to the first NMI
1524          *
1525          * Now on exit of the first NMI, we first clear the stack variable
1526          * The NMI stack will tell any nested NMIs at that point that it is
1527          * nested. Then we pop the stack normally with iret, and if there was
1528          * a nested NMI that updated the copy interrupt stack frame, a
1529          * jump will be made to the repeat_nmi code that will handle the second
1530          * NMI.
1531          */
1532
1533         /* Use %rdx as out temp variable throughout */
1534         pushq_cfi %rdx
1535         CFI_REL_OFFSET rdx, 0
1536
1537         /*
1538          * If %cs was not the kernel segment, then the NMI triggered in user
1539          * space, which means it is definitely not nested.
1540          */
1541         cmpl $__KERNEL_CS, 16(%rsp)
1542         jne first_nmi
1543
1544         /*
1545          * Check the special variable on the stack to see if NMIs are
1546          * executing.
1547          */
1548         cmpl $1, -8(%rsp)
1549         je nested_nmi
1550
1551         /*
1552          * Now test if the previous stack was an NMI stack.
1553          * We need the double check. We check the NMI stack to satisfy the
1554          * race when the first NMI clears the variable before returning.
1555          * We check the variable because the first NMI could be in a
1556          * breakpoint routine using a breakpoint stack.
1557          */
1558         lea 6*8(%rsp), %rdx
1559         test_in_nmi rdx, 4*8(%rsp), nested_nmi, first_nmi
1560         CFI_REMEMBER_STATE
1561
1562 nested_nmi:
1563         /*
1564          * Do nothing if we interrupted the fixup in repeat_nmi.
1565          * It's about to repeat the NMI handler, so we are fine
1566          * with ignoring this one.
1567          */
1568         movq $repeat_nmi, %rdx
1569         cmpq 8(%rsp), %rdx
1570         ja 1f
1571         movq $end_repeat_nmi, %rdx
1572         cmpq 8(%rsp), %rdx
1573         ja nested_nmi_out
1574
1575 1:
1576         /* Set up the interrupted NMIs stack to jump to repeat_nmi */
1577         leaq -1*8(%rsp), %rdx
1578         movq %rdx, %rsp
1579         CFI_ADJUST_CFA_OFFSET 1*8
1580         leaq -10*8(%rsp), %rdx
1581         pushq_cfi $__KERNEL_DS
1582         pushq_cfi %rdx
1583         pushfq_cfi
1584         pushq_cfi $__KERNEL_CS
1585         pushq_cfi $repeat_nmi
1586
1587         /* Put stack back */
1588         addq $(6*8), %rsp
1589         CFI_ADJUST_CFA_OFFSET -6*8
1590
1591 nested_nmi_out:
1592         popq_cfi %rdx
1593         CFI_RESTORE rdx
1594
1595         /* No need to check faults here */
1596         INTERRUPT_RETURN
1597
1598         CFI_RESTORE_STATE
1599 first_nmi:
1600         /*
1601          * Because nested NMIs will use the pushed location that we
1602          * stored in rdx, we must keep that space available.
1603          * Here's what our stack frame will look like:
1604          * +-------------------------+
1605          * | original SS             |
1606          * | original Return RSP     |
1607          * | original RFLAGS         |
1608          * | original CS             |
1609          * | original RIP            |
1610          * +-------------------------+
1611          * | temp storage for rdx    |
1612          * +-------------------------+
1613          * | NMI executing variable  |
1614          * +-------------------------+
1615          * | copied SS               |
1616          * | copied Return RSP       |
1617          * | copied RFLAGS           |
1618          * | copied CS               |
1619          * | copied RIP              |
1620          * +-------------------------+
1621          * | Saved SS                |
1622          * | Saved Return RSP        |
1623          * | Saved RFLAGS            |
1624          * | Saved CS                |
1625          * | Saved RIP               |
1626          * +-------------------------+
1627          * | pt_regs                 |
1628          * +-------------------------+
1629          *
1630          * The saved stack frame is used to fix up the copied stack frame
1631          * that a nested NMI may change to make the interrupted NMI iret jump
1632          * to the repeat_nmi. The original stack frame and the temp storage
1633          * is also used by nested NMIs and can not be trusted on exit.
1634          */
1635         /* Do not pop rdx, nested NMIs will corrupt that part of the stack */
1636         movq (%rsp), %rdx
1637         CFI_RESTORE rdx
1638
1639         /* Set the NMI executing variable on the stack. */
1640         pushq_cfi $1
1641
1642         /*
1643          * Leave room for the "copied" frame
1644          */
1645         subq $(5*8), %rsp
1646         CFI_ADJUST_CFA_OFFSET 5*8
1647
1648         /* Copy the stack frame to the Saved frame */
1649         .rept 5
1650         pushq_cfi 11*8(%rsp)
1651         .endr
1652         CFI_DEF_CFA_OFFSET SS+8-RIP
1653
1654         /* Everything up to here is safe from nested NMIs */
1655
1656         /*
1657          * If there was a nested NMI, the first NMI's iret will return
1658          * here. But NMIs are still enabled and we can take another
1659          * nested NMI. The nested NMI checks the interrupted RIP to see
1660          * if it is between repeat_nmi and end_repeat_nmi, and if so
1661          * it will just return, as we are about to repeat an NMI anyway.
1662          * This makes it safe to copy to the stack frame that a nested
1663          * NMI will update.
1664          */
1665 repeat_nmi:
1666         /*
1667          * Update the stack variable to say we are still in NMI (the update
1668          * is benign for the non-repeat case, where 1 was pushed just above
1669          * to this very stack slot).
1670          */
1671         movq $1, 10*8(%rsp)
1672
1673         /* Make another copy, this one may be modified by nested NMIs */
1674         addq $(10*8), %rsp
1675         CFI_ADJUST_CFA_OFFSET -10*8
1676         .rept 5
1677         pushq_cfi -6*8(%rsp)
1678         .endr
1679         subq $(5*8), %rsp
1680         CFI_DEF_CFA_OFFSET SS+8-RIP
1681 end_repeat_nmi:
1682
1683         /*
1684          * Everything below this point can be preempted by a nested
1685          * NMI if the first NMI took an exception and reset our iret stack
1686          * so that we repeat another NMI.
1687          */
1688         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1689         subq $ORIG_RAX-R15, %rsp
1690         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1691         /*
1692          * Use save_paranoid to handle SWAPGS, but no need to use paranoid_exit
1693          * as we should not be calling schedule in NMI context.
1694          * Even with normal interrupts enabled. An NMI should not be
1695          * setting NEED_RESCHED or anything that normal interrupts and
1696          * exceptions might do.
1697          */
1698         call save_paranoid
1699         DEFAULT_FRAME 0
1700
1701         /*
1702          * Save off the CR2 register. If we take a page fault in the NMI then
1703          * it could corrupt the CR2 value. If the NMI preempts a page fault
1704          * handler before it was able to read the CR2 register, and then the
1705          * NMI itself takes a page fault, the page fault that was preempted
1706          * will read the information from the NMI page fault and not the
1707          * origin fault. Save it off and restore it if it changes.
1708          * Use the r12 callee-saved register.
1709          */
1710         movq %cr2, %r12
1711
1712         /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1713         movq %rsp,%rdi
1714         movq $-1,%rsi
1715         call do_nmi
1716
1717         /* Did the NMI take a page fault? Restore cr2 if it did */
1718         movq %cr2, %rcx
1719         cmpq %rcx, %r12
1720         je 1f
1721         movq %r12, %cr2
1722 1:
1723
1724         testl %ebx,%ebx                         /* swapgs needed? */
1725         jnz nmi_restore
1726 nmi_swapgs:
1727         SWAPGS_UNSAFE_STACK
1728 nmi_restore:
1729         /* Pop the extra iret frame at once */
1730         RESTORE_ALL 6*8
1731
1732         /* Clear the NMI executing stack variable */
1733         movq $0, 5*8(%rsp)
1734         jmp irq_return
1735         CFI_ENDPROC
1736 END(nmi)
1737
1738 ENTRY(ignore_sysret)
1739         CFI_STARTPROC
1740         mov $-ENOSYS,%eax
1741         sysret
1742         CFI_ENDPROC
1743 END(ignore_sysret)
1744
1745 /*
1746  * End of kprobes section
1747  */
1748         .popsection