arch/powerpc/kvm/book3s_hv_rmhandlers.S

   1 /*
   2  * This program is free software; you can redistribute it and/or modify
   3  * it under the terms of the GNU General Public License, version 2, as
   4  * published by the Free Software Foundation.
   5  *
   6  * This program is distributed in the hope that it will be useful,
   7  * but WITHOUT ANY WARRANTY; without even the implied warranty of
   8  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   9  * GNU General Public License for more details.
  10  *
  11  * Copyright 2011 Paul Mackerras, IBM Corp. <paulus@au1.ibm.com>
  12  *
  13  * Derived from book3s_rmhandlers.S and other files, which are:
  14  *
  15  * Copyright SUSE Linux Products GmbH 2009
  16  *
  17  * Authors: Alexander Graf <agraf@suse.de>
  18  */
  19
  20 #include <asm/ppc_asm.h>
  21 #include <asm/kvm_asm.h>
  22 #include <asm/reg.h>
  23 #include <asm/mmu.h>
  24 #include <asm/page.h>
  25 #include <asm/ptrace.h>
  26 #include <asm/hvcall.h>
  27 #include <asm/asm-offsets.h>
  28 #include <asm/exception-64s.h>
  29 #include <asm/kvm_book3s_asm.h>
  30 #include <asm/book3s/64/mmu-hash.h>
  31 #include <asm/tm.h>
  32 #include <asm/opal.h>
  33 #include <asm/xive-regs.h>
  34 #include <asm/thread_info.h>
  35
  36 /* Sign-extend HDEC if not on POWER9 */
  37 #define EXTEND_HDEC(reg)                        \
  38 BEGIN_FTR_SECTION;                              \
  39         extsw   reg, reg;                       \
  40 END_FTR_SECTION_IFCLR(CPU_FTR_ARCH_300)
  41
  42 #define VCPU_GPRS_TM(reg) (((reg) * ULONG_SIZE) + VCPU_GPR_TM)
  43
  44 /* Values in HSTATE_NAPPING(r13) */
  45 #define NAPPING_CEDE    1
  46 #define NAPPING_NOVCPU  2
  47
  48 /* Stack frame offsets for kvmppc_hv_entry */
  49 #define SFS                     160
  50 #define STACK_SLOT_TRAP         (SFS-4)
  51 #define STACK_SLOT_TID          (SFS-16)
  52 #define STACK_SLOT_PSSCR        (SFS-24)
  53 #define STACK_SLOT_PID          (SFS-32)
  54 #define STACK_SLOT_IAMR         (SFS-40)
  55 #define STACK_SLOT_CIABR        (SFS-48)
  56 #define STACK_SLOT_DAWR         (SFS-56)
  57 #define STACK_SLOT_DAWRX        (SFS-64)
  58 #define STACK_SLOT_HFSCR        (SFS-72)
  59
  60 /*
  61  * Call kvmppc_hv_entry in real mode.
  62  * Must be called with interrupts hard-disabled.
  63  *
  64  * Input Registers:
  65  *
  66  * LR = return address to continue at after eventually re-enabling MMU
  67  */
  68 _GLOBAL_TOC(kvmppc_hv_entry_trampoline)
  69         mflr    r0
  70         std     r0, PPC_LR_STKOFF(r1)
  71         stdu    r1, -112(r1)
  72         mfmsr   r10
  73         std     r10, HSTATE_HOST_MSR(r13)
  74         LOAD_REG_ADDR(r5, kvmppc_call_hv_entry)
  75         li      r0,MSR_RI
  76         andc    r0,r10,r0
  77         li      r6,MSR_IR | MSR_DR
  78         andc    r6,r10,r6
  79         mtmsrd  r0,1            /* clear RI in MSR */
  80         mtsrr0  r5
  81         mtsrr1  r6
  82         RFI_TO_KERNEL
  83
  84 kvmppc_call_hv_entry:
  85 BEGIN_FTR_SECTION
  86         /* On P9, do LPCR setting, if necessary */
  87         ld      r3, HSTATE_SPLIT_MODE(r13)
  88         cmpdi   r3, 0
  89         beq     46f
  90         lwz     r4, KVM_SPLIT_DO_SET(r3)
  91         cmpwi   r4, 0
  92         beq     46f
  93         bl      kvmhv_p9_set_lpcr
  94         nop
  95 46:
  96 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_300)
  97
  98         ld      r4, HSTATE_KVM_VCPU(r13)
  99         bl      kvmppc_hv_entry
 100
 101         /* Back from guest - restore host state and return to caller */
 102
 103 BEGIN_FTR_SECTION
 104         /* Restore host DABR and DABRX */
 105         ld      r5,HSTATE_DABR(r13)
 106         li      r6,7
 107         mtspr   SPRN_DABR,r5
 108         mtspr   SPRN_DABRX,r6
 109 END_FTR_SECTION_IFCLR(CPU_FTR_ARCH_207S)
 110
 111         /* Restore SPRG3 */
 112         ld      r3,PACA_SPRG_VDSO(r13)
 113         mtspr   SPRN_SPRG_VDSO_WRITE,r3
 114
 115         /* Reload the host's PMU registers */
 116         ld      r3, PACALPPACAPTR(r13)  /* is the host using the PMU? */
 117         lbz     r4, LPPACA_PMCINUSE(r3)
 118         cmpwi   r4, 0
 119         beq     23f                     /* skip if not */
 120 BEGIN_FTR_SECTION
 121         ld      r3, HSTATE_MMCR0(r13)
 122         andi.   r4, r3, MMCR0_PMAO_SYNC | MMCR0_PMAO
 123         cmpwi   r4, MMCR0_PMAO
 124         beql    kvmppc_fix_pmao
 125 END_FTR_SECTION_IFSET(CPU_FTR_PMAO_BUG)
 126         lwz     r3, HSTATE_PMC1(r13)
 127         lwz     r4, HSTATE_PMC2(r13)
 128         lwz     r5, HSTATE_PMC3(r13)
 129         lwz     r6, HSTATE_PMC4(r13)
 130         lwz     r8, HSTATE_PMC5(r13)
 131         lwz     r9, HSTATE_PMC6(r13)
 132         mtspr   SPRN_PMC1, r3
 133         mtspr   SPRN_PMC2, r4
 134         mtspr   SPRN_PMC3, r5
 135         mtspr   SPRN_PMC4, r6
 136         mtspr   SPRN_PMC5, r8
 137         mtspr   SPRN_PMC6, r9
 138         ld      r3, HSTATE_MMCR0(r13)
 139         ld      r4, HSTATE_MMCR1(r13)
 140         ld      r5, HSTATE_MMCRA(r13)
 141         ld      r6, HSTATE_SIAR(r13)
 142         ld      r7, HSTATE_SDAR(r13)
 143         mtspr   SPRN_MMCR1, r4
 144         mtspr   SPRN_MMCRA, r5
 145         mtspr   SPRN_SIAR, r6
 146         mtspr   SPRN_SDAR, r7
 147 BEGIN_FTR_SECTION
 148         ld      r8, HSTATE_MMCR2(r13)
 149         ld      r9, HSTATE_SIER(r13)
 150         mtspr   SPRN_MMCR2, r8
 151         mtspr   SPRN_SIER, r9
 152 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_207S)
 153         mtspr   SPRN_MMCR0, r3
 154         isync
 155 23:
 156
 157         /*
 158          * Reload DEC.  HDEC interrupts were disabled when
 159          * we reloaded the host's LPCR value.
 160          */
 161         ld      r3, HSTATE_DECEXP(r13)
 162         mftb    r4
 163         subf    r4, r4, r3
 164         mtspr   SPRN_DEC, r4
 165
 166         /* hwthread_req may have got set by cede or no vcpu, so clear it */
 167         li      r0, 0
 168         stb     r0, HSTATE_HWTHREAD_REQ(r13)
 169
 170         /*
 171          * For external interrupts we need to call the Linux
 172          * handler to process the interrupt. We do that by jumping
 173          * to absolute address 0x500 for external interrupts.
 174          * The [h]rfid at the end of the handler will return to
 175          * the book3s_hv_interrupts.S code. For other interrupts
 176          * we do the rfid to get back to the book3s_hv_interrupts.S
 177          * code here.
 178          */
 179         ld      r8, 112+PPC_LR_STKOFF(r1)
 180         addi    r1, r1, 112
 181         ld      r7, HSTATE_HOST_MSR(r13)
 182
 183         /* Return the trap number on this thread as the return value */
 184         mr      r3, r12
 185
 186         /*
 187          * If we came back from the guest via a relocation-on interrupt,
 188          * we will be in virtual mode at this point, which makes it a
 189          * little easier to get back to the caller.
 190          */
 191         mfmsr   r0
 192         andi.   r0, r0, MSR_IR          /* in real mode? */
 193         bne     .Lvirt_return
 194
 195         /* RFI into the highmem handler */
 196         mfmsr   r6
 197         li      r0, MSR_RI
 198         andc    r6, r6, r0
 199         mtmsrd  r6, 1                   /* Clear RI in MSR */
 200         mtsrr0  r8
 201         mtsrr1  r7
 202         RFI_TO_KERNEL
 203
 204         /* Virtual-mode return */
 205 .Lvirt_return:
 206         mtlr    r8
 207         blr
 208
 209 kvmppc_primary_no_guest:
 210         /* We handle this much like a ceded vcpu */
 211         /* put the HDEC into the DEC, since HDEC interrupts don't wake us */
 212         /* HDEC may be larger than DEC for arch >= v3.00, but since the */
 213         /* HDEC value came from DEC in the first place, it will fit */
 214         mfspr   r3, SPRN_HDEC
 215         mtspr   SPRN_DEC, r3
 216         /*
 217          * Make sure the primary has finished the MMU switch.
 218          * We should never get here on a secondary thread, but
 219          * check it for robustness' sake.
 220          */
 221         ld      r5, HSTATE_KVM_VCORE(r13)
 222 65:     lbz     r0, VCORE_IN_GUEST(r5)
 223         cmpwi   r0, 0
 224         beq     65b
 225         /* Set LPCR. */
 226         ld      r8,VCORE_LPCR(r5)
 227         mtspr   SPRN_LPCR,r8
 228         isync
 229         /* set our bit in napping_threads */
 230         ld      r5, HSTATE_KVM_VCORE(r13)
 231         lbz     r7, HSTATE_PTID(r13)
 232         li      r0, 1
 233         sld     r0, r0, r7
 234         addi    r6, r5, VCORE_NAPPING_THREADS
 235 1:      lwarx   r3, 0, r6
 236         or      r3, r3, r0
 237         stwcx.  r3, 0, r6
 238         bne     1b
 239         /* order napping_threads update vs testing entry_exit_map */
 240         isync
 241         li      r12, 0
 242         lwz     r7, VCORE_ENTRY_EXIT(r5)
 243         cmpwi   r7, 0x100
 244         bge     kvm_novcpu_exit /* another thread already exiting */
 245         li      r3, NAPPING_NOVCPU
 246         stb     r3, HSTATE_NAPPING(r13)
 247
 248         li      r3, 0           /* Don't wake on privileged (OS) doorbell */
 249         b       kvm_do_nap
 250
 251 /*
 252  * kvm_novcpu_wakeup
 253  *      Entered from kvm_start_guest if kvm_hstate.napping is set
 254  *      to NAPPING_NOVCPU
 255  *              r2 = kernel TOC
 256  *              r13 = paca
 257  */
 258 kvm_novcpu_wakeup:
 259         ld      r1, HSTATE_HOST_R1(r13)
 260         ld      r5, HSTATE_KVM_VCORE(r13)
 261         li      r0, 0
 262         stb     r0, HSTATE_NAPPING(r13)
 263
 264         /* check the wake reason */
 265         bl      kvmppc_check_wake_reason
 266
 267         /*
 268          * Restore volatile registers since we could have called
 269          * a C routine in kvmppc_check_wake_reason.
 270          *      r5 = VCORE
 271          */
 272         ld      r5, HSTATE_KVM_VCORE(r13)
 273
 274         /* see if any other thread is already exiting */
 275         lwz     r0, VCORE_ENTRY_EXIT(r5)
 276         cmpwi   r0, 0x100
 277         bge     kvm_novcpu_exit
 278
 279         /* clear our bit in napping_threads */
 280         lbz     r7, HSTATE_PTID(r13)
 281         li      r0, 1
 282         sld     r0, r0, r7
 283         addi    r6, r5, VCORE_NAPPING_THREADS
 284 4:      lwarx   r7, 0, r6
 285         andc    r7, r7, r0
 286         stwcx.  r7, 0, r6
 287         bne     4b
 288
 289         /* See if the wake reason means we need to exit */
 290         cmpdi   r3, 0
 291         bge     kvm_novcpu_exit
 292
 293         /* See if our timeslice has expired (HDEC is negative) */
 294         mfspr   r0, SPRN_HDEC
 295         EXTEND_HDEC(r0)
 296         li      r12, BOOK3S_INTERRUPT_HV_DECREMENTER
 297         cmpdi   r0, 0
 298         blt     kvm_novcpu_exit
 299
 300         /* Got an IPI but other vcpus aren't yet exiting, must be a latecomer */
 301         ld      r4, HSTATE_KVM_VCPU(r13)
 302         cmpdi   r4, 0
 303         beq     kvmppc_primary_no_guest
 304
 305 #ifdef CONFIG_KVM_BOOK3S_HV_EXIT_TIMING
 306         addi    r3, r4, VCPU_TB_RMENTRY
 307         bl      kvmhv_start_timing
 308 #endif
 309         b       kvmppc_got_guest
 310
 311 kvm_novcpu_exit:
 312 #ifdef CONFIG_KVM_BOOK3S_HV_EXIT_TIMING
 313         ld      r4, HSTATE_KVM_VCPU(r13)
 314         cmpdi   r4, 0
 315         beq     13f
 316         addi    r3, r4, VCPU_TB_RMEXIT
 317         bl      kvmhv_accumulate_time
 318 #endif
 319 13:     mr      r3, r12
 320         stw     r12, STACK_SLOT_TRAP(r1)
 321         bl      kvmhv_commence_exit
 322         nop
 323         lwz     r12, STACK_SLOT_TRAP(r1)
 324         b       kvmhv_switch_to_host
 325
 326 /*
 327  * We come in here when wakened from nap mode.
 328  * Relocation is off and most register values are lost.
 329  * r13 points to the PACA.
 330  * r3 contains the SRR1 wakeup value, SRR1 is trashed.
 331  */
 332         .globl  kvm_start_guest
 333 kvm_start_guest:
 334         /* Set runlatch bit the minute you wake up from nap */
 335         mfspr   r0, SPRN_CTRLF
 336         ori     r0, r0, 1
 337         mtspr   SPRN_CTRLT, r0
 338
 339         /*
 340          * Could avoid this and pass it through in r3. For now,
 341          * code expects it to be in SRR1.
 342          */
 343         mtspr   SPRN_SRR1,r3
 344
 345         ld      r2,PACATOC(r13)
 346
 347         li      r0,KVM_HWTHREAD_IN_KVM
 348         stb     r0,HSTATE_HWTHREAD_STATE(r13)
 349
 350         /* NV GPR values from power7_idle() will no longer be valid */
 351         li      r0,1
 352         stb     r0,PACA_NAPSTATELOST(r13)
 353
 354         /* were we napping due to cede? */
 355         lbz     r0,HSTATE_NAPPING(r13)
 356         cmpwi   r0,NAPPING_CEDE
 357         beq     kvm_end_cede
 358         cmpwi   r0,NAPPING_NOVCPU
 359         beq     kvm_novcpu_wakeup
 360
 361         ld      r1,PACAEMERGSP(r13)
 362         subi    r1,r1,STACK_FRAME_OVERHEAD
 363
 364         /*
 365          * We weren't napping due to cede, so this must be a secondary
 366          * thread being woken up to run a guest, or being woken up due
 367          * to a stray IPI.  (Or due to some machine check or hypervisor
 368          * maintenance interrupt while the core is in KVM.)
 369          */
 370
 371         /* Check the wake reason in SRR1 to see why we got here */
 372         bl      kvmppc_check_wake_reason
 373         /*
 374          * kvmppc_check_wake_reason could invoke a C routine, but we
 375          * have no volatile registers to restore when we return.
 376          */
 377
 378         cmpdi   r3, 0
 379         bge     kvm_no_guest
 380
 381         /* get vcore pointer, NULL if we have nothing to run */
 382         ld      r5,HSTATE_KVM_VCORE(r13)
 383         cmpdi   r5,0
 384         /* if we have no vcore to run, go back to sleep */
 385         beq     kvm_no_guest
 386
 387 kvm_secondary_got_guest:
 388
 389         /* Set HSTATE_DSCR(r13) to something sensible */
 390         ld      r6, PACA_DSCR_DEFAULT(r13)
 391         std     r6, HSTATE_DSCR(r13)
 392
 393         /* On thread 0 of a subcore, set HDEC to max */
 394         lbz     r4, HSTATE_PTID(r13)
 395         cmpwi   r4, 0
 396         bne     63f
 397         LOAD_REG_ADDR(r6, decrementer_max)
 398         ld      r6, 0(r6)
 399         mtspr   SPRN_HDEC, r6
 400         /* and set per-LPAR registers, if doing dynamic micro-threading */
 401         ld      r6, HSTATE_SPLIT_MODE(r13)
 402         cmpdi   r6, 0
 403         beq     63f
 404 BEGIN_FTR_SECTION
 405         ld      r0, KVM_SPLIT_RPR(r6)
 406         mtspr   SPRN_RPR, r0
 407         ld      r0, KVM_SPLIT_PMMAR(r6)
 408         mtspr   SPRN_PMMAR, r0
 409         ld      r0, KVM_SPLIT_LDBAR(r6)
 410         mtspr   SPRN_LDBAR, r0
 411         isync
 412 FTR_SECTION_ELSE
 413         /* On P9 we use the split_info for coordinating LPCR changes */
 414         lwz     r4, KVM_SPLIT_DO_SET(r6)
 415         cmpwi   r4, 0
 416         beq     63f
 417         mr      r3, r6
 418         bl      kvmhv_p9_set_lpcr
 419         nop
 420 ALT_FTR_SECTION_END_IFCLR(CPU_FTR_ARCH_300)
 421 63:
 422         /* Order load of vcpu after load of vcore */
 423         lwsync
 424         ld      r4, HSTATE_KVM_VCPU(r13)
 425         bl      kvmppc_hv_entry
 426
 427         /* Back from the guest, go back to nap */
 428         /* Clear our vcpu and vcore pointers so we don't come back in early */
 429         li      r0, 0
 430         std     r0, HSTATE_KVM_VCPU(r13)
 431         /*
 432          * Once we clear HSTATE_KVM_VCORE(r13), the code in
 433          * kvmppc_run_core() is going to assume that all our vcpu
 434          * state is visible in memory.  This lwsync makes sure
 435          * that that is true.
 436          */
 437         lwsync
 438         std     r0, HSTATE_KVM_VCORE(r13)
 439
 440         /*
 441          * All secondaries exiting guest will fall through this path.
 442          * Before proceeding, just check for HMI interrupt and
 443          * invoke opal hmi handler. By now we are sure that the
 444          * primary thread on this core/subcore has already made partition
 445          * switch/TB resync and we are good to call opal hmi handler.
 446          */
 447         cmpwi   r12, BOOK3S_INTERRUPT_HMI
 448         bne     kvm_no_guest
 449
 450         li      r3,0                    /* NULL argument */
 451         bl      hmi_exception_realmode
 452 /*
 453  * At this point we have finished executing in the guest.
 454  * We need to wait for hwthread_req to become zero, since
 455  * we may not turn on the MMU while hwthread_req is non-zero.
 456  * While waiting we also need to check if we get given a vcpu to run.
 457  */
 458 kvm_no_guest:
 459         lbz     r3, HSTATE_HWTHREAD_REQ(r13)
 460         cmpwi   r3, 0
 461         bne     53f
 462         HMT_MEDIUM
 463         li      r0, KVM_HWTHREAD_IN_KERNEL
 464         stb     r0, HSTATE_HWTHREAD_STATE(r13)
 465         /* need to recheck hwthread_req after a barrier, to avoid race */
 466         sync
 467         lbz     r3, HSTATE_HWTHREAD_REQ(r13)
 468         cmpwi   r3, 0
 469         bne     54f
 470 /*
 471  * We jump to pnv_wakeup_loss, which will return to the caller
 472  * of power7_nap in the powernv cpu offline loop.  The value we
 473  * put in r3 becomes the return value for power7_nap. pnv_wakeup_loss
 474  * requires SRR1 in r12.
 475  */
 476         li      r3, LPCR_PECE0
 477         mfspr   r4, SPRN_LPCR
 478         rlwimi  r4, r3, 0, LPCR_PECE0 | LPCR_PECE1
 479         mtspr   SPRN_LPCR, r4
 480         li      r3, 0
 481         mfspr   r12,SPRN_SRR1
 482         b       pnv_wakeup_loss
 483
 484 53:     HMT_LOW
 485         ld      r5, HSTATE_KVM_VCORE(r13)
 486         cmpdi   r5, 0
 487         bne     60f
 488         ld      r3, HSTATE_SPLIT_MODE(r13)
 489         cmpdi   r3, 0
 490         beq     kvm_no_guest
 491         lwz     r0, KVM_SPLIT_DO_SET(r3)
 492         cmpwi   r0, 0
 493         bne     kvmhv_do_set
 494         lwz     r0, KVM_SPLIT_DO_RESTORE(r3)
 495         cmpwi   r0, 0
 496         bne     kvmhv_do_restore
 497         lbz     r0, KVM_SPLIT_DO_NAP(r3)
 498         cmpwi   r0, 0
 499         beq     kvm_no_guest
 500         HMT_MEDIUM
 501         b       kvm_unsplit_nap
 502 60:     HMT_MEDIUM
 503         b       kvm_secondary_got_guest
 504
 505 54:     li      r0, KVM_HWTHREAD_IN_KVM
 506         stb     r0, HSTATE_HWTHREAD_STATE(r13)
 507         b       kvm_no_guest
 508
 509 kvmhv_do_set:
 510         /* Set LPCR, LPIDR etc. on P9 */
 511         HMT_MEDIUM
 512         bl      kvmhv_p9_set_lpcr
 513         nop
 514         b       kvm_no_guest
 515
 516 kvmhv_do_restore:
 517         HMT_MEDIUM
 518         bl      kvmhv_p9_restore_lpcr
 519         nop
 520         b       kvm_no_guest
 521
 522 /*
 523  * Here the primary thread is trying to return the core to
 524  * whole-core mode, so we need to nap.
 525  */
 526 kvm_unsplit_nap:
 527         /*
 528          * When secondaries are napping in kvm_unsplit_nap() with
 529          * hwthread_req = 1, HMI goes ignored even though subcores are
 530          * already exited the guest. Hence HMI keeps waking up secondaries
 531          * from nap in a loop and secondaries always go back to nap since
 532          * no vcore is assigned to them. This makes impossible for primary
 533          * thread to get hold of secondary threads resulting into a soft
 534          * lockup in KVM path.
 535          *
 536          * Let us check if HMI is pending and handle it before we go to nap.
 537          */
 538         cmpwi   r12, BOOK3S_INTERRUPT_HMI
 539         bne     55f
 540         li      r3, 0                   /* NULL argument */
 541         bl      hmi_exception_realmode
 542 55:
 543         /*
 544          * Ensure that secondary doesn't nap when it has
 545          * its vcore pointer set.
 546          */
 547         sync            /* matches smp_mb() before setting split_info.do_nap */
 548         ld      r0, HSTATE_KVM_VCORE(r13)
 549         cmpdi   r0, 0
 550         bne     kvm_no_guest
 551         /* clear any pending message */
 552 BEGIN_FTR_SECTION
 553         lis     r6, (PPC_DBELL_SERVER << (63-36))@h
 554         PPC_MSGCLR(6)
 555 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_207S)
 556         /* Set kvm_split_mode.napped[tid] = 1 */
 557         ld      r3, HSTATE_SPLIT_MODE(r13)
 558         li      r0, 1
 559         lbz     r4, HSTATE_TID(r13)
 560         addi    r4, r4, KVM_SPLIT_NAPPED
 561         stbx    r0, r3, r4
 562         /* Check the do_nap flag again after setting napped[] */
 563         sync
 564         lbz     r0, KVM_SPLIT_DO_NAP(r3)
 565         cmpwi   r0, 0
 566         beq     57f
 567         li      r3, (LPCR_PECEDH | LPCR_PECE0) >> 4
 568         mfspr   r5, SPRN_LPCR
 569         rlwimi  r5, r3, 4, (LPCR_PECEDP | LPCR_PECEDH | LPCR_PECE0 | LPCR_PECE1)
 570         b       kvm_nap_sequence
 571
 572 57:     li      r0, 0
 573         stbx    r0, r3, r4
 574         b       kvm_no_guest
 575
 576 /******************************************************************************
 577  *                                                                            *
 578  *                               Entry code                                   *
 579  *                                                                            *
 580  *****************************************************************************/
 581
 582 .global kvmppc_hv_entry
 583 kvmppc_hv_entry:
 584
 585         /* Required state:
 586          *
 587          * R4 = vcpu pointer (or NULL)
 588          * MSR = ~IR|DR
 589          * R13 = PACA
 590          * R1 = host R1
 591          * R2 = TOC
 592          * all other volatile GPRS = free
 593          * Does not preserve non-volatile GPRs or CR fields
 594          */
 595         mflr    r0
 596         std     r0, PPC_LR_STKOFF(r1)
 597         stdu    r1, -SFS(r1)
 598
 599         /* Save R1 in the PACA */
 600         std     r1, HSTATE_HOST_R1(r13)
 601
 602         li      r6, KVM_GUEST_MODE_HOST_HV
 603         stb     r6, HSTATE_IN_GUEST(r13)
 604
 605 #ifdef CONFIG_KVM_BOOK3S_HV_EXIT_TIMING
 606         /* Store initial timestamp */
 607         cmpdi   r4, 0
 608         beq     1f
 609         addi    r3, r4, VCPU_TB_RMENTRY
 610         bl      kvmhv_start_timing
 611 1:
 612 #endif
 613
 614         /* Use cr7 as an indication of radix mode */
 615         ld      r5, HSTATE_KVM_VCORE(r13)
 616         ld      r9, VCORE_KVM(r5)       /* pointer to struct kvm */
 617         lbz     r0, KVM_RADIX(r9)
 618         cmpwi   cr7, r0, 0
 619
 620         /* Clear out SLB if hash */
 621         bne     cr7, 2f
 622         li      r6,0
 623         slbmte  r6,r6
 624         slbia
 625         ptesync
 626 2:
 627         /*
 628          * POWER7/POWER8 host -> guest partition switch code.
 629          * We don't have to lock against concurrent tlbies,
 630          * but we do have to coordinate across hardware threads.
 631          */
 632         /* Set bit in entry map iff exit map is zero. */
 633         li      r7, 1
 634         lbz     r6, HSTATE_PTID(r13)
 635         sld     r7, r7, r6
 636         addi    r8, r5, VCORE_ENTRY_EXIT
 637 21:     lwarx   r3, 0, r8
 638         cmpwi   r3, 0x100               /* any threads starting to exit? */
 639         bge     secondary_too_late      /* if so we're too late to the party */
 640         or      r3, r3, r7
 641         stwcx.  r3, 0, r8
 642         bne     21b
 643
 644         /* Primary thread switches to guest partition. */
 645         cmpwi   r6,0
 646         bne     10f
 647         lwz     r7,KVM_LPID(r9)
 648 BEGIN_FTR_SECTION
 649         ld      r6,KVM_SDR1(r9)
 650         li      r0,LPID_RSVD            /* switch to reserved LPID */
 651         mtspr   SPRN_LPID,r0
 652         ptesync
 653         mtspr   SPRN_SDR1,r6            /* switch to partition page table */
 654 END_FTR_SECTION_IFCLR(CPU_FTR_ARCH_300)
 655         mtspr   SPRN_LPID,r7
 656         isync
 657
 658         /* See if we need to flush the TLB */
 659         lhz     r6,PACAPACAINDEX(r13)   /* test_bit(cpu, need_tlb_flush) */
 660 BEGIN_FTR_SECTION
 661         /*
 662          * On POWER9, individual threads can come in here, but the
 663          * TLB is shared between the 4 threads in a core, hence
 664          * invalidating on one thread invalidates for all.
 665          * Thus we make all 4 threads use the same bit here.
 666          */
 667         clrrdi  r6,r6,2
 668 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_300)
 669         clrldi  r7,r6,64-6              /* extract bit number (6 bits) */
 670         srdi    r6,r6,6                 /* doubleword number */
 671         sldi    r6,r6,3                 /* address offset */
 672         add     r6,r6,r9
 673         addi    r6,r6,KVM_NEED_FLUSH    /* dword in kvm->arch.need_tlb_flush */
 674         li      r8,1
 675         sld     r8,r8,r7
 676         ld      r7,0(r6)
 677         and.    r7,r7,r8
 678         beq     22f
 679         /* Flush the TLB of any entries for this LPID */
 680         lwz     r0,KVM_TLB_SETS(r9)
 681         mtctr   r0
 682         li      r7,0x800                /* IS field = 0b10 */
 683         ptesync
 684         li      r0,0                    /* RS for P9 version of tlbiel */
 685         bne     cr7, 29f
 686 28:     tlbiel  r7                      /* On P9, rs=0, RIC=0, PRS=0, R=0 */
 687         addi    r7,r7,0x1000
 688         bdnz    28b
 689         b       30f
 690 29:     PPC_TLBIEL(7,0,2,1,1)           /* for radix, RIC=2, PRS=1, R=1 */
 691         addi    r7,r7,0x1000
 692         bdnz    29b
 693 30:     ptesync
 694 23:     ldarx   r7,0,r6                 /* clear the bit after TLB flushed */
 695         andc    r7,r7,r8
 696         stdcx.  r7,0,r6
 697         bne     23b
 698
 699         /* Add timebase offset onto timebase */
 700 22:     ld      r8,VCORE_TB_OFFSET(r5)
 701         cmpdi   r8,0
 702         beq     37f
 703         mftb    r6              /* current host timebase */
 704         add     r8,r8,r6
 705         mtspr   SPRN_TBU40,r8   /* update upper 40 bits */
 706         mftb    r7              /* check if lower 24 bits overflowed */
 707         clrldi  r6,r6,40
 708         clrldi  r7,r7,40
 709         cmpld   r7,r6
 710         bge     37f
 711         addis   r8,r8,0x100     /* if so, increment upper 40 bits */
 712         mtspr   SPRN_TBU40,r8
 713
 714         /* Load guest PCR value to select appropriate compat mode */
 715 37:     ld      r7, VCORE_PCR(r5)
 716         cmpdi   r7, 0
 717         beq     38f
 718         mtspr   SPRN_PCR, r7
 719 38:
 720
 721 BEGIN_FTR_SECTION
 722         /* DPDES and VTB are shared between threads */
 723         ld      r8, VCORE_DPDES(r5)
 724         ld      r7, VCORE_VTB(r5)
 725         mtspr   SPRN_DPDES, r8
 726         mtspr   SPRN_VTB, r7
 727 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_207S)
 728
 729         /* Mark the subcore state as inside guest */
 730         bl      kvmppc_subcore_enter_guest
 731         nop
 732         ld      r5, HSTATE_KVM_VCORE(r13)
 733         ld      r4, HSTATE_KVM_VCPU(r13)
 734         li      r0,1
 735         stb     r0,VCORE_IN_GUEST(r5)   /* signal secondaries to continue */
 736
 737         /* Do we have a guest vcpu to run? */
 738 10:     cmpdi   r4, 0
 739         beq     kvmppc_primary_no_guest
 740 kvmppc_got_guest:
 741
 742         /* Load up guest SLB entries (N.B. slb_max will be 0 for radix) */
 743         lwz     r5,VCPU_SLB_MAX(r4)
 744         cmpwi   r5,0
 745         beq     9f
 746         mtctr   r5
 747         addi    r6,r4,VCPU_SLB
 748 1:      ld      r8,VCPU_SLB_E(r6)
 749         ld      r9,VCPU_SLB_V(r6)
 750         slbmte  r9,r8
 751         addi    r6,r6,VCPU_SLB_SIZE
 752         bdnz    1b
 753 9:
 754         /* Increment yield count if they have a VPA */
 755         ld      r3, VCPU_VPA(r4)
 756         cmpdi   r3, 0
 757         beq     25f
 758         li      r6, LPPACA_YIELDCOUNT
 759         LWZX_BE r5, r3, r6
 760         addi    r5, r5, 1
 761         STWX_BE r5, r3, r6
 762         li      r6, 1
 763         stb     r6, VCPU_VPA_DIRTY(r4)
 764 25:
 765
 766         /* Save purr/spurr */
 767         mfspr   r5,SPRN_PURR
 768         mfspr   r6,SPRN_SPURR
 769         std     r5,HSTATE_PURR(r13)
 770         std     r6,HSTATE_SPURR(r13)
 771         ld      r7,VCPU_PURR(r4)
 772         ld      r8,VCPU_SPURR(r4)
 773         mtspr   SPRN_PURR,r7
 774         mtspr   SPRN_SPURR,r8
 775
 776         /* Save host values of some registers */
 777 BEGIN_FTR_SECTION
 778         mfspr   r5, SPRN_TIDR
 779         mfspr   r6, SPRN_PSSCR
 780         mfspr   r7, SPRN_PID
 781         mfspr   r8, SPRN_IAMR
 782         std     r5, STACK_SLOT_TID(r1)
 783         std     r6, STACK_SLOT_PSSCR(r1)
 784         std     r7, STACK_SLOT_PID(r1)
 785         std     r8, STACK_SLOT_IAMR(r1)
 786         mfspr   r5, SPRN_HFSCR
 787         std     r5, STACK_SLOT_HFSCR(r1)
 788 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_300)
 789 BEGIN_FTR_SECTION
 790         mfspr   r5, SPRN_CIABR
 791         mfspr   r6, SPRN_DAWR
 792         mfspr   r7, SPRN_DAWRX
 793         std     r5, STACK_SLOT_CIABR(r1)
 794         std     r6, STACK_SLOT_DAWR(r1)
 795         std     r7, STACK_SLOT_DAWRX(r1)
 796 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_207S)
 797
 798 BEGIN_FTR_SECTION
 799         /* Set partition DABR */
 800         /* Do this before re-enabling PMU to avoid P7 DABR corruption bug */
 801         lwz     r5,VCPU_DABRX(r4)
 802         ld      r6,VCPU_DABR(r4)
 803         mtspr   SPRN_DABRX,r5
 804         mtspr   SPRN_DABR,r6
 805         isync
 806 END_FTR_SECTION_IFCLR(CPU_FTR_ARCH_207S)
 807
 808 #ifdef CONFIG_PPC_TRANSACTIONAL_MEM
 809 BEGIN_FTR_SECTION
 810         /*
 811          * NOTE THAT THIS TRASHES ALL NON-VOLATILE REGISTERS INCLUDING CR
 812          */
 813         bl      kvmppc_restore_tm
 814 END_FTR_SECTION_IFSET(CPU_FTR_TM)
 815 #endif
 816
 817         /* Load guest PMU registers */
 818         /* R4 is live here (vcpu pointer) */
 819         li      r3, 1
 820         sldi    r3, r3, 31              /* MMCR0_FC (freeze counters) bit */
 821         mtspr   SPRN_MMCR0, r3          /* freeze all counters, disable ints */
 822         isync
 823 BEGIN_FTR_SECTION
 824         ld      r3, VCPU_MMCR(r4)
 825         andi.   r5, r3, MMCR0_PMAO_SYNC | MMCR0_PMAO
 826         cmpwi   r5, MMCR0_PMAO
 827         beql    kvmppc_fix_pmao
 828 END_FTR_SECTION_IFSET(CPU_FTR_PMAO_BUG)
 829         lwz     r3, VCPU_PMC(r4)        /* always load up guest PMU registers */
 830         lwz     r5, VCPU_PMC + 4(r4)    /* to prevent information leak */
 831         lwz     r6, VCPU_PMC + 8(r4)
 832         lwz     r7, VCPU_PMC + 12(r4)
 833         lwz     r8, VCPU_PMC + 16(r4)
 834         lwz     r9, VCPU_PMC + 20(r4)
 835         mtspr   SPRN_PMC1, r3
 836         mtspr   SPRN_PMC2, r5
 837         mtspr   SPRN_PMC3, r6
 838         mtspr   SPRN_PMC4, r7
 839         mtspr   SPRN_PMC5, r8
 840         mtspr   SPRN_PMC6, r9
 841         ld      r3, VCPU_MMCR(r4)
 842         ld      r5, VCPU_MMCR + 8(r4)
 843         ld      r6, VCPU_MMCR + 16(r4)
 844         ld      r7, VCPU_SIAR(r4)
 845         ld      r8, VCPU_SDAR(r4)
 846         mtspr   SPRN_MMCR1, r5
 847         mtspr   SPRN_MMCRA, r6
 848         mtspr   SPRN_SIAR, r7
 849         mtspr   SPRN_SDAR, r8
 850 BEGIN_FTR_SECTION
 851         ld      r5, VCPU_MMCR + 24(r4)
 852         ld      r6, VCPU_SIER(r4)
 853         mtspr   SPRN_MMCR2, r5
 854         mtspr   SPRN_SIER, r6
 855 BEGIN_FTR_SECTION_NESTED(96)
 856         lwz     r7, VCPU_PMC + 24(r4)
 857         lwz     r8, VCPU_PMC + 28(r4)
 858         ld      r9, VCPU_MMCR + 32(r4)
 859         mtspr   SPRN_SPMC1, r7
 860         mtspr   SPRN_SPMC2, r8
 861         mtspr   SPRN_MMCRS, r9
 862 END_FTR_SECTION_NESTED(CPU_FTR_ARCH_300, 0, 96)
 863 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_207S)
 864         mtspr   SPRN_MMCR0, r3
 865         isync
 866
 867         /* Load up FP, VMX and VSX registers */
 868         bl      kvmppc_load_fp
 869
 870         ld      r14, VCPU_GPR(R14)(r4)
 871         ld      r15, VCPU_GPR(R15)(r4)
 872         ld      r16, VCPU_GPR(R16)(r4)
 873         ld      r17, VCPU_GPR(R17)(r4)
 874         ld      r18, VCPU_GPR(R18)(r4)
 875         ld      r19, VCPU_GPR(R19)(r4)
 876         ld      r20, VCPU_GPR(R20)(r4)
 877         ld      r21, VCPU_GPR(R21)(r4)
 878         ld      r22, VCPU_GPR(R22)(r4)
 879         ld      r23, VCPU_GPR(R23)(r4)
 880         ld      r24, VCPU_GPR(R24)(r4)
 881         ld      r25, VCPU_GPR(R25)(r4)
 882         ld      r26, VCPU_GPR(R26)(r4)
 883         ld      r27, VCPU_GPR(R27)(r4)
 884         ld      r28, VCPU_GPR(R28)(r4)
 885         ld      r29, VCPU_GPR(R29)(r4)
 886         ld      r30, VCPU_GPR(R30)(r4)
 887         ld      r31, VCPU_GPR(R31)(r4)
 888
 889         /* Switch DSCR to guest value */
 890         ld      r5, VCPU_DSCR(r4)
 891         mtspr   SPRN_DSCR, r5
 892
 893 BEGIN_FTR_SECTION
 894         /* Skip next section on POWER7 */
 895         b       8f
 896 END_FTR_SECTION_IFCLR(CPU_FTR_ARCH_207S)
 897         /* Load up POWER8-specific registers */
 898         ld      r5, VCPU_IAMR(r4)
 899         lwz     r6, VCPU_PSPB(r4)
 900         ld      r7, VCPU_FSCR(r4)
 901         mtspr   SPRN_IAMR, r5
 902         mtspr   SPRN_PSPB, r6
 903         mtspr   SPRN_FSCR, r7
 904         ld      r5, VCPU_DAWR(r4)
 905         ld      r6, VCPU_DAWRX(r4)
 906         ld      r7, VCPU_CIABR(r4)
 907         ld      r8, VCPU_TAR(r4)
 908         mtspr   SPRN_DAWR, r5
 909         mtspr   SPRN_DAWRX, r6
 910         mtspr   SPRN_CIABR, r7
 911         mtspr   SPRN_TAR, r8
 912         ld      r5, VCPU_IC(r4)
 913         ld      r8, VCPU_EBBHR(r4)
 914         mtspr   SPRN_IC, r5
 915         mtspr   SPRN_EBBHR, r8
 916         ld      r5, VCPU_EBBRR(r4)
 917         ld      r6, VCPU_BESCR(r4)
 918         lwz     r7, VCPU_GUEST_PID(r4)
 919         ld      r8, VCPU_WORT(r4)
 920         mtspr   SPRN_EBBRR, r5
 921         mtspr   SPRN_BESCR, r6
 922         mtspr   SPRN_PID, r7
 923         mtspr   SPRN_WORT, r8
 924 BEGIN_FTR_SECTION
 925         PPC_INVALIDATE_ERAT
 926 END_FTR_SECTION_IFSET(CPU_FTR_POWER9_DD1)
 927 BEGIN_FTR_SECTION
 928         /* POWER8-only registers */
 929         ld      r5, VCPU_TCSCR(r4)
 930         ld      r6, VCPU_ACOP(r4)
 931         ld      r7, VCPU_CSIGR(r4)
 932         ld      r8, VCPU_TACR(r4)
 933         mtspr   SPRN_TCSCR, r5
 934         mtspr   SPRN_ACOP, r6
 935         mtspr   SPRN_CSIGR, r7
 936         mtspr   SPRN_TACR, r8
 937 FTR_SECTION_ELSE
 938         /* POWER9-only registers */
 939         ld      r5, VCPU_TID(r4)
 940         ld      r6, VCPU_PSSCR(r4)
 941         oris    r6, r6, PSSCR_EC@h      /* This makes stop trap to HV */
 942         ld      r7, VCPU_HFSCR(r4)
 943         mtspr   SPRN_TIDR, r5
 944         mtspr   SPRN_PSSCR, r6
 945         mtspr   SPRN_HFSCR, r7
 946 ALT_FTR_SECTION_END_IFCLR(CPU_FTR_ARCH_300)
 947 8:
 948
 949         /*
 950          * Set the decrementer to the guest decrementer.
 951          */
 952         ld      r8,VCPU_DEC_EXPIRES(r4)
 953         /* r8 is a host timebase value here, convert to guest TB */
 954         ld      r5,HSTATE_KVM_VCORE(r13)
 955         ld      r6,VCORE_TB_OFFSET(r5)
 956         add     r8,r8,r6
 957         mftb    r7
 958         subf    r3,r7,r8
 959         mtspr   SPRN_DEC,r3
 960         std     r3,VCPU_DEC(r4)
 961
 962         ld      r5, VCPU_SPRG0(r4)
 963         ld      r6, VCPU_SPRG1(r4)
 964         ld      r7, VCPU_SPRG2(r4)
 965         ld      r8, VCPU_SPRG3(r4)
 966         mtspr   SPRN_SPRG0, r5
 967         mtspr   SPRN_SPRG1, r6
 968         mtspr   SPRN_SPRG2, r7
 969         mtspr   SPRN_SPRG3, r8
 970
 971         /* Load up DAR and DSISR */
 972         ld      r5, VCPU_DAR(r4)
 973         lwz     r6, VCPU_DSISR(r4)
 974         mtspr   SPRN_DAR, r5
 975         mtspr   SPRN_DSISR, r6
 976
 977         /* Restore AMR and UAMOR, set AMOR to all 1s */
 978         ld      r5,VCPU_AMR(r4)
 979         ld      r6,VCPU_UAMOR(r4)
 980         li      r7,-1
 981         mtspr   SPRN_AMR,r5
 982         mtspr   SPRN_UAMOR,r6
 983         mtspr   SPRN_AMOR,r7
 984
 985         /* Restore state of CTRL run bit; assume 1 on entry */
 986         lwz     r5,VCPU_CTRL(r4)
 987         andi.   r5,r5,1
 988         bne     4f
 989         mfspr   r6,SPRN_CTRLF
 990         clrrdi  r6,r6,1
 991         mtspr   SPRN_CTRLT,r6
 992 4:
 993         /* Secondary threads wait for primary to have done partition switch */
 994         ld      r5, HSTATE_KVM_VCORE(r13)
 995         lbz     r6, HSTATE_PTID(r13)
 996         cmpwi   r6, 0
 997         beq     21f
 998         lbz     r0, VCORE_IN_GUEST(r5)
 999         cmpwi   r0, 0
1000         bne     21f
1001         HMT_LOW
1002 20:     lwz     r3, VCORE_ENTRY_EXIT(r5)
1003         cmpwi   r3, 0x100
1004         bge     no_switch_exit
1005         lbz     r0, VCORE_IN_GUEST(r5)
1006         cmpwi   r0, 0
1007         beq     20b
1008         HMT_MEDIUM
1009 21:
1010         /* Set LPCR. */
1011         ld      r8,VCORE_LPCR(r5)
1012         mtspr   SPRN_LPCR,r8
1013         isync
1014
1015         /* Check if HDEC expires soon */
1016         mfspr   r3, SPRN_HDEC
1017         EXTEND_HDEC(r3)
1018         cmpdi   r3, 512         /* 1 microsecond */
1019         blt     hdec_soon
1020
1021 #ifdef CONFIG_KVM_XICS
1022         /* We are entering the guest on that thread, push VCPU to XIVE */
1023         ld      r10, HSTATE_XIVE_TIMA_PHYS(r13)
1024         cmpldi  cr0, r10, 0
1025         beq     no_xive
1026         ld      r11, VCPU_XIVE_SAVED_STATE(r4)
1027         li      r9, TM_QW1_OS
1028         eieio
1029         stdcix  r11,r9,r10
1030         lwz     r11, VCPU_XIVE_CAM_WORD(r4)
1031         li      r9, TM_QW1_OS + TM_WORD2
1032         stwcix  r11,r9,r10
1033         li      r9, 1
1034         stw     r9, VCPU_XIVE_PUSHED(r4)
1035         eieio
1036 no_xive:
1037 #endif /* CONFIG_KVM_XICS */
1038
1039 deliver_guest_interrupt:
1040         ld      r6, VCPU_CTR(r4)
1041         ld      r7, VCPU_XER(r4)
1042
1043         mtctr   r6
1044         mtxer   r7
1045
1046 kvmppc_cede_reentry:            /* r4 = vcpu, r13 = paca */
1047         ld      r10, VCPU_PC(r4)
1048         ld      r11, VCPU_MSR(r4)
1049         ld      r6, VCPU_SRR0(r4)
1050         ld      r7, VCPU_SRR1(r4)
1051         mtspr   SPRN_SRR0, r6
1052         mtspr   SPRN_SRR1, r7
1053
1054         /* r11 = vcpu->arch.msr & ~MSR_HV */
1055         rldicl  r11, r11, 63 - MSR_HV_LG, 1
1056         rotldi  r11, r11, 1 + MSR_HV_LG
1057         ori     r11, r11, MSR_ME
1058
1059         /* Check if we can deliver an external or decrementer interrupt now */
1060         ld      r0, VCPU_PENDING_EXC(r4)
1061         rldicl  r0, r0, 64 - BOOK3S_IRQPRIO_EXTERNAL_LEVEL, 63
1062         cmpdi   cr1, r0, 0
1063         andi.   r8, r11, MSR_EE
1064         mfspr   r8, SPRN_LPCR
1065         /* Insert EXTERNAL_LEVEL bit into LPCR at the MER bit position */
1066         rldimi  r8, r0, LPCR_MER_SH, 63 - LPCR_MER_SH
1067         mtspr   SPRN_LPCR, r8
1068         isync
1069         beq     5f
1070         li      r0, BOOK3S_INTERRUPT_EXTERNAL
1071         bne     cr1, 12f
1072         mfspr   r0, SPRN_DEC
1073 BEGIN_FTR_SECTION
1074         /* On POWER9 check whether the guest has large decrementer enabled */
1075         andis.  r8, r8, LPCR_LD@h
1076         bne     15f
1077 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_300)
1078         extsw   r0, r0
1079 15:     cmpdi   r0, 0
1080         li      r0, BOOK3S_INTERRUPT_DECREMENTER
1081         bge     5f
1082
1083 12:     mtspr   SPRN_SRR0, r10
1084         mr      r10,r0
1085         mtspr   SPRN_SRR1, r11
1086         mr      r9, r4
1087         bl      kvmppc_msr_interrupt
1088 5:
1089 BEGIN_FTR_SECTION
1090         b       fast_guest_return
1091 END_FTR_SECTION_IFCLR(CPU_FTR_ARCH_300)
1092         /* On POWER9, check for pending doorbell requests */
1093         lbz     r0, VCPU_DBELL_REQ(r4)
1094         cmpwi   r0, 0
1095         beq     fast_guest_return
1096         ld      r5, HSTATE_KVM_VCORE(r13)
1097         /* Set DPDES register so the CPU will take a doorbell interrupt */
1098         li      r0, 1
1099         mtspr   SPRN_DPDES, r0
1100         std     r0, VCORE_DPDES(r5)
1101         /* Make sure other cpus see vcore->dpdes set before dbell req clear */
1102         lwsync
1103         /* Clear the pending doorbell request */
1104         li      r0, 0
1105         stb     r0, VCPU_DBELL_REQ(r4)
1106
1107 /*
1108  * Required state:
1109  * R4 = vcpu
1110  * R10: value for HSRR0
1111  * R11: value for HSRR1
1112  * R13 = PACA
1113  */
1114 fast_guest_return:
1115         li      r0,0
1116         stb     r0,VCPU_CEDED(r4)       /* cancel cede */
1117         mtspr   SPRN_HSRR0,r10
1118         mtspr   SPRN_HSRR1,r11
1119
1120         /* Activate guest mode, so faults get handled by KVM */
1121         li      r9, KVM_GUEST_MODE_GUEST_HV
1122         stb     r9, HSTATE_IN_GUEST(r13)
1123
1124 #ifdef CONFIG_KVM_BOOK3S_HV_EXIT_TIMING
1125         /* Accumulate timing */
1126         addi    r3, r4, VCPU_TB_GUEST
1127         bl      kvmhv_accumulate_time
1128 #endif
1129
1130         /* Enter guest */
1131
1132 BEGIN_FTR_SECTION
1133         ld      r5, VCPU_CFAR(r4)
1134         mtspr   SPRN_CFAR, r5
1135 END_FTR_SECTION_IFSET(CPU_FTR_CFAR)
1136 BEGIN_FTR_SECTION
1137         ld      r0, VCPU_PPR(r4)
1138 END_FTR_SECTION_IFSET(CPU_FTR_HAS_PPR)
1139
1140         ld      r5, VCPU_LR(r4)
1141         lwz     r6, VCPU_CR(r4)
1142         mtlr    r5
1143         mtcr    r6
1144
1145         ld      r1, VCPU_GPR(R1)(r4)
1146         ld      r2, VCPU_GPR(R2)(r4)
1147         ld      r3, VCPU_GPR(R3)(r4)
1148         ld      r5, VCPU_GPR(R5)(r4)
1149         ld      r6, VCPU_GPR(R6)(r4)
1150         ld      r7, VCPU_GPR(R7)(r4)
1151         ld      r8, VCPU_GPR(R8)(r4)
1152         ld      r9, VCPU_GPR(R9)(r4)
1153         ld      r10, VCPU_GPR(R10)(r4)
1154         ld      r11, VCPU_GPR(R11)(r4)
1155         ld      r12, VCPU_GPR(R12)(r4)
1156         ld      r13, VCPU_GPR(R13)(r4)
1157
1158 BEGIN_FTR_SECTION
1159         mtspr   SPRN_PPR, r0
1160 END_FTR_SECTION_IFSET(CPU_FTR_HAS_PPR)
1161
1162 /* Move canary into DSISR to check for later */
1163 BEGIN_FTR_SECTION
1164         li      r0, 0x7fff
1165         mtspr   SPRN_HDSISR, r0
1166 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_300)
1167
1168         ld      r0, VCPU_GPR(R0)(r4)
1169         ld      r4, VCPU_GPR(R4)(r4)
1170         HRFI_TO_GUEST
1171         b       .
1172
1173 secondary_too_late:
1174         li      r12, 0
1175         cmpdi   r4, 0
1176         beq     11f
1177         stw     r12, VCPU_TRAP(r4)
1178 #ifdef CONFIG_KVM_BOOK3S_HV_EXIT_TIMING
1179         addi    r3, r4, VCPU_TB_RMEXIT
1180         bl      kvmhv_accumulate_time
1181 #endif
1182 11:     b       kvmhv_switch_to_host
1183
1184 no_switch_exit:
1185         HMT_MEDIUM
1186         li      r12, 0
1187         b       12f
1188 hdec_soon:
1189         li      r12, BOOK3S_INTERRUPT_HV_DECREMENTER
1190 12:     stw     r12, VCPU_TRAP(r4)
1191         mr      r9, r4
1192 #ifdef CONFIG_KVM_BOOK3S_HV_EXIT_TIMING
1193         addi    r3, r4, VCPU_TB_RMEXIT
1194         bl      kvmhv_accumulate_time
1195 #endif
1196         b       guest_exit_cont
1197
1198 /******************************************************************************
1199  *                                                                            *
1200  *                               Exit code                                    *
1201  *                                                                            *
1202  *****************************************************************************/
1203
1204 /*
1205  * We come here from the first-level interrupt handlers.
1206  */
1207         .globl  kvmppc_interrupt_hv
1208 kvmppc_interrupt_hv:
1209         /*
1210          * Register contents:
1211          * R12          = (guest CR << 32) | interrupt vector
1212          * R13          = PACA
1213          * guest R12 saved in shadow VCPU SCRATCH0
1214          * guest CTR saved in shadow VCPU SCRATCH1 if RELOCATABLE
1215          * guest R13 saved in SPRN_SCRATCH0
1216          */
1217         std     r9, HSTATE_SCRATCH2(r13)
1218         lbz     r9, HSTATE_IN_GUEST(r13)
1219         cmpwi   r9, KVM_GUEST_MODE_HOST_HV
1220         beq     kvmppc_bad_host_intr
1221 #ifdef CONFIG_KVM_BOOK3S_PR_POSSIBLE
1222         cmpwi   r9, KVM_GUEST_MODE_GUEST
1223         ld      r9, HSTATE_SCRATCH2(r13)
1224         beq     kvmppc_interrupt_pr
1225 #endif
1226         /* We're now back in the host but in guest MMU context */
1227         li      r9, KVM_GUEST_MODE_HOST_HV
1228         stb     r9, HSTATE_IN_GUEST(r13)
1229
1230         ld      r9, HSTATE_KVM_VCPU(r13)
1231
1232         /* Save registers */
1233
1234         std     r0, VCPU_GPR(R0)(r9)
1235         std     r1, VCPU_GPR(R1)(r9)
1236         std     r2, VCPU_GPR(R2)(r9)
1237         std     r3, VCPU_GPR(R3)(r9)
1238         std     r4, VCPU_GPR(R4)(r9)
1239         std     r5, VCPU_GPR(R5)(r9)
1240         std     r6, VCPU_GPR(R6)(r9)
1241         std     r7, VCPU_GPR(R7)(r9)
1242         std     r8, VCPU_GPR(R8)(r9)
1243         ld      r0, HSTATE_SCRATCH2(r13)
1244         std     r0, VCPU_GPR(R9)(r9)
1245         std     r10, VCPU_GPR(R10)(r9)
1246         std     r11, VCPU_GPR(R11)(r9)
1247         ld      r3, HSTATE_SCRATCH0(r13)
1248         std     r3, VCPU_GPR(R12)(r9)
1249         /* CR is in the high half of r12 */
1250         srdi    r4, r12, 32
1251         stw     r4, VCPU_CR(r9)
1252 BEGIN_FTR_SECTION
1253         ld      r3, HSTATE_CFAR(r13)
1254         std     r3, VCPU_CFAR(r9)
1255 END_FTR_SECTION_IFSET(CPU_FTR_CFAR)
1256 BEGIN_FTR_SECTION
1257         ld      r4, HSTATE_PPR(r13)
1258         std     r4, VCPU_PPR(r9)
1259 END_FTR_SECTION_IFSET(CPU_FTR_HAS_PPR)
1260
1261         /* Restore R1/R2 so we can handle faults */
1262         ld      r1, HSTATE_HOST_R1(r13)
1263         ld      r2, PACATOC(r13)
1264
1265         mfspr   r10, SPRN_SRR0
1266         mfspr   r11, SPRN_SRR1
1267         std     r10, VCPU_SRR0(r9)
1268         std     r11, VCPU_SRR1(r9)
1269         /* trap is in the low half of r12, clear CR from the high half */
1270         clrldi  r12, r12, 32
1271         andi.   r0, r12, 2              /* need to read HSRR0/1? */
1272         beq     1f
1273         mfspr   r10, SPRN_HSRR0
1274         mfspr   r11, SPRN_HSRR1
1275         clrrdi  r12, r12, 2
1276 1:      std     r10, VCPU_PC(r9)
1277         std     r11, VCPU_MSR(r9)
1278
1279         GET_SCRATCH0(r3)
1280         mflr    r4
1281         std     r3, VCPU_GPR(R13)(r9)
1282         std     r4, VCPU_LR(r9)
1283
1284         stw     r12,VCPU_TRAP(r9)
1285
1286         /*
1287          * Now that we have saved away SRR0/1 and HSRR0/1,
1288          * interrupts are recoverable in principle, so set MSR_RI.
1289          * This becomes important for relocation-on interrupts from
1290          * the guest, which we can get in radix mode on POWER9.
1291          */
1292         li      r0, MSR_RI
1293         mtmsrd  r0, 1
1294
1295 #ifdef CONFIG_KVM_BOOK3S_HV_EXIT_TIMING
1296         addi    r3, r9, VCPU_TB_RMINTR
1297         mr      r4, r9
1298         bl      kvmhv_accumulate_time
1299         ld      r5, VCPU_GPR(R5)(r9)
1300         ld      r6, VCPU_GPR(R6)(r9)
1301         ld      r7, VCPU_GPR(R7)(r9)
1302         ld      r8, VCPU_GPR(R8)(r9)
1303 #endif
1304
1305         /* Save HEIR (HV emulation assist reg) in emul_inst
1306            if this is an HEI (HV emulation interrupt, e40) */
1307         li      r3,KVM_INST_FETCH_FAILED
1308         stw     r3,VCPU_LAST_INST(r9)
1309         cmpwi   r12,BOOK3S_INTERRUPT_H_EMUL_ASSIST
1310         bne     11f
1311         mfspr   r3,SPRN_HEIR
1312 11:     stw     r3,VCPU_HEIR(r9)
1313
1314         /* these are volatile across C function calls */
1315 #ifdef CONFIG_RELOCATABLE
1316         ld      r3, HSTATE_SCRATCH1(r13)
1317         mtctr   r3
1318 #else
1319         mfctr   r3
1320 #endif
1321         mfxer   r4
1322         std     r3, VCPU_CTR(r9)
1323         std     r4, VCPU_XER(r9)
1324
1325         /* If this is a page table miss then see if it's theirs or ours */
1326         cmpwi   r12, BOOK3S_INTERRUPT_H_DATA_STORAGE
1327         beq     kvmppc_hdsi
1328         cmpwi   r12, BOOK3S_INTERRUPT_H_INST_STORAGE
1329         beq     kvmppc_hisi
1330
1331         /* See if this is a leftover HDEC interrupt */
1332         cmpwi   r12,BOOK3S_INTERRUPT_HV_DECREMENTER
1333         bne     2f
1334         mfspr   r3,SPRN_HDEC
1335         EXTEND_HDEC(r3)
1336         cmpdi   r3,0
1337         mr      r4,r9
1338         bge     fast_guest_return
1339 2:
1340         /* See if this is an hcall we can handle in real mode */
1341         cmpwi   r12,BOOK3S_INTERRUPT_SYSCALL
1342         beq     hcall_try_real_mode
1343
1344         /* Hypervisor doorbell - exit only if host IPI flag set */
1345         cmpwi   r12, BOOK3S_INTERRUPT_H_DOORBELL
1346         bne     3f
1347 BEGIN_FTR_SECTION
1348         PPC_MSGSYNC
1349         lwsync
1350 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_300)
1351         lbz     r0, HSTATE_HOST_IPI(r13)
1352         cmpwi   r0, 0
1353         beq     4f
1354         b       guest_exit_cont
1355 3:
1356         /* If it's a hypervisor facility unavailable interrupt, save HFSCR */
1357         cmpwi   r12, BOOK3S_INTERRUPT_H_FAC_UNAVAIL
1358         bne     14f
1359         mfspr   r3, SPRN_HFSCR
1360         std     r3, VCPU_HFSCR(r9)
1361         b       guest_exit_cont
1362 14:
1363         /* External interrupt ? */
1364         cmpwi   r12, BOOK3S_INTERRUPT_EXTERNAL
1365         bne+    guest_exit_cont
1366
1367         /* External interrupt, first check for host_ipi. If this is
1368          * set, we know the host wants us out so let's do it now
1369          */
1370         bl      kvmppc_read_intr
1371
1372         /*
1373          * Restore the active volatile registers after returning from
1374          * a C function.
1375          */
1376         ld      r9, HSTATE_KVM_VCPU(r13)
1377         li      r12, BOOK3S_INTERRUPT_EXTERNAL
1378
1379         /*
1380          * kvmppc_read_intr return codes:
1381          *
1382          * Exit to host (r3 > 0)
1383          *   1 An interrupt is pending that needs to be handled by the host
1384          *     Exit guest and return to host by branching to guest_exit_cont
1385          *
1386          *   2 Passthrough that needs completion in the host
1387          *     Exit guest and return to host by branching to guest_exit_cont
1388          *     However, we also set r12 to BOOK3S_INTERRUPT_HV_RM_HARD
1389          *     to indicate to the host to complete handling the interrupt
1390          *
1391          * Before returning to guest, we check if any CPU is heading out
1392          * to the host and if so, we head out also. If no CPUs are heading
1393          * check return values <= 0.
1394          *
1395          * Return to guest (r3 <= 0)
1396          *  0 No external interrupt is pending
1397          * -1 A guest wakeup IPI (which has now been cleared)
1398          *    In either case, we return to guest to deliver any pending
1399          *    guest interrupts.
1400          *
1401          * -2 A PCI passthrough external interrupt was handled
1402          *    (interrupt was delivered directly to guest)
1403          *    Return to guest to deliver any pending guest interrupts.
1404          */
1405
1406         cmpdi   r3, 1
1407         ble     1f
1408
1409         /* Return code = 2 */
1410         li      r12, BOOK3S_INTERRUPT_HV_RM_HARD
1411         stw     r12, VCPU_TRAP(r9)
1412         b       guest_exit_cont
1413
1414 1:      /* Return code <= 1 */
1415         cmpdi   r3, 0
1416         bgt     guest_exit_cont
1417
1418         /* Return code <= 0 */
1419 4:      ld      r5, HSTATE_KVM_VCORE(r13)
1420         lwz     r0, VCORE_ENTRY_EXIT(r5)
1421         cmpwi   r0, 0x100
1422         mr      r4, r9
1423         blt     deliver_guest_interrupt
1424
1425 guest_exit_cont:                /* r9 = vcpu, r12 = trap, r13 = paca */
1426 #ifdef CONFIG_KVM_XICS
1427         /* We are exiting, pull the VP from the XIVE */
1428         lwz     r0, VCPU_XIVE_PUSHED(r9)
1429         cmpwi   cr0, r0, 0
1430         beq     1f
1431         li      r7, TM_SPC_PULL_OS_CTX
1432         li      r6, TM_QW1_OS
1433         mfmsr   r0
1434         andi.   r0, r0, MSR_IR          /* in real mode? */
1435         beq     2f
1436         ld      r10, HSTATE_XIVE_TIMA_VIRT(r13)
1437         cmpldi  cr0, r10, 0
1438         beq     1f
1439         /* First load to pull the context, we ignore the value */
1440         eieio
1441         lwzx    r11, r7, r10
1442         /* Second load to recover the context state (Words 0 and 1) */
1443         ldx     r11, r6, r10
1444         b       3f
1445 2:      ld      r10, HSTATE_XIVE_TIMA_PHYS(r13)
1446         cmpldi  cr0, r10, 0
1447         beq     1f
1448         /* First load to pull the context, we ignore the value */
1449         eieio
1450         lwzcix  r11, r7, r10
1451         /* Second load to recover the context state (Words 0 and 1) */
1452         ldcix   r11, r6, r10
1453 3:      std     r11, VCPU_XIVE_SAVED_STATE(r9)
1454         /* Fixup some of the state for the next load */
1455         li      r10, 0
1456         li      r0, 0xff
1457         stw     r10, VCPU_XIVE_PUSHED(r9)
1458         stb     r10, (VCPU_XIVE_SAVED_STATE+3)(r9)
1459         stb     r0, (VCPU_XIVE_SAVED_STATE+4)(r9)
1460         eieio
1461 1:
1462 #endif /* CONFIG_KVM_XICS */
1463         /* Save more register state  */
1464         mfdar   r6
1465         mfdsisr r7
1466         std     r6, VCPU_DAR(r9)
1467         stw     r7, VCPU_DSISR(r9)
1468         /* don't overwrite fault_dar/fault_dsisr if HDSI */
1469         cmpwi   r12,BOOK3S_INTERRUPT_H_DATA_STORAGE
1470         beq     mc_cont
1471         std     r6, VCPU_FAULT_DAR(r9)
1472         stw     r7, VCPU_FAULT_DSISR(r9)
1473
1474         /* See if it is a machine check */
1475         cmpwi   r12, BOOK3S_INTERRUPT_MACHINE_CHECK
1476         beq     machine_check_realmode
1477 mc_cont:
1478 #ifdef CONFIG_KVM_BOOK3S_HV_EXIT_TIMING
1479         addi    r3, r9, VCPU_TB_RMEXIT
1480         mr      r4, r9
1481         bl      kvmhv_accumulate_time
1482 #endif
1483
1484         mr      r3, r12
1485         /* Increment exit count, poke other threads to exit */
1486         bl      kvmhv_commence_exit
1487         nop
1488         ld      r9, HSTATE_KVM_VCPU(r13)
1489         lwz     r12, VCPU_TRAP(r9)
1490
1491         /* Stop others sending VCPU interrupts to this physical CPU */
1492         li      r0, -1
1493         stw     r0, VCPU_CPU(r9)
1494         stw     r0, VCPU_THREAD_CPU(r9)
1495
1496         /* Save guest CTRL register, set runlatch to 1 */
1497         mfspr   r6,SPRN_CTRLF
1498         stw     r6,VCPU_CTRL(r9)
1499         andi.   r0,r6,1
1500         bne     4f
1501         ori     r6,r6,1
1502         mtspr   SPRN_CTRLT,r6
1503 4:
1504         /* Check if we are running hash or radix and store it in cr2 */
1505         ld      r5, VCPU_KVM(r9)
1506         lbz     r0, KVM_RADIX(r5)
1507         cmpwi   cr2,r0,0
1508
1509         /* Read the guest SLB and save it away */
1510         li      r5, 0
1511         bne     cr2, 3f                 /* for radix, save 0 entries */
1512         lwz     r0,VCPU_SLB_NR(r9)      /* number of entries in SLB */
1513         mtctr   r0
1514         li      r6,0
1515         addi    r7,r9,VCPU_SLB
1516 1:      slbmfee r8,r6
1517         andis.  r0,r8,SLB_ESID_V@h
1518         beq     2f
1519         add     r8,r8,r6                /* put index in */
1520         slbmfev r3,r6
1521         std     r8,VCPU_SLB_E(r7)
1522         std     r3,VCPU_SLB_V(r7)
1523         addi    r7,r7,VCPU_SLB_SIZE
1524         addi    r5,r5,1
1525 2:      addi    r6,r6,1
1526         bdnz    1b
1527 3:      stw     r5,VCPU_SLB_MAX(r9)
1528
1529         /*
1530          * Save the guest PURR/SPURR
1531          */
1532         mfspr   r5,SPRN_PURR
1533         mfspr   r6,SPRN_SPURR
1534         ld      r7,VCPU_PURR(r9)
1535         ld      r8,VCPU_SPURR(r9)
1536         std     r5,VCPU_PURR(r9)
1537         std     r6,VCPU_SPURR(r9)
1538         subf    r5,r7,r5
1539         subf    r6,r8,r6
1540
1541         /*
1542          * Restore host PURR/SPURR and add guest times
1543          * so that the time in the guest gets accounted.
1544          */
1545         ld      r3,HSTATE_PURR(r13)
1546         ld      r4,HSTATE_SPURR(r13)
1547         add     r3,r3,r5
1548         add     r4,r4,r6
1549         mtspr   SPRN_PURR,r3
1550         mtspr   SPRN_SPURR,r4
1551
1552         /* Save DEC */
1553         ld      r3, HSTATE_KVM_VCORE(r13)
1554         mfspr   r5,SPRN_DEC
1555         mftb    r6
1556         /* On P9, if the guest has large decr enabled, don't sign extend */
1557 BEGIN_FTR_SECTION
1558         ld      r4, VCORE_LPCR(r3)
1559         andis.  r4, r4, LPCR_LD@h
1560         bne     16f
1561 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_300)
1562         extsw   r5,r5
1563 16:     add     r5,r5,r6
1564         /* r5 is a guest timebase value here, convert to host TB */
1565         ld      r4,VCORE_TB_OFFSET(r3)
1566         subf    r5,r4,r5
1567         std     r5,VCPU_DEC_EXPIRES(r9)
1568
1569 BEGIN_FTR_SECTION
1570         b       8f
1571 END_FTR_SECTION_IFCLR(CPU_FTR_ARCH_207S)
1572         /* Save POWER8-specific registers */
1573         mfspr   r5, SPRN_IAMR
1574         mfspr   r6, SPRN_PSPB
1575         mfspr   r7, SPRN_FSCR
1576         std     r5, VCPU_IAMR(r9)
1577         stw     r6, VCPU_PSPB(r9)
1578         std     r7, VCPU_FSCR(r9)
1579         mfspr   r5, SPRN_IC
1580         mfspr   r7, SPRN_TAR
1581         std     r5, VCPU_IC(r9)
1582         std     r7, VCPU_TAR(r9)
1583         mfspr   r8, SPRN_EBBHR
1584         std     r8, VCPU_EBBHR(r9)
1585         mfspr   r5, SPRN_EBBRR
1586         mfspr   r6, SPRN_BESCR
1587         mfspr   r7, SPRN_PID
1588         mfspr   r8, SPRN_WORT
1589         std     r5, VCPU_EBBRR(r9)
1590         std     r6, VCPU_BESCR(r9)
1591         stw     r7, VCPU_GUEST_PID(r9)
1592         std     r8, VCPU_WORT(r9)
1593 BEGIN_FTR_SECTION
1594         mfspr   r5, SPRN_TCSCR
1595         mfspr   r6, SPRN_ACOP
1596         mfspr   r7, SPRN_CSIGR
1597         mfspr   r8, SPRN_TACR
1598         std     r5, VCPU_TCSCR(r9)
1599         std     r6, VCPU_ACOP(r9)
1600         std     r7, VCPU_CSIGR(r9)
1601         std     r8, VCPU_TACR(r9)
1602 FTR_SECTION_ELSE
1603         mfspr   r5, SPRN_TIDR
1604         mfspr   r6, SPRN_PSSCR
1605         std     r5, VCPU_TID(r9)
1606         rldicl  r6, r6, 4, 50           /* r6 &= PSSCR_GUEST_VIS */
1607         rotldi  r6, r6, 60
1608         std     r6, VCPU_PSSCR(r9)
1609         /* Restore host HFSCR value */
1610         ld      r7, STACK_SLOT_HFSCR(r1)
1611         mtspr   SPRN_HFSCR, r7
1612 ALT_FTR_SECTION_END_IFCLR(CPU_FTR_ARCH_300)
1613         /*
1614          * Restore various registers to 0, where non-zero values
1615          * set by the guest could disrupt the host.
1616          */
1617         li      r0, 0
1618         mtspr   SPRN_PSPB, r0
1619         mtspr   SPRN_WORT, r0
1620 BEGIN_FTR_SECTION
1621         mtspr   SPRN_IAMR, r0
1622         mtspr   SPRN_TCSCR, r0
1623         /* Set MMCRS to 1<<31 to freeze and disable the SPMC counters */
1624         li      r0, 1
1625         sldi    r0, r0, 31
1626         mtspr   SPRN_MMCRS, r0
1627 END_FTR_SECTION_IFCLR(CPU_FTR_ARCH_300)
1628 8:
1629
1630         /* Save and reset AMR and UAMOR before turning on the MMU */
1631         mfspr   r5,SPRN_AMR
1632         mfspr   r6,SPRN_UAMOR
1633         std     r5,VCPU_AMR(r9)
1634         std     r6,VCPU_UAMOR(r9)
1635         li      r6,0
1636         mtspr   SPRN_AMR,r6
1637         mtspr   SPRN_UAMOR, r6
1638
1639         /* Switch DSCR back to host value */
1640         mfspr   r8, SPRN_DSCR
1641         ld      r7, HSTATE_DSCR(r13)
1642         std     r8, VCPU_DSCR(r9)
1643         mtspr   SPRN_DSCR, r7
1644
1645         /* Save non-volatile GPRs */
1646         std     r14, VCPU_GPR(R14)(r9)
1647         std     r15, VCPU_GPR(R15)(r9)
1648         std     r16, VCPU_GPR(R16)(r9)
1649         std     r17, VCPU_GPR(R17)(r9)
1650         std     r18, VCPU_GPR(R18)(r9)
1651         std     r19, VCPU_GPR(R19)(r9)
1652         std     r20, VCPU_GPR(R20)(r9)
1653         std     r21, VCPU_GPR(R21)(r9)
1654         std     r22, VCPU_GPR(R22)(r9)
1655         std     r23, VCPU_GPR(R23)(r9)
1656         std     r24, VCPU_GPR(R24)(r9)
1657         std     r25, VCPU_GPR(R25)(r9)
1658         std     r26, VCPU_GPR(R26)(r9)
1659         std     r27, VCPU_GPR(R27)(r9)
1660         std     r28, VCPU_GPR(R28)(r9)
1661         std     r29, VCPU_GPR(R29)(r9)
1662         std     r30, VCPU_GPR(R30)(r9)
1663         std     r31, VCPU_GPR(R31)(r9)
1664
1665         /* Save SPRGs */
1666         mfspr   r3, SPRN_SPRG0
1667         mfspr   r4, SPRN_SPRG1
1668         mfspr   r5, SPRN_SPRG2
1669         mfspr   r6, SPRN_SPRG3
1670         std     r3, VCPU_SPRG0(r9)
1671         std     r4, VCPU_SPRG1(r9)
1672         std     r5, VCPU_SPRG2(r9)
1673         std     r6, VCPU_SPRG3(r9)
1674
1675         /* save FP state */
1676         mr      r3, r9
1677         bl      kvmppc_save_fp
1678
1679 #ifdef CONFIG_PPC_TRANSACTIONAL_MEM
1680 BEGIN_FTR_SECTION
1681         /*
1682          * NOTE THAT THIS TRASHES ALL NON-VOLATILE REGISTERS INCLUDING CR
1683          */
1684         bl      kvmppc_save_tm
1685 END_FTR_SECTION_IFSET(CPU_FTR_TM)
1686 #endif
1687
1688         /* Increment yield count if they have a VPA */
1689         ld      r8, VCPU_VPA(r9)        /* do they have a VPA? */
1690         cmpdi   r8, 0
1691         beq     25f
1692         li      r4, LPPACA_YIELDCOUNT
1693         LWZX_BE r3, r8, r4
1694         addi    r3, r3, 1
1695         STWX_BE r3, r8, r4
1696         li      r3, 1
1697         stb     r3, VCPU_VPA_DIRTY(r9)
1698 25:
1699         /* Save PMU registers if requested */
1700         /* r8 and cr0.eq are live here */
1701 BEGIN_FTR_SECTION
1702         /*
1703          * POWER8 seems to have a hardware bug where setting
1704          * MMCR0[PMAE] along with MMCR0[PMC1CE] and/or MMCR0[PMCjCE]
1705          * when some counters are already negative doesn't seem
1706          * to cause a performance monitor alert (and hence interrupt).
1707          * The effect of this is that when saving the PMU state,
1708          * if there is no PMU alert pending when we read MMCR0
1709          * before freezing the counters, but one becomes pending
1710          * before we read the counters, we lose it.
1711          * To work around this, we need a way to freeze the counters
1712          * before reading MMCR0.  Normally, freezing the counters
1713          * is done by writing MMCR0 (to set MMCR0[FC]) which
1714          * unavoidably writes MMCR0[PMA0] as well.  On POWER8,
1715          * we can also freeze the counters using MMCR2, by writing
1716          * 1s to all the counter freeze condition bits (there are
1717          * 9 bits each for 6 counters).
1718          */
1719         li      r3, -1                  /* set all freeze bits */
1720         clrrdi  r3, r3, 10
1721         mfspr   r10, SPRN_MMCR2
1722         mtspr   SPRN_MMCR2, r3
1723         isync
1724 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_207S)
1725         li      r3, 1
1726         sldi    r3, r3, 31              /* MMCR0_FC (freeze counters) bit */
1727         mfspr   r4, SPRN_MMCR0          /* save MMCR0 */
1728         mtspr   SPRN_MMCR0, r3          /* freeze all counters, disable ints */
1729         mfspr   r6, SPRN_MMCRA
1730         /* Clear MMCRA in order to disable SDAR updates */
1731         li      r7, 0
1732         mtspr   SPRN_MMCRA, r7
1733         isync
1734         beq     21f                     /* if no VPA, save PMU stuff anyway */
1735         lbz     r7, LPPACA_PMCINUSE(r8)
1736         cmpwi   r7, 0                   /* did they ask for PMU stuff to be saved? */
1737         bne     21f
1738         std     r3, VCPU_MMCR(r9)       /* if not, set saved MMCR0 to FC */
1739         b       22f
1740 21:     mfspr   r5, SPRN_MMCR1
1741         mfspr   r7, SPRN_SIAR
1742         mfspr   r8, SPRN_SDAR
1743         std     r4, VCPU_MMCR(r9)
1744         std     r5, VCPU_MMCR + 8(r9)
1745         std     r6, VCPU_MMCR + 16(r9)
1746 BEGIN_FTR_SECTION
1747         std     r10, VCPU_MMCR + 24(r9)
1748 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_207S)
1749         std     r7, VCPU_SIAR(r9)
1750         std     r8, VCPU_SDAR(r9)
1751         mfspr   r3, SPRN_PMC1
1752         mfspr   r4, SPRN_PMC2
1753         mfspr   r5, SPRN_PMC3
1754         mfspr   r6, SPRN_PMC4
1755         mfspr   r7, SPRN_PMC5
1756         mfspr   r8, SPRN_PMC6
1757         stw     r3, VCPU_PMC(r9)
1758         stw     r4, VCPU_PMC + 4(r9)
1759         stw     r5, VCPU_PMC + 8(r9)
1760         stw     r6, VCPU_PMC + 12(r9)
1761         stw     r7, VCPU_PMC + 16(r9)
1762         stw     r8, VCPU_PMC + 20(r9)
1763 BEGIN_FTR_SECTION
1764         mfspr   r5, SPRN_SIER
1765         std     r5, VCPU_SIER(r9)
1766 BEGIN_FTR_SECTION_NESTED(96)
1767         mfspr   r6, SPRN_SPMC1
1768         mfspr   r7, SPRN_SPMC2
1769         mfspr   r8, SPRN_MMCRS
1770         stw     r6, VCPU_PMC + 24(r9)
1771         stw     r7, VCPU_PMC + 28(r9)
1772         std     r8, VCPU_MMCR + 32(r9)
1773         lis     r4, 0x8000
1774         mtspr   SPRN_MMCRS, r4
1775 END_FTR_SECTION_NESTED(CPU_FTR_ARCH_300, 0, 96)
1776 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_207S)
1777 22:
1778
1779         /* Restore host values of some registers */
1780 BEGIN_FTR_SECTION
1781         ld      r5, STACK_SLOT_CIABR(r1)
1782         ld      r6, STACK_SLOT_DAWR(r1)
1783         ld      r7, STACK_SLOT_DAWRX(r1)
1784         mtspr   SPRN_CIABR, r5
1785         mtspr   SPRN_DAWR, r6
1786         mtspr   SPRN_DAWRX, r7
1787 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_207S)
1788 BEGIN_FTR_SECTION
1789         ld      r5, STACK_SLOT_TID(r1)
1790         ld      r6, STACK_SLOT_PSSCR(r1)
1791         ld      r7, STACK_SLOT_PID(r1)
1792         ld      r8, STACK_SLOT_IAMR(r1)
1793         mtspr   SPRN_TIDR, r5
1794         mtspr   SPRN_PSSCR, r6
1795         mtspr   SPRN_PID, r7
1796         mtspr   SPRN_IAMR, r8
1797 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_300)
1798
1799 #ifdef CONFIG_PPC_RADIX_MMU
1800         /*
1801          * Are we running hash or radix ?
1802          */
1803         ld      r5, VCPU_KVM(r9)
1804         lbz     r0, KVM_RADIX(r5)
1805         cmpwi   cr2, r0, 0
1806         beq     cr2, 3f
1807
1808         /* Radix: Handle the case where the guest used an illegal PID */
1809         LOAD_REG_ADDR(r4, mmu_base_pid)
1810         lwz     r3, VCPU_GUEST_PID(r9)
1811         lwz     r5, 0(r4)
1812         cmpw    cr0,r3,r5
1813         blt     2f
1814
1815         /*
1816          * Illegal PID, the HW might have prefetched and cached in the TLB
1817          * some translations for the  LPID 0 / guest PID combination which
1818          * Linux doesn't know about, so we need to flush that PID out of
1819          * the TLB. First we need to set LPIDR to 0 so tlbiel applies to
1820          * the right context.
1821         */
1822         li      r0,0
1823         mtspr   SPRN_LPID,r0
1824         isync
1825
1826         /* Then do a congruence class local flush */
1827         ld      r6,VCPU_KVM(r9)
1828         lwz     r0,KVM_TLB_SETS(r6)
1829         mtctr   r0
1830         li      r7,0x400                /* IS field = 0b01 */
1831         ptesync
1832         sldi    r0,r3,32                /* RS has PID */
1833 1:      PPC_TLBIEL(7,0,2,1,1)           /* RIC=2, PRS=1, R=1 */
1834         addi    r7,r7,0x1000
1835         bdnz    1b
1836         ptesync
1837
1838 2:      /* Flush the ERAT on radix P9 DD1 guest exit */
1839 BEGIN_FTR_SECTION
1840         PPC_INVALIDATE_ERAT
1841 END_FTR_SECTION_IFSET(CPU_FTR_POWER9_DD1)
1842         b       4f
1843 #endif /* CONFIG_PPC_RADIX_MMU */
1844
1845         /* Hash: clear out SLB */
1846 3:      li      r5,0
1847         slbmte  r5,r5
1848         slbia
1849         ptesync
1850 4:
1851         /*
1852          * POWER7/POWER8 guest -> host partition switch code.
1853          * We don't have to lock against tlbies but we do
1854          * have to coordinate the hardware threads.
1855          */
1856 kvmhv_switch_to_host:
1857         /* Secondary threads wait for primary to do partition switch */
1858         ld      r5,HSTATE_KVM_VCORE(r13)
1859         ld      r4,VCORE_KVM(r5)        /* pointer to struct kvm */
1860         lbz     r3,HSTATE_PTID(r13)
1861         cmpwi   r3,0
1862         beq     15f
1863         HMT_LOW
1864 13:     lbz     r3,VCORE_IN_GUEST(r5)
1865         cmpwi   r3,0
1866         bne     13b
1867         HMT_MEDIUM
1868         b       16f
1869
1870         /* Primary thread waits for all the secondaries to exit guest */
1871 15:     lwz     r3,VCORE_ENTRY_EXIT(r5)
1872         rlwinm  r0,r3,32-8,0xff
1873         clrldi  r3,r3,56
1874         cmpw    r3,r0
1875         bne     15b
1876         isync
1877
1878         /* Did we actually switch to the guest at all? */
1879         lbz     r6, VCORE_IN_GUEST(r5)
1880         cmpwi   r6, 0
1881         beq     19f
1882
1883         /* Primary thread switches back to host partition */
1884         lwz     r7,KVM_HOST_LPID(r4)
1885 BEGIN_FTR_SECTION
1886         ld      r6,KVM_HOST_SDR1(r4)
1887         li      r8,LPID_RSVD            /* switch to reserved LPID */
1888         mtspr   SPRN_LPID,r8
1889         ptesync
1890         mtspr   SPRN_SDR1,r6            /* switch to host page table */
1891 END_FTR_SECTION_IFCLR(CPU_FTR_ARCH_300)
1892         mtspr   SPRN_LPID,r7
1893         isync
1894
1895 BEGIN_FTR_SECTION
1896         /* DPDES and VTB are shared between threads */
1897         mfspr   r7, SPRN_DPDES
1898         mfspr   r8, SPRN_VTB
1899         std     r7, VCORE_DPDES(r5)
1900         std     r8, VCORE_VTB(r5)
1901         /* clear DPDES so we don't get guest doorbells in the host */
1902         li      r8, 0
1903         mtspr   SPRN_DPDES, r8
1904 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_207S)
1905
1906         /* If HMI, call kvmppc_realmode_hmi_handler() */
1907         cmpwi   r12, BOOK3S_INTERRUPT_HMI
1908         bne     27f
1909         bl      kvmppc_realmode_hmi_handler
1910         nop
1911         li      r12, BOOK3S_INTERRUPT_HMI
1912         /*
1913          * At this point kvmppc_realmode_hmi_handler would have resync-ed
1914          * the TB. Hence it is not required to subtract guest timebase
1915          * offset from timebase. So, skip it.
1916          *
1917          * Also, do not call kvmppc_subcore_exit_guest() because it has
1918          * been invoked as part of kvmppc_realmode_hmi_handler().
1919          */
1920         b       30f
1921
1922 27:
1923         /* Subtract timebase offset from timebase */
1924         ld      r8,VCORE_TB_OFFSET(r5)
1925         cmpdi   r8,0
1926         beq     17f
1927         mftb    r6                      /* current guest timebase */
1928         subf    r8,r8,r6
1929         mtspr   SPRN_TBU40,r8           /* update upper 40 bits */
1930         mftb    r7                      /* check if lower 24 bits overflowed */
1931         clrldi  r6,r6,40
1932         clrldi  r7,r7,40
1933         cmpld   r7,r6
1934         bge     17f
1935         addis   r8,r8,0x100             /* if so, increment upper 40 bits */
1936         mtspr   SPRN_TBU40,r8
1937
1938 17:     bl      kvmppc_subcore_exit_guest
1939         nop
1940 30:     ld      r5,HSTATE_KVM_VCORE(r13)
1941         ld      r4,VCORE_KVM(r5)        /* pointer to struct kvm */
1942
1943         /* Reset PCR */
1944         ld      r0, VCORE_PCR(r5)
1945         cmpdi   r0, 0
1946         beq     18f
1947         li      r0, 0
1948         mtspr   SPRN_PCR, r0
1949 18:
1950         /* Signal secondary CPUs to continue */
1951         stb     r0,VCORE_IN_GUEST(r5)
1952 19:     lis     r8,0x7fff               /* MAX_INT@h */
1953         mtspr   SPRN_HDEC,r8
1954
1955 16:
1956 BEGIN_FTR_SECTION
1957         /* On POWER9 with HPT-on-radix we need to wait for all other threads */
1958         ld      r3, HSTATE_SPLIT_MODE(r13)
1959         cmpdi   r3, 0
1960         beq     47f
1961         lwz     r8, KVM_SPLIT_DO_RESTORE(r3)
1962         cmpwi   r8, 0
1963         beq     47f
1964         stw     r12, STACK_SLOT_TRAP(r1)
1965         bl      kvmhv_p9_restore_lpcr
1966         nop
1967         lwz     r12, STACK_SLOT_TRAP(r1)
1968         b       48f
1969 47:
1970 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_300)
1971         ld      r8,KVM_HOST_LPCR(r4)
1972         mtspr   SPRN_LPCR,r8
1973         isync
1974 48:
1975         /* load host SLB entries */
1976 BEGIN_MMU_FTR_SECTION
1977         b       0f
1978 END_MMU_FTR_SECTION_IFSET(MMU_FTR_TYPE_RADIX)
1979         ld      r8,PACA_SLBSHADOWPTR(r13)
1980
1981         .rept   SLB_NUM_BOLTED
1982         li      r3, SLBSHADOW_SAVEAREA
1983         LDX_BE  r5, r8, r3
1984         addi    r3, r3, 8
1985         LDX_BE  r6, r8, r3
1986         andis.  r7,r5,SLB_ESID_V@h
1987         beq     1f
1988         slbmte  r6,r5
1989 1:      addi    r8,r8,16
1990         .endr
1991 0:
1992 #ifdef CONFIG_KVM_BOOK3S_HV_EXIT_TIMING
1993         /* Finish timing, if we have a vcpu */
1994         ld      r4, HSTATE_KVM_VCPU(r13)
1995         cmpdi   r4, 0
1996         li      r3, 0
1997         beq     2f
1998         bl      kvmhv_accumulate_time
1999 2:
2000 #endif
2001         /* Unset guest mode */
2002         li      r0, KVM_GUEST_MODE_NONE
2003         stb     r0, HSTATE_IN_GUEST(r13)
2004
2005         ld      r0, SFS+PPC_LR_STKOFF(r1)
2006         addi    r1, r1, SFS
2007         mtlr    r0
2008         blr
2009
2010 /*
2011  * Check whether an HDSI is an HPTE not found fault or something else.
2012  * If it is an HPTE not found fault that is due to the guest accessing
2013  * a page that they have mapped but which we have paged out, then
2014  * we continue on with the guest exit path.  In all other cases,
2015  * reflect the HDSI to the guest as a DSI.
2016  */
2017 kvmppc_hdsi:
2018         ld      r3, VCPU_KVM(r9)
2019         lbz     r0, KVM_RADIX(r3)
2020         mfspr   r4, SPRN_HDAR
2021         mfspr   r6, SPRN_HDSISR
2022 BEGIN_FTR_SECTION
2023         /* Look for DSISR canary. If we find it, retry instruction */
2024         cmpdi   r6, 0x7fff
2025         beq     6f
2026 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_300)
2027         cmpwi   r0, 0
2028         bne     .Lradix_hdsi            /* on radix, just save DAR/DSISR/ASDR */
2029         /* HPTE not found fault or protection fault? */
2030         andis.  r0, r6, (DSISR_NOHPTE | DSISR_PROTFAULT)@h
2031         beq     1f                      /* if not, send it to the guest */
2032         andi.   r0, r11, MSR_DR         /* data relocation enabled? */
2033         beq     3f
2034 BEGIN_FTR_SECTION
2035         mfspr   r5, SPRN_ASDR           /* on POWER9, use ASDR to get VSID */
2036         b       4f
2037 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_300)
2038         clrrdi  r0, r4, 28
2039         PPC_SLBFEE_DOT(R5, R0)          /* if so, look up SLB */
2040         li      r0, BOOK3S_INTERRUPT_DATA_SEGMENT
2041         bne     7f                      /* if no SLB entry found */
2042 4:      std     r4, VCPU_FAULT_DAR(r9)
2043         stw     r6, VCPU_FAULT_DSISR(r9)
2044
2045         /* Search the hash table. */
2046         mr      r3, r9                  /* vcpu pointer */
2047         li      r7, 1                   /* data fault */
2048         bl      kvmppc_hpte_hv_fault
2049         ld      r9, HSTATE_KVM_VCPU(r13)
2050         ld      r10, VCPU_PC(r9)
2051         ld      r11, VCPU_MSR(r9)
2052         li      r12, BOOK3S_INTERRUPT_H_DATA_STORAGE
2053         cmpdi   r3, 0                   /* retry the instruction */
2054         beq     6f
2055         cmpdi   r3, -1                  /* handle in kernel mode */
2056         beq     guest_exit_cont
2057         cmpdi   r3, -2                  /* MMIO emulation; need instr word */
2058         beq     2f
2059
2060         /* Synthesize a DSI (or DSegI) for the guest */
2061         ld      r4, VCPU_FAULT_DAR(r9)
2062         mr      r6, r3
2063 1:      li      r0, BOOK3S_INTERRUPT_DATA_STORAGE
2064         mtspr   SPRN_DSISR, r6
2065 7:      mtspr   SPRN_DAR, r4
2066         mtspr   SPRN_SRR0, r10
2067         mtspr   SPRN_SRR1, r11
2068         mr      r10, r0
2069         bl      kvmppc_msr_interrupt
2070 fast_interrupt_c_return:
2071 6:      ld      r7, VCPU_CTR(r9)
2072         ld      r8, VCPU_XER(r9)
2073         mtctr   r7
2074         mtxer   r8
2075         mr      r4, r9
2076         b       fast_guest_return
2077
2078 3:      ld      r5, VCPU_KVM(r9)        /* not relocated, use VRMA */
2079         ld      r5, KVM_VRMA_SLB_V(r5)
2080         b       4b
2081
2082         /* If this is for emulated MMIO, load the instruction word */
2083 2:      li      r8, KVM_INST_FETCH_FAILED       /* In case lwz faults */
2084
2085         /* Set guest mode to 'jump over instruction' so if lwz faults
2086          * we'll just continue at the next IP. */
2087         li      r0, KVM_GUEST_MODE_SKIP
2088         stb     r0, HSTATE_IN_GUEST(r13)
2089
2090         /* Do the access with MSR:DR enabled */
2091         mfmsr   r3
2092         ori     r4, r3, MSR_DR          /* Enable paging for data */
2093         mtmsrd  r4
2094         lwz     r8, 0(r10)
2095         mtmsrd  r3
2096
2097         /* Store the result */
2098         stw     r8, VCPU_LAST_INST(r9)
2099
2100         /* Unset guest mode. */
2101         li      r0, KVM_GUEST_MODE_HOST_HV
2102         stb     r0, HSTATE_IN_GUEST(r13)
2103         b       guest_exit_cont
2104
2105 .Lradix_hdsi:
2106         std     r4, VCPU_FAULT_DAR(r9)
2107         stw     r6, VCPU_FAULT_DSISR(r9)
2108 .Lradix_hisi:
2109         mfspr   r5, SPRN_ASDR
2110         std     r5, VCPU_FAULT_GPA(r9)
2111         b       guest_exit_cont
2112
2113 /*
2114  * Similarly for an HISI, reflect it to the guest as an ISI unless
2115  * it is an HPTE not found fault for a page that we have paged out.
2116  */
2117 kvmppc_hisi:
2118         ld      r3, VCPU_KVM(r9)
2119         lbz     r0, KVM_RADIX(r3)
2120         cmpwi   r0, 0
2121         bne     .Lradix_hisi            /* for radix, just save ASDR */
2122         andis.  r0, r11, SRR1_ISI_NOPT@h
2123         beq     1f
2124         andi.   r0, r11, MSR_IR         /* instruction relocation enabled? */
2125         beq     3f
2126 BEGIN_FTR_SECTION
2127         mfspr   r5, SPRN_ASDR           /* on POWER9, use ASDR to get VSID */
2128         b       4f
2129 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_300)
2130         clrrdi  r0, r10, 28
2131         PPC_SLBFEE_DOT(R5, R0)          /* if so, look up SLB */
2132         li      r0, BOOK3S_INTERRUPT_INST_SEGMENT
2133         bne     7f                      /* if no SLB entry found */
2134 4:
2135         /* Search the hash table. */
2136         mr      r3, r9                  /* vcpu pointer */
2137         mr      r4, r10
2138         mr      r6, r11
2139         li      r7, 0                   /* instruction fault */
2140         bl      kvmppc_hpte_hv_fault
2141         ld      r9, HSTATE_KVM_VCPU(r13)
2142         ld      r10, VCPU_PC(r9)
2143         ld      r11, VCPU_MSR(r9)
2144         li      r12, BOOK3S_INTERRUPT_H_INST_STORAGE
2145         cmpdi   r3, 0                   /* retry the instruction */
2146         beq     fast_interrupt_c_return
2147         cmpdi   r3, -1                  /* handle in kernel mode */
2148         beq     guest_exit_cont
2149
2150         /* Synthesize an ISI (or ISegI) for the guest */
2151         mr      r11, r3
2152 1:      li      r0, BOOK3S_INTERRUPT_INST_STORAGE
2153 7:      mtspr   SPRN_SRR0, r10
2154         mtspr   SPRN_SRR1, r11
2155         mr      r10, r0
2156         bl      kvmppc_msr_interrupt
2157         b       fast_interrupt_c_return
2158
2159 3:      ld      r6, VCPU_KVM(r9)        /* not relocated, use VRMA */
2160         ld      r5, KVM_VRMA_SLB_V(r6)
2161         b       4b
2162
2163 /*
2164  * Try to handle an hcall in real mode.
2165  * Returns to the guest if we handle it, or continues on up to
2166  * the kernel if we can't (i.e. if we don't have a handler for
2167  * it, or if the handler returns H_TOO_HARD).
2168  *
2169  * r5 - r8 contain hcall args,
2170  * r9 = vcpu, r10 = pc, r11 = msr, r12 = trap, r13 = paca
2171  */
2172 hcall_try_real_mode:
2173         ld      r3,VCPU_GPR(R3)(r9)
2174         andi.   r0,r11,MSR_PR
2175         /* sc 1 from userspace - reflect to guest syscall */
2176         bne     sc_1_fast_return
2177         clrrdi  r3,r3,2
2178         cmpldi  r3,hcall_real_table_end - hcall_real_table
2179         bge     guest_exit_cont
2180         /* See if this hcall is enabled for in-kernel handling */
2181         ld      r4, VCPU_KVM(r9)
2182         srdi    r0, r3, 8       /* r0 = (r3 / 4) >> 6 */
2183         sldi    r0, r0, 3       /* index into kvm->arch.enabled_hcalls[] */
2184         add     r4, r4, r0
2185         ld      r0, KVM_ENABLED_HCALLS(r4)
2186         rlwinm  r4, r3, 32-2, 0x3f      /* r4 = (r3 / 4) & 0x3f */
2187         srd     r0, r0, r4
2188         andi.   r0, r0, 1
2189         beq     guest_exit_cont
2190         /* Get pointer to handler, if any, and call it */
2191         LOAD_REG_ADDR(r4, hcall_real_table)
2192         lwax    r3,r3,r4
2193         cmpwi   r3,0
2194         beq     guest_exit_cont
2195         add     r12,r3,r4
2196         mtctr   r12
2197         mr      r3,r9           /* get vcpu pointer */
2198         ld      r4,VCPU_GPR(R4)(r9)
2199         bctrl
2200         cmpdi   r3,H_TOO_HARD
2201         beq     hcall_real_fallback
2202         ld      r4,HSTATE_KVM_VCPU(r13)
2203         std     r3,VCPU_GPR(R3)(r4)
2204         ld      r10,VCPU_PC(r4)
2205         ld      r11,VCPU_MSR(r4)
2206         b       fast_guest_return
2207
2208 sc_1_fast_return:
2209         mtspr   SPRN_SRR0,r10
2210         mtspr   SPRN_SRR1,r11
2211         li      r10, BOOK3S_INTERRUPT_SYSCALL
2212         bl      kvmppc_msr_interrupt
2213         mr      r4,r9
2214         b       fast_guest_return
2215
2216         /* We've attempted a real mode hcall, but it's punted it back
2217          * to userspace.  We need to restore some clobbered volatiles
2218          * before resuming the pass-it-to-qemu path */
2219 hcall_real_fallback:
2220         li      r12,BOOK3S_INTERRUPT_SYSCALL
2221         ld      r9, HSTATE_KVM_VCPU(r13)
2222
2223         b       guest_exit_cont
2224
2225         .globl  hcall_real_table
2226 hcall_real_table:
2227         .long   0               /* 0 - unused */
2228         .long   DOTSYM(kvmppc_h_remove) - hcall_real_table
2229         .long   DOTSYM(kvmppc_h_enter) - hcall_real_table
2230         .long   DOTSYM(kvmppc_h_read) - hcall_real_table
2231         .long   DOTSYM(kvmppc_h_clear_mod) - hcall_real_table
2232         .long   DOTSYM(kvmppc_h_clear_ref) - hcall_real_table
2233         .long   DOTSYM(kvmppc_h_protect) - hcall_real_table
2234         .long   DOTSYM(kvmppc_h_get_tce) - hcall_real_table
2235         .long   DOTSYM(kvmppc_rm_h_put_tce) - hcall_real_table
2236         .long   0               /* 0x24 - H_SET_SPRG0 */
2237         .long   DOTSYM(kvmppc_h_set_dabr) - hcall_real_table
2238         .long   0               /* 0x2c */
2239         .long   0               /* 0x30 */
2240         .long   0               /* 0x34 */
2241         .long   0               /* 0x38 */
2242         .long   0               /* 0x3c */
2243         .long   0               /* 0x40 */
2244         .long   0               /* 0x44 */
2245         .long   0               /* 0x48 */
2246         .long   0               /* 0x4c */
2247         .long   0               /* 0x50 */
2248         .long   0               /* 0x54 */
2249         .long   0               /* 0x58 */
2250         .long   0               /* 0x5c */
2251         .long   0               /* 0x60 */
2252 #ifdef CONFIG_KVM_XICS
2253         .long   DOTSYM(kvmppc_rm_h_eoi) - hcall_real_table
2254         .long   DOTSYM(kvmppc_rm_h_cppr) - hcall_real_table
2255         .long   DOTSYM(kvmppc_rm_h_ipi) - hcall_real_table
2256         .long   DOTSYM(kvmppc_rm_h_ipoll) - hcall_real_table
2257         .long   DOTSYM(kvmppc_rm_h_xirr) - hcall_real_table
2258 #else
2259         .long   0               /* 0x64 - H_EOI */
2260         .long   0               /* 0x68 - H_CPPR */
2261         .long   0               /* 0x6c - H_IPI */
2262         .long   0               /* 0x70 - H_IPOLL */
2263         .long   0               /* 0x74 - H_XIRR */
2264 #endif
2265         .long   0               /* 0x78 */
2266         .long   0               /* 0x7c */
2267         .long   0               /* 0x80 */
2268         .long   0               /* 0x84 */
2269         .long   0               /* 0x88 */
2270         .long   0               /* 0x8c */
2271         .long   0               /* 0x90 */
2272         .long   0               /* 0x94 */
2273         .long   0               /* 0x98 */
2274         .long   0               /* 0x9c */
2275         .long   0               /* 0xa0 */
2276         .long   0               /* 0xa4 */
2277         .long   0               /* 0xa8 */
2278         .long   0               /* 0xac */
2279         .long   0               /* 0xb0 */
2280         .long   0               /* 0xb4 */
2281         .long   0               /* 0xb8 */
2282         .long   0               /* 0xbc */
2283         .long   0               /* 0xc0 */
2284         .long   0               /* 0xc4 */
2285         .long   0               /* 0xc8 */
2286         .long   0               /* 0xcc */
2287         .long   0               /* 0xd0 */
2288         .long   0               /* 0xd4 */
2289         .long   0               /* 0xd8 */
2290         .long   0               /* 0xdc */
2291         .long   DOTSYM(kvmppc_h_cede) - hcall_real_table
2292         .long   DOTSYM(kvmppc_rm_h_confer) - hcall_real_table
2293         .long   0               /* 0xe8 */
2294         .long   0               /* 0xec */
2295         .long   0               /* 0xf0 */
2296         .long   0               /* 0xf4 */
2297         .long   0               /* 0xf8 */
2298         .long   0               /* 0xfc */
2299         .long   0               /* 0x100 */
2300         .long   0               /* 0x104 */
2301         .long   0               /* 0x108 */
2302         .long   0               /* 0x10c */
2303         .long   0               /* 0x110 */
2304         .long   0               /* 0x114 */
2305         .long   0               /* 0x118 */
2306         .long   0               /* 0x11c */
2307         .long   0               /* 0x120 */
2308         .long   DOTSYM(kvmppc_h_bulk_remove) - hcall_real_table
2309         .long   0               /* 0x128 */
2310         .long   0               /* 0x12c */
2311         .long   0               /* 0x130 */
2312         .long   DOTSYM(kvmppc_h_set_xdabr) - hcall_real_table
2313         .long   DOTSYM(kvmppc_rm_h_stuff_tce) - hcall_real_table
2314         .long   DOTSYM(kvmppc_rm_h_put_tce_indirect) - hcall_real_table
2315         .long   0               /* 0x140 */
2316         .long   0               /* 0x144 */
2317         .long   0               /* 0x148 */
2318         .long   0               /* 0x14c */
2319         .long   0               /* 0x150 */
2320         .long   0               /* 0x154 */
2321         .long   0               /* 0x158 */
2322         .long   0               /* 0x15c */
2323         .long   0               /* 0x160 */
2324         .long   0               /* 0x164 */
2325         .long   0               /* 0x168 */
2326         .long   0               /* 0x16c */
2327         .long   0               /* 0x170 */
2328         .long   0               /* 0x174 */
2329         .long   0               /* 0x178 */
2330         .long   0               /* 0x17c */
2331         .long   0               /* 0x180 */
2332         .long   0               /* 0x184 */
2333         .long   0               /* 0x188 */
2334         .long   0               /* 0x18c */
2335         .long   0               /* 0x190 */
2336         .long   0               /* 0x194 */
2337         .long   0               /* 0x198 */
2338         .long   0               /* 0x19c */
2339         .long   0               /* 0x1a0 */
2340         .long   0               /* 0x1a4 */
2341         .long   0               /* 0x1a8 */
2342         .long   0               /* 0x1ac */
2343         .long   0               /* 0x1b0 */
2344         .long   0               /* 0x1b4 */
2345         .long   0               /* 0x1b8 */
2346         .long   0               /* 0x1bc */
2347         .long   0               /* 0x1c0 */
2348         .long   0               /* 0x1c4 */
2349         .long   0               /* 0x1c8 */
2350         .long   0               /* 0x1cc */
2351         .long   0               /* 0x1d0 */
2352         .long   0               /* 0x1d4 */
2353         .long   0               /* 0x1d8 */
2354         .long   0               /* 0x1dc */
2355         .long   0               /* 0x1e0 */
2356         .long   0               /* 0x1e4 */
2357         .long   0               /* 0x1e8 */
2358         .long   0               /* 0x1ec */
2359         .long   0               /* 0x1f0 */
2360         .long   0               /* 0x1f4 */
2361         .long   0               /* 0x1f8 */
2362         .long   0               /* 0x1fc */
2363         .long   0               /* 0x200 */
2364         .long   0               /* 0x204 */
2365         .long   0               /* 0x208 */
2366         .long   0               /* 0x20c */
2367         .long   0               /* 0x210 */
2368         .long   0               /* 0x214 */
2369         .long   0               /* 0x218 */
2370         .long   0               /* 0x21c */
2371         .long   0               /* 0x220 */
2372         .long   0               /* 0x224 */
2373         .long   0               /* 0x228 */
2374         .long   0               /* 0x22c */
2375         .long   0               /* 0x230 */
2376         .long   0               /* 0x234 */
2377         .long   0               /* 0x238 */
2378         .long   0               /* 0x23c */
2379         .long   0               /* 0x240 */
2380         .long   0               /* 0x244 */
2381         .long   0               /* 0x248 */
2382         .long   0               /* 0x24c */
2383         .long   0               /* 0x250 */
2384         .long   0               /* 0x254 */
2385         .long   0               /* 0x258 */
2386         .long   0               /* 0x25c */
2387         .long   0               /* 0x260 */
2388         .long   0               /* 0x264 */
2389         .long   0               /* 0x268 */
2390         .long   0               /* 0x26c */
2391         .long   0               /* 0x270 */
2392         .long   0               /* 0x274 */
2393         .long   0               /* 0x278 */
2394         .long   0               /* 0x27c */
2395         .long   0               /* 0x280 */
2396         .long   0               /* 0x284 */
2397         .long   0               /* 0x288 */
2398         .long   0               /* 0x28c */
2399         .long   0               /* 0x290 */
2400         .long   0               /* 0x294 */
2401         .long   0               /* 0x298 */
2402         .long   0               /* 0x29c */
2403         .long   0               /* 0x2a0 */
2404         .long   0               /* 0x2a4 */
2405         .long   0               /* 0x2a8 */
2406         .long   0               /* 0x2ac */
2407         .long   0               /* 0x2b0 */
2408         .long   0               /* 0x2b4 */
2409         .long   0               /* 0x2b8 */
2410         .long   0               /* 0x2bc */
2411         .long   0               /* 0x2c0 */
2412         .long   0               /* 0x2c4 */
2413         .long   0               /* 0x2c8 */
2414         .long   0               /* 0x2cc */
2415         .long   0               /* 0x2d0 */
2416         .long   0               /* 0x2d4 */
2417         .long   0               /* 0x2d8 */
2418         .long   0               /* 0x2dc */
2419         .long   0               /* 0x2e0 */
2420         .long   0               /* 0x2e4 */
2421         .long   0               /* 0x2e8 */
2422         .long   0               /* 0x2ec */
2423         .long   0               /* 0x2f0 */
2424         .long   0               /* 0x2f4 */
2425         .long   0               /* 0x2f8 */
2426 #ifdef CONFIG_KVM_XICS
2427         .long   DOTSYM(kvmppc_rm_h_xirr_x) - hcall_real_table
2428 #else
2429         .long   0               /* 0x2fc - H_XIRR_X*/
2430 #endif
2431         .long   DOTSYM(kvmppc_h_random) - hcall_real_table
2432         .globl  hcall_real_table_end
2433 hcall_real_table_end:
2434
2435 _GLOBAL(kvmppc_h_set_xdabr)
2436         andi.   r0, r5, DABRX_USER | DABRX_KERNEL
2437         beq     6f
2438         li      r0, DABRX_USER | DABRX_KERNEL | DABRX_BTI
2439         andc.   r0, r5, r0
2440         beq     3f
2441 6:      li      r3, H_PARAMETER
2442         blr
2443
2444 _GLOBAL(kvmppc_h_set_dabr)
2445         li      r5, DABRX_USER | DABRX_KERNEL
2446 3:
2447 BEGIN_FTR_SECTION
2448         b       2f
2449 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_207S)
2450         std     r4,VCPU_DABR(r3)
2451         stw     r5, VCPU_DABRX(r3)
2452         mtspr   SPRN_DABRX, r5
2453         /* Work around P7 bug where DABR can get corrupted on mtspr */
2454 1:      mtspr   SPRN_DABR,r4
2455         mfspr   r5, SPRN_DABR
2456         cmpd    r4, r5
2457         bne     1b
2458         isync
2459         li      r3,0
2460         blr
2461
2462         /* Emulate H_SET_DABR/X on P8 for the sake of compat mode guests */
2463 2:      rlwimi  r5, r4, 5, DAWRX_DR | DAWRX_DW
2464         rlwimi  r5, r4, 2, DAWRX_WT
2465         clrrdi  r4, r4, 3
2466         std     r4, VCPU_DAWR(r3)
2467         std     r5, VCPU_DAWRX(r3)
2468         mtspr   SPRN_DAWR, r4
2469         mtspr   SPRN_DAWRX, r5
2470         li      r3, 0
2471         blr
2472
2473 _GLOBAL(kvmppc_h_cede)          /* r3 = vcpu pointer, r11 = msr, r13 = paca */
2474         ori     r11,r11,MSR_EE
2475         std     r11,VCPU_MSR(r3)
2476         li      r0,1
2477         stb     r0,VCPU_CEDED(r3)
2478         sync                    /* order setting ceded vs. testing prodded */
2479         lbz     r5,VCPU_PRODDED(r3)
2480         cmpwi   r5,0
2481         bne     kvm_cede_prodded
2482         li      r12,0           /* set trap to 0 to say hcall is handled */
2483         stw     r12,VCPU_TRAP(r3)
2484         li      r0,H_SUCCESS
2485         std     r0,VCPU_GPR(R3)(r3)
2486
2487         /*
2488          * Set our bit in the bitmask of napping threads unless all the
2489          * other threads are already napping, in which case we send this
2490          * up to the host.
2491          */
2492         ld      r5,HSTATE_KVM_VCORE(r13)
2493         lbz     r6,HSTATE_PTID(r13)
2494         lwz     r8,VCORE_ENTRY_EXIT(r5)
2495         clrldi  r8,r8,56
2496         li      r0,1
2497         sld     r0,r0,r6
2498         addi    r6,r5,VCORE_NAPPING_THREADS
2499 31:     lwarx   r4,0,r6
2500         or      r4,r4,r0
2501         cmpw    r4,r8
2502         beq     kvm_cede_exit
2503         stwcx.  r4,0,r6
2504         bne     31b
2505         /* order napping_threads update vs testing entry_exit_map */
2506         isync
2507         li      r0,NAPPING_CEDE
2508         stb     r0,HSTATE_NAPPING(r13)
2509         lwz     r7,VCORE_ENTRY_EXIT(r5)
2510         cmpwi   r7,0x100
2511         bge     33f             /* another thread already exiting */
2512
2513 /*
2514  * Although not specifically required by the architecture, POWER7
2515  * preserves the following registers in nap mode, even if an SMT mode
2516  * switch occurs: SLB entries, PURR, SPURR, AMOR, UAMOR, AMR, SPRG0-3,
2517  * DAR, DSISR, DABR, DABRX, DSCR, PMCx, MMCRx, SIAR, SDAR.
2518  */
2519         /* Save non-volatile GPRs */
2520         std     r14, VCPU_GPR(R14)(r3)
2521         std     r15, VCPU_GPR(R15)(r3)
2522         std     r16, VCPU_GPR(R16)(r3)
2523         std     r17, VCPU_GPR(R17)(r3)
2524         std     r18, VCPU_GPR(R18)(r3)
2525         std     r19, VCPU_GPR(R19)(r3)
2526         std     r20, VCPU_GPR(R20)(r3)
2527         std     r21, VCPU_GPR(R21)(r3)
2528         std     r22, VCPU_GPR(R22)(r3)
2529         std     r23, VCPU_GPR(R23)(r3)
2530         std     r24, VCPU_GPR(R24)(r3)
2531         std     r25, VCPU_GPR(R25)(r3)
2532         std     r26, VCPU_GPR(R26)(r3)
2533         std     r27, VCPU_GPR(R27)(r3)
2534         std     r28, VCPU_GPR(R28)(r3)
2535         std     r29, VCPU_GPR(R29)(r3)
2536         std     r30, VCPU_GPR(R30)(r3)
2537         std     r31, VCPU_GPR(R31)(r3)
2538
2539         /* save FP state */
2540         bl      kvmppc_save_fp
2541
2542 #ifdef CONFIG_PPC_TRANSACTIONAL_MEM
2543 BEGIN_FTR_SECTION
2544         /*
2545          * NOTE THAT THIS TRASHES ALL NON-VOLATILE REGISTERS INCLUDING CR
2546          */
2547         ld      r9, HSTATE_KVM_VCPU(r13)
2548         bl      kvmppc_save_tm
2549 END_FTR_SECTION_IFSET(CPU_FTR_TM)
2550 #endif
2551
2552         /*
2553          * Set DEC to the smaller of DEC and HDEC, so that we wake
2554          * no later than the end of our timeslice (HDEC interrupts
2555          * don't wake us from nap).
2556          */
2557         mfspr   r3, SPRN_DEC
2558         mfspr   r4, SPRN_HDEC
2559         mftb    r5
2560 BEGIN_FTR_SECTION
2561         /* On P9 check whether the guest has large decrementer mode enabled */
2562         ld      r6, HSTATE_KVM_VCORE(r13)
2563         ld      r6, VCORE_LPCR(r6)
2564         andis.  r6, r6, LPCR_LD@h
2565         bne     68f
2566 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_300)
2567         extsw   r3, r3
2568 68:     EXTEND_HDEC(r4)
2569         cmpd    r3, r4
2570         ble     67f
2571         mtspr   SPRN_DEC, r4
2572 67:
2573         /* save expiry time of guest decrementer */
2574         add     r3, r3, r5
2575         ld      r4, HSTATE_KVM_VCPU(r13)
2576         ld      r5, HSTATE_KVM_VCORE(r13)
2577         ld      r6, VCORE_TB_OFFSET(r5)
2578         subf    r3, r6, r3      /* convert to host TB value */
2579         std     r3, VCPU_DEC_EXPIRES(r4)
2580
2581 #ifdef CONFIG_KVM_BOOK3S_HV_EXIT_TIMING
2582         ld      r4, HSTATE_KVM_VCPU(r13)
2583         addi    r3, r4, VCPU_TB_CEDE
2584         bl      kvmhv_accumulate_time
2585 #endif
2586
2587         lis     r3, LPCR_PECEDP@h       /* Do wake on privileged doorbell */
2588
2589         /*
2590          * Take a nap until a decrementer or external or doobell interrupt
2591          * occurs, with PECE1 and PECE0 set in LPCR.
2592          * On POWER8, set PECEDH, and if we are ceding, also set PECEDP.
2593          * Also clear the runlatch bit before napping.
2594          */
2595 kvm_do_nap:
2596         mfspr   r0, SPRN_CTRLF
2597         clrrdi  r0, r0, 1
2598         mtspr   SPRN_CTRLT, r0
2599
2600         li      r0,1
2601         stb     r0,HSTATE_HWTHREAD_REQ(r13)
2602         mfspr   r5,SPRN_LPCR
2603         ori     r5,r5,LPCR_PECE0 | LPCR_PECE1
2604 BEGIN_FTR_SECTION
2605         ori     r5, r5, LPCR_PECEDH
2606         rlwimi  r5, r3, 0, LPCR_PECEDP
2607 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_207S)
2608
2609 kvm_nap_sequence:               /* desired LPCR value in r5 */
2610 BEGIN_FTR_SECTION
2611         /*
2612          * PSSCR bits:  exit criterion = 1 (wakeup based on LPCR at sreset)
2613          *              enable state loss = 1 (allow SMT mode switch)
2614          *              requested level = 0 (just stop dispatching)
2615          */
2616         lis     r3, (PSSCR_EC | PSSCR_ESL)@h
2617         mtspr   SPRN_PSSCR, r3
2618         /* Set LPCR_PECE_HVEE bit to enable wakeup by HV interrupts */
2619         li      r4, LPCR_PECE_HVEE@higher
2620         sldi    r4, r4, 32
2621         or      r5, r5, r4
2622 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_300)
2623         mtspr   SPRN_LPCR,r5
2624         isync
2625         li      r0, 0
2626         std     r0, HSTATE_SCRATCH0(r13)
2627         ptesync
2628         ld      r0, HSTATE_SCRATCH0(r13)
2629 1:      cmpd    r0, r0
2630         bne     1b
2631 BEGIN_FTR_SECTION
2632         nap
2633 FTR_SECTION_ELSE
2634         PPC_STOP
2635 ALT_FTR_SECTION_END_IFCLR(CPU_FTR_ARCH_300)
2636         b       .
2637
2638 33:     mr      r4, r3
2639         li      r3, 0
2640         li      r12, 0
2641         b       34f
2642
2643 kvm_end_cede:
2644         /* get vcpu pointer */
2645         ld      r4, HSTATE_KVM_VCPU(r13)
2646
2647         /* Woken by external or decrementer interrupt */
2648         ld      r1, HSTATE_HOST_R1(r13)
2649
2650 #ifdef CONFIG_KVM_BOOK3S_HV_EXIT_TIMING
2651         addi    r3, r4, VCPU_TB_RMINTR
2652         bl      kvmhv_accumulate_time
2653 #endif
2654
2655 #ifdef CONFIG_PPC_TRANSACTIONAL_MEM
2656 BEGIN_FTR_SECTION
2657         /*
2658          * NOTE THAT THIS TRASHES ALL NON-VOLATILE REGISTERS INCLUDING CR
2659          */
2660         bl      kvmppc_restore_tm
2661 END_FTR_SECTION_IFSET(CPU_FTR_TM)
2662 #endif
2663
2664         /* load up FP state */
2665         bl      kvmppc_load_fp
2666
2667         /* Restore guest decrementer */
2668         ld      r3, VCPU_DEC_EXPIRES(r4)
2669         ld      r5, HSTATE_KVM_VCORE(r13)
2670         ld      r6, VCORE_TB_OFFSET(r5)
2671         add     r3, r3, r6      /* convert host TB to guest TB value */
2672         mftb    r7
2673         subf    r3, r7, r3
2674         mtspr   SPRN_DEC, r3
2675
2676         /* Load NV GPRS */
2677         ld      r14, VCPU_GPR(R14)(r4)
2678         ld      r15, VCPU_GPR(R15)(r4)
2679         ld      r16, VCPU_GPR(R16)(r4)
2680         ld      r17, VCPU_GPR(R17)(r4)
2681         ld      r18, VCPU_GPR(R18)(r4)
2682         ld      r19, VCPU_GPR(R19)(r4)
2683         ld      r20, VCPU_GPR(R20)(r4)
2684         ld      r21, VCPU_GPR(R21)(r4)
2685         ld      r22, VCPU_GPR(R22)(r4)
2686         ld      r23, VCPU_GPR(R23)(r4)
2687         ld      r24, VCPU_GPR(R24)(r4)
2688         ld      r25, VCPU_GPR(R25)(r4)
2689         ld      r26, VCPU_GPR(R26)(r4)
2690         ld      r27, VCPU_GPR(R27)(r4)
2691         ld      r28, VCPU_GPR(R28)(r4)
2692         ld      r29, VCPU_GPR(R29)(r4)
2693         ld      r30, VCPU_GPR(R30)(r4)
2694         ld      r31, VCPU_GPR(R31)(r4)
2695
2696         /* Check the wake reason in SRR1 to see why we got here */
2697         bl      kvmppc_check_wake_reason
2698
2699         /*
2700          * Restore volatile registers since we could have called a
2701          * C routine in kvmppc_check_wake_reason
2702          *      r4 = VCPU
2703          * r3 tells us whether we need to return to host or not
2704          * WARNING: it gets checked further down:
2705          * should not modify r3 until this check is done.
2706          */
2707         ld      r4, HSTATE_KVM_VCPU(r13)
2708
2709         /* clear our bit in vcore->napping_threads */
2710 34:     ld      r5,HSTATE_KVM_VCORE(r13)
2711         lbz     r7,HSTATE_PTID(r13)
2712         li      r0,1
2713         sld     r0,r0,r7
2714         addi    r6,r5,VCORE_NAPPING_THREADS
2715 32:     lwarx   r7,0,r6
2716         andc    r7,r7,r0
2717         stwcx.  r7,0,r6
2718         bne     32b
2719         li      r0,0
2720         stb     r0,HSTATE_NAPPING(r13)
2721
2722         /* See if the wake reason saved in r3 means we need to exit */
2723         stw     r12, VCPU_TRAP(r4)
2724         mr      r9, r4
2725         cmpdi   r3, 0
2726         bgt     guest_exit_cont
2727
2728         /* see if any other thread is already exiting */
2729         lwz     r0,VCORE_ENTRY_EXIT(r5)
2730         cmpwi   r0,0x100
2731         bge     guest_exit_cont
2732
2733         b       kvmppc_cede_reentry     /* if not go back to guest */
2734
2735         /* cede when already previously prodded case */
2736 kvm_cede_prodded:
2737         li      r0,0
2738         stb     r0,VCPU_PRODDED(r3)
2739         sync                    /* order testing prodded vs. clearing ceded */
2740         stb     r0,VCPU_CEDED(r3)
2741         li      r3,H_SUCCESS
2742         blr
2743
2744         /* we've ceded but we want to give control to the host */
2745 kvm_cede_exit:
2746         ld      r9, HSTATE_KVM_VCPU(r13)
2747         b       guest_exit_cont
2748
2749         /* Try to handle a machine check in real mode */
2750 machine_check_realmode:
2751         mr      r3, r9          /* get vcpu pointer */
2752         bl      kvmppc_realmode_machine_check
2753         nop
2754         ld      r9, HSTATE_KVM_VCPU(r13)
2755         li      r12, BOOK3S_INTERRUPT_MACHINE_CHECK
2756         /*
2757          * For the guest that is FWNMI capable, deliver all the MCE errors
2758          * (handled/unhandled) by exiting the guest with KVM_EXIT_NMI exit
2759          * reason. This new approach injects machine check errors in guest
2760          * address space to guest with additional information in the form
2761          * of RTAS event, thus enabling guest kernel to suitably handle
2762          * such errors.
2763          *
2764          * For the guest that is not FWNMI capable (old QEMU) fallback
2765          * to old behaviour for backward compatibility:
2766          * Deliver unhandled/fatal (e.g. UE) MCE errors to guest either
2767          * through machine check interrupt (set HSRR0 to 0x200).
2768          * For handled errors (no-fatal), just go back to guest execution
2769          * with current HSRR0.
2770          * if we receive machine check with MSR(RI=0) then deliver it to
2771          * guest as machine check causing guest to crash.
2772          */
2773         ld      r11, VCPU_MSR(r9)
2774         rldicl. r0, r11, 64-MSR_HV_LG, 63 /* check if it happened in HV mode */
2775         bne     mc_cont                 /* if so, exit to host */
2776         /* Check if guest is capable of handling NMI exit */
2777         ld      r10, VCPU_KVM(r9)
2778         lbz     r10, KVM_FWNMI(r10)
2779         cmpdi   r10, 1                  /* FWNMI capable? */
2780         beq     mc_cont                 /* if so, exit with KVM_EXIT_NMI. */
2781
2782         /* if not, fall through for backward compatibility. */
2783         andi.   r10, r11, MSR_RI        /* check for unrecoverable exception */
2784         beq     1f                      /* Deliver a machine check to guest */
2785         ld      r10, VCPU_PC(r9)
2786         cmpdi   r3, 0           /* Did we handle MCE ? */
2787         bne     2f      /* Continue guest execution. */
2788         /* If not, deliver a machine check.  SRR0/1 are already set */
2789 1:      li      r10, BOOK3S_INTERRUPT_MACHINE_CHECK
2790         bl      kvmppc_msr_interrupt
2791 2:      b       fast_interrupt_c_return
2792
2793 /*
2794  * Check the reason we woke from nap, and take appropriate action.
2795  * Returns (in r3):
2796  *      0 if nothing needs to be done
2797  *      1 if something happened that needs to be handled by the host
2798  *      -1 if there was a guest wakeup (IPI or msgsnd)
2799  *      -2 if we handled a PCI passthrough interrupt (returned by
2800  *              kvmppc_read_intr only)
2801  *
2802  * Also sets r12 to the interrupt vector for any interrupt that needs
2803  * to be handled now by the host (0x500 for external interrupt), or zero.
2804  * Modifies all volatile registers (since it may call a C function).
2805  * This routine calls kvmppc_read_intr, a C function, if an external
2806  * interrupt is pending.
2807  */
2808 kvmppc_check_wake_reason:
2809         mfspr   r6, SPRN_SRR1
2810 BEGIN_FTR_SECTION
2811         rlwinm  r6, r6, 45-31, 0xf      /* extract wake reason field (P8) */
2812 FTR_SECTION_ELSE
2813         rlwinm  r6, r6, 45-31, 0xe      /* P7 wake reason field is 3 bits */
2814 ALT_FTR_SECTION_END_IFSET(CPU_FTR_ARCH_207S)
2815         cmpwi   r6, 8                   /* was it an external interrupt? */
2816         beq     7f                      /* if so, see what it was */
2817         li      r3, 0
2818         li      r12, 0
2819         cmpwi   r6, 6                   /* was it the decrementer? */
2820         beq     0f
2821 BEGIN_FTR_SECTION
2822         cmpwi   r6, 5                   /* privileged doorbell? */
2823         beq     0f
2824         cmpwi   r6, 3                   /* hypervisor doorbell? */
2825         beq     3f
2826 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_207S)
2827         cmpwi   r6, 0xa                 /* Hypervisor maintenance ? */
2828         beq     4f
2829         li      r3, 1                   /* anything else, return 1 */
2830 0:      blr
2831
2832         /* hypervisor doorbell */
2833 3:      li      r12, BOOK3S_INTERRUPT_H_DOORBELL
2834
2835         /*
2836          * Clear the doorbell as we will invoke the handler
2837          * explicitly in the guest exit path.
2838          */
2839         lis     r6, (PPC_DBELL_SERVER << (63-36))@h
2840         PPC_MSGCLR(6)
2841         /* see if it's a host IPI */
2842         li      r3, 1
2843 BEGIN_FTR_SECTION
2844         PPC_MSGSYNC
2845         lwsync
2846 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_300)
2847         lbz     r0, HSTATE_HOST_IPI(r13)
2848         cmpwi   r0, 0
2849         bnelr
2850         /* if not, return -1 */
2851         li      r3, -1
2852         blr
2853
2854         /* Woken up due to Hypervisor maintenance interrupt */
2855 4:      li      r12, BOOK3S_INTERRUPT_HMI
2856         li      r3, 1
2857         blr
2858
2859         /* external interrupt - create a stack frame so we can call C */
2860 7:      mflr    r0
2861         std     r0, PPC_LR_STKOFF(r1)
2862         stdu    r1, -PPC_MIN_STKFRM(r1)
2863         bl      kvmppc_read_intr
2864         nop
2865         li      r12, BOOK3S_INTERRUPT_EXTERNAL
2866         cmpdi   r3, 1
2867         ble     1f
2868
2869         /*
2870          * Return code of 2 means PCI passthrough interrupt, but
2871          * we need to return back to host to complete handling the
2872          * interrupt. Trap reason is expected in r12 by guest
2873          * exit code.
2874          */
2875         li      r12, BOOK3S_INTERRUPT_HV_RM_HARD
2876 1:
2877         ld      r0, PPC_MIN_STKFRM+PPC_LR_STKOFF(r1)
2878         addi    r1, r1, PPC_MIN_STKFRM
2879         mtlr    r0
2880         blr
2881
2882 /*
2883  * Save away FP, VMX and VSX registers.
2884  * r3 = vcpu pointer
2885  * N.B. r30 and r31 are volatile across this function,
2886  * thus it is not callable from C.
2887  */
2888 kvmppc_save_fp:
2889         mflr    r30
2890         mr      r31,r3
2891         mfmsr   r5
2892         ori     r8,r5,MSR_FP
2893 #ifdef CONFIG_ALTIVEC
2894 BEGIN_FTR_SECTION
2895         oris    r8,r8,MSR_VEC@h
2896 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
2897 #endif
2898 #ifdef CONFIG_VSX
2899 BEGIN_FTR_SECTION
2900         oris    r8,r8,MSR_VSX@h
2901 END_FTR_SECTION_IFSET(CPU_FTR_VSX)
2902 #endif
2903         mtmsrd  r8
2904         addi    r3,r3,VCPU_FPRS
2905         bl      store_fp_state
2906 #ifdef CONFIG_ALTIVEC
2907 BEGIN_FTR_SECTION
2908         addi    r3,r31,VCPU_VRS
2909         bl      store_vr_state
2910 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
2911 #endif
2912         mfspr   r6,SPRN_VRSAVE
2913         stw     r6,VCPU_VRSAVE(r31)
2914         mtlr    r30
2915         blr
2916
2917 /*
2918  * Load up FP, VMX and VSX registers
2919  * r4 = vcpu pointer
2920  * N.B. r30 and r31 are volatile across this function,
2921  * thus it is not callable from C.
2922  */
2923 kvmppc_load_fp:
2924         mflr    r30
2925         mr      r31,r4
2926         mfmsr   r9
2927         ori     r8,r9,MSR_FP
2928 #ifdef CONFIG_ALTIVEC
2929 BEGIN_FTR_SECTION
2930         oris    r8,r8,MSR_VEC@h
2931 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
2932 #endif
2933 #ifdef CONFIG_VSX
2934 BEGIN_FTR_SECTION
2935         oris    r8,r8,MSR_VSX@h
2936 END_FTR_SECTION_IFSET(CPU_FTR_VSX)
2937 #endif
2938         mtmsrd  r8
2939         addi    r3,r4,VCPU_FPRS
2940         bl      load_fp_state
2941 #ifdef CONFIG_ALTIVEC
2942 BEGIN_FTR_SECTION
2943         addi    r3,r31,VCPU_VRS
2944         bl      load_vr_state
2945 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
2946 #endif
2947         lwz     r7,VCPU_VRSAVE(r31)
2948         mtspr   SPRN_VRSAVE,r7
2949         mtlr    r30
2950         mr      r4,r31
2951         blr
2952
2953 #ifdef CONFIG_PPC_TRANSACTIONAL_MEM
2954 /*
2955  * Save transactional state and TM-related registers.
2956  * Called with r9 pointing to the vcpu struct.
2957  * This can modify all checkpointed registers, but
2958  * restores r1, r2 and r9 (vcpu pointer) before exit.
2959  */
2960 kvmppc_save_tm:
2961         mflr    r0
2962         std     r0, PPC_LR_STKOFF(r1)
2963
2964         /* Turn on TM. */
2965         mfmsr   r8
2966         li      r0, 1
2967         rldimi  r8, r0, MSR_TM_LG, 63-MSR_TM_LG
2968         mtmsrd  r8
2969
2970         ld      r5, VCPU_MSR(r9)
2971         rldicl. r5, r5, 64 - MSR_TS_S_LG, 62
2972         beq     1f      /* TM not active in guest. */
2973
2974         std     r1, HSTATE_HOST_R1(r13)
2975         li      r3, TM_CAUSE_KVM_RESCHED
2976
2977         /* Clear the MSR RI since r1, r13 are all going to be foobar. */
2978         li      r5, 0
2979         mtmsrd  r5, 1
2980
2981         /* All GPRs are volatile at this point. */
2982         TRECLAIM(R3)
2983
2984         /* Temporarily store r13 and r9 so we have some regs to play with */
2985         SET_SCRATCH0(r13)
2986         GET_PACA(r13)
2987         std     r9, PACATMSCRATCH(r13)
2988         ld      r9, HSTATE_KVM_VCPU(r13)
2989
2990         /* Get a few more GPRs free. */
2991         std     r29, VCPU_GPRS_TM(29)(r9)
2992         std     r30, VCPU_GPRS_TM(30)(r9)
2993         std     r31, VCPU_GPRS_TM(31)(r9)
2994
2995         /* Save away PPR and DSCR soon so don't run with user values. */
2996         mfspr   r31, SPRN_PPR
2997         HMT_MEDIUM
2998         mfspr   r30, SPRN_DSCR
2999         ld      r29, HSTATE_DSCR(r13)
3000         mtspr   SPRN_DSCR, r29
3001
3002         /* Save all but r9, r13 & r29-r31 */
3003         reg = 0
3004         .rept   29
3005         .if (reg != 9) && (reg != 13)
3006         std     reg, VCPU_GPRS_TM(reg)(r9)
3007         .endif
3008         reg = reg + 1
3009         .endr
3010         /* ... now save r13 */
3011         GET_SCRATCH0(r4)
3012         std     r4, VCPU_GPRS_TM(13)(r9)
3013         /* ... and save r9 */
3014         ld      r4, PACATMSCRATCH(r13)
3015         std     r4, VCPU_GPRS_TM(9)(r9)
3016
3017         /* Reload stack pointer and TOC. */
3018         ld      r1, HSTATE_HOST_R1(r13)
3019         ld      r2, PACATOC(r13)
3020
3021         /* Set MSR RI now we have r1 and r13 back. */
3022         li      r5, MSR_RI
3023         mtmsrd  r5, 1
3024
3025         /* Save away checkpinted SPRs. */
3026         std     r31, VCPU_PPR_TM(r9)
3027         std     r30, VCPU_DSCR_TM(r9)
3028         mflr    r5
3029         mfcr    r6
3030         mfctr   r7
3031         mfspr   r8, SPRN_AMR
3032         mfspr   r10, SPRN_TAR
3033         mfxer   r11
3034         std     r5, VCPU_LR_TM(r9)
3035         stw     r6, VCPU_CR_TM(r9)
3036         std     r7, VCPU_CTR_TM(r9)
3037         std     r8, VCPU_AMR_TM(r9)
3038         std     r10, VCPU_TAR_TM(r9)
3039         std     r11, VCPU_XER_TM(r9)
3040
3041         /* Restore r12 as trap number. */
3042         lwz     r12, VCPU_TRAP(r9)
3043
3044         /* Save FP/VSX. */
3045         addi    r3, r9, VCPU_FPRS_TM
3046         bl      store_fp_state
3047         addi    r3, r9, VCPU_VRS_TM
3048         bl      store_vr_state
3049         mfspr   r6, SPRN_VRSAVE
3050         stw     r6, VCPU_VRSAVE_TM(r9)
3051 1:
3052         /*
3053          * We need to save these SPRs after the treclaim so that the software
3054          * error code is recorded correctly in the TEXASR.  Also the user may
3055          * change these outside of a transaction, so they must always be
3056          * context switched.
3057          */
3058         mfspr   r5, SPRN_TFHAR
3059         mfspr   r6, SPRN_TFIAR
3060         mfspr   r7, SPRN_TEXASR
3061         std     r5, VCPU_TFHAR(r9)
3062         std     r6, VCPU_TFIAR(r9)
3063         std     r7, VCPU_TEXASR(r9)
3064
3065         ld      r0, PPC_LR_STKOFF(r1)
3066         mtlr    r0
3067         blr
3068
3069 /*
3070  * Restore transactional state and TM-related registers.
3071  * Called with r4 pointing to the vcpu struct.
3072  * This potentially modifies all checkpointed registers.
3073  * It restores r1, r2, r4 from the PACA.
3074  */
3075 kvmppc_restore_tm:
3076         mflr    r0
3077         std     r0, PPC_LR_STKOFF(r1)
3078
3079         /* Turn on TM/FP/VSX/VMX so we can restore them. */
3080         mfmsr   r5
3081         li      r6, MSR_TM >> 32
3082         sldi    r6, r6, 32
3083         or      r5, r5, r6
3084         ori     r5, r5, MSR_FP
3085         oris    r5, r5, (MSR_VEC | MSR_VSX)@h
3086         mtmsrd  r5
3087
3088         /*
3089          * The user may change these outside of a transaction, so they must
3090          * always be context switched.
3091          */
3092         ld      r5, VCPU_TFHAR(r4)
3093         ld      r6, VCPU_TFIAR(r4)
3094         ld      r7, VCPU_TEXASR(r4)
3095         mtspr   SPRN_TFHAR, r5
3096         mtspr   SPRN_TFIAR, r6
3097         mtspr   SPRN_TEXASR, r7
3098
3099         ld      r5, VCPU_MSR(r4)
3100         rldicl. r5, r5, 64 - MSR_TS_S_LG, 62
3101         beqlr           /* TM not active in guest */
3102         std     r1, HSTATE_HOST_R1(r13)
3103
3104         /* Make sure the failure summary is set, otherwise we'll program check
3105          * when we trechkpt.  It's possible that this might have been not set
3106          * on a kvmppc_set_one_reg() call but we shouldn't let this crash the
3107          * host.
3108          */
3109         oris    r7, r7, (TEXASR_FS)@h
3110         mtspr   SPRN_TEXASR, r7
3111
3112         /*
3113          * We need to load up the checkpointed state for the guest.
3114          * We need to do this early as it will blow away any GPRs, VSRs and
3115          * some SPRs.
3116          */
3117
3118         mr      r31, r4
3119         addi    r3, r31, VCPU_FPRS_TM
3120         bl      load_fp_state
3121         addi    r3, r31, VCPU_VRS_TM
3122         bl      load_vr_state
3123         mr      r4, r31
3124         lwz     r7, VCPU_VRSAVE_TM(r4)
3125         mtspr   SPRN_VRSAVE, r7
3126
3127         ld      r5, VCPU_LR_TM(r4)
3128         lwz     r6, VCPU_CR_TM(r4)
3129         ld      r7, VCPU_CTR_TM(r4)
3130         ld      r8, VCPU_AMR_TM(r4)
3131         ld      r9, VCPU_TAR_TM(r4)
3132         ld      r10, VCPU_XER_TM(r4)
3133         mtlr    r5
3134         mtcr    r6
3135         mtctr   r7
3136         mtspr   SPRN_AMR, r8
3137         mtspr   SPRN_TAR, r9
3138         mtxer   r10
3139
3140         /*
3141          * Load up PPR and DSCR values but don't put them in the actual SPRs
3142          * till the last moment to avoid running with userspace PPR and DSCR for
3143          * too long.
3144          */
3145         ld      r29, VCPU_DSCR_TM(r4)
3146         ld      r30, VCPU_PPR_TM(r4)
3147
3148         std     r2, PACATMSCRATCH(r13) /* Save TOC */
3149
3150         /* Clear the MSR RI since r1, r13 are all going to be foobar. */
3151         li      r5, 0
3152         mtmsrd  r5, 1
3153
3154         /* Load GPRs r0-r28 */
3155         reg = 0
3156         .rept   29
3157         ld      reg, VCPU_GPRS_TM(reg)(r31)
3158         reg = reg + 1
3159         .endr
3160
3161         mtspr   SPRN_DSCR, r29
3162         mtspr   SPRN_PPR, r30
3163
3164         /* Load final GPRs */
3165         ld      29, VCPU_GPRS_TM(29)(r31)
3166         ld      30, VCPU_GPRS_TM(30)(r31)
3167         ld      31, VCPU_GPRS_TM(31)(r31)
3168
3169         /* TM checkpointed state is now setup.  All GPRs are now volatile. */
3170         TRECHKPT
3171
3172         /* Now let's get back the state we need. */
3173         HMT_MEDIUM
3174         GET_PACA(r13)
3175         ld      r29, HSTATE_DSCR(r13)
3176         mtspr   SPRN_DSCR, r29
3177         ld      r4, HSTATE_KVM_VCPU(r13)
3178         ld      r1, HSTATE_HOST_R1(r13)
3179         ld      r2, PACATMSCRATCH(r13)
3180
3181         /* Set the MSR RI since we have our registers back. */
3182         li      r5, MSR_RI
3183         mtmsrd  r5, 1
3184
3185         ld      r0, PPC_LR_STKOFF(r1)
3186         mtlr    r0
3187         blr
3188 #endif
3189
3190 /*
3191  * We come here if we get any exception or interrupt while we are
3192  * executing host real mode code while in guest MMU context.
3193  * r12 is (CR << 32) | vector
3194  * r13 points to our PACA
3195  * r12 is saved in HSTATE_SCRATCH0(r13)
3196  * ctr is saved in HSTATE_SCRATCH1(r13) if RELOCATABLE
3197  * r9 is saved in HSTATE_SCRATCH2(r13)
3198  * r13 is saved in HSPRG1
3199  * cfar is saved in HSTATE_CFAR(r13)
3200  * ppr is saved in HSTATE_PPR(r13)
3201  */
3202 kvmppc_bad_host_intr:
3203         /*
3204          * Switch to the emergency stack, but start half-way down in
3205          * case we were already on it.
3206          */
3207         mr      r9, r1
3208         std     r1, PACAR1(r13)
3209         ld      r1, PACAEMERGSP(r13)
3210         subi    r1, r1, THREAD_SIZE/2 + INT_FRAME_SIZE
3211         std     r9, 0(r1)
3212         std     r0, GPR0(r1)
3213         std     r9, GPR1(r1)
3214         std     r2, GPR2(r1)
3215         SAVE_4GPRS(3, r1)
3216         SAVE_2GPRS(7, r1)
3217         srdi    r0, r12, 32
3218         clrldi  r12, r12, 32
3219         std     r0, _CCR(r1)
3220         std     r12, _TRAP(r1)
3221         andi.   r0, r12, 2
3222         beq     1f
3223         mfspr   r3, SPRN_HSRR0
3224         mfspr   r4, SPRN_HSRR1
3225         mfspr   r5, SPRN_HDAR
3226         mfspr   r6, SPRN_HDSISR
3227         b       2f
3228 1:      mfspr   r3, SPRN_SRR0
3229         mfspr   r4, SPRN_SRR1
3230         mfspr   r5, SPRN_DAR
3231         mfspr   r6, SPRN_DSISR
3232 2:      std     r3, _NIP(r1)
3233         std     r4, _MSR(r1)
3234         std     r5, _DAR(r1)
3235         std     r6, _DSISR(r1)
3236         ld      r9, HSTATE_SCRATCH2(r13)
3237         ld      r12, HSTATE_SCRATCH0(r13)
3238         GET_SCRATCH0(r0)
3239         SAVE_4GPRS(9, r1)
3240         std     r0, GPR13(r1)
3241         SAVE_NVGPRS(r1)
3242         ld      r5, HSTATE_CFAR(r13)
3243         std     r5, ORIG_GPR3(r1)
3244         mflr    r3
3245 #ifdef CONFIG_RELOCATABLE
3246         ld      r4, HSTATE_SCRATCH1(r13)
3247 #else
3248         mfctr   r4
3249 #endif
3250         mfxer   r5
3251         lbz     r6, PACASOFTIRQEN(r13)
3252         std     r3, _LINK(r1)
3253         std     r4, _CTR(r1)
3254         std     r5, _XER(r1)
3255         std     r6, SOFTE(r1)
3256         ld      r2, PACATOC(r13)
3257         LOAD_REG_IMMEDIATE(3, 0x7265677368657265)
3258         std     r3, STACK_FRAME_OVERHEAD-16(r1)
3259
3260         /*
3261          * On POWER9 do a minimal restore of the MMU and call C code,
3262          * which will print a message and panic.
3263          * XXX On POWER7 and POWER8, we just spin here since we don't
3264          * know what the other threads are doing (and we don't want to
3265          * coordinate with them) - but at least we now have register state
3266          * in memory that we might be able to look at from another CPU.
3267          */
3268 BEGIN_FTR_SECTION
3269         b       .
3270 END_FTR_SECTION_IFCLR(CPU_FTR_ARCH_300)
3271         ld      r9, HSTATE_KVM_VCPU(r13)
3272         ld      r10, VCPU_KVM(r9)
3273
3274         li      r0, 0
3275         mtspr   SPRN_AMR, r0
3276         mtspr   SPRN_IAMR, r0
3277         mtspr   SPRN_CIABR, r0
3278         mtspr   SPRN_DAWRX, r0
3279
3280         /* Flush the ERAT on radix P9 DD1 guest exit */
3281 BEGIN_FTR_SECTION
3282         PPC_INVALIDATE_ERAT
3283 END_FTR_SECTION_IFSET(CPU_FTR_POWER9_DD1)
3284
3285 BEGIN_MMU_FTR_SECTION
3286         b       4f
3287 END_MMU_FTR_SECTION_IFSET(MMU_FTR_TYPE_RADIX)
3288
3289         slbmte  r0, r0
3290         slbia
3291         ptesync
3292         ld      r8, PACA_SLBSHADOWPTR(r13)
3293         .rept   SLB_NUM_BOLTED
3294         li      r3, SLBSHADOW_SAVEAREA
3295         LDX_BE  r5, r8, r3
3296         addi    r3, r3, 8
3297         LDX_BE  r6, r8, r3
3298         andis.  r7, r5, SLB_ESID_V@h
3299         beq     3f
3300         slbmte  r6, r5
3301 3:      addi    r8, r8, 16
3302         .endr
3303
3304 4:      lwz     r7, KVM_HOST_LPID(r10)
3305         mtspr   SPRN_LPID, r7
3306         mtspr   SPRN_PID, r0
3307         ld      r8, KVM_HOST_LPCR(r10)
3308         mtspr   SPRN_LPCR, r8
3309         isync
3310         li      r0, KVM_GUEST_MODE_NONE
3311         stb     r0, HSTATE_IN_GUEST(r13)
3312
3313         /*
3314          * Turn on the MMU and jump to C code
3315          */
3316         bcl     20, 31, .+4
3317 5:      mflr    r3
3318         addi    r3, r3, 9f - 5b
3319         ld      r4, PACAKMSR(r13)
3320         mtspr   SPRN_SRR0, r3
3321         mtspr   SPRN_SRR1, r4
3322         RFI_TO_KERNEL
3323 9:      addi    r3, r1, STACK_FRAME_OVERHEAD
3324         bl      kvmppc_bad_interrupt
3325         b       9b
3326
3327 /*
3328  * This mimics the MSR transition on IRQ delivery.  The new guest MSR is taken
3329  * from VCPU_INTR_MSR and is modified based on the required TM state changes.
3330  *   r11 has the guest MSR value (in/out)
3331  *   r9 has a vcpu pointer (in)
3332  *   r0 is used as a scratch register
3333  */
3334 kvmppc_msr_interrupt:
3335         rldicl  r0, r11, 64 - MSR_TS_S_LG, 62
3336         cmpwi   r0, 2 /* Check if we are in transactional state..  */
3337         ld      r11, VCPU_INTR_MSR(r9)
3338         bne     1f
3339         /* ... if transactional, change to suspended */
3340         li      r0, 1
3341 1:      rldimi  r11, r0, MSR_TS_S_LG, 63 - MSR_TS_T_LG
3342         blr
3343
3344 /*
3345  * This works around a hardware bug on POWER8E processors, where
3346  * writing a 1 to the MMCR0[PMAO] bit doesn't generate a
3347  * performance monitor interrupt.  Instead, when we need to have
3348  * an interrupt pending, we have to arrange for a counter to overflow.
3349  */
3350 kvmppc_fix_pmao:
3351         li      r3, 0
3352         mtspr   SPRN_MMCR2, r3
3353         lis     r3, (MMCR0_PMXE | MMCR0_FCECE)@h
3354         ori     r3, r3, MMCR0_PMCjCE | MMCR0_C56RUN
3355         mtspr   SPRN_MMCR0, r3
3356         lis     r3, 0x7fff
3357         ori     r3, r3, 0xffff
3358         mtspr   SPRN_PMC6, r3
3359         isync
3360         blr
3361
3362 #ifdef CONFIG_KVM_BOOK3S_HV_EXIT_TIMING
3363 /*
3364  * Start timing an activity
3365  * r3 = pointer to time accumulation struct, r4 = vcpu
3366  */
3367 kvmhv_start_timing:
3368         ld      r5, HSTATE_KVM_VCORE(r13)
3369         lbz     r6, VCORE_IN_GUEST(r5)
3370         cmpwi   r6, 0
3371         beq     5f                              /* if in guest, need to */
3372         ld      r6, VCORE_TB_OFFSET(r5)         /* subtract timebase offset */
3373 5:      mftb    r5
3374         subf    r5, r6, r5
3375         std     r3, VCPU_CUR_ACTIVITY(r4)
3376         std     r5, VCPU_ACTIVITY_START(r4)
3377         blr
3378
3379 /*
3380  * Accumulate time to one activity and start another.
3381  * r3 = pointer to new time accumulation struct, r4 = vcpu
3382  */
3383 kvmhv_accumulate_time:
3384         ld      r5, HSTATE_KVM_VCORE(r13)
3385         lbz     r8, VCORE_IN_GUEST(r5)
3386         cmpwi   r8, 0
3387         beq     4f                              /* if in guest, need to */
3388         ld      r8, VCORE_TB_OFFSET(r5)         /* subtract timebase offset */
3389 4:      ld      r5, VCPU_CUR_ACTIVITY(r4)
3390         ld      r6, VCPU_ACTIVITY_START(r4)
3391         std     r3, VCPU_CUR_ACTIVITY(r4)
3392         mftb    r7
3393         subf    r7, r8, r7
3394         std     r7, VCPU_ACTIVITY_START(r4)
3395         cmpdi   r5, 0
3396         beqlr
3397         subf    r3, r6, r7
3398         ld      r8, TAS_SEQCOUNT(r5)
3399         cmpdi   r8, 0
3400         addi    r8, r8, 1
3401         std     r8, TAS_SEQCOUNT(r5)
3402         lwsync
3403         ld      r7, TAS_TOTAL(r5)
3404         add     r7, r7, r3
3405         std     r7, TAS_TOTAL(r5)
3406         ld      r6, TAS_MIN(r5)
3407         ld      r7, TAS_MAX(r5)
3408         beq     3f
3409         cmpd    r3, r6
3410         bge     1f
3411 3:      std     r3, TAS_MIN(r5)
3412 1:      cmpd    r3, r7
3413         ble     2f
3414         std     r3, TAS_MAX(r5)
3415 2:      lwsync
3416         addi    r8, r8, 1
3417         std     r8, TAS_SEQCOUNT(r5)
3418         blr
3419 #endif