arch/parisc/kernel/syscall.S

   1 /*
   2  * Linux/PA-RISC Project (http://www.parisc-linux.org/)
   3  *
   4  * System call entry code Copyright (c) Matthew Wilcox 1999 <willy@bofh.ai>
   5  * Licensed under the GNU GPL.
   6  * thanks to Philipp Rumpf, Mike Shaver and various others
   7  * sorry about the wall, puffin..
   8  */
   9 #include <linux/config.h> /* for CONFIG_SMP */
  10
  11 #include <asm/asm-offsets.h>
  12 #include <asm/unistd.h>
  13 #include <asm/errno.h>
  14 #include <asm/psw.h>
  15 #include <asm/thread_info.h>
  16
  17 #include <asm/assembly.h>
  18 #include <asm/processor.h>
  19
  20         /* We fill the empty parts of the gateway page with
  21          * something that will kill the kernel or a
  22          * userspace application.
  23          */
  24 #define KILL_INSN       break   0,0
  25
  26 #ifdef CONFIG_64BIT
  27         .level          2.0w
  28 #else
  29         .level          1.1
  30 #endif
  31
  32 #ifndef CONFIG_64BIT
  33         .macro fixup_branch,lbl
  34         b           \lbl
  35         .endm
  36 #else
  37         .macro fixup_branch,lbl
  38         ldil        L%\lbl, %r1
  39         ldo         R%\lbl(%r1), %r1
  40         bv,n        %r0(%r1)
  41         .endm
  42 #endif
  43
  44         .text
  45
  46         .import syscall_exit,code
  47         .import syscall_exit_rfi,code
  48         .export linux_gateway_page
  49
  50         /* Linux gateway page is aliased to virtual page 0 in the kernel
  51          * address space. Since it is a gateway page it cannot be
  52          * dereferenced, so null pointers will still fault. We start
  53          * the actual entry point at 0x100. We put break instructions
  54          * at the beginning of the page to trap null indirect function
  55          * pointers.
  56          */
  57
  58         .align ASM_PAGE_SIZE
  59 linux_gateway_page:
  60
  61         /* ADDRESS 0x00 to 0xb0 = 176 bytes / 4 bytes per insn = 44 insns */
  62         .rept 44
  63         KILL_INSN
  64         .endr
  65
  66         /* ADDRESS 0xb0 to 0xb4, lws uses 1 insns for entry */
  67         /* Light-weight-syscall entry must always be located at 0xb0 */
  68         /* WARNING: Keep this number updated with table size changes */
  69 #define __NR_lws_entries (2)
  70
  71 lws_entry:
  72         /* Unconditional branch to lws_start, located on the
  73            same gateway page */
  74         b,n     lws_start
  75
  76         /* Fill from 0xb4 to 0xe0 */
  77         .rept 11
  78         KILL_INSN
  79         .endr
  80
  81         /* This function MUST be located at 0xe0 for glibc's threading
  82         mechanism to work. DO NOT MOVE THIS CODE EVER! */
  83 set_thread_pointer:
  84         gate    .+8, %r0                /* increase privilege */
  85         depi    3, 31, 2, %r31          /* Ensure we return into user mode. */
  86         be      0(%sr7,%r31)            /* return to user space */
  87         mtctl   %r26, %cr27             /* move arg0 to the control register */
  88
  89         /* Increase the chance of trapping if random jumps occur to this
  90         address, fill from 0xf0 to 0x100 */
  91         .rept 4
  92         KILL_INSN
  93         .endr
  94
  95 /* This address must remain fixed at 0x100 for glibc's syscalls to work */
  96         .align 256
  97 linux_gateway_entry:
  98         gate    .+8, %r0                        /* become privileged */
  99         mtsp    %r0,%sr4                        /* get kernel space into sr4 */
 100         mtsp    %r0,%sr5                        /* get kernel space into sr5 */
 101         mtsp    %r0,%sr6                        /* get kernel space into sr6 */
 102         mfsp    %sr7,%r1                        /* save user sr7 */
 103         mtsp    %r1,%sr3                        /* and store it in sr3 */
 104
 105 #ifdef CONFIG_64BIT
 106         /* for now we can *always* set the W bit on entry to the syscall
 107          * since we don't support wide userland processes.  We could
 108          * also save the current SM other than in r0 and restore it on
 109          * exit from the syscall, and also use that value to know
 110          * whether to do narrow or wide syscalls. -PB
 111          */
 112         ssm     PSW_SM_W, %r1
 113         extrd,u %r1,PSW_W_BIT,1,%r1
 114         /* sp must be aligned on 4, so deposit the W bit setting into
 115          * the bottom of sp temporarily */
 116         or,ev   %r1,%r30,%r30
 117         b,n     1f
 118         /* The top halves of argument registers must be cleared on syscall
 119          * entry from narrow executable.
 120          */
 121         depdi   0, 31, 32, %r26
 122         depdi   0, 31, 32, %r25
 123         depdi   0, 31, 32, %r24
 124         depdi   0, 31, 32, %r23
 125         depdi   0, 31, 32, %r22
 126         depdi   0, 31, 32, %r21
 127 1:
 128 #endif
 129         mfctl   %cr30,%r1
 130         xor     %r1,%r30,%r30                   /* ye olde xor trick */
 131         xor     %r1,%r30,%r1
 132         xor     %r1,%r30,%r30
 133
 134         ldo     THREAD_SZ_ALGN+FRAME_SIZE(%r30),%r30  /* set up kernel stack */
 135
 136         /* N.B.: It is critical that we don't set sr7 to 0 until r30
 137          *       contains a valid kernel stack pointer. It is also
 138          *       critical that we don't start using the kernel stack
 139          *       until after sr7 has been set to 0.
 140          */
 141
 142         mtsp    %r0,%sr7                        /* get kernel space into sr7 */
 143         STREGM  %r1,FRAME_SIZE(%r30)            /* save r1 (usp) here for now */
 144         mfctl   %cr30,%r1                       /* get task ptr in %r1 */
 145         LDREG   TI_TASK(%r1),%r1
 146
 147         /* Save some registers for sigcontext and potential task
 148            switch (see entry.S for the details of which ones are
 149            saved/restored).  TASK_PT_PSW is zeroed so we can see whether
 150            a process is on a syscall or not.  For an interrupt the real
 151            PSW value is stored.  This is needed for gdb and sys_ptrace. */
 152         STREG   %r0,  TASK_PT_PSW(%r1)
 153         STREG   %r2,  TASK_PT_GR2(%r1)          /* preserve rp */
 154         STREG   %r19, TASK_PT_GR19(%r1)
 155
 156         LDREGM  -FRAME_SIZE(%r30), %r2          /* get users sp back */
 157 #ifdef CONFIG_64BIT
 158         extrd,u %r2,63,1,%r19                   /* W hidden in bottom bit */
 159 #if 0
 160         xor     %r19,%r2,%r2                    /* clear bottom bit */
 161         depd,z  %r19,1,1,%r19
 162         std     %r19,TASK_PT_PSW(%r1)
 163 #endif
 164 #endif
 165         STREG   %r2,  TASK_PT_GR30(%r1)         /* ... and save it */
 166
 167         STREG   %r20, TASK_PT_GR20(%r1)         /* Syscall number */
 168         STREG   %r21, TASK_PT_GR21(%r1)
 169         STREG   %r22, TASK_PT_GR22(%r1)
 170         STREG   %r23, TASK_PT_GR23(%r1)         /* 4th argument */
 171         STREG   %r24, TASK_PT_GR24(%r1)         /* 3rd argument */
 172         STREG   %r25, TASK_PT_GR25(%r1)         /* 2nd argument */
 173         STREG   %r26, TASK_PT_GR26(%r1)         /* 1st argument */
 174         STREG   %r27, TASK_PT_GR27(%r1)         /* user dp */
 175         STREG   %r28, TASK_PT_GR28(%r1)         /* return value 0 */
 176         STREG   %r28, TASK_PT_ORIG_R28(%r1)     /* return value 0 (saved for signals) */
 177         STREG   %r29, TASK_PT_GR29(%r1)         /* return value 1 */
 178         STREG   %r31, TASK_PT_GR31(%r1)         /* preserve syscall return ptr */
 179
 180         ldo     TASK_PT_FR0(%r1), %r27          /* save fpregs from the kernel */
 181         save_fp %r27                            /* or potential task switch  */
 182
 183         mfctl   %cr11, %r27                     /* i.e. SAR */
 184         STREG   %r27, TASK_PT_SAR(%r1)
 185
 186         loadgp
 187
 188 #ifdef CONFIG_64BIT
 189         ldo     -16(%r30),%r29                  /* Reference param save area */
 190         copy    %r19,%r2                        /* W bit back to r2 */
 191 #else
 192         /* no need to save these on stack in wide mode because the first 8
 193          * args are passed in registers */
 194         stw     %r22, -52(%r30)                 /* 5th argument */
 195         stw     %r21, -56(%r30)                 /* 6th argument */
 196 #endif
 197
 198         /* Are we being ptraced? */
 199         mfctl   %cr30, %r1
 200         LDREG   TI_TASK(%r1),%r1
 201         LDREG   TASK_PTRACE(%r1), %r1
 202         bb,<,n  %r1,31,.Ltracesys
 203
 204         /* Note!  We cannot use the syscall table that is mapped
 205         nearby since the gateway page is mapped execute-only. */
 206
 207 #ifdef CONFIG_64BIT
 208         ldil    L%sys_call_table, %r1
 209         or,=    %r2,%r2,%r2
 210         addil   L%(sys_call_table64-sys_call_table), %r1
 211         ldo     R%sys_call_table(%r1), %r19
 212         or,=    %r2,%r2,%r2
 213         ldo     R%sys_call_table64(%r1), %r19
 214 #else
 215         ldil    L%sys_call_table, %r1
 216         ldo     R%sys_call_table(%r1), %r19
 217 #endif
 218         comiclr,>>=     __NR_Linux_syscalls, %r20, %r0
 219         b,n     .Lsyscall_nosys
 220
 221         LDREGX  %r20(%r19), %r19
 222
 223         /* If this is a sys_rt_sigreturn call, and the signal was received
 224          * when not in_syscall, then we want to return via syscall_exit_rfi,
 225          * not syscall_exit.  Signal no. in r20, in_syscall in r25 (see
 226          * trampoline code in signal.c).
 227          */
 228         ldi     __NR_rt_sigreturn,%r2
 229         comb,=  %r2,%r20,.Lrt_sigreturn
 230 .Lin_syscall:
 231         ldil    L%syscall_exit,%r2
 232         be      0(%sr7,%r19)
 233         ldo     R%syscall_exit(%r2),%r2
 234 .Lrt_sigreturn:
 235         comib,<> 0,%r25,.Lin_syscall
 236         ldil    L%syscall_exit_rfi,%r2
 237         be      0(%sr7,%r19)
 238         ldo     R%syscall_exit_rfi(%r2),%r2
 239
 240         /* Note!  Because we are not running where we were linked, any
 241         calls to functions external to this file must be indirect.  To
 242         be safe, we apply the opposite rule to functions within this
 243         file, with local labels given to them to ensure correctness. */
 244
 245 .Lsyscall_nosys:
 246 syscall_nosys:
 247         ldil    L%syscall_exit,%r1
 248         be      R%syscall_exit(%sr7,%r1)
 249         ldo     -ENOSYS(%r0),%r28                  /* set errno */
 250
 251
 252 /* Warning! This trace code is a virtual duplicate of the code above so be
 253  * sure to maintain both! */
 254 .Ltracesys:
 255 tracesys:
 256         /* Need to save more registers so the debugger can see where we
 257          * are.  This saves only the lower 8 bits of PSW, so that the C
 258          * bit is still clear on syscalls, and the D bit is set if this
 259          * full register save path has been executed.  We check the D
 260          * bit on syscall_return_rfi to determine which registers to
 261          * restore.  An interrupt results in a full PSW saved with the
 262          * C bit set, a non-straced syscall entry results in C and D clear
 263          * in the saved PSW.
 264          */
 265         ldo     -THREAD_SZ_ALGN-FRAME_SIZE(%r30),%r1      /* get task ptr */
 266         LDREG   TI_TASK(%r1), %r1
 267         ssm     0,%r2
 268         STREG   %r2,TASK_PT_PSW(%r1)            /* Lower 8 bits only!! */
 269         mfsp    %sr0,%r2
 270         STREG   %r2,TASK_PT_SR0(%r1)
 271         mfsp    %sr1,%r2
 272         STREG   %r2,TASK_PT_SR1(%r1)
 273         mfsp    %sr2,%r2
 274         STREG   %r2,TASK_PT_SR2(%r1)
 275         mfsp    %sr3,%r2
 276         STREG   %r2,TASK_PT_SR3(%r1)
 277         STREG   %r2,TASK_PT_SR4(%r1)
 278         STREG   %r2,TASK_PT_SR5(%r1)
 279         STREG   %r2,TASK_PT_SR6(%r1)
 280         STREG   %r2,TASK_PT_SR7(%r1)
 281         STREG   %r2,TASK_PT_IASQ0(%r1)
 282         STREG   %r2,TASK_PT_IASQ1(%r1)
 283         LDREG   TASK_PT_GR31(%r1),%r2
 284         STREG   %r2,TASK_PT_IAOQ0(%r1)
 285         ldo     4(%r2),%r2
 286         STREG   %r2,TASK_PT_IAOQ1(%r1)
 287         ldo     TASK_REGS(%r1),%r2
 288         /* reg_save %r2 */
 289         STREG   %r3,PT_GR3(%r2)
 290         STREG   %r4,PT_GR4(%r2)
 291         STREG   %r5,PT_GR5(%r2)
 292         STREG   %r6,PT_GR6(%r2)
 293         STREG   %r7,PT_GR7(%r2)
 294         STREG   %r8,PT_GR8(%r2)
 295         STREG   %r9,PT_GR9(%r2)
 296         STREG   %r10,PT_GR10(%r2)
 297         STREG   %r11,PT_GR11(%r2)
 298         STREG   %r12,PT_GR12(%r2)
 299         STREG   %r13,PT_GR13(%r2)
 300         STREG   %r14,PT_GR14(%r2)
 301         STREG   %r15,PT_GR15(%r2)
 302         STREG   %r16,PT_GR16(%r2)
 303         STREG   %r17,PT_GR17(%r2)
 304         STREG   %r18,PT_GR18(%r2)
 305         /* Finished saving things for the debugger */
 306
 307         ldil    L%syscall_trace,%r1
 308         ldil    L%tracesys_next,%r2
 309         be      R%syscall_trace(%sr7,%r1)
 310         ldo     R%tracesys_next(%r2),%r2
 311
 312 tracesys_next:
 313         ldil    L%sys_call_table,%r1
 314         ldo     R%sys_call_table(%r1), %r19
 315
 316         ldo     -THREAD_SZ_ALGN-FRAME_SIZE(%r30),%r1      /* get task ptr */
 317         LDREG   TI_TASK(%r1), %r1
 318         LDREG   TASK_PT_GR20(%r1), %r20
 319         LDREG   TASK_PT_GR26(%r1), %r26         /* Restore the users args */
 320         LDREG   TASK_PT_GR25(%r1), %r25
 321         LDREG   TASK_PT_GR24(%r1), %r24
 322         LDREG   TASK_PT_GR23(%r1), %r23
 323 #ifdef CONFIG_64BIT
 324         LDREG   TASK_PT_GR22(%r1), %r22
 325         LDREG   TASK_PT_GR21(%r1), %r21
 326         ldo     -16(%r30),%r29                  /* Reference param save area */
 327 #endif
 328
 329         comiclr,>>=     __NR_Linux_syscalls, %r20, %r0
 330         b,n     .Lsyscall_nosys
 331
 332         LDREGX  %r20(%r19), %r19
 333
 334         /* If this is a sys_rt_sigreturn call, and the signal was received
 335          * when not in_syscall, then we want to return via syscall_exit_rfi,
 336          * not syscall_exit.  Signal no. in r20, in_syscall in r25 (see
 337          * trampoline code in signal.c).
 338          */
 339         ldi     __NR_rt_sigreturn,%r2
 340         comb,=  %r2,%r20,.Ltrace_rt_sigreturn
 341 .Ltrace_in_syscall:
 342         ldil    L%tracesys_exit,%r2
 343         be      0(%sr7,%r19)
 344         ldo     R%tracesys_exit(%r2),%r2
 345
 346         /* Do *not* call this function on the gateway page, because it
 347         makes a direct call to syscall_trace. */
 348
 349 tracesys_exit:
 350         ldo     -THREAD_SZ_ALGN-FRAME_SIZE(%r30),%r1      /* get task ptr */
 351         LDREG   TI_TASK(%r1), %r1
 352 #ifdef CONFIG_64BIT
 353         ldo     -16(%r30),%r29                  /* Reference param save area */
 354 #endif
 355         bl      syscall_trace, %r2
 356         STREG   %r28,TASK_PT_GR28(%r1)          /* save return value now */
 357         ldo     -THREAD_SZ_ALGN-FRAME_SIZE(%r30),%r1      /* get task ptr */
 358         LDREG   TI_TASK(%r1), %r1
 359         LDREG   TASK_PT_GR28(%r1), %r28         /* Restore return val. */
 360
 361         ldil    L%syscall_exit,%r1
 362         be,n    R%syscall_exit(%sr7,%r1)
 363
 364 .Ltrace_rt_sigreturn:
 365         comib,<> 0,%r25,.Ltrace_in_syscall
 366         ldil    L%tracesys_sigexit,%r2
 367         be      0(%sr7,%r19)
 368         ldo     R%tracesys_sigexit(%r2),%r2
 369
 370 tracesys_sigexit:
 371         ldo     -THREAD_SZ_ALGN-FRAME_SIZE(%r30),%r1      /* get task ptr */
 372         LDREG   0(%r1), %r1
 373 #ifdef CONFIG_64BIT
 374         ldo     -16(%r30),%r29                  /* Reference param save area */
 375 #endif
 376         bl      syscall_trace, %r2
 377         nop
 378
 379         ldil    L%syscall_exit_rfi,%r1
 380         be,n    R%syscall_exit_rfi(%sr7,%r1)
 381
 382
 383         /*********************************************************
 384                 Light-weight-syscall code
 385
 386                 r20 - lws number
 387                 r26,r25,r24,r23,r22 - Input registers
 388                 r28 - Function return register
 389                 r21 - Error code.
 390
 391                 Scracth: Any of the above that aren't being
 392                 currently used, including r1.
 393
 394                 Return pointer: r31 (Not usable)
 395
 396                 Error codes returned by entry path:
 397
 398                 ENOSYS - r20 was an invalid LWS number.
 399
 400         *********************************************************/
 401 lws_start:
 402         /* Gate and ensure we return to userspace */
 403         gate    .+8, %r0
 404         depi    3, 31, 2, %r31  /* Ensure we return to userspace */
 405
 406 #ifdef CONFIG_64BIT
 407         /* FIXME: If we are a 64-bit kernel just
 408          *        turn this on unconditionally.
 409          */
 410         ssm     PSW_SM_W, %r1
 411         extrd,u %r1,PSW_W_BIT,1,%r1
 412         /* sp must be aligned on 4, so deposit the W bit setting into
 413          * the bottom of sp temporarily */
 414         or,ev   %r1,%r30,%r30
 415
 416         /* Clip LWS number to a 32-bit value always */
 417         depdi   0, 31, 32, %r20
 418 #endif
 419
 420         /* Is the lws entry number valid? */
 421         comiclr,>>=     __NR_lws_entries, %r20, %r0
 422         b,n     lws_exit_nosys
 423
 424         /* WARNING: Trashing sr2 and sr3 */
 425         mfsp    %sr7,%r1                        /* get userspace into sr3 */
 426         mtsp    %r1,%sr3
 427         mtsp    %r0,%sr2                        /* get kernel space into sr2 */
 428
 429         /* Load table start */
 430         ldil    L%lws_table, %r1
 431         ldo     R%lws_table(%r1), %r28  /* Scratch use of r28 */
 432         LDREGX  %r20(%sr2,r28), %r21    /* Scratch use of r21 */
 433
 434         /* Jump to lws, lws table pointers already relocated */
 435         be,n    0(%sr2,%r21)
 436
 437 lws_exit_nosys:
 438         ldo     -ENOSYS(%r0),%r21                  /* set errno */
 439         /* Fall through: Return to userspace */
 440
 441 lws_exit:
 442 #ifdef CONFIG_64BIT
 443         /* decide whether to reset the wide mode bit
 444          *
 445          * For a syscall, the W bit is stored in the lowest bit
 446          * of sp.  Extract it and reset W if it is zero */
 447         extrd,u,*<>     %r30,63,1,%r1
 448         rsm     PSW_SM_W, %r0
 449         /* now reset the lowest bit of sp if it was set */
 450         xor     %r30,%r1,%r30
 451 #endif
 452         be,n    0(%sr3, %r31)
 453
 454
 455
 456         /***************************************************
 457                 Implementing CAS as an atomic operation:
 458
 459                 %r26 - Address to examine
 460                 %r25 - Old value to check (old)
 461                 %r24 - New value to set (new)
 462                 %r28 - Return prev through this register.
 463                 %r21 - Kernel error code
 464
 465                 If debugging is DISabled:
 466
 467                 %r21 has the following meanings:
 468
 469                 EAGAIN - CAS is busy, ldcw failed, try again.
 470                 EFAULT - Read or write failed.
 471
 472                 If debugging is enabled:
 473
 474                 EDEADLOCK - CAS called recursively.
 475                 EAGAIN && r28 == 1 - CAS is busy. Lock contended.
 476                 EAGAIN && r28 == 2 - CAS is busy. ldcw failed.
 477                 EFAULT - Read or write failed.
 478
 479                 Scratch: r20, r28, r1
 480
 481         ****************************************************/
 482
 483         /* Do not enable LWS debugging */
 484 #define ENABLE_LWS_DEBUG 0
 485
 486         /* ELF64 Process entry path */
 487 lws_compare_and_swap64:
 488 #ifdef CONFIG_64BIT
 489         b,n     lws_compare_and_swap
 490 #else
 491         /* If we are not a 64-bit kernel, then we don't
 492          * implement having 64-bit input registers
 493          */
 494         b,n     lws_exit_nosys
 495 #endif
 496
 497         /* ELF32 Process entry path */
 498 lws_compare_and_swap32:
 499 #ifdef CONFIG_64BIT
 500         /* Clip all the input registers */
 501         depdi   0, 31, 32, %r26
 502         depdi   0, 31, 32, %r25
 503         depdi   0, 31, 32, %r24
 504 #endif
 505
 506 lws_compare_and_swap:
 507 #ifdef CONFIG_SMP
 508         /* Load start of lock table */
 509         ldil    L%lws_lock_start, %r20
 510         ldo     R%lws_lock_start(%r20), %r28
 511
 512         /* Extract four bits from r26 and hash lock (Bits 4-7) */
 513         extru  %r26, 27, 4, %r20
 514
 515         /* Find lock to use, the hash is either one of 0 to
 516            15, multiplied by 16 (keep it 16-byte aligned)
 517            and add to the lock table offset. */
 518         shlw    %r20, 4, %r20
 519         add     %r20, %r28, %r20
 520
 521 # ifdef ENABLE_LWS_DEBUG
 522         /*
 523                 DEBUG, check for deadlock!
 524                 If the thread register values are the same
 525                 then we were the one that locked it last and
 526                 this is a recurisve call that will deadlock.
 527                 We *must* giveup this call and fail.
 528         */
 529         ldw     4(%sr2,%r20), %r28                      /* Load thread register */
 530         /* WARNING: If cr27 cycles to the same value we have problems */
 531         mfctl   %cr27, %r21                             /* Get current thread register */
 532         cmpb,<>,n       %r21, %r28, cas_lock            /* Called recursive? */
 533         b       lws_exit                                /* Return error! */
 534         ldo     -EDEADLOCK(%r0), %r21
 535 cas_lock:
 536         cmpb,=,n        %r0, %r28, cas_nocontend        /* Is nobody using it? */
 537         ldo     1(%r0), %r28                            /* 1st case */
 538         b       lws_exit                                /* Contended... */
 539         ldo     -EAGAIN(%r0), %r21                      /* Spin in userspace */
 540 cas_nocontend:
 541 # endif
 542 /* ENABLE_LWS_DEBUG */
 543
 544         ldcw    0(%sr2,%r20), %r28                      /* Try to acquire the lock */
 545         cmpb,<>,n       %r0, %r28, cas_action           /* Did we get it? */
 546 cas_wouldblock:
 547         ldo     2(%r0), %r28                            /* 2nd case */
 548         b       lws_exit                                /* Contended... */
 549         ldo     -EAGAIN(%r0), %r21                      /* Spin in userspace */
 550 #endif
 551 /* CONFIG_SMP */
 552
 553         /*
 554                 prev = *addr;
 555                 if ( prev == old )
 556                   *addr = new;
 557                 return prev;
 558         */
 559
 560         /* NOTES:
 561                 This all works becuse intr_do_signal
 562                 and schedule both check the return iasq
 563                 and see that we are on the kernel page
 564                 so this process is never scheduled off
 565                 or is ever sent any signal of any sort,
 566                 thus it is wholly atomic from usrspaces
 567                 perspective
 568         */
 569 cas_action:
 570 #if defined CONFIG_SMP && defined ENABLE_LWS_DEBUG
 571         /* DEBUG */
 572         mfctl   %cr27, %r1
 573         stw     %r1, 4(%sr2,%r20)
 574 #endif
 575         /* The load and store could fail */
 576 1:      ldw     0(%sr3,%r26), %r28
 577         sub,<>  %r28, %r25, %r0
 578 2:      stw     %r24, 0(%sr3,%r26)
 579 #ifdef CONFIG_SMP
 580         /* Free lock */
 581         stw     %r20, 0(%sr2,%r20)
 582 # ifdef ENABLE_LWS_DEBUG
 583         /* Clear thread register indicator */
 584         stw     %r0, 4(%sr2,%r20)
 585 # endif
 586 #endif
 587         /* Return to userspace, set no error */
 588         b       lws_exit
 589         copy    %r0, %r21
 590
 591 3:
 592         /* Error occured on load or store */
 593 #ifdef CONFIG_SMP
 594         /* Free lock */
 595         stw     %r20, 0(%sr2,%r20)
 596 # ifdef ENABLE_LWS_DEBUG
 597         stw     %r0, 4(%sr2,%r20)
 598 # endif
 599 #endif
 600         b       lws_exit
 601         ldo     -EFAULT(%r0),%r21       /* set errno */
 602         nop
 603         nop
 604         nop
 605         nop
 606
 607         /* Two exception table entries, one for the load,
 608            the other for the store. Either return -EFAULT.
 609            Each of the entries must be relocated. */
 610         .section __ex_table,"aw"
 611 #ifdef CONFIG_64BIT
 612         /* Pad the address calculation */
 613         .word   0,(2b - linux_gateway_page)
 614         .word   0,(3b - linux_gateway_page)
 615 #else
 616         .word   (2b - linux_gateway_page)
 617         .word   (3b - linux_gateway_page)
 618 #endif
 619         .previous
 620
 621         .section __ex_table,"aw"
 622 #ifdef CONFIG_64BIT
 623         /* Pad the address calculation */
 624         .word   0,(1b - linux_gateway_page)
 625         .word   0,(3b - linux_gateway_page)
 626 #else
 627         .word   (1b - linux_gateway_page)
 628         .word   (3b - linux_gateway_page)
 629 #endif
 630         .previous
 631
 632 end_compare_and_swap:
 633
 634         /* Make sure nothing else is placed on this page */
 635         .align ASM_PAGE_SIZE
 636         .export end_linux_gateway_page
 637 end_linux_gateway_page:
 638
 639         /* Relocate symbols assuming linux_gateway_page is mapped
 640            to virtual address 0x0 */
 641 #ifdef CONFIG_64BIT
 642         /* FIXME: The code will always be on the gateay page
 643                   and thus it will be on the first 4k, the
 644                   assembler seems to think that the final
 645                   subtraction result is only a word in
 646                   length, so we pad the value.
 647         */
 648 #define LWS_ENTRY(_name_) .word 0,(lws_##_name_ - linux_gateway_page)
 649 #else
 650 #define LWS_ENTRY(_name_) .word  (lws_##_name_ - linux_gateway_page)
 651 #endif
 652
 653         .section .rodata,"a"
 654
 655         .align ASM_PAGE_SIZE
 656         /* Light-weight-syscall table */
 657         /* Start of lws table. */
 658         .export lws_table
 659 .Llws_table:
 660 lws_table:
 661         LWS_ENTRY(compare_and_swap32)   /* 0 - ELF32 Atomic compare and swap */
 662         LWS_ENTRY(compare_and_swap64)   /* 1 - ELF64 Atomic compare and swap */
 663         /* End of lws table */
 664
 665         .align ASM_PAGE_SIZE
 666         .export sys_call_table
 667 .Lsys_call_table:
 668 sys_call_table:
 669 #include "syscall_table.S"
 670
 671 #ifdef CONFIG_64BIT
 672         .align ASM_PAGE_SIZE
 673         .export sys_call_table64
 674 .Lsys_call_table64:
 675 sys_call_table64:
 676 #define SYSCALL_TABLE_64BIT
 677 #include "syscall_table.S"
 678 #endif
 679
 680 #ifdef CONFIG_SMP
 681         /*
 682                 All light-weight-syscall atomic operations
 683                 will use this set of locks
 684         */
 685         .section .data
 686         .align 4096
 687         .export lws_lock_start
 688 .Llws_lock_start:
 689 lws_lock_start:
 690         /* lws locks */
 691         .align 16
 692         .rept 16
 693         /* Keep locks aligned at 16-bytes */
 694         .word 1
 695         .word 0
 696         .word 0
 697         .word 0
 698         .endr
 699         .previous
 700 #endif
 701 /* CONFIG_SMP for lws_lock_start */
 702
 703 .end
 704
 705