configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT()
   4 AC_CONFIG_SRCDIR([byteorder.h])
   5 AC_CONFIG_HEADER(config.h)
   6 AC_PREREQ(2.52)
   7
   8 RSYNC_VERSION=2.5.1pre2
   9 AC_SUBST(RSYNC_VERSION)
  10 AC_MSG_NOTICE([Configuring rsync $RSYNC_VERSION])
  11
  12 AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$RSYNC_VERSION"], [rsync release version])
  13
  14 LDFLAGS=${LDFLAGS-""}
  15
  16 AC_CANONICAL_TARGET([])
  17
  18 dnl Checks for programs.
  19 AC_PROG_CC
  20 AC_PROG_CPP
  21 AC_PROG_INSTALL
  22 AC_PROG_CC_STDC
  23 AC_SUBST(SHELL)
  24
  25 if test "$xac_cv_prog_cc_stdc" = xno
  26 then
  27         AC_MSG_WARN([rsync requires an ANSI C compiler and you don't seem to have one])
  28 fi
  29
  30 # compile with optimisation and without debugging by default, unless
  31 # --debug is given.  We must decide this before testing the compiler.
  32
  33 AC_MSG_CHECKING([whether to include debugging symbols])
  34 AC_ARG_ENABLE(debug,
  35         AC_HELP_STRING([--enable-debug],
  36                 [including debugging symbols and features (default yes)]),
  37                 [], [])
  38
  39 if test x"$enable_debug" = x"no"
  40 then
  41     AC_MSG_RESULT(no)
  42     CFLAGS=${CFLAGS-"-O"}
  43 else
  44     AC_MSG_RESULT([yes])
  45     # leave CFLAGS alone; AC_PROG_CC will try to include -g if it can
  46     AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  47     dnl CFLAGS=${CFLAGS-"-g"}
  48 fi
  49
  50 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
  51
  52 AC_ARG_WITH(included-popt,
  53         [  --with-included-popt    use bundled popt library, not from system])
  54
  55 AC_ARG_WITH(rsync-path,
  56         [  --with-rsync-path=PATH  set default --rsync-path to PATH (default: \"rsync\")],
  57         [ RSYNC_PATH="$with_rsync_path" ],
  58         [ RSYNC_PATH="rsync" ])
  59 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [ ])
  60
  61 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
  62 AC_DEFINE_UNQUOTED(HAVE_REMSH, $HAVE_REMSH, [ ])
  63
  64
  65 # arrgh. libc in the current debian stable screws up the largefile
  66 # stuff, getting byte range locking wrong
  67 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
  68 AC_TRY_RUN([
  69 #define _FILE_OFFSET_BITS 64
  70 #include <stdio.h>
  71 #include <fcntl.h>
  72 #include <sys/types.h>
  73 #include <sys/wait.h>
  74
  75 int main(void)
  76 {
  77         struct flock lock;
  78         int status;
  79         int fd = open("conftest.dat", O_CREAT|O_RDWR, 0600);
  80         lock.l_type = F_WRLCK;
  81         lock.l_whence = SEEK_SET;
  82         lock.l_start = 0;
  83         lock.l_len = 1;
  84         lock.l_pid = 0;
  85
  86         fcntl(fd,F_SETLK,&lock);
  87         if (fork() == 0) {
  88                 lock.l_start = 1;
  89                 exit(fcntl(fd,F_SETLK,&lock) == 0);
  90         }
  91         wait(&status);
  92         unlink("conftest.dat");
  93         exit(WEXITSTATUS(status));
  94 }
  95 ],
  96 rsync_cv_HAVE_BROKEN_LARGEFILE=yes,rsync_cv_HAVE_BROKEN_LARGEFILE=no,rsync_cv_HAVE_BROKEN_LARGEFILE=cross)])
  97 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
  98    AC_SYS_LARGEFILE
  99 fi
 100
 101 ipv6type=unknown
 102 ipv6lib=none
 103 ipv6trylibc=yes
 104
 105 AC_ARG_ENABLE(ipv6,
 106         AC_HELP_STRING([--disable-ipv6], [don't even try to use IPv6]))
 107
 108 if test "x$enable_ipv6" != xno
 109 then
 110         AC_MSG_CHECKING([ipv6 stack type])
 111         for i in inria kame linux-glibc linux-inet6 toshiba v6d zeta; do
 112                 case $i in
 113                 inria)
 114                         # http://www.kame.net/
 115                         AC_EGREP_CPP(yes, [
 116 #include <netinet/in.h>
 117 #ifdef IPV6_INRIA_VERSION
 118 yes
 119 #endif],
 120                                 [ipv6type=$i;
 121                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 122                                 ])
 123                         ;;
 124                 kame)
 125                         # http://www.kame.net/
 126                         AC_EGREP_CPP(yes, [
 127 #include <netinet/in.h>
 128 #ifdef __KAME__
 129 yes
 130 #endif],
 131                                 [ipv6type=$i;
 132                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 133                         ;;
 134                 linux-glibc)
 135                         # http://www.v6.linux.or.jp/
 136                         AC_EGREP_CPP(yes, [
 137 #include <features.h>
 138 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 139 yes
 140 #endif],
 141                                 [ipv6type=$i;
 142 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 143                         ;;
 144                 linux-inet6)
 145                         # http://www.v6.linux.or.jp/
 146                         if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
 147                                 ipv6type=$i
 148                                 ipv6lib=inet6
 149                                 ipv6libdir=/usr/inet6/lib
 150                                 ipv6trylibc=yes;
 151                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 152                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 153                         fi
 154                         ;;
 155                 toshiba)
 156                         AC_EGREP_CPP(yes, [
 157 #include <sys/param.h>
 158 #ifdef _TOSHIBA_INET6
 159 yes
 160 #endif],
 161                                 [ipv6type=$i;
 162                                 ipv6lib=inet6;
 163                                 ipv6libdir=/usr/local/v6/lib;
 164                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 165                         ;;
 166                 v6d)
 167                         AC_EGREP_CPP(yes, [
 168 #include </usr/local/v6/include/sys/v6config.h>
 169 #ifdef __V6D__
 170 yes
 171 #endif],
 172                                 [ipv6type=$i;
 173                                 ipv6lib=v6;
 174                                 ipv6libdir=/usr/local/v6/lib;
 175                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 176                         ;;
 177                 zeta)
 178                         AC_EGREP_CPP(yes, [
 179 #include <sys/param.h>
 180 #ifdef _ZETA_MINAMI_INET6
 181 yes
 182 #endif],
 183                                 [ipv6type=$i;
 184                                 ipv6lib=inet6;
 185                                 ipv6libdir=/usr/local/v6/lib;
 186                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 187                         ;;
 188                 esac
 189                 if test "$ipv6type" != "unknown"; then
 190                         break
 191                 fi
 192         done
 193         AC_MSG_RESULT($ipv6type)
 194
 195         AC_SEARCH_LIBS(getaddrinfo, inet6)
 196 fi
 197
 198 AC_C_BIGENDIAN
 199 AC_HEADER_DIRENT
 200 AC_HEADER_TIME
 201 AC_HEADER_SYS_WAIT
 202 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h unistd.h utime.h grp.h)
 203 AC_CHECK_HEADERS(compat.h sys/param.h ctype.h sys/wait.h sys/ioctl.h)
 204 AC_CHECK_HEADERS(sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h)
 205 AC_CHECK_HEADERS(glob.h alloca.h mcheck.h sys/sysctl.h arpa/inet.h arpa/nameser.h)
 206 AC_CHECK_HEADERS(netdb.h)
 207
 208 AC_CHECK_SIZEOF(int)
 209 AC_CHECK_SIZEOF(long)
 210 AC_CHECK_SIZEOF(short)
 211
 212 AC_C_INLINE
 213
 214 AC_TYPE_SIGNAL
 215 AC_TYPE_UID_T
 216 AC_TYPE_MODE_T
 217 AC_TYPE_OFF_T
 218 AC_TYPE_SIZE_T
 219 AC_TYPE_PID_T
 220 AC_TYPE_GETGROUPS
 221 AC_CHECK_MEMBERS([struct stat.st_rdev])
 222
 223 AC_CHECK_TYPE([ino_t], [unsigned])
 224 TYPE_SOCKLEN_T
 225
 226 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 227     AC_TRY_COMPILE([#include <errno.h>],[int i = errno],
 228         rsync_cv_errno=yes,rsync_cv_have_errno_decl=no)])
 229 if test x"$rsync_cv_errno" = x"yes"; then
 230    AC_DEFINE(HAVE_ERRNO_DECL, 1, [ ])
 231 fi
 232
 233 # The following test taken from the cvs sources
 234 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 235 # These need checks to be before checks for any other functions that
 236 #    might be in the same libraries.
 237 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 238 # libsocket.so which has a bad implementation of gethostbyname (it
 239 # only looks in /etc/hosts), so we only look for -lsocket if we need
 240 # it.
 241 AC_CHECK_FUNCS(connect)
 242 if test x"$ac_cv_func_connect" = x"no"; then
 243     case "$LIBS" in
 244     *-lnsl*) ;;
 245     *) AC_CHECK_LIB(nsl_s, printf) ;;
 246     esac
 247     case "$LIBS" in
 248     *-lnsl*) ;;
 249     *) AC_CHECK_LIB(nsl, printf) ;;
 250     esac
 251     case "$LIBS" in
 252     *-lsocket*) ;;
 253     *) AC_CHECK_LIB(socket, connect) ;;
 254     esac
 255     case "$LIBS" in
 256     *-linet*) ;;
 257     *) AC_CHECK_LIB(inet, connect) ;;
 258     esac
 259     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 260     dnl has been cached.
 261     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 262        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 263         # ac_cv_func_connect=yes
 264         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 265         AC_DEFINE(HAVE_CONNECT, 1, [ ])
 266     fi
 267 fi
 268
 269 AC_CHECK_LIB(resolv, inet_ntop)
 270
 271 AC_MSG_NOTICE([Looking in libraries: $LIBS])
 272
 273 AC_CHECK_FUNC(inet_ntop, , AC_LIBOBJ(lib/inet_ntop))
 274 AC_CHECK_FUNC(inet_pton, , AC_LIBOBJ(lib/inet_pton))
 275
 276 AC_CHECK_FUNC(getaddrinfo, , AC_LIBOBJ(lib/getaddrinfo))
 277 AC_CHECK_FUNC(getnameinfo, , AC_LIBOBJ(lib/getnameinfo))
 278
 279 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 280                 [ AC_DEFINE(HAVE_SOCKADDR_LEN) ],
 281                 [],
 282                 [
 283 #include <sys/types.h>
 284 #include <sys/socket.h>
 285 ])
 286
 287 AC_MSG_CHECKING(struct sockaddr_storage)
 288 AC_TRY_COMPILE([#include <sys/types.h>
 289 #include <sys/socket.h>],
 290 [struct sockaddr_storage x;],
 291         AC_MSG_RESULT(yes)
 292         AC_DEFINE(HAVE_SOCKADDR_STORAGE),
 293         AC_MSG_RESULT(no))
 294
 295 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 296 #
 297 AC_CHECK_FUNCS(strcasecmp)
 298 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 299     AC_CHECK_LIB(resolv, strcasecmp)
 300 fi
 301
 302 dnl At the moment we don't test for a broken memcmp(), because all we
 303 dnl need to do is test for equality, not comparison, and it seems that
 304 dnl every platform has a memcmp that can do at least that.
 305 dnl AC_FUNC_MEMCMP
 306
 307 AC_FUNC_UTIME_NULL
 308 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup strerror chown chmod mknod)
 309 AC_CHECK_FUNCS(fchmod fstat strchr readlink link utime utimes strftime)
 310 AC_CHECK_FUNCS(memmove lchown vsnprintf snprintf asprintf setsid glob strpbrk)
 311 AC_CHECK_FUNCS(strlcat strlcpy mtrace)
 312
 313 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
 314 AC_TRY_RUN([
 315 #include <sys/types.h>
 316 #include <sys/socket.h>
 317
 318 main() {
 319        int fd[2];
 320        exit((socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1);
 321 }],
 322 rsync_cv_HAVE_SOCKETPAIR=yes,rsync_cv_HAVE_SOCKETPAIR=no,rsync_cv_HAVE_SOCKETPAIR=cross)])
 323 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
 324     AC_DEFINE(HAVE_SOCKETPAIR, 1, [ ])
 325 fi
 326
 327 AC_CACHE_CHECK([for working fnmatch],rsync_cv_HAVE_FNMATCH,[
 328 AC_TRY_RUN([#include <fnmatch.h>
 329 main() { exit((fnmatch("*.o", "x.o", FNM_PATHNAME) == 0 &&
 330                fnmatch("a/b/*", "a/b/c/d", FNM_PATHNAME) != 0) ? 0: 1); }],
 331 rsync_cv_HAVE_FNMATCH=yes,rsync_cv_HAVE_FNMATCH=no,rsync_cv_HAVE_FNMATCH=cross)])
 332 if test x"$rsync_cv_HAVE_FNMATCH" = x"yes"; then
 333     AC_DEFINE(HAVE_FNMATCH, 1, [ ])
 334 fi
 335
 336 if test x"$with_included_popt" != x"yes"
 337 then
 338     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
 339 fi
 340
 341 AC_MSG_CHECKING([whether to use included libpopt])
 342 if test x"$with_included_popt" = x"yes"
 343 then
 344     AC_MSG_RESULT($srcdir/popt)
 345     BUILD_POPT='$(popt_OBJS)'
 346     CFLAGS="$CFLAGS -I$srcdir/popt"
 347 else
 348     AC_MSG_RESULT(no)
 349 fi
 350
 351 AC_CACHE_CHECK([for long long],rsync_cv_HAVE_LONGLONG,[
 352 AC_TRY_RUN([#include <stdio.h>
 353 main() { long long x = 1000000; x *= x; exit(((x/1000000) == 1000000)? 0: 1); }],
 354 rsync_cv_HAVE_LONGLONG=yes,rsync_cv_HAVE_LONGLONG=no,rsync_cv_HAVE_LONGLONG=cross)])
 355 if test x"$rsync_cv_HAVE_LONGLONG" = x"yes"; then
 356     AC_DEFINE(HAVE_LONGLONG, 1, [ ])
 357 fi
 358
 359 AC_CACHE_CHECK([for off64_t],rsync_cv_HAVE_OFF64_T,[
 360 AC_TRY_RUN([#include <stdio.h>
 361 #include <sys/stat.h>
 362 main() { struct stat64 st; off64_t s; if (sizeof(off_t) == sizeof(off64_t)) exit(1); exit((lstat64("/dev/null", &st)==0)?0:1); }],
 363 rsync_cv_HAVE_OFF64_T=yes,rsync_cv_HAVE_OFF64_T=no,rsync_cv_HAVE_OFF64_T=cross)])
 364 if test x"$rsync_cv_HAVE_OFF64_T" = x"yes"; then
 365     AC_DEFINE(HAVE_OFF64_T, 1, [ ])
 366 fi
 367
 368 AC_CACHE_CHECK([for short ino_t],rsync_cv_HAVE_SHORT_INO_T,[
 369 AC_TRY_RUN([#include <stdio.h>
 370 #include <sys/types.h>
 371 #include <sys/stat.h>
 372 main() { if (sizeof(ino_t) < sizeof(unsigned int)) return 0; return 1; }],
 373 rsync_cv_HAVE_SHORT_INO_T=yes,rsync_cv_HAVE_SHORT_INO_T=no,rsync_cv_HAVE_SHORT_INO_T=cross)])
 374 if test x"$rsync_cv_HAVE_SHORT_INO_T" = x"yes"; then
 375     AC_DEFINE(HAVE_SHORT_INO_T, 1, [ ])
 376 fi
 377
 378 AC_CACHE_CHECK([for unsigned char],rsync_cv_HAVE_UNSIGNED_CHAR,[
 379 AC_TRY_RUN([#include <stdio.h>
 380 main() { char c; c=250; exit((c > 0)?0:1); }],
 381 rsync_cv_HAVE_UNSIGNED_CHAR=yes,rsync_cv_HAVE_UNSIGNED_CHAR=no,rsync_cv_HAVE_UNSIGNED_CHAR=cross)])
 382 if test x"$rsync_cv_HAVE_UNSIGNED_CHAR" = x"yes"; then
 383     AC_DEFINE(HAVE_UNSIGNED_CHAR, 1, [ ])
 384 fi
 385
 386 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
 387 AC_TRY_RUN([#include <sys/types.h>
 388 #include <dirent.h>
 389 main() { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
 390 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
 391 di->d_name[0] == 0) exit(0); exit(1);} ],
 392 rsync_cv_HAVE_BROKEN_READDIR=yes,rsync_cv_HAVE_BROKEN_READDIR=no,rsync_cv_HAVE_BROKEN_READDIR=cross)])
 393 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
 394     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [ ])
 395 fi
 396
 397 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_UTIMBUF,[
 398 AC_TRY_COMPILE([#include <sys/types.h>
 399 #include <utime.h>],
 400 [struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; exit(utime("foo.c",&tbuf));],
 401 rsync_cv_HAVE_UTIMBUF=yes,rsync_cv_HAVE_UTIMBUF=no,rsync_cv_HAVE_UTIMBUF=cross)])
 402 if test x"$rsync_cv_HAVE_UTIMBUF" = x"yes"; then
 403     AC_DEFINE(HAVE_UTIMBUF, 1, [ ])
 404 fi
 405
 406 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
 407 AC_TRY_RUN([
 408 #include <sys/time.h>
 409 #include <unistd.h>
 410 main() { struct timeval tv; exit(gettimeofday(&tv, NULL));}],
 411            rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes,rsync_cv_HAVE_GETTIMEOFDAY_TZ=no,rsync_cv_HAVE_GETTIMEOFDAY_TZ=cross)])
 412 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" = x"yes"; then
 413     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [ ])
 414 fi
 415
 416 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
 417 AC_TRY_RUN([
 418 #include <sys/types.h>
 419 #include <stdarg.h>
 420 void foo(const char *format, ...) {
 421        va_list ap;
 422        int len;
 423        char buf[5];
 424
 425        va_start(ap, format);
 426        len = vsnprintf(0, 0, format, ap);
 427        va_end(ap);
 428        if (len != 5) exit(1);
 429
 430        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 431
 432        exit(0);
 433 }
 434 main() { foo("hello"); }
 435 ],
 436 rsync_cv_HAVE_C99_VSNPRINTF=yes,rsync_cv_HAVE_C99_VSNPRINTF=no,rsync_cv_HAVE_C99_VSNPRINTF=cross)])
 437 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 438     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [ ])
 439 fi
 440
 441
 442 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
 443 AC_TRY_RUN([#include <stdlib.h>
 444 #include <sys/types.h>
 445 #include <sys/stat.h>
 446 #include <unistd.h>
 447 main() {
 448   struct stat st;
 449   char tpl[20]="/tmp/test.XXXXXX";
 450   int fd = mkstemp(tpl);
 451   if (fd == -1) exit(1);
 452   unlink(tpl);
 453   if (fstat(fd, &st) != 0) exit(1);
 454   if ((st.st_mode & 0777) != 0600) exit(1);
 455   exit(0);
 456 }],
 457 rsync_cv_HAVE_SECURE_MKSTEMP=yes,
 458 rsync_cv_HAVE_SECURE_MKSTEMP=no,
 459 rsync_cv_HAVE_SECURE_MKSTEMP=cross)])
 460 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
 461     AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [ ])
 462 fi
 463
 464
 465 AC_CACHE_CHECK([for broken inet_ntoa],rsync_cv_REPLACE_INET_NTOA,[
 466 AC_TRY_RUN([
 467 #include <stdio.h>
 468 #include <sys/types.h>
 469 #include <netinet/in.h>
 470 #include <arpa/inet.h>
 471 main() { struct in_addr ip; ip.s_addr = 0x12345678;
 472 if (strcmp(inet_ntoa(ip),"18.52.86.120") &&
 473     strcmp(inet_ntoa(ip),"120.86.52.18")) { exit(1); }
 474 exit(0);}],
 475            rsync_cv_REPLACE_INET_NTOA=no,rsync_cv_REPLACE_INET_NTOA=yes,rsync_cv_REPLACE_INET_NTOA=cross)])
 476 if test x"$rsync_cv_REPLACE_INET_NTOA" = x"yes"; then
 477     AC_DEFINE(REPLACE_INET_NTOA, 1, [ ])
 478 fi
 479
 480
 481 AC_CACHE_CHECK([for broken inet_aton],rsync_cv_REPLACE_INET_ATON,[
 482 AC_TRY_RUN([
 483 #include <stdio.h>
 484 #include <sys/types.h>
 485 #include <netinet/in.h>
 486 #include <arpa/inet.h>
 487 main() { struct in_addr ip;
 488 if (inet_aton("example", &ip) == 0) exit(0); exit(1);}],
 489            rsync_cv_REPLACE_INET_ATON=no,rsync_cv_REPLACE_INET_ATON=yes,rsync_cv_REPLACE_INET_ATON=cross)])
 490 if test x"$rsync_cv_REPLACE_INET_ATON" = x"yes"; then
 491     AC_DEFINE(REPLACE_INET_ATON, 1, [ ])
 492 fi
 493
 494 #
 495 # The following test was mostly taken from the tcl/tk plus patches
 496 #
 497 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
 498 rm -rf conftest*
 499 cat > conftest.$ac_ext <<EOF
 500 int main() { return 0; }
 501 EOF
 502 ${CC-cc} -c -o conftest..o conftest.$ac_ext
 503 if test -f conftest..o; then
 504     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
 505 else
 506     rsync_cv_DASHC_WORKS_WITH_DASHO=no
 507 fi
 508 rm -rf conftest*
 509 ])
 510 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
 511     OBJ_SAVE="#"
 512     OBJ_RESTORE="#"
 513     CC_SHOBJ_FLAG='-o $@'
 514 else
 515     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
 516     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
 517     CC_SHOBJ_FLAG=""
 518 fi
 519
 520 AC_SUBST(OBJ_SAVE)
 521 AC_SUBST(OBJ_RESTORE)
 522 AC_SUBST(CC_SHOBJ_FLAG)
 523 AC_SUBST(BUILD_POPT)
 524
 525 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
 526 AC_OUTPUT