arch/arm/kernel/entry-common.S

   1 /*
   2  *  linux/arch/arm/kernel/entry-common.S
   3  *
   4  *  Copyright (C) 2000 Russell King
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  */
  10 #include <linux/config.h>
  11
  12 #include <asm/unistd.h>
  13
  14 #include "entry-header.S"
  15
  16
  17         .align  5
  18 /*
  19  * This is the fast syscall return path.  We do as little as
  20  * possible here, and this includes saving r0 back into the SVC
  21  * stack.
  22  */
  23 ret_fast_syscall:
  24         disable_irq                             @ disable interrupts
  25         ldr     r1, [tsk, #TI_FLAGS]
  26         tst     r1, #_TIF_WORK_MASK
  27         bne     fast_work_pending
  28
  29         @ fast_restore_user_regs
  30         ldr     r1, [sp, #S_OFF + S_PSR]        @ get calling cpsr
  31         ldr     lr, [sp, #S_OFF + S_PC]!        @ get pc
  32         msr     spsr_cxsf, r1                   @ save in spsr_svc
  33         ldmdb   sp, {r1 - lr}^                  @ get calling r1 - lr
  34         mov     r0, r0
  35         add     sp, sp, #S_FRAME_SIZE - S_PC
  36         movs    pc, lr                          @ return & move spsr_svc into cpsr
  37
  38 /*
  39  * Ok, we need to do extra processing, enter the slow path.
  40  */
  41 fast_work_pending:
  42         str     r0, [sp, #S_R0+S_OFF]!          @ returned r0
  43 work_pending:
  44         tst     r1, #_TIF_NEED_RESCHED
  45         bne     work_resched
  46         tst     r1, #_TIF_NOTIFY_RESUME | _TIF_SIGPENDING
  47         beq     no_work_pending
  48         mov     r0, sp                          @ 'regs'
  49         mov     r2, why                         @ 'syscall'
  50         bl      do_notify_resume
  51         b       ret_slow_syscall                @ Check work again
  52
  53 work_resched:
  54         bl      schedule
  55 /*
  56  * "slow" syscall return path.  "why" tells us if this was a real syscall.
  57  */
  58 ENTRY(ret_to_user)
  59 ret_slow_syscall:
  60         disable_irq                             @ disable interrupts
  61         ldr     r1, [tsk, #TI_FLAGS]
  62         tst     r1, #_TIF_WORK_MASK
  63         bne     work_pending
  64 no_work_pending:
  65         @ slow_restore_user_regs
  66         ldr     r1, [sp, #S_PSR]                @ get calling cpsr
  67         ldr     lr, [sp, #S_PC]!                @ get pc
  68         msr     spsr_cxsf, r1                   @ save in spsr_svc
  69         ldmdb   sp, {r0 - lr}^                  @ get calling r1 - lr
  70         mov     r0, r0
  71         add     sp, sp, #S_FRAME_SIZE - S_PC
  72         movs    pc, lr                          @ return & move spsr_svc into cpsr
  73
  74 /*
  75  * This is how we return from a fork.
  76  */
  77 ENTRY(ret_from_fork)
  78         bl      schedule_tail
  79         get_thread_info tsk
  80         ldr     r1, [tsk, #TI_FLAGS]            @ check for syscall tracing
  81         mov     why, #1
  82         tst     r1, #_TIF_SYSCALL_TRACE         @ are we tracing syscalls?
  83         beq     ret_slow_syscall
  84         mov     r1, sp
  85         mov     r0, #1                          @ trace exit [IP = 1]
  86         bl      syscall_trace
  87         b       ret_slow_syscall
  88
  89
  90 #include "calls.S"
  91
  92 /*=============================================================================
  93  * SWI handler
  94  *-----------------------------------------------------------------------------
  95  */
  96
  97         /* If we're optimising for StrongARM the resulting code won't
  98            run on an ARM7 and we can save a couple of instructions.
  99                                                                 --pb */
 100 #ifdef CONFIG_CPU_ARM710
 101 #define A710(code...) code
 102 .Larm710bug:
 103         ldmia   sp, {r0 - lr}^                  @ Get calling r0 - lr
 104         mov     r0, r0
 105         add     sp, sp, #S_FRAME_SIZE
 106         subs    pc, lr, #4
 107 #else
 108 #define A710(code...)
 109 #endif
 110
 111         .align  5
 112 ENTRY(vector_swi)
 113         sub     sp, sp, #S_FRAME_SIZE
 114         stmia   sp, {r0 - r12}                  @ Calling r0 - r12
 115         add     r8, sp, #S_PC
 116         stmdb   r8, {sp, lr}^                   @ Calling sp, lr
 117         mrs     r8, spsr                        @ called from non-FIQ mode, so ok.
 118         str     lr, [sp, #S_PC]                 @ Save calling PC
 119         str     r8, [sp, #S_PSR]                @ Save CPSR
 120         str     r0, [sp, #S_OLD_R0]             @ Save OLD_R0
 121         zero_fp
 122
 123         /*
 124          * Get the system call number.
 125          */
 126
 127 #if defined(CONFIG_OABI_COMPAT)
 128
 129         /*
 130          * If we have CONFIG_OABI_COMPAT then we need to look at the swi
 131          * value to determine if it is an EABI or an old ABI call.
 132          */
 133 #ifdef CONFIG_ARM_THUMB
 134         tst     r8, #PSR_T_BIT
 135         movne   r10, #0                         @ no thumb OABI emulation
 136         ldreq   r10, [lr, #-4]                  @ get SWI instruction
 137 #else
 138         ldr     r10, [lr, #-4]                  @ get SWI instruction
 139   A710( and     ip, r10, #0x0f000000            @ check for SWI         )
 140   A710( teq     ip, #0x0f000000                                         )
 141   A710( bne     .Larm710bug                                             )
 142 #endif
 143
 144 #elif defined(CONFIG_AEABI)
 145
 146         /*
 147          * Pure EABI user space always put syscall number into scno (r7).
 148          */
 149   A710( ldr     ip, [lr, #-4]                   @ get SWI instruction   )
 150   A710( and     ip, ip, #0x0f000000             @ check for SWI         )
 151   A710( teq     ip, #0x0f000000                                         )
 152   A710( bne     .Larm710bug                                             )
 153
 154 #elif defined(CONFIG_ARM_THUMB)
 155
 156         /* Legacy ABI only, possibly thumb mode. */
 157         tst     r8, #PSR_T_BIT                  @ this is SPSR from save_user_regs
 158         addne   scno, r7, #__NR_SYSCALL_BASE    @ put OS number in
 159         ldreq   scno, [lr, #-4]
 160
 161 #else
 162
 163         /* Legacy ABI only. */
 164         ldr     scno, [lr, #-4]                 @ get SWI instruction
 165   A710( and     ip, scno, #0x0f000000           @ check for SWI         )
 166   A710( teq     ip, #0x0f000000                                         )
 167   A710( bne     .Larm710bug                                             )
 168
 169 #endif
 170
 171 #ifdef CONFIG_ALIGNMENT_TRAP
 172         ldr     ip, __cr_alignment
 173         ldr     ip, [ip]
 174         mcr     p15, 0, ip, c1, c0              @ update control register
 175 #endif
 176         enable_irq
 177
 178         get_thread_info tsk
 179         adr     tbl, sys_call_table             @ load syscall table pointer
 180         ldr     ip, [tsk, #TI_FLAGS]            @ check for syscall tracing
 181
 182 #if defined(CONFIG_OABI_COMPAT)
 183         /*
 184          * If the swi argument is zero, this is an EABI call and we do nothing.
 185          *
 186          * If this is an old ABI call, get the syscall number into scno and
 187          * get the old ABI syscall table address.
 188          */
 189         bics    r10, r10, #0xff000000
 190         eorne   scno, r10, #__NR_OABI_SYSCALL_BASE
 191         ldrne   tbl, =sys_oabi_call_table
 192 #elif !defined(CONFIG_AEABI)
 193         bic     scno, scno, #0xff000000         @ mask off SWI op-code
 194         eor     scno, scno, #__NR_SYSCALL_BASE  @ check OS number
 195 #endif
 196
 197         stmdb   sp!, {r4, r5}                   @ push fifth and sixth args
 198         tst     ip, #_TIF_SYSCALL_TRACE         @ are we tracing syscalls?
 199         bne     __sys_trace
 200
 201         cmp     scno, #NR_syscalls              @ check upper syscall limit
 202         adr     lr, ret_fast_syscall            @ return address
 203         ldrcc   pc, [tbl, scno, lsl #2]         @ call sys_* routine
 204
 205         add     r1, sp, #S_OFF
 206 2:      mov     why, #0                         @ no longer a real syscall
 207         cmp     scno, #(__ARM_NR_BASE - __NR_SYSCALL_BASE)
 208         eor     r0, scno, #__NR_SYSCALL_BASE    @ put OS number back
 209         bcs     arm_syscall
 210         b       sys_ni_syscall                  @ not private func
 211
 212         /*
 213          * This is the really slow path.  We're going to be doing
 214          * context switches, and waiting for our parent to respond.
 215          */
 216 __sys_trace:
 217         mov     r2, scno
 218         add     r1, sp, #S_OFF
 219         mov     r0, #0                          @ trace entry [IP = 0]
 220         bl      syscall_trace
 221
 222         adr     lr, __sys_trace_return          @ return address
 223         mov     scno, r0                        @ syscall number (possibly new)
 224         add     r1, sp, #S_R0 + S_OFF           @ pointer to regs
 225         cmp     scno, #NR_syscalls              @ check upper syscall limit
 226         ldmccia r1, {r0 - r3}                   @ have to reload r0 - r3
 227         ldrcc   pc, [tbl, scno, lsl #2]         @ call sys_* routine
 228         b       2b
 229
 230 __sys_trace_return:
 231         str     r0, [sp, #S_R0 + S_OFF]!        @ save returned r0
 232         mov     r2, scno
 233         mov     r1, sp
 234         mov     r0, #1                          @ trace exit [IP = 1]
 235         bl      syscall_trace
 236         b       ret_slow_syscall
 237
 238         .align  5
 239 #ifdef CONFIG_ALIGNMENT_TRAP
 240         .type   __cr_alignment, #object
 241 __cr_alignment:
 242         .word   cr_alignment
 243 #endif
 244         .ltorg
 245
 246 /*
 247  * This is the syscall table declaration for native ABI syscalls.
 248  * With EABI a couple syscalls are obsolete and defined as sys_ni_syscall.
 249  */
 250 #define ABI(native, compat) native
 251 #ifdef CONFIG_AEABI
 252 #define OBSOLETE(syscall) sys_ni_syscall
 253 #else
 254 #define OBSOLETE(syscall) syscall
 255 #endif
 256
 257         .type   sys_call_table, #object
 258 ENTRY(sys_call_table)
 259 #include "calls.S"
 260 #undef ABI
 261 #undef OBSOLETE
 262
 263 /*============================================================================
 264  * Special system call wrappers
 265  */
 266 @ r0 = syscall number
 267 @ r8 = syscall table
 268                 .type   sys_syscall, #function
 269 sys_syscall:
 270                 eor     scno, r0, #__NR_OABI_SYSCALL_BASE
 271                 cmp     scno, #__NR_syscall - __NR_SYSCALL_BASE
 272                 cmpne   scno, #NR_syscalls      @ check range
 273                 stmloia sp, {r5, r6}            @ shuffle args
 274                 movlo   r0, r1
 275                 movlo   r1, r2
 276                 movlo   r2, r3
 277                 movlo   r3, r4
 278                 ldrlo   pc, [tbl, scno, lsl #2]
 279                 b       sys_ni_syscall
 280
 281 sys_fork_wrapper:
 282                 add     r0, sp, #S_OFF
 283                 b       sys_fork
 284
 285 sys_vfork_wrapper:
 286                 add     r0, sp, #S_OFF
 287                 b       sys_vfork
 288
 289 sys_execve_wrapper:
 290                 add     r3, sp, #S_OFF
 291                 b       sys_execve
 292
 293 sys_clone_wrapper:
 294                 add     ip, sp, #S_OFF
 295                 str     ip, [sp, #4]
 296                 b       sys_clone
 297
 298 sys_sigsuspend_wrapper:
 299                 add     r3, sp, #S_OFF
 300                 b       sys_sigsuspend
 301
 302 sys_rt_sigsuspend_wrapper:
 303                 add     r2, sp, #S_OFF
 304                 b       sys_rt_sigsuspend
 305
 306 sys_sigreturn_wrapper:
 307                 add     r0, sp, #S_OFF
 308                 b       sys_sigreturn
 309
 310 sys_rt_sigreturn_wrapper:
 311                 add     r0, sp, #S_OFF
 312                 b       sys_rt_sigreturn
 313
 314 sys_sigaltstack_wrapper:
 315                 ldr     r2, [sp, #S_OFF + S_SP]
 316                 b       do_sigaltstack
 317
 318 sys_statfs64_wrapper:
 319                 teq     r1, #88
 320                 moveq   r1, #84
 321                 b       sys_statfs64
 322
 323 sys_fstatfs64_wrapper:
 324                 teq     r1, #88
 325                 moveq   r1, #84
 326                 b       sys_fstatfs64
 327
 328 /*
 329  * Note: off_4k (r5) is always units of 4K.  If we can't do the requested
 330  * offset, we return EINVAL.
 331  */
 332 sys_mmap2:
 333 #if PAGE_SHIFT > 12
 334                 tst     r5, #PGOFF_MASK
 335                 moveq   r5, r5, lsr #PAGE_SHIFT - 12
 336                 streq   r5, [sp, #4]
 337                 beq     do_mmap2
 338                 mov     r0, #-EINVAL
 339                 RETINSTR(mov,pc, lr)
 340 #else
 341                 str     r5, [sp, #4]
 342                 b       do_mmap2
 343 #endif
 344
 345 #ifdef CONFIG_OABI_COMPAT
 346
 347 /*
 348  * These are syscalls with argument register differences
 349  */
 350
 351 sys_oabi_pread64:
 352                 stmia   sp, {r3, r4}
 353                 b       sys_pread64
 354
 355 sys_oabi_pwrite64:
 356                 stmia   sp, {r3, r4}
 357                 b       sys_pwrite64
 358
 359 sys_oabi_truncate64:
 360                 mov     r3, r2
 361                 mov     r2, r1
 362                 b       sys_truncate64
 363
 364 sys_oabi_ftruncate64:
 365                 mov     r3, r2
 366                 mov     r2, r1
 367                 b       sys_ftruncate64
 368
 369 sys_oabi_readahead:
 370                 str     r3, [sp]
 371                 mov     r3, r2
 372                 mov     r2, r1
 373                 b       sys_readahead
 374
 375 /*
 376  * Let's declare a second syscall table for old ABI binaries
 377  * using the compatibility syscall entries.
 378  */
 379 #define ABI(native, compat) compat
 380 #define OBSOLETE(syscall) syscall
 381
 382         .type   sys_oabi_call_table, #object
 383 ENTRY(sys_oabi_call_table)
 384 #include "calls.S"
 385 #undef ABI
 386 #undef OBSOLETE
 387
 388 #endif
 389