arch/s390/kernel/vdso64/clock_gettime.S

   1 /* SPDX-License-Identifier: GPL-2.0 */
   2 /*
   3  * Userland implementation of clock_gettime() for 64 bits processes in a
   4  * s390 kernel for use in the vDSO
   5  *
   6  *  Copyright IBM Corp. 2008
   7  *  Author(s): Martin Schwidefsky (schwidefsky@de.ibm.com)
   8  */
   9 #include <asm/vdso.h>
  10 #include <asm/asm-offsets.h>
  11 #include <asm/unistd.h>
  12
  13         .text
  14         .align 4
  15         .globl __kernel_clock_gettime
  16         .type  __kernel_clock_gettime,@function
  17 __kernel_clock_gettime:
  18         .cfi_startproc
  19         aghi    %r15,-16
  20         larl    %r5,_vdso_data
  21         cghi    %r2,__CLOCK_REALTIME_COARSE
  22         je      4f
  23         cghi    %r2,__CLOCK_REALTIME
  24         je      5f
  25         cghi    %r2,-3          /* Per-thread CPUCLOCK with PID=0, VIRT=1 */
  26         je      9f
  27         cghi    %r2,__CLOCK_MONOTONIC_COARSE
  28         je      3f
  29         cghi    %r2,__CLOCK_MONOTONIC
  30         jne     12f
  31
  32         /* CLOCK_MONOTONIC */
  33 0:      lg      %r4,__VDSO_UPD_COUNT(%r5)       /* load update counter */
  34         tmll    %r4,0x0001                      /* pending update ? loop */
  35         jnz     0b
  36         stcke   0(%r15)                         /* Store TOD clock */
  37         lgf     %r2,__VDSO_TK_SHIFT(%r5)        /* Timekeeper shift */
  38         lg      %r0,__VDSO_WTOM_SEC(%r5)
  39         lg      %r1,1(%r15)
  40         sg      %r1,__VDSO_XTIME_STAMP(%r5)     /* TOD - cycle_last */
  41         msgf    %r1,__VDSO_TK_MULT(%r5)         /*  * tk->mult */
  42         alg     %r1,__VDSO_WTOM_NSEC(%r5)
  43         srlg    %r1,%r1,0(%r2)                  /*  >> tk->shift */
  44         clg     %r4,__VDSO_UPD_COUNT(%r5)       /* check update counter */
  45         jne     0b
  46         larl    %r5,13f
  47 1:      clg     %r1,0(%r5)
  48         jl      2f
  49         slg     %r1,0(%r5)
  50         aghi    %r0,1
  51         j       1b
  52 2:      stg     %r0,0(%r3)                      /* store tp->tv_sec */
  53         stg     %r1,8(%r3)                      /* store tp->tv_nsec */
  54         lghi    %r2,0
  55         aghi    %r15,16
  56         br      %r14
  57
  58         /* CLOCK_MONOTONIC_COARSE */
  59 3:      lg      %r4,__VDSO_UPD_COUNT(%r5)       /* load update counter */
  60         tmll    %r4,0x0001                      /* pending update ? loop */
  61         jnz     3b
  62         lg      %r0,__VDSO_WTOM_CRS_SEC(%r5)
  63         lg      %r1,__VDSO_WTOM_CRS_NSEC(%r5)
  64         clg     %r4,__VDSO_UPD_COUNT(%r5)       /* check update counter */
  65         jne     3b
  66         j       2b
  67
  68         /* CLOCK_REALTIME_COARSE */
  69 4:      lg      %r4,__VDSO_UPD_COUNT(%r5)       /* load update counter */
  70         tmll    %r4,0x0001                      /* pending update ? loop */
  71         jnz     4b
  72         lg      %r0,__VDSO_XTIME_CRS_SEC(%r5)
  73         lg      %r1,__VDSO_XTIME_CRS_NSEC(%r5)
  74         clg     %r4,__VDSO_UPD_COUNT(%r5)       /* check update counter */
  75         jne     4b
  76         j       7f
  77
  78         /* CLOCK_REALTIME */
  79 5:      lg      %r4,__VDSO_UPD_COUNT(%r5)       /* load update counter */
  80         tmll    %r4,0x0001                      /* pending update ? loop */
  81         jnz     5b
  82         stcke   0(%r15)                         /* Store TOD clock */
  83         lg      %r1,1(%r15)
  84         lg      %r0,__VDSO_TS_END(%r5)          /* TOD steering end time */
  85         slgr    %r0,%r1                         /* now - ts_steering_end */
  86         ltgr    %r0,%r0                         /* past end of steering ? */
  87         jm      17f
  88         srlg    %r0,%r0,15                      /* 1 per 2^16 */
  89         tm      __VDSO_TS_DIR+3(%r5),0x01       /* steering direction? */
  90         jz      18f
  91         lcgr    %r0,%r0                         /* negative TOD offset */
  92 18:     algr    %r1,%r0                         /* add steering offset */
  93 17:     lgf     %r2,__VDSO_TK_SHIFT(%r5)        /* Timekeeper shift */
  94         sg      %r1,__VDSO_XTIME_STAMP(%r5)     /* TOD - cycle_last */
  95         msgf    %r1,__VDSO_TK_MULT(%r5)         /*  * tk->mult */
  96         alg     %r1,__VDSO_XTIME_NSEC(%r5)      /*  + tk->xtime_nsec */
  97         srlg    %r1,%r1,0(%r2)                  /*  >> tk->shift */
  98         lg      %r0,__VDSO_XTIME_SEC(%r5)       /* tk->xtime_sec */
  99         clg     %r4,__VDSO_UPD_COUNT(%r5)       /* check update counter */
 100         jne     5b
 101         larl    %r5,13f
 102 6:      clg     %r1,0(%r5)
 103         jl      7f
 104         slg     %r1,0(%r5)
 105         aghi    %r0,1
 106         j       6b
 107 7:      stg     %r0,0(%r3)                      /* store tp->tv_sec */
 108         stg     %r1,8(%r3)                      /* store tp->tv_nsec */
 109         lghi    %r2,0
 110         aghi    %r15,16
 111         br      %r14
 112
 113         /* CPUCLOCK_VIRT for this thread */
 114 9:      lghi    %r4,0
 115         icm     %r0,15,__VDSO_ECTG_OK(%r5)
 116         jz      12f
 117         sacf    256                             /* Magic ectg instruction */
 118         .insn   ssf,0xc80100000000,__VDSO_ECTG_BASE(4),__VDSO_ECTG_USER(4),4
 119         sacf    0
 120         algr    %r1,%r0                         /* r1 = cputime as TOD value */
 121         mghi    %r1,1000                        /* convert to nanoseconds */
 122         srlg    %r1,%r1,12                      /* r1 = cputime in nanosec */
 123         lgr     %r4,%r1
 124         larl    %r5,13f
 125         srlg    %r1,%r1,9                       /* divide by 1000000000 */
 126         mlg     %r0,8(%r5)
 127         srlg    %r0,%r0,11                      /* r0 = tv_sec */
 128         stg     %r0,0(%r3)
 129         msg     %r0,0(%r5)                      /* calculate tv_nsec */
 130         slgr    %r4,%r0                         /* r4 = tv_nsec */
 131         stg     %r4,8(%r3)
 132         lghi    %r2,0
 133         aghi    %r15,16
 134         br      %r14
 135
 136         /* Fallback to system call */
 137 12:     lghi    %r1,__NR_clock_gettime
 138         svc     0
 139         aghi    %r15,16
 140         br      %r14
 141
 142 13:     .quad   1000000000
 143 14:     .quad   19342813113834067
 144         .cfi_endproc
 145         .size   __kernel_clock_gettime,.-__kernel_clock_gettime