arch/s390/kernel/entry64.S

   1 /*
   2  *  arch/s390/kernel/entry64.S
   3  *    S390 low-level entry points.
   4  *
   5  *    Copyright (C) IBM Corp. 1999,2006
   6  *    Author(s): Martin Schwidefsky (schwidefsky@de.ibm.com),
   7  *               Hartmut Penner (hp@de.ibm.com),
   8  *               Denis Joseph Barrow (djbarrow@de.ibm.com,barrow_dj@yahoo.com),
   9  *               Heiko Carstens <heiko.carstens@de.ibm.com>
  10  */
  11
  12 #include <linux/sys.h>
  13 #include <linux/linkage.h>
  14 #include <asm/cache.h>
  15 #include <asm/lowcore.h>
  16 #include <asm/errno.h>
  17 #include <asm/ptrace.h>
  18 #include <asm/thread_info.h>
  19 #include <asm/asm-offsets.h>
  20 #include <asm/unistd.h>
  21 #include <asm/page.h>
  22
  23 /*
  24  * Stack layout for the system_call stack entry.
  25  * The first few entries are identical to the user_regs_struct.
  26  */
  27 SP_PTREGS    =  STACK_FRAME_OVERHEAD
  28 SP_ARGS      =  STACK_FRAME_OVERHEAD + __PT_ARGS
  29 SP_PSW       =  STACK_FRAME_OVERHEAD + __PT_PSW
  30 SP_R0        =  STACK_FRAME_OVERHEAD + __PT_GPRS
  31 SP_R1        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 8
  32 SP_R2        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 16
  33 SP_R3        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 24
  34 SP_R4        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 32
  35 SP_R5        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 40
  36 SP_R6        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 48
  37 SP_R7        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 56
  38 SP_R8        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 64
  39 SP_R9        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 72
  40 SP_R10       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 80
  41 SP_R11       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 88
  42 SP_R12       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 96
  43 SP_R13       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 104
  44 SP_R14       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 112
  45 SP_R15       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 120
  46 SP_ORIG_R2   =  STACK_FRAME_OVERHEAD + __PT_ORIG_GPR2
  47 SP_ILC       =  STACK_FRAME_OVERHEAD + __PT_ILC
  48 SP_TRAP      =  STACK_FRAME_OVERHEAD + __PT_TRAP
  49 SP_SIZE      =  STACK_FRAME_OVERHEAD + __PT_SIZE
  50
  51 STACK_SHIFT = PAGE_SHIFT + THREAD_ORDER
  52 STACK_SIZE  = 1 << STACK_SHIFT
  53
  54 _TIF_WORK_SVC = (_TIF_SIGPENDING | _TIF_RESTORE_SIGMASK | _TIF_NEED_RESCHED | \
  55                  _TIF_MCCK_PENDING | _TIF_RESTART_SVC | _TIF_SINGLE_STEP )
  56 _TIF_WORK_INT = (_TIF_SIGPENDING | _TIF_RESTORE_SIGMASK | _TIF_NEED_RESCHED | \
  57                  _TIF_MCCK_PENDING)
  58
  59 #define BASED(name) name-system_call(%r13)
  60
  61 #ifdef CONFIG_TRACE_IRQFLAGS
  62         .macro  TRACE_IRQS_ON
  63          brasl  %r14,trace_hardirqs_on
  64         .endm
  65
  66         .macro  TRACE_IRQS_OFF
  67          brasl  %r14,trace_hardirqs_off
  68         .endm
  69 #else
  70 #define TRACE_IRQS_ON
  71 #define TRACE_IRQS_OFF
  72 #endif
  73
  74         .macro  STORE_TIMER lc_offset
  75 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
  76         stpt    \lc_offset
  77 #endif
  78         .endm
  79
  80 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
  81         .macro  UPDATE_VTIME lc_from,lc_to,lc_sum
  82         lg      %r10,\lc_from
  83         slg     %r10,\lc_to
  84         alg     %r10,\lc_sum
  85         stg     %r10,\lc_sum
  86         .endm
  87 #endif
  88
  89 /*
  90  * Register usage in interrupt handlers:
  91  *    R9  - pointer to current task structure
  92  *    R13 - pointer to literal pool
  93  *    R14 - return register for function calls
  94  *    R15 - kernel stack pointer
  95  */
  96
  97         .macro  SAVE_ALL_BASE savearea
  98         stmg    %r12,%r15,\savearea
  99         larl    %r13,system_call
 100         .endm
 101
 102         .macro  SAVE_ALL_SVC psworg,savearea
 103         la      %r12,\psworg
 104         lg      %r15,__LC_KERNEL_STACK  # problem state -> load ksp
 105         .endm
 106
 107         .macro  SAVE_ALL_SYNC psworg,savearea
 108         la      %r12,\psworg
 109         tm      \psworg+1,0x01          # test problem state bit
 110         jz      2f                      # skip stack setup save
 111         lg      %r15,__LC_KERNEL_STACK  # problem state -> load ksp
 112 #ifdef CONFIG_CHECK_STACK
 113         j       3f
 114 2:      tml     %r15,STACK_SIZE - CONFIG_STACK_GUARD
 115         jz      stack_overflow
 116 3:
 117 #endif
 118 2:
 119         .endm
 120
 121         .macro  SAVE_ALL_ASYNC psworg,savearea
 122         la      %r12,\psworg
 123         tm      \psworg+1,0x01          # test problem state bit
 124         jnz     1f                      # from user -> load kernel stack
 125         clc     \psworg+8(8),BASED(.Lcritical_end)
 126         jhe     0f
 127         clc     \psworg+8(8),BASED(.Lcritical_start)
 128         jl      0f
 129         brasl   %r14,cleanup_critical
 130         tm      1(%r12),0x01            # retest problem state after cleanup
 131         jnz     1f
 132 0:      lg      %r14,__LC_ASYNC_STACK   # are we already on the async. stack ?
 133         slgr    %r14,%r15
 134         srag    %r14,%r14,STACK_SHIFT
 135         jz      2f
 136 1:      lg      %r15,__LC_ASYNC_STACK   # load async stack
 137 #ifdef CONFIG_CHECK_STACK
 138         j       3f
 139 2:      tml     %r15,STACK_SIZE - CONFIG_STACK_GUARD
 140         jz      stack_overflow
 141 3:
 142 #endif
 143 2:
 144         .endm
 145
 146         .macro  CREATE_STACK_FRAME psworg,savearea
 147         aghi    %r15,-SP_SIZE           # make room for registers & psw
 148         mvc     SP_PSW(16,%r15),0(%r12) # move user PSW to stack
 149         la      %r12,\psworg
 150         stg     %r2,SP_ORIG_R2(%r15)    # store original content of gpr 2
 151         icm     %r12,12,__LC_SVC_ILC
 152         stmg    %r0,%r11,SP_R0(%r15)    # store gprs %r0-%r11 to kernel stack
 153         st      %r12,SP_ILC(%r15)
 154         mvc     SP_R12(32,%r15),\savearea # move %r12-%r15 to stack
 155         la      %r12,0
 156         stg     %r12,__SF_BACKCHAIN(%r15)
 157         .endm
 158
 159         .macro  RESTORE_ALL psworg,sync
 160         mvc     \psworg(16),SP_PSW(%r15) # move user PSW to lowcore
 161         .if !\sync
 162         ni      \psworg+1,0xfd          # clear wait state bit
 163         .endif
 164         lmg     %r0,%r15,SP_R0(%r15)    # load gprs 0-15 of user
 165         STORE_TIMER __LC_EXIT_TIMER
 166         lpswe   \psworg                 # back to caller
 167         .endm
 168
 169 /*
 170  * Scheduler resume function, called by switch_to
 171  *  gpr2 = (task_struct *) prev
 172  *  gpr3 = (task_struct *) next
 173  * Returns:
 174  *  gpr2 = prev
 175  */
 176         .globl  __switch_to
 177 __switch_to:
 178         tm      __THREAD_per+4(%r3),0xe8 # is the new process using per ?
 179         jz      __switch_to_noper               # if not we're fine
 180         stctg   %c9,%c11,__SF_EMPTY(%r15)# We are using per stuff
 181         clc     __THREAD_per(24,%r3),__SF_EMPTY(%r15)
 182         je      __switch_to_noper            # we got away without bashing TLB's
 183         lctlg   %c9,%c11,__THREAD_per(%r3)      # Nope we didn't
 184 __switch_to_noper:
 185         lg      %r4,__THREAD_info(%r2)              # get thread_info of prev
 186         tm      __TI_flags+7(%r4),_TIF_MCCK_PENDING # machine check pending?
 187         jz      __switch_to_no_mcck
 188         ni      __TI_flags+7(%r4),255-_TIF_MCCK_PENDING # clear flag in prev
 189         lg      %r4,__THREAD_info(%r3)              # get thread_info of next
 190         oi      __TI_flags+7(%r4),_TIF_MCCK_PENDING # set it in next
 191 __switch_to_no_mcck:
 192         stmg    %r6,%r15,__SF_GPRS(%r15)# store __switch_to registers of prev task
 193         stg     %r15,__THREAD_ksp(%r2)  # store kernel stack to prev->tss.ksp
 194         lg      %r15,__THREAD_ksp(%r3)  # load kernel stack from next->tss.ksp
 195         lmg     %r6,%r15,__SF_GPRS(%r15)# load __switch_to registers of next task
 196         stg     %r3,__LC_CURRENT        # __LC_CURRENT = current task struct
 197         lctl    %c4,%c4,__TASK_pid(%r3) # load pid to control reg. 4
 198         lg      %r3,__THREAD_info(%r3)  # load thread_info from task struct
 199         stg     %r3,__LC_THREAD_INFO
 200         aghi    %r3,STACK_SIZE
 201         stg     %r3,__LC_KERNEL_STACK   # __LC_KERNEL_STACK = new kernel stack
 202         br      %r14
 203
 204 __critical_start:
 205 /*
 206  * SVC interrupt handler routine. System calls are synchronous events and
 207  * are executed with interrupts enabled.
 208  */
 209
 210         .globl  system_call
 211 system_call:
 212         STORE_TIMER __LC_SYNC_ENTER_TIMER
 213 sysc_saveall:
 214         SAVE_ALL_BASE __LC_SAVE_AREA
 215         SAVE_ALL_SVC __LC_SVC_OLD_PSW,__LC_SAVE_AREA
 216         CREATE_STACK_FRAME __LC_SVC_OLD_PSW,__LC_SAVE_AREA
 217         llgh    %r7,__LC_SVC_INT_CODE   # get svc number from lowcore
 218 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 219 sysc_vtime:
 220         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 221         jz      sysc_do_svc
 222         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 223 sysc_stime:
 224         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 225 sysc_update:
 226         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 227 #endif
 228 sysc_do_svc:
 229         lg      %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 230         slag    %r7,%r7,2       # *4 and test for svc 0
 231         jnz     sysc_nr_ok
 232         # svc 0: system call number in %r1
 233         cl      %r1,BASED(.Lnr_syscalls)
 234         jnl     sysc_nr_ok
 235         lgfr    %r7,%r1         # clear high word in r1
 236         slag    %r7,%r7,2       # svc 0: system call number in %r1
 237 sysc_nr_ok:
 238         mvc     SP_ARGS(8,%r15),SP_R7(%r15)
 239 sysc_do_restart:
 240         larl    %r10,sys_call_table
 241 #ifdef CONFIG_COMPAT
 242         tm      __TI_flags+5(%r9),(_TIF_31BIT>>16)  # running in 31 bit mode ?
 243         jno     sysc_noemu
 244         larl    %r10,sys_call_table_emu  # use 31 bit emulation system calls
 245 sysc_noemu:
 246 #endif
 247         tm      __TI_flags+7(%r9),(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT)
 248         lgf     %r8,0(%r7,%r10) # load address of system call routine
 249         jnz     sysc_tracesys
 250         basr    %r14,%r8        # call sys_xxxx
 251         stg     %r2,SP_R2(%r15) # store return value (change R2 on stack)
 252
 253 sysc_return:
 254         tm      SP_PSW+1(%r15),0x01     # returning to user ?
 255         jno     sysc_leave
 256         tm      __TI_flags+7(%r9),_TIF_WORK_SVC
 257         jnz     sysc_work       # there is work to do (signals etc.)
 258 sysc_leave:
 259         RESTORE_ALL __LC_RETURN_PSW,1
 260
 261 #
 262 # recheck if there is more work to do
 263 #
 264 sysc_work_loop:
 265         tm      __TI_flags+7(%r9),_TIF_WORK_SVC
 266         jz      sysc_leave        # there is no work to do
 267 #
 268 # One of the work bits is on. Find out which one.
 269 #
 270 sysc_work:
 271         tm      __TI_flags+7(%r9),_TIF_MCCK_PENDING
 272         jo      sysc_mcck_pending
 273         tm      __TI_flags+7(%r9),_TIF_NEED_RESCHED
 274         jo      sysc_reschedule
 275         tm      __TI_flags+7(%r9),(_TIF_SIGPENDING | _TIF_RESTORE_SIGMASK)
 276         jnz     sysc_sigpending
 277         tm      __TI_flags+7(%r9),_TIF_RESTART_SVC
 278         jo      sysc_restart
 279         tm      __TI_flags+7(%r9),_TIF_SINGLE_STEP
 280         jo      sysc_singlestep
 281         j       sysc_leave
 282
 283 #
 284 # _TIF_NEED_RESCHED is set, call schedule
 285 #
 286 sysc_reschedule:
 287         larl    %r14,sysc_work_loop
 288         jg      schedule        # return point is sysc_return
 289
 290 #
 291 # _TIF_MCCK_PENDING is set, call handler
 292 #
 293 sysc_mcck_pending:
 294         larl    %r14,sysc_work_loop
 295         jg      s390_handle_mcck        # TIF bit will be cleared by handler
 296
 297 #
 298 # _TIF_SIGPENDING or _TIF_RESTORE_SIGMASK is set, call do_signal
 299 #
 300 sysc_sigpending:
 301         ni      __TI_flags+7(%r9),255-_TIF_SINGLE_STEP # clear TIF_SINGLE_STEP
 302         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 303         brasl   %r14,do_signal          # call do_signal
 304         tm      __TI_flags+7(%r9),_TIF_RESTART_SVC
 305         jo      sysc_restart
 306         tm      __TI_flags+7(%r9),_TIF_SINGLE_STEP
 307         jo      sysc_singlestep
 308         j       sysc_work_loop
 309
 310 #
 311 # _TIF_RESTART_SVC is set, set up registers and restart svc
 312 #
 313 sysc_restart:
 314         ni      __TI_flags+7(%r9),255-_TIF_RESTART_SVC # clear TIF_RESTART_SVC
 315         lg      %r7,SP_R2(%r15)         # load new svc number
 316         slag    %r7,%r7,2               # *4
 317         mvc     SP_R2(8,%r15),SP_ORIG_R2(%r15) # restore first argument
 318         lmg     %r2,%r6,SP_R2(%r15)     # load svc arguments
 319         j       sysc_do_restart         # restart svc
 320
 321 #
 322 # _TIF_SINGLE_STEP is set, call do_single_step
 323 #
 324 sysc_singlestep:
 325         ni      __TI_flags+7(%r9),255-_TIF_SINGLE_STEP # clear TIF_SINGLE_STEP
 326         lhi     %r0,__LC_PGM_OLD_PSW
 327         sth     %r0,SP_TRAP(%r15)       # set trap indication to pgm check
 328         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 329         larl    %r14,sysc_return        # load adr. of system return
 330         jg      do_single_step          # branch to do_sigtrap
 331
 332 #
 333 # call syscall_trace before and after system call
 334 # special linkage: %r12 contains the return address for trace_svc
 335 #
 336 sysc_tracesys:
 337         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 338         la      %r3,0
 339         srl     %r7,2
 340         stg     %r7,SP_R2(%r15)
 341         brasl   %r14,syscall_trace
 342         lghi    %r0,NR_syscalls
 343         clg     %r0,SP_R2(%r15)
 344         jnh     sysc_tracenogo
 345         lg      %r7,SP_R2(%r15)         # strace might have changed the
 346         sll     %r7,2                   # system call
 347         lgf     %r8,0(%r7,%r10)
 348 sysc_tracego:
 349         lmg     %r3,%r6,SP_R3(%r15)
 350         lg      %r2,SP_ORIG_R2(%r15)
 351         basr    %r14,%r8                # call sys_xxx
 352         stg     %r2,SP_R2(%r15)         # store return value
 353 sysc_tracenogo:
 354         tm      __TI_flags+7(%r9),(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT)
 355         jz      sysc_return
 356         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 357         la      %r3,1
 358         larl    %r14,sysc_return        # return point is sysc_return
 359         jg      syscall_trace
 360
 361 #
 362 # a new process exits the kernel with ret_from_fork
 363 #
 364         .globl  ret_from_fork
 365 ret_from_fork:
 366         lg      %r13,__LC_SVC_NEW_PSW+8
 367         lg      %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 368         tm      SP_PSW+1(%r15),0x01     # forking a kernel thread ?
 369         jo      0f
 370         stg     %r15,SP_R15(%r15)       # store stack pointer for new kthread
 371 0:      brasl   %r14,schedule_tail
 372         TRACE_IRQS_ON
 373         stosm   24(%r15),0x03           # reenable interrupts
 374         j       sysc_return
 375
 376 #
 377 # kernel_execve function needs to deal with pt_regs that is not
 378 # at the usual place
 379 #
 380         .globl  kernel_execve
 381 kernel_execve:
 382         stmg    %r12,%r15,96(%r15)
 383         lgr     %r14,%r15
 384         aghi    %r15,-SP_SIZE
 385         stg     %r14,__SF_BACKCHAIN(%r15)
 386         la      %r12,SP_PTREGS(%r15)
 387         xc      0(__PT_SIZE,%r12),0(%r12)
 388         lgr     %r5,%r12
 389         brasl   %r14,do_execve
 390         ltgfr   %r2,%r2
 391         je      0f
 392         aghi    %r15,SP_SIZE
 393         lmg     %r12,%r15,96(%r15)
 394         br      %r14
 395         # execve succeeded.
 396 0:      stnsm   __SF_EMPTY(%r15),0xfc   # disable interrupts
 397         lg      %r15,__LC_KERNEL_STACK  # load ksp
 398         aghi    %r15,-SP_SIZE           # make room for registers & psw
 399         lg      %r13,__LC_SVC_NEW_PSW+8
 400         lg      %r9,__LC_THREAD_INFO
 401         mvc     SP_PTREGS(__PT_SIZE,%r15),0(%r12)       # copy pt_regs
 402         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
 403         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 404         brasl   %r14,execve_tail
 405         j       sysc_return
 406
 407 /*
 408  * Program check handler routine
 409  */
 410
 411         .globl  pgm_check_handler
 412 pgm_check_handler:
 413 /*
 414  * First we need to check for a special case:
 415  * Single stepping an instruction that disables the PER event mask will
 416  * cause a PER event AFTER the mask has been set. Example: SVC or LPSW.
 417  * For a single stepped SVC the program check handler gets control after
 418  * the SVC new PSW has been loaded. But we want to execute the SVC first and
 419  * then handle the PER event. Therefore we update the SVC old PSW to point
 420  * to the pgm_check_handler and branch to the SVC handler after we checked
 421  * if we have to load the kernel stack register.
 422  * For every other possible cause for PER event without the PER mask set
 423  * we just ignore the PER event (FIXME: is there anything we have to do
 424  * for LPSW?).
 425  */
 426         STORE_TIMER __LC_SYNC_ENTER_TIMER
 427         SAVE_ALL_BASE __LC_SAVE_AREA
 428         tm      __LC_PGM_INT_CODE+1,0x80 # check whether we got a per exception
 429         jnz     pgm_per                  # got per exception -> special case
 430         SAVE_ALL_SYNC __LC_PGM_OLD_PSW,__LC_SAVE_AREA
 431         CREATE_STACK_FRAME __LC_PGM_OLD_PSW,__LC_SAVE_AREA
 432 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 433         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 434         jz      pgm_no_vtime
 435         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 436         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 437         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 438 pgm_no_vtime:
 439 #endif
 440         lg      %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 441         lgf     %r3,__LC_PGM_ILC        # load program interruption code
 442         lghi    %r8,0x7f
 443         ngr     %r8,%r3
 444 pgm_do_call:
 445         sll     %r8,3
 446         larl    %r1,pgm_check_table
 447         lg      %r1,0(%r8,%r1)          # load address of handler routine
 448         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 449         larl    %r14,sysc_return
 450         br      %r1                     # branch to interrupt-handler
 451
 452 #
 453 # handle per exception
 454 #
 455 pgm_per:
 456         tm      __LC_PGM_OLD_PSW,0x40   # test if per event recording is on
 457         jnz     pgm_per_std             # ok, normal per event from user space
 458 # ok its one of the special cases, now we need to find out which one
 459         clc     __LC_PGM_OLD_PSW(16),__LC_SVC_NEW_PSW
 460         je      pgm_svcper
 461 # no interesting special case, ignore PER event
 462         lmg     %r12,%r15,__LC_SAVE_AREA
 463         lpswe   __LC_PGM_OLD_PSW
 464
 465 #
 466 # Normal per exception
 467 #
 468 pgm_per_std:
 469         SAVE_ALL_SYNC __LC_PGM_OLD_PSW,__LC_SAVE_AREA
 470         CREATE_STACK_FRAME __LC_PGM_OLD_PSW,__LC_SAVE_AREA
 471 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 472         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 473         jz      pgm_no_vtime2
 474         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 475         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 476         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 477 pgm_no_vtime2:
 478 #endif
 479         lg      %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 480         lg      %r1,__TI_task(%r9)
 481         tm      SP_PSW+1(%r15),0x01     # kernel per event ?
 482         jz      kernel_per
 483         mvc     __THREAD_per+__PER_atmid(2,%r1),__LC_PER_ATMID
 484         mvc     __THREAD_per+__PER_address(8,%r1),__LC_PER_ADDRESS
 485         mvc     __THREAD_per+__PER_access_id(1,%r1),__LC_PER_ACCESS_ID
 486         oi      __TI_flags+7(%r9),_TIF_SINGLE_STEP # set TIF_SINGLE_STEP
 487         lgf     %r3,__LC_PGM_ILC        # load program interruption code
 488         lghi    %r8,0x7f
 489         ngr     %r8,%r3                 # clear per-event-bit and ilc
 490         je      sysc_return
 491         j       pgm_do_call
 492
 493 #
 494 # it was a single stepped SVC that is causing all the trouble
 495 #
 496 pgm_svcper:
 497         SAVE_ALL_SYNC __LC_SVC_OLD_PSW,__LC_SAVE_AREA
 498         CREATE_STACK_FRAME __LC_SVC_OLD_PSW,__LC_SAVE_AREA
 499 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 500         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 501         jz      pgm_no_vtime3
 502         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 503         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 504         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 505 pgm_no_vtime3:
 506 #endif
 507         llgh    %r7,__LC_SVC_INT_CODE   # get svc number from lowcore
 508         lg      %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 509         lg      %r1,__TI_task(%r9)
 510         mvc     __THREAD_per+__PER_atmid(2,%r1),__LC_PER_ATMID
 511         mvc     __THREAD_per+__PER_address(8,%r1),__LC_PER_ADDRESS
 512         mvc     __THREAD_per+__PER_access_id(1,%r1),__LC_PER_ACCESS_ID
 513         oi      __TI_flags+7(%r9),_TIF_SINGLE_STEP # set TIF_SINGLE_STEP
 514         TRACE_IRQS_ON
 515         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 516         j       sysc_do_svc
 517
 518 #
 519 # per was called from kernel, must be kprobes
 520 #
 521 kernel_per:
 522         lhi     %r0,__LC_PGM_OLD_PSW
 523         sth     %r0,SP_TRAP(%r15)       # set trap indication to pgm check
 524         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 525         larl    %r14,sysc_leave         # load adr. of system ret, no work
 526         jg      do_single_step          # branch to do_single_step
 527
 528 /*
 529  * IO interrupt handler routine
 530  */
 531         .globl io_int_handler
 532 io_int_handler:
 533         STORE_TIMER __LC_ASYNC_ENTER_TIMER
 534         stck    __LC_INT_CLOCK
 535         SAVE_ALL_BASE __LC_SAVE_AREA+32
 536         SAVE_ALL_ASYNC __LC_IO_OLD_PSW,__LC_SAVE_AREA+32
 537         CREATE_STACK_FRAME __LC_IO_OLD_PSW,__LC_SAVE_AREA+32
 538 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 539         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 540         jz      io_no_vtime
 541         UPDATE_VTIME __LC_EXIT_TIMER,__LC_ASYNC_ENTER_TIMER,__LC_USER_TIMER
 542         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 543         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_ASYNC_ENTER_TIMER
 544 io_no_vtime:
 545 #endif
 546         lg      %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 547         TRACE_IRQS_OFF
 548         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 549         brasl   %r14,do_IRQ             # call standard irq handler
 550         TRACE_IRQS_ON
 551
 552 io_return:
 553         tm      SP_PSW+1(%r15),0x01     # returning to user ?
 554 #ifdef CONFIG_PREEMPT
 555         jno     io_preempt              # no -> check for preemptive scheduling
 556 #else
 557         jno     io_leave                # no-> skip resched & signal
 558 #endif
 559         tm      __TI_flags+7(%r9),_TIF_WORK_INT
 560         jnz     io_work                 # there is work to do (signals etc.)
 561 io_leave:
 562         RESTORE_ALL __LC_RETURN_PSW,0
 563 io_done:
 564
 565 #ifdef CONFIG_PREEMPT
 566 io_preempt:
 567         icm     %r0,15,__TI_precount(%r9)
 568         jnz     io_leave
 569         # switch to kernel stack
 570         lg      %r1,SP_R15(%r15)
 571         aghi    %r1,-SP_SIZE
 572         mvc     SP_PTREGS(__PT_SIZE,%r1),SP_PTREGS(%r15)
 573         xc      __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1) # clear back chain
 574         lgr     %r15,%r1
 575 io_resume_loop:
 576         tm      __TI_flags+7(%r9),_TIF_NEED_RESCHED
 577         jno     io_leave
 578         larl    %r1,.Lc_pactive
 579         mvc     __TI_precount(4,%r9),0(%r1)
 580         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 581         brasl   %r14,schedule           # call schedule
 582         stnsm   __SF_EMPTY(%r15),0xfc   # disable I/O and ext. interrupts
 583         xc      __TI_precount(4,%r9),__TI_precount(%r9)
 584         j       io_resume_loop
 585 #endif
 586
 587 #
 588 # switch to kernel stack, then check TIF bits
 589 #
 590 io_work:
 591         lg      %r1,__LC_KERNEL_STACK
 592         aghi    %r1,-SP_SIZE
 593         mvc     SP_PTREGS(__PT_SIZE,%r1),SP_PTREGS(%r15)
 594         xc      __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1) # clear back chain
 595         lgr     %r15,%r1
 596 #
 597 # One of the work bits is on. Find out which one.
 598 # Checked are: _TIF_SIGPENDING, _TIF_RESTORE_SIGPENDING, _TIF_NEED_RESCHED
 599 #              and _TIF_MCCK_PENDING
 600 #
 601 io_work_loop:
 602         tm      __TI_flags+7(%r9),_TIF_MCCK_PENDING
 603         jo      io_mcck_pending
 604         tm      __TI_flags+7(%r9),_TIF_NEED_RESCHED
 605         jo      io_reschedule
 606         tm      __TI_flags+7(%r9),(_TIF_SIGPENDING | _TIF_RESTORE_SIGMASK)
 607         jnz     io_sigpending
 608         j       io_leave
 609
 610 #
 611 # _TIF_MCCK_PENDING is set, call handler
 612 #
 613 io_mcck_pending:
 614         larl    %r14,io_work_loop
 615         jg      s390_handle_mcck        # TIF bit will be cleared by handler
 616
 617 #
 618 # _TIF_NEED_RESCHED is set, call schedule
 619 #
 620 io_reschedule:
 621         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 622         brasl   %r14,schedule           # call scheduler
 623         stnsm   __SF_EMPTY(%r15),0xfc   # disable I/O and ext. interrupts
 624         tm      __TI_flags+7(%r9),_TIF_WORK_INT
 625         jz      io_leave                # there is no work to do
 626         j       io_work_loop
 627
 628 #
 629 # _TIF_SIGPENDING or _TIF_RESTORE_SIGMASK is set, call do_signal
 630 #
 631 io_sigpending:
 632         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 633         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 634         brasl   %r14,do_signal          # call do_signal
 635         stnsm   __SF_EMPTY(%r15),0xfc   # disable I/O and ext. interrupts
 636         j       io_work_loop
 637
 638 /*
 639  * External interrupt handler routine
 640  */
 641         .globl  ext_int_handler
 642 ext_int_handler:
 643         STORE_TIMER __LC_ASYNC_ENTER_TIMER
 644         stck    __LC_INT_CLOCK
 645         SAVE_ALL_BASE __LC_SAVE_AREA+32
 646         SAVE_ALL_ASYNC __LC_EXT_OLD_PSW,__LC_SAVE_AREA+32
 647         CREATE_STACK_FRAME __LC_EXT_OLD_PSW,__LC_SAVE_AREA+32
 648 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 649         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 650         jz      ext_no_vtime
 651         UPDATE_VTIME __LC_EXIT_TIMER,__LC_ASYNC_ENTER_TIMER,__LC_USER_TIMER
 652         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 653         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_ASYNC_ENTER_TIMER
 654 ext_no_vtime:
 655 #endif
 656         lg      %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 657         TRACE_IRQS_OFF
 658         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 659         llgh    %r3,__LC_EXT_INT_CODE   # get interruption code
 660         brasl   %r14,do_extint
 661         TRACE_IRQS_ON
 662         j       io_return
 663
 664 __critical_end:
 665
 666 /*
 667  * Machine check handler routines
 668  */
 669         .globl mcck_int_handler
 670 mcck_int_handler:
 671         la      %r1,4095                # revalidate r1
 672         spt     __LC_CPU_TIMER_SAVE_AREA-4095(%r1)      # revalidate cpu timer
 673         lmg     %r0,%r15,__LC_GPREGS_SAVE_AREA-4095(%r1)# revalidate gprs
 674         SAVE_ALL_BASE __LC_SAVE_AREA+64
 675         la      %r12,__LC_MCK_OLD_PSW
 676         tm      __LC_MCCK_CODE,0x80     # system damage?
 677         jo      mcck_int_main           # yes -> rest of mcck code invalid
 678 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 679         la      %r14,4095
 680         mvc     __LC_SAVE_AREA+104(8),__LC_ASYNC_ENTER_TIMER
 681         mvc     __LC_ASYNC_ENTER_TIMER(8),__LC_CPU_TIMER_SAVE_AREA-4095(%r14)
 682         tm      __LC_MCCK_CODE+5,0x02   # stored cpu timer value valid?
 683         jo      1f
 684         la      %r14,__LC_SYNC_ENTER_TIMER
 685         clc     0(8,%r14),__LC_ASYNC_ENTER_TIMER
 686         jl      0f
 687         la      %r14,__LC_ASYNC_ENTER_TIMER
 688 0:      clc     0(8,%r14),__LC_EXIT_TIMER
 689         jl      0f
 690         la      %r14,__LC_EXIT_TIMER
 691 0:      clc     0(8,%r14),__LC_LAST_UPDATE_TIMER
 692         jl      0f
 693         la      %r14,__LC_LAST_UPDATE_TIMER
 694 0:      spt     0(%r14)
 695         mvc     __LC_ASYNC_ENTER_TIMER(8),0(%r14)
 696 1:
 697 #endif
 698         tm      __LC_MCCK_CODE+2,0x09   # mwp + ia of old psw valid?
 699         jno     mcck_int_main           # no -> skip cleanup critical
 700         tm      __LC_MCK_OLD_PSW+1,0x01 # test problem state bit
 701         jnz     mcck_int_main           # from user -> load kernel stack
 702         clc     __LC_MCK_OLD_PSW+8(8),BASED(.Lcritical_end)
 703         jhe     mcck_int_main
 704         clc     __LC_MCK_OLD_PSW+8(8),BASED(.Lcritical_start)
 705         jl      mcck_int_main
 706         brasl   %r14,cleanup_critical
 707 mcck_int_main:
 708         lg      %r14,__LC_PANIC_STACK   # are we already on the panic stack?
 709         slgr    %r14,%r15
 710         srag    %r14,%r14,PAGE_SHIFT
 711         jz      0f
 712         lg      %r15,__LC_PANIC_STACK   # load panic stack
 713 0:      CREATE_STACK_FRAME __LC_MCK_OLD_PSW,__LC_SAVE_AREA+64
 714 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 715         tm      __LC_MCCK_CODE+2,0x08   # mwp of old psw valid?
 716         jno     mcck_no_vtime           # no -> no timer update
 717         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 718         jz      mcck_no_vtime
 719         UPDATE_VTIME __LC_EXIT_TIMER,__LC_ASYNC_ENTER_TIMER,__LC_USER_TIMER
 720         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 721         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_ASYNC_ENTER_TIMER
 722 mcck_no_vtime:
 723 #endif
 724         lg      %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 725         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 726         brasl   %r14,s390_do_machine_check
 727         tm      SP_PSW+1(%r15),0x01     # returning to user ?
 728         jno     mcck_return
 729         lg      %r1,__LC_KERNEL_STACK   # switch to kernel stack
 730         aghi    %r1,-SP_SIZE
 731         mvc     SP_PTREGS(__PT_SIZE,%r1),SP_PTREGS(%r15)
 732         xc      __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1) # clear back chain
 733         lgr     %r15,%r1
 734         stosm   __SF_EMPTY(%r15),0x04   # turn dat on
 735         tm      __TI_flags+7(%r9),_TIF_MCCK_PENDING
 736         jno     mcck_return
 737         TRACE_IRQS_OFF
 738         brasl   %r14,s390_handle_mcck
 739         TRACE_IRQS_ON
 740 mcck_return:
 741         mvc     __LC_RETURN_MCCK_PSW(16),SP_PSW(%r15) # move return PSW
 742         ni      __LC_RETURN_MCCK_PSW+1,0xfd # clear wait state bit
 743         lmg     %r0,%r15,SP_R0(%r15)    # load gprs 0-15
 744 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 745         mvc     __LC_ASYNC_ENTER_TIMER(8),__LC_SAVE_AREA+104
 746         tm      __LC_RETURN_MCCK_PSW+1,0x01 # returning to user ?
 747         jno     0f
 748         stpt    __LC_EXIT_TIMER
 749 0:
 750 #endif
 751         lpswe   __LC_RETURN_MCCK_PSW    # back to caller
 752
 753 /*
 754  * Restart interruption handler, kick starter for additional CPUs
 755  */
 756 #ifdef CONFIG_SMP
 757 #ifndef CONFIG_HOTPLUG_CPU
 758         .section .init.text,"ax"
 759 #endif
 760         .globl restart_int_handler
 761 restart_int_handler:
 762         lg      %r15,__LC_SAVE_AREA+120 # load ksp
 763         lghi    %r10,__LC_CREGS_SAVE_AREA
 764         lctlg   %c0,%c15,0(%r10) # get new ctl regs
 765         lghi    %r10,__LC_AREGS_SAVE_AREA
 766         lam     %a0,%a15,0(%r10)
 767         lmg     %r6,%r15,__SF_GPRS(%r15) # load registers from clone
 768         stosm   __SF_EMPTY(%r15),0x04   # now we can turn dat on
 769         jg      start_secondary
 770 #ifndef CONFIG_HOTPLUG_CPU
 771         .previous
 772 #endif
 773 #else
 774 /*
 775  * If we do not run with SMP enabled, let the new CPU crash ...
 776  */
 777         .globl restart_int_handler
 778 restart_int_handler:
 779         basr    %r1,0
 780 restart_base:
 781         lpswe   restart_crash-restart_base(%r1)
 782         .align 8
 783 restart_crash:
 784         .long  0x000a0000,0x00000000,0x00000000,0x00000000
 785 restart_go:
 786 #endif
 787
 788 #ifdef CONFIG_CHECK_STACK
 789 /*
 790  * The synchronous or the asynchronous stack overflowed. We are dead.
 791  * No need to properly save the registers, we are going to panic anyway.
 792  * Setup a pt_regs so that show_trace can provide a good call trace.
 793  */
 794 stack_overflow:
 795         lg      %r15,__LC_PANIC_STACK   # change to panic stack
 796         aghi    %r15,-SP_SIZE
 797         mvc     SP_PSW(16,%r15),0(%r12) # move user PSW to stack
 798         stmg    %r0,%r11,SP_R0(%r15)    # store gprs %r0-%r11 to kernel stack
 799         la      %r1,__LC_SAVE_AREA
 800         chi     %r12,__LC_SVC_OLD_PSW
 801         je      0f
 802         chi     %r12,__LC_PGM_OLD_PSW
 803         je      0f
 804         la      %r1,__LC_SAVE_AREA+32
 805 0:      mvc     SP_R12(32,%r15),0(%r1)  # move %r12-%r15 to stack
 806         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15) # clear back chain
 807         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 808         jg      kernel_stack_overflow
 809 #endif
 810
 811 cleanup_table_system_call:
 812         .quad   system_call, sysc_do_svc
 813 cleanup_table_sysc_return:
 814         .quad   sysc_return, sysc_leave
 815 cleanup_table_sysc_leave:
 816         .quad   sysc_leave, sysc_work_loop
 817 cleanup_table_sysc_work_loop:
 818         .quad   sysc_work_loop, sysc_reschedule
 819 cleanup_table_io_return:
 820         .quad   io_return, io_leave
 821 cleanup_table_io_leave:
 822         .quad   io_leave, io_done
 823 cleanup_table_io_work_loop:
 824         .quad   io_work_loop, io_mcck_pending
 825
 826 cleanup_critical:
 827         clc     8(8,%r12),BASED(cleanup_table_system_call)
 828         jl      0f
 829         clc     8(8,%r12),BASED(cleanup_table_system_call+8)
 830         jl      cleanup_system_call
 831 0:
 832         clc     8(8,%r12),BASED(cleanup_table_sysc_return)
 833         jl      0f
 834         clc     8(8,%r12),BASED(cleanup_table_sysc_return+8)
 835         jl      cleanup_sysc_return
 836 0:
 837         clc     8(8,%r12),BASED(cleanup_table_sysc_leave)
 838         jl      0f
 839         clc     8(8,%r12),BASED(cleanup_table_sysc_leave+8)
 840         jl      cleanup_sysc_leave
 841 0:
 842         clc     8(8,%r12),BASED(cleanup_table_sysc_work_loop)
 843         jl      0f
 844         clc     8(8,%r12),BASED(cleanup_table_sysc_work_loop+8)
 845         jl      cleanup_sysc_return
 846 0:
 847         clc     8(8,%r12),BASED(cleanup_table_io_return)
 848         jl      0f
 849         clc     8(8,%r12),BASED(cleanup_table_io_return+8)
 850         jl      cleanup_io_return
 851 0:
 852         clc     8(8,%r12),BASED(cleanup_table_io_leave)
 853         jl      0f
 854         clc     8(8,%r12),BASED(cleanup_table_io_leave+8)
 855         jl      cleanup_io_leave
 856 0:
 857         clc     8(8,%r12),BASED(cleanup_table_io_work_loop)
 858         jl      0f
 859         clc     8(8,%r12),BASED(cleanup_table_io_work_loop+8)
 860         jl      cleanup_io_return
 861 0:
 862         br      %r14
 863
 864 cleanup_system_call:
 865         mvc     __LC_RETURN_PSW(16),0(%r12)
 866         cghi    %r12,__LC_MCK_OLD_PSW
 867         je      0f
 868         la      %r12,__LC_SAVE_AREA+32
 869         j       1f
 870 0:      la      %r12,__LC_SAVE_AREA+64
 871 1:
 872 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 873         clc     __LC_RETURN_PSW+8(8),BASED(cleanup_system_call_insn+8)
 874         jh      0f
 875         mvc     __LC_SYNC_ENTER_TIMER(8),__LC_ASYNC_ENTER_TIMER
 876 0:      clc     __LC_RETURN_PSW+8(8),BASED(cleanup_system_call_insn+16)
 877         jhe     cleanup_vtime
 878 #endif
 879         clc     __LC_RETURN_PSW+8(8),BASED(cleanup_system_call_insn)
 880         jh      0f
 881         mvc     __LC_SAVE_AREA(32),0(%r12)
 882 0:      stg     %r13,8(%r12)
 883         stg     %r12,__LC_SAVE_AREA+96  # argh
 884         SAVE_ALL_SYNC __LC_SVC_OLD_PSW,__LC_SAVE_AREA
 885         CREATE_STACK_FRAME __LC_SVC_OLD_PSW,__LC_SAVE_AREA
 886         lg      %r12,__LC_SAVE_AREA+96  # argh
 887         stg     %r15,24(%r12)
 888         llgh    %r7,__LC_SVC_INT_CODE
 889 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 890 cleanup_vtime:
 891         clc     __LC_RETURN_PSW+8(8),BASED(cleanup_system_call_insn+24)
 892         jhe     cleanup_stime
 893         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 894         jz      cleanup_novtime
 895         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 896 cleanup_stime:
 897         clc     __LC_RETURN_PSW+8(8),BASED(cleanup_system_call_insn+32)
 898         jh      cleanup_update
 899         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 900 cleanup_update:
 901         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 902 cleanup_novtime:
 903 #endif
 904         mvc     __LC_RETURN_PSW+8(8),BASED(cleanup_table_system_call+8)
 905         la      %r12,__LC_RETURN_PSW
 906         br      %r14
 907 cleanup_system_call_insn:
 908         .quad   sysc_saveall
 909 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 910         .quad   system_call
 911         .quad   sysc_vtime
 912         .quad   sysc_stime
 913         .quad   sysc_update
 914 #endif
 915
 916 cleanup_sysc_return:
 917         mvc     __LC_RETURN_PSW(8),0(%r12)
 918         mvc     __LC_RETURN_PSW+8(8),BASED(cleanup_table_sysc_return)
 919         la      %r12,__LC_RETURN_PSW
 920         br      %r14
 921
 922 cleanup_sysc_leave:
 923         clc     8(8,%r12),BASED(cleanup_sysc_leave_insn)
 924         je      2f
 925 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 926         mvc     __LC_EXIT_TIMER(8),__LC_ASYNC_ENTER_TIMER
 927         clc     8(8,%r12),BASED(cleanup_sysc_leave_insn+8)
 928         je      2f
 929 #endif
 930         mvc     __LC_RETURN_PSW(16),SP_PSW(%r15)
 931         cghi    %r12,__LC_MCK_OLD_PSW
 932         jne     0f
 933         mvc     __LC_SAVE_AREA+64(32),SP_R12(%r15)
 934         j       1f
 935 0:      mvc     __LC_SAVE_AREA+32(32),SP_R12(%r15)
 936 1:      lmg     %r0,%r11,SP_R0(%r15)
 937         lg      %r15,SP_R15(%r15)
 938 2:      la      %r12,__LC_RETURN_PSW
 939         br      %r14
 940 cleanup_sysc_leave_insn:
 941 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 942         .quad   sysc_leave + 16
 943 #endif
 944         .quad   sysc_leave + 12
 945
 946 cleanup_io_return:
 947         mvc     __LC_RETURN_PSW(8),0(%r12)
 948         mvc     __LC_RETURN_PSW+8(8),BASED(cleanup_table_io_work_loop)
 949         la      %r12,__LC_RETURN_PSW
 950         br      %r14
 951
 952 cleanup_io_leave:
 953         clc     8(8,%r12),BASED(cleanup_io_leave_insn)
 954         je      2f
 955 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 956         mvc     __LC_EXIT_TIMER(8),__LC_ASYNC_ENTER_TIMER
 957         clc     8(8,%r12),BASED(cleanup_io_leave_insn+8)
 958         je      2f
 959 #endif
 960         mvc     __LC_RETURN_PSW(16),SP_PSW(%r15)
 961         cghi    %r12,__LC_MCK_OLD_PSW
 962         jne     0f
 963         mvc     __LC_SAVE_AREA+64(32),SP_R12(%r15)
 964         j       1f
 965 0:      mvc     __LC_SAVE_AREA+32(32),SP_R12(%r15)
 966 1:      lmg     %r0,%r11,SP_R0(%r15)
 967         lg      %r15,SP_R15(%r15)
 968 2:      la      %r12,__LC_RETURN_PSW
 969         br      %r14
 970 cleanup_io_leave_insn:
 971 #ifdef CONFIG_VIRT_CPU_ACCOUNTING
 972         .quad   io_leave + 20
 973 #endif
 974         .quad   io_leave + 16
 975
 976 /*
 977  * Integer constants
 978  */
 979                 .align  4
 980 .Lconst:
 981 .Lc_pactive:    .long   PREEMPT_ACTIVE
 982 .Lnr_syscalls:  .long   NR_syscalls
 983 .L0x0130:       .short  0x130
 984 .L0x0140:       .short  0x140
 985 .L0x0150:       .short  0x150
 986 .L0x0160:       .short  0x160
 987 .L0x0170:       .short  0x170
 988 .Lcritical_start:
 989                 .quad   __critical_start
 990 .Lcritical_end:
 991                 .quad   __critical_end
 992
 993                 .section .rodata, "a"
 994 #define SYSCALL(esa,esame,emu)  .long esame
 995 sys_call_table:
 996 #include "syscalls.S"
 997 #undef SYSCALL
 998
 999 #ifdef CONFIG_COMPAT
1000
1001 #define SYSCALL(esa,esame,emu)  .long emu
1002 sys_call_table_emu:
1003 #include "syscalls.S"
1004 #undef SYSCALL
1005 #endif