arch/powerpc/kernel/exceptions-64s.S

   1 /* SPDX-License-Identifier: GPL-2.0 */
   2 /*
   3  * This file contains the 64-bit "server" PowerPC variant
   4  * of the low level exception handling including exception
   5  * vectors, exception return, part of the slb and stab
   6  * handling and other fixed offset specific things.
   7  *
   8  * This file is meant to be #included from head_64.S due to
   9  * position dependent assembly.
  10  *
  11  * Most of this originates from head_64.S and thus has the same
  12  * copyright history.
  13  *
  14  */
  15
  16 #include <asm/hw_irq.h>
  17 #include <asm/exception-64s.h>
  18 #include <asm/ptrace.h>
  19 #include <asm/cpuidle.h>
  20 #include <asm/head-64.h>
  21
  22 /*
  23  * There are a few constraints to be concerned with.
  24  * - Real mode exceptions code/data must be located at their physical location.
  25  * - Virtual mode exceptions must be mapped at their 0xc000... location.
  26  * - Fixed location code must not call directly beyond the __end_interrupts
  27  *   area when built with CONFIG_RELOCATABLE. LOAD_HANDLER / bctr sequence
  28  *   must be used.
  29  * - LOAD_HANDLER targets must be within first 64K of physical 0 /
  30  *   virtual 0xc00...
  31  * - Conditional branch targets must be within +/-32K of caller.
  32  *
  33  * "Virtual exceptions" run with relocation on (MSR_IR=1, MSR_DR=1), and
  34  * therefore don't have to run in physically located code or rfid to
  35  * virtual mode kernel code. However on relocatable kernels they do have
  36  * to branch to KERNELBASE offset because the rest of the kernel (outside
  37  * the exception vectors) may be located elsewhere.
  38  *
  39  * Virtual exceptions correspond with physical, except their entry points
  40  * are offset by 0xc000000000000000 and also tend to get an added 0x4000
  41  * offset applied. Virtual exceptions are enabled with the Alternate
  42  * Interrupt Location (AIL) bit set in the LPCR. However this does not
  43  * guarantee they will be delivered virtually. Some conditions (see the ISA)
  44  * cause exceptions to be delivered in real mode.
  45  *
  46  * It's impossible to receive interrupts below 0x300 via AIL.
  47  *
  48  * KVM: None of the virtual exceptions are from the guest. Anything that
  49  * escalated to HV=1 from HV=0 is delivered via real mode handlers.
  50  *
  51  *
  52  * We layout physical memory as follows:
  53  * 0x0000 - 0x00ff : Secondary processor spin code
  54  * 0x0100 - 0x18ff : Real mode pSeries interrupt vectors
  55  * 0x1900 - 0x3fff : Real mode trampolines
  56  * 0x4000 - 0x58ff : Relon (IR=1,DR=1) mode pSeries interrupt vectors
  57  * 0x5900 - 0x6fff : Relon mode trampolines
  58  * 0x7000 - 0x7fff : FWNMI data area
  59  * 0x8000 -   .... : Common interrupt handlers, remaining early
  60  *                   setup code, rest of kernel.
  61  *
  62  * We could reclaim 0x4000-0x42ff for real mode trampolines if the space
  63  * is necessary. Until then it's more consistent to explicitly put VIRT_NONE
  64  * vectors there.
  65  */
  66 OPEN_FIXED_SECTION(real_vectors,        0x0100, 0x1900)
  67 OPEN_FIXED_SECTION(real_trampolines,    0x1900, 0x4000)
  68 OPEN_FIXED_SECTION(virt_vectors,        0x4000, 0x5900)
  69 OPEN_FIXED_SECTION(virt_trampolines,    0x5900, 0x7000)
  70 #if defined(CONFIG_PPC_PSERIES) || defined(CONFIG_PPC_POWERNV)
  71 /*
  72  * Data area reserved for FWNMI option.
  73  * This address (0x7000) is fixed by the RPA.
  74  * pseries and powernv need to keep the whole page from
  75  * 0x7000 to 0x8000 free for use by the firmware
  76  */
  77 ZERO_FIXED_SECTION(fwnmi_page,          0x7000, 0x8000)
  78 OPEN_TEXT_SECTION(0x8000)
  79 #else
  80 OPEN_TEXT_SECTION(0x7000)
  81 #endif
  82
  83 USE_FIXED_SECTION(real_vectors)
  84
  85 /*
  86  * This is the start of the interrupt handlers for pSeries
  87  * This code runs with relocation off.
  88  * Code from here to __end_interrupts gets copied down to real
  89  * address 0x100 when we are running a relocatable kernel.
  90  * Therefore any relative branches in this section must only
  91  * branch to labels in this section.
  92  */
  93         .globl __start_interrupts
  94 __start_interrupts:
  95
  96 /* No virt vectors corresponding with 0x0..0x100 */
  97 EXC_VIRT_NONE(0x4000, 0x100)
  98
  99
 100 #ifdef CONFIG_PPC_P7_NAP
 101         /*
 102          * If running native on arch 2.06 or later, check if we are waking up
 103          * from nap/sleep/winkle, and branch to idle handler. This tests SRR1
 104          * bits 46:47. A non-0 value indicates that we are coming from a power
 105          * saving state. The idle wakeup handler initially runs in real mode,
 106          * but we branch to the 0xc000... address so we can turn on relocation
 107          * with mtmsr.
 108          */
 109 #define IDLETEST(n)                                                     \
 110         BEGIN_FTR_SECTION ;                                             \
 111         mfspr   r10,SPRN_SRR1 ;                                         \
 112         rlwinm. r10,r10,47-31,30,31 ;                                   \
 113         beq-    1f ;                                                    \
 114         cmpwi   cr3,r10,2 ;                                             \
 115         BRANCH_TO_C000(r10, system_reset_idle_common) ;                 \
 116 1:                                                                      \
 117         KVMTEST_PR(n) ;                                                 \
 118         END_FTR_SECTION_IFSET(CPU_FTR_HVMODE | CPU_FTR_ARCH_206)
 119 #else
 120 #define IDLETEST NOTEST
 121 #endif
 122
 123 EXC_REAL_BEGIN(system_reset, 0x100, 0x100)
 124         SET_SCRATCH0(r13)
 125         /*
 126          * MSR_RI is not enabled, because PACA_EXNMI and nmi stack is
 127          * being used, so a nested NMI exception would corrupt it.
 128          */
 129         EXCEPTION_PROLOG_PSERIES_NORI(PACA_EXNMI, system_reset_common, EXC_STD,
 130                                  IDLETEST, 0x100)
 131
 132 EXC_REAL_END(system_reset, 0x100, 0x100)
 133 EXC_VIRT_NONE(0x4100, 0x100)
 134 TRAMP_KVM(PACA_EXNMI, 0x100)
 135
 136 #ifdef CONFIG_PPC_P7_NAP
 137 EXC_COMMON_BEGIN(system_reset_idle_common)
 138         mfspr   r12,SPRN_SRR1
 139         b       pnv_powersave_wakeup
 140 #endif
 141
 142 EXC_COMMON_BEGIN(system_reset_common)
 143         /*
 144          * Increment paca->in_nmi then enable MSR_RI. SLB or MCE will be able
 145          * to recover, but nested NMI will notice in_nmi and not recover
 146          * because of the use of the NMI stack. in_nmi reentrancy is tested in
 147          * system_reset_exception.
 148          */
 149         lhz     r10,PACA_IN_NMI(r13)
 150         addi    r10,r10,1
 151         sth     r10,PACA_IN_NMI(r13)
 152         li      r10,MSR_RI
 153         mtmsrd  r10,1
 154
 155         mr      r10,r1
 156         ld      r1,PACA_NMI_EMERG_SP(r13)
 157         subi    r1,r1,INT_FRAME_SIZE
 158         EXCEPTION_COMMON_NORET_STACK(PACA_EXNMI, 0x100,
 159                         system_reset, system_reset_exception,
 160                         ADD_NVGPRS;ADD_RECONCILE)
 161
 162         /*
 163          * The stack is no longer in use, decrement in_nmi.
 164          */
 165         lhz     r10,PACA_IN_NMI(r13)
 166         subi    r10,r10,1
 167         sth     r10,PACA_IN_NMI(r13)
 168
 169         b       ret_from_except
 170
 171 #ifdef CONFIG_PPC_PSERIES
 172 /*
 173  * Vectors for the FWNMI option.  Share common code.
 174  */
 175 TRAMP_REAL_BEGIN(system_reset_fwnmi)
 176         SET_SCRATCH0(r13)               /* save r13 */
 177         /* See comment at system_reset exception */
 178         EXCEPTION_PROLOG_PSERIES_NORI(PACA_EXNMI, system_reset_common,
 179                                                 EXC_STD, NOTEST, 0x100)
 180 #endif /* CONFIG_PPC_PSERIES */
 181
 182
 183 EXC_REAL_BEGIN(machine_check, 0x200, 0x100)
 184         /* This is moved out of line as it can be patched by FW, but
 185          * some code path might still want to branch into the original
 186          * vector
 187          */
 188         SET_SCRATCH0(r13)               /* save r13 */
 189         EXCEPTION_PROLOG_0(PACA_EXMC)
 190 BEGIN_FTR_SECTION
 191         b       machine_check_powernv_early
 192 FTR_SECTION_ELSE
 193         b       machine_check_pSeries_0
 194 ALT_FTR_SECTION_END_IFSET(CPU_FTR_HVMODE)
 195 EXC_REAL_END(machine_check, 0x200, 0x100)
 196 EXC_VIRT_NONE(0x4200, 0x100)
 197 TRAMP_REAL_BEGIN(machine_check_powernv_early)
 198 BEGIN_FTR_SECTION
 199         EXCEPTION_PROLOG_1(PACA_EXMC, NOTEST, 0x200)
 200         /*
 201          * Register contents:
 202          * R13          = PACA
 203          * R9           = CR
 204          * Original R9 to R13 is saved on PACA_EXMC
 205          *
 206          * Switch to mc_emergency stack and handle re-entrancy (we limit
 207          * the nested MCE upto level 4 to avoid stack overflow).
 208          * Save MCE registers srr1, srr0, dar and dsisr and then set ME=1
 209          *
 210          * We use paca->in_mce to check whether this is the first entry or
 211          * nested machine check. We increment paca->in_mce to track nested
 212          * machine checks.
 213          *
 214          * If this is the first entry then set stack pointer to
 215          * paca->mc_emergency_sp, otherwise r1 is already pointing to
 216          * stack frame on mc_emergency stack.
 217          *
 218          * NOTE: We are here with MSR_ME=0 (off), which means we risk a
 219          * checkstop if we get another machine check exception before we do
 220          * rfid with MSR_ME=1.
 221          *
 222          * This interrupt can wake directly from idle. If that is the case,
 223          * the machine check is handled then the idle wakeup code is called
 224          * to restore state. In that case, the POWER9 DD1 idle PACA workaround
 225          * is not applied in the early machine check code, which will cause
 226          * bugs.
 227          */
 228         mr      r11,r1                  /* Save r1 */
 229         lhz     r10,PACA_IN_MCE(r13)
 230         cmpwi   r10,0                   /* Are we in nested machine check */
 231         bne     0f                      /* Yes, we are. */
 232         /* First machine check entry */
 233         ld      r1,PACAMCEMERGSP(r13)   /* Use MC emergency stack */
 234 0:      subi    r1,r1,INT_FRAME_SIZE    /* alloc stack frame */
 235         addi    r10,r10,1               /* increment paca->in_mce */
 236         sth     r10,PACA_IN_MCE(r13)
 237         /* Limit nested MCE to level 4 to avoid stack overflow */
 238         cmpwi   r10,MAX_MCE_DEPTH
 239         bgt     2f                      /* Check if we hit limit of 4 */
 240         std     r11,GPR1(r1)            /* Save r1 on the stack. */
 241         std     r11,0(r1)               /* make stack chain pointer */
 242         mfspr   r11,SPRN_SRR0           /* Save SRR0 */
 243         std     r11,_NIP(r1)
 244         mfspr   r11,SPRN_SRR1           /* Save SRR1 */
 245         std     r11,_MSR(r1)
 246         mfspr   r11,SPRN_DAR            /* Save DAR */
 247         std     r11,_DAR(r1)
 248         mfspr   r11,SPRN_DSISR          /* Save DSISR */
 249         std     r11,_DSISR(r1)
 250         std     r9,_CCR(r1)             /* Save CR in stackframe */
 251         /* Save r9 through r13 from EXMC save area to stack frame. */
 252         EXCEPTION_PROLOG_COMMON_2(PACA_EXMC)
 253         mfmsr   r11                     /* get MSR value */
 254         ori     r11,r11,MSR_ME          /* turn on ME bit */
 255         ori     r11,r11,MSR_RI          /* turn on RI bit */
 256         LOAD_HANDLER(r12, machine_check_handle_early)
 257 1:      mtspr   SPRN_SRR0,r12
 258         mtspr   SPRN_SRR1,r11
 259         RFI_TO_KERNEL
 260         b       .       /* prevent speculative execution */
 261 2:
 262         /* Stack overflow. Stay on emergency stack and panic.
 263          * Keep the ME bit off while panic-ing, so that if we hit
 264          * another machine check we checkstop.
 265          */
 266         addi    r1,r1,INT_FRAME_SIZE    /* go back to previous stack frame */
 267         ld      r11,PACAKMSR(r13)
 268         LOAD_HANDLER(r12, unrecover_mce)
 269         li      r10,MSR_ME
 270         andc    r11,r11,r10             /* Turn off MSR_ME */
 271         b       1b
 272         b       .       /* prevent speculative execution */
 273 END_FTR_SECTION_IFSET(CPU_FTR_HVMODE)
 274
 275 TRAMP_REAL_BEGIN(machine_check_pSeries)
 276         .globl machine_check_fwnmi
 277 machine_check_fwnmi:
 278         SET_SCRATCH0(r13)               /* save r13 */
 279         EXCEPTION_PROLOG_0(PACA_EXMC)
 280 machine_check_pSeries_0:
 281         EXCEPTION_PROLOG_1(PACA_EXMC, KVMTEST_PR, 0x200)
 282         /*
 283          * MSR_RI is not enabled, because PACA_EXMC is being used, so a
 284          * nested machine check corrupts it. machine_check_common enables
 285          * MSR_RI.
 286          */
 287         EXCEPTION_PROLOG_PSERIES_1_NORI(machine_check_common, EXC_STD)
 288
 289 TRAMP_KVM_SKIP(PACA_EXMC, 0x200)
 290
 291 EXC_COMMON_BEGIN(machine_check_common)
 292         /*
 293          * Machine check is different because we use a different
 294          * save area: PACA_EXMC instead of PACA_EXGEN.
 295          */
 296         mfspr   r10,SPRN_DAR
 297         std     r10,PACA_EXMC+EX_DAR(r13)
 298         mfspr   r10,SPRN_DSISR
 299         stw     r10,PACA_EXMC+EX_DSISR(r13)
 300         EXCEPTION_PROLOG_COMMON(0x200, PACA_EXMC)
 301         FINISH_NAP
 302         RECONCILE_IRQ_STATE(r10, r11)
 303         ld      r3,PACA_EXMC+EX_DAR(r13)
 304         lwz     r4,PACA_EXMC+EX_DSISR(r13)
 305         /* Enable MSR_RI when finished with PACA_EXMC */
 306         li      r10,MSR_RI
 307         mtmsrd  r10,1
 308         std     r3,_DAR(r1)
 309         std     r4,_DSISR(r1)
 310         bl      save_nvgprs
 311         addi    r3,r1,STACK_FRAME_OVERHEAD
 312         bl      machine_check_exception
 313         b       ret_from_except
 314
 315 #define MACHINE_CHECK_HANDLER_WINDUP                    \
 316         /* Clear MSR_RI before setting SRR0 and SRR1. */\
 317         li      r0,MSR_RI;                              \
 318         mfmsr   r9;             /* get MSR value */     \
 319         andc    r9,r9,r0;                               \
 320         mtmsrd  r9,1;           /* Clear MSR_RI */      \
 321         /* Move original SRR0 and SRR1 into the respective regs */      \
 322         ld      r9,_MSR(r1);                            \
 323         mtspr   SPRN_SRR1,r9;                           \
 324         ld      r3,_NIP(r1);                            \
 325         mtspr   SPRN_SRR0,r3;                           \
 326         ld      r9,_CTR(r1);                            \
 327         mtctr   r9;                                     \
 328         ld      r9,_XER(r1);                            \
 329         mtxer   r9;                                     \
 330         ld      r9,_LINK(r1);                           \
 331         mtlr    r9;                                     \
 332         REST_GPR(0, r1);                                \
 333         REST_8GPRS(2, r1);                              \
 334         REST_GPR(10, r1);                               \
 335         ld      r11,_CCR(r1);                           \
 336         mtcr    r11;                                    \
 337         /* Decrement paca->in_mce. */                   \
 338         lhz     r12,PACA_IN_MCE(r13);                   \
 339         subi    r12,r12,1;                              \
 340         sth     r12,PACA_IN_MCE(r13);                   \
 341         REST_GPR(11, r1);                               \
 342         REST_2GPRS(12, r1);                             \
 343         /* restore original r1. */                      \
 344         ld      r1,GPR1(r1)
 345
 346 #ifdef CONFIG_PPC_P7_NAP
 347 /*
 348  * This is an idle wakeup. Low level machine check has already been
 349  * done. Queue the event then call the idle code to do the wake up.
 350  */
 351 EXC_COMMON_BEGIN(machine_check_idle_common)
 352         bl      machine_check_queue_event
 353
 354         /*
 355          * We have not used any non-volatile GPRs here, and as a rule
 356          * most exception code including machine check does not.
 357          * Therefore PACA_NAPSTATELOST does not need to be set. Idle
 358          * wakeup will restore volatile registers.
 359          *
 360          * Load the original SRR1 into r3 for pnv_powersave_wakeup_mce.
 361          *
 362          * Then decrement MCE nesting after finishing with the stack.
 363          */
 364         ld      r3,_MSR(r1)
 365
 366         lhz     r11,PACA_IN_MCE(r13)
 367         subi    r11,r11,1
 368         sth     r11,PACA_IN_MCE(r13)
 369
 370         /* Turn off the RI bit because SRR1 is used by idle wakeup code. */
 371         /* Recoverability could be improved by reducing the use of SRR1. */
 372         li      r11,0
 373         mtmsrd  r11,1
 374
 375         b       pnv_powersave_wakeup_mce
 376 #endif
 377         /*
 378          * Handle machine check early in real mode. We come here with
 379          * ME=1, MMU (IR=0 and DR=0) off and using MC emergency stack.
 380          */
 381 EXC_COMMON_BEGIN(machine_check_handle_early)
 382         std     r0,GPR0(r1)     /* Save r0 */
 383         EXCEPTION_PROLOG_COMMON_3(0x200)
 384         bl      save_nvgprs
 385         addi    r3,r1,STACK_FRAME_OVERHEAD
 386         bl      machine_check_early
 387         std     r3,RESULT(r1)   /* Save result */
 388         ld      r12,_MSR(r1)
 389
 390 #ifdef  CONFIG_PPC_P7_NAP
 391         /*
 392          * Check if thread was in power saving mode. We come here when any
 393          * of the following is true:
 394          * a. thread wasn't in power saving mode
 395          * b. thread was in power saving mode with no state loss,
 396          *    supervisor state loss or hypervisor state loss.
 397          *
 398          * Go back to nap/sleep/winkle mode again if (b) is true.
 399          */
 400         BEGIN_FTR_SECTION
 401         rlwinm. r11,r12,47-31,30,31
 402         bne     machine_check_idle_common
 403         END_FTR_SECTION_IFSET(CPU_FTR_HVMODE | CPU_FTR_ARCH_206)
 404 #endif
 405
 406         /*
 407          * Check if we are coming from hypervisor userspace. If yes then we
 408          * continue in host kernel in V mode to deliver the MC event.
 409          */
 410         rldicl. r11,r12,4,63            /* See if MC hit while in HV mode. */
 411         beq     5f
 412         andi.   r11,r12,MSR_PR          /* See if coming from user. */
 413         bne     9f                      /* continue in V mode if we are. */
 414
 415 5:
 416 #ifdef CONFIG_KVM_BOOK3S_64_HANDLER
 417         /*
 418          * We are coming from kernel context. Check if we are coming from
 419          * guest. if yes, then we can continue. We will fall through
 420          * do_kvm_200->kvmppc_interrupt to deliver the MC event to guest.
 421          */
 422         lbz     r11,HSTATE_IN_GUEST(r13)
 423         cmpwi   r11,0                   /* Check if coming from guest */
 424         bne     9f                      /* continue if we are. */
 425 #endif
 426         /*
 427          * At this point we are not sure about what context we come from.
 428          * Queue up the MCE event and return from the interrupt.
 429          * But before that, check if this is an un-recoverable exception.
 430          * If yes, then stay on emergency stack and panic.
 431          */
 432         andi.   r11,r12,MSR_RI
 433         bne     2f
 434 1:      mfspr   r11,SPRN_SRR0
 435         LOAD_HANDLER(r10,unrecover_mce)
 436         mtspr   SPRN_SRR0,r10
 437         ld      r10,PACAKMSR(r13)
 438         /*
 439          * We are going down. But there are chances that we might get hit by
 440          * another MCE during panic path and we may run into unstable state
 441          * with no way out. Hence, turn ME bit off while going down, so that
 442          * when another MCE is hit during panic path, system will checkstop
 443          * and hypervisor will get restarted cleanly by SP.
 444          */
 445         li      r3,MSR_ME
 446         andc    r10,r10,r3              /* Turn off MSR_ME */
 447         mtspr   SPRN_SRR1,r10
 448         RFI_TO_KERNEL
 449         b       .
 450 2:
 451         /*
 452          * Check if we have successfully handled/recovered from error, if not
 453          * then stay on emergency stack and panic.
 454          */
 455         ld      r3,RESULT(r1)   /* Load result */
 456         cmpdi   r3,0            /* see if we handled MCE successfully */
 457
 458         beq     1b              /* if !handled then panic */
 459         /*
 460          * Return from MC interrupt.
 461          * Queue up the MCE event so that we can log it later, while
 462          * returning from kernel or opal call.
 463          */
 464         bl      machine_check_queue_event
 465         MACHINE_CHECK_HANDLER_WINDUP
 466         RFI_TO_USER_OR_KERNEL
 467 9:
 468         /* Deliver the machine check to host kernel in V mode. */
 469         MACHINE_CHECK_HANDLER_WINDUP
 470         b       machine_check_pSeries
 471
 472 EXC_COMMON_BEGIN(unrecover_mce)
 473         /* Invoke machine_check_exception to print MCE event and panic. */
 474         addi    r3,r1,STACK_FRAME_OVERHEAD
 475         bl      machine_check_exception
 476         /*
 477          * We will not reach here. Even if we did, there is no way out. Call
 478          * unrecoverable_exception and die.
 479          */
 480 1:      addi    r3,r1,STACK_FRAME_OVERHEAD
 481         bl      unrecoverable_exception
 482         b       1b
 483
 484
 485 EXC_REAL(data_access, 0x300, 0x80)
 486 EXC_VIRT(data_access, 0x4300, 0x80, 0x300)
 487 TRAMP_KVM_SKIP(PACA_EXGEN, 0x300)
 488
 489 EXC_COMMON_BEGIN(data_access_common)
 490         /*
 491          * Here r13 points to the paca, r9 contains the saved CR,
 492          * SRR0 and SRR1 are saved in r11 and r12,
 493          * r9 - r13 are saved in paca->exgen.
 494          */
 495         mfspr   r10,SPRN_DAR
 496         std     r10,PACA_EXGEN+EX_DAR(r13)
 497         mfspr   r10,SPRN_DSISR
 498         stw     r10,PACA_EXGEN+EX_DSISR(r13)
 499         EXCEPTION_PROLOG_COMMON(0x300, PACA_EXGEN)
 500         RECONCILE_IRQ_STATE(r10, r11)
 501         ld      r12,_MSR(r1)
 502         ld      r3,PACA_EXGEN+EX_DAR(r13)
 503         lwz     r4,PACA_EXGEN+EX_DSISR(r13)
 504         li      r5,0x300
 505         std     r3,_DAR(r1)
 506         std     r4,_DSISR(r1)
 507 BEGIN_MMU_FTR_SECTION
 508         b       do_hash_page            /* Try to handle as hpte fault */
 509 MMU_FTR_SECTION_ELSE
 510         b       handle_page_fault
 511 ALT_MMU_FTR_SECTION_END_IFCLR(MMU_FTR_TYPE_RADIX)
 512
 513
 514 EXC_REAL_BEGIN(data_access_slb, 0x380, 0x80)
 515         SET_SCRATCH0(r13)
 516         EXCEPTION_PROLOG_0(PACA_EXSLB)
 517         EXCEPTION_PROLOG_1(PACA_EXSLB, KVMTEST_PR, 0x380)
 518         mr      r12,r3  /* save r3 */
 519         mfspr   r3,SPRN_DAR
 520         mfspr   r11,SPRN_SRR1
 521         crset   4*cr6+eq
 522         BRANCH_TO_COMMON(r10, slb_miss_common)
 523 EXC_REAL_END(data_access_slb, 0x380, 0x80)
 524
 525 EXC_VIRT_BEGIN(data_access_slb, 0x4380, 0x80)
 526         SET_SCRATCH0(r13)
 527         EXCEPTION_PROLOG_0(PACA_EXSLB)
 528         EXCEPTION_PROLOG_1(PACA_EXSLB, NOTEST, 0x380)
 529         mr      r12,r3  /* save r3 */
 530         mfspr   r3,SPRN_DAR
 531         mfspr   r11,SPRN_SRR1
 532         crset   4*cr6+eq
 533         BRANCH_TO_COMMON(r10, slb_miss_common)
 534 EXC_VIRT_END(data_access_slb, 0x4380, 0x80)
 535 TRAMP_KVM_SKIP(PACA_EXSLB, 0x380)
 536
 537
 538 EXC_REAL(instruction_access, 0x400, 0x80)
 539 EXC_VIRT(instruction_access, 0x4400, 0x80, 0x400)
 540 TRAMP_KVM(PACA_EXGEN, 0x400)
 541
 542 EXC_COMMON_BEGIN(instruction_access_common)
 543         EXCEPTION_PROLOG_COMMON(0x400, PACA_EXGEN)
 544         RECONCILE_IRQ_STATE(r10, r11)
 545         ld      r12,_MSR(r1)
 546         ld      r3,_NIP(r1)
 547         andis.  r4,r12,DSISR_SRR1_MATCH_64S@h
 548         li      r5,0x400
 549         std     r3,_DAR(r1)
 550         std     r4,_DSISR(r1)
 551 BEGIN_MMU_FTR_SECTION
 552         b       do_hash_page            /* Try to handle as hpte fault */
 553 MMU_FTR_SECTION_ELSE
 554         b       handle_page_fault
 555 ALT_MMU_FTR_SECTION_END_IFCLR(MMU_FTR_TYPE_RADIX)
 556
 557
 558 EXC_REAL_BEGIN(instruction_access_slb, 0x480, 0x80)
 559         SET_SCRATCH0(r13)
 560         EXCEPTION_PROLOG_0(PACA_EXSLB)
 561         EXCEPTION_PROLOG_1(PACA_EXSLB, KVMTEST_PR, 0x480)
 562         mr      r12,r3  /* save r3 */
 563         mfspr   r3,SPRN_SRR0            /* SRR0 is faulting address */
 564         mfspr   r11,SPRN_SRR1
 565         crclr   4*cr6+eq
 566         BRANCH_TO_COMMON(r10, slb_miss_common)
 567 EXC_REAL_END(instruction_access_slb, 0x480, 0x80)
 568
 569 EXC_VIRT_BEGIN(instruction_access_slb, 0x4480, 0x80)
 570         SET_SCRATCH0(r13)
 571         EXCEPTION_PROLOG_0(PACA_EXSLB)
 572         EXCEPTION_PROLOG_1(PACA_EXSLB, NOTEST, 0x480)
 573         mr      r12,r3  /* save r3 */
 574         mfspr   r3,SPRN_SRR0            /* SRR0 is faulting address */
 575         mfspr   r11,SPRN_SRR1
 576         crclr   4*cr6+eq
 577         BRANCH_TO_COMMON(r10, slb_miss_common)
 578 EXC_VIRT_END(instruction_access_slb, 0x4480, 0x80)
 579 TRAMP_KVM(PACA_EXSLB, 0x480)
 580
 581
 582 /*
 583  * This handler is used by the 0x380 and 0x480 SLB miss interrupts, as well as
 584  * the virtual mode 0x4380 and 0x4480 interrupts if AIL is enabled.
 585  */
 586 EXC_COMMON_BEGIN(slb_miss_common)
 587         /*
 588          * r13 points to the PACA, r9 contains the saved CR,
 589          * r12 contains the saved r3,
 590          * r11 contain the saved SRR1, SRR0 is still ready for return
 591          * r3 has the faulting address
 592          * r9 - r13 are saved in paca->exslb.
 593          * cr6.eq is set for a D-SLB miss, clear for a I-SLB miss
 594          * We assume we aren't going to take any exceptions during this
 595          * procedure.
 596          */
 597         mflr    r10
 598         stw     r9,PACA_EXSLB+EX_CCR(r13)       /* save CR in exc. frame */
 599         std     r10,PACA_EXSLB+EX_LR(r13)       /* save LR */
 600
 601         andi.   r9,r11,MSR_PR   // Check for exception from userspace
 602         cmpdi   cr4,r9,MSR_PR   // And save the result in CR4 for later
 603
 604         /*
 605          * Test MSR_RI before calling slb_allocate_realmode, because the
 606          * MSR in r11 gets clobbered. However we still want to allocate
 607          * SLB in case MSR_RI=0, to minimise the risk of getting stuck in
 608          * recursive SLB faults. So use cr5 for this, which is preserved.
 609          */
 610         andi.   r11,r11,MSR_RI  /* check for unrecoverable exception */
 611         cmpdi   cr5,r11,MSR_RI
 612
 613         crset   4*cr0+eq
 614 #ifdef CONFIG_PPC_BOOK3S_64
 615 BEGIN_MMU_FTR_SECTION
 616         bl      slb_allocate
 617 END_MMU_FTR_SECTION_IFCLR(MMU_FTR_TYPE_RADIX)
 618 #endif
 619
 620         ld      r10,PACA_EXSLB+EX_LR(r13)
 621         lwz     r9,PACA_EXSLB+EX_CCR(r13)       /* get saved CR */
 622         mtlr    r10
 623
 624         beq-    8f              /* if bad address, make full stack frame */
 625
 626         bne-    cr5,2f          /* if unrecoverable exception, oops */
 627
 628         /* All done -- return from exception. */
 629
 630         bne     cr4,1f          /* returning to kernel */
 631
 632 .machine        push
 633 .machine        "power4"
 634         mtcrf   0x80,r9
 635         mtcrf   0x08,r9         /* MSR[PR] indication is in cr4 */
 636         mtcrf   0x04,r9         /* MSR[RI] indication is in cr5 */
 637         mtcrf   0x02,r9         /* I/D indication is in cr6 */
 638         mtcrf   0x01,r9         /* slb_allocate uses cr0 and cr7 */
 639 .machine        pop
 640
 641         RESTORE_CTR(r9, PACA_EXSLB)
 642         RESTORE_PPR_PACA(PACA_EXSLB, r9)
 643         mr      r3,r12
 644         ld      r9,PACA_EXSLB+EX_R9(r13)
 645         ld      r10,PACA_EXSLB+EX_R10(r13)
 646         ld      r11,PACA_EXSLB+EX_R11(r13)
 647         ld      r12,PACA_EXSLB+EX_R12(r13)
 648         ld      r13,PACA_EXSLB+EX_R13(r13)
 649         RFI_TO_USER
 650         b       .       /* prevent speculative execution */
 651 1:
 652 .machine        push
 653 .machine        "power4"
 654         mtcrf   0x80,r9
 655         mtcrf   0x08,r9         /* MSR[PR] indication is in cr4 */
 656         mtcrf   0x04,r9         /* MSR[RI] indication is in cr5 */
 657         mtcrf   0x02,r9         /* I/D indication is in cr6 */
 658         mtcrf   0x01,r9         /* slb_allocate uses cr0 and cr7 */
 659 .machine        pop
 660
 661         RESTORE_CTR(r9, PACA_EXSLB)
 662         RESTORE_PPR_PACA(PACA_EXSLB, r9)
 663         mr      r3,r12
 664         ld      r9,PACA_EXSLB+EX_R9(r13)
 665         ld      r10,PACA_EXSLB+EX_R10(r13)
 666         ld      r11,PACA_EXSLB+EX_R11(r13)
 667         ld      r12,PACA_EXSLB+EX_R12(r13)
 668         ld      r13,PACA_EXSLB+EX_R13(r13)
 669         RFI_TO_KERNEL
 670         b       .       /* prevent speculative execution */
 671
 672
 673 2:      std     r3,PACA_EXSLB+EX_DAR(r13)
 674         mr      r3,r12
 675         mfspr   r11,SPRN_SRR0
 676         mfspr   r12,SPRN_SRR1
 677         LOAD_HANDLER(r10,unrecov_slb)
 678         mtspr   SPRN_SRR0,r10
 679         ld      r10,PACAKMSR(r13)
 680         mtspr   SPRN_SRR1,r10
 681         RFI_TO_KERNEL
 682         b       .
 683
 684 8:      std     r3,PACA_EXSLB+EX_DAR(r13)
 685         mr      r3,r12
 686         mfspr   r11,SPRN_SRR0
 687         mfspr   r12,SPRN_SRR1
 688         LOAD_HANDLER(r10,bad_addr_slb)
 689         mtspr   SPRN_SRR0,r10
 690         ld      r10,PACAKMSR(r13)
 691         mtspr   SPRN_SRR1,r10
 692         RFI_TO_KERNEL
 693         b       .
 694
 695 EXC_COMMON_BEGIN(unrecov_slb)
 696         EXCEPTION_PROLOG_COMMON(0x4100, PACA_EXSLB)
 697         RECONCILE_IRQ_STATE(r10, r11)
 698         bl      save_nvgprs
 699 1:      addi    r3,r1,STACK_FRAME_OVERHEAD
 700         bl      unrecoverable_exception
 701         b       1b
 702
 703 EXC_COMMON_BEGIN(bad_addr_slb)
 704         EXCEPTION_PROLOG_COMMON(0x380, PACA_EXSLB)
 705         RECONCILE_IRQ_STATE(r10, r11)
 706         ld      r3, PACA_EXSLB+EX_DAR(r13)
 707         std     r3, _DAR(r1)
 708         beq     cr6, 2f
 709         li      r10, 0x480              /* fix trap number for I-SLB miss */
 710         std     r10, _TRAP(r1)
 711 2:      bl      save_nvgprs
 712         addi    r3, r1, STACK_FRAME_OVERHEAD
 713         bl      slb_miss_bad_addr
 714         b       ret_from_except
 715
 716 EXC_REAL_BEGIN(hardware_interrupt, 0x500, 0x100)
 717         .globl hardware_interrupt_hv;
 718 hardware_interrupt_hv:
 719         BEGIN_FTR_SECTION
 720                 _MASKABLE_EXCEPTION_PSERIES(0x500, hardware_interrupt_common,
 721                                             EXC_HV, SOFTEN_TEST_HV)
 722         FTR_SECTION_ELSE
 723                 _MASKABLE_EXCEPTION_PSERIES(0x500, hardware_interrupt_common,
 724                                             EXC_STD, SOFTEN_TEST_PR)
 725         ALT_FTR_SECTION_END_IFSET(CPU_FTR_HVMODE | CPU_FTR_ARCH_206)
 726 EXC_REAL_END(hardware_interrupt, 0x500, 0x100)
 727
 728 EXC_VIRT_BEGIN(hardware_interrupt, 0x4500, 0x100)
 729         .globl hardware_interrupt_relon_hv;
 730 hardware_interrupt_relon_hv:
 731         BEGIN_FTR_SECTION
 732                 _MASKABLE_RELON_EXCEPTION_PSERIES(0x500, hardware_interrupt_common, EXC_HV, SOFTEN_TEST_HV)
 733         FTR_SECTION_ELSE
 734                 _MASKABLE_RELON_EXCEPTION_PSERIES(0x500, hardware_interrupt_common, EXC_STD, SOFTEN_TEST_PR)
 735         ALT_FTR_SECTION_END_IFSET(CPU_FTR_HVMODE)
 736 EXC_VIRT_END(hardware_interrupt, 0x4500, 0x100)
 737
 738 TRAMP_KVM(PACA_EXGEN, 0x500)
 739 TRAMP_KVM_HV(PACA_EXGEN, 0x500)
 740 EXC_COMMON_ASYNC(hardware_interrupt_common, 0x500, do_IRQ)
 741
 742
 743 EXC_REAL(alignment, 0x600, 0x100)
 744 EXC_VIRT(alignment, 0x4600, 0x100, 0x600)
 745 TRAMP_KVM(PACA_EXGEN, 0x600)
 746 EXC_COMMON_BEGIN(alignment_common)
 747         mfspr   r10,SPRN_DAR
 748         std     r10,PACA_EXGEN+EX_DAR(r13)
 749         mfspr   r10,SPRN_DSISR
 750         stw     r10,PACA_EXGEN+EX_DSISR(r13)
 751         EXCEPTION_PROLOG_COMMON(0x600, PACA_EXGEN)
 752         ld      r3,PACA_EXGEN+EX_DAR(r13)
 753         lwz     r4,PACA_EXGEN+EX_DSISR(r13)
 754         std     r3,_DAR(r1)
 755         std     r4,_DSISR(r1)
 756         bl      save_nvgprs
 757         RECONCILE_IRQ_STATE(r10, r11)
 758         addi    r3,r1,STACK_FRAME_OVERHEAD
 759         bl      alignment_exception
 760         b       ret_from_except
 761
 762
 763 EXC_REAL(program_check, 0x700, 0x100)
 764 EXC_VIRT(program_check, 0x4700, 0x100, 0x700)
 765 TRAMP_KVM(PACA_EXGEN, 0x700)
 766 EXC_COMMON_BEGIN(program_check_common)
 767         /*
 768          * It's possible to receive a TM Bad Thing type program check with
 769          * userspace register values (in particular r1), but with SRR1 reporting
 770          * that we came from the kernel. Normally that would confuse the bad
 771          * stack logic, and we would report a bad kernel stack pointer. Instead
 772          * we switch to the emergency stack if we're taking a TM Bad Thing from
 773          * the kernel.
 774          */
 775         li      r10,MSR_PR              /* Build a mask of MSR_PR ..    */
 776         oris    r10,r10,0x200000@h      /* .. and SRR1_PROGTM           */
 777         and     r10,r10,r12             /* Mask SRR1 with that.         */
 778         srdi    r10,r10,8               /* Shift it so we can compare   */
 779         cmpldi  r10,(0x200000 >> 8)     /* .. with an immediate.        */
 780         bne 1f                          /* If != go to normal path.     */
 781
 782         /* SRR1 had PR=0 and SRR1_PROGTM=1, so use the emergency stack  */
 783         andi.   r10,r12,MSR_PR;         /* Set CR0 correctly for label  */
 784                                         /* 3 in EXCEPTION_PROLOG_COMMON */
 785         mr      r10,r1                  /* Save r1                      */
 786         ld      r1,PACAEMERGSP(r13)     /* Use emergency stack          */
 787         subi    r1,r1,INT_FRAME_SIZE    /* alloc stack frame            */
 788         b 3f                            /* Jump into the macro !!       */
 789 1:      EXCEPTION_PROLOG_COMMON(0x700, PACA_EXGEN)
 790         bl      save_nvgprs
 791         RECONCILE_IRQ_STATE(r10, r11)
 792         addi    r3,r1,STACK_FRAME_OVERHEAD
 793         bl      program_check_exception
 794         b       ret_from_except
 795
 796
 797 EXC_REAL(fp_unavailable, 0x800, 0x100)
 798 EXC_VIRT(fp_unavailable, 0x4800, 0x100, 0x800)
 799 TRAMP_KVM(PACA_EXGEN, 0x800)
 800 EXC_COMMON_BEGIN(fp_unavailable_common)
 801         EXCEPTION_PROLOG_COMMON(0x800, PACA_EXGEN)
 802         bne     1f                      /* if from user, just load it up */
 803         bl      save_nvgprs
 804         RECONCILE_IRQ_STATE(r10, r11)
 805         addi    r3,r1,STACK_FRAME_OVERHEAD
 806         bl      kernel_fp_unavailable_exception
 807         BUG_OPCODE
 808 1:
 809 #ifdef CONFIG_PPC_TRANSACTIONAL_MEM
 810 BEGIN_FTR_SECTION
 811         /* Test if 2 TM state bits are zero.  If non-zero (ie. userspace was in
 812          * transaction), go do TM stuff
 813          */
 814         rldicl. r0, r12, (64-MSR_TS_LG), (64-2)
 815         bne-    2f
 816 END_FTR_SECTION_IFSET(CPU_FTR_TM)
 817 #endif
 818         bl      load_up_fpu
 819         b       fast_exception_return
 820 #ifdef CONFIG_PPC_TRANSACTIONAL_MEM
 821 2:      /* User process was in a transaction */
 822         bl      save_nvgprs
 823         RECONCILE_IRQ_STATE(r10, r11)
 824         addi    r3,r1,STACK_FRAME_OVERHEAD
 825         bl      fp_unavailable_tm
 826         b       ret_from_except
 827 #endif
 828
 829
 830 EXC_REAL_MASKABLE(decrementer, 0x900, 0x80)
 831 EXC_VIRT_MASKABLE(decrementer, 0x4900, 0x80, 0x900)
 832 TRAMP_KVM(PACA_EXGEN, 0x900)
 833 EXC_COMMON_ASYNC(decrementer_common, 0x900, timer_interrupt)
 834
 835
 836 EXC_REAL_HV(hdecrementer, 0x980, 0x80)
 837 EXC_VIRT_HV(hdecrementer, 0x4980, 0x80, 0x980)
 838 TRAMP_KVM_HV(PACA_EXGEN, 0x980)
 839 EXC_COMMON(hdecrementer_common, 0x980, hdec_interrupt)
 840
 841
 842 EXC_REAL_MASKABLE(doorbell_super, 0xa00, 0x100)
 843 EXC_VIRT_MASKABLE(doorbell_super, 0x4a00, 0x100, 0xa00)
 844 TRAMP_KVM(PACA_EXGEN, 0xa00)
 845 #ifdef CONFIG_PPC_DOORBELL
 846 EXC_COMMON_ASYNC(doorbell_super_common, 0xa00, doorbell_exception)
 847 #else
 848 EXC_COMMON_ASYNC(doorbell_super_common, 0xa00, unknown_exception)
 849 #endif
 850
 851
 852 EXC_REAL(trap_0b, 0xb00, 0x100)
 853 EXC_VIRT(trap_0b, 0x4b00, 0x100, 0xb00)
 854 TRAMP_KVM(PACA_EXGEN, 0xb00)
 855 EXC_COMMON(trap_0b_common, 0xb00, unknown_exception)
 856
 857 /*
 858  * system call / hypercall (0xc00, 0x4c00)
 859  *
 860  * The system call exception is invoked with "sc 0" and does not alter HV bit.
 861  * There is support for kernel code to invoke system calls but there are no
 862  * in-tree users.
 863  *
 864  * The hypercall is invoked with "sc 1" and sets HV=1.
 865  *
 866  * In HPT, sc 1 always goes to 0xc00 real mode. In RADIX, sc 1 can go to
 867  * 0x4c00 virtual mode.
 868  *
 869  * Call convention:
 870  *
 871  * syscall register convention is in Documentation/powerpc/syscall64-abi.txt
 872  *
 873  * For hypercalls, the register convention is as follows:
 874  * r0 volatile
 875  * r1-2 nonvolatile
 876  * r3 volatile parameter and return value for status
 877  * r4-r10 volatile input and output value
 878  * r11 volatile hypercall number and output value
 879  * r12 volatile input and output value
 880  * r13-r31 nonvolatile
 881  * LR nonvolatile
 882  * CTR volatile
 883  * XER volatile
 884  * CR0-1 CR5-7 volatile
 885  * CR2-4 nonvolatile
 886  * Other registers nonvolatile
 887  *
 888  * The intersection of volatile registers that don't contain possible
 889  * inputs is: cr0, xer, ctr. We may use these as scratch regs upon entry
 890  * without saving, though xer is not a good idea to use, as hardware may
 891  * interpret some bits so it may be costly to change them.
 892  */
 893 #ifdef CONFIG_KVM_BOOK3S_64_HANDLER
 894         /*
 895          * There is a little bit of juggling to get syscall and hcall
 896          * working well. Save r13 in ctr to avoid using SPRG scratch
 897          * register.
 898          *
 899          * Userspace syscalls have already saved the PPR, hcalls must save
 900          * it before setting HMT_MEDIUM.
 901          */
 902 #define SYSCALL_KVMTEST                                                 \
 903         mtctr   r13;                                                    \
 904         GET_PACA(r13);                                                  \
 905         std     r10,PACA_EXGEN+EX_R10(r13);                             \
 906         KVMTEST_PR(0xc00); /* uses r10, branch to do_kvm_0xc00_system_call */ \
 907         HMT_MEDIUM;                                                     \
 908         mfctr   r9;
 909
 910 #else
 911 #define SYSCALL_KVMTEST                                                 \
 912         HMT_MEDIUM;                                                     \
 913         mr      r9,r13;                                                 \
 914         GET_PACA(r13);
 915 #endif
 916
 917 #define LOAD_SYSCALL_HANDLER(reg)                                       \
 918         __LOAD_HANDLER(reg, system_call_common)
 919
 920 /*
 921  * After SYSCALL_KVMTEST, we reach here with PACA in r13, r13 in r9,
 922  * and HMT_MEDIUM.
 923  */
 924 #define SYSCALL_REAL                                            \
 925         mfspr   r11,SPRN_SRR0 ;                                 \
 926         mfspr   r12,SPRN_SRR1 ;                                 \
 927         LOAD_SYSCALL_HANDLER(r10) ;                             \
 928         mtspr   SPRN_SRR0,r10 ;                                 \
 929         ld      r10,PACAKMSR(r13) ;                             \
 930         mtspr   SPRN_SRR1,r10 ;                                 \
 931         RFI_TO_KERNEL ;                                         \
 932         b       . ;     /* prevent speculative execution */
 933
 934 #ifdef CONFIG_PPC_FAST_ENDIAN_SWITCH
 935 #define SYSCALL_FASTENDIAN_TEST                                 \
 936 BEGIN_FTR_SECTION                                               \
 937         cmpdi   r0,0x1ebe ;                                     \
 938         beq-    1f ;                                            \
 939 END_FTR_SECTION_IFSET(CPU_FTR_REAL_LE)                          \
 940
 941 #define SYSCALL_FASTENDIAN                                      \
 942         /* Fast LE/BE switch system call */                     \
 943 1:      mfspr   r12,SPRN_SRR1 ;                                 \
 944         xori    r12,r12,MSR_LE ;                                \
 945         mtspr   SPRN_SRR1,r12 ;                                 \
 946         mr      r13,r9 ;                                        \
 947         RFI_TO_USER ;   /* return to userspace */               \
 948         b       . ;     /* prevent speculative execution */
 949 #else
 950 #define SYSCALL_FASTENDIAN_TEST
 951 #define SYSCALL_FASTENDIAN
 952 #endif /* CONFIG_PPC_FAST_ENDIAN_SWITCH */
 953
 954 #if defined(CONFIG_RELOCATABLE)
 955         /*
 956          * We can't branch directly so we do it via the CTR which
 957          * is volatile across system calls.
 958          */
 959 #define SYSCALL_VIRT                                            \
 960         LOAD_SYSCALL_HANDLER(r10) ;                             \
 961         mtctr   r10 ;                                           \
 962         mfspr   r11,SPRN_SRR0 ;                                 \
 963         mfspr   r12,SPRN_SRR1 ;                                 \
 964         li      r10,MSR_RI ;                                    \
 965         mtmsrd  r10,1 ;                                         \
 966         bctr ;
 967 #else
 968         /* We can branch directly */
 969 #define SYSCALL_VIRT                                            \
 970         mfspr   r11,SPRN_SRR0 ;                                 \
 971         mfspr   r12,SPRN_SRR1 ;                                 \
 972         li      r10,MSR_RI ;                                    \
 973         mtmsrd  r10,1 ;                 /* Set RI (EE=0) */     \
 974         b       system_call_common ;
 975 #endif
 976
 977 EXC_REAL_BEGIN(system_call, 0xc00, 0x100)
 978         SYSCALL_KVMTEST /* loads PACA into r13, and saves r13 to r9 */
 979         SYSCALL_FASTENDIAN_TEST
 980         SYSCALL_REAL
 981         SYSCALL_FASTENDIAN
 982 EXC_REAL_END(system_call, 0xc00, 0x100)
 983
 984 EXC_VIRT_BEGIN(system_call, 0x4c00, 0x100)
 985         SYSCALL_KVMTEST /* loads PACA into r13, and saves r13 to r9 */
 986         SYSCALL_FASTENDIAN_TEST
 987         SYSCALL_VIRT
 988         SYSCALL_FASTENDIAN
 989 EXC_VIRT_END(system_call, 0x4c00, 0x100)
 990
 991 #ifdef CONFIG_KVM_BOOK3S_64_HANDLER
 992         /*
 993          * This is a hcall, so register convention is as above, with these
 994          * differences:
 995          * r13 = PACA
 996          * ctr = orig r13
 997          * orig r10 saved in PACA
 998          */
 999 TRAMP_KVM_BEGIN(do_kvm_0xc00)
1000          /*
1001           * Save the PPR (on systems that support it) before changing to
1002           * HMT_MEDIUM. That allows the KVM code to save that value into the
1003           * guest state (it is the guest's PPR value).
1004           */
1005         OPT_GET_SPR(r10, SPRN_PPR, CPU_FTR_HAS_PPR)
1006         HMT_MEDIUM
1007         OPT_SAVE_REG_TO_PACA(PACA_EXGEN+EX_PPR, r10, CPU_FTR_HAS_PPR)
1008         mfctr   r10
1009         SET_SCRATCH0(r10)
1010         std     r9,PACA_EXGEN+EX_R9(r13)
1011         mfcr    r9
1012         KVM_HANDLER(PACA_EXGEN, EXC_STD, 0xc00)
1013 #endif
1014
1015
1016 EXC_REAL(single_step, 0xd00, 0x100)
1017 EXC_VIRT(single_step, 0x4d00, 0x100, 0xd00)
1018 TRAMP_KVM(PACA_EXGEN, 0xd00)
1019 EXC_COMMON(single_step_common, 0xd00, single_step_exception)
1020
1021 EXC_REAL_OOL_HV(h_data_storage, 0xe00, 0x20)
1022 EXC_VIRT_OOL_HV(h_data_storage, 0x4e00, 0x20, 0xe00)
1023 TRAMP_KVM_HV_SKIP(PACA_EXGEN, 0xe00)
1024 EXC_COMMON_BEGIN(h_data_storage_common)
1025         mfspr   r10,SPRN_HDAR
1026         std     r10,PACA_EXGEN+EX_DAR(r13)
1027         mfspr   r10,SPRN_HDSISR
1028         stw     r10,PACA_EXGEN+EX_DSISR(r13)
1029         EXCEPTION_PROLOG_COMMON(0xe00, PACA_EXGEN)
1030         bl      save_nvgprs
1031         RECONCILE_IRQ_STATE(r10, r11)
1032         addi    r3,r1,STACK_FRAME_OVERHEAD
1033         bl      unknown_exception
1034         b       ret_from_except
1035
1036
1037 EXC_REAL_OOL_HV(h_instr_storage, 0xe20, 0x20)
1038 EXC_VIRT_OOL_HV(h_instr_storage, 0x4e20, 0x20, 0xe20)
1039 TRAMP_KVM_HV(PACA_EXGEN, 0xe20)
1040 EXC_COMMON(h_instr_storage_common, 0xe20, unknown_exception)
1041
1042
1043 EXC_REAL_OOL_HV(emulation_assist, 0xe40, 0x20)
1044 EXC_VIRT_OOL_HV(emulation_assist, 0x4e40, 0x20, 0xe40)
1045 TRAMP_KVM_HV(PACA_EXGEN, 0xe40)
1046 EXC_COMMON(emulation_assist_common, 0xe40, emulation_assist_interrupt)
1047
1048
1049 /*
1050  * hmi_exception trampoline is a special case. It jumps to hmi_exception_early
1051  * first, and then eventaully from there to the trampoline to get into virtual
1052  * mode.
1053  */
1054 __EXC_REAL_OOL_HV_DIRECT(hmi_exception, 0xe60, 0x20, hmi_exception_early)
1055 __TRAMP_REAL_OOL_MASKABLE_HV(hmi_exception, 0xe60)
1056 EXC_VIRT_NONE(0x4e60, 0x20)
1057 TRAMP_KVM_HV(PACA_EXGEN, 0xe60)
1058 TRAMP_REAL_BEGIN(hmi_exception_early)
1059         EXCEPTION_PROLOG_1(PACA_EXGEN, KVMTEST_HV, 0xe60)
1060         mr      r10,r1                  /* Save r1 */
1061         ld      r1,PACAEMERGSP(r13)     /* Use emergency stack for realmode */
1062         subi    r1,r1,INT_FRAME_SIZE    /* alloc stack frame            */
1063         mfspr   r11,SPRN_HSRR0          /* Save HSRR0 */
1064         mfspr   r12,SPRN_HSRR1          /* Save HSRR1 */
1065         EXCEPTION_PROLOG_COMMON_1()
1066         EXCEPTION_PROLOG_COMMON_2(PACA_EXGEN)
1067         EXCEPTION_PROLOG_COMMON_3(0xe60)
1068         addi    r3,r1,STACK_FRAME_OVERHEAD
1069         BRANCH_LINK_TO_FAR(hmi_exception_realmode) /* Function call ABI */
1070         cmpdi   cr0,r3,0
1071
1072         /* Windup the stack. */
1073         /* Move original HSRR0 and HSRR1 into the respective regs */
1074         ld      r9,_MSR(r1)
1075         mtspr   SPRN_HSRR1,r9
1076         ld      r3,_NIP(r1)
1077         mtspr   SPRN_HSRR0,r3
1078         ld      r9,_CTR(r1)
1079         mtctr   r9
1080         ld      r9,_XER(r1)
1081         mtxer   r9
1082         ld      r9,_LINK(r1)
1083         mtlr    r9
1084         REST_GPR(0, r1)
1085         REST_8GPRS(2, r1)
1086         REST_GPR(10, r1)
1087         ld      r11,_CCR(r1)
1088         REST_2GPRS(12, r1)
1089         bne     1f
1090         mtcr    r11
1091         REST_GPR(11, r1)
1092         ld      r1,GPR1(r1)
1093         HRFI_TO_USER_OR_KERNEL
1094
1095 1:      mtcr    r11
1096         REST_GPR(11, r1)
1097         ld      r1,GPR1(r1)
1098
1099         /*
1100          * Go to virtual mode and pull the HMI event information from
1101          * firmware.
1102          */
1103         .globl hmi_exception_after_realmode
1104 hmi_exception_after_realmode:
1105         SET_SCRATCH0(r13)
1106         EXCEPTION_PROLOG_0(PACA_EXGEN)
1107         b       tramp_real_hmi_exception
1108
1109 EXC_COMMON_BEGIN(hmi_exception_common)
1110 EXCEPTION_COMMON(PACA_EXGEN, 0xe60, hmi_exception_common, handle_hmi_exception,
1111         ret_from_except, FINISH_NAP;ADD_NVGPRS;ADD_RECONCILE;RUNLATCH_ON)
1112
1113 EXC_REAL_OOL_MASKABLE_HV(h_doorbell, 0xe80, 0x20)
1114 EXC_VIRT_OOL_MASKABLE_HV(h_doorbell, 0x4e80, 0x20, 0xe80)
1115 TRAMP_KVM_HV(PACA_EXGEN, 0xe80)
1116 #ifdef CONFIG_PPC_DOORBELL
1117 EXC_COMMON_ASYNC(h_doorbell_common, 0xe80, doorbell_exception)
1118 #else
1119 EXC_COMMON_ASYNC(h_doorbell_common, 0xe80, unknown_exception)
1120 #endif
1121
1122
1123 EXC_REAL_OOL_MASKABLE_HV(h_virt_irq, 0xea0, 0x20)
1124 EXC_VIRT_OOL_MASKABLE_HV(h_virt_irq, 0x4ea0, 0x20, 0xea0)
1125 TRAMP_KVM_HV(PACA_EXGEN, 0xea0)
1126 EXC_COMMON_ASYNC(h_virt_irq_common, 0xea0, do_IRQ)
1127
1128
1129 EXC_REAL_NONE(0xec0, 0x20)
1130 EXC_VIRT_NONE(0x4ec0, 0x20)
1131 EXC_REAL_NONE(0xee0, 0x20)
1132 EXC_VIRT_NONE(0x4ee0, 0x20)
1133
1134
1135 EXC_REAL_OOL(performance_monitor, 0xf00, 0x20)
1136 EXC_VIRT_OOL(performance_monitor, 0x4f00, 0x20, 0xf00)
1137 TRAMP_KVM(PACA_EXGEN, 0xf00)
1138 EXC_COMMON_ASYNC(performance_monitor_common, 0xf00, performance_monitor_exception)
1139
1140
1141 EXC_REAL_OOL(altivec_unavailable, 0xf20, 0x20)
1142 EXC_VIRT_OOL(altivec_unavailable, 0x4f20, 0x20, 0xf20)
1143 TRAMP_KVM(PACA_EXGEN, 0xf20)
1144 EXC_COMMON_BEGIN(altivec_unavailable_common)
1145         EXCEPTION_PROLOG_COMMON(0xf20, PACA_EXGEN)
1146 #ifdef CONFIG_ALTIVEC
1147 BEGIN_FTR_SECTION
1148         beq     1f
1149 #ifdef CONFIG_PPC_TRANSACTIONAL_MEM
1150   BEGIN_FTR_SECTION_NESTED(69)
1151         /* Test if 2 TM state bits are zero.  If non-zero (ie. userspace was in
1152          * transaction), go do TM stuff
1153          */
1154         rldicl. r0, r12, (64-MSR_TS_LG), (64-2)
1155         bne-    2f
1156   END_FTR_SECTION_NESTED(CPU_FTR_TM, CPU_FTR_TM, 69)
1157 #endif
1158         bl      load_up_altivec
1159         b       fast_exception_return
1160 #ifdef CONFIG_PPC_TRANSACTIONAL_MEM
1161 2:      /* User process was in a transaction */
1162         bl      save_nvgprs
1163         RECONCILE_IRQ_STATE(r10, r11)
1164         addi    r3,r1,STACK_FRAME_OVERHEAD
1165         bl      altivec_unavailable_tm
1166         b       ret_from_except
1167 #endif
1168 1:
1169 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
1170 #endif
1171         bl      save_nvgprs
1172         RECONCILE_IRQ_STATE(r10, r11)
1173         addi    r3,r1,STACK_FRAME_OVERHEAD
1174         bl      altivec_unavailable_exception
1175         b       ret_from_except
1176
1177
1178 EXC_REAL_OOL(vsx_unavailable, 0xf40, 0x20)
1179 EXC_VIRT_OOL(vsx_unavailable, 0x4f40, 0x20, 0xf40)
1180 TRAMP_KVM(PACA_EXGEN, 0xf40)
1181 EXC_COMMON_BEGIN(vsx_unavailable_common)
1182         EXCEPTION_PROLOG_COMMON(0xf40, PACA_EXGEN)
1183 #ifdef CONFIG_VSX
1184 BEGIN_FTR_SECTION
1185         beq     1f
1186 #ifdef CONFIG_PPC_TRANSACTIONAL_MEM
1187   BEGIN_FTR_SECTION_NESTED(69)
1188         /* Test if 2 TM state bits are zero.  If non-zero (ie. userspace was in
1189          * transaction), go do TM stuff
1190          */
1191         rldicl. r0, r12, (64-MSR_TS_LG), (64-2)
1192         bne-    2f
1193   END_FTR_SECTION_NESTED(CPU_FTR_TM, CPU_FTR_TM, 69)
1194 #endif
1195         b       load_up_vsx
1196 #ifdef CONFIG_PPC_TRANSACTIONAL_MEM
1197 2:      /* User process was in a transaction */
1198         bl      save_nvgprs
1199         RECONCILE_IRQ_STATE(r10, r11)
1200         addi    r3,r1,STACK_FRAME_OVERHEAD
1201         bl      vsx_unavailable_tm
1202         b       ret_from_except
1203 #endif
1204 1:
1205 END_FTR_SECTION_IFSET(CPU_FTR_VSX)
1206 #endif
1207         bl      save_nvgprs
1208         RECONCILE_IRQ_STATE(r10, r11)
1209         addi    r3,r1,STACK_FRAME_OVERHEAD
1210         bl      vsx_unavailable_exception
1211         b       ret_from_except
1212
1213
1214 EXC_REAL_OOL(facility_unavailable, 0xf60, 0x20)
1215 EXC_VIRT_OOL(facility_unavailable, 0x4f60, 0x20, 0xf60)
1216 TRAMP_KVM(PACA_EXGEN, 0xf60)
1217 EXC_COMMON(facility_unavailable_common, 0xf60, facility_unavailable_exception)
1218
1219
1220 EXC_REAL_OOL_HV(h_facility_unavailable, 0xf80, 0x20)
1221 EXC_VIRT_OOL_HV(h_facility_unavailable, 0x4f80, 0x20, 0xf80)
1222 TRAMP_KVM_HV(PACA_EXGEN, 0xf80)
1223 EXC_COMMON(h_facility_unavailable_common, 0xf80, facility_unavailable_exception)
1224
1225
1226 EXC_REAL_NONE(0xfa0, 0x20)
1227 EXC_VIRT_NONE(0x4fa0, 0x20)
1228 EXC_REAL_NONE(0xfc0, 0x20)
1229 EXC_VIRT_NONE(0x4fc0, 0x20)
1230 EXC_REAL_NONE(0xfe0, 0x20)
1231 EXC_VIRT_NONE(0x4fe0, 0x20)
1232
1233 EXC_REAL_NONE(0x1000, 0x100)
1234 EXC_VIRT_NONE(0x5000, 0x100)
1235 EXC_REAL_NONE(0x1100, 0x100)
1236 EXC_VIRT_NONE(0x5100, 0x100)
1237
1238 #ifdef CONFIG_CBE_RAS
1239 EXC_REAL_HV(cbe_system_error, 0x1200, 0x100)
1240 EXC_VIRT_NONE(0x5200, 0x100)
1241 TRAMP_KVM_HV_SKIP(PACA_EXGEN, 0x1200)
1242 EXC_COMMON(cbe_system_error_common, 0x1200, cbe_system_error_exception)
1243 #else /* CONFIG_CBE_RAS */
1244 EXC_REAL_NONE(0x1200, 0x100)
1245 EXC_VIRT_NONE(0x5200, 0x100)
1246 #endif
1247
1248
1249 EXC_REAL(instruction_breakpoint, 0x1300, 0x100)
1250 EXC_VIRT(instruction_breakpoint, 0x5300, 0x100, 0x1300)
1251 TRAMP_KVM_SKIP(PACA_EXGEN, 0x1300)
1252 EXC_COMMON(instruction_breakpoint_common, 0x1300, instruction_breakpoint_exception)
1253
1254 EXC_REAL_NONE(0x1400, 0x100)
1255 EXC_VIRT_NONE(0x5400, 0x100)
1256
1257 EXC_REAL_BEGIN(denorm_exception_hv, 0x1500, 0x100)
1258         mtspr   SPRN_SPRG_HSCRATCH0,r13
1259         EXCEPTION_PROLOG_0(PACA_EXGEN)
1260         EXCEPTION_PROLOG_1(PACA_EXGEN, NOTEST, 0x1500)
1261
1262 #ifdef CONFIG_PPC_DENORMALISATION
1263         mfspr   r10,SPRN_HSRR1
1264         mfspr   r11,SPRN_HSRR0          /* save HSRR0 */
1265         andis.  r10,r10,(HSRR1_DENORM)@h /* denorm? */
1266         addi    r11,r11,-4              /* HSRR0 is next instruction */
1267         bne+    denorm_assist
1268 #endif
1269
1270         KVMTEST_PR(0x1500)
1271         EXCEPTION_PROLOG_PSERIES_1(denorm_common, EXC_HV)
1272 EXC_REAL_END(denorm_exception_hv, 0x1500, 0x100)
1273
1274 #ifdef CONFIG_PPC_DENORMALISATION
1275 EXC_VIRT_BEGIN(denorm_exception, 0x5500, 0x100)
1276         b       exc_real_0x1500_denorm_exception_hv
1277 EXC_VIRT_END(denorm_exception, 0x5500, 0x100)
1278 #else
1279 EXC_VIRT_NONE(0x5500, 0x100)
1280 #endif
1281
1282 TRAMP_KVM_SKIP(PACA_EXGEN, 0x1500)
1283
1284 #ifdef CONFIG_PPC_DENORMALISATION
1285 TRAMP_REAL_BEGIN(denorm_assist)
1286 BEGIN_FTR_SECTION
1287 /*
1288  * To denormalise we need to move a copy of the register to itself.
1289  * For POWER6 do that here for all FP regs.
1290  */
1291         mfmsr   r10
1292         ori     r10,r10,(MSR_FP|MSR_FE0|MSR_FE1)
1293         xori    r10,r10,(MSR_FE0|MSR_FE1)
1294         mtmsrd  r10
1295         sync
1296
1297 #define FMR2(n)  fmr (n), (n) ; fmr n+1, n+1
1298 #define FMR4(n)  FMR2(n) ; FMR2(n+2)
1299 #define FMR8(n)  FMR4(n) ; FMR4(n+4)
1300 #define FMR16(n) FMR8(n) ; FMR8(n+8)
1301 #define FMR32(n) FMR16(n) ; FMR16(n+16)
1302         FMR32(0)
1303
1304 FTR_SECTION_ELSE
1305 /*
1306  * To denormalise we need to move a copy of the register to itself.
1307  * For POWER7 do that here for the first 32 VSX registers only.
1308  */
1309         mfmsr   r10
1310         oris    r10,r10,MSR_VSX@h
1311         mtmsrd  r10
1312         sync
1313
1314 #define XVCPSGNDP2(n) XVCPSGNDP(n,n,n) ; XVCPSGNDP(n+1,n+1,n+1)
1315 #define XVCPSGNDP4(n) XVCPSGNDP2(n) ; XVCPSGNDP2(n+2)
1316 #define XVCPSGNDP8(n) XVCPSGNDP4(n) ; XVCPSGNDP4(n+4)
1317 #define XVCPSGNDP16(n) XVCPSGNDP8(n) ; XVCPSGNDP8(n+8)
1318 #define XVCPSGNDP32(n) XVCPSGNDP16(n) ; XVCPSGNDP16(n+16)
1319         XVCPSGNDP32(0)
1320
1321 ALT_FTR_SECTION_END_IFCLR(CPU_FTR_ARCH_206)
1322
1323 BEGIN_FTR_SECTION
1324         b       denorm_done
1325 END_FTR_SECTION_IFCLR(CPU_FTR_ARCH_207S)
1326 /*
1327  * To denormalise we need to move a copy of the register to itself.
1328  * For POWER8 we need to do that for all 64 VSX registers
1329  */
1330         XVCPSGNDP32(32)
1331 denorm_done:
1332         mtspr   SPRN_HSRR0,r11
1333         mtcrf   0x80,r9
1334         ld      r9,PACA_EXGEN+EX_R9(r13)
1335         RESTORE_PPR_PACA(PACA_EXGEN, r10)
1336 BEGIN_FTR_SECTION
1337         ld      r10,PACA_EXGEN+EX_CFAR(r13)
1338         mtspr   SPRN_CFAR,r10
1339 END_FTR_SECTION_IFSET(CPU_FTR_CFAR)
1340         ld      r10,PACA_EXGEN+EX_R10(r13)
1341         ld      r11,PACA_EXGEN+EX_R11(r13)
1342         ld      r12,PACA_EXGEN+EX_R12(r13)
1343         ld      r13,PACA_EXGEN+EX_R13(r13)
1344         HRFI_TO_UNKNOWN
1345         b       .
1346 #endif
1347
1348 EXC_COMMON_HV(denorm_common, 0x1500, unknown_exception)
1349
1350
1351 #ifdef CONFIG_CBE_RAS
1352 EXC_REAL_HV(cbe_maintenance, 0x1600, 0x100)
1353 EXC_VIRT_NONE(0x5600, 0x100)
1354 TRAMP_KVM_HV_SKIP(PACA_EXGEN, 0x1600)
1355 EXC_COMMON(cbe_maintenance_common, 0x1600, cbe_maintenance_exception)
1356 #else /* CONFIG_CBE_RAS */
1357 EXC_REAL_NONE(0x1600, 0x100)
1358 EXC_VIRT_NONE(0x5600, 0x100)
1359 #endif
1360
1361
1362 EXC_REAL(altivec_assist, 0x1700, 0x100)
1363 EXC_VIRT(altivec_assist, 0x5700, 0x100, 0x1700)
1364 TRAMP_KVM(PACA_EXGEN, 0x1700)
1365 #ifdef CONFIG_ALTIVEC
1366 EXC_COMMON(altivec_assist_common, 0x1700, altivec_assist_exception)
1367 #else
1368 EXC_COMMON(altivec_assist_common, 0x1700, unknown_exception)
1369 #endif
1370
1371
1372 #ifdef CONFIG_CBE_RAS
1373 EXC_REAL_HV(cbe_thermal, 0x1800, 0x100)
1374 EXC_VIRT_NONE(0x5800, 0x100)
1375 TRAMP_KVM_HV_SKIP(PACA_EXGEN, 0x1800)
1376 EXC_COMMON(cbe_thermal_common, 0x1800, cbe_thermal_exception)
1377 #else /* CONFIG_CBE_RAS */
1378 EXC_REAL_NONE(0x1800, 0x100)
1379 EXC_VIRT_NONE(0x5800, 0x100)
1380 #endif
1381
1382 #ifdef CONFIG_PPC_WATCHDOG
1383
1384 #define MASKED_DEC_HANDLER_LABEL 3f
1385
1386 #define MASKED_DEC_HANDLER(_H)                          \
1387 3: /* soft-nmi */                                       \
1388         std     r12,PACA_EXGEN+EX_R12(r13);             \
1389         GET_SCRATCH0(r10);                              \
1390         std     r10,PACA_EXGEN+EX_R13(r13);             \
1391         EXCEPTION_PROLOG_PSERIES_1(soft_nmi_common, _H)
1392
1393 /*
1394  * Branch to soft_nmi_interrupt using the emergency stack. The emergency
1395  * stack is one that is usable by maskable interrupts so long as MSR_EE
1396  * remains off. It is used for recovery when something has corrupted the
1397  * normal kernel stack, for example. The "soft NMI" must not use the process
1398  * stack because we want irq disabled sections to avoid touching the stack
1399  * at all (other than PMU interrupts), so use the emergency stack for this,
1400  * and run it entirely with interrupts hard disabled.
1401  */
1402 EXC_COMMON_BEGIN(soft_nmi_common)
1403         mr      r10,r1
1404         ld      r1,PACAEMERGSP(r13)
1405         subi    r1,r1,INT_FRAME_SIZE
1406         EXCEPTION_COMMON_NORET_STACK(PACA_EXGEN, 0x900,
1407                         system_reset, soft_nmi_interrupt,
1408                         ADD_NVGPRS;ADD_RECONCILE)
1409         b       ret_from_except
1410
1411 #else /* CONFIG_PPC_WATCHDOG */
1412 #define MASKED_DEC_HANDLER_LABEL 2f /* normal return */
1413 #define MASKED_DEC_HANDLER(_H)
1414 #endif /* CONFIG_PPC_WATCHDOG */
1415
1416 /*
1417  * An interrupt came in while soft-disabled. We set paca->irq_happened, then:
1418  * - If it was a decrementer interrupt, we bump the dec to max and and return.
1419  * - If it was a doorbell we return immediately since doorbells are edge
1420  *   triggered and won't automatically refire.
1421  * - If it was a HMI we return immediately since we handled it in realmode
1422  *   and it won't refire.
1423  * - else we hard disable and return.
1424  * This is called with r10 containing the value to OR to the paca field.
1425  */
1426 #define MASKED_INTERRUPT(_H)                            \
1427 masked_##_H##interrupt:                                 \
1428         std     r11,PACA_EXGEN+EX_R11(r13);             \
1429         lbz     r11,PACAIRQHAPPENED(r13);               \
1430         or      r11,r11,r10;                            \
1431         stb     r11,PACAIRQHAPPENED(r13);               \
1432         cmpwi   r10,PACA_IRQ_DEC;                       \
1433         bne     1f;                                     \
1434         lis     r10,0x7fff;                             \
1435         ori     r10,r10,0xffff;                         \
1436         mtspr   SPRN_DEC,r10;                           \
1437         b       MASKED_DEC_HANDLER_LABEL;               \
1438 1:      andi.   r10,r10,(PACA_IRQ_DBELL|PACA_IRQ_HMI);  \
1439         bne     2f;                                     \
1440         mfspr   r10,SPRN_##_H##SRR1;                    \
1441         xori    r10,r10,MSR_EE; /* clear MSR_EE */      \
1442         mtspr   SPRN_##_H##SRR1,r10;                    \
1443 2:      mtcrf   0x80,r9;                                \
1444         ld      r9,PACA_EXGEN+EX_R9(r13);               \
1445         ld      r10,PACA_EXGEN+EX_R10(r13);             \
1446         ld      r11,PACA_EXGEN+EX_R11(r13);             \
1447         /* returns to kernel where r13 must be set up, so don't restore it */ \
1448         ##_H##RFI_TO_KERNEL;                            \
1449         b       .;                                      \
1450         MASKED_DEC_HANDLER(_H)
1451
1452 TRAMP_REAL_BEGIN(rfi_flush_fallback)
1453         SET_SCRATCH0(r13);
1454         GET_PACA(r13);
1455         std     r9,PACA_EXRFI+EX_R9(r13)
1456         std     r10,PACA_EXRFI+EX_R10(r13)
1457         std     r11,PACA_EXRFI+EX_R11(r13)
1458         std     r12,PACA_EXRFI+EX_R12(r13)
1459         std     r8,PACA_EXRFI+EX_R13(r13)
1460         mfctr   r9
1461         ld      r10,PACA_RFI_FLUSH_FALLBACK_AREA(r13)
1462         ld      r11,PACA_L1D_FLUSH_SETS(r13)
1463         ld      r12,PACA_L1D_FLUSH_CONGRUENCE(r13)
1464         /*
1465          * The load adresses are at staggered offsets within cachelines,
1466          * which suits some pipelines better (on others it should not
1467          * hurt).
1468          */
1469         addi    r12,r12,8
1470         mtctr   r11
1471         DCBT_STOP_ALL_STREAM_IDS(r11) /* Stop prefetch streams */
1472
1473         /* order ld/st prior to dcbt stop all streams with flushing */
1474         sync
1475 1:      li      r8,0
1476         .rept   8 /* 8-way set associative */
1477         ldx     r11,r10,r8
1478         add     r8,r8,r12
1479         xor     r11,r11,r11     // Ensure r11 is 0 even if fallback area is not
1480         add     r8,r8,r11       // Add 0, this creates a dependency on the ldx
1481         .endr
1482         addi    r10,r10,128 /* 128 byte cache line */
1483         bdnz    1b
1484
1485         mtctr   r9
1486         ld      r9,PACA_EXRFI+EX_R9(r13)
1487         ld      r10,PACA_EXRFI+EX_R10(r13)
1488         ld      r11,PACA_EXRFI+EX_R11(r13)
1489         ld      r12,PACA_EXRFI+EX_R12(r13)
1490         ld      r8,PACA_EXRFI+EX_R13(r13)
1491         GET_SCRATCH0(r13);
1492         rfid
1493
1494 TRAMP_REAL_BEGIN(hrfi_flush_fallback)
1495         SET_SCRATCH0(r13);
1496         GET_PACA(r13);
1497         std     r9,PACA_EXRFI+EX_R9(r13)
1498         std     r10,PACA_EXRFI+EX_R10(r13)
1499         std     r11,PACA_EXRFI+EX_R11(r13)
1500         std     r12,PACA_EXRFI+EX_R12(r13)
1501         std     r8,PACA_EXRFI+EX_R13(r13)
1502         mfctr   r9
1503         ld      r10,PACA_RFI_FLUSH_FALLBACK_AREA(r13)
1504         ld      r11,PACA_L1D_FLUSH_SETS(r13)
1505         ld      r12,PACA_L1D_FLUSH_CONGRUENCE(r13)
1506         /*
1507          * The load adresses are at staggered offsets within cachelines,
1508          * which suits some pipelines better (on others it should not
1509          * hurt).
1510          */
1511         addi    r12,r12,8
1512         mtctr   r11
1513         DCBT_STOP_ALL_STREAM_IDS(r11) /* Stop prefetch streams */
1514
1515         /* order ld/st prior to dcbt stop all streams with flushing */
1516         sync
1517 1:      li      r8,0
1518         .rept   8 /* 8-way set associative */
1519         ldx     r11,r10,r8
1520         add     r8,r8,r12
1521         xor     r11,r11,r11     // Ensure r11 is 0 even if fallback area is not
1522         add     r8,r8,r11       // Add 0, this creates a dependency on the ldx
1523         .endr
1524         addi    r10,r10,128 /* 128 byte cache line */
1525         bdnz    1b
1526
1527         mtctr   r9
1528         ld      r9,PACA_EXRFI+EX_R9(r13)
1529         ld      r10,PACA_EXRFI+EX_R10(r13)
1530         ld      r11,PACA_EXRFI+EX_R11(r13)
1531         ld      r12,PACA_EXRFI+EX_R12(r13)
1532         ld      r8,PACA_EXRFI+EX_R13(r13)
1533         GET_SCRATCH0(r13);
1534         hrfid
1535
1536 /*
1537  * Real mode exceptions actually use this too, but alternate
1538  * instruction code patches (which end up in the common .text area)
1539  * cannot reach these if they are put there.
1540  */
1541 USE_FIXED_SECTION(virt_trampolines)
1542         MASKED_INTERRUPT()
1543         MASKED_INTERRUPT(H)
1544
1545 #ifdef CONFIG_KVM_BOOK3S_64_HANDLER
1546 TRAMP_REAL_BEGIN(kvmppc_skip_interrupt)
1547         /*
1548          * Here all GPRs are unchanged from when the interrupt happened
1549          * except for r13, which is saved in SPRG_SCRATCH0.
1550          */
1551         mfspr   r13, SPRN_SRR0
1552         addi    r13, r13, 4
1553         mtspr   SPRN_SRR0, r13
1554         GET_SCRATCH0(r13)
1555         RFI_TO_KERNEL
1556         b       .
1557
1558 TRAMP_REAL_BEGIN(kvmppc_skip_Hinterrupt)
1559         /*
1560          * Here all GPRs are unchanged from when the interrupt happened
1561          * except for r13, which is saved in SPRG_SCRATCH0.
1562          */
1563         mfspr   r13, SPRN_HSRR0
1564         addi    r13, r13, 4
1565         mtspr   SPRN_HSRR0, r13
1566         GET_SCRATCH0(r13)
1567         HRFI_TO_KERNEL
1568         b       .
1569 #endif
1570
1571 /*
1572  * Ensure that any handlers that get invoked from the exception prologs
1573  * above are below the first 64KB (0x10000) of the kernel image because
1574  * the prologs assemble the addresses of these handlers using the
1575  * LOAD_HANDLER macro, which uses an ori instruction.
1576  */
1577
1578 /*** Common interrupt handlers ***/
1579
1580
1581         /*
1582          * Relocation-on interrupts: A subset of the interrupts can be delivered
1583          * with IR=1/DR=1, if AIL==2 and MSR.HV won't be changed by delivering
1584          * it.  Addresses are the same as the original interrupt addresses, but
1585          * offset by 0xc000000000004000.
1586          * It's impossible to receive interrupts below 0x300 via this mechanism.
1587          * KVM: None of these traps are from the guest ; anything that escalated
1588          * to HV=1 from HV=0 is delivered via real mode handlers.
1589          */
1590
1591         /*
1592          * This uses the standard macro, since the original 0x300 vector
1593          * only has extra guff for STAB-based processors -- which never
1594          * come here.
1595          */
1596
1597 EXC_COMMON_BEGIN(ppc64_runlatch_on_trampoline)
1598         b       __ppc64_runlatch_on
1599
1600 USE_FIXED_SECTION(virt_trampolines)
1601         /*
1602          * The __end_interrupts marker must be past the out-of-line (OOL)
1603          * handlers, so that they are copied to real address 0x100 when running
1604          * a relocatable kernel. This ensures they can be reached from the short
1605          * trampoline handlers (like 0x4f00, 0x4f20, etc.) which branch
1606          * directly, without using LOAD_HANDLER().
1607          */
1608         .align  7
1609         .globl  __end_interrupts
1610 __end_interrupts:
1611 DEFINE_FIXED_SYMBOL(__end_interrupts)
1612
1613 #ifdef CONFIG_PPC_970_NAP
1614 EXC_COMMON_BEGIN(power4_fixup_nap)
1615         andc    r9,r9,r10
1616         std     r9,TI_LOCAL_FLAGS(r11)
1617         ld      r10,_LINK(r1)           /* make idle task do the */
1618         std     r10,_NIP(r1)            /* equivalent of a blr */
1619         blr
1620 #endif
1621
1622 CLOSE_FIXED_SECTION(real_vectors);
1623 CLOSE_FIXED_SECTION(real_trampolines);
1624 CLOSE_FIXED_SECTION(virt_vectors);
1625 CLOSE_FIXED_SECTION(virt_trampolines);
1626
1627 USE_TEXT_SECTION()
1628
1629 /*
1630  * Hash table stuff
1631  */
1632         .balign IFETCH_ALIGN_BYTES
1633 do_hash_page:
1634 #ifdef CONFIG_PPC_BOOK3S_64
1635         lis     r0,(DSISR_BAD_FAULT_64S|DSISR_DABRMATCH)@h
1636         ori     r0,r0,DSISR_BAD_FAULT_64S@l
1637         and.    r0,r4,r0                /* weird error? */
1638         bne-    handle_page_fault       /* if not, try to insert a HPTE */
1639         CURRENT_THREAD_INFO(r11, r1)
1640         lwz     r0,TI_PREEMPT(r11)      /* If we're in an "NMI" */
1641         andis.  r0,r0,NMI_MASK@h        /* (i.e. an irq when soft-disabled) */
1642         bne     77f                     /* then don't call hash_page now */
1643
1644         /*
1645          * r3 contains the faulting address
1646          * r4 msr
1647          * r5 contains the trap number
1648          * r6 contains dsisr
1649          *
1650          * at return r3 = 0 for success, 1 for page fault, negative for error
1651          */
1652         mr      r4,r12
1653         ld      r6,_DSISR(r1)
1654         bl      __hash_page             /* build HPTE if possible */
1655         cmpdi   r3,0                    /* see if __hash_page succeeded */
1656
1657         /* Success */
1658         beq     fast_exc_return_irq     /* Return from exception on success */
1659
1660         /* Error */
1661         blt-    13f
1662
1663         /* Reload DSISR into r4 for the DABR check below */
1664         ld      r4,_DSISR(r1)
1665 #endif /* CONFIG_PPC_BOOK3S_64 */
1666
1667 /* Here we have a page fault that hash_page can't handle. */
1668 handle_page_fault:
1669 11:     andis.  r0,r4,DSISR_DABRMATCH@h
1670         bne-    handle_dabr_fault
1671         ld      r4,_DAR(r1)
1672         ld      r5,_DSISR(r1)
1673         addi    r3,r1,STACK_FRAME_OVERHEAD
1674         bl      do_page_fault
1675         cmpdi   r3,0
1676         beq+    12f
1677         bl      save_nvgprs
1678         mr      r5,r3
1679         addi    r3,r1,STACK_FRAME_OVERHEAD
1680         lwz     r4,_DAR(r1)
1681         bl      bad_page_fault
1682         b       ret_from_except
1683
1684 /* We have a data breakpoint exception - handle it */
1685 handle_dabr_fault:
1686         bl      save_nvgprs
1687         ld      r4,_DAR(r1)
1688         ld      r5,_DSISR(r1)
1689         addi    r3,r1,STACK_FRAME_OVERHEAD
1690         bl      do_break
1691 12:     b       ret_from_except_lite
1692
1693
1694 #ifdef CONFIG_PPC_BOOK3S_64
1695 /* We have a page fault that hash_page could handle but HV refused
1696  * the PTE insertion
1697  */
1698 13:     bl      save_nvgprs
1699         mr      r5,r3
1700         addi    r3,r1,STACK_FRAME_OVERHEAD
1701         ld      r4,_DAR(r1)
1702         bl      low_hash_fault
1703         b       ret_from_except
1704 #endif
1705
1706 /*
1707  * We come here as a result of a DSI at a point where we don't want
1708  * to call hash_page, such as when we are accessing memory (possibly
1709  * user memory) inside a PMU interrupt that occurred while interrupts
1710  * were soft-disabled.  We want to invoke the exception handler for
1711  * the access, or panic if there isn't a handler.
1712  */
1713 77:     bl      save_nvgprs
1714         mr      r4,r3
1715         addi    r3,r1,STACK_FRAME_OVERHEAD
1716         li      r5,SIGSEGV
1717         bl      bad_page_fault
1718         b       ret_from_except
1719
1720 /*
1721  * Here we have detected that the kernel stack pointer is bad.
1722  * R9 contains the saved CR, r13 points to the paca,
1723  * r10 contains the (bad) kernel stack pointer,
1724  * r11 and r12 contain the saved SRR0 and SRR1.
1725  * We switch to using an emergency stack, save the registers there,
1726  * and call kernel_bad_stack(), which panics.
1727  */
1728 bad_stack:
1729         ld      r1,PACAEMERGSP(r13)
1730         subi    r1,r1,64+INT_FRAME_SIZE
1731         std     r9,_CCR(r1)
1732         std     r10,GPR1(r1)
1733         std     r11,_NIP(r1)
1734         std     r12,_MSR(r1)
1735         mfspr   r11,SPRN_DAR
1736         mfspr   r12,SPRN_DSISR
1737         std     r11,_DAR(r1)
1738         std     r12,_DSISR(r1)
1739         mflr    r10
1740         mfctr   r11
1741         mfxer   r12
1742         std     r10,_LINK(r1)
1743         std     r11,_CTR(r1)
1744         std     r12,_XER(r1)
1745         SAVE_GPR(0,r1)
1746         SAVE_GPR(2,r1)
1747         ld      r10,EX_R3(r3)
1748         std     r10,GPR3(r1)
1749         SAVE_GPR(4,r1)
1750         SAVE_4GPRS(5,r1)
1751         ld      r9,EX_R9(r3)
1752         ld      r10,EX_R10(r3)
1753         SAVE_2GPRS(9,r1)
1754         ld      r9,EX_R11(r3)
1755         ld      r10,EX_R12(r3)
1756         ld      r11,EX_R13(r3)
1757         std     r9,GPR11(r1)
1758         std     r10,GPR12(r1)
1759         std     r11,GPR13(r1)
1760 BEGIN_FTR_SECTION
1761         ld      r10,EX_CFAR(r3)
1762         std     r10,ORIG_GPR3(r1)
1763 END_FTR_SECTION_IFSET(CPU_FTR_CFAR)
1764         SAVE_8GPRS(14,r1)
1765         SAVE_10GPRS(22,r1)
1766         lhz     r12,PACA_TRAP_SAVE(r13)
1767         std     r12,_TRAP(r1)
1768         addi    r11,r1,INT_FRAME_SIZE
1769         std     r11,0(r1)
1770         li      r12,0
1771         std     r12,0(r11)
1772         ld      r2,PACATOC(r13)
1773         ld      r11,exception_marker@toc(r2)
1774         std     r12,RESULT(r1)
1775         std     r11,STACK_FRAME_OVERHEAD-16(r1)
1776 1:      addi    r3,r1,STACK_FRAME_OVERHEAD
1777         bl      kernel_bad_stack
1778         b       1b
1779 _ASM_NOKPROBE_SYMBOL(bad_stack);
1780
1781 /*
1782  * When doorbell is triggered from system reset wakeup, the message is
1783  * not cleared, so it would fire again when EE is enabled.
1784  *
1785  * When coming from local_irq_enable, there may be the same problem if
1786  * we were hard disabled.
1787  *
1788  * Execute msgclr to clear pending exceptions before handling it.
1789  */
1790 h_doorbell_common_msgclr:
1791         LOAD_REG_IMMEDIATE(r3, PPC_DBELL_MSGTYPE << (63-36))
1792         PPC_MSGCLR(3)
1793         b       h_doorbell_common
1794
1795 doorbell_super_common_msgclr:
1796         LOAD_REG_IMMEDIATE(r3, PPC_DBELL_MSGTYPE << (63-36))
1797         PPC_MSGCLRP(3)
1798         b       doorbell_super_common
1799
1800 /*
1801  * Called from arch_local_irq_enable when an interrupt needs
1802  * to be resent. r3 contains 0x500, 0x900, 0xa00 or 0xe80 to indicate
1803  * which kind of interrupt. MSR:EE is already off. We generate a
1804  * stackframe like if a real interrupt had happened.
1805  *
1806  * Note: While MSR:EE is off, we need to make sure that _MSR
1807  * in the generated frame has EE set to 1 or the exception
1808  * handler will not properly re-enable them.
1809  *
1810  * Note that we don't specify LR as the NIP (return address) for
1811  * the interrupt because that would unbalance the return branch
1812  * predictor.
1813  */
1814 _GLOBAL(__replay_interrupt)
1815         /* We are going to jump to the exception common code which
1816          * will retrieve various register values from the PACA which
1817          * we don't give a damn about, so we don't bother storing them.
1818          */
1819         mfmsr   r12
1820         LOAD_REG_ADDR(r11, replay_interrupt_return)
1821         mfcr    r9
1822         ori     r12,r12,MSR_EE
1823         cmpwi   r3,0x900
1824         beq     decrementer_common
1825         cmpwi   r3,0x500
1826 BEGIN_FTR_SECTION
1827         beq     h_virt_irq_common
1828 FTR_SECTION_ELSE
1829         beq     hardware_interrupt_common
1830 ALT_FTR_SECTION_END_IFSET(CPU_FTR_HVMODE | CPU_FTR_ARCH_300)
1831 BEGIN_FTR_SECTION
1832         cmpwi   r3,0xa00
1833         beq     h_doorbell_common_msgclr
1834         cmpwi   r3,0xe60
1835         beq     hmi_exception_common
1836 FTR_SECTION_ELSE
1837         cmpwi   r3,0xa00
1838         beq     doorbell_super_common_msgclr
1839 ALT_FTR_SECTION_END_IFSET(CPU_FTR_HVMODE)
1840 replay_interrupt_return:
1841         blr
1842
1843 _ASM_NOKPROBE_SYMBOL(__replay_interrupt)