configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT()
   4 AC_CONFIG_SRCDIR([byteorder.h])
   5 AC_CONFIG_HEADER(config.h)
   6 AC_PREREQ(2.59)
   7
   8 RSYNC_VERSION=2.6.6pre1
   9 AC_SUBST(RSYNC_VERSION)
  10 AC_MSG_NOTICE([Configuring rsync $RSYNC_VERSION])
  11
  12 AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$RSYNC_VERSION"], [rsync release version])
  13
  14 LDFLAGS=${LDFLAGS-""}
  15
  16 AC_CANONICAL_TARGET([])
  17
  18 dnl Checks for programs.
  19 AC_PROG_CC
  20 AC_PROG_CPP
  21 AC_PROG_EGREP
  22 AC_PROG_INSTALL
  23 AC_PROG_CC_STDC
  24 AC_SUBST(SHELL)
  25
  26 AC_DEFINE([_GNU_SOURCE], 1,
  27           [Define _GNU_SOURCE so that we get all necessary prototypes])
  28
  29 if test "x$ac_cv_prog_cc_stdc" = xno
  30 then
  31         AC_MSG_WARN([rsync requires an ANSI C compiler and you don't seem to have one])
  32 fi
  33
  34 # We must decide this before testing the compiler.
  35
  36 # Please allow this to default to yes, so that your users have more
  37 # chance of getting a useful stack trace if problems occur.
  38
  39 AC_MSG_CHECKING([whether to include debugging symbols])
  40 AC_ARG_ENABLE(debug,
  41         AC_HELP_STRING([--enable-debug],
  42                 [including debugging symbols and features (default yes)]),
  43                 [], [])
  44
  45 if test x"$enable_debug" = x"no"
  46 then
  47     AC_MSG_RESULT(no)
  48     CFLAGS=${CFLAGS-"-O"}
  49 else
  50     AC_MSG_RESULT([yes])
  51     # leave CFLAGS alone; AC_PROG_CC will try to include -g if it can
  52     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  53     dnl CFLAGS=${CFLAGS-"-g"}
  54 fi
  55
  56
  57 AC_ARG_ENABLE(profile,
  58         AC_HELP_STRING([--enable-profile],
  59                 [turn on CPU profiling (default no)],
  60                 [], []))
  61 if test x"$enable_profile" = xyes
  62 then
  63         CFLAGS="$CFLAGS -pg"
  64 fi
  65
  66
  67 # Specifically, this turns on panic_action handling.
  68 AC_ARG_ENABLE(maintainer-mode,
  69         AC_HELP_STRING([--enable-maintainer-mode],
  70                 [turn on extra debug features],
  71                 [], []))
  72 if test x"$enable_maintainer_mode" = xyes
  73 then
  74         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
  75 fi
  76
  77
  78 # This is needed for our included version of popt.  Kind of silly, but
  79 # I don't want our version too far out of sync.
  80 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
  81
  82 # If GCC, turn on warnings.
  83 if test x"$GCC" = x"yes"
  84 then
  85         CFLAGS="$CFLAGS -Wall -W"
  86 fi
  87
  88 AC_ARG_WITH(included-popt,
  89         [  --with-included-popt    use bundled popt library, not from system])
  90
  91 AC_ARG_WITH(rsync-path,
  92         [  --with-rsync-path=PATH  set default --rsync-path to PATH (default: rsync)],
  93         [ RSYNC_PATH="$with_rsync_path" ],
  94         [ RSYNC_PATH="rsync" ])
  95
  96 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
  97
  98 AC_ARG_WITH(rsyncd-conf,
  99         AC_HELP_STRING([--with-rsyncd-conf=PATH], [set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]),
 100         [ if test ! -z "$with_rsyncd_conf" ; then
 101                 case $with_rsyncd_conf in
 102                         yes|no)
 103                                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 104                                 ;;
 105                         /*)
 106                                 RSYNCD_SYSCONF="$with_rsyncd_conf"
 107                                 ;;
 108                         *)
 109                                 AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH)
 110                                 ;;
 111                 esac
 112         else
 113                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 114         fi ],
 115         [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ])
 116
 117 AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server])
 118
 119 AC_ARG_WITH(rsh,
 120         AC_HELP_STRING([--with-rsh=CMD], [set remote shell command to CMD (default: ssh)]))
 121
 122 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
 123 if test x$HAVE_REMSH = x1; then
 124         AC_DEFINE(HAVE_REMSH, 1, [Define to 1 if remote shell is remsh, not rsh])
 125 fi
 126
 127 if test x"$with_rsh" != x
 128 then
 129         RSYNC_RSH="$with_rsh"
 130 else
 131         RSYNC_RSH="ssh"
 132 fi
 133 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
 134
 135 AC_MSG_CHECKING([the group for user "nobody"])
 136 if grep '^nobody:' /etc/group >/dev/null 2>&1; then
 137     NOBODY_GROUP=nobody
 138 elif grep '^nogroup:' /etc/group >/dev/null 2>&1; then
 139     NOBODY_GROUP=nogroup
 140 else
 141     NOBODY_GROUP=nobody # test for others?
 142 fi
 143 AC_MSG_RESULT($NOBODY_GROUP)
 144 AC_DEFINE_UNQUOTED(NOBODY_USER, "nobody", [unprivileged user--e.g. nobody])
 145 AC_DEFINE_UNQUOTED(NOBODY_GROUP, "$NOBODY_GROUP", [unprivileged group for unprivileged user])
 146
 147 # arrgh. libc in the current debian stable screws up the largefile
 148 # stuff, getting byte range locking wrong
 149 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
 150 AC_TRY_RUN([
 151 #define _FILE_OFFSET_BITS 64
 152 #include <stdio.h>
 153 #include <fcntl.h>
 154 #include <sys/types.h>
 155 #include <sys/wait.h>
 156
 157 int main(void)
 158 {
 159         struct flock lock;
 160         int status;
 161         char tpl[32] = "/tmp/locktest.XXXXXX";
 162         int fd = mkstemp(tpl);
 163         if (fd < 0) {
 164                 strcpy(tpl, "conftest.dat");
 165                 fd = open(tpl, O_CREAT|O_RDWR, 0600);
 166         }
 167
 168         lock.l_type = F_WRLCK;
 169         lock.l_whence = SEEK_SET;
 170         lock.l_start = 0;
 171         lock.l_len = 1;
 172         lock.l_pid = 0;
 173         fcntl(fd,F_SETLK,&lock);
 174         if (fork() == 0) {
 175                 lock.l_start = 1;
 176                 _exit(fcntl(fd,F_SETLK,&lock) == 0);
 177         }
 178         wait(&status);
 179         unlink(tpl);
 180         exit(WEXITSTATUS(status));
 181 }
 182 ],
 183 rsync_cv_HAVE_BROKEN_LARGEFILE=yes,rsync_cv_HAVE_BROKEN_LARGEFILE=no,rsync_cv_HAVE_BROKEN_LARGEFILE=cross)])
 184 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
 185    AC_SYS_LARGEFILE
 186 fi
 187
 188 ipv6type=unknown
 189 ipv6lib=none
 190 ipv6trylibc=yes
 191
 192 AC_ARG_ENABLE(ipv6,
 193         AC_HELP_STRING([--disable-ipv6], [don't even try to use IPv6]))
 194
 195 dnl Do you want to disable use of locale functions
 196 AH_TEMPLATE([CONFIG_LOCALE],
 197 [Undefine if you don't want locale features.  By default this is defined.])
 198 AC_ARG_ENABLE([locale],
 199         AC_HELP_STRING([--disable-locale], [turn off locale features]),
 200 [if test x$enableval = xyes; then
 201   AC_DEFINE(CONFIG_LOCALE)
 202 fi],
 203 AC_DEFINE(CONFIG_LOCALE)
 204 )
 205
 206 if test "x$enable_ipv6" != xno
 207 then
 208         AC_MSG_CHECKING([ipv6 stack type])
 209         for i in inria kame linux-glibc linux-inet6 toshiba v6d zeta; do
 210                 case $i in
 211                 inria)
 212                         # http://www.kame.net/
 213                         AC_EGREP_CPP(yes, [
 214 #include <netinet/in.h>
 215 #ifdef IPV6_INRIA_VERSION
 216 yes
 217 #endif],
 218                                 [ipv6type=$i;
 219                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 220                                 ])
 221                         ;;
 222                 kame)
 223                         # http://www.kame.net/
 224                         AC_EGREP_CPP(yes, [
 225 #include <netinet/in.h>
 226 #ifdef __KAME__
 227 yes
 228 #endif],
 229                                 [ipv6type=$i;
 230                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 231                         ;;
 232                 linux-glibc)
 233                         # http://www.v6.linux.or.jp/
 234                         AC_EGREP_CPP(yes, [
 235 #include <features.h>
 236 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 237 yes
 238 #endif],
 239                                 [ipv6type=$i;
 240 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 241                         ;;
 242                 linux-inet6)
 243                         # http://www.v6.linux.or.jp/
 244                         if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
 245                                 ipv6type=$i
 246                                 ipv6lib=inet6
 247                                 ipv6libdir=/usr/inet6/lib
 248                                 ipv6trylibc=yes;
 249                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 250                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 251                         fi
 252                         ;;
 253                 toshiba)
 254                         AC_EGREP_CPP(yes, [
 255 #include <sys/param.h>
 256 #ifdef _TOSHIBA_INET6
 257 yes
 258 #endif],
 259                                 [ipv6type=$i;
 260                                 ipv6lib=inet6;
 261                                 ipv6libdir=/usr/local/v6/lib;
 262                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 263                         ;;
 264                 v6d)
 265                         AC_EGREP_CPP(yes, [
 266 #include </usr/local/v6/include/sys/v6config.h>
 267 #ifdef __V6D__
 268 yes
 269 #endif],
 270                                 [ipv6type=$i;
 271                                 ipv6lib=v6;
 272                                 ipv6libdir=/usr/local/v6/lib;
 273                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 274                         ;;
 275                 zeta)
 276                         AC_EGREP_CPP(yes, [
 277 #include <sys/param.h>
 278 #ifdef _ZETA_MINAMI_INET6
 279 yes
 280 #endif],
 281                                 [ipv6type=$i;
 282                                 ipv6lib=inet6;
 283                                 ipv6libdir=/usr/local/v6/lib;
 284                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 285                         ;;
 286                 esac
 287                 if test "$ipv6type" != "unknown"; then
 288                         break
 289                 fi
 290         done
 291         AC_MSG_RESULT($ipv6type)
 292
 293         AC_SEARCH_LIBS(getaddrinfo, inet6)
 294 fi
 295
 296 AC_MSG_CHECKING([whether to call shutdown on all sockets])
 297 case $host_os in
 298         *cygwin* ) AC_MSG_RESULT(yes)
 299                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
 300                             [Define to 1 if sockets need to be shutdown])
 301                    ;;
 302                * ) AC_MSG_RESULT(no);;
 303 esac
 304
 305 AC_C_BIGENDIAN
 306 AC_HEADER_DIRENT
 307 AC_HEADER_TIME
 308 AC_HEADER_SYS_WAIT
 309 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \
 310     unistd.h utime.h grp.h compat.h sys/param.h ctype.h sys/wait.h \
 311     sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h \
 312     sys/un.h glob.h mcheck.h arpa/inet.h arpa/nameser.h locale.h \
 313     netdb.h malloc.h float.h)
 314 AC_HEADER_MAJOR
 315
 316 AC_CHECK_SIZEOF(int)
 317 AC_CHECK_SIZEOF(long)
 318 AC_CHECK_SIZEOF(long long)
 319 AC_CHECK_SIZEOF(short)
 320 AC_CHECK_SIZEOF(off_t)
 321 AC_CHECK_SIZEOF(off64_t)
 322
 323 AC_C_INLINE
 324 AC_C_LONG_DOUBLE
 325
 326 AC_TYPE_SIGNAL
 327 AC_TYPE_UID_T
 328 AC_TYPE_MODE_T
 329 AC_TYPE_OFF_T
 330 AC_TYPE_SIZE_T
 331 AC_TYPE_PID_T
 332 AC_TYPE_GETGROUPS
 333 AC_CHECK_MEMBERS([struct stat.st_rdev])
 334
 335 TYPE_SOCKLEN_T
 336
 337 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 338     AC_TRY_COMPILE([#include <errno.h>],[int i = errno],
 339         rsync_cv_errno=yes,rsync_cv_have_errno_decl=no)])
 340 if test x"$rsync_cv_errno" = x"yes"; then
 341    AC_DEFINE(HAVE_ERRNO_DECL, 1, [Define to 1 if errno is declared in errno.h])
 342 fi
 343
 344 # The following test taken from the cvs sources
 345 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 346 # These need checks to be before checks for any other functions that
 347 #    might be in the same libraries.
 348 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 349 # libsocket.so which has a bad implementation of gethostbyname (it
 350 # only looks in /etc/hosts), so we only look for -lsocket if we need
 351 # it.
 352 AC_CHECK_FUNCS(connect)
 353 if test x"$ac_cv_func_connect" = x"no"; then
 354     case "$LIBS" in
 355     *-lnsl*) ;;
 356     *) AC_CHECK_LIB(nsl_s, printf) ;;
 357     esac
 358     case "$LIBS" in
 359     *-lnsl*) ;;
 360     *) AC_CHECK_LIB(nsl, printf) ;;
 361     esac
 362     case "$LIBS" in
 363     *-lsocket*) ;;
 364     *) AC_CHECK_LIB(socket, connect) ;;
 365     esac
 366     case "$LIBS" in
 367     *-linet*) ;;
 368     *) AC_CHECK_LIB(inet, connect) ;;
 369     esac
 370     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 371     dnl has been cached.
 372     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 373        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 374         # ac_cv_func_connect=yes
 375         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 376         AC_DEFINE(HAVE_CONNECT, 1, [Define to 1 if you have the "connect" function])
 377     fi
 378 fi
 379
 380 AC_CHECK_LIB(resolv, inet_ntop)
 381
 382 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
 383
 384 AC_CHECK_FUNCS(inet_ntop, , [AC_LIBOBJ(lib/inet_ntop)])
 385 AC_CHECK_FUNCS(inet_pton, , [AC_LIBOBJ(lib/inet_pton)])
 386
 387 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
 388 #   builtin getaddrinfo if one of the defines don't exist
 389 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
 390                rsync_cv_HAVE_GETADDR_DEFINES,[
 391                         AC_EGREP_CPP(yes, [
 392                         #include <sys/types.h>
 393                         #include <sys/socket.h>
 394                         #include <netdb.h>
 395                         #ifdef AI_PASSIVE
 396                         yes
 397                         #endif],
 398                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
 399                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
 400 if test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes"; then
 401         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
 402         # something else so we must include <netdb.h> to get the
 403         # redefinition.
 404         AC_CHECK_FUNCS(getaddrinfo, ,
 405                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
 406                 AC_TRY_LINK([#include <sys/types.h>
 407                 #include <sys/socket.h>
 408                 #include <netdb.h>],[getaddrinfo(NULL, NULL, NULL, NULL);],
 409                         [AC_MSG_RESULT([yes])
 410                         AC_DEFINE(HAVE_GETADDRINFO, 1,
 411                                 [Define to 1 if you have the "getaddrinfo" function.])],
 412                         [AC_MSG_RESULT([no])
 413                         AC_LIBOBJ(lib/getaddrinfo)])])
 414         AC_CHECK_FUNCS(getnameinfo, , [AC_LIBOBJ(lib/getnameinfo)])
 415 else
 416         AC_LIBOBJ(lib/getaddrinfo)
 417         AC_LIBOBJ(lib/getnameinfo)
 418 fi
 419
 420 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 421                 [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ],
 422                 [],
 423                 [
 424 #include <sys/types.h>
 425 #include <sys/socket.h>
 426 ])
 427
 428 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
 429                 [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ],
 430                 [],
 431                 [
 432 #include <sys/types.h>
 433 #include <sys/socket.h>
 434 #include <netinet/in.h>
 435 ])
 436
 437 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 438                 [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ],
 439                 [],
 440                 [
 441 #include <sys/types.h>
 442 #include <sys/socket.h>
 443 #include <netinet/in.h>
 444 ])
 445
 446 AC_MSG_CHECKING(struct sockaddr_storage)
 447 AC_TRY_COMPILE([#include <sys/types.h>
 448 #include <sys/socket.h>],
 449 [struct sockaddr_storage x;],
 450         AC_MSG_RESULT(yes)
 451         AC_DEFINE(HAVE_SOCKADDR_STORAGE, 1,
 452                 [Define to 1 if you have struct sockaddr_storage.] ),
 453         AC_MSG_RESULT(no))
 454
 455 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
 456                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ],
 457                 [],
 458                 [
 459 #include <sys/types.h>
 460 #include <sys/socket.h>
 461 #include <netinet/in.h>
 462 ])
 463
 464 AC_MSG_CHECKING(struct stat64)
 465 AC_TRY_COMPILE([#include <stdio.h>
 466 #if HAVE_SYS_TYPES_H
 467 # include <sys/types.h>
 468 #endif
 469 #if HAVE_SYS_STAT_H
 470 # include <sys/stat.h>
 471 #endif
 472 #if STDC_HEADERS
 473 # include <stdlib.h>
 474 # include <stddef.h>
 475 #else
 476 # if HAVE_STDLIB_H
 477 #  include <stdlib.h>
 478 # endif
 479 #endif
 480 ],[struct stat64 st;],
 481     AC_MSG_RESULT(yes)
 482         AC_DEFINE(HAVE_STRUCT_STAT64,1,[Define to 1 if you have struct stat64.]),
 483     AC_MSG_RESULT(no))
 484
 485 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 486 #
 487 AC_CHECK_FUNCS(strcasecmp)
 488 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 489     AC_CHECK_LIB(resolv, strcasecmp)
 490 fi
 491
 492 dnl At the moment we don't test for a broken memcmp(), because all we
 493 dnl need to do is test for equality, not comparison, and it seems that
 494 dnl every platform has a memcmp that can do at least that.
 495 dnl AC_FUNC_MEMCMP
 496
 497 AC_FUNC_UTIME_NULL
 498 AC_FUNC_ALLOCA
 499 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup chown chmod lchmod mknod mkfifo \
 500     fchmod fstat ftruncate strchr readlink link utime utimes lutimes strftime \
 501     memmove lchown vsnprintf snprintf vasprintf asprintf setsid glob strpbrk \
 502     strlcat strlcpy strtol mallinfo getgroups setgroups geteuid getegid \
 503     setlocale setmode open64 lseek64 mkstemp64 mtrace va_copy __va_copy \
 504     strerror putenv)
 505
 506 AC_CHECK_FUNCS(getpgrp tcgetpgrp)
 507 if test $ac_cv_func_getpgrp = yes; then
 508     AC_FUNC_GETPGRP
 509 fi
 510
 511 # Determine whether chown follows symlinks (it should).
 512 AC_CACHE_CHECK([whether chown() dereferences symlinks],rsync_cv_chown_follows_symlink,[
 513   AC_TRY_RUN([
 514 #if HAVE_UNISTD_H
 515 # include <unistd.h>
 516 #endif
 517 #include <stdlib.h>
 518 #include <errno.h>
 519     main() {
 520         char const *dangling_symlink = "conftest.dangle";
 521         unlink(dangling_symlink);
 522         if (symlink("conftest.no-such", dangling_symlink) < 0) abort();
 523         if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) exit(0);
 524         exit(1);
 525     }],
 526   rsync_cv_chown_follows_symlink=yes,rsync_cv_chown_follows_symlink=no,rsync_cv_chown_follows_symlink=yes)])
 527 if test $rsync_cv_chown_follows_symlink = no; then
 528   AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define to 1 if chown modifies symlinks.])
 529 fi
 530
 531 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
 532 AC_TRY_RUN([
 533 #include <sys/types.h>
 534 #include <sys/socket.h>
 535
 536 main() {
 537        int fd[2];
 538        exit((socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1);
 539 }],
 540 rsync_cv_HAVE_SOCKETPAIR=yes,rsync_cv_HAVE_SOCKETPAIR=no,rsync_cv_HAVE_SOCKETPAIR=cross)])
 541 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
 542     AC_DEFINE(HAVE_SOCKETPAIR, 1, [Define to 1 if you have the "socketpair" function])
 543 fi
 544
 545 if test x"$with_included_popt" != x"yes"
 546 then
 547     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
 548 fi
 549
 550 AC_MSG_CHECKING([whether to use included libpopt])
 551 if test x"$with_included_popt" = x"yes"
 552 then
 553     AC_MSG_RESULT($srcdir/popt)
 554     BUILD_POPT='$(popt_OBJS)'
 555     CFLAGS="$CFLAGS -I$srcdir/popt"
 556     if test x"$ALLOCA" != x
 557     then
 558         # this can be removed when/if we add an included alloca.c;
 559         #  see autoconf documentation on AC_FUNC_ALLOCA
 560         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
 561     fi
 562 else
 563     AC_MSG_RESULT(no)
 564 fi
 565
 566 AC_CACHE_CHECK([for unsigned char],rsync_cv_SIGNED_CHAR_OK,[
 567 AC_TRY_COMPILE([],[signed char *s = ""],
 568 rsync_cv_SIGNED_CHAR_OK=yes,rsync_cv_SIGNED_CHAR_OK=no)])
 569 if test x"$rsync_cv_SIGNED_CHAR_OK" = x"yes"; then
 570     AC_DEFINE(SIGNED_CHAR_OK, 1, [Define to 1 if "signed char" is a valid type])
 571 fi
 572
 573 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
 574 AC_TRY_RUN([#include <sys/types.h>
 575 #include <dirent.h>
 576 main() { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
 577 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
 578 di->d_name[0] == 0) exit(0); exit(1);} ],
 579 rsync_cv_HAVE_BROKEN_READDIR=yes,rsync_cv_HAVE_BROKEN_READDIR=no,rsync_cv_HAVE_BROKEN_READDIR=cross)])
 580 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
 581     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [Define to 1 if readdir() is broken])
 582 fi
 583
 584 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_UTIMBUF,[
 585 AC_TRY_COMPILE([#include <sys/types.h>
 586 #include <utime.h>],
 587 [struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; exit(utime("foo.c",&tbuf));],
 588 rsync_cv_HAVE_UTIMBUF=yes,rsync_cv_HAVE_UTIMBUF=no)])
 589 if test x"$rsync_cv_HAVE_UTIMBUF" = x"yes"; then
 590     AC_DEFINE(HAVE_UTIMBUF, 1, [Define to 1 if you have the "struct utimbuf" type])
 591 fi
 592
 593 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
 594 AC_TRY_COMPILE([#include <sys/time.h>
 595 #include <unistd.h>],
 596 [struct timeval tv; exit(gettimeofday(&tv, NULL));],
 597 rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes,rsync_cv_HAVE_GETTIMEOFDAY_TZ=no)])
 598 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then
 599     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [Define to 1 if gettimeofday() takes a time-zone arg])
 600 fi
 601
 602 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
 603 AC_TRY_RUN([
 604 #include <sys/types.h>
 605 #include <stdarg.h>
 606 void foo(const char *format, ...) {
 607        va_list ap;
 608        int len;
 609        char buf[5];
 610
 611        va_start(ap, format);
 612        len = vsnprintf(0, 0, format, ap);
 613        va_end(ap);
 614        if (len != 5) exit(1);
 615
 616        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 617
 618        exit(0);
 619 }
 620 main() { foo("hello"); }
 621 ],
 622 rsync_cv_HAVE_C99_VSNPRINTF=yes,rsync_cv_HAVE_C99_VSNPRINTF=no,rsync_cv_HAVE_C99_VSNPRINTF=cross)])
 623 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 624     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [Define to 1 if vsprintf has a C99-compatible return value])
 625 fi
 626
 627
 628 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
 629 AC_TRY_RUN([#include <stdlib.h>
 630 #include <sys/types.h>
 631 #include <sys/stat.h>
 632 #include <unistd.h>
 633 main() {
 634   struct stat st;
 635   char tpl[20]="/tmp/test.XXXXXX";
 636   int fd = mkstemp(tpl);
 637   if (fd == -1) exit(1);
 638   unlink(tpl);
 639   if (fstat(fd, &st) != 0) exit(1);
 640   if ((st.st_mode & 0777) != 0600) exit(1);
 641   exit(0);
 642 }],
 643 rsync_cv_HAVE_SECURE_MKSTEMP=yes,
 644 rsync_cv_HAVE_SECURE_MKSTEMP=no,
 645 rsync_cv_HAVE_SECURE_MKSTEMP=cross)])
 646 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
 647     case $target_os in
 648     hpux*)
 649         dnl HP-UX has a broken mkstemp() implementation they refuse to fix,
 650         dnl so we noisily skip using it.  See HP change request JAGaf34426
 651         dnl for details. (sbonds)
 652         AC_MSG_WARN(Skipping broken HP-UX mkstemp() -- using mktemp() instead)
 653         ;;
 654     *)
 655         AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [Define to 1 if mkstemp() is available and works right])
 656         ;;
 657     esac
 658 fi
 659
 660
 661 AC_CACHE_CHECK([for broken inet_ntoa],rsync_cv_REPLACE_INET_NTOA,[
 662 AC_TRY_RUN([
 663 #include <stdio.h>
 664 #include <sys/types.h>
 665 #include <netinet/in.h>
 666 #include <arpa/inet.h>
 667 main() { struct in_addr ip; ip.s_addr = 0x12345678;
 668 if (strcmp(inet_ntoa(ip),"18.52.86.120") &&
 669     strcmp(inet_ntoa(ip),"120.86.52.18")) { exit(1); }
 670 exit(0);}],
 671            rsync_cv_REPLACE_INET_NTOA=no,rsync_cv_REPLACE_INET_NTOA=yes,rsync_cv_REPLACE_INET_NTOA=cross)])
 672 if test x"$rsync_cv_REPLACE_INET_NTOA" = x"yes"; then
 673     AC_DEFINE(REPLACE_INET_NTOA, 1, [Define to 1 if inet_ntoa() needs to be replaced])
 674 fi
 675
 676
 677 AC_CACHE_CHECK([for broken inet_aton],rsync_cv_REPLACE_INET_ATON,[
 678 AC_TRY_RUN([
 679 #include <stdio.h>
 680 #include <sys/types.h>
 681 #include <netinet/in.h>
 682 #include <arpa/inet.h>
 683 main() { struct in_addr ip;
 684 if (inet_aton("example", &ip) == 0) exit(0); exit(1);}],
 685            rsync_cv_REPLACE_INET_ATON=no,rsync_cv_REPLACE_INET_ATON=yes,rsync_cv_REPLACE_INET_ATON=cross)])
 686 if test x"$rsync_cv_REPLACE_INET_ATON" = x"yes"; then
 687     AC_DEFINE(REPLACE_INET_ATON, 1, [Define to 1 if inet_aton() needs to be replaced])
 688 fi
 689
 690 AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[
 691 AC_TRY_RUN([
 692 #include <stdio.h>
 693 #include <sys/stat.h>
 694 #include <errno.h>
 695 main() { int rc, ec; char *fn = "fifo-test";
 696 unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn);
 697 if (rc) {printf("%d %d\n",rc,ec); return ec;}
 698 return 0;}],
 699            rsync_cv_MKNOD_CREATES_FIFOS=yes,rsync_cv_MKNOD_CREATES_FIFOS=no,rsync_cv_MKNOD_CREATES_FIFOS=cross)])
 700 if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then
 701     AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.])
 702 fi
 703
 704 AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[
 705 AC_TRY_RUN([
 706 #include <stdio.h>
 707 #include <sys/stat.h>
 708 #include <errno.h>
 709 main() { int rc, ec; char *fn = "sock-test";
 710 unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn);
 711 if (rc) {printf("%d %d\n",rc,ec); return ec;}
 712 return 0;}],
 713            rsync_cv_MKNOD_CREATES_SOCKETS=yes,rsync_cv_MKNOD_CREATES_SOCKETS=no,rsync_cv_MKNOD_CREATES_SOCKETS=cross)])
 714 if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then
 715     AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.])
 716 fi
 717
 718 #
 719 # The following test was mostly taken from the tcl/tk plus patches
 720 #
 721 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
 722 rm -rf conftest*
 723 cat > conftest.$ac_ext <<EOF
 724 int main() { return 0; }
 725 EOF
 726 ${CC-cc} -c -o conftest..o conftest.$ac_ext
 727 if test -f conftest..o; then
 728     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
 729 else
 730     rsync_cv_DASHC_WORKS_WITH_DASHO=no
 731 fi
 732 rm -rf conftest*
 733 ])
 734 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
 735     OBJ_SAVE="#"
 736     OBJ_RESTORE="#"
 737     CC_SHOBJ_FLAG='-o $@'
 738 else
 739     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
 740     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
 741     CC_SHOBJ_FLAG=""
 742 fi
 743
 744 AC_SUBST(OBJ_SAVE)
 745 AC_SUBST(OBJ_RESTORE)
 746 AC_SUBST(CC_SHOBJ_FLAG)
 747 AC_SUBST(BUILD_POPT)
 748
 749 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
 750 AC_OUTPUT
 751
 752 AC_MSG_RESULT()
 753 AC_MSG_RESULT([    rsync ${RSYNC_VERSION} configuration successful])
 754 AC_MSG_RESULT()