arch/arm/kernel/entry-common.S

   1 /*
   2  *  linux/arch/arm/kernel/entry-common.S
   3  *
   4  *  Copyright (C) 2000 Russell King
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  */
  10
  11 #include <asm/assembler.h>
  12 #include <asm/unistd.h>
  13 #include <asm/ftrace.h>
  14 #include <asm/unwind.h>
  15
  16 #ifdef CONFIG_NEED_RET_TO_USER
  17 #include <mach/entry-macro.S>
  18 #else
  19         .macro  arch_ret_to_user, tmp1, tmp2
  20         .endm
  21 #endif
  22
  23 #include "entry-header.S"
  24
  25
  26         .align  5
  27 /*
  28  * This is the fast syscall return path.  We do as little as
  29  * possible here, and this includes saving r0 back into the SVC
  30  * stack.
  31  */
  32 ret_fast_syscall:
  33  UNWIND(.fnstart        )
  34  UNWIND(.cantunwind     )
  35         disable_irq                             @ disable interrupts
  36         ldr     r1, [tsk, #TI_FLAGS]
  37         tst     r1, #_TIF_WORK_MASK
  38         bne     fast_work_pending
  39         asm_trace_hardirqs_on
  40
  41         /* perform architecture specific actions before user return */
  42         arch_ret_to_user r1, lr
  43         ct_user_enter
  44
  45         restore_user_regs fast = 1, offset = S_OFF
  46  UNWIND(.fnend          )
  47
  48 /*
  49  * Ok, we need to do extra processing, enter the slow path.
  50  */
  51 fast_work_pending:
  52         str     r0, [sp, #S_R0+S_OFF]!          @ returned r0
  53 work_pending:
  54         mov     r0, sp                          @ 'regs'
  55         mov     r2, why                         @ 'syscall'
  56         bl      do_work_pending
  57         cmp     r0, #0
  58         beq     no_work_pending
  59         movlt   scno, #(__NR_restart_syscall - __NR_SYSCALL_BASE)
  60         ldmia   sp, {r0 - r6}                   @ have to reload r0 - r6
  61         b       local_restart                   @ ... and off we go
  62
  63 /*
  64  * "slow" syscall return path.  "why" tells us if this was a real syscall.
  65  */
  66 ENTRY(ret_to_user)
  67 ret_slow_syscall:
  68         disable_irq                             @ disable interrupts
  69 ENTRY(ret_to_user_from_irq)
  70         ldr     r1, [tsk, #TI_FLAGS]
  71         tst     r1, #_TIF_WORK_MASK
  72         bne     work_pending
  73 no_work_pending:
  74         asm_trace_hardirqs_on
  75
  76         /* perform architecture specific actions before user return */
  77         arch_ret_to_user r1, lr
  78         ct_user_enter save = 0
  79
  80         restore_user_regs fast = 0, offset = 0
  81 ENDPROC(ret_to_user_from_irq)
  82 ENDPROC(ret_to_user)
  83
  84 /*
  85  * This is how we return from a fork.
  86  */
  87 ENTRY(ret_from_fork)
  88         bl      schedule_tail
  89         cmp     r5, #0
  90         movne   r0, r4
  91         adrne   lr, BSYM(1f)
  92         retne   r5
  93 1:      get_thread_info tsk
  94         b       ret_slow_syscall
  95 ENDPROC(ret_from_fork)
  96
  97         .equ NR_syscalls,0
  98 #define CALL(x) .equ NR_syscalls,NR_syscalls+1
  99 #include "calls.S"
 100
 101 /*
 102  * Ensure that the system call table is equal to __NR_syscalls,
 103  * which is the value the rest of the system sees
 104  */
 105 .ifne NR_syscalls - __NR_syscalls
 106 .error "__NR_syscalls is not equal to the size of the syscall table"
 107 .endif
 108
 109 #undef CALL
 110 #define CALL(x) .long x
 111
 112 /*=============================================================================
 113  * SWI handler
 114  *-----------------------------------------------------------------------------
 115  */
 116
 117         .align  5
 118 ENTRY(vector_swi)
 119 #ifdef CONFIG_CPU_V7M
 120         v7m_exception_entry
 121 #else
 122         sub     sp, sp, #S_FRAME_SIZE
 123         stmia   sp, {r0 - r12}                  @ Calling r0 - r12
 124  ARM(   add     r8, sp, #S_PC           )
 125  ARM(   stmdb   r8, {sp, lr}^           )       @ Calling sp, lr
 126  THUMB( mov     r8, sp                  )
 127  THUMB( store_user_sp_lr r8, r10, S_SP  )       @ calling sp, lr
 128         mrs     r8, spsr                        @ called from non-FIQ mode, so ok.
 129         str     lr, [sp, #S_PC]                 @ Save calling PC
 130         str     r8, [sp, #S_PSR]                @ Save CPSR
 131         str     r0, [sp, #S_OLD_R0]             @ Save OLD_R0
 132 #endif
 133         zero_fp
 134         alignment_trap r10, ip, __cr_alignment
 135         enable_irq
 136         ct_user_exit
 137         get_thread_info tsk
 138
 139         /*
 140          * Get the system call number.
 141          */
 142
 143 #if defined(CONFIG_OABI_COMPAT)
 144
 145         /*
 146          * If we have CONFIG_OABI_COMPAT then we need to look at the swi
 147          * value to determine if it is an EABI or an old ABI call.
 148          */
 149 #ifdef CONFIG_ARM_THUMB
 150         tst     r8, #PSR_T_BIT
 151         movne   r10, #0                         @ no thumb OABI emulation
 152  USER(  ldreq   r10, [lr, #-4]          )       @ get SWI instruction
 153 #else
 154  USER(  ldr     r10, [lr, #-4]          )       @ get SWI instruction
 155 #endif
 156  ARM_BE8(rev    r10, r10)                       @ little endian instruction
 157
 158 #elif defined(CONFIG_AEABI)
 159
 160         /*
 161          * Pure EABI user space always put syscall number into scno (r7).
 162          */
 163 #elif defined(CONFIG_ARM_THUMB)
 164         /* Legacy ABI only, possibly thumb mode. */
 165         tst     r8, #PSR_T_BIT                  @ this is SPSR from save_user_regs
 166         addne   scno, r7, #__NR_SYSCALL_BASE    @ put OS number in
 167  USER(  ldreq   scno, [lr, #-4]         )
 168
 169 #else
 170         /* Legacy ABI only. */
 171  USER(  ldr     scno, [lr, #-4]         )       @ get SWI instruction
 172 #endif
 173
 174         adr     tbl, sys_call_table             @ load syscall table pointer
 175
 176 #if defined(CONFIG_OABI_COMPAT)
 177         /*
 178          * If the swi argument is zero, this is an EABI call and we do nothing.
 179          *
 180          * If this is an old ABI call, get the syscall number into scno and
 181          * get the old ABI syscall table address.
 182          */
 183         bics    r10, r10, #0xff000000
 184         eorne   scno, r10, #__NR_OABI_SYSCALL_BASE
 185         ldrne   tbl, =sys_oabi_call_table
 186 #elif !defined(CONFIG_AEABI)
 187         bic     scno, scno, #0xff000000         @ mask off SWI op-code
 188         eor     scno, scno, #__NR_SYSCALL_BASE  @ check OS number
 189 #endif
 190
 191 local_restart:
 192         ldr     r10, [tsk, #TI_FLAGS]           @ check for syscall tracing
 193         stmdb   sp!, {r4, r5}                   @ push fifth and sixth args
 194
 195         tst     r10, #_TIF_SYSCALL_WORK         @ are we tracing syscalls?
 196         bne     __sys_trace
 197
 198         cmp     scno, #NR_syscalls              @ check upper syscall limit
 199         adr     lr, BSYM(ret_fast_syscall)      @ return address
 200         ldrcc   pc, [tbl, scno, lsl #2]         @ call sys_* routine
 201
 202         add     r1, sp, #S_OFF
 203 2:      cmp     scno, #(__ARM_NR_BASE - __NR_SYSCALL_BASE)
 204         eor     r0, scno, #__NR_SYSCALL_BASE    @ put OS number back
 205         bcs     arm_syscall
 206         mov     why, #0                         @ no longer a real syscall
 207         b       sys_ni_syscall                  @ not private func
 208
 209 #if defined(CONFIG_OABI_COMPAT) || !defined(CONFIG_AEABI)
 210         /*
 211          * We failed to handle a fault trying to access the page
 212          * containing the swi instruction, but we're not really in a
 213          * position to return -EFAULT. Instead, return back to the
 214          * instruction and re-enter the user fault handling path trying
 215          * to page it in. This will likely result in sending SEGV to the
 216          * current task.
 217          */
 218 9001:
 219         sub     lr, lr, #4
 220         str     lr, [sp, #S_PC]
 221         b       ret_fast_syscall
 222 #endif
 223 ENDPROC(vector_swi)
 224
 225         /*
 226          * This is the really slow path.  We're going to be doing
 227          * context switches, and waiting for our parent to respond.
 228          */
 229 __sys_trace:
 230         mov     r1, scno
 231         add     r0, sp, #S_OFF
 232         bl      syscall_trace_enter
 233
 234         adr     lr, BSYM(__sys_trace_return)    @ return address
 235         mov     scno, r0                        @ syscall number (possibly new)
 236         add     r1, sp, #S_R0 + S_OFF           @ pointer to regs
 237         cmp     scno, #NR_syscalls              @ check upper syscall limit
 238         ldmccia r1, {r0 - r6}                   @ have to reload r0 - r6
 239         stmccia sp, {r4, r5}                    @ and update the stack args
 240         ldrcc   pc, [tbl, scno, lsl #2]         @ call sys_* routine
 241         cmp     scno, #-1                       @ skip the syscall?
 242         bne     2b
 243         add     sp, sp, #S_OFF                  @ restore stack
 244         b       ret_slow_syscall
 245
 246 __sys_trace_return:
 247         str     r0, [sp, #S_R0 + S_OFF]!        @ save returned r0
 248         mov     r0, sp
 249         bl      syscall_trace_exit
 250         b       ret_slow_syscall
 251
 252         .align  5
 253 #ifdef CONFIG_ALIGNMENT_TRAP
 254         .type   __cr_alignment, #object
 255 __cr_alignment:
 256         .word   cr_alignment
 257 #endif
 258         .ltorg
 259
 260 /*
 261  * This is the syscall table declaration for native ABI syscalls.
 262  * With EABI a couple syscalls are obsolete and defined as sys_ni_syscall.
 263  */
 264 #define ABI(native, compat) native
 265 #ifdef CONFIG_AEABI
 266 #define OBSOLETE(syscall) sys_ni_syscall
 267 #else
 268 #define OBSOLETE(syscall) syscall
 269 #endif
 270
 271         .type   sys_call_table, #object
 272 ENTRY(sys_call_table)
 273 #include "calls.S"
 274 #undef ABI
 275 #undef OBSOLETE
 276
 277 /*============================================================================
 278  * Special system call wrappers
 279  */
 280 @ r0 = syscall number
 281 @ r8 = syscall table
 282 sys_syscall:
 283                 bic     scno, r0, #__NR_OABI_SYSCALL_BASE
 284                 cmp     scno, #__NR_syscall - __NR_SYSCALL_BASE
 285                 cmpne   scno, #NR_syscalls      @ check range
 286                 stmloia sp, {r5, r6}            @ shuffle args
 287                 movlo   r0, r1
 288                 movlo   r1, r2
 289                 movlo   r2, r3
 290                 movlo   r3, r4
 291                 ldrlo   pc, [tbl, scno, lsl #2]
 292                 b       sys_ni_syscall
 293 ENDPROC(sys_syscall)
 294
 295 sys_sigreturn_wrapper:
 296                 add     r0, sp, #S_OFF
 297                 mov     why, #0         @ prevent syscall restart handling
 298                 b       sys_sigreturn
 299 ENDPROC(sys_sigreturn_wrapper)
 300
 301 sys_rt_sigreturn_wrapper:
 302                 add     r0, sp, #S_OFF
 303                 mov     why, #0         @ prevent syscall restart handling
 304                 b       sys_rt_sigreturn
 305 ENDPROC(sys_rt_sigreturn_wrapper)
 306
 307 sys_statfs64_wrapper:
 308                 teq     r1, #88
 309                 moveq   r1, #84
 310                 b       sys_statfs64
 311 ENDPROC(sys_statfs64_wrapper)
 312
 313 sys_fstatfs64_wrapper:
 314                 teq     r1, #88
 315                 moveq   r1, #84
 316                 b       sys_fstatfs64
 317 ENDPROC(sys_fstatfs64_wrapper)
 318
 319 /*
 320  * Note: off_4k (r5) is always units of 4K.  If we can't do the requested
 321  * offset, we return EINVAL.
 322  */
 323 sys_mmap2:
 324 #if PAGE_SHIFT > 12
 325                 tst     r5, #PGOFF_MASK
 326                 moveq   r5, r5, lsr #PAGE_SHIFT - 12
 327                 streq   r5, [sp, #4]
 328                 beq     sys_mmap_pgoff
 329                 mov     r0, #-EINVAL
 330                 ret     lr
 331 #else
 332                 str     r5, [sp, #4]
 333                 b       sys_mmap_pgoff
 334 #endif
 335 ENDPROC(sys_mmap2)
 336
 337 #ifdef CONFIG_OABI_COMPAT
 338
 339 /*
 340  * These are syscalls with argument register differences
 341  */
 342
 343 sys_oabi_pread64:
 344                 stmia   sp, {r3, r4}
 345                 b       sys_pread64
 346 ENDPROC(sys_oabi_pread64)
 347
 348 sys_oabi_pwrite64:
 349                 stmia   sp, {r3, r4}
 350                 b       sys_pwrite64
 351 ENDPROC(sys_oabi_pwrite64)
 352
 353 sys_oabi_truncate64:
 354                 mov     r3, r2
 355                 mov     r2, r1
 356                 b       sys_truncate64
 357 ENDPROC(sys_oabi_truncate64)
 358
 359 sys_oabi_ftruncate64:
 360                 mov     r3, r2
 361                 mov     r2, r1
 362                 b       sys_ftruncate64
 363 ENDPROC(sys_oabi_ftruncate64)
 364
 365 sys_oabi_readahead:
 366                 str     r3, [sp]
 367                 mov     r3, r2
 368                 mov     r2, r1
 369                 b       sys_readahead
 370 ENDPROC(sys_oabi_readahead)
 371
 372 /*
 373  * Let's declare a second syscall table for old ABI binaries
 374  * using the compatibility syscall entries.
 375  */
 376 #define ABI(native, compat) compat
 377 #define OBSOLETE(syscall) syscall
 378
 379         .type   sys_oabi_call_table, #object
 380 ENTRY(sys_oabi_call_table)
 381 #include "calls.S"
 382 #undef ABI
 383 #undef OBSOLETE
 384
 385 #endif
 386