arch/arm/lib/getuser.S

   1 /*
   2  *  linux/arch/arm/lib/getuser.S
   3  *
   4  *  Copyright (C) 2001 Russell King
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  *
  10  *  Idea from x86 version, (C) Copyright 1998 Linus Torvalds
  11  *
  12  * These functions have a non-standard call interface to make them more
  13  * efficient, especially as they return an error value in addition to
  14  * the "real" return value.
  15  *
  16  * __get_user_X
  17  *
  18  * Inputs:      r0 contains the address
  19  * Outputs:     r0 is the error code
  20  *              r2, r3 contains the zero-extended value
  21  *              lr corrupted
  22  *
  23  * No other registers must be altered.  (see include/asm-arm/uaccess.h
  24  * for specific ASM register usage).
  25  *
  26  * Note that ADDR_LIMIT is either 0 or 0xc0000000.
  27  * Note also that it is intended that __get_user_bad is not global.
  28  */
  29 #include <asm/asm-offsets.h>
  30 #include <asm/thread_info.h>
  31 #include <asm/errno.h>
  32
  33         .global __get_user_1
  34 __get_user_1:
  35 1:      ldrbt   r2, [r0]
  36         mov     r0, #0
  37         mov     pc, lr
  38
  39         .global __get_user_2
  40 __get_user_2:
  41 2:      ldrbt   r2, [r0], #1
  42 3:      ldrbt   r3, [r0]
  43 #ifndef __ARMEB__
  44         orr     r2, r2, r3, lsl #8
  45 #else
  46         orr     r2, r3, r2, lsl #8
  47 #endif
  48         mov     r0, #0
  49         mov     pc, lr
  50
  51         .global __get_user_4
  52 __get_user_4:
  53 4:      ldrt    r2, [r0]
  54         mov     r0, #0
  55         mov     pc, lr
  56
  57         .global __get_user_8
  58 __get_user_8:
  59 5:      ldrt    r2, [r0], #4
  60 6:      ldrt    r3, [r0]
  61         mov     r0, #0
  62         mov     pc, lr
  63
  64 __get_user_bad_8:
  65         mov     r3, #0
  66 __get_user_bad:
  67         mov     r2, #0
  68         mov     r0, #-EFAULT
  69         mov     pc, lr
  70
  71 .section __ex_table, "a"
  72         .long   1b, __get_user_bad
  73         .long   2b, __get_user_bad
  74         .long   3b, __get_user_bad
  75         .long   4b, __get_user_bad
  76         .long   5b, __get_user_bad_8
  77         .long   6b, __get_user_bad_8
  78 .previous