arch/sh/kernel/vsyscall/vsyscall.lds.S

   1 /*
   2  * Linker script for vsyscall DSO.  The vsyscall page is an ELF shared
   3  * object prelinked to its virtual address, and with only one read-only
   4  * segment (that fits in one page).  This script controls its layout.
   5  */
   6 #include <asm/asm-offsets.h>
   7
   8 #ifdef CONFIG_CPU_LITTLE_ENDIAN
   9 OUTPUT_FORMAT("elf32-sh-linux", "elf32-sh-linux", "elf32-sh-linux")
  10 #else
  11 OUTPUT_FORMAT("elf32-shbig-linux", "elf32-shbig-linux", "elf32-shbig-linux")
  12 #endif
  13 OUTPUT_ARCH(sh)
  14
  15 /* The ELF entry point can be used to set the AT_SYSINFO value.  */
  16 ENTRY(__kernel_vsyscall);
  17
  18 SECTIONS
  19 {
  20   . = SIZEOF_HEADERS;
  21
  22   .hash           : { *(.hash) }                :text
  23   .gnu.hash       : { *(.gnu.hash) }
  24   .dynsym         : { *(.dynsym) }
  25   .dynstr         : { *(.dynstr) }
  26   .gnu.version    : { *(.gnu.version) }
  27   .gnu.version_d  : { *(.gnu.version_d) }
  28   .gnu.version_r  : { *(.gnu.version_r) }
  29
  30   /* This linker script is used both with -r and with -shared.
  31      For the layouts to match, we need to skip more than enough
  32      space for the dynamic symbol table et al.  If this amount
  33      is insufficient, ld -shared will barf.  Just increase it here.  */
  34   . = 0x400;
  35
  36   .text           : { *(.text) }                :text =0x90909090
  37   .note           : { *(.note.*) }              :text :note
  38   .eh_frame_hdr   : { *(.eh_frame_hdr) }        :text :eh_frame_hdr
  39   .eh_frame       : { KEEP (*(.eh_frame)) }     :text
  40   .dynamic        : { *(.dynamic) }             :text :dynamic
  41   .useless        : {
  42         *(.got.plt) *(.got)
  43         *(.data .data.* .gnu.linkonce.d.*)
  44         *(.dynbss)
  45         *(.bss .bss.* .gnu.linkonce.b.*)
  46   }                                             :text
  47 }
  48
  49 /*
  50  * We must supply the ELF program headers explicitly to get just one
  51  * PT_LOAD segment, and set the flags explicitly to make segments read-only.
  52  */
  53 PHDRS
  54 {
  55   text PT_LOAD FILEHDR PHDRS FLAGS(5); /* PF_R|PF_X */
  56   dynamic PT_DYNAMIC FLAGS(4); /* PF_R */
  57   note PT_NOTE FLAGS(4); /* PF_R */
  58   eh_frame_hdr 0x6474e550; /* PT_GNU_EH_FRAME, but ld doesn't match the name */
  59 }
  60
  61 /*
  62  * This controls what symbols we export from the DSO.
  63  */
  64 VERSION
  65 {
  66   LINUX_2.6 {
  67     global:
  68         __kernel_vsyscall;
  69         __kernel_sigreturn;
  70         __kernel_rt_sigreturn;
  71
  72     local: *;
  73   };
  74 }