Merge branch 'master' into percpu
[sfrench/cifs-2.6.git] / arch / blackfin / mach-common / entry.S
1 /*
2  * Contains the system-call and fault low-level handling routines.
3  * This also contains the timer-interrupt handler, as well as all
4  * interrupts and faults that can result in a task-switch.
5  *
6  * Copyright 2005-2009 Analog Devices Inc.
7  *
8  * Licensed under the GPL-2 or later.
9  */
10
11 /* NOTE: This code handles signal-recognition, which happens every time
12  * after a timer-interrupt and after each system call.
13  */
14
15 #include <linux/init.h>
16 #include <linux/linkage.h>
17 #include <linux/unistd.h>
18 #include <asm/blackfin.h>
19 #include <asm/errno.h>
20 #include <asm/fixed_code.h>
21 #include <asm/thread_info.h>  /* TIF_NEED_RESCHED */
22 #include <asm/asm-offsets.h>
23 #include <asm/trace.h>
24 #include <asm/traps.h>
25
26 #include <asm/context.S>
27
28 #if defined(CONFIG_BFIN_SCRATCH_REG_RETN)
29 # define EX_SCRATCH_REG RETN
30 #elif defined(CONFIG_BFIN_SCRATCH_REG_RETE)
31 # define EX_SCRATCH_REG RETE
32 #else
33 # define EX_SCRATCH_REG CYCLES
34 #endif
35
36 #ifdef CONFIG_EXCPT_IRQ_SYSC_L1
37 .section .l1.text
38 #else
39 .text
40 #endif
41
42 /* Slightly simplified and streamlined entry point for CPLB misses.
43  * This one does not lower the level to IRQ5, and thus can be used to
44  * patch up CPLB misses on the kernel stack.
45  */
46 #if ANOMALY_05000261
47 #define _ex_dviol _ex_workaround_261
48 #define _ex_dmiss _ex_workaround_261
49 #define _ex_dmult _ex_workaround_261
50
51 ENTRY(_ex_workaround_261)
52         /*
53          * Work around an anomaly: if we see a new DCPLB fault, return
54          * without doing anything.  Then, if we get the same fault again,
55          * handle it.
56          */
57         P4 = R7;        /* Store EXCAUSE */
58
59         GET_PDA(p5, r7);
60         r7 = [p5 + PDA_LFRETX];
61         r6 = retx;
62         [p5 + PDA_LFRETX] = r6;
63         cc = r6 == r7;
64         if !cc jump _bfin_return_from_exception;
65         /* fall through */
66         R7 = P4;
67         R6 = VEC_CPLB_M;        /* Data CPLB Miss */
68         cc = R6 == R7;
69         if cc jump _ex_dcplb_miss (BP);
70 #ifdef CONFIG_MPU
71         R6 = VEC_CPLB_VL;       /* Data CPLB Violation */
72         cc = R6 == R7;
73         if cc jump _ex_dcplb_viol (BP);
74 #endif
75         /* Handle Data CPLB Protection Violation
76          * and Data CPLB Multiple Hits - Linux Trap Zero
77          */
78         jump _ex_trap_c;
79 ENDPROC(_ex_workaround_261)
80
81 #else
82 #ifdef CONFIG_MPU
83 #define _ex_dviol _ex_dcplb_viol
84 #else
85 #define _ex_dviol _ex_trap_c
86 #endif
87 #define _ex_dmiss _ex_dcplb_miss
88 #define _ex_dmult _ex_trap_c
89 #endif
90
91
92 ENTRY(_ex_dcplb_viol)
93 ENTRY(_ex_dcplb_miss)
94 ENTRY(_ex_icplb_miss)
95         (R7:6,P5:4) = [sp++];
96         /* We leave the previously pushed ASTAT on the stack.  */
97         SAVE_CONTEXT_CPLB
98
99         /* We must load R1 here, _before_ DEBUG_HWTRACE_SAVE, since that
100          * will change the stack pointer.  */
101         R0 = SEQSTAT;
102         R1 = SP;
103
104         DEBUG_HWTRACE_SAVE(p5, r7)
105
106         sp += -12;
107         call _cplb_hdr;
108         sp += 12;
109         CC = R0 == 0;
110         IF !CC JUMP _handle_bad_cplb;
111
112 #ifdef CONFIG_DEBUG_DOUBLEFAULT
113         /* While we were processing this, did we double fault? */
114         r7 = SEQSTAT;           /* reason code is in bit 5:0 */
115         r6.l = lo(SEQSTAT_EXCAUSE);
116         r6.h = hi(SEQSTAT_EXCAUSE);
117         r7 = r7 & r6;
118         r6 = 0x25;
119         CC = R7 == R6;
120         if CC JUMP _double_fault;
121 #endif
122
123         DEBUG_HWTRACE_RESTORE(p5, r7)
124         RESTORE_CONTEXT_CPLB
125         ASTAT = [SP++];
126         SP = EX_SCRATCH_REG;
127         rtx;
128 ENDPROC(_ex_icplb_miss)
129
130 ENTRY(_ex_syscall)
131         raise 15;               /* invoked by TRAP #0, for sys call */
132         jump.s _bfin_return_from_exception;
133 ENDPROC(_ex_syscall)
134
135 ENTRY(_ex_single_step)
136         /* If we just returned from an interrupt, the single step event is
137            for the RTI instruction.  */
138         r7 = retx;
139         r6 = reti;
140         cc = r7 == r6;
141         if cc jump _bfin_return_from_exception;
142
143 #ifdef CONFIG_KGDB
144         /* Don't do single step in hardware exception handler */
145         p5.l = lo(IPEND);
146         p5.h = hi(IPEND);
147         r6 = [p5];
148         cc = bittst(r6, 4);
149         if cc jump _bfin_return_from_exception;
150         cc = bittst(r6, 5);
151         if cc jump _bfin_return_from_exception;
152
153         /* skip single step if current interrupt priority is higher than
154          * that of the first instruction, from which gdb starts single step */
155         r6 >>= 6;
156         r7 = 10;
157 .Lfind_priority_start:
158         cc = bittst(r6, 0);
159         if cc jump .Lfind_priority_done;
160         r6 >>= 1;
161         r7 += -1;
162         cc = r7 == 0;
163         if cc jump .Lfind_priority_done;
164         jump.s .Lfind_priority_start;
165 .Lfind_priority_done:
166         p4.l = _kgdb_single_step;
167         p4.h = _kgdb_single_step;
168         r6 = [p4];
169         cc = r6 == 0;
170         if cc jump .Ldo_single_step;
171         r6 += -1;
172         cc = r6 < r7;
173         if cc jump 1f;
174 .Ldo_single_step:
175 #else
176         /* If we were in user mode, do the single step normally.  */
177         p5.l = lo(IPEND);
178         p5.h = hi(IPEND);
179         r6 = [p5];
180         r7 = 0xffe0 (z);
181         r7 = r7 & r6;
182         cc = r7 == 0;
183         if !cc jump 1f;
184 #endif
185 #ifdef CONFIG_EXACT_HWERR
186         /* Read the ILAT, and to check to see if the process we are
187          * single stepping caused a previous hardware error
188          * If so, do not single step, (which lowers to IRQ5, and makes
189          * us miss the error).
190          */
191         p5.l = lo(ILAT);
192         p5.h = hi(ILAT);
193         r7 = [p5];
194         cc = bittst(r7, EVT_IVHW_P);
195         if cc jump 1f;
196 #endif
197         /* Single stepping only a single instruction, so clear the trace
198          * bit here.  */
199         r7 = syscfg;
200         bitclr (r7, SYSCFG_SSSTEP_P);
201         syscfg = R7;
202         jump _ex_trap_c;
203
204 1:
205         /*
206          * We were in an interrupt handler.  By convention, all of them save
207          * SYSCFG with their first instruction, so by checking whether our
208          * RETX points at the entry point, we can determine whether to allow
209          * a single step, or whether to clear SYSCFG.
210          *
211          * First, find out the interrupt level and the event vector for it.
212          */
213         p5.l = lo(EVT0);
214         p5.h = hi(EVT0);
215         p5 += -4;
216 2:
217         r7 = rot r7 by -1;
218         p5 += 4;
219         if !cc jump 2b;
220
221         /* What we actually do is test for the _second_ instruction in the
222          * IRQ handler.  That way, if there are insns following the restore
223          * of SYSCFG after leaving the handler, we will not turn off SYSCFG
224          * for them.  */
225
226         r7 = [p5];
227         r7 += 2;
228         r6 = RETX;
229         cc = R7 == R6;
230         if !cc jump _bfin_return_from_exception;
231
232         r7 = syscfg;
233         bitclr (r7, SYSCFG_SSSTEP_P);   /* Turn off single step */
234         syscfg = R7;
235
236         /* Fall through to _bfin_return_from_exception.  */
237 ENDPROC(_ex_single_step)
238
239 ENTRY(_bfin_return_from_exception)
240 #if ANOMALY_05000257
241         R7=LC0;
242         LC0=R7;
243         R7=LC1;
244         LC1=R7;
245 #endif
246
247 #ifdef CONFIG_DEBUG_DOUBLEFAULT
248         /* While we were processing the current exception,
249          * did we cause another, and double fault?
250          */
251         r7 = SEQSTAT;           /* reason code is in bit 5:0 */
252         r6.l = lo(SEQSTAT_EXCAUSE);
253         r6.h = hi(SEQSTAT_EXCAUSE);
254         r7 = r7 & r6;
255         r6 = VEC_UNCOV;
256         CC = R7 == R6;
257         if CC JUMP _double_fault;
258 #endif
259
260         (R7:6,P5:4) = [sp++];
261         ASTAT = [sp++];
262         sp = EX_SCRATCH_REG;
263         rtx;
264 ENDPROC(_bfin_return_from_exception)
265
266 ENTRY(_handle_bad_cplb)
267         DEBUG_HWTRACE_RESTORE(p5, r7)
268         /* To get here, we just tried and failed to change a CPLB
269          * so, handle things in trap_c (C code), by lowering to
270          * IRQ5, just like we normally do. Since this is not a
271          * "normal" return path, we have a do alot of stuff to
272          * the stack to get ready so, we can fall through - we
273          * need to make a CPLB exception look like a normal exception
274          */
275         RESTORE_CONTEXT_CPLB
276         /* ASTAT is still on the stack, where it is needed.  */
277         [--sp] = (R7:6,P5:4);
278
279 ENTRY(_ex_replaceable)
280         nop;
281
282 ENTRY(_ex_trap_c)
283         /* The only thing that has been saved in this context is
284          * (R7:6,P5:4), ASTAT & SP - don't use anything else
285          */
286
287         GET_PDA(p5, r6);
288
289         /* Make sure we are not in a double fault */
290         p4.l = lo(IPEND);
291         p4.h = hi(IPEND);
292         r7 = [p4];
293         CC = BITTST (r7, 5);
294         if CC jump _double_fault;
295         [p5 + PDA_EXIPEND] = r7;
296
297         /* Call C code (trap_c) to handle the exception, which most
298          * likely involves sending a signal to the current process.
299          * To avoid double faults, lower our priority to IRQ5 first.
300          */
301         r7.h = _exception_to_level5;
302         r7.l = _exception_to_level5;
303         p4.l = lo(EVT5);
304         p4.h = hi(EVT5);
305         [p4] = r7;
306         csync;
307
308         /*
309          * Save these registers, as they are only valid in exception context
310          *  (where we are now - as soon as we defer to IRQ5, they can change)
311          * DCPLB_STATUS and ICPLB_STATUS are also only valid in EVT3,
312          * but they are not very interesting, so don't save them
313          */
314
315         p4.l = lo(DCPLB_FAULT_ADDR);
316         p4.h = hi(DCPLB_FAULT_ADDR);
317         r7 = [p4];
318         [p5 + PDA_DCPLB] = r7;
319
320         p4.l = lo(ICPLB_FAULT_ADDR);
321         p4.h = hi(ICPLB_FAULT_ADDR);
322         r6 = [p4];
323         [p5 + PDA_ICPLB] = r6;
324
325         r6 = retx;
326         [p5 + PDA_RETX] = r6;
327
328         r6 = SEQSTAT;
329         [p5 + PDA_SEQSTAT] = r6;
330
331         /* Save the state of single stepping */
332         r6 = SYSCFG;
333         [p5 + PDA_SYSCFG] = r6;
334         /* Clear it while we handle the exception in IRQ5 mode */
335         BITCLR(r6, SYSCFG_SSSTEP_P);
336         SYSCFG = r6;
337
338         /* Save the current IMASK, since we change in order to jump to level 5 */
339         cli r6;
340         [p5 + PDA_EXIMASK] = r6;
341
342         p4.l = lo(SAFE_USER_INSTRUCTION);
343         p4.h = hi(SAFE_USER_INSTRUCTION);
344         retx = p4;
345
346         /* Disable all interrupts, but make sure level 5 is enabled so
347          * we can switch to that level.
348          */
349         r6 = 0x3f;
350         sti r6;
351
352         /* In case interrupts are disabled IPEND[4] (global interrupt disable bit)
353          * clear it (re-enabling interrupts again) by the special sequence of pushing
354          * RETI onto the stack.  This way we can lower ourselves to IVG5 even if the
355          * exception was taken after the interrupt handler was called but before it
356          * got a chance to enable global interrupts itself.
357          */
358         [--sp] = reti;
359         sp += 4;
360
361         raise 5;
362         jump.s _bfin_return_from_exception;
363 ENDPROC(_ex_trap_c)
364
365 /* We just realized we got an exception, while we were processing a different
366  * exception. This is a unrecoverable event, so crash.
367  * Note: this cannot be ENTRY() as we jump here with "if cc jump" ...
368  */
369 ENTRY(_double_fault)
370         /* Turn caches & protection off, to ensure we don't get any more
371          * double exceptions
372          */
373
374         P4.L = LO(IMEM_CONTROL);
375         P4.H = HI(IMEM_CONTROL);
376
377         R5 = [P4];              /* Control Register*/
378         BITCLR(R5,ENICPLB_P);
379         CSYNC;          /* Disabling of CPLBs should be proceeded by a CSYNC */
380         [P4] = R5;
381         SSYNC;
382
383         P4.L = LO(DMEM_CONTROL);
384         P4.H = HI(DMEM_CONTROL);
385         R5 = [P4];
386         BITCLR(R5,ENDCPLB_P);
387         CSYNC;          /* Disabling of CPLBs should be proceeded by a CSYNC */
388         [P4] = R5;
389         SSYNC;
390
391         /* Fix up the stack */
392         (R7:6,P5:4) = [sp++];
393         ASTAT = [sp++];
394         SP = EX_SCRATCH_REG;
395
396         /* We should be out of the exception stack, and back down into
397          * kernel or user space stack
398          */
399         SAVE_ALL_SYS
400
401         /* The dumping functions expect the return address in the RETI
402          * slot.  */
403         r6 = retx;
404         [sp + PT_PC] = r6;
405
406         r0 = sp;        /* stack frame pt_regs pointer argument ==> r0 */
407         SP += -12;
408         call _double_fault_c;
409         SP += 12;
410 .L_double_fault_panic:
411         JUMP .L_double_fault_panic
412
413 ENDPROC(_double_fault)
414
415 ENTRY(_exception_to_level5)
416         SAVE_ALL_SYS
417
418         GET_PDA(p5, r7);        /* Fetch current PDA */
419         r6 = [p5 + PDA_RETX];
420         [sp + PT_PC] = r6;
421
422         r6 = [p5 + PDA_SYSCFG];
423         [sp + PT_SYSCFG] = r6;
424
425         r6 = [p5 + PDA_SEQSTAT]; /* Read back seqstat */
426         [sp + PT_SEQSTAT] = r6;
427
428         /* Restore the hardware error vector.  */
429         r7.h = _evt_ivhw;
430         r7.l = _evt_ivhw;
431         p4.l = lo(EVT5);
432         p4.h = hi(EVT5);
433         [p4] = r7;
434         csync;
435
436 #ifdef CONFIG_DEBUG_DOUBLEFAULT
437         /* Now that we have the hardware error vector programmed properly
438          * we can re-enable interrupts (IPEND[4]), so if the _trap_c causes
439          * another hardware error, we can catch it (self-nesting).
440          */
441         [--sp] = reti;
442         sp += 4;
443 #endif
444
445         r7 = [p5 + PDA_EXIPEND] /* Read the IPEND from the Exception state */
446         [sp + PT_IPEND] = r7;   /* Store IPEND onto the stack */
447
448         r0 = sp;        /* stack frame pt_regs pointer argument ==> r0 */
449         SP += -12;
450         call _trap_c;
451         SP += 12;
452
453         /* If interrupts were off during the exception (IPEND[4] = 1), turn them off
454          * before we return.
455          */
456         CC = BITTST(r7, EVT_IRPTEN_P)
457         if !CC jump 1f;
458         /* this will load a random value into the reti register - but that is OK,
459          * since we do restore it to the correct value in the 'RESTORE_ALL_SYS' macro
460          */
461         sp += -4;
462         reti = [sp++];
463 1:
464         /* restore the interrupt mask (IMASK) */
465         r6 = [p5 + PDA_EXIMASK];
466         sti r6;
467
468         call _ret_from_exception;
469         RESTORE_ALL_SYS
470         rti;
471 ENDPROC(_exception_to_level5)
472
473 ENTRY(_trap) /* Exception: 4th entry into system event table(supervisor mode)*/
474         /* Since the kernel stack can be anywhere, it's not guaranteed to be
475          * covered by a CPLB.  Switch to an exception stack; use RETN as a
476          * scratch register (for want of a better option).
477          */
478         EX_SCRATCH_REG = sp;
479         GET_PDA_SAFE(sp);
480         sp = [sp + PDA_EXSTACK];
481         /* Try to deal with syscalls quickly.  */
482         [--sp] = ASTAT;
483         [--sp] = (R7:6,P5:4);
484
485 #ifdef CONFIG_EXACT_HWERR
486         /* Make sure all pending read/writes complete. This will ensure any
487          * accesses which could cause hardware errors completes, and signal
488          * the the hardware before we do something silly, like crash the
489          * kernel. We don't need to work around anomaly 05000312, since
490          * we are already atomic
491          */
492         ssync;
493 #endif
494
495         ANOMALY_283_315_WORKAROUND(p5, r7)
496
497 #ifdef CONFIG_DEBUG_DOUBLEFAULT
498         /*
499          * Save these registers, as they are only valid in exception context
500          * (where we are now - as soon as we defer to IRQ5, they can change)
501          * DCPLB_STATUS and ICPLB_STATUS are also only valid in EVT3,
502          * but they are not very interesting, so don't save them
503          */
504
505         GET_PDA(p5, r7);
506         p4.l = lo(DCPLB_FAULT_ADDR);
507         p4.h = hi(DCPLB_FAULT_ADDR);
508         r7 = [p4];
509         [p5 + PDA_DF_DCPLB] = r7;
510
511         p4.l = lo(ICPLB_FAULT_ADDR);
512         p4.h = hi(ICPLB_FAULT_ADDR);
513         r7 = [p4];
514         [p5 + PDA_DF_ICPLB] = r7;
515
516         r7 = retx;
517         [p5 + PDA_DF_RETX] = r7;
518
519         r7 = SEQSTAT;           /* reason code is in bit 5:0 */
520         [p5 + PDA_DF_SEQSTAT] = r7;
521 #else
522         r7 = SEQSTAT;           /* reason code is in bit 5:0 */
523 #endif
524         r6.l = lo(SEQSTAT_EXCAUSE);
525         r6.h = hi(SEQSTAT_EXCAUSE);
526         r7 = r7 & r6;
527         p5.h = _ex_table;
528         p5.l = _ex_table;
529         p4 = r7;
530         p5 = p5 + (p4 << 2);
531         p4 = [p5];
532         jump (p4);
533
534 .Lbadsys:
535         r7 = -ENOSYS;           /* signextending enough */
536         [sp + PT_R0] = r7;      /* return value from system call */
537         jump .Lsyscall_really_exit;
538 ENDPROC(_trap)
539
540 ENTRY(_kernel_execve)
541         link SIZEOF_PTREGS;
542         p0 = sp;
543         r3 = SIZEOF_PTREGS / 4;
544         r4 = 0(x);
545 .Lclear_regs:
546         [p0++] = r4;
547         r3 += -1;
548         cc = r3 == 0;
549         if !cc jump .Lclear_regs (bp);
550
551         p0 = sp;
552         sp += -16;
553         [sp + 12] = p0;
554         call _do_execve;
555         SP += 16;
556         cc = r0 == 0;
557         if ! cc jump .Lexecve_failed;
558         /* Success.  Copy our temporary pt_regs to the top of the kernel
559          * stack and do a normal exception return.
560          */
561         r1 = sp;
562         r0 = (-KERNEL_STACK_SIZE) (x);
563         r1 = r1 & r0;
564         p2 = r1;
565         p3 = [p2];
566         r0 = KERNEL_STACK_SIZE - 4 (z);
567         p1 = r0;
568         p1 = p1 + p2;
569
570         p0 = fp;
571         r4 = [p0--];
572         r3 = SIZEOF_PTREGS / 4;
573 .Lcopy_regs:
574         r4 = [p0--];
575         [p1--] = r4;
576         r3 += -1;
577         cc = r3 == 0;
578         if ! cc jump .Lcopy_regs (bp);
579
580         r0 = (KERNEL_STACK_SIZE - SIZEOF_PTREGS) (z);
581         p1 = r0;
582         p1 = p1 + p2;
583         sp = p1;
584         r0 = syscfg;
585         [SP + PT_SYSCFG] = r0;
586         [p3 + (TASK_THREAD + THREAD_KSP)] = sp;
587
588         RESTORE_CONTEXT;
589         rti;
590 .Lexecve_failed:
591         unlink;
592         rts;
593 ENDPROC(_kernel_execve)
594
595 ENTRY(_system_call)
596         /* Store IPEND */
597         p2.l = lo(IPEND);
598         p2.h = hi(IPEND);
599         csync;
600         r0 = [p2];
601         [sp + PT_IPEND] = r0;
602
603         /* Store RETS for now */
604         r0 = rets;
605         [sp + PT_RESERVED] = r0;
606         /* Set the stack for the current process */
607         r7 = sp;
608         r6.l = lo(ALIGN_PAGE_MASK);
609         r6.h = hi(ALIGN_PAGE_MASK);
610         r7 = r7 & r6;           /* thread_info */
611         p2 = r7;
612         p2 = [p2];
613
614         [p2+(TASK_THREAD+THREAD_KSP)] = sp;
615 #ifdef CONFIG_IPIPE
616         r0 = sp;
617         SP += -12;
618         call ___ipipe_syscall_root;
619         SP += 12;
620         cc = r0 == 1;
621         if cc jump .Lsyscall_really_exit;
622         cc = r0 == -1;
623         if cc jump .Lresume_userspace;
624         r3 = [sp + PT_R3];
625         r4 = [sp + PT_R4];
626         p0 = [sp + PT_ORIG_P0];
627 #endif /* CONFIG_IPIPE */
628
629         /* Check the System Call */
630         r7 = __NR_syscall;
631         /* System call number is passed in P0 */
632         r6 = p0;
633         cc = r6 < r7;
634         if ! cc jump .Lbadsys;
635
636         /* are we tracing syscalls?*/
637         r7 = sp;
638         r6.l = lo(ALIGN_PAGE_MASK);
639         r6.h = hi(ALIGN_PAGE_MASK);
640         r7 = r7 & r6;
641         p2 = r7;
642         r7 = [p2+TI_FLAGS];
643         CC = BITTST(r7,TIF_SYSCALL_TRACE);
644         if CC JUMP _sys_trace;
645
646         /* Execute the appropriate system call */
647
648         p4 = p0;
649         p5.l = _sys_call_table;
650         p5.h = _sys_call_table;
651         p5 = p5 + (p4 << 2);
652         r0 = [sp + PT_R0];
653         r1 = [sp + PT_R1];
654         r2 = [sp + PT_R2];
655         p5 = [p5];
656
657         [--sp] = r5;
658         [--sp] = r4;
659         [--sp] = r3;
660         SP += -12;
661         call (p5);
662         SP += 24;
663         [sp + PT_R0] = r0;
664
665 .Lresume_userspace:
666         r7 = sp;
667         r4.l = lo(ALIGN_PAGE_MASK);
668         r4.h = hi(ALIGN_PAGE_MASK);
669         r7 = r7 & r4;           /* thread_info->flags */
670         p5 = r7;
671 .Lresume_userspace_1:
672         /* Disable interrupts.  */
673         [--sp] = reti;
674         reti = [sp++];
675
676         r7 = [p5 + TI_FLAGS];
677         r4.l = lo(_TIF_WORK_MASK);
678         r4.h = hi(_TIF_WORK_MASK);
679         r7 =  r7 & r4;
680
681 .Lsyscall_resched:
682 #ifdef CONFIG_IPIPE
683         cc = BITTST(r7, TIF_IRQ_SYNC);
684         if !cc jump .Lsyscall_no_irqsync;
685         /*
686          * Clear IPEND[4] manually to undo what resume_userspace_1 just did;
687          * we need this so that high priority domain interrupts may still
688          * preempt the current domain while the pipeline log is being played
689          * back.
690          */
691         [--sp] = reti;
692         SP += 4; /* don't merge with next insn to keep the pattern obvious */
693         SP += -12;
694         call ___ipipe_sync_root;
695         SP += 12;
696         jump .Lresume_userspace_1;
697 .Lsyscall_no_irqsync:
698 #endif
699         cc = BITTST(r7, TIF_NEED_RESCHED);
700         if !cc jump .Lsyscall_sigpending;
701
702         /* Reenable interrupts.  */
703         [--sp] = reti;
704         sp += 4;
705
706         SP += -12;
707         call _schedule;
708         SP += 12;
709
710         jump .Lresume_userspace_1;
711
712 .Lsyscall_sigpending:
713         cc = BITTST(r7, TIF_RESTORE_SIGMASK);
714         if cc jump .Lsyscall_do_signals;
715         cc = BITTST(r7, TIF_SIGPENDING);
716         if cc jump .Lsyscall_do_signals;
717         cc = BITTST(r7, TIF_NOTIFY_RESUME);
718         if !cc jump .Lsyscall_really_exit;
719 .Lsyscall_do_signals:
720         /* Reenable interrupts.  */
721         [--sp] = reti;
722         sp += 4;
723
724         r0 = sp;
725         SP += -12;
726         call _do_notify_resume;
727         SP += 12;
728
729 .Lsyscall_really_exit:
730         r5 = [sp + PT_RESERVED];
731         rets = r5;
732         rts;
733 ENDPROC(_system_call)
734
735 /* Do not mark as ENTRY() to avoid error in assembler ...
736  * this symbol need not be global anyways, so ...
737  */
738 _sys_trace:
739         call _syscall_trace;
740
741         /* Execute the appropriate system call */
742
743         p4 = [SP + PT_P0];
744         p5.l = _sys_call_table;
745         p5.h = _sys_call_table;
746         p5 = p5 + (p4 << 2);
747         r0 = [sp + PT_R0];
748         r1 = [sp + PT_R1];
749         r2 = [sp + PT_R2];
750         r3 = [sp + PT_R3];
751         r4 = [sp + PT_R4];
752         r5 = [sp + PT_R5];
753         p5 = [p5];
754
755         [--sp] = r5;
756         [--sp] = r4;
757         [--sp] = r3;
758         SP += -12;
759         call (p5);
760         SP += 24;
761         [sp + PT_R0] = r0;
762
763         call _syscall_trace;
764         jump .Lresume_userspace;
765 ENDPROC(_sys_trace)
766
767 ENTRY(_resume)
768         /*
769          * Beware - when entering resume, prev (the current task) is
770          * in r0, next (the new task) is in r1.
771          */
772         p0 = r0;
773         p1 = r1;
774         [--sp] = rets;
775         [--sp] = fp;
776         [--sp] = (r7:4, p5:3);
777
778         /* save usp */
779         p2 = usp;
780         [p0+(TASK_THREAD+THREAD_USP)] = p2;
781
782         /* save current kernel stack pointer */
783         [p0+(TASK_THREAD+THREAD_KSP)] = sp;
784
785         /* save program counter */
786         r1.l = _new_old_task;
787         r1.h = _new_old_task;
788         [p0+(TASK_THREAD+THREAD_PC)] = r1;
789
790         /* restore the kernel stack pointer */
791         sp = [p1+(TASK_THREAD+THREAD_KSP)];
792
793         /* restore user stack pointer */
794         p0 = [p1+(TASK_THREAD+THREAD_USP)];
795         usp = p0;
796
797         /* restore pc */
798         p0 = [p1+(TASK_THREAD+THREAD_PC)];
799         jump (p0);
800
801         /*
802          * Following code actually lands up in a new (old) task.
803          */
804
805 _new_old_task:
806         (r7:4, p5:3) = [sp++];
807         fp = [sp++];
808         rets = [sp++];
809
810         /*
811          * When we come out of resume, r0 carries "old" task, becuase we are
812          * in "new" task.
813          */
814         rts;
815 ENDPROC(_resume)
816
817 ENTRY(_ret_from_exception)
818 #ifdef CONFIG_IPIPE
819         p2.l = _ipipe_percpu_domain;
820         p2.h = _ipipe_percpu_domain;
821         r0.l = _ipipe_root;
822         r0.h = _ipipe_root;
823         r2 = [p2];
824         cc = r0 == r2;
825         if !cc jump 4f;  /* not on behalf of the root domain, get out */
826 #endif /* CONFIG_IPIPE */
827         p2.l = lo(IPEND);
828         p2.h = hi(IPEND);
829
830         csync;
831         r0 = [p2];
832         [sp + PT_IPEND] = r0;
833
834 1:
835         r2 = LO(~0x37) (Z);
836         r0 = r2 & r0;
837         cc = r0 == 0;
838         if !cc jump 4f; /* if not return to user mode, get out */
839
840         /* Make sure any pending system call or deferred exception
841          * return in ILAT for this process to get executed, otherwise
842          * in case context switch happens, system call of
843          * first process (i.e in ILAT) will be carried
844          * forward to the switched process
845          */
846
847         p2.l = lo(ILAT);
848         p2.h = hi(ILAT);
849         r0 = [p2];
850         r1 = (EVT_IVG14 | EVT_IVG15) (z);
851         r0 = r0 & r1;
852         cc = r0 == 0;
853         if !cc jump 5f;
854
855         /* Set the stack for the current process */
856         r7 = sp;
857         r4.l = lo(ALIGN_PAGE_MASK);
858         r4.h = hi(ALIGN_PAGE_MASK);
859         r7 = r7 & r4;           /* thread_info->flags */
860         p5 = r7;
861         r7 = [p5 + TI_FLAGS];
862         r4.l = lo(_TIF_WORK_MASK);
863         r4.h = hi(_TIF_WORK_MASK);
864         r7 =  r7 & r4;
865         cc = r7 == 0;
866         if cc jump 4f;
867
868         p0.l = lo(EVT15);
869         p0.h = hi(EVT15);
870         p1.l = _schedule_and_signal;
871         p1.h = _schedule_and_signal;
872         [p0] = p1;
873         csync;
874         raise 15;               /* raise evt15 to do signal or reschedule */
875 4:
876         r0 = syscfg;
877         bitclr(r0, SYSCFG_SSSTEP_P);            /* Turn off single step */
878         syscfg = r0;
879 5:
880         rts;
881 ENDPROC(_ret_from_exception)
882
883 #ifdef CONFIG_IPIPE
884
885 _resume_kernel_from_int:
886         r0.l = ___ipipe_sync_root;
887         r0.h = ___ipipe_sync_root;
888         [--sp] = rets;
889         [--sp] = ( r7:4, p5:3 );
890         SP += -12;
891         call ___ipipe_call_irqtail
892         SP += 12;
893         ( r7:4, p5:3 ) = [sp++];
894         rets = [sp++];
895         rts
896 #else
897 #define _resume_kernel_from_int  2f
898 #endif
899
900 ENTRY(_return_from_int)
901         /* If someone else already raised IRQ 15, do nothing.  */
902         csync;
903         p2.l = lo(ILAT);
904         p2.h = hi(ILAT);
905         r0 = [p2];
906         cc = bittst (r0, EVT_IVG15_P);
907         if cc jump 2f;
908
909         /* if not return to user mode, get out */
910         p2.l = lo(IPEND);
911         p2.h = hi(IPEND);
912         r0 = [p2];
913         r1 = 0x17(Z);
914         r2 = ~r1;
915         r2.h = 0;
916         r0 = r2 & r0;
917         r1 = 1;
918         r1 = r0 - r1;
919         r2 = r0 & r1;
920         cc = r2 == 0;
921         if !cc jump _resume_kernel_from_int;
922
923         /* Lower the interrupt level to 15.  */
924         p0.l = lo(EVT15);
925         p0.h = hi(EVT15);
926         p1.l = _schedule_and_signal_from_int;
927         p1.h = _schedule_and_signal_from_int;
928         [p0] = p1;
929         csync;
930 #if ANOMALY_05000281 || ANOMALY_05000461
931         r0.l = lo(SAFE_USER_INSTRUCTION);
932         r0.h = hi(SAFE_USER_INSTRUCTION);
933         reti = r0;
934 #endif
935         r0 = 0x801f (z);
936         STI r0;
937         raise 15;       /* raise evt15 to do signal or reschedule */
938         rti;
939 2:
940         rts;
941 ENDPROC(_return_from_int)
942
943 ENTRY(_lower_to_irq14)
944 #if ANOMALY_05000281 || ANOMALY_05000461
945         r0.l = lo(SAFE_USER_INSTRUCTION);
946         r0.h = hi(SAFE_USER_INSTRUCTION);
947         reti = r0;
948 #endif
949
950 #ifdef CONFIG_DEBUG_HWERR
951         /* enable irq14 & hwerr interrupt, until we transition to _evt_evt14 */
952         r0 = (EVT_IVG14 | EVT_IVHW | EVT_IRPTEN | EVT_EVX | EVT_NMI | EVT_RST | EVT_EMU);
953 #else
954         /* Only enable irq14 interrupt, until we transition to _evt_evt14 */
955         r0 = (EVT_IVG14 | EVT_IRPTEN | EVT_EVX | EVT_NMI | EVT_RST | EVT_EMU);
956 #endif
957         sti r0;
958         raise 14;
959         rti;
960 ENDPROC(_lower_to_irq14)
961
962 ENTRY(_evt_evt14)
963 #ifdef CONFIG_DEBUG_HWERR
964         r0 = (EVT_IVHW | EVT_IRPTEN | EVT_EVX | EVT_NMI | EVT_RST | EVT_EMU);
965         sti r0;
966 #else
967         cli r0;
968 #endif
969         [--sp] = RETI;
970         SP += 4;
971         rts;
972 ENDPROC(_evt_evt14)
973
974 ENTRY(_schedule_and_signal_from_int)
975         /* To end up here, vector 15 was changed - so we have to change it
976          * back.
977          */
978         p0.l = lo(EVT15);
979         p0.h = hi(EVT15);
980         p1.l = _evt_system_call;
981         p1.h = _evt_system_call;
982         [p0] = p1;
983         csync;
984
985         /* Set orig_p0 to -1 to indicate this isn't the end of a syscall.  */
986         r0 = -1 (x);
987         [sp + PT_ORIG_P0] = r0;
988
989         p1 = rets;
990         [sp + PT_RESERVED] = p1;
991
992 #ifdef CONFIG_SMP
993         GET_PDA(p0, r0);        /* Fetch current PDA (can't migrate to other CPU here) */
994         r0 = [p0 + PDA_IRQFLAGS];
995 #else
996         p0.l = _bfin_irq_flags;
997         p0.h = _bfin_irq_flags;
998         r0 = [p0];
999 #endif
1000         sti r0;
1001
1002         /* finish the userspace "atomic" functions for it */
1003         r1 = FIXED_CODE_END;
1004         r2 = [sp + PT_PC];
1005         cc = r1 <= r2;
1006         if cc jump .Lresume_userspace (bp);
1007
1008         r0 = sp;
1009         sp += -12;
1010         call _finish_atomic_sections;
1011         sp += 12;
1012         jump.s .Lresume_userspace;
1013 ENDPROC(_schedule_and_signal_from_int)
1014
1015 ENTRY(_schedule_and_signal)
1016         SAVE_CONTEXT_SYSCALL
1017         /* To end up here, vector 15 was changed - so we have to change it
1018          * back.
1019          */
1020         p0.l = lo(EVT15);
1021         p0.h = hi(EVT15);
1022         p1.l = _evt_system_call;
1023         p1.h = _evt_system_call;
1024         [p0] = p1;
1025         csync;
1026         p0.l = 1f;
1027         p0.h = 1f;
1028         [sp + PT_RESERVED] = P0;
1029         call .Lresume_userspace;
1030 1:
1031         RESTORE_CONTEXT
1032         rti;
1033 ENDPROC(_schedule_and_signal)
1034
1035 /* We handle this 100% in exception space - to reduce overhead
1036  * Only potiential problem is if the software buffer gets swapped out of the
1037  * CPLB table - then double fault. - so we don't let this happen in other places
1038  */
1039 #ifdef CONFIG_DEBUG_BFIN_HWTRACE_EXPAND
1040 ENTRY(_ex_trace_buff_full)
1041         [--sp] = P3;
1042         [--sp] = P2;
1043         [--sp] = LC0;
1044         [--sp] = LT0;
1045         [--sp] = LB0;
1046         P5.L = _trace_buff_offset;
1047         P5.H = _trace_buff_offset;
1048         P3 = [P5];              /* trace_buff_offset */
1049         P5.L = lo(TBUFSTAT);
1050         P5.H = hi(TBUFSTAT);
1051         R7 = [P5];
1052         R7 <<= 1;               /* double, since we need to read twice */
1053         LC0 = R7;
1054         R7 <<= 2;               /* need to shift over again,
1055                                  * to get the number of bytes */
1056         P5.L = lo(TBUF);
1057         P5.H = hi(TBUF);
1058         R6 = ((1 << CONFIG_DEBUG_BFIN_HWTRACE_EXPAND_LEN)*1024) - 1;
1059
1060         P2 = R7;
1061         P3 = P3 + P2;
1062         R7 = P3;
1063         R7 = R7 & R6;
1064         P3 = R7;
1065         P2.L = _trace_buff_offset;
1066         P2.H = _trace_buff_offset;
1067         [P2] = P3;
1068
1069         P2.L = _software_trace_buff;
1070         P2.H = _software_trace_buff;
1071
1072         LSETUP (.Lstart, .Lend) LC0;
1073 .Lstart:
1074         R7 = [P5];      /* read TBUF */
1075         P4 = P3 + P2;
1076         [P4] = R7;
1077         P3 += -4;
1078         R7 = P3;
1079         R7 = R7 & R6;
1080 .Lend:
1081         P3 = R7;
1082
1083         LB0 = [sp++];
1084         LT0 = [sp++];
1085         LC0 = [sp++];
1086         P2 = [sp++];
1087         P3 = [sp++];
1088         jump _bfin_return_from_exception;
1089 ENDPROC(_ex_trace_buff_full)
1090
1091 #if CONFIG_DEBUG_BFIN_HWTRACE_EXPAND_LEN == 4
1092 .data
1093 #else
1094 .section .l1.data.B
1095 #endif /* CONFIG_DEBUG_BFIN_HWTRACE_EXPAND_LEN */
1096 ENTRY(_trace_buff_offset)
1097         .long 0;
1098 ALIGN
1099 ENTRY(_software_trace_buff)
1100         .rept ((1 << CONFIG_DEBUG_BFIN_HWTRACE_EXPAND_LEN)*256);
1101         .long 0
1102         .endr
1103 #endif /* CONFIG_DEBUG_BFIN_HWTRACE_EXPAND */
1104
1105 #if CONFIG_EARLY_PRINTK
1106 __INIT
1107 ENTRY(_early_trap)
1108         SAVE_ALL_SYS
1109         trace_buffer_stop(p0,r0);
1110
1111         ANOMALY_283_315_WORKAROUND(p4, r5)
1112
1113         /* Turn caches off, to ensure we don't get double exceptions */
1114
1115         P4.L = LO(IMEM_CONTROL);
1116         P4.H = HI(IMEM_CONTROL);
1117
1118         R5 = [P4];              /* Control Register*/
1119         BITCLR(R5,ENICPLB_P);
1120         CSYNC;          /* Disabling of CPLBs should be proceeded by a CSYNC */
1121         [P4] = R5;
1122         SSYNC;
1123
1124         P4.L = LO(DMEM_CONTROL);
1125         P4.H = HI(DMEM_CONTROL);
1126         R5 = [P4];
1127         BITCLR(R5,ENDCPLB_P);
1128         CSYNC;          /* Disabling of CPLBs should be proceeded by a CSYNC */
1129         [P4] = R5;
1130         SSYNC;
1131
1132         r0 = sp;        /* stack frame pt_regs pointer argument ==> r0 */
1133         r1 = RETX;
1134
1135         SP += -12;
1136         call _early_trap_c;
1137         SP += 12;
1138 ENDPROC(_early_trap)
1139 __FINIT
1140 #endif /* CONFIG_EARLY_PRINTK */
1141
1142 /*
1143  * Put these in the kernel data section - that should always be covered by
1144  * a CPLB. This is needed to ensure we don't get double fault conditions
1145  */
1146
1147 #ifdef CONFIG_SYSCALL_TAB_L1
1148 .section .l1.data
1149 #else
1150 .data
1151 #endif
1152
1153 ENTRY(_ex_table)
1154         /* entry for each EXCAUSE[5:0]
1155          * This table must be in sync with the table in ./kernel/traps.c
1156          * EXCPT instruction can provide 4 bits of EXCAUSE, allowing 16 to be user defined
1157          */
1158         .long _ex_syscall       /* 0x00 - User Defined - Linux Syscall */
1159         .long _ex_trap_c        /* 0x01 - User Defined - Software breakpoint */
1160 #ifdef  CONFIG_KGDB
1161         .long _ex_trap_c        /* 0x02 - User Defined - KGDB initial connection
1162                                                          and break signal trap */
1163 #else
1164         .long _ex_replaceable   /* 0x02 - User Defined */
1165 #endif
1166         .long _ex_trap_c        /* 0x03 - User Defined - userspace stack overflow */
1167         .long _ex_trap_c        /* 0x04 - User Defined - dump trace buffer */
1168         .long _ex_replaceable   /* 0x05 - User Defined */
1169         .long _ex_replaceable   /* 0x06 - User Defined */
1170         .long _ex_replaceable   /* 0x07 - User Defined */
1171         .long _ex_replaceable   /* 0x08 - User Defined */
1172         .long _ex_replaceable   /* 0x09 - User Defined */
1173         .long _ex_replaceable   /* 0x0A - User Defined */
1174         .long _ex_replaceable   /* 0x0B - User Defined */
1175         .long _ex_replaceable   /* 0x0C - User Defined */
1176         .long _ex_replaceable   /* 0x0D - User Defined */
1177         .long _ex_replaceable   /* 0x0E - User Defined */
1178         .long _ex_replaceable   /* 0x0F - User Defined */
1179         .long _ex_single_step   /* 0x10 - HW Single step */
1180 #ifdef CONFIG_DEBUG_BFIN_HWTRACE_EXPAND
1181         .long _ex_trace_buff_full /* 0x11 - Trace Buffer Full */
1182 #else
1183         .long _ex_trap_c        /* 0x11 - Trace Buffer Full */
1184 #endif
1185         .long _ex_trap_c        /* 0x12 - Reserved */
1186         .long _ex_trap_c        /* 0x13 - Reserved */
1187         .long _ex_trap_c        /* 0x14 - Reserved */
1188         .long _ex_trap_c        /* 0x15 - Reserved */
1189         .long _ex_trap_c        /* 0x16 - Reserved */
1190         .long _ex_trap_c        /* 0x17 - Reserved */
1191         .long _ex_trap_c        /* 0x18 - Reserved */
1192         .long _ex_trap_c        /* 0x19 - Reserved */
1193         .long _ex_trap_c        /* 0x1A - Reserved */
1194         .long _ex_trap_c        /* 0x1B - Reserved */
1195         .long _ex_trap_c        /* 0x1C - Reserved */
1196         .long _ex_trap_c        /* 0x1D - Reserved */
1197         .long _ex_trap_c        /* 0x1E - Reserved */
1198         .long _ex_trap_c        /* 0x1F - Reserved */
1199         .long _ex_trap_c        /* 0x20 - Reserved */
1200         .long _ex_trap_c        /* 0x21 - Undefined Instruction */
1201         .long _ex_trap_c        /* 0x22 - Illegal Instruction Combination */
1202         .long _ex_dviol         /* 0x23 - Data CPLB Protection Violation */
1203         .long _ex_trap_c        /* 0x24 - Data access misaligned */
1204         .long _ex_trap_c        /* 0x25 - Unrecoverable Event */
1205         .long _ex_dmiss         /* 0x26 - Data CPLB Miss */
1206         .long _ex_dmult         /* 0x27 - Data CPLB Multiple Hits - Linux Trap Zero */
1207         .long _ex_trap_c        /* 0x28 - Emulation Watchpoint */
1208         .long _ex_trap_c        /* 0x29 - Instruction fetch access error (535 only) */
1209         .long _ex_trap_c        /* 0x2A - Instruction fetch misaligned */
1210         .long _ex_trap_c        /* 0x2B - Instruction CPLB protection Violation */
1211         .long _ex_icplb_miss    /* 0x2C - Instruction CPLB miss */
1212         .long _ex_trap_c        /* 0x2D - Instruction CPLB Multiple Hits */
1213         .long _ex_trap_c        /* 0x2E - Illegal use of Supervisor Resource */
1214         .long _ex_trap_c        /* 0x2E - Illegal use of Supervisor Resource */
1215         .long _ex_trap_c        /* 0x2F - Reserved */
1216         .long _ex_trap_c        /* 0x30 - Reserved */
1217         .long _ex_trap_c        /* 0x31 - Reserved */
1218         .long _ex_trap_c        /* 0x32 - Reserved */
1219         .long _ex_trap_c        /* 0x33 - Reserved */
1220         .long _ex_trap_c        /* 0x34 - Reserved */
1221         .long _ex_trap_c        /* 0x35 - Reserved */
1222         .long _ex_trap_c        /* 0x36 - Reserved */
1223         .long _ex_trap_c        /* 0x37 - Reserved */
1224         .long _ex_trap_c        /* 0x38 - Reserved */
1225         .long _ex_trap_c        /* 0x39 - Reserved */
1226         .long _ex_trap_c        /* 0x3A - Reserved */
1227         .long _ex_trap_c        /* 0x3B - Reserved */
1228         .long _ex_trap_c        /* 0x3C - Reserved */
1229         .long _ex_trap_c        /* 0x3D - Reserved */
1230         .long _ex_trap_c        /* 0x3E - Reserved */
1231         .long _ex_trap_c        /* 0x3F - Reserved */
1232 END(_ex_table)
1233
1234 ENTRY(_sys_call_table)
1235         .long _sys_restart_syscall      /* 0 */
1236         .long _sys_exit
1237         .long _sys_fork
1238         .long _sys_read
1239         .long _sys_write
1240         .long _sys_open         /* 5 */
1241         .long _sys_close
1242         .long _sys_ni_syscall   /* old waitpid */
1243         .long _sys_creat
1244         .long _sys_link
1245         .long _sys_unlink       /* 10 */
1246         .long _sys_execve
1247         .long _sys_chdir
1248         .long _sys_time
1249         .long _sys_mknod
1250         .long _sys_chmod                /* 15 */
1251         .long _sys_chown        /* chown16 */
1252         .long _sys_ni_syscall   /* old break syscall holder */
1253         .long _sys_ni_syscall   /* old stat */
1254         .long _sys_lseek
1255         .long _sys_getpid       /* 20 */
1256         .long _sys_mount
1257         .long _sys_ni_syscall   /* old umount */
1258         .long _sys_setuid
1259         .long _sys_getuid
1260         .long _sys_stime                /* 25 */
1261         .long _sys_ptrace
1262         .long _sys_alarm
1263         .long _sys_ni_syscall   /* old fstat */
1264         .long _sys_pause
1265         .long _sys_ni_syscall   /* old utime */ /* 30 */
1266         .long _sys_ni_syscall   /* old stty syscall holder */
1267         .long _sys_ni_syscall   /* old gtty syscall holder */
1268         .long _sys_access
1269         .long _sys_nice
1270         .long _sys_ni_syscall   /* 35 */ /* old ftime syscall holder */
1271         .long _sys_sync
1272         .long _sys_kill
1273         .long _sys_rename
1274         .long _sys_mkdir
1275         .long _sys_rmdir                /* 40 */
1276         .long _sys_dup
1277         .long _sys_pipe
1278         .long _sys_times
1279         .long _sys_ni_syscall   /* old prof syscall holder */
1280         .long _sys_brk          /* 45 */
1281         .long _sys_setgid
1282         .long _sys_getgid
1283         .long _sys_ni_syscall   /* old sys_signal */
1284         .long _sys_geteuid      /* geteuid16 */
1285         .long _sys_getegid      /* getegid16 */ /* 50 */
1286         .long _sys_acct
1287         .long _sys_umount       /* recycled never used phys() */
1288         .long _sys_ni_syscall   /* old lock syscall holder */
1289         .long _sys_ioctl
1290         .long _sys_fcntl                /* 55 */
1291         .long _sys_ni_syscall   /* old mpx syscall holder */
1292         .long _sys_setpgid
1293         .long _sys_ni_syscall   /* old ulimit syscall holder */
1294         .long _sys_ni_syscall   /* old old uname */
1295         .long _sys_umask                /* 60 */
1296         .long _sys_chroot
1297         .long _sys_ustat
1298         .long _sys_dup2
1299         .long _sys_getppid
1300         .long _sys_getpgrp      /* 65 */
1301         .long _sys_setsid
1302         .long _sys_ni_syscall   /* old sys_sigaction */
1303         .long _sys_sgetmask
1304         .long _sys_ssetmask
1305         .long _sys_setreuid     /* setreuid16 */        /* 70 */
1306         .long _sys_setregid     /* setregid16 */
1307         .long _sys_ni_syscall   /* old sys_sigsuspend */
1308         .long _sys_ni_syscall   /* old sys_sigpending */
1309         .long _sys_sethostname
1310         .long _sys_setrlimit    /* 75 */
1311         .long _sys_ni_syscall   /* old getrlimit */
1312         .long _sys_getrusage
1313         .long _sys_gettimeofday
1314         .long _sys_settimeofday
1315         .long _sys_getgroups    /* getgroups16 */       /* 80 */
1316         .long _sys_setgroups    /* setgroups16 */
1317         .long _sys_ni_syscall   /* old_select */
1318         .long _sys_symlink
1319         .long _sys_ni_syscall   /* old lstat */
1320         .long _sys_readlink     /* 85 */
1321         .long _sys_uselib
1322         .long _sys_ni_syscall   /* sys_swapon */
1323         .long _sys_reboot
1324         .long _sys_ni_syscall   /* old_readdir */
1325         .long _sys_ni_syscall   /* sys_mmap */  /* 90 */
1326         .long _sys_munmap
1327         .long _sys_truncate
1328         .long _sys_ftruncate
1329         .long _sys_fchmod
1330         .long _sys_fchown       /* fchown16 */  /* 95 */
1331         .long _sys_getpriority
1332         .long _sys_setpriority
1333         .long _sys_ni_syscall   /* old profil syscall holder */
1334         .long _sys_statfs
1335         .long _sys_fstatfs      /* 100 */
1336         .long _sys_ni_syscall
1337         .long _sys_ni_syscall   /* old sys_socketcall */
1338         .long _sys_syslog
1339         .long _sys_setitimer
1340         .long _sys_getitimer    /* 105 */
1341         .long _sys_newstat
1342         .long _sys_newlstat
1343         .long _sys_newfstat
1344         .long _sys_ni_syscall   /* old uname */
1345         .long _sys_ni_syscall   /* iopl for i386 */ /* 110 */
1346         .long _sys_vhangup
1347         .long _sys_ni_syscall   /* obsolete idle() syscall */
1348         .long _sys_ni_syscall   /* vm86old for i386 */
1349         .long _sys_wait4
1350         .long _sys_ni_syscall   /* 115 */ /* sys_swapoff */
1351         .long _sys_sysinfo
1352         .long _sys_ni_syscall   /* old sys_ipc */
1353         .long _sys_fsync
1354         .long _sys_ni_syscall   /* old sys_sigreturn */
1355         .long _sys_clone                /* 120 */
1356         .long _sys_setdomainname
1357         .long _sys_newuname
1358         .long _sys_ni_syscall   /* old sys_modify_ldt */
1359         .long _sys_adjtimex
1360         .long _sys_ni_syscall   /* 125 */ /* sys_mprotect */
1361         .long _sys_ni_syscall   /* old sys_sigprocmask */
1362         .long _sys_ni_syscall   /* old "creat_module" */
1363         .long _sys_init_module
1364         .long _sys_delete_module
1365         .long _sys_ni_syscall   /* 130: old "get_kernel_syms" */
1366         .long _sys_quotactl
1367         .long _sys_getpgid
1368         .long _sys_fchdir
1369         .long _sys_bdflush
1370         .long _sys_ni_syscall   /* 135 */ /* sys_sysfs */
1371         .long _sys_personality
1372         .long _sys_ni_syscall   /* for afs_syscall */
1373         .long _sys_setfsuid     /* setfsuid16 */
1374         .long _sys_setfsgid     /* setfsgid16 */
1375         .long _sys_llseek       /* 140 */
1376         .long _sys_getdents
1377         .long _sys_ni_syscall   /* sys_select */
1378         .long _sys_flock
1379         .long _sys_ni_syscall   /* sys_msync */
1380         .long _sys_readv                /* 145 */
1381         .long _sys_writev
1382         .long _sys_getsid
1383         .long _sys_fdatasync
1384         .long _sys_sysctl
1385         .long _sys_ni_syscall   /* 150 */ /* sys_mlock */
1386         .long _sys_ni_syscall   /* sys_munlock */
1387         .long _sys_ni_syscall   /* sys_mlockall */
1388         .long _sys_ni_syscall   /* sys_munlockall */
1389         .long _sys_sched_setparam
1390         .long _sys_sched_getparam /* 155 */
1391         .long _sys_sched_setscheduler
1392         .long _sys_sched_getscheduler
1393         .long _sys_sched_yield
1394         .long _sys_sched_get_priority_max
1395         .long _sys_sched_get_priority_min  /* 160 */
1396         .long _sys_sched_rr_get_interval
1397         .long _sys_nanosleep
1398         .long _sys_mremap
1399         .long _sys_setresuid    /* setresuid16 */
1400         .long _sys_getresuid    /* getresuid16 */       /* 165 */
1401         .long _sys_ni_syscall   /* for vm86 */
1402         .long _sys_ni_syscall   /* old "query_module" */
1403         .long _sys_ni_syscall   /* sys_poll */
1404         .long _sys_nfsservctl
1405         .long _sys_setresgid    /* setresgid16 */       /* 170 */
1406         .long _sys_getresgid    /* getresgid16 */
1407         .long _sys_prctl
1408         .long _sys_rt_sigreturn
1409         .long _sys_rt_sigaction
1410         .long _sys_rt_sigprocmask /* 175 */
1411         .long _sys_rt_sigpending
1412         .long _sys_rt_sigtimedwait
1413         .long _sys_rt_sigqueueinfo
1414         .long _sys_rt_sigsuspend
1415         .long _sys_pread64      /* 180 */
1416         .long _sys_pwrite64
1417         .long _sys_lchown       /* lchown16 */
1418         .long _sys_getcwd
1419         .long _sys_capget
1420         .long _sys_capset       /* 185 */
1421         .long _sys_sigaltstack
1422         .long _sys_sendfile
1423         .long _sys_ni_syscall   /* streams1 */
1424         .long _sys_ni_syscall   /* streams2 */
1425         .long _sys_vfork                /* 190 */
1426         .long _sys_getrlimit
1427         .long _sys_mmap_pgoff
1428         .long _sys_truncate64
1429         .long _sys_ftruncate64
1430         .long _sys_stat64       /* 195 */
1431         .long _sys_lstat64
1432         .long _sys_fstat64
1433         .long _sys_chown
1434         .long _sys_getuid
1435         .long _sys_getgid       /* 200 */
1436         .long _sys_geteuid
1437         .long _sys_getegid
1438         .long _sys_setreuid
1439         .long _sys_setregid
1440         .long _sys_getgroups    /* 205 */
1441         .long _sys_setgroups
1442         .long _sys_fchown
1443         .long _sys_setresuid
1444         .long _sys_getresuid
1445         .long _sys_setresgid    /* 210 */
1446         .long _sys_getresgid
1447         .long _sys_lchown
1448         .long _sys_setuid
1449         .long _sys_setgid
1450         .long _sys_setfsuid     /* 215 */
1451         .long _sys_setfsgid
1452         .long _sys_pivot_root
1453         .long _sys_ni_syscall   /* sys_mincore */
1454         .long _sys_ni_syscall   /* sys_madvise */
1455         .long _sys_getdents64   /* 220 */
1456         .long _sys_fcntl64
1457         .long _sys_ni_syscall   /* reserved for TUX */
1458         .long _sys_ni_syscall
1459         .long _sys_gettid
1460         .long _sys_readahead    /* 225 */
1461         .long _sys_setxattr
1462         .long _sys_lsetxattr
1463         .long _sys_fsetxattr
1464         .long _sys_getxattr
1465         .long _sys_lgetxattr    /* 230 */
1466         .long _sys_fgetxattr
1467         .long _sys_listxattr
1468         .long _sys_llistxattr
1469         .long _sys_flistxattr
1470         .long _sys_removexattr  /* 235 */
1471         .long _sys_lremovexattr
1472         .long _sys_fremovexattr
1473         .long _sys_tkill
1474         .long _sys_sendfile64
1475         .long _sys_futex                /* 240 */
1476         .long _sys_sched_setaffinity
1477         .long _sys_sched_getaffinity
1478         .long _sys_ni_syscall   /* sys_set_thread_area */
1479         .long _sys_ni_syscall   /* sys_get_thread_area */
1480         .long _sys_io_setup     /* 245 */
1481         .long _sys_io_destroy
1482         .long _sys_io_getevents
1483         .long _sys_io_submit
1484         .long _sys_io_cancel
1485         .long _sys_ni_syscall   /* 250 */ /* sys_alloc_hugepages */
1486         .long _sys_ni_syscall   /* sys_freec_hugepages */
1487         .long _sys_exit_group
1488         .long _sys_lookup_dcookie
1489         .long _sys_bfin_spinlock
1490         .long _sys_epoll_create /* 255 */
1491         .long _sys_epoll_ctl
1492         .long _sys_epoll_wait
1493         .long _sys_ni_syscall /* remap_file_pages */
1494         .long _sys_set_tid_address
1495         .long _sys_timer_create /* 260 */
1496         .long _sys_timer_settime
1497         .long _sys_timer_gettime
1498         .long _sys_timer_getoverrun
1499         .long _sys_timer_delete
1500         .long _sys_clock_settime /* 265 */
1501         .long _sys_clock_gettime
1502         .long _sys_clock_getres
1503         .long _sys_clock_nanosleep
1504         .long _sys_statfs64
1505         .long _sys_fstatfs64    /* 270 */
1506         .long _sys_tgkill
1507         .long _sys_utimes
1508         .long _sys_fadvise64_64
1509         .long _sys_ni_syscall /* vserver */
1510         .long _sys_ni_syscall /* 275, mbind */
1511         .long _sys_ni_syscall /* get_mempolicy */
1512         .long _sys_ni_syscall /* set_mempolicy */
1513         .long _sys_mq_open
1514         .long _sys_mq_unlink
1515         .long _sys_mq_timedsend /* 280 */
1516         .long _sys_mq_timedreceive
1517         .long _sys_mq_notify
1518         .long _sys_mq_getsetattr
1519         .long _sys_ni_syscall /* kexec_load */
1520         .long _sys_waitid       /* 285 */
1521         .long _sys_add_key
1522         .long _sys_request_key
1523         .long _sys_keyctl
1524         .long _sys_ioprio_set
1525         .long _sys_ioprio_get   /* 290 */
1526         .long _sys_inotify_init
1527         .long _sys_inotify_add_watch
1528         .long _sys_inotify_rm_watch
1529         .long _sys_ni_syscall /* migrate_pages */
1530         .long _sys_openat       /* 295 */
1531         .long _sys_mkdirat
1532         .long _sys_mknodat
1533         .long _sys_fchownat
1534         .long _sys_futimesat
1535         .long _sys_fstatat64    /* 300 */
1536         .long _sys_unlinkat
1537         .long _sys_renameat
1538         .long _sys_linkat
1539         .long _sys_symlinkat
1540         .long _sys_readlinkat   /* 305 */
1541         .long _sys_fchmodat
1542         .long _sys_faccessat
1543         .long _sys_pselect6
1544         .long _sys_ppoll
1545         .long _sys_unshare      /* 310 */
1546         .long _sys_sram_alloc
1547         .long _sys_sram_free
1548         .long _sys_dma_memcpy
1549         .long _sys_accept
1550         .long _sys_bind         /* 315 */
1551         .long _sys_connect
1552         .long _sys_getpeername
1553         .long _sys_getsockname
1554         .long _sys_getsockopt
1555         .long _sys_listen       /* 320 */
1556         .long _sys_recv
1557         .long _sys_recvfrom
1558         .long _sys_recvmsg
1559         .long _sys_send
1560         .long _sys_sendmsg      /* 325 */
1561         .long _sys_sendto
1562         .long _sys_setsockopt
1563         .long _sys_shutdown
1564         .long _sys_socket
1565         .long _sys_socketpair   /* 330 */
1566         .long _sys_semctl
1567         .long _sys_semget
1568         .long _sys_semop
1569         .long _sys_msgctl
1570         .long _sys_msgget       /* 335 */
1571         .long _sys_msgrcv
1572         .long _sys_msgsnd
1573         .long _sys_shmat
1574         .long _sys_shmctl
1575         .long _sys_shmdt        /* 340 */
1576         .long _sys_shmget
1577         .long _sys_splice
1578         .long _sys_sync_file_range
1579         .long _sys_tee
1580         .long _sys_vmsplice     /* 345 */
1581         .long _sys_epoll_pwait
1582         .long _sys_utimensat
1583         .long _sys_signalfd
1584         .long _sys_timerfd_create
1585         .long _sys_eventfd      /* 350 */
1586         .long _sys_pread64
1587         .long _sys_pwrite64
1588         .long _sys_fadvise64
1589         .long _sys_set_robust_list
1590         .long _sys_get_robust_list      /* 355 */
1591         .long _sys_fallocate
1592         .long _sys_semtimedop
1593         .long _sys_timerfd_settime
1594         .long _sys_timerfd_gettime
1595         .long _sys_signalfd4            /* 360 */
1596         .long _sys_eventfd2
1597         .long _sys_epoll_create1
1598         .long _sys_dup3
1599         .long _sys_pipe2
1600         .long _sys_inotify_init1        /* 365 */
1601         .long _sys_preadv
1602         .long _sys_pwritev
1603         .long _sys_rt_tgsigqueueinfo
1604         .long _sys_perf_event_open
1605         .long _sys_recvmmsg             /* 370 */
1606
1607         .rept NR_syscalls-(.-_sys_call_table)/4
1608         .long _sys_ni_syscall
1609         .endr
1610 END(_sys_call_table)