arch/s390/kernel/vmlinux.lds.S

   1 /* ld script to make s390 Linux kernel
   2  * Written by Martin Schwidefsky (schwidefsky@de.ibm.com)
   3  */
   4
   5 #include <asm/thread_info.h>
   6 #include <asm/page.h>
   7
   8 /*
   9  * Put .bss..swapper_pg_dir as the first thing in .bss. This will
  10  * make sure it has 16k alignment.
  11  */
  12 #define BSS_FIRST_SECTIONS *(.bss..swapper_pg_dir)
  13
  14 /* Handle ro_after_init data on our own. */
  15 #define RO_AFTER_INIT_DATA
  16
  17 #include <asm-generic/vmlinux.lds.h>
  18
  19 OUTPUT_FORMAT("elf64-s390", "elf64-s390", "elf64-s390")
  20 OUTPUT_ARCH(s390:64-bit)
  21 ENTRY(startup)
  22 jiffies = jiffies_64;
  23
  24 PHDRS {
  25         text PT_LOAD FLAGS(5);  /* R_E */
  26         data PT_LOAD FLAGS(7);  /* RWE */
  27         note PT_NOTE FLAGS(0);  /* ___ */
  28 }
  29
  30 SECTIONS
  31 {
  32         . = 0x00000000;
  33         .text : {
  34         _text = .;              /* Text and read-only data */
  35                 HEAD_TEXT
  36                 TEXT_TEXT
  37                 SCHED_TEXT
  38                 CPUIDLE_TEXT
  39                 LOCK_TEXT
  40                 KPROBES_TEXT
  41                 IRQENTRY_TEXT
  42                 SOFTIRQENTRY_TEXT
  43                 *(.fixup)
  44                 *(.gnu.warning)
  45         } :text = 0x0700
  46
  47         . = ALIGN(PAGE_SIZE);
  48         _etext = .;             /* End of text section */
  49
  50         NOTES :text :note
  51
  52         .dummy : { *(.dummy) } :data
  53
  54         RO_DATA_SECTION(PAGE_SIZE)
  55
  56 #ifdef CONFIG_SHARED_KERNEL
  57         . = ALIGN(0x100000);    /* VM shared segments are 1MB aligned */
  58 #endif
  59
  60         . = ALIGN(PAGE_SIZE);
  61         _eshared = .;           /* End of shareable data */
  62         _sdata = .;             /* Start of data section */
  63
  64         . = ALIGN(PAGE_SIZE);
  65         __start_ro_after_init = .;
  66         .data..ro_after_init : {
  67                  *(.data..ro_after_init)
  68         }
  69         EXCEPTION_TABLE(16)
  70         . = ALIGN(PAGE_SIZE);
  71         __end_ro_after_init = .;
  72
  73         RW_DATA_SECTION(0x100, PAGE_SIZE, THREAD_SIZE)
  74
  75         _edata = .;             /* End of data section */
  76
  77         /* will be freed after init */
  78         . = ALIGN(PAGE_SIZE);   /* Init code and data */
  79         __init_begin = .;
  80
  81         . = ALIGN(PAGE_SIZE);
  82         .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {
  83                 VMLINUX_SYMBOL(_sinittext) = . ;
  84                 INIT_TEXT
  85                 . = ALIGN(PAGE_SIZE);
  86                 VMLINUX_SYMBOL(_einittext) = . ;
  87         }
  88
  89         /*
  90          * .exit.text is discarded at runtime, not link time,
  91          * to deal with references from __bug_table
  92         */
  93         .exit.text : {
  94                 EXIT_TEXT
  95         }
  96
  97         .exit.data : {
  98                 EXIT_DATA
  99         }
 100
 101         /* early.c uses stsi, which requires page aligned data. */
 102         . = ALIGN(PAGE_SIZE);
 103         INIT_DATA_SECTION(0x100)
 104
 105         PERCPU_SECTION(0x100)
 106         . = ALIGN(PAGE_SIZE);
 107         __init_end = .;         /* freed after init ends here */
 108
 109         BSS_SECTION(PAGE_SIZE, 4 * PAGE_SIZE, PAGE_SIZE)
 110
 111         _end = . ;
 112
 113         /* Debugging sections.  */
 114         STABS_DEBUG
 115         DWARF_DEBUG
 116
 117         /* Sections to be discarded */
 118         DISCARDS
 119 }