arch/i386/kernel/vmlinux.lds.S

   1 /* ld script to make i386 Linux kernel
   2  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>;
   3  */
   4
   5 #define LOAD_OFFSET __PAGE_OFFSET
   6
   7 #include <asm-generic/vmlinux.lds.h>
   8 #include <asm/thread_info.h>
   9 #include <asm/page.h>
  10 #include <asm/cache.h>
  11
  12 OUTPUT_FORMAT("elf32-i386", "elf32-i386", "elf32-i386")
  13 OUTPUT_ARCH(i386)
  14 ENTRY(phys_startup_32)
  15 jiffies = jiffies_64;
  16 SECTIONS
  17 {
  18   . = __KERNEL_START;
  19   phys_startup_32 = startup_32 - LOAD_OFFSET;
  20   /* read-only */
  21   _text = .;                    /* Text and read-only data */
  22   .text : AT(ADDR(.text) - LOAD_OFFSET) {
  23         *(.text)
  24         SCHED_TEXT
  25         LOCK_TEXT
  26         KPROBES_TEXT
  27         *(.fixup)
  28         *(.gnu.warning)
  29         } = 0x9090
  30
  31   _etext = .;                   /* End of text section */
  32
  33   . = ALIGN(16);                /* Exception table */
  34   __start___ex_table = .;
  35   __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { *(__ex_table) }
  36   __stop___ex_table = .;
  37
  38   RODATA
  39
  40   . = ALIGN(4);
  41   __tracedata_start = .;
  42   .tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) {
  43         *(.tracedata)
  44   }
  45   __tracedata_end = .;
  46
  47   /* writeable */
  48   .data : AT(ADDR(.data) - LOAD_OFFSET) {       /* Data */
  49         *(.data)
  50         CONSTRUCTORS
  51         }
  52
  53   . = ALIGN(4096);
  54   __nosave_begin = .;
  55   .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) { *(.data.nosave) }
  56   . = ALIGN(4096);
  57   __nosave_end = .;
  58
  59   . = ALIGN(4096);
  60   .data.page_aligned : AT(ADDR(.data.page_aligned) - LOAD_OFFSET) {
  61         *(.data.idt)
  62   }
  63
  64   . = ALIGN(32);
  65   .data.cacheline_aligned : AT(ADDR(.data.cacheline_aligned) - LOAD_OFFSET) {
  66         *(.data.cacheline_aligned)
  67   }
  68
  69   /* rarely changed data like cpu maps */
  70   . = ALIGN(32);
  71   .data.read_mostly : AT(ADDR(.data.read_mostly) - LOAD_OFFSET) { *(.data.read_mostly) }
  72   _edata = .;                   /* End of data section */
  73
  74 #ifdef CONFIG_STACK_UNWIND
  75   . = ALIGN(4);
  76   .eh_frame : AT(ADDR(.eh_frame) - LOAD_OFFSET) {
  77         __start_unwind = .;
  78         *(.eh_frame)
  79         __end_unwind = .;
  80   }
  81 #endif
  82
  83   . = ALIGN(THREAD_SIZE);       /* init_task */
  84   .data.init_task : AT(ADDR(.data.init_task) - LOAD_OFFSET) {
  85         *(.data.init_task)
  86   }
  87
  88   /* might get freed after init */
  89   . = ALIGN(4096);
  90   __smp_alt_begin = .;
  91   __smp_alt_instructions = .;
  92   .smp_altinstructions : AT(ADDR(.smp_altinstructions) - LOAD_OFFSET) {
  93         *(.smp_altinstructions)
  94   }
  95   __smp_alt_instructions_end = .;
  96   . = ALIGN(4);
  97   __smp_locks = .;
  98   .smp_locks : AT(ADDR(.smp_locks) - LOAD_OFFSET) {
  99         *(.smp_locks)
 100   }
 101   __smp_locks_end = .;
 102   .smp_altinstr_replacement : AT(ADDR(.smp_altinstr_replacement) - LOAD_OFFSET) {
 103         *(.smp_altinstr_replacement)
 104   }
 105   . = ALIGN(4096);
 106   __smp_alt_end = .;
 107
 108   /* will be freed after init */
 109   . = ALIGN(4096);              /* Init code and data */
 110   __init_begin = .;
 111   .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {
 112         _sinittext = .;
 113         *(.init.text)
 114         _einittext = .;
 115   }
 116   .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { *(.init.data) }
 117   . = ALIGN(16);
 118   __setup_start = .;
 119   .init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) { *(.init.setup) }
 120   __setup_end = .;
 121   __initcall_start = .;
 122   .initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET) {
 123         *(.initcall1.init)
 124         *(.initcall2.init)
 125         *(.initcall3.init)
 126         *(.initcall4.init)
 127         *(.initcall5.init)
 128         *(.initcall6.init)
 129         *(.initcall7.init)
 130   }
 131   __initcall_end = .;
 132   __con_initcall_start = .;
 133   .con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) {
 134         *(.con_initcall.init)
 135   }
 136   __con_initcall_end = .;
 137   SECURITY_INIT
 138   . = ALIGN(4);
 139   __alt_instructions = .;
 140   .altinstructions : AT(ADDR(.altinstructions) - LOAD_OFFSET) {
 141         *(.altinstructions)
 142   }
 143   __alt_instructions_end = .;
 144   .altinstr_replacement : AT(ADDR(.altinstr_replacement) - LOAD_OFFSET) {
 145         *(.altinstr_replacement)
 146   }
 147   /* .exit.text is discard at runtime, not link time, to deal with references
 148      from .altinstructions and .eh_frame */
 149   .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) { *(.exit.text) }
 150   .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) { *(.exit.data) }
 151   . = ALIGN(4096);
 152   __initramfs_start = .;
 153   .init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET) { *(.init.ramfs) }
 154   __initramfs_end = .;
 155   . = ALIGN(L1_CACHE_BYTES);
 156   __per_cpu_start = .;
 157   .data.percpu  : AT(ADDR(.data.percpu) - LOAD_OFFSET) { *(.data.percpu) }
 158   __per_cpu_end = .;
 159   . = ALIGN(4096);
 160   __init_end = .;
 161   /* freed after init ends here */
 162
 163   __bss_start = .;              /* BSS */
 164   .bss.page_aligned : AT(ADDR(.bss.page_aligned) - LOAD_OFFSET) {
 165         *(.bss.page_aligned)
 166   }
 167   .bss : AT(ADDR(.bss) - LOAD_OFFSET) {
 168         *(.bss)
 169   }
 170   . = ALIGN(4);
 171   __bss_stop = .;
 172
 173   _end = . ;
 174
 175   /* This is where the kernel creates the early boot page tables */
 176   . = ALIGN(4096);
 177   pg0 = .;
 178
 179   /* Sections to be discarded */
 180   /DISCARD/ : {
 181         *(.exitcall.exit)
 182         }
 183
 184   STABS_DEBUG
 185
 186   DWARF_DEBUG
 187 }