configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT()
   4 AC_CONFIG_SRCDIR([byteorder.h])
   5 AC_CONFIG_HEADER(config.h)
   6 AC_PREREQ(2.52)
   7
   8 LDFLAGS=${LDFLAGS-""}
   9
  10 AC_CANONICAL_TARGET([])
  11
  12 dnl Checks for programs.
  13 AC_PROG_CC
  14 AC_PROG_CPP
  15 AC_PROG_INSTALL
  16 AC_SUBST(SHELL)
  17
  18 RSYNC_VERSION=2.4.7pre4
  19 AC_SUBST(RSYNC_VERSION)
  20 AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$RSYNC_VERSION"], [rsync release version])
  21
  22 # compile with optimisation and without debugging by default, unless
  23 # --debug is given.  We must decide this before testing the compiler.
  24
  25 AC_MSG_CHECKING([whether to include debugging symbols])
  26 AC_ARG_ENABLE(debug,
  27         AC_HELP_STRING([--enable-debug],
  28                 [including debugging symbols and features (default yes)]),
  29                 [], [])
  30
  31 if test x"$enable_debug" = x"no"
  32 then
  33     AC_MSG_RESULT(no)
  34     CFLAGS=${CFLAGS-"-O"}
  35 else
  36     AC_MSG_RESULT([yes])
  37     # leave CFLAGS alone; AC_PROG_CC will try to include -g if it can
  38     AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  39     dnl CFLAGS=${CFLAGS-"-g"}
  40 fi
  41
  42 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
  43
  44 AC_ARG_WITH(included-popt,
  45         [  --with-included-popt    use bundled popt library, not from system])
  46
  47 AC_ARG_WITH(rsync-path,
  48         [  --with-rsync-path=PATH  set default --rsync-path to PATH (default: \"rsync\")],
  49         [ RSYNC_PATH="$with_rsync_path" ],
  50         [ RSYNC_PATH="rsync" ])
  51 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [ ])
  52
  53 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
  54 AC_DEFINE_UNQUOTED(HAVE_REMSH, $HAVE_REMSH, [ ])
  55
  56
  57 # arrgh. libc in the current debian stable screws up the largefile
  58 # stuff, getting byte range locking wrong
  59 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
  60 AC_TRY_RUN([
  61 #define _FILE_OFFSET_BITS 64
  62 #include <stdio.h>
  63 #include <fcntl.h>
  64 #include <sys/types.h>
  65 #include <sys/wait.h>
  66
  67 int main(void)
  68 {
  69         struct flock lock;
  70         int status;
  71         int fd = open("conftest.dat", O_CREAT|O_RDWR, 0600);
  72         lock.l_type = F_WRLCK;
  73         lock.l_whence = SEEK_SET;
  74         lock.l_start = 0;
  75         lock.l_len = 1;
  76         lock.l_pid = 0;
  77
  78         fcntl(fd,F_SETLK,&lock);
  79         if (fork() == 0) {
  80                 lock.l_start = 1;
  81                 exit(fcntl(fd,F_SETLK,&lock) == 0);
  82         }
  83         wait(&status);
  84         unlink("conftest.dat");
  85         exit(WEXITSTATUS(status));
  86 }
  87 ],
  88 rsync_cv_HAVE_BROKEN_LARGEFILE=yes,rsync_cv_HAVE_BROKEN_LARGEFILE=no,rsync_cv_HAVE_BROKEN_LARGEFILE=cross)])
  89 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
  90    AC_SYS_LARGEFILE
  91 fi
  92
  93 ipv6type=unknown
  94 ipv6lib=none
  95 ipv6trylibc=yes
  96
  97 AC_ARG_ENABLE(ipv6,
  98         AC_HELP_STRING([--disable-ipv6], [don't even try to use IPv6]))
  99
 100 if test "x$enable_ipv6" != xno
 101 then
 102         AC_MSG_CHECKING([ipv6 stack type])
 103         for i in inria kame linux-glibc linux-inet6 toshiba v6d zeta; do
 104                 case $i in
 105                 inria)
 106                         # http://www.kame.net/
 107                         AC_EGREP_CPP(yes, [
 108 #include <netinet/in.h>
 109 #ifdef IPV6_INRIA_VERSION
 110 yes
 111 #endif],
 112                                 [ipv6type=$i;
 113                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 114                                 ])
 115                         ;;
 116                 kame)
 117                         # http://www.kame.net/
 118                         AC_EGREP_CPP(yes, [
 119 #include <netinet/in.h>
 120 #ifdef __KAME__
 121 yes
 122 #endif],
 123                                 [ipv6type=$i;
 124                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 125                         ;;
 126                 linux-glibc)
 127                         # http://www.v6.linux.or.jp/
 128                         AC_EGREP_CPP(yes, [
 129 #include <features.h>
 130 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 131 yes
 132 #endif],
 133                                 [ipv6type=$i;
 134 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 135                         ;;
 136                 linux-inet6)
 137                         # http://www.v6.linux.or.jp/
 138                         if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
 139                                 ipv6type=$i
 140                                 ipv6lib=inet6
 141                                 ipv6libdir=/usr/inet6/lib
 142                                 ipv6trylibc=yes;
 143                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 144                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 145                         fi
 146                         ;;
 147                 toshiba)
 148                         AC_EGREP_CPP(yes, [
 149 #include <sys/param.h>
 150 #ifdef _TOSHIBA_INET6
 151 yes
 152 #endif],
 153                                 [ipv6type=$i;
 154                                 ipv6lib=inet6;
 155                                 ipv6libdir=/usr/local/v6/lib;
 156                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 157                         ;;
 158                 v6d)
 159                         AC_EGREP_CPP(yes, [
 160 #include </usr/local/v6/include/sys/v6config.h>
 161 #ifdef __V6D__
 162 yes
 163 #endif],
 164                                 [ipv6type=$i;
 165                                 ipv6lib=v6;
 166                                 ipv6libdir=/usr/local/v6/lib;
 167                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 168                         ;;
 169                 zeta)
 170                         AC_EGREP_CPP(yes, [
 171 #include <sys/param.h>
 172 #ifdef _ZETA_MINAMI_INET6
 173 yes
 174 #endif],
 175                                 [ipv6type=$i;
 176                                 ipv6lib=inet6;
 177                                 ipv6libdir=/usr/local/v6/lib;
 178                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 179                         ;;
 180                 esac
 181                 if test "$ipv6type" != "unknown"; then
 182                         break
 183                 fi
 184         done
 185         AC_MSG_RESULT($ipv6type)
 186
 187         AC_SEARCH_LIBS(getaddrinfo, inet6)
 188 fi
 189
 190 AC_C_BIGENDIAN
 191 AC_HEADER_DIRENT
 192 AC_HEADER_TIME
 193 AC_HEADER_SYS_WAIT
 194 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h unistd.h utime.h grp.h)
 195 AC_CHECK_HEADERS(compat.h sys/param.h ctype.h sys/wait.h sys/ioctl.h)
 196 AC_CHECK_HEADERS(sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h)
 197 AC_CHECK_HEADERS(glob.h alloca.h mcheck.h sys/sysctl.h arpa/inet.h arpa/nameser.h)
 198 AC_CHECK_HEADERS(netdb.h)
 199
 200 AC_CHECK_SIZEOF(int)
 201 AC_CHECK_SIZEOF(long)
 202 AC_CHECK_SIZEOF(short)
 203
 204 AC_C_INLINE
 205
 206 AC_TYPE_SIGNAL
 207 AC_TYPE_UID_T
 208 AC_TYPE_MODE_T
 209 AC_TYPE_OFF_T
 210 AC_TYPE_SIZE_T
 211 AC_TYPE_PID_T
 212 AC_TYPE_GETGROUPS
 213 AC_CHECK_MEMBERS([struct stat.st_rdev])
 214
 215 AC_CHECK_TYPE([ino_t], [unsigned])
 216 TYPE_SOCKLEN_T
 217
 218 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 219     AC_TRY_COMPILE([#include <errno.h>],[int i = errno],
 220         rsync_cv_errno=yes,rsync_cv_have_errno_decl=no)])
 221 if test x"$rsync_cv_errno" = x"yes"; then
 222    AC_DEFINE(HAVE_ERRNO_DECL, 1, [ ])
 223 fi
 224
 225 # The following test taken from the cvs sources
 226 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 227 # These need checks to be before checks for any other functions that
 228 #    might be in the same libraries.
 229 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 230 # libsocket.so which has a bad implementation of gethostbyname (it
 231 # only looks in /etc/hosts), so we only look for -lsocket if we need
 232 # it.
 233 AC_CHECK_FUNCS(connect)
 234 if test x"$ac_cv_func_connect" = x"no"; then
 235     case "$LIBS" in
 236     *-lnsl*) ;;
 237     *) AC_CHECK_LIB(nsl_s, printf) ;;
 238     esac
 239     case "$LIBS" in
 240     *-lnsl*) ;;
 241     *) AC_CHECK_LIB(nsl, printf) ;;
 242     esac
 243     case "$LIBS" in
 244     *-lsocket*) ;;
 245     *) AC_CHECK_LIB(socket, connect) ;;
 246     esac
 247     case "$LIBS" in
 248     *-linet*) ;;
 249     *) AC_CHECK_LIB(inet, connect) ;;
 250     esac
 251     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 252     dnl has been cached.
 253     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 254        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 255         # ac_cv_func_connect=yes
 256         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 257         AC_DEFINE(HAVE_CONNECT, 1, [ ])
 258     fi
 259 fi
 260
 261 AC_CHECK_LIB(resolv, inet_ntop)
 262
 263 AC_MSG_NOTICE([Looking in libraries: $LIBS])
 264
 265 AC_CHECK_FUNC(inet_ntop, , AC_LIBOBJ(lib/inet_ntop))
 266 AC_CHECK_FUNC(inet_pton, , AC_LIBOBJ(lib/inet_pton))
 267
 268 AC_CHECK_FUNC(getaddrinfo, , AC_LIBOBJ(lib/getaddrinfo))
 269 AC_CHECK_FUNC(getnameinfo, , AC_LIBOBJ(lib/getnameinfo))
 270
 271 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 272                 [ AC_DEFINE(HAVE_SOCKADDR_LEN) ],
 273                 [],
 274                 [
 275 #include <sys/types.h>
 276 #include <sys/socket.h>
 277 ])
 278
 279 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 280 #
 281 AC_CHECK_FUNCS(strcasecmp)
 282 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 283     AC_CHECK_LIB(resolv, strcasecmp)
 284 fi
 285
 286 AC_FUNC_MEMCMP
 287 AC_FUNC_UTIME_NULL
 288 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup strerror chown chmod mknod)
 289 AC_CHECK_FUNCS(fchmod fstat strchr readlink link utime utimes strftime)
 290 AC_CHECK_FUNCS(memmove lchown vsnprintf snprintf asprintf setsid glob strpbrk)
 291 AC_CHECK_FUNCS(strlcat strlcpy mtrace)
 292
 293 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
 294 AC_TRY_RUN([
 295 #include <sys/types.h>
 296 #include <sys/socket.h>
 297
 298 main() {
 299        int fd[2];
 300        exit((socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1);
 301 }],
 302 rsync_cv_HAVE_SOCKETPAIR=yes,rsync_cv_HAVE_SOCKETPAIR=no,rsync_cv_HAVE_SOCKETPAIR=cross)])
 303 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
 304     AC_DEFINE(HAVE_SOCKETPAIR, 1, [ ])
 305 fi
 306
 307 AC_CACHE_CHECK([for working fnmatch],rsync_cv_HAVE_FNMATCH,[
 308 AC_TRY_RUN([#include <fnmatch.h>
 309 main() { exit((fnmatch("*.o", "x.o", FNM_PATHNAME) == 0 &&
 310                fnmatch("a/b/*", "a/b/c/d", FNM_PATHNAME) != 0) ? 0: 1); }],
 311 rsync_cv_HAVE_FNMATCH=yes,rsync_cv_HAVE_FNMATCH=no,rsync_cv_HAVE_FNMATCH=cross)])
 312 if test x"$rsync_cv_HAVE_FNMATCH" = x"yes"; then
 313     AC_DEFINE(HAVE_FNMATCH, 1, [ ])
 314 fi
 315
 316 if test x"$with_included_popt" != x"yes"
 317 then
 318     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
 319 fi
 320
 321 AC_MSG_CHECKING([whether to use included libpopt])
 322 if test x"$with_included_popt" = x"yes"
 323 then
 324     AC_MSG_RESULT($srcdir/popt)
 325     BUILD_POPT='$(popt_OBJS)'
 326     CFLAGS="$CFLAGS -I$srcdir/popt"
 327 else
 328     AC_MSG_RESULT(no)
 329 fi
 330
 331 AC_CACHE_CHECK([for long long],rsync_cv_HAVE_LONGLONG,[
 332 AC_TRY_RUN([#include <stdio.h>
 333 main() { long long x = 1000000; x *= x; exit(((x/1000000) == 1000000)? 0: 1); }],
 334 rsync_cv_HAVE_LONGLONG=yes,rsync_cv_HAVE_LONGLONG=no,rsync_cv_HAVE_LONGLONG=cross)])
 335 if test x"$rsync_cv_HAVE_LONGLONG" = x"yes"; then
 336     AC_DEFINE(HAVE_LONGLONG, 1, [ ])
 337 fi
 338
 339 AC_CACHE_CHECK([for off64_t],rsync_cv_HAVE_OFF64_T,[
 340 AC_TRY_RUN([#include <stdio.h>
 341 #include <sys/stat.h>
 342 main() { struct stat64 st; off64_t s; if (sizeof(off_t) == sizeof(off64_t)) exit(1); exit((lstat64("/dev/null", &st)==0)?0:1); }],
 343 rsync_cv_HAVE_OFF64_T=yes,rsync_cv_HAVE_OFF64_T=no,rsync_cv_HAVE_OFF64_T=cross)])
 344 if test x"$rsync_cv_HAVE_OFF64_T" = x"yes"; then
 345     AC_DEFINE(HAVE_OFF64_T, 1, [ ])
 346 fi
 347
 348 AC_CACHE_CHECK([for short ino_t],rsync_cv_HAVE_SHORT_INO_T,[
 349 AC_TRY_RUN([#include <stdio.h>
 350 #include <sys/types.h>
 351 #include <sys/stat.h>
 352 main() { if (sizeof(ino_t) < sizeof(unsigned int)) return 0; return 1; }],
 353 rsync_cv_HAVE_SHORT_INO_T=yes,rsync_cv_HAVE_SHORT_INO_T=no,rsync_cv_HAVE_SHORT_INO_T=cross)])
 354 if test x"$rsync_cv_HAVE_SHORT_INO_T" = x"yes"; then
 355     AC_DEFINE(HAVE_SHORT_INO_T, 1, [ ])
 356 fi
 357
 358 AC_CACHE_CHECK([for unsigned char],rsync_cv_HAVE_UNSIGNED_CHAR,[
 359 AC_TRY_RUN([#include <stdio.h>
 360 main() { char c; c=250; exit((c > 0)?0:1); }],
 361 rsync_cv_HAVE_UNSIGNED_CHAR=yes,rsync_cv_HAVE_UNSIGNED_CHAR=no,rsync_cv_HAVE_UNSIGNED_CHAR=cross)])
 362 if test x"$rsync_cv_HAVE_UNSIGNED_CHAR" = x"yes"; then
 363     AC_DEFINE(HAVE_UNSIGNED_CHAR, 1, [ ])
 364 fi
 365
 366 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
 367 AC_TRY_RUN([#include <sys/types.h>
 368 #include <dirent.h>
 369 main() { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
 370 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
 371 di->d_name[0] == 0) exit(0); exit(1);} ],
 372 rsync_cv_HAVE_BROKEN_READDIR=yes,rsync_cv_HAVE_BROKEN_READDIR=no,rsync_cv_HAVE_BROKEN_READDIR=cross)])
 373 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
 374     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [ ])
 375 fi
 376
 377 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_UTIMBUF,[
 378 AC_TRY_COMPILE([#include <sys/types.h>
 379 #include <utime.h>],
 380 [struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; exit(utime("foo.c",&tbuf));],
 381 rsync_cv_HAVE_UTIMBUF=yes,rsync_cv_HAVE_UTIMBUF=no,rsync_cv_HAVE_UTIMBUF=cross)])
 382 if test x"$rsync_cv_HAVE_UTIMBUF" = x"yes"; then
 383     AC_DEFINE(HAVE_UTIMBUF, 1, [ ])
 384 fi
 385
 386 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
 387 AC_TRY_RUN([
 388 #include <sys/time.h>
 389 #include <unistd.h>
 390 main() { struct timeval tv; exit(gettimeofday(&tv, NULL));}],
 391            rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes,rsync_cv_HAVE_GETTIMEOFDAY_TZ=no,rsync_cv_HAVE_GETTIMEOFDAY_TZ=cross)])
 392 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" = x"yes"; then
 393     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [ ])
 394 fi
 395
 396 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
 397 AC_TRY_RUN([
 398 #include <sys/types.h>
 399 #include <stdarg.h>
 400 void foo(const char *format, ...) {
 401        va_list ap;
 402        int len;
 403        char buf[5];
 404
 405        va_start(ap, format);
 406        len = vsnprintf(0, 0, format, ap);
 407        va_end(ap);
 408        if (len != 5) exit(1);
 409
 410        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 411
 412        exit(0);
 413 }
 414 main() { foo("hello"); }
 415 ],
 416 rsync_cv_HAVE_C99_VSNPRINTF=yes,rsync_cv_HAVE_C99_VSNPRINTF=no,rsync_cv_HAVE_C99_VSNPRINTF=cross)])
 417 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 418     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [ ])
 419 fi
 420
 421
 422 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
 423 AC_TRY_RUN([#include <stdlib.h>
 424 #include <sys/types.h>
 425 #include <sys/stat.h>
 426 #include <unistd.h>
 427 main() {
 428   struct stat st;
 429   char tpl[20]="/tmp/test.XXXXXX";
 430   int fd = mkstemp(tpl);
 431   if (fd == -1) exit(1);
 432   unlink(tpl);
 433   if (fstat(fd, &st) != 0) exit(1);
 434   if ((st.st_mode & 0777) != 0600) exit(1);
 435   exit(0);
 436 }],
 437 rsync_cv_HAVE_SECURE_MKSTEMP=yes,
 438 rsync_cv_HAVE_SECURE_MKSTEMP=no,
 439 rsync_cv_HAVE_SECURE_MKSTEMP=cross)])
 440 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
 441     AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [ ])
 442 fi
 443
 444
 445 AC_CACHE_CHECK([for broken inet_ntoa],rsync_cv_REPLACE_INET_NTOA,[
 446 AC_TRY_RUN([
 447 #include <stdio.h>
 448 #include <sys/types.h>
 449 #include <netinet/in.h>
 450 #include <arpa/inet.h>
 451 main() { struct in_addr ip; ip.s_addr = 0x12345678;
 452 if (strcmp(inet_ntoa(ip),"18.52.86.120") &&
 453     strcmp(inet_ntoa(ip),"120.86.52.18")) { exit(1); }
 454 exit(0);}],
 455            rsync_cv_REPLACE_INET_NTOA=no,rsync_cv_REPLACE_INET_NTOA=yes,rsync_cv_REPLACE_INET_NTOA=cross)])
 456 if test x"$rsync_cv_REPLACE_INET_NTOA" = x"yes"; then
 457     AC_DEFINE(REPLACE_INET_NTOA, 1, [ ])
 458 fi
 459
 460
 461 AC_CACHE_CHECK([for broken inet_aton],rsync_cv_REPLACE_INET_ATON,[
 462 AC_TRY_RUN([
 463 #include <stdio.h>
 464 #include <sys/types.h>
 465 #include <netinet/in.h>
 466 #include <arpa/inet.h>
 467 main() { struct in_addr ip;
 468 if (inet_aton("example", &ip) == 0) exit(0); exit(1);}],
 469            rsync_cv_REPLACE_INET_ATON=no,rsync_cv_REPLACE_INET_ATON=yes,rsync_cv_REPLACE_INET_ATON=cross)])
 470 if test x"$rsync_cv_REPLACE_INET_ATON" = x"yes"; then
 471     AC_DEFINE(REPLACE_INET_ATON, 1, [ ])
 472 fi
 473
 474 #
 475 # The following test was mostly taken from the tcl/tk plus patches
 476 #
 477 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
 478 rm -rf conftest*
 479 cat > conftest.$ac_ext <<EOF
 480 int main() { return 0; }
 481 EOF
 482 ${CC-cc} -c -o conftest..o conftest.$ac_ext
 483 if test -f conftest..o; then
 484     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
 485 else
 486     rsync_cv_DASHC_WORKS_WITH_DASHO=no
 487 fi
 488 rm -rf conftest*
 489 ])
 490 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
 491     OBJ_SAVE="#"
 492     OBJ_RESTORE="#"
 493     CC_SHOBJ_FLAG='-o $@'
 494 else
 495     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
 496     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
 497     CC_SHOBJ_FLAG=""
 498 fi
 499
 500 AC_SUBST(OBJ_SAVE)
 501 AC_SUBST(OBJ_RESTORE)
 502 AC_SUBST(CC_SHOBJ_FLAG)
 503 AC_SUBST(BUILD_POPT)
 504
 505 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
 506 AC_OUTPUT