configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT()
   4 AC_CONFIG_SRCDIR([byteorder.h])
   5 AC_CONFIG_HEADER(config.h)
   6 AC_PREREQ(2.52)
   7
   8 LDFLAGS=${LDFLAGS-""}
   9
  10 AC_CANONICAL_TARGET([])
  11
  12 dnl Checks for programs.
  13 AC_PROG_CC
  14 AC_PROG_CPP
  15 AC_PROG_INSTALL
  16 AC_SUBST(SHELL)
  17
  18 RSYNC_VERSION=2.4.7pre3
  19 AC_SUBST(RSYNC_VERSION)
  20 AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$RSYNC_VERSION"], [rsync release version])
  21
  22 # compile with optimisation and without debugging by default, unless
  23 # --debug is given.  We must decide this before testing the compiler.
  24
  25 AC_MSG_CHECKING([whether to include debugging symbols])
  26 AC_ARG_ENABLE(debug,
  27         AC_HELP_STRING([--enable-debug],
  28                 [including debugging symbols and features (default yes)]),
  29                 [], [])
  30
  31 if test x"$enable_debug" = x"no"
  32 then
  33     AC_MSG_RESULT(no)
  34     CFLAGS=${CFLAGS-"-O"}
  35 else
  36     AC_MSG_RESULT([yes])
  37     # leave CFLAGS alone; AC_PROG_CC will try to include -g if it can
  38     AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  39     dnl CFLAGS=${CFLAGS-"-g"}
  40 fi
  41
  42 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
  43
  44 AC_ARG_WITH(included-popt,
  45         [  --with-included-popt    use bundled popt library, not from system])
  46
  47 AC_ARG_WITH(rsync-path,
  48         [  --with-rsync-path=PATH  set default --rsync-path to PATH (default: \"rsync\")],
  49         [ RSYNC_PATH="$with_rsync_path" ],
  50         [ RSYNC_PATH="rsync" ])
  51 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [ ])
  52
  53 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
  54 AC_DEFINE_UNQUOTED(HAVE_REMSH, $HAVE_REMSH, [ ])
  55
  56
  57 # arrgh. libc in the current debian stable screws up the largefile
  58 # stuff, getting byte range locking wrong
  59 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
  60 AC_TRY_RUN([
  61 #define _FILE_OFFSET_BITS 64
  62 #include <stdio.h>
  63 #include <fcntl.h>
  64 #include <sys/types.h>
  65 #include <sys/wait.h>
  66
  67 int main(void)
  68 {
  69         struct flock lock;
  70         int status;
  71         int fd = open("conftest.dat", O_CREAT|O_RDWR, 0600);
  72         lock.l_type = F_WRLCK;
  73         lock.l_whence = SEEK_SET;
  74         lock.l_start = 0;
  75         lock.l_len = 1;
  76         lock.l_pid = 0;
  77
  78         fcntl(fd,F_SETLK,&lock);
  79         if (fork() == 0) {
  80                 lock.l_start = 1;
  81                 exit(fcntl(fd,F_SETLK,&lock) == 0);
  82         }
  83         wait(&status);
  84         unlink("conftest.dat");
  85         exit(WEXITSTATUS(status));
  86 }
  87 ],
  88 rsync_cv_HAVE_BROKEN_LARGEFILE=yes,rsync_cv_HAVE_BROKEN_LARGEFILE=no,rsync_cv_HAVE_BROKEN_LARGEFILE=cross)])
  89 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
  90    AC_SYS_LARGEFILE
  91 fi
  92
  93
  94
  95 AC_DEFINE(ss_family, __ss_family, [KAME hack])
  96 AC_DEFINE(ss_len, __ss_len, [KAME hack])
  97
  98 CFLAGS="$CFLAGS"
  99 AC_ARG_ENABLE(ipv6,
 100         AC_HELP_STRING([--enable-ipv6], [try to support IPv6]))
 101 AC_MSG_CHECKING([whether IPv6 is requested])
 102 if test "$xenable_ipv6" = xyes
 103 then
 104         AC_MSG_RESULT(yes)
 105         ipv6=yes
 106 else
 107         AC_MSG_RESULT(no)
 108         ipv6=no
 109 fi
 110
 111 ipv6type=unknown
 112 ipv6lib=none
 113 ipv6trylibc=no
 114
 115 if test "$ipv6" = "yes"; then
 116         AC_MSG_CHECKING([ipv6 stack type])
 117         for i in inria kame linux-glibc linux-inet6 toshiba v6d zeta; do
 118                 case $i in
 119                 inria)
 120                         # http://www.kame.net/
 121                         AC_EGREP_CPP(yes, [
 122 #include <netinet/in.h>
 123 #ifdef IPV6_INRIA_VERSION
 124 yes
 125 #endif],
 126                                 [ipv6type=$i;
 127                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 128                                 ])
 129                         ;;
 130                 kame)
 131                         # http://www.kame.net/
 132                         AC_EGREP_CPP(yes, [
 133 #include <netinet/in.h>
 134 #ifdef __KAME__
 135 yes
 136 #endif],
 137                                 [ipv6type=$i;
 138                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 139                         ;;
 140                 linux-glibc)
 141                         # http://www.v6.linux.or.jp/
 142                         AC_EGREP_CPP(yes, [
 143 #include <features.h>
 144 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 145 yes
 146 #endif],
 147                                 [ipv6type=$i;
 148 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 149                         ;;
 150                 linux-inet6)
 151                         # http://www.v6.linux.or.jp/
 152                         if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
 153                                 ipv6type=$i
 154                                 ipv6lib=inet6
 155                                 ipv6libdir=/usr/inet6/lib
 156                                 ipv6trylibc=yes;
 157                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 158                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 159                         fi
 160                         ;;
 161                 toshiba)
 162                         AC_EGREP_CPP(yes, [
 163 #include <sys/param.h>
 164 #ifdef _TOSHIBA_INET6
 165 yes
 166 #endif],
 167                                 [ipv6type=$i;
 168                                 ipv6lib=inet6;
 169                                 ipv6libdir=/usr/local/v6/lib;
 170                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 171                         ;;
 172                 v6d)
 173                         AC_EGREP_CPP(yes, [
 174 #include </usr/local/v6/include/sys/v6config.h>
 175 #ifdef __V6D__
 176 yes
 177 #endif],
 178                                 [ipv6type=$i;
 179                                 ipv6lib=v6;
 180                                 ipv6libdir=/usr/local/v6/lib;
 181                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 182                         ;;
 183                 zeta)
 184                         AC_EGREP_CPP(yes, [
 185 #include <sys/param.h>
 186 #ifdef _ZETA_MINAMI_INET6
 187 yes
 188 #endif],
 189                                 [ipv6type=$i;
 190                                 ipv6lib=inet6;
 191                                 ipv6libdir=/usr/local/v6/lib;
 192                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 193                         ;;
 194                 esac
 195                 if test "$ipv6type" != "unknown"; then
 196                         break
 197                 fi
 198         done
 199         AC_MSG_RESULT($ipv6type)
 200 fi
 201
 202 if test "$ipv6" = "yes" -a -f /usr/local/v6/lib/libinet6.a; then
 203         ac_inet6_LDFLAGS="inet6"
 204         ipv6libdir=/usr/local/v6/lib
 205         LDFLAGS="$LDFLAGS -L/usr/local/v6/lib"
 206         AC_CHECK_LIB(inet6, getaddrinfo, , ipv6lib="$ac_inet6_LDFLAGS")
 207 fi
 208
 209 if test "$ipv6" = "yes" -a -f /usr/lib/libinet6.a; then
 210         ac_inet6_LDFLAGS="inet6"
 211         AC_CHECK_LIB(inet6, getaddrinfo, , ipv6lib="$ac_inet6_LDFLAGS")
 212 fi
 213
 214 if test "$ipv6" = "yes" -a "$ipv6lib" != "none"; then
 215         if test -d $ipv6libdir -a -f $ipv6libdir/lib$ipv6lib.a; then
 216                 LIBS="-L$ipv6libdir -l$ipv6lib $LIBS"
 217                 AC_MSG_NOTICE([You have $ipv6lib library, using it])
 218         else
 219                 if test "$ipv6trylibc" = "yes"; then
 220                         AC_MSG_WARN([You do not have $ipv6lib library, using libc])
 221                 else
 222                         AC_MSG_ERROR([No $ipv6lib library found.  cannot continue.  You need to fetch lib$ipv6lib.a from appropriate ipv6 kit and compile beforehand.])
 223                 fi
 224         fi
 225 fi
 226
 227
 228 AC_MSG_CHECKING(getaddrinfo bug)
 229 AC_TRY_RUN([
 230 #include <sys/types.h>
 231 #include <netdb.h>
 232 #include <string.h>
 233 #include <sys/socket.h>
 234 #include <netinet/in.h>
 235
 236 main()
 237 {
 238   int passive, gaierr, inet4 = 0, inet6 = 0;
 239   struct addrinfo hints, *ai, *aitop;
 240   char straddr[INET6_ADDRSTRLEN], strport[16];
 241
 242   for (passive = 0; passive <= 1; passive++) {
 243     memset(&hints, 0, sizeof(hints));
 244     hints.ai_family = AF_UNSPEC;
 245     hints.ai_flags = passive ? AI_PASSIVE : 0;
 246     hints.ai_socktype = SOCK_STREAM;
 247     if ((gaierr = getaddrinfo(NULL, "54321", &hints, &aitop)) != 0) {
 248       (void)gai_strerror(gaierr);
 249       goto bad;
 250     }
 251     for (ai = aitop; ai; ai = ai->ai_next) {
 252       if (ai->ai_addr == NULL ||
 253           ai->ai_addrlen == 0 ||
 254           getnameinfo(ai->ai_addr, ai->ai_addrlen,
 255                       straddr, sizeof(straddr), strport, sizeof(strport),
 256                       NI_NUMERICHOST|NI_NUMERICSERV) != 0) {
 257         goto bad;
 258       }
 259       switch (ai->ai_family) {
 260       case AF_INET:
 261         if (strcmp(strport, "54321") != 0) {
 262           goto bad;
 263         }
 264         if (passive) {
 265           if (strcmp(straddr, "0.0.0.0") != 0) {
 266             goto bad;
 267           }
 268         } else {
 269           if (strcmp(straddr, "127.0.0.1") != 0) {
 270             goto bad;
 271           }
 272         }
 273         inet4++;
 274         break;
 275       case AF_INET6:
 276         if (strcmp(strport, "54321") != 0) {
 277           goto bad;
 278         }
 279         if (passive) {
 280           if (strcmp(straddr, "::") != 0) {
 281             goto bad;
 282           }
 283         } else {
 284           if (strcmp(straddr, "::1") != 0) {
 285             goto bad;
 286           }
 287         }
 288         inet6++;
 289         break;
 290       case AF_UNSPEC:
 291         goto bad;
 292         break;
 293       default:
 294         /* another family support? */
 295         break;
 296       }
 297     }
 298   }
 299
 300   if (!(inet4 == 0 || inet4 == 2))
 301     goto bad;
 302   if (!(inet6 == 0 || inet6 == 2))
 303     goto bad;
 304
 305   if (aitop)
 306     freeaddrinfo(aitop);
 307   exit(0);
 308
 309  bad:
 310   if (aitop)
 311     freeaddrinfo(aitop);
 312   exit(1);
 313 }
 314 ],
 315 AC_MSG_RESULT(good)
 316 buggygetaddrinfo=no,
 317 AC_MSG_RESULT(buggy)
 318 buggygetaddrinfo=yes,
 319 AC_MSG_RESULT(buggy)
 320 buggygetaddrinfo=yes)
 321
 322 if test "$buggygetaddrinfo" = "yes"; then
 323         if test "$ipv6" = "yes" -a "$ipv6type" != "linux"; then
 324                 AC_MSG_ERROR([You must get working getaddrinfo() function or you can specify "--disable-ipv6"])
 325         elif test "$ipv6type" = "linux"; then
 326                 AC_MSG_ERROR([getaddrinfo() implementation on your system seems be buggy.  Better upgrade your system library to newest version of GNU C library (aka glibc).])
 327         fi
 328 fi
 329 AC_REPLACE_FUNCS(getaddrinfo getnameinfo)
 330
 331 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 332                 [ AC_DEFINE(HAVE_SOCKADDR_LEN) ],
 333                 [],
 334                 [
 335 #include <sys/types.h>
 336 #include <sys/socket.h>
 337 ])
 338
 339 AC_C_BIGENDIAN
 340 AC_HEADER_DIRENT
 341 AC_HEADER_TIME
 342 AC_HEADER_SYS_WAIT
 343 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h unistd.h utime.h grp.h)
 344 AC_CHECK_HEADERS(compat.h sys/param.h ctype.h sys/wait.h sys/ioctl.h)
 345 AC_CHECK_HEADERS(sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h)
 346 AC_CHECK_HEADERS(glob.h alloca.h mcheck.h)
 347
 348 AC_CHECK_SIZEOF(int)
 349 AC_CHECK_SIZEOF(long)
 350 AC_CHECK_SIZEOF(short)
 351
 352 AC_C_INLINE
 353
 354 AC_TYPE_SIGNAL
 355 AC_TYPE_UID_T
 356 AC_TYPE_MODE_T
 357 AC_TYPE_OFF_T
 358 AC_TYPE_SIZE_T
 359 AC_TYPE_PID_T
 360 AC_TYPE_GETGROUPS
 361 AC_CHECK_MEMBERS([struct stat.st_rdev])
 362
 363 AC_CHECK_TYPE([ino_t], [unsigned])
 364 TYPE_SOCKLEN_T
 365
 366 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 367     AC_TRY_COMPILE([#include <errno.h>],[int i = errno],
 368         rsync_cv_errno=yes,rsync_cv_have_errno_decl=no)])
 369 if test x"$rsync_cv_errno" = x"yes"; then
 370    AC_DEFINE(HAVE_ERRNO_DECL, 1, [ ])
 371 fi
 372
 373 # The following test taken from the cvs sources
 374 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 375 # These need checks to be before checks for any other functions that
 376 #    might be in the same libraries.
 377 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 378 # libsocket.so which has a bad implementation of gethostbyname (it
 379 # only looks in /etc/hosts), so we only look for -lsocket if we need
 380 # it.
 381 AC_CHECK_FUNCS(connect)
 382 if test x"$ac_cv_func_connect" = x"no"; then
 383     case "$LIBS" in
 384     *-lnsl*) ;;
 385     *) AC_CHECK_LIB(nsl_s, printf) ;;
 386     esac
 387     case "$LIBS" in
 388     *-lnsl*) ;;
 389     *) AC_CHECK_LIB(nsl, printf) ;;
 390     esac
 391     case "$LIBS" in
 392     *-lsocket*) ;;
 393     *) AC_CHECK_LIB(socket, connect) ;;
 394     esac
 395     case "$LIBS" in
 396     *-linet*) ;;
 397     *) AC_CHECK_LIB(inet, connect) ;;
 398     esac
 399     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 400     dnl has been cached.
 401     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 402        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 403         # ac_cv_func_connect=yes
 404         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 405         AC_DEFINE(HAVE_CONNECT, 1, [ ])
 406     fi
 407 fi
 408
 409 #
 410 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 411 #
 412 AC_CHECK_FUNCS(strcasecmp)
 413 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 414     AC_CHECK_LIB(resolv, strcasecmp)
 415 fi
 416
 417 AC_FUNC_MEMCMP
 418 AC_FUNC_UTIME_NULL
 419 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup strerror chown chmod mknod)
 420 AC_CHECK_FUNCS(fchmod fstat strchr readlink link utime utimes strftime)
 421 AC_CHECK_FUNCS(memmove lchown vsnprintf snprintf asprintf setsid glob strpbrk)
 422 AC_CHECK_FUNCS(strlcat strlcpy mtrace)
 423
 424 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
 425 AC_TRY_RUN([#include <sys/types.h>
 426             #include <sys/socket.h>
 427             main() {
 428                 int fd[2];
 429                 exit((socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1);
 430             }],
 431 rsync_cv_HAVE_SOCKETPAIR=yes,rsync_cv_HAVE_SOCKETPAIR=no,rsync_cv_HAVE_SOCKETPAIR=cross)])
 432 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
 433     AC_DEFINE(HAVE_SOCKETPAIR, 1, [ ])
 434 fi
 435
 436 AC_CACHE_CHECK([for working fnmatch],rsync_cv_HAVE_FNMATCH,[
 437 AC_TRY_RUN([#include <fnmatch.h>
 438 main() { exit((fnmatch("*.o", "x.o", FNM_PATHNAME) == 0 &&
 439                fnmatch("a/b/*", "a/b/c/d", FNM_PATHNAME) != 0) ? 0: 1); }],
 440 rsync_cv_HAVE_FNMATCH=yes,rsync_cv_HAVE_FNMATCH=no,rsync_cv_HAVE_FNMATCH=cross)])
 441 if test x"$rsync_cv_HAVE_FNMATCH" = x"yes"; then
 442     AC_DEFINE(HAVE_FNMATCH, 1, [ ])
 443 fi
 444
 445 if test x"$with_included_popt" != x"yes"
 446 then
 447     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
 448 fi
 449
 450 AC_MSG_CHECKING([whether to use included libpopt])
 451 if test x"$with_included_popt" = x"yes"
 452 then
 453     AC_MSG_RESULT($srcdir/popt)
 454     BUILD_POPT='$(popt_OBJS)'
 455     CFLAGS="$CFLAGS -I$srcdir/popt"
 456 else
 457     AC_MSG_RESULT(no)
 458 fi
 459
 460 AC_CACHE_CHECK([for long long],rsync_cv_HAVE_LONGLONG,[
 461 AC_TRY_RUN([#include <stdio.h>
 462 main() { long long x = 1000000; x *= x; exit(((x/1000000) == 1000000)? 0: 1); }],
 463 rsync_cv_HAVE_LONGLONG=yes,rsync_cv_HAVE_LONGLONG=no,rsync_cv_HAVE_LONGLONG=cross)])
 464 if test x"$rsync_cv_HAVE_LONGLONG" = x"yes"; then
 465     AC_DEFINE(HAVE_LONGLONG, 1, [ ])
 466 fi
 467
 468 AC_CACHE_CHECK([for off64_t],rsync_cv_HAVE_OFF64_T,[
 469 AC_TRY_RUN([#include <stdio.h>
 470 #include <sys/stat.h>
 471 main() { struct stat64 st; off64_t s; if (sizeof(off_t) == sizeof(off64_t)) exit(1); exit((lstat64("/dev/null", &st)==0)?0:1); }],
 472 rsync_cv_HAVE_OFF64_T=yes,rsync_cv_HAVE_OFF64_T=no,rsync_cv_HAVE_OFF64_T=cross)])
 473 if test x"$rsync_cv_HAVE_OFF64_T" = x"yes"; then
 474     AC_DEFINE(HAVE_OFF64_T, 1, [ ])
 475 fi
 476
 477 AC_CACHE_CHECK([for short ino_t],rsync_cv_HAVE_SHORT_INO_T,[
 478 AC_TRY_RUN([#include <stdio.h>
 479 #include <sys/types.h>
 480 #include <sys/stat.h>
 481 main() { if (sizeof(ino_t) < sizeof(unsigned int)) return 0; return 1; }],
 482 rsync_cv_HAVE_SHORT_INO_T=yes,rsync_cv_HAVE_SHORT_INO_T=no,rsync_cv_HAVE_SHORT_INO_T=cross)])
 483 if test x"$rsync_cv_HAVE_SHORT_INO_T" = x"yes"; then
 484     AC_DEFINE(HAVE_SHORT_INO_T, 1, [ ])
 485 fi
 486
 487 AC_CACHE_CHECK([for unsigned char],rsync_cv_HAVE_UNSIGNED_CHAR,[
 488 AC_TRY_RUN([#include <stdio.h>
 489 main() { char c; c=250; exit((c > 0)?0:1); }],
 490 rsync_cv_HAVE_UNSIGNED_CHAR=yes,rsync_cv_HAVE_UNSIGNED_CHAR=no,rsync_cv_HAVE_UNSIGNED_CHAR=cross)])
 491 if test x"$rsync_cv_HAVE_UNSIGNED_CHAR" = x"yes"; then
 492     AC_DEFINE(HAVE_UNSIGNED_CHAR, 1, [ ])
 493 fi
 494
 495 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
 496 AC_TRY_RUN([#include <sys/types.h>
 497 #include <dirent.h>
 498 main() { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
 499 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
 500 di->d_name[0] == 0) exit(0); exit(1);} ],
 501 rsync_cv_HAVE_BROKEN_READDIR=yes,rsync_cv_HAVE_BROKEN_READDIR=no,rsync_cv_HAVE_BROKEN_READDIR=cross)])
 502 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
 503     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [ ])
 504 fi
 505
 506 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_UTIMBUF,[
 507 AC_TRY_COMPILE([#include <sys/types.h>
 508 #include <utime.h>],
 509 [struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; exit(utime("foo.c",&tbuf));],
 510 rsync_cv_HAVE_UTIMBUF=yes,rsync_cv_HAVE_UTIMBUF=no,rsync_cv_HAVE_UTIMBUF=cross)])
 511 if test x"$rsync_cv_HAVE_UTIMBUF" = x"yes"; then
 512     AC_DEFINE(HAVE_UTIMBUF, 1, [ ])
 513 fi
 514
 515 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
 516 AC_TRY_RUN([
 517 #include <sys/time.h>
 518 #include <unistd.h>
 519 main() { struct timeval tv; exit(gettimeofday(&tv, NULL));}],
 520            rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes,rsync_cv_HAVE_GETTIMEOFDAY_TZ=no,rsync_cv_HAVE_GETTIMEOFDAY_TZ=cross)])
 521 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" = x"yes"; then
 522     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [ ])
 523 fi
 524
 525 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
 526 AC_TRY_RUN([
 527 #include <sys/types.h>
 528 #include <stdarg.h>
 529 void foo(const char *format, ...) {
 530        va_list ap;
 531        int len;
 532        char buf[5];
 533
 534        va_start(ap, format);
 535        len = vsnprintf(0, 0, format, ap);
 536        va_end(ap);
 537        if (len != 5) exit(1);
 538
 539        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 540
 541        exit(0);
 542 }
 543 main() { foo("hello"); }
 544 ],
 545 rsync_cv_HAVE_C99_VSNPRINTF=yes,rsync_cv_HAVE_C99_VSNPRINTF=no,rsync_cv_HAVE_C99_VSNPRINTF=cross)])
 546 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 547     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [ ])
 548 fi
 549
 550
 551 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
 552 AC_TRY_RUN([#include <stdlib.h>
 553 #include <sys/types.h>
 554 #include <sys/stat.h>
 555 #include <unistd.h>
 556 main() {
 557   struct stat st;
 558   char tpl[20]="/tmp/test.XXXXXX";
 559   int fd = mkstemp(tpl);
 560   if (fd == -1) exit(1);
 561   unlink(tpl);
 562   if (fstat(fd, &st) != 0) exit(1);
 563   if ((st.st_mode & 0777) != 0600) exit(1);
 564   exit(0);
 565 }],
 566 rsync_cv_HAVE_SECURE_MKSTEMP=yes,
 567 rsync_cv_HAVE_SECURE_MKSTEMP=no,
 568 rsync_cv_HAVE_SECURE_MKSTEMP=cross)])
 569 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
 570     AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [ ])
 571 fi
 572
 573
 574 AC_CACHE_CHECK([for broken inet_ntoa],rsync_cv_REPLACE_INET_NTOA,[
 575 AC_TRY_RUN([
 576 #include <stdio.h>
 577 #include <sys/types.h>
 578 #include <netinet/in.h>
 579 #include <arpa/inet.h>
 580 main() { struct in_addr ip; ip.s_addr = 0x12345678;
 581 if (strcmp(inet_ntoa(ip),"18.52.86.120") &&
 582     strcmp(inet_ntoa(ip),"120.86.52.18")) { exit(1); }
 583 exit(0);}],
 584            rsync_cv_REPLACE_INET_NTOA=no,rsync_cv_REPLACE_INET_NTOA=yes,rsync_cv_REPLACE_INET_NTOA=cross)])
 585 if test x"$rsync_cv_REPLACE_INET_NTOA" = x"yes"; then
 586     AC_DEFINE(REPLACE_INET_NTOA, 1, [ ])
 587 fi
 588
 589
 590 AC_CACHE_CHECK([for broken inet_aton],rsync_cv_REPLACE_INET_ATON,[
 591 AC_TRY_RUN([
 592 #include <stdio.h>
 593 #include <sys/types.h>
 594 #include <netinet/in.h>
 595 #include <arpa/inet.h>
 596 main() { struct in_addr ip;
 597 if (inet_aton("example", &ip) == 0) exit(0); exit(1);}],
 598            rsync_cv_REPLACE_INET_ATON=no,rsync_cv_REPLACE_INET_ATON=yes,rsync_cv_REPLACE_INET_ATON=cross)])
 599 if test x"$rsync_cv_REPLACE_INET_ATON" = x"yes"; then
 600     AC_DEFINE(REPLACE_INET_ATON, 1, [ ])
 601 fi
 602
 603 #
 604 # The following test was mostly taken from the tcl/tk plus patches
 605 #
 606 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
 607 rm -rf conftest*
 608 cat > conftest.$ac_ext <<EOF
 609 int main() { return 0; }
 610 EOF
 611 ${CC-cc} -c -o conftest..o conftest.$ac_ext
 612 if test -f conftest..o; then
 613     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
 614 else
 615     rsync_cv_DASHC_WORKS_WITH_DASHO=no
 616 fi
 617 rm -rf conftest*
 618 ])
 619 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
 620     OBJ_SAVE="#"
 621     OBJ_RESTORE="#"
 622     CC_SHOBJ_FLAG='-o $@'
 623 else
 624     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
 625     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
 626     CC_SHOBJ_FLAG=""
 627 fi
 628
 629 AC_SUBST(OBJ_SAVE)
 630 AC_SUBST(OBJ_RESTORE)
 631 AC_SUBST(CC_SHOBJ_FLAG)
 632 AC_SUBST(BUILD_POPT)
 633
 634 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
 635 AC_OUTPUT