Use 0-length MSG_DATA when MSG_NOOP is not available
[rsync.git] / configure.in
1 dnl Process this file with autoconf to produce a configure script.
2
3 AC_INIT()
4 AC_CONFIG_SRCDIR([byteorder.h])
5 AC_CONFIG_HEADER(config.h)
6 AC_PREREQ(2.59)
7
8 RSYNC_VERSION=3.0.7dev
9 AC_SUBST(RSYNC_VERSION)
10 AC_MSG_NOTICE([Configuring rsync $RSYNC_VERSION])
11
12 AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$RSYNC_VERSION"], [rsync release version])
13
14 LDFLAGS=${LDFLAGS-""}
15
16 AC_CANONICAL_HOST
17
18 # We must decide this before testing the compiler.
19
20 # Please allow this to default to yes, so that your users have more
21 # chance of getting a useful stack trace if problems occur.
22
23 AC_MSG_CHECKING([whether to include debugging symbols])
24 AC_ARG_ENABLE(debug,
25         AC_HELP_STRING([--disable-debug],
26                 [disable debugging symbols and features]))
27
28 if test x"$enable_debug" = x"no"; then
29     AC_MSG_RESULT(no)
30     ac_cv_prog_cc_g=no
31 else
32     AC_MSG_RESULT([yes])
33     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
34     # leave ac_cv_prog_cc_g alone; AC_PROG_CC will try to include -g if it can
35 fi
36
37 dnl Checks for programs.
38 AC_PROG_CC
39 AC_PROG_CPP
40 AC_PROG_EGREP
41 AC_PROG_INSTALL
42 AC_PROG_CC_STDC
43 AC_SUBST(SHELL)
44
45 AC_DEFINE([_GNU_SOURCE], 1,
46           [Define _GNU_SOURCE so that we get all necessary prototypes])
47
48 if test x"$ac_cv_prog_cc_stdc" = x"no"; then
49         AC_MSG_WARN([rsync requires an ANSI C compiler and you don't seem to have one])
50 fi
51
52 AC_ARG_ENABLE(profile,
53         AC_HELP_STRING([--enable-profile],
54                 [turn on CPU profiling]))
55 if test x"$enable_profile" = x"yes"; then
56         CFLAGS="$CFLAGS -pg"
57 fi
58
59
60 # Specifically, this turns on panic_action handling.
61 AC_ARG_ENABLE(maintainer-mode,
62         AC_HELP_STRING([--enable-maintainer-mode],
63                 [turn on extra debug features]))
64 if test x"$enable_maintainer_mode" = x"yes"; then
65         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
66 fi
67
68
69 # This is needed for our included version of popt.  Kind of silly, but
70 # I don't want our version too far out of sync.
71 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
72
73 # If GCC, turn on warnings.
74 if test x"$GCC" = x"yes"; then
75         CFLAGS="$CFLAGS -Wall -W"
76 fi
77
78 AC_ARG_WITH(included-popt,
79         AC_HELP_STRING([--with-included-popt], [use bundled popt library, not from system]))
80
81 AC_ARG_WITH(rsync-path,
82         AC_HELP_STRING([--with-rsync-path=PATH], [set default --rsync-path to PATH (default: rsync)]),
83         [ RSYNC_PATH="$with_rsync_path" ],
84         [ RSYNC_PATH="rsync" ])
85
86 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
87
88 AC_ARG_WITH(rsyncd-conf,
89         AC_HELP_STRING([--with-rsyncd-conf=PATH], [set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]),
90         [ if test ! -z "$with_rsyncd_conf" ; then
91                 case $with_rsyncd_conf in
92                         yes|no)
93                                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
94                                 ;;
95                         /*)
96                                 RSYNCD_SYSCONF="$with_rsyncd_conf"
97                                 ;;
98                         *)
99                                 AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH)
100                                 ;;
101                 esac
102         else
103                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
104         fi ],
105         [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ])
106
107 AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server])
108
109 AC_ARG_WITH(rsh,
110         AC_HELP_STRING([--with-rsh=CMD], [set remote shell command to CMD (default: ssh)]))
111
112 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
113 if test x$HAVE_REMSH = x1; then
114         AC_DEFINE(HAVE_REMSH, 1, [Define to 1 if remote shell is remsh, not rsh])
115 fi
116
117 if test x"$with_rsh" != x; then
118         RSYNC_RSH="$with_rsh"
119 else
120         RSYNC_RSH="ssh"
121 fi
122 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
123
124 AC_CHECK_PROG(HAVE_YODL2MAN, yodl2man, 1, 0)
125 if test x$HAVE_YODL2MAN = x1; then
126     MAKE_MAN=man
127 fi
128
129 AC_ARG_WITH(nobody-group,
130     AC_HELP_STRING([--with-nobody-group=GROUP],
131                    [set the default unprivileged group (default nobody or nogroup)]),
132     [ NOBODY_GROUP="$with_nobody_group" ])
133
134 if test x"$with_nobody_group" = x; then
135     AC_MSG_CHECKING([the group for user "nobody"])
136     if grep '^nobody:' /etc/group >/dev/null 2>&1; then
137         NOBODY_GROUP=nobody
138     elif grep '^nogroup:' /etc/group >/dev/null 2>&1; then
139         NOBODY_GROUP=nogroup
140     else
141         NOBODY_GROUP=nobody # test for others?
142     fi
143     AC_MSG_RESULT($NOBODY_GROUP)
144 fi
145
146 AC_DEFINE_UNQUOTED(NOBODY_USER, "nobody", [unprivileged user--e.g. nobody])
147 AC_DEFINE_UNQUOTED(NOBODY_GROUP, "$NOBODY_GROUP", [unprivileged group for unprivileged user])
148
149 # arrgh. libc in some old debian version screwed up the largefile
150 # stuff, getting byte range locking wrong
151 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
152 AC_TRY_RUN([
153 #define _FILE_OFFSET_BITS 64
154 #include <stdio.h>
155 #include <fcntl.h>
156 #include <sys/types.h>
157 #include <sys/wait.h>
158
159 int main(void)
160 {
161         struct flock lock;
162         int status;
163         char tpl[32] = "/tmp/locktest.XXXXXX";
164         int fd = mkstemp(tpl);
165         if (fd < 0) {
166                 strcpy(tpl, "conftest.dat");
167                 fd = open(tpl, O_CREAT|O_RDWR, 0600);
168         }
169
170         lock.l_type = F_WRLCK;
171         lock.l_whence = SEEK_SET;
172         lock.l_start = 0;
173         lock.l_len = 1;
174         lock.l_pid = 0;
175         fcntl(fd,F_SETLK,&lock);
176         if (fork() == 0) {
177                 lock.l_start = 1;
178                 _exit(fcntl(fd,F_SETLK,&lock) == 0);
179         }
180         wait(&status);
181         unlink(tpl);
182         exit(WEXITSTATUS(status));
183 }
184 ],
185 rsync_cv_HAVE_BROKEN_LARGEFILE=yes,rsync_cv_HAVE_BROKEN_LARGEFILE=no,rsync_cv_HAVE_BROKEN_LARGEFILE=cross)])
186 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
187    AC_SYS_LARGEFILE
188 fi
189
190 ipv6type=unknown
191 ipv6lib=none
192 ipv6trylibc=yes
193
194 AC_ARG_ENABLE(ipv6,
195         AC_HELP_STRING([--disable-ipv6],
196                 [don't even try to use IPv6]))
197 if test x"$enable_ipv6" != x"no"; then
198         AC_MSG_CHECKING([ipv6 stack type])
199         for i in inria kame linux-glibc linux-inet6 solaris toshiba v6d zeta cygwin; do
200                 case $i in
201                 inria)
202                         # http://www.kame.net/
203                         AC_EGREP_CPP(yes, [
204 #include <netinet/in.h>
205 #ifdef IPV6_INRIA_VERSION
206 yes
207 #endif],
208                                 [ipv6type=$i;
209                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
210                                 ])
211                         ;;
212                 kame)
213                         # http://www.kame.net/
214                         AC_EGREP_CPP(yes, [
215 #include <netinet/in.h>
216 #ifdef __KAME__
217 yes
218 #endif],
219                                 [ipv6type=$i;
220                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
221                         ;;
222                 linux-glibc)
223                         # http://www.v6.linux.or.jp/
224                         AC_EGREP_CPP(yes, [
225 #include <features.h>
226 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
227 yes
228 #endif],
229                                 [ipv6type=$i;
230 AC_DEFINE(INET6, 1, [true if you have IPv6])])
231                         ;;
232                 linux-inet6)
233                         # http://www.v6.linux.or.jp/
234                         if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
235                                 ipv6type=$i
236                                 ipv6lib=inet6
237                                 ipv6libdir=/usr/inet6/lib
238                                 ipv6trylibc=yes;
239                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
240                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
241                         fi
242                         ;;
243                 solaris)
244                         # http://www.sun.com
245                         AC_EGREP_CPP(yes, [
246 #include <netinet/ip6.h>
247 #ifdef __sun
248 yes
249 #endif],
250                                 [ipv6type=$i;
251                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
252                         ;;
253                 toshiba)
254                         AC_EGREP_CPP(yes, [
255 #include <sys/param.h>
256 #ifdef _TOSHIBA_INET6
257 yes
258 #endif],
259                                 [ipv6type=$i;
260                                 ipv6lib=inet6;
261                                 ipv6libdir=/usr/local/v6/lib;
262                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
263                         ;;
264                 v6d)
265                         AC_EGREP_CPP(yes, [
266 #include </usr/local/v6/include/sys/v6config.h>
267 #ifdef __V6D__
268 yes
269 #endif],
270                                 [ipv6type=$i;
271                                 ipv6lib=v6;
272                                 ipv6libdir=/usr/local/v6/lib;
273                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
274                         ;;
275                 zeta)
276                         AC_EGREP_CPP(yes, [
277 #include <sys/param.h>
278 #ifdef _ZETA_MINAMI_INET6
279 yes
280 #endif],
281                                 [ipv6type=$i;
282                                 ipv6lib=inet6;
283                                 ipv6libdir=/usr/local/v6/lib;
284                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
285                         ;;
286                 cygwin)
287                         AC_EGREP_CPP(yes, [
288 #include <netinet/in.h>
289 #ifdef _CYGWIN_IN6_H
290 yes
291 #endif],
292                                 [ipv6type=$i;
293                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
294                         ;;
295                 esac
296                 if test "$ipv6type" != "unknown"; then
297                         break
298                 fi
299         done
300         AC_MSG_RESULT($ipv6type)
301
302         AC_SEARCH_LIBS(getaddrinfo, inet6)
303 fi
304
305 dnl Do you want to disable use of locale functions
306 AC_ARG_ENABLE([locale],
307         AC_HELP_STRING([--disable-locale],
308                 [disable locale features]))
309 AH_TEMPLATE([CONFIG_LOCALE],
310 [Undefine if you don't want locale features.  By default this is defined.])
311 if test x"$enable_locale" != x"no"; then
312         AC_DEFINE(CONFIG_LOCALE)
313 fi
314
315 AC_MSG_CHECKING([whether to call shutdown on all sockets])
316 case $host_os in
317         *cygwin* ) AC_MSG_RESULT(yes)
318                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
319                             [Define to 1 if sockets need to be shutdown])
320                    ;;
321                * ) AC_MSG_RESULT(no);;
322 esac
323
324 AC_C_BIGENDIAN
325 AC_HEADER_DIRENT
326 AC_HEADER_TIME
327 AC_HEADER_SYS_WAIT
328 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \
329     unistd.h utime.h grp.h compat.h sys/param.h ctype.h sys/wait.h \
330     sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h \
331     sys/un.h sys/attr.h mcheck.h arpa/inet.h arpa/nameser.h locale.h \
332     netdb.h malloc.h float.h limits.h iconv.h libcharset.h langinfo.h \
333     sys/acl.h acl/libacl.h attr/xattr.h sys/xattr.h sys/extattr.h \
334     popt.h popt/popt.h)
335 AC_HEADER_MAJOR
336
337 AC_CACHE_CHECK([if makedev takes 3 args],rsync_cv_MAKEDEV_TAKES_3_ARGS,[
338 AC_TRY_RUN([
339 #include <sys/types.h>
340 #ifdef MAJOR_IN_MKDEV
341 #include <sys/mkdev.h>
342 # if !defined makedev && (defined mkdev || defined _WIN32 || defined __WIN32__)
343 #  define makedev mkdev
344 # endif
345 #elif defined MAJOR_IN_SYSMACROS
346 #include <sys/sysmacros.h>
347 #endif
348
349 int main(void)
350 {
351         dev_t dev = makedev(0, 5, 7);
352         if (major(dev) != 5 || minor(dev) != 7)
353                 exit(1);
354         return 0;
355 }
356 ],
357 rsync_cv_MAKEDEV_TAKES_3_ARGS=yes,rsync_cv_MAKEDEV_TAKES_3_ARGS=no,rsync_cv_MAKEDEV_TAKES_3_ARGS=no)])
358 if test x"$rsync_cv_MAKEDEV_TAKES_3_ARGS" = x"yes"; then
359    AC_DEFINE(MAKEDEV_TAKES_3_ARGS, 1, [Define to 1 if makedev() takes 3 args])
360 fi
361
362 AC_CHECK_SIZEOF(int)
363 AC_CHECK_SIZEOF(long)
364 AC_CHECK_SIZEOF(long long)
365 AC_CHECK_SIZEOF(short)
366 AC_CHECK_SIZEOF(int16_t)
367 AC_CHECK_SIZEOF(uint16_t)
368 AC_CHECK_SIZEOF(int32_t)
369 AC_CHECK_SIZEOF(uint32_t)
370 AC_CHECK_SIZEOF(int64_t)
371 AC_CHECK_SIZEOF(off_t)
372 AC_CHECK_SIZEOF(off64_t)
373 AC_CHECK_SIZEOF(time_t)
374
375 AC_C_INLINE
376 AC_C_LONG_DOUBLE
377
378 AC_TYPE_SIGNAL
379 AC_TYPE_UID_T
380 AC_CHECK_TYPES([mode_t,off_t,size_t,pid_t,id_t])
381 AC_TYPE_GETGROUPS
382 AC_CHECK_MEMBERS([struct stat.st_rdev])
383
384 TYPE_SOCKLEN_T
385
386 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
387     AC_TRY_COMPILE([#include <errno.h>],[int i = errno],
388         rsync_cv_errno=yes,rsync_cv_have_errno_decl=no)])
389 if test x"$rsync_cv_errno" = x"yes"; then
390    AC_DEFINE(HAVE_ERRNO_DECL, 1, [Define to 1 if errno is declared in errno.h])
391 fi
392
393 # The following test taken from the cvs sources
394 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
395 # These need checks to be before checks for any other functions that
396 #    might be in the same libraries.
397 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
398 # libsocket.so which has a bad implementation of gethostbyname (it
399 # only looks in /etc/hosts), so we only look for -lsocket if we need
400 # it.
401 AC_CHECK_FUNCS(connect)
402 if test x"$ac_cv_func_connect" = x"no"; then
403     case "$LIBS" in
404     *-lnsl*) ;;
405     *) AC_CHECK_LIB(nsl_s, printf) ;;
406     esac
407     case "$LIBS" in
408     *-lnsl*) ;;
409     *) AC_CHECK_LIB(nsl, printf) ;;
410     esac
411     case "$LIBS" in
412     *-lsocket*) ;;
413     *) AC_CHECK_LIB(socket, connect) ;;
414     esac
415     case "$LIBS" in
416     *-linet*) ;;
417     *) AC_CHECK_LIB(inet, connect) ;;
418     esac
419     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
420     dnl has been cached.
421     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
422        test x"$ac_cv_lib_inet_connect" = x"yes"; then
423         # ac_cv_func_connect=yes
424         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
425         AC_DEFINE(HAVE_CONNECT, 1, [Define to 1 if you have the "connect" function])
426     fi
427 fi
428
429 AC_SEARCH_LIBS(inet_ntop, resolv)
430
431 # Solaris and HP-UX weirdness:
432 # Search for libiconv_open (not iconv_open) to discover if -liconv is needed!
433 AC_SEARCH_LIBS(libiconv_open, iconv)
434
435 AC_MSG_CHECKING([for iconv declaration])
436 AC_CACHE_VAL(am_cv_proto_iconv, [
437     AC_TRY_COMPILE([
438 #include <stdlib.h>
439 #include <iconv.h>
440 extern
441 #ifdef __cplusplus
442 "C"
443 #endif
444 #if defined(__STDC__) || defined(__cplusplus)
445 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
446 #else
447 size_t iconv();
448 #endif
449 ], [], am_cv_proto_iconv_arg1="", am_cv_proto_iconv_arg1="const")
450       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
451     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed -e 's/( /(/'`
452 AC_MSG_RESULT([$]{ac_t:-
453          }[$]am_cv_proto_iconv)
454 AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
455                    [Define as const if the declaration of iconv() needs const.])
456
457 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
458
459 AC_CHECK_FUNCS(inet_ntop, , [AC_LIBOBJ(lib/inet_ntop)])
460 AC_CHECK_FUNCS(inet_pton, , [AC_LIBOBJ(lib/inet_pton)])
461
462 AC_HAVE_TYPE([struct addrinfo], [#include <netdb.h>])
463 AC_HAVE_TYPE([struct sockaddr_storage], [#include <sys/types.h>
464 #include <sys/socket.h>])
465
466 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
467 #   builtin getaddrinfo if one of the defines don't exist
468 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
469                rsync_cv_HAVE_GETADDR_DEFINES,[
470                         AC_EGREP_CPP(yes, [
471                         #include <sys/types.h>
472                         #include <sys/socket.h>
473                         #include <netdb.h>
474                         #ifdef AI_PASSIVE
475                         yes
476                         #endif],
477                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
478                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
479 if test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes" -a x"$ac_cv_type_struct_addrinfo" = x"yes"; then
480         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
481         # something else so we must include <netdb.h> to get the
482         # redefinition.
483         AC_CHECK_FUNCS(getaddrinfo, ,
484                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
485                 AC_TRY_LINK([#include <sys/types.h>
486                 #include <sys/socket.h>
487                 #include <netdb.h>],[getaddrinfo(NULL, NULL, NULL, NULL);],
488                         [AC_MSG_RESULT([yes])
489                         AC_DEFINE(HAVE_GETADDRINFO, 1,
490                                 [Define to 1 if you have the "getaddrinfo" function and required types.])],
491                         [AC_MSG_RESULT([no])
492                         AC_LIBOBJ(lib/getaddrinfo)])])
493 else
494         AC_LIBOBJ(lib/getaddrinfo)
495 fi
496
497 AC_CHECK_MEMBER([struct sockaddr.sa_len],
498                 [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ],
499                 [],
500                 [
501 #include <sys/types.h>
502 #include <sys/socket.h>
503 ])
504
505 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
506                 [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ],
507                 [],
508                 [
509 #include <sys/types.h>
510 #include <sys/socket.h>
511 #include <netinet/in.h>
512 ])
513
514 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
515                 [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ],
516                 [],
517                 [
518 #include <sys/types.h>
519 #include <sys/socket.h>
520 #include <netinet/in.h>
521 ])
522
523 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
524                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ],
525                 [],
526                 [
527 #include <sys/types.h>
528 #include <sys/socket.h>
529 #include <netinet/in.h>
530 ])
531
532 AC_HAVE_TYPE([struct stat64], [#include <stdio.h>
533 #if HAVE_SYS_TYPES_H
534 # include <sys/types.h>
535 #endif
536 #if HAVE_SYS_STAT_H
537 # include <sys/stat.h>
538 #endif
539 #if STDC_HEADERS
540 # include <stdlib.h>
541 # include <stddef.h>
542 #else
543 # if HAVE_STDLIB_H
544 #  include <stdlib.h>
545 # endif
546 #endif
547 ])
548
549 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
550 #
551 AC_CHECK_FUNCS(strcasecmp)
552 if test x"$ac_cv_func_strcasecmp" = x"no"; then
553     AC_CHECK_LIB(resolv, strcasecmp)
554 fi
555
556 AC_CHECK_FUNCS(aclsort)
557 if test x"$ac_cv_func_aclsort" = x"no"; then
558     AC_CHECK_LIB(sec, aclsort)
559 fi
560
561 dnl At the moment we don't test for a broken memcmp(), because all we
562 dnl need to do is test for equality, not comparison, and it seems that
563 dnl every platform has a memcmp that can do at least that.
564 dnl AC_FUNC_MEMCMP
565
566 AC_FUNC_UTIME_NULL
567 AC_FUNC_ALLOCA
568 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup chown chmod lchmod mknod mkfifo \
569     fchmod fstat ftruncate strchr readlink link utime utimes lutimes strftime \
570     memmove lchown vsnprintf snprintf vasprintf asprintf setsid strpbrk \
571     strlcat strlcpy strtol mallinfo getgroups setgroups geteuid getegid \
572     setlocale setmode open64 lseek64 mkstemp64 mtrace va_copy __va_copy \
573     seteuid strerror putenv iconv_open locale_charset nl_langinfo getxattr \
574     extattr_get_link sigaction sigprocmask setattrlist)
575
576 dnl cygwin iconv.h defines iconv_open as libiconv_open
577 if test x"$ac_cv_func_iconv_open" != x"yes"; then
578     AC_CHECK_FUNC(libiconv_open, [ac_cv_func_iconv_open=yes; AC_DEFINE(HAVE_ICONV_OPEN, 1)])
579 fi
580
581 AC_CHECK_FUNCS(getpgrp tcgetpgrp)
582 if test $ac_cv_func_getpgrp = yes; then
583     AC_FUNC_GETPGRP
584 fi
585
586 AC_ARG_ENABLE(iconv-open,
587     AC_HELP_STRING([--disable-iconv-open],
588             [disable all use of iconv_open() function]),
589     [], [enable_iconv_open=$ac_cv_func_iconv_open])
590
591 if test x"$enable_iconv_open" != x"no"; then
592     AC_DEFINE(USE_ICONV_OPEN, 1, [Define to 1 if you want rsync to make use of iconv_open()])
593 fi
594
595 AC_ARG_ENABLE(iconv,
596     AC_HELP_STRING([--disable-iconv],
597             [disable rsync's --iconv option]),
598     [], [enable_iconv=$enable_iconv_open])
599 AH_TEMPLATE([ICONV_OPTION],
600 [Define if you want the --iconv option.  Specifing a value will set the
601 default iconv setting (a NULL means no --iconv processing by default).])
602 if test x"$enable_iconv" != x"no"; then
603         if test x"$enable_iconv" = x"yes"; then
604                 AC_DEFINE(ICONV_OPTION, NULL)
605         else
606                 AC_DEFINE_UNQUOTED(ICONV_OPTION, "$enable_iconv")
607         fi
608         AC_DEFINE(UTF8_CHARSET, "UTF-8", [String to pass to iconv() for the UTF-8 charset.])
609 fi
610
611 AC_CACHE_CHECK([whether chown() modifies symlinks],rsync_cv_chown_modifies_symlink,[
612   AC_TRY_RUN([
613 #if HAVE_UNISTD_H
614 # include <unistd.h>
615 #endif
616 #include <stdlib.h>
617 #include <errno.h>
618     main() {
619         char const *dangling_symlink = "conftest.dangle";
620         unlink(dangling_symlink);
621         if (symlink("conftest.no-such", dangling_symlink) < 0) abort();
622         if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) exit(1);
623         exit(0);
624     }],
625   rsync_cv_chown_modifies_symlink=yes,rsync_cv_chown_modifies_symlink=no,rsync_cv_chown_modifies_symlink=no)])
626 if test $rsync_cv_chown_modifies_symlink = yes; then
627   AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define to 1 if chown modifies symlinks.])
628 fi
629
630 AC_CACHE_CHECK([whether link() can hard-link symlinks],rsync_cv_can_hardlink_symlink,[
631   AC_TRY_RUN([
632 #if HAVE_UNISTD_H
633 # include <unistd.h>
634 #endif
635 #include <stdlib.h>
636 #include <errno.h>
637 #define FILENAME "conftest.dangle"
638     main() {
639         unlink(FILENAME);
640         if (symlink("conftest.no-such", FILENAME) < 0) abort();
641         if (link(FILENAME, FILENAME "2") < 0) exit(1);
642         exit(0);
643     }],
644   rsync_cv_can_hardlink_symlink=yes,rsync_cv_can_hardlink_symlink=no,rsync_cv_can_hardlink_symlink=no)])
645 if test $rsync_cv_can_hardlink_symlink = yes; then
646   AC_DEFINE(CAN_HARDLINK_SYMLINK, 1, [Define to 1 if link() can hard-link symlinks.])
647 fi
648
649 AC_CACHE_CHECK([whether link() can hard-link special files],rsync_cv_can_hardlink_special,[
650   AC_TRY_RUN([
651 #if HAVE_UNISTD_H
652 # include <unistd.h>
653 #endif
654 #include <stdlib.h>
655 #include <errno.h>
656 #define FILENAME "conftest.fifi"
657     main() {
658         unlink(FILENAME);
659         if (mkfifo(FILENAME, 0777) < 0) abort();
660         if (link(FILENAME, FILENAME "2") < 0) exit(1);
661         exit(0);
662     }],
663   rsync_cv_can_hardlink_special=yes,rsync_cv_can_hardlink_special=no,rsync_cv_can_hardlink_special=no)])
664 if test $rsync_cv_can_hardlink_special = yes; then
665     AC_DEFINE(CAN_HARDLINK_SPECIAL, 1, [Define to 1 if link() can hard-link special files.])
666 fi
667
668 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
669 AC_TRY_RUN([
670 #include <sys/types.h>
671 #include <sys/socket.h>
672
673 main() {
674        int fd[2];
675        exit((socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1);
676 }],
677 rsync_cv_HAVE_SOCKETPAIR=yes,rsync_cv_HAVE_SOCKETPAIR=no,rsync_cv_HAVE_SOCKETPAIR=cross)])
678 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
679     AC_DEFINE(HAVE_SOCKETPAIR, 1, [Define to 1 if you have the "socketpair" function])
680 fi
681
682 if test x"$with_included_popt" != x"yes"; then
683     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
684 fi
685 if test x"$ac_cv_header_popt_popt_h" = x"yes"; then
686     # If the system has /usr/include/popt/popt.h, we enable the
687     # included popt because an attempt to "#include <popt/popt.h>"
688     # would use our included header file anyway (due to -I.), and
689     # might conflict with the system popt.
690     with_included_popt=yes
691 elif test x"$ac_cv_header_popt_h" != x"yes"; then
692     with_included_popt=yes
693 fi
694
695 AC_MSG_CHECKING([whether to use included libpopt])
696 if test x"$with_included_popt" = x"yes"; then
697     AC_MSG_RESULT($srcdir/popt)
698     BUILD_POPT='$(popt_OBJS)'
699     CFLAGS="$CFLAGS -I$srcdir/popt"
700     if test x"$ALLOCA" != x
701     then
702         # this can be removed when/if we add an included alloca.c;
703         #  see autoconf documentation on AC_FUNC_ALLOCA
704         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
705     fi
706 else
707     AC_MSG_RESULT(no)
708 fi
709
710 AC_CACHE_CHECK([for unsigned char],rsync_cv_SIGNED_CHAR_OK,[
711 AC_TRY_COMPILE([],[signed char *s = ""],
712 rsync_cv_SIGNED_CHAR_OK=yes,rsync_cv_SIGNED_CHAR_OK=no)])
713 if test x"$rsync_cv_SIGNED_CHAR_OK" = x"yes"; then
714     AC_DEFINE(SIGNED_CHAR_OK, 1, [Define to 1 if "signed char" is a valid type])
715 fi
716
717 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
718 AC_TRY_RUN([#include <sys/types.h>
719 #include <dirent.h>
720 main() { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
721 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
722 di->d_name[0] == 0) exit(0); exit(1);} ],
723 rsync_cv_HAVE_BROKEN_READDIR=yes,rsync_cv_HAVE_BROKEN_READDIR=no,rsync_cv_HAVE_BROKEN_READDIR=cross)])
724 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
725     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [Define to 1 if readdir() is broken])
726 fi
727
728 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_STRUCT_UTIMBUF,[
729 AC_TRY_COMPILE([#include <sys/types.h>
730 #include <utime.h>],
731 [struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; exit(utime("foo.c",&tbuf));],
732 rsync_cv_HAVE_STRUCT_UTIMBUF=yes,rsync_cv_HAVE_STRUCT_UTIMBUF=no)])
733 if test x"$rsync_cv_HAVE_STRUCT_UTIMBUF" = x"yes"; then
734     AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if you have the "struct utimbuf" type])
735 fi
736
737 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
738 AC_TRY_COMPILE([#include <sys/time.h>
739 #include <unistd.h>],
740 [struct timeval tv; exit(gettimeofday(&tv, NULL));],
741 rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes,rsync_cv_HAVE_GETTIMEOFDAY_TZ=no)])
742 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then
743     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [Define to 1 if gettimeofday() takes a time-zone arg])
744 fi
745
746 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
747 AC_TRY_RUN([
748 #include <sys/types.h>
749 #include <stdarg.h>
750 void foo(const char *format, ...) {
751        va_list ap;
752        int len;
753        char buf[5];
754
755        va_start(ap, format);
756        len = vsnprintf(0, 0, format, ap);
757        va_end(ap);
758        if (len != 5) exit(1);
759
760        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
761
762        exit(0);
763 }
764 main() { foo("hello"); }
765 ],
766 rsync_cv_HAVE_C99_VSNPRINTF=yes,rsync_cv_HAVE_C99_VSNPRINTF=no,rsync_cv_HAVE_C99_VSNPRINTF=cross)])
767 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
768     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [Define to 1 if vsprintf has a C99-compatible return value])
769 fi
770
771
772 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
773 AC_TRY_RUN([#include <stdlib.h>
774 #include <sys/types.h>
775 #include <sys/stat.h>
776 #include <unistd.h>
777 main() {
778   struct stat st;
779   char tpl[20]="/tmp/test.XXXXXX";
780   int fd = mkstemp(tpl);
781   if (fd == -1) exit(1);
782   unlink(tpl);
783   if (fstat(fd, &st) != 0) exit(1);
784   if ((st.st_mode & 0777) != 0600) exit(1);
785   exit(0);
786 }],
787 rsync_cv_HAVE_SECURE_MKSTEMP=yes,
788 rsync_cv_HAVE_SECURE_MKSTEMP=no,
789 rsync_cv_HAVE_SECURE_MKSTEMP=cross)])
790 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
791     case $host_os in
792     hpux*)
793         dnl HP-UX has a broken mkstemp() implementation they refuse to fix,
794         dnl so we noisily skip using it.  See HP change request JAGaf34426
795         dnl for details. (sbonds)
796         AC_MSG_WARN(Skipping broken HP-UX mkstemp() -- using mktemp() instead)
797         ;;
798     *)
799         AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [Define to 1 if mkstemp() is available and works right])
800         ;;
801     esac
802 fi
803
804
805 AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[
806 AC_TRY_RUN([
807 #include <stdio.h>
808 #include <sys/stat.h>
809 #include <errno.h>
810 main() { int rc, ec; char *fn = "fifo-test";
811 unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn);
812 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
813 return 0;}],
814            rsync_cv_MKNOD_CREATES_FIFOS=yes,rsync_cv_MKNOD_CREATES_FIFOS=no,rsync_cv_MKNOD_CREATES_FIFOS=cross)])
815 if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then
816     AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.])
817 fi
818
819 AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[
820 AC_TRY_RUN([
821 #include <stdio.h>
822 #include <sys/stat.h>
823 #include <errno.h>
824 main() { int rc, ec; char *fn = "sock-test";
825 unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn);
826 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
827 return 0;}],
828            rsync_cv_MKNOD_CREATES_SOCKETS=yes,rsync_cv_MKNOD_CREATES_SOCKETS=no,rsync_cv_MKNOD_CREATES_SOCKETS=cross)])
829 if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then
830     AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.])
831 fi
832
833 #
834 # The following test was mostly taken from the tcl/tk plus patches
835 #
836 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
837 rm -rf conftest*
838 cat > conftest.$ac_ext <<EOF
839 int main() { return 0; }
840 EOF
841 ${CC-cc} -c -o conftest..o conftest.$ac_ext
842 if test -f conftest..o; then
843     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
844 else
845     rsync_cv_DASHC_WORKS_WITH_DASHO=no
846 fi
847 rm -rf conftest*
848 ])
849 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
850     OBJ_SAVE="#"
851     OBJ_RESTORE="#"
852     CC_SHOBJ_FLAG='-o $@'
853 else
854     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
855     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
856     CC_SHOBJ_FLAG=""
857 fi
858
859 AC_SUBST(OBJ_SAVE)
860 AC_SUBST(OBJ_RESTORE)
861 AC_SUBST(CC_SHOBJ_FLAG)
862 AC_SUBST(BUILD_POPT)
863 AC_SUBST(MAKE_MAN)
864
865 AC_CHECK_FUNCS(_acl __acl _facl __facl)
866 #################################################
867 # check for ACL support
868
869 AC_MSG_CHECKING([whether to support ACLs])
870 AC_ARG_ENABLE(acl-support,
871         AC_HELP_STRING([--disable-acl-support],
872                        [disable ACL support]))
873
874 if test x"$enable_acl_support" = x"no"; then
875     AC_MSG_RESULT(no)
876 else
877     case "$host_os" in
878     *sysv5*)
879         AC_MSG_RESULT(Using UnixWare ACLs)
880         AC_DEFINE(HAVE_UNIXWARE_ACLS, 1, [true if you have UnixWare ACLs])
881         AC_DEFINE(SUPPORT_ACLS, 1, [Define to 1 to add support for ACLs])
882         ;;
883     *solaris*|*cygwin*)
884         AC_MSG_RESULT(Using solaris ACLs)
885         AC_DEFINE(HAVE_SOLARIS_ACLS, 1, [true if you have solaris ACLs])
886         AC_DEFINE(SUPPORT_ACLS, 1)
887         ;;
888     *hpux*)
889         AC_MSG_RESULT(Using HPUX ACLs)
890         AC_DEFINE(HAVE_HPUX_ACLS, 1, [true if you have HPUX ACLs])
891         AC_DEFINE(SUPPORT_ACLS, 1)
892         ;;
893     *irix*)
894         AC_MSG_RESULT(Using IRIX ACLs)
895         AC_DEFINE(HAVE_IRIX_ACLS, 1, [true if you have IRIX ACLs])
896         AC_DEFINE(SUPPORT_ACLS, 1)
897         ;;
898     *aix*)
899         AC_MSG_RESULT(Using AIX ACLs)
900         AC_DEFINE(HAVE_AIX_ACLS, 1, [true if you have AIX ACLs])
901         AC_DEFINE(SUPPORT_ACLS, 1)
902         ;;
903     *osf*)
904         AC_MSG_RESULT(Using Tru64 ACLs)
905         AC_DEFINE(HAVE_TRU64_ACLS, 1, [true if you have Tru64 ACLs])
906         AC_DEFINE(SUPPORT_ACLS, 1)
907         LIBS="$LIBS -lpacl"
908         ;;
909     darwin*)
910         AC_MSG_RESULT(Using OS X ACLs)
911         AC_DEFINE(HAVE_OSX_ACLS, 1, [true if you have Mac OS X ACLs])
912         AC_DEFINE(SUPPORT_ACLS, 1)
913         ;;
914     *)
915         AC_MSG_RESULT(running tests:)
916         AC_CHECK_LIB(acl,acl_get_file)
917             AC_CACHE_CHECK([for ACL support],samba_cv_HAVE_POSIX_ACLS,[
918             AC_TRY_LINK([#include <sys/types.h>
919 #include <sys/acl.h>],
920 [ acl_t acl; int entry_id; acl_entry_t *entry_p; return acl_get_entry( acl, entry_id, entry_p);],
921 samba_cv_HAVE_POSIX_ACLS=yes,samba_cv_HAVE_POSIX_ACLS=no)])
922         AC_MSG_CHECKING(ACL test results)
923         if test x"$samba_cv_HAVE_POSIX_ACLS" = x"yes"; then
924             AC_MSG_RESULT(Using posix ACLs)
925             AC_DEFINE(HAVE_POSIX_ACLS, 1, [true if you have posix ACLs])
926             AC_DEFINE(SUPPORT_ACLS, 1)
927             AC_CACHE_CHECK([for acl_get_perm_np],samba_cv_HAVE_ACL_GET_PERM_NP,[
928                 AC_TRY_LINK([#include <sys/types.h>
929 #include <sys/acl.h>],
930 [ acl_permset_t permset_d; acl_perm_t perm; return acl_get_perm_np( permset_d, perm);],
931 samba_cv_HAVE_ACL_GET_PERM_NP=yes,samba_cv_HAVE_ACL_GET_PERM_NP=no)])
932             if test x"$samba_cv_HAVE_ACL_GET_PERM_NP" = x"yes"; then
933                 AC_DEFINE(HAVE_ACL_GET_PERM_NP, 1, [true if you have acl_get_perm_np])
934             fi
935         else
936             if test x"$enable_acl_support" = x"yes"; then
937                 AC_MSG_ERROR(Failed to find ACL support)
938             else
939                 AC_MSG_RESULT(No ACL support found)
940             fi
941         fi
942         ;;
943     esac
944 fi
945
946 #################################################
947 # check for extended attribute support
948 AC_MSG_CHECKING(whether to support extended attributes)
949 AC_ARG_ENABLE(xattr-support,
950     AC_HELP_STRING([--disable-xattr-support],
951             [disable extended attributes]),
952     [], [case "$ac_cv_func_getxattr$ac_cv_func_extattr_get_link" in
953         *yes*) enable_xattr_support=maybe ;;
954         *) enable_xattr_support=no ;;
955         esac])
956 AH_TEMPLATE([SUPPORT_XATTRS],
957 [Define to 1 to add support for extended attributes])
958 if test x"$enable_xattr_support" = x"no"; then
959     AC_MSG_RESULT(no)
960 else
961     case "$host_os" in
962     *linux*)
963         AC_MSG_RESULT(Using Linux xattrs)
964         AC_DEFINE(HAVE_LINUX_XATTRS, 1, [True if you have Linux xattrs])
965         AC_DEFINE(SUPPORT_XATTRS, 1)
966         ;;
967     darwin*)
968         AC_MSG_RESULT(Using OS X xattrs)
969         AC_DEFINE(HAVE_OSX_XATTRS, 1, [True if you have Mac OS X xattrs])
970         AC_DEFINE(SUPPORT_XATTRS, 1)
971         ;;
972     freebsd*)
973         AC_MSG_RESULT(Using FreeBSD extattrs)
974         AC_DEFINE(HAVE_FREEBSD_XATTRS, 1, [True if you have FreeBSD xattrs])
975         AC_DEFINE(SUPPORT_XATTRS, 1)
976         ;;
977     *)
978         if test x"$enable_xattr_support" = x"yes"; then
979             AC_MSG_ERROR(Failed to find extended attribute support)
980         else
981             AC_MSG_RESULT(No extended attribute support found)
982         fi
983         ;;
984     esac
985 fi
986
987 if test x"$enable_acl_support" = x"no" -o x"$enable_xattr_support" = x"no" -o x"$enable_iconv" = x"no"; then
988     AC_MSG_CHECKING([whether $CC supports -Wno-unused-parameter])
989     OLD_CFLAGS="$CFLAGS"
990     CFLAGS="$CFLAGS -Wno-unused-parameter"
991     AC_COMPILE_IFELSE([ ], [rsync_warn_flag=yes], [rsync_warn_flag=no])
992     AC_MSG_RESULT([$rsync_warn_flag])
993     if test x"$rsync_warn_flag" = x"no"; then
994         CFLAGS="$OLD_CFLAGS"
995     fi
996 fi
997
998 case "$CC" in
999 ' checker'*|checker*)
1000     AC_DEFINE(FORCE_FD_ZERO_MEMSET, 1, [Used to make "checker" understand that FD_ZERO() clears memory.])
1001     ;;
1002 esac
1003
1004 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
1005 AC_OUTPUT
1006
1007 AC_MSG_RESULT()
1008 AC_MSG_RESULT([    rsync ${RSYNC_VERSION} configuration successful])
1009 AC_MSG_RESULT()