arch/arm/boot/compressed/vmlinux.lds.S

   1 /*
   2  *  Copyright (C) 2000 Russell King
   3  *
   4  * This program is free software; you can redistribute it and/or modify
   5  * it under the terms of the GNU General Public License version 2 as
   6  * published by the Free Software Foundation.
   7  */
   8
   9 #ifdef CONFIG_CPU_ENDIAN_BE8
  10 #define ZIMAGE_MAGIC(x) ( (((x) >> 24) & 0x000000ff) | \
  11                           (((x) >>  8) & 0x0000ff00) | \
  12                           (((x) <<  8) & 0x00ff0000) | \
  13                           (((x) << 24) & 0xff000000) )
  14 #else
  15 #define ZIMAGE_MAGIC(x) (x)
  16 #endif
  17
  18 OUTPUT_ARCH(arm)
  19 ENTRY(_start)
  20 SECTIONS
  21 {
  22   /DISCARD/ : {
  23     *(.ARM.exidx*)
  24     *(.ARM.extab*)
  25     /*
  26      * Discard any r/w data - this produces a link error if we have any,
  27      * which is required for PIC decompression.  Local data generates
  28      * GOTOFF relocations, which prevents it being relocated independently
  29      * of the text/got segments.
  30      */
  31     *(.data)
  32   }
  33
  34   . = TEXT_START;
  35   _text = .;
  36
  37   .text : {
  38     _start = .;
  39     *(.start)
  40     *(.text)
  41     *(.text.*)
  42     *(.fixup)
  43     *(.gnu.warning)
  44     *(.glue_7t)
  45     *(.glue_7)
  46   }
  47   .table : ALIGN(4) {
  48     _table_start = .;
  49     LONG(ZIMAGE_MAGIC(2))
  50     LONG(ZIMAGE_MAGIC(0x5a534c4b))
  51     LONG(ZIMAGE_MAGIC(__piggy_size_addr - _start))
  52     LONG(ZIMAGE_MAGIC(_kernel_bss_size))
  53     LONG(0)
  54     _table_end = .;
  55   }
  56   .rodata : {
  57     *(.rodata)
  58     *(.rodata.*)
  59   }
  60   .piggydata : {
  61     *(.piggydata)
  62     __piggy_size_addr = . - 4;
  63   }
  64
  65   . = ALIGN(4);
  66   _etext = .;
  67
  68   .got.plt              : { *(.got.plt) }
  69   _got_start = .;
  70   .got                  : { *(.got) }
  71   _got_end = .;
  72
  73   /* ensure the zImage file size is always a multiple of 64 bits */
  74   /* (without a dummy byte, ld just ignores the empty section) */
  75   .pad                  : { BYTE(0); . = ALIGN(8); }
  76
  77 #ifdef CONFIG_EFI_STUB
  78   .data : ALIGN(4096) {
  79     __pecoff_data_start = .;
  80     /*
  81      * The EFI stub always executes from RAM, and runs strictly before the
  82      * decompressor, so we can make an exception for its r/w data, and keep it
  83      */
  84     *(.data.efistub)
  85     __pecoff_data_end = .;
  86
  87     /*
  88      * PE/COFF mandates a file size which is a multiple of 512 bytes if the
  89      * section size equals or exceeds 4 KB
  90      */
  91     . = ALIGN(512);
  92   }
  93   __pecoff_data_rawsize = . - ADDR(.data);
  94 #endif
  95
  96   _edata = .;
  97
  98   /*
  99    * The image_end section appears after any additional loadable sections
 100    * that the linker may decide to insert in the binary image.  Having
 101    * this symbol allows further debug in the near future.
 102    */
 103   .image_end (NOLOAD) : {
 104     _edata_real = .;
 105   }
 106
 107   _magic_sig = ZIMAGE_MAGIC(0x016f2818);
 108   _magic_start = ZIMAGE_MAGIC(_start);
 109   _magic_end = ZIMAGE_MAGIC(_edata);
 110   _magic_table = ZIMAGE_MAGIC(_table_start - _start);
 111
 112   . = BSS_START;
 113   __bss_start = .;
 114   .bss                  : { *(.bss) }
 115   _end = .;
 116
 117   . = ALIGN(8);         /* the stack must be 64-bit aligned */
 118   .stack                : { *(.stack) }
 119
 120   PROVIDE(__pecoff_data_size = ALIGN(512) - ADDR(.data));
 121   PROVIDE(__pecoff_end = ALIGN(512));
 122
 123   .stab 0               : { *(.stab) }
 124   .stabstr 0            : { *(.stabstr) }
 125   .stab.excl 0          : { *(.stab.excl) }
 126   .stab.exclstr 0       : { *(.stab.exclstr) }
 127   .stab.index 0         : { *(.stab.index) }
 128   .stab.indexstr 0      : { *(.stab.indexstr) }
 129   .comment 0            : { *(.comment) }
 130 }