5f90a5fb7022866644e5dfdae2cf81cf220e1e76
[sfrench/cifs-2.6.git] / arch / arm / kernel / head-nommu.S
1 /*
2  *  linux/arch/arm/kernel/head-nommu.S
3  *
4  *  Copyright (C) 1994-2002 Russell King
5  *  Copyright (C) 2003-2006 Hyok S. Choi
6  *
7  * This program is free software; you can redistribute it and/or modify
8  * it under the terms of the GNU General Public License version 2 as
9  * published by the Free Software Foundation.
10  *
11  *  Common kernel startup code (non-paged MM)
12  *
13  */
14 #include <linux/linkage.h>
15 #include <linux/init.h>
16 #include <linux/errno.h>
17
18 #include <asm/assembler.h>
19 #include <asm/ptrace.h>
20 #include <asm/asm-offsets.h>
21 #include <asm/memory.h>
22 #include <asm/cp15.h>
23 #include <asm/thread_info.h>
24 #include <asm/v7m.h>
25 #include <asm/mpu.h>
26 #include <asm/page.h>
27
28 /*
29  * Kernel startup entry point.
30  * ---------------------------
31  *
32  * This is normally called from the decompressor code.  The requirements
33  * are: MMU = off, D-cache = off, I-cache = dont care, r0 = 0,
34  * r1 = machine nr.
35  *
36  * See linux/arch/arm/tools/mach-types for the complete list of machine
37  * numbers for r1.
38  *
39  */
40
41         __HEAD
42
43 #ifdef CONFIG_CPU_THUMBONLY
44         .thumb
45 ENTRY(stext)
46 #else
47         .arm
48 ENTRY(stext)
49
50  THUMB( badr    r9, 1f          )       @ Kernel is always entered in ARM.
51  THUMB( bx      r9              )       @ If this is a Thumb-2 kernel,
52  THUMB( .thumb                  )       @ switch to Thumb now.
53  THUMB(1:                       )
54 #endif
55
56         setmode PSR_F_BIT | PSR_I_BIT | SVC_MODE, r9 @ ensure svc mode
57                                                 @ and irqs disabled
58 #if defined(CONFIG_CPU_CP15)
59         mrc     p15, 0, r9, c0, c0              @ get processor id
60 #elif defined(CONFIG_CPU_V7M)
61         ldr     r9, =BASEADDR_V7M_SCB
62         ldr     r9, [r9, V7M_SCB_CPUID]
63 #else
64         ldr     r9, =CONFIG_PROCESSOR_ID
65 #endif
66         bl      __lookup_processor_type         @ r5=procinfo r9=cpuid
67         movs    r10, r5                         @ invalid processor (r5=0)?
68         beq     __error_p                               @ yes, error 'p'
69
70 #ifdef CONFIG_ARM_MPU
71         /* Calculate the size of a region covering just the kernel */
72         ldr     r5, =PLAT_PHYS_OFFSET           @ Region start: PHYS_OFFSET
73         ldr     r6, =(_end)                     @ Cover whole kernel
74         sub     r6, r6, r5                      @ Minimum size of region to map
75         clz     r6, r6                          @ Region size must be 2^N...
76         rsb     r6, r6, #31                     @ ...so round up region size
77         lsl     r6, r6, #MPU_RSR_SZ             @ Put size in right field
78         orr     r6, r6, #(1 << MPU_RSR_EN)      @ Set region enabled bit
79         bl      __setup_mpu
80 #endif
81
82         badr    lr, 1f                          @ return (PIC) address
83         ldr     r12, [r10, #PROCINFO_INITFUNC]
84         add     r12, r12, r10
85         ret     r12
86 1:      bl      __after_proc_init
87         b       __mmap_switched
88 ENDPROC(stext)
89
90 #ifdef CONFIG_SMP
91         .text
92 ENTRY(secondary_startup)
93         /*
94          * Common entry point for secondary CPUs.
95          *
96          * Ensure that we're in SVC mode, and IRQs are disabled.  Lookup
97          * the processor type - there is no need to check the machine type
98          * as it has already been validated by the primary processor.
99          */
100         setmode PSR_F_BIT | PSR_I_BIT | SVC_MODE, r9
101 #ifndef CONFIG_CPU_CP15
102         ldr     r9, =CONFIG_PROCESSOR_ID
103 #else
104         mrc     p15, 0, r9, c0, c0              @ get processor id
105 #endif
106         bl      __lookup_processor_type         @ r5=procinfo r9=cpuid
107         movs    r10, r5                         @ invalid processor?
108         beq     __error_p                       @ yes, error 'p'
109
110         ldr     r7, __secondary_data
111
112 #ifdef CONFIG_ARM_MPU
113         /* Use MPU region info supplied by __cpu_up */
114         ldr     r6, [r7]                        @ get secondary_data.mpu_rgn_info
115         bl      __secondary_setup_mpu           @ Initialize the MPU
116 #endif
117
118         badr    lr, 1f                          @ return (PIC) address
119         ldr     r12, [r10, #PROCINFO_INITFUNC]
120         add     r12, r12, r10
121         ret     r12
122 1:      bl      __after_proc_init
123         ldr     sp, [r7, #12]                   @ set up the stack pointer
124         mov     fp, #0
125         b       secondary_start_kernel
126 ENDPROC(secondary_startup)
127
128         .type   __secondary_data, %object
129 __secondary_data:
130         .long   secondary_data
131 #endif /* CONFIG_SMP */
132
133 /*
134  * Set the Control Register and Read the process ID.
135  */
136 __after_proc_init:
137 #ifdef CONFIG_CPU_CP15
138         /*
139          * CP15 system control register value returned in r0 from
140          * the CPU init function.
141          */
142 #if defined(CONFIG_ALIGNMENT_TRAP) && __LINUX_ARM_ARCH__ < 6
143         orr     r0, r0, #CR_A
144 #else
145         bic     r0, r0, #CR_A
146 #endif
147 #ifdef CONFIG_CPU_DCACHE_DISABLE
148         bic     r0, r0, #CR_C
149 #endif
150 #ifdef CONFIG_CPU_BPREDICT_DISABLE
151         bic     r0, r0, #CR_Z
152 #endif
153 #ifdef CONFIG_CPU_ICACHE_DISABLE
154         bic     r0, r0, #CR_I
155 #endif
156         mcr     p15, 0, r0, c1, c0, 0           @ write control reg
157 #elif defined (CONFIG_CPU_V7M)
158         /* For V7M systems we want to modify the CCR similarly to the SCTLR */
159 #ifdef CONFIG_CPU_DCACHE_DISABLE
160         bic     r0, r0, #V7M_SCB_CCR_DC
161 #endif
162 #ifdef CONFIG_CPU_BPREDICT_DISABLE
163         bic     r0, r0, #V7M_SCB_CCR_BP
164 #endif
165 #ifdef CONFIG_CPU_ICACHE_DISABLE
166         bic     r0, r0, #V7M_SCB_CCR_IC
167 #endif
168         movw    r3, #:lower16:(BASEADDR_V7M_SCB + V7M_SCB_CCR)
169         movt    r3, #:upper16:(BASEADDR_V7M_SCB + V7M_SCB_CCR)
170         str     r0, [r3]
171 #endif /* CONFIG_CPU_CP15 elif CONFIG_CPU_V7M */
172         ret     lr
173 ENDPROC(__after_proc_init)
174         .ltorg
175
176 #ifdef CONFIG_ARM_MPU
177
178
179 /* Set which MPU region should be programmed */
180 .macro set_region_nr tmp, rgnr
181         mov     \tmp, \rgnr                     @ Use static region numbers
182         mcr     p15, 0, \tmp, c6, c2, 0         @ Write RGNR
183 .endm
184
185 /* Setup a single MPU region, either D or I side (D-side for unified) */
186 .macro setup_region bar, acr, sr, side = MPU_DATA_SIDE
187         mcr     p15, 0, \bar, c6, c1, (0 + \side)       @ I/DRBAR
188         mcr     p15, 0, \acr, c6, c1, (4 + \side)       @ I/DRACR
189         mcr     p15, 0, \sr, c6, c1, (2 + \side)                @ I/DRSR
190 .endm
191
192 /*
193  * Setup the MPU and initial MPU Regions. We create the following regions:
194  * Region 0: Use this for probing the MPU details, so leave disabled.
195  * Region 1: Background region - covers the whole of RAM as strongly ordered
196  * Region 2: Normal, Shared, cacheable for RAM. From PHYS_OFFSET, size from r6
197  * Region 3: Normal, shared, inaccessible from PL0 to protect the vectors page
198  *
199  * r6: Value to be written to DRSR (and IRSR if required) for MPU_RAM_REGION
200 */
201
202 ENTRY(__setup_mpu)
203
204         /* Probe for v7 PMSA compliance */
205         mrc     p15, 0, r0, c0, c1, 4           @ Read ID_MMFR0
206         and     r0, r0, #(MMFR0_PMSA)           @ PMSA field
207         teq     r0, #(MMFR0_PMSAv7)             @ PMSA v7
208         bxne    lr
209
210         /* Determine whether the D/I-side memory map is unified. We set the
211          * flags here and continue to use them for the rest of this function */
212         mrc     p15, 0, r0, c0, c0, 4           @ MPUIR
213         ands    r5, r0, #MPUIR_DREGION_SZMASK   @ 0 size d region => No MPU
214         bxeq    lr
215         tst     r0, #MPUIR_nU                   @ MPUIR_nU = 0 for unified
216
217         /* Setup second region first to free up r6 */
218         set_region_nr r0, #MPU_RAM_REGION
219         isb
220         /* Full access from PL0, PL1, shared for CONFIG_SMP, cacheable */
221         ldr     r0, =PLAT_PHYS_OFFSET           @ RAM starts at PHYS_OFFSET
222         ldr     r5,=(MPU_AP_PL1RW_PL0RW | MPU_RGN_NORMAL)
223
224         setup_region r0, r5, r6, MPU_DATA_SIDE  @ PHYS_OFFSET, shared, enabled
225         beq     1f                              @ Memory-map not unified
226         setup_region r0, r5, r6, MPU_INSTR_SIDE @ PHYS_OFFSET, shared, enabled
227 1:      isb
228
229         /* First/background region */
230         set_region_nr r0, #MPU_BG_REGION
231         isb
232         /* Execute Never,  strongly ordered, inaccessible to PL0, rw PL1  */
233         mov     r0, #0                          @ BG region starts at 0x0
234         ldr     r5,=(MPU_ACR_XN | MPU_RGN_STRONGLY_ORDERED | MPU_AP_PL1RW_PL0NA)
235         mov     r6, #MPU_RSR_ALL_MEM            @ 4GB region, enabled
236
237         setup_region r0, r5, r6, MPU_DATA_SIDE  @ 0x0, BG region, enabled
238         beq     2f                              @ Memory-map not unified
239         setup_region r0, r5, r6, MPU_INSTR_SIDE @ 0x0, BG region, enabled
240 2:      isb
241
242         /* Enable the MPU */
243         mrc     p15, 0, r0, c1, c0, 0           @ Read SCTLR
244         bic     r0, r0, #CR_BR                  @ Disable the 'default mem-map'
245         orr     r0, r0, #CR_M                   @ Set SCTRL.M (MPU on)
246         mcr     p15, 0, r0, c1, c0, 0           @ Enable MPU
247         isb
248
249         ret     lr
250 ENDPROC(__setup_mpu)
251
252 #ifdef CONFIG_SMP
253 /*
254  * r6: pointer at mpu_rgn_info
255  */
256
257 ENTRY(__secondary_setup_mpu)
258         /* Probe for v7 PMSA compliance */
259         mrc     p15, 0, r0, c0, c1, 4           @ Read ID_MMFR0
260         and     r0, r0, #(MMFR0_PMSA)           @ PMSA field
261         teq     r0, #(MMFR0_PMSAv7)             @ PMSA v7
262         bne     __error_p
263
264         /* Determine whether the D/I-side memory map is unified. We set the
265          * flags here and continue to use them for the rest of this function */
266         mrc     p15, 0, r0, c0, c0, 4           @ MPUIR
267         ands    r5, r0, #MPUIR_DREGION_SZMASK   @ 0 size d region => No MPU
268         beq     __error_p
269
270         ldr     r4, [r6, #MPU_RNG_INFO_USED]
271         mov     r5, #MPU_RNG_SIZE
272         add     r3, r6, #MPU_RNG_INFO_RNGS
273         mla     r3, r4, r5, r3
274
275 1:
276         tst     r0, #MPUIR_nU                   @ MPUIR_nU = 0 for unified
277         sub     r3, r3, #MPU_RNG_SIZE
278         sub     r4, r4, #1
279
280         set_region_nr r0, r4
281         isb
282
283         ldr     r0, [r3, #MPU_RGN_DRBAR]
284         ldr     r6, [r3, #MPU_RGN_DRSR]
285         ldr     r5, [r3, #MPU_RGN_DRACR]
286
287         setup_region r0, r5, r6, MPU_DATA_SIDE
288         beq     2f
289         setup_region r0, r5, r6, MPU_INSTR_SIDE
290 2:      isb
291
292         mrc     p15, 0, r0, c0, c0, 4           @ Reevaluate the MPUIR
293         cmp     r4, #0
294         bgt     1b
295
296         /* Enable the MPU */
297         mrc     p15, 0, r0, c1, c0, 0           @ Read SCTLR
298         bic     r0, r0, #CR_BR                  @ Disable the 'default mem-map'
299         orr     r0, r0, #CR_M                   @ Set SCTRL.M (MPU on)
300         mcr     p15, 0, r0, c1, c0, 0           @ Enable MPU
301         isb
302
303         ret     lr
304 ENDPROC(__secondary_setup_mpu)
305
306 #endif /* CONFIG_SMP */
307 #endif /* CONFIG_ARM_MPU */
308 #include "head-common.S"