Preparing for release of 3.0.0pre1
[rsync.git] / configure.in
1 dnl Process this file with autoconf to produce a configure script.
2
3 AC_INIT()
4 AC_CONFIG_SRCDIR([byteorder.h])
5 AC_CONFIG_HEADER(config.h)
6 AC_PREREQ(2.59)
7
8 RSYNC_VERSION=3.0.0pre1
9 AC_SUBST(RSYNC_VERSION)
10 AC_MSG_NOTICE([Configuring rsync $RSYNC_VERSION])
11
12 AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$RSYNC_VERSION"], [rsync release version])
13
14 LDFLAGS=${LDFLAGS-""}
15
16 AC_CANONICAL_TARGET([])
17
18 dnl Checks for programs.
19 AC_PROG_CC
20 AC_PROG_CPP
21 AC_PROG_EGREP
22 AC_PROG_INSTALL
23 AC_PROG_CC_STDC
24 AC_SUBST(SHELL)
25
26 AC_DEFINE([_GNU_SOURCE], 1,
27           [Define _GNU_SOURCE so that we get all necessary prototypes])
28
29 if test x"$ac_cv_prog_cc_stdc" = x"no"; then
30         AC_MSG_WARN([rsync requires an ANSI C compiler and you don't seem to have one])
31 fi
32
33 # We must decide this before testing the compiler.
34
35 # Please allow this to default to yes, so that your users have more
36 # chance of getting a useful stack trace if problems occur.
37
38 AC_MSG_CHECKING([whether to include debugging symbols])
39 AC_ARG_ENABLE(debug,
40         AC_HELP_STRING([--disable-debug],
41                 [disable debugging symbols and features]))
42
43 if test x"$enable_debug" = x"no"; then
44     AC_MSG_RESULT(no)
45     CFLAGS=${CFLAGS-"-O"}
46 else
47     AC_MSG_RESULT([yes])
48     # leave CFLAGS alone; AC_PROG_CC will try to include -g if it can
49     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
50     dnl CFLAGS=${CFLAGS-"-g"}
51 fi
52
53
54 AC_ARG_ENABLE(profile,
55         AC_HELP_STRING([--enable-profile],
56                 [turn on CPU profiling]))
57 if test x"$enable_profile" = x"yes"; then
58         CFLAGS="$CFLAGS -pg"
59 fi
60
61
62 # Specifically, this turns on panic_action handling.
63 AC_ARG_ENABLE(maintainer-mode,
64         AC_HELP_STRING([--enable-maintainer-mode],
65                 [turn on extra debug features]))
66 if test x"$enable_maintainer_mode" = x"yes"; then
67         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
68 fi
69
70
71 # This is needed for our included version of popt.  Kind of silly, but
72 # I don't want our version too far out of sync.
73 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
74
75 # If GCC, turn on warnings.
76 if test x"$GCC" = x"yes"; then
77         CFLAGS="$CFLAGS -Wall -W"
78 fi
79
80 AC_ARG_WITH(included-popt,
81         AC_HELP_STRING([--with-included-popt], [use bundled popt library, not from system]))
82
83 AC_ARG_WITH(rsync-path,
84         AC_HELP_STRING([--with-rsync-path=PATH], [set default --rsync-path to PATH (default: rsync)]),
85         [ RSYNC_PATH="$with_rsync_path" ],
86         [ RSYNC_PATH="rsync" ])
87
88 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
89
90 AC_ARG_WITH(rsyncd-conf,
91         AC_HELP_STRING([--with-rsyncd-conf=PATH], [set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]),
92         [ if test ! -z "$with_rsyncd_conf" ; then
93                 case $with_rsyncd_conf in
94                         yes|no)
95                                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
96                                 ;;
97                         /*)
98                                 RSYNCD_SYSCONF="$with_rsyncd_conf"
99                                 ;;
100                         *)
101                                 AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH)
102                                 ;;
103                 esac
104         else
105                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
106         fi ],
107         [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ])
108
109 AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server])
110
111 AC_ARG_WITH(rsh,
112         AC_HELP_STRING([--with-rsh=CMD], [set remote shell command to CMD (default: ssh)]))
113
114 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
115 if test x$HAVE_REMSH = x1; then
116         AC_DEFINE(HAVE_REMSH, 1, [Define to 1 if remote shell is remsh, not rsh])
117 fi
118
119 if test x"$with_rsh" != x; then
120         RSYNC_RSH="$with_rsh"
121 else
122         RSYNC_RSH="ssh"
123 fi
124 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
125
126 AC_ARG_WITH(nobody-group,
127     AC_HELP_STRING([--with-nobody-group=GROUP],
128                    [set the default unprivileged group (default nobody or nogroup)]),
129     [ NOBODY_GROUP="$with_nobody_group" ])
130
131 if test x"$with_nobody_group" = x; then
132     AC_MSG_CHECKING([the group for user "nobody"])
133     if grep '^nobody:' /etc/group >/dev/null 2>&1; then
134         NOBODY_GROUP=nobody
135     elif grep '^nogroup:' /etc/group >/dev/null 2>&1; then
136         NOBODY_GROUP=nogroup
137     else
138         NOBODY_GROUP=nobody # test for others?
139     fi
140     AC_MSG_RESULT($NOBODY_GROUP)
141 fi
142
143 AC_DEFINE_UNQUOTED(NOBODY_USER, "nobody", [unprivileged user--e.g. nobody])
144 AC_DEFINE_UNQUOTED(NOBODY_GROUP, "$NOBODY_GROUP", [unprivileged group for unprivileged user])
145
146 # arrgh. libc in some old debian version screwed up the largefile
147 # stuff, getting byte range locking wrong
148 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
149 AC_TRY_RUN([
150 #define _FILE_OFFSET_BITS 64
151 #include <stdio.h>
152 #include <fcntl.h>
153 #include <sys/types.h>
154 #include <sys/wait.h>
155
156 int main(void)
157 {
158         struct flock lock;
159         int status;
160         char tpl[32] = "/tmp/locktest.XXXXXX";
161         int fd = mkstemp(tpl);
162         if (fd < 0) {
163                 strcpy(tpl, "conftest.dat");
164                 fd = open(tpl, O_CREAT|O_RDWR, 0600);
165         }
166
167         lock.l_type = F_WRLCK;
168         lock.l_whence = SEEK_SET;
169         lock.l_start = 0;
170         lock.l_len = 1;
171         lock.l_pid = 0;
172         fcntl(fd,F_SETLK,&lock);
173         if (fork() == 0) {
174                 lock.l_start = 1;
175                 _exit(fcntl(fd,F_SETLK,&lock) == 0);
176         }
177         wait(&status);
178         unlink(tpl);
179         exit(WEXITSTATUS(status));
180 }
181 ],
182 rsync_cv_HAVE_BROKEN_LARGEFILE=yes,rsync_cv_HAVE_BROKEN_LARGEFILE=no,rsync_cv_HAVE_BROKEN_LARGEFILE=cross)])
183 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
184    AC_SYS_LARGEFILE
185 fi
186
187 ipv6type=unknown
188 ipv6lib=none
189 ipv6trylibc=yes
190
191 AC_ARG_ENABLE(ipv6,
192         AC_HELP_STRING([--disable-ipv6],
193                 [don't even try to use IPv6]))
194 if test x"$enable_ipv6" != x"no"; then
195         AC_MSG_CHECKING([ipv6 stack type])
196         for i in inria kame linux-glibc linux-inet6 toshiba v6d zeta; do
197                 case $i in
198                 inria)
199                         # http://www.kame.net/
200                         AC_EGREP_CPP(yes, [
201 #include <netinet/in.h>
202 #ifdef IPV6_INRIA_VERSION
203 yes
204 #endif],
205                                 [ipv6type=$i;
206                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
207                                 ])
208                         ;;
209                 kame)
210                         # http://www.kame.net/
211                         AC_EGREP_CPP(yes, [
212 #include <netinet/in.h>
213 #ifdef __KAME__
214 yes
215 #endif],
216                                 [ipv6type=$i;
217                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
218                         ;;
219                 linux-glibc)
220                         # http://www.v6.linux.or.jp/
221                         AC_EGREP_CPP(yes, [
222 #include <features.h>
223 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
224 yes
225 #endif],
226                                 [ipv6type=$i;
227 AC_DEFINE(INET6, 1, [true if you have IPv6])])
228                         ;;
229                 linux-inet6)
230                         # http://www.v6.linux.or.jp/
231                         if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
232                                 ipv6type=$i
233                                 ipv6lib=inet6
234                                 ipv6libdir=/usr/inet6/lib
235                                 ipv6trylibc=yes;
236                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
237                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
238                         fi
239                         ;;
240                 toshiba)
241                         AC_EGREP_CPP(yes, [
242 #include <sys/param.h>
243 #ifdef _TOSHIBA_INET6
244 yes
245 #endif],
246                                 [ipv6type=$i;
247                                 ipv6lib=inet6;
248                                 ipv6libdir=/usr/local/v6/lib;
249                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
250                         ;;
251                 v6d)
252                         AC_EGREP_CPP(yes, [
253 #include </usr/local/v6/include/sys/v6config.h>
254 #ifdef __V6D__
255 yes
256 #endif],
257                                 [ipv6type=$i;
258                                 ipv6lib=v6;
259                                 ipv6libdir=/usr/local/v6/lib;
260                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
261                         ;;
262                 zeta)
263                         AC_EGREP_CPP(yes, [
264 #include <sys/param.h>
265 #ifdef _ZETA_MINAMI_INET6
266 yes
267 #endif],
268                                 [ipv6type=$i;
269                                 ipv6lib=inet6;
270                                 ipv6libdir=/usr/local/v6/lib;
271                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
272                         ;;
273                 esac
274                 if test "$ipv6type" != "unknown"; then
275                         break
276                 fi
277         done
278         AC_MSG_RESULT($ipv6type)
279
280         AC_SEARCH_LIBS(getaddrinfo, inet6)
281 fi
282
283 dnl Do you want to disable use of locale functions
284 AC_ARG_ENABLE([locale],
285         AC_HELP_STRING([--disable-locale],
286                 [disable locale features]))
287 AH_TEMPLATE([CONFIG_LOCALE],
288 [Undefine if you don't want locale features.  By default this is defined.])
289 if test x"$enable_locale" != x"no"; then
290         AC_DEFINE(CONFIG_LOCALE)
291 fi
292
293 AC_MSG_CHECKING([whether to call shutdown on all sockets])
294 case $host_os in
295         *cygwin* ) AC_MSG_RESULT(yes)
296                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
297                             [Define to 1 if sockets need to be shutdown])
298                    ;;
299                * ) AC_MSG_RESULT(no);;
300 esac
301
302 AC_C_BIGENDIAN
303 AC_HEADER_DIRENT
304 AC_HEADER_TIME
305 AC_HEADER_SYS_WAIT
306 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \
307     unistd.h utime.h grp.h compat.h sys/param.h ctype.h sys/wait.h \
308     sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h \
309     sys/un.h glob.h mcheck.h arpa/inet.h arpa/nameser.h locale.h \
310     netdb.h malloc.h float.h limits.h iconv.h libcharset.h langinfo.h)
311 AC_HEADER_MAJOR
312
313 AC_CACHE_CHECK([if makedev takes 3 args],rsync_cv_MAKEDEV_TAKES_3_ARGS,[
314 AC_TRY_RUN([
315 #include <sys/types.h>
316 #ifdef MAJOR_IN_MKDEV
317 #include <sys/mkdev.h>
318 # if !defined makedev && (defined mkdev || defined _WIN32 || defined __WIN32__)
319 #  define makedev mkdev
320 # endif
321 #elif defined MAJOR_IN_SYSMACROS
322 #include <sys/sysmacros.h>
323 #endif
324
325 int main(void)
326 {
327         dev_t dev = makedev(0, 5, 7);
328         if (major(dev) != 5 || minor(dev) != 7)
329                 exit(1);
330         return 0;
331 }
332 ],
333 rsync_cv_MAKEDEV_TAKES_3_ARGS=yes,rsync_cv_MAKEDEV_TAKES_3_ARGS=no,rsync_cv_MAKEDEV_TAKES_3_ARGS=no)])
334 if test x"$rsync_cv_MAKEDEV_TAKES_3_ARGS" = x"yes"; then
335    AC_DEFINE(MAKEDEV_TAKES_3_ARGS, 1, [Define to 1 if makedev() takes 3 args])
336 fi
337
338 AC_CHECK_SIZEOF(int)
339 AC_CHECK_SIZEOF(long)
340 AC_CHECK_SIZEOF(long long)
341 AC_CHECK_SIZEOF(short)
342 AC_CHECK_SIZEOF(int16_t)
343 AC_CHECK_SIZEOF(uint16_t)
344 AC_CHECK_SIZEOF(int32_t)
345 AC_CHECK_SIZEOF(uint32_t)
346 AC_CHECK_SIZEOF(int64_t)
347 AC_CHECK_SIZEOF(off_t)
348 AC_CHECK_SIZEOF(off64_t)
349 AC_CHECK_SIZEOF(time_t)
350
351 AC_C_INLINE
352 AC_C_LONG_DOUBLE
353
354 AC_TYPE_SIGNAL
355 AC_TYPE_UID_T
356 AC_TYPE_MODE_T
357 AC_TYPE_OFF_T
358 AC_TYPE_SIZE_T
359 AC_TYPE_PID_T
360 AC_TYPE_GETGROUPS
361 AC_CHECK_MEMBERS([struct stat.st_rdev])
362
363 TYPE_SOCKLEN_T
364
365 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
366     AC_TRY_COMPILE([#include <errno.h>],[int i = errno],
367         rsync_cv_errno=yes,rsync_cv_have_errno_decl=no)])
368 if test x"$rsync_cv_errno" = x"yes"; then
369    AC_DEFINE(HAVE_ERRNO_DECL, 1, [Define to 1 if errno is declared in errno.h])
370 fi
371
372 # The following test taken from the cvs sources
373 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
374 # These need checks to be before checks for any other functions that
375 #    might be in the same libraries.
376 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
377 # libsocket.so which has a bad implementation of gethostbyname (it
378 # only looks in /etc/hosts), so we only look for -lsocket if we need
379 # it.
380 AC_CHECK_FUNCS(connect)
381 if test x"$ac_cv_func_connect" = x"no"; then
382     case "$LIBS" in
383     *-lnsl*) ;;
384     *) AC_CHECK_LIB(nsl_s, printf) ;;
385     esac
386     case "$LIBS" in
387     *-lnsl*) ;;
388     *) AC_CHECK_LIB(nsl, printf) ;;
389     esac
390     case "$LIBS" in
391     *-lsocket*) ;;
392     *) AC_CHECK_LIB(socket, connect) ;;
393     esac
394     case "$LIBS" in
395     *-linet*) ;;
396     *) AC_CHECK_LIB(inet, connect) ;;
397     esac
398     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
399     dnl has been cached.
400     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
401        test x"$ac_cv_lib_inet_connect" = x"yes"; then
402         # ac_cv_func_connect=yes
403         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
404         AC_DEFINE(HAVE_CONNECT, 1, [Define to 1 if you have the "connect" function])
405     fi
406 fi
407
408 AC_SEARCH_LIBS(inet_ntop, resolv)
409
410 # Solaris and HP-UX weirdness:
411 # Search for libiconv_open (not iconv_open) to discover if -liconv is needed!
412 AC_SEARCH_LIBS(libiconv_open, iconv)
413
414 AC_MSG_CHECKING([for iconv declaration])
415 AC_CACHE_VAL(am_cv_proto_iconv, [
416     AC_TRY_COMPILE([
417 #include <stdlib.h>
418 #include <iconv.h>
419 extern
420 #ifdef __cplusplus
421 "C"
422 #endif
423 #if defined(__STDC__) || defined(__cplusplus)
424 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
425 #else
426 size_t iconv();
427 #endif
428 ], [], am_cv_proto_iconv_arg1="", am_cv_proto_iconv_arg1="const")
429       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
430     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed -e 's/( /(/'`
431 AC_MSG_RESULT([$]{ac_t:-
432          }[$]am_cv_proto_iconv)
433 AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
434                    [Define as const if the declaration of iconv() needs const.])
435
436 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
437
438 AC_CHECK_FUNCS(inet_ntop, , [AC_LIBOBJ(lib/inet_ntop)])
439 AC_CHECK_FUNCS(inet_pton, , [AC_LIBOBJ(lib/inet_pton)])
440
441 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
442 #   builtin getaddrinfo if one of the defines don't exist
443 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
444                rsync_cv_HAVE_GETADDR_DEFINES,[
445                         AC_EGREP_CPP(yes, [
446                         #include <sys/types.h>
447                         #include <sys/socket.h>
448                         #include <netdb.h>
449                         #ifdef AI_PASSIVE
450                         yes
451                         #endif],
452                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
453                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
454 if test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes"; then
455         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
456         # something else so we must include <netdb.h> to get the
457         # redefinition.
458         AC_CHECK_FUNCS(getaddrinfo, ,
459                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
460                 AC_TRY_LINK([#include <sys/types.h>
461                 #include <sys/socket.h>
462                 #include <netdb.h>],[getaddrinfo(NULL, NULL, NULL, NULL);],
463                         [AC_MSG_RESULT([yes])
464                         AC_DEFINE(HAVE_GETADDRINFO, 1,
465                                 [Define to 1 if you have the "getaddrinfo" function.])],
466                         [AC_MSG_RESULT([no])
467                         AC_LIBOBJ(lib/getaddrinfo)])])
468         AC_CHECK_FUNCS(getnameinfo, , [AC_LIBOBJ(lib/getnameinfo)])
469 else
470         AC_LIBOBJ(lib/getaddrinfo)
471         AC_LIBOBJ(lib/getnameinfo)
472 fi
473
474 AC_CHECK_MEMBER([struct sockaddr.sa_len],
475                 [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ],
476                 [],
477                 [
478 #include <sys/types.h>
479 #include <sys/socket.h>
480 ])
481
482 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
483                 [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ],
484                 [],
485                 [
486 #include <sys/types.h>
487 #include <sys/socket.h>
488 #include <netinet/in.h>
489 ])
490
491 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
492                 [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ],
493                 [],
494                 [
495 #include <sys/types.h>
496 #include <sys/socket.h>
497 #include <netinet/in.h>
498 ])
499
500 AC_MSG_CHECKING(struct sockaddr_storage)
501 AC_TRY_COMPILE([#include <sys/types.h>
502 #include <sys/socket.h>],
503 [struct sockaddr_storage x;],
504         AC_MSG_RESULT(yes)
505         AC_DEFINE(HAVE_SOCKADDR_STORAGE, 1,
506                 [Define to 1 if you have struct sockaddr_storage.] ),
507         AC_MSG_RESULT(no))
508
509 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
510                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ],
511                 [],
512                 [
513 #include <sys/types.h>
514 #include <sys/socket.h>
515 #include <netinet/in.h>
516 ])
517
518 AC_MSG_CHECKING(struct stat64)
519 AC_TRY_COMPILE([#include <stdio.h>
520 #if HAVE_SYS_TYPES_H
521 # include <sys/types.h>
522 #endif
523 #if HAVE_SYS_STAT_H
524 # include <sys/stat.h>
525 #endif
526 #if STDC_HEADERS
527 # include <stdlib.h>
528 # include <stddef.h>
529 #else
530 # if HAVE_STDLIB_H
531 #  include <stdlib.h>
532 # endif
533 #endif
534 ],[struct stat64 st;],
535     AC_MSG_RESULT(yes)
536         AC_DEFINE(HAVE_STRUCT_STAT64,1,[Define to 1 if you have struct stat64.]),
537     AC_MSG_RESULT(no))
538
539 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
540 #
541 AC_CHECK_FUNCS(strcasecmp)
542 if test x"$ac_cv_func_strcasecmp" = x"no"; then
543     AC_CHECK_LIB(resolv, strcasecmp)
544 fi
545
546 AC_CHECK_FUNCS(aclsort)
547 if test x"$ac_cv_func_aclsort" = x"no"; then
548     AC_CHECK_LIB(sec, aclsort)
549 fi
550
551 dnl At the moment we don't test for a broken memcmp(), because all we
552 dnl need to do is test for equality, not comparison, and it seems that
553 dnl every platform has a memcmp that can do at least that.
554 dnl AC_FUNC_MEMCMP
555
556 AC_FUNC_UTIME_NULL
557 AC_FUNC_ALLOCA
558 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup chown chmod lchmod mknod mkfifo \
559     fchmod fstat ftruncate strchr readlink link utime utimes lutimes strftime \
560     memmove lchown vsnprintf snprintf vasprintf asprintf setsid glob strpbrk \
561     strlcat strlcpy strtol mallinfo getgroups setgroups geteuid getegid \
562     setlocale setmode open64 lseek64 mkstemp64 mtrace va_copy __va_copy \
563     strerror putenv iconv_open locale_charset nl_langinfo getxattr \
564     extattr_get_link sigaction sigprocmask)
565
566 AC_CHECK_FUNCS(getpgrp tcgetpgrp)
567 if test $ac_cv_func_getpgrp = yes; then
568     AC_FUNC_GETPGRP
569 fi
570
571 AC_ARG_ENABLE(iconv,
572     AC_HELP_STRING([--disable-iconv],
573             [disable rsync's --iconv option]),
574     [], [enable_iconv=$ac_cv_func_iconv_open])
575 AH_TEMPLATE([ICONV_OPTION],
576 [Define if you want the --iconv option.  Specifing a value will set the
577 default iconv setting (a NULL means no --iconv processing by default).])
578 if test x"$enable_iconv" != x"no"; then
579         if test x"$enable_iconv" = x"yes"; then
580                 AC_DEFINE(ICONV_OPTION, NULL)
581         else
582                 AC_DEFINE_UNQUOTED(ICONV_OPTION, "$enable_iconv")
583         fi
584         AC_DEFINE(UTF8_CHARSET, "UTF-8", [String to pass to iconv() for the UTF-8 charset.])
585 fi
586
587 AC_CACHE_CHECK([whether chown() modifies symlinks],rsync_cv_chown_modifies_symlink,[
588   AC_TRY_RUN([
589 #if HAVE_UNISTD_H
590 # include <unistd.h>
591 #endif
592 #include <stdlib.h>
593 #include <errno.h>
594     main() {
595         char const *dangling_symlink = "conftest.dangle";
596         unlink(dangling_symlink);
597         if (symlink("conftest.no-such", dangling_symlink) < 0) abort();
598         if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) exit(1);
599         exit(0);
600     }],
601   rsync_cv_chown_modifies_symlink=yes,rsync_cv_chown_modifies_symlink=no,rsync_cv_chown_modifies_symlink=no)])
602 if test $rsync_cv_chown_modifies_symlink = yes; then
603   AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define to 1 if chown modifies symlinks.])
604 fi
605
606 AC_CACHE_CHECK([whether link() can hard-link symlinks],rsync_cv_can_hardlink_symlink,[
607   AC_TRY_RUN([
608 #if HAVE_UNISTD_H
609 # include <unistd.h>
610 #endif
611 #include <stdlib.h>
612 #include <errno.h>
613 #define FILENAME "conftest.dangle"
614     main() {
615         unlink(FILENAME);
616         if (symlink("conftest.no-such", FILENAME) < 0) abort();
617         if (link(FILENAME, FILENAME "2") < 0) exit(1);
618         exit(0);
619     }],
620   rsync_cv_can_hardlink_symlink=yes,rsync_cv_can_hardlink_symlink=no,rsync_cv_can_hardlink_symlink=no)])
621 if test $rsync_cv_can_hardlink_symlink = yes; then
622   AC_DEFINE(CAN_HARDLINK_SYMLINK, 1, [Define to 1 if link() can hard-link symlinks.])
623 fi
624
625 AC_CACHE_CHECK([whether link() can hard-link special files],rsync_cv_can_hardlink_special,[
626   AC_TRY_RUN([
627 #if HAVE_UNISTD_H
628 # include <unistd.h>
629 #endif
630 #include <stdlib.h>
631 #include <errno.h>
632 #define FILENAME "conftest.fifi"
633     main() {
634         unlink(FILENAME);
635         if (mkfifo(FILENAME, 0777) < 0) abort();
636         if (link(FILENAME, FILENAME "2") < 0) exit(1);
637         exit(0);
638     }],
639   rsync_cv_can_hardlink_special=yes,rsync_cv_can_hardlink_special=no,rsync_cv_can_hardlink_special=no)])
640 if test $rsync_cv_can_hardlink_special = yes; then
641     AC_DEFINE(CAN_HARDLINK_SPECIAL, 1, [Define to 1 if link() can hard-link special files.])
642 fi
643
644 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
645 AC_TRY_RUN([
646 #include <sys/types.h>
647 #include <sys/socket.h>
648
649 main() {
650        int fd[2];
651        exit((socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1);
652 }],
653 rsync_cv_HAVE_SOCKETPAIR=yes,rsync_cv_HAVE_SOCKETPAIR=no,rsync_cv_HAVE_SOCKETPAIR=cross)])
654 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
655     AC_DEFINE(HAVE_SOCKETPAIR, 1, [Define to 1 if you have the "socketpair" function])
656 fi
657
658 if test x"$with_included_popt" != x"yes"; then
659     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
660 fi
661
662 AC_MSG_CHECKING([whether to use included libpopt])
663 if test x"$with_included_popt" = x"yes"; then
664     AC_MSG_RESULT($srcdir/popt)
665     BUILD_POPT='$(popt_OBJS)'
666     CFLAGS="$CFLAGS -I$srcdir/popt"
667     if test x"$ALLOCA" != x
668     then
669         # this can be removed when/if we add an included alloca.c;
670         #  see autoconf documentation on AC_FUNC_ALLOCA
671         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
672     fi
673 else
674     AC_MSG_RESULT(no)
675 fi
676
677 AC_CACHE_CHECK([for unsigned char],rsync_cv_SIGNED_CHAR_OK,[
678 AC_TRY_COMPILE([],[signed char *s = ""],
679 rsync_cv_SIGNED_CHAR_OK=yes,rsync_cv_SIGNED_CHAR_OK=no)])
680 if test x"$rsync_cv_SIGNED_CHAR_OK" = x"yes"; then
681     AC_DEFINE(SIGNED_CHAR_OK, 1, [Define to 1 if "signed char" is a valid type])
682 fi
683
684 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
685 AC_TRY_RUN([#include <sys/types.h>
686 #include <dirent.h>
687 main() { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
688 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
689 di->d_name[0] == 0) exit(0); exit(1);} ],
690 rsync_cv_HAVE_BROKEN_READDIR=yes,rsync_cv_HAVE_BROKEN_READDIR=no,rsync_cv_HAVE_BROKEN_READDIR=cross)])
691 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
692     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [Define to 1 if readdir() is broken])
693 fi
694
695 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_UTIMBUF,[
696 AC_TRY_COMPILE([#include <sys/types.h>
697 #include <utime.h>],
698 [struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; exit(utime("foo.c",&tbuf));],
699 rsync_cv_HAVE_UTIMBUF=yes,rsync_cv_HAVE_UTIMBUF=no)])
700 if test x"$rsync_cv_HAVE_UTIMBUF" = x"yes"; then
701     AC_DEFINE(HAVE_UTIMBUF, 1, [Define to 1 if you have the "struct utimbuf" type])
702 fi
703
704 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
705 AC_TRY_COMPILE([#include <sys/time.h>
706 #include <unistd.h>],
707 [struct timeval tv; exit(gettimeofday(&tv, NULL));],
708 rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes,rsync_cv_HAVE_GETTIMEOFDAY_TZ=no)])
709 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then
710     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [Define to 1 if gettimeofday() takes a time-zone arg])
711 fi
712
713 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
714 AC_TRY_RUN([
715 #include <sys/types.h>
716 #include <stdarg.h>
717 void foo(const char *format, ...) {
718        va_list ap;
719        int len;
720        char buf[5];
721
722        va_start(ap, format);
723        len = vsnprintf(0, 0, format, ap);
724        va_end(ap);
725        if (len != 5) exit(1);
726
727        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
728
729        exit(0);
730 }
731 main() { foo("hello"); }
732 ],
733 rsync_cv_HAVE_C99_VSNPRINTF=yes,rsync_cv_HAVE_C99_VSNPRINTF=no,rsync_cv_HAVE_C99_VSNPRINTF=cross)])
734 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
735     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [Define to 1 if vsprintf has a C99-compatible return value])
736 fi
737
738
739 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
740 AC_TRY_RUN([#include <stdlib.h>
741 #include <sys/types.h>
742 #include <sys/stat.h>
743 #include <unistd.h>
744 main() {
745   struct stat st;
746   char tpl[20]="/tmp/test.XXXXXX";
747   int fd = mkstemp(tpl);
748   if (fd == -1) exit(1);
749   unlink(tpl);
750   if (fstat(fd, &st) != 0) exit(1);
751   if ((st.st_mode & 0777) != 0600) exit(1);
752   exit(0);
753 }],
754 rsync_cv_HAVE_SECURE_MKSTEMP=yes,
755 rsync_cv_HAVE_SECURE_MKSTEMP=no,
756 rsync_cv_HAVE_SECURE_MKSTEMP=cross)])
757 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
758     case $target_os in
759     hpux*)
760         dnl HP-UX has a broken mkstemp() implementation they refuse to fix,
761         dnl so we noisily skip using it.  See HP change request JAGaf34426
762         dnl for details. (sbonds)
763         AC_MSG_WARN(Skipping broken HP-UX mkstemp() -- using mktemp() instead)
764         ;;
765     *)
766         AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [Define to 1 if mkstemp() is available and works right])
767         ;;
768     esac
769 fi
770
771
772 AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[
773 AC_TRY_RUN([
774 #include <stdio.h>
775 #include <sys/stat.h>
776 #include <errno.h>
777 main() { int rc, ec; char *fn = "fifo-test";
778 unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn);
779 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
780 return 0;}],
781            rsync_cv_MKNOD_CREATES_FIFOS=yes,rsync_cv_MKNOD_CREATES_FIFOS=no,rsync_cv_MKNOD_CREATES_FIFOS=cross)])
782 if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then
783     AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.])
784 fi
785
786 AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[
787 AC_TRY_RUN([
788 #include <stdio.h>
789 #include <sys/stat.h>
790 #include <errno.h>
791 main() { int rc, ec; char *fn = "sock-test";
792 unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn);
793 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
794 return 0;}],
795            rsync_cv_MKNOD_CREATES_SOCKETS=yes,rsync_cv_MKNOD_CREATES_SOCKETS=no,rsync_cv_MKNOD_CREATES_SOCKETS=cross)])
796 if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then
797     AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.])
798 fi
799
800 #
801 # The following test was mostly taken from the tcl/tk plus patches
802 #
803 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
804 rm -rf conftest*
805 cat > conftest.$ac_ext <<EOF
806 int main() { return 0; }
807 EOF
808 ${CC-cc} -c -o conftest..o conftest.$ac_ext
809 if test -f conftest..o; then
810     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
811 else
812     rsync_cv_DASHC_WORKS_WITH_DASHO=no
813 fi
814 rm -rf conftest*
815 ])
816 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
817     OBJ_SAVE="#"
818     OBJ_RESTORE="#"
819     CC_SHOBJ_FLAG='-o $@'
820 else
821     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
822     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
823     CC_SHOBJ_FLAG=""
824 fi
825
826 AC_SUBST(OBJ_SAVE)
827 AC_SUBST(OBJ_RESTORE)
828 AC_SUBST(CC_SHOBJ_FLAG)
829 AC_SUBST(BUILD_POPT)
830
831 AC_CHECK_HEADERS(sys/acl.h acl/libacl.h)
832 AC_CHECK_FUNCS(_acl __acl _facl __facl)
833 #################################################
834 # check for ACL support
835
836 AC_MSG_CHECKING([whether to support ACLs])
837 AC_ARG_ENABLE(acl-support,
838         AC_HELP_STRING([--disable-acl-support],
839                        [disable ACL support]))
840
841 if test x"$enable_acl_support" = x"no"; then
842     AC_MSG_RESULT(no)
843 else
844     case "$host_os" in
845     *sysv5*)
846         AC_MSG_RESULT(Using UnixWare ACLs)
847         AC_DEFINE(HAVE_UNIXWARE_ACLS, 1, [true if you have UnixWare ACLs])
848         AC_DEFINE(SUPPORT_ACLS, 1, [Define to 1 to add support for ACLs])
849         ;;
850     *solaris*|*cygwin*)
851         AC_MSG_RESULT(Using solaris ACLs)
852         AC_DEFINE(HAVE_SOLARIS_ACLS, 1, [true if you have solaris ACLs])
853         AC_DEFINE(SUPPORT_ACLS, 1)
854         ;;
855     *hpux*)
856         AC_MSG_RESULT(Using HPUX ACLs)
857         AC_DEFINE(HAVE_HPUX_ACLS, 1, [true if you have HPUX ACLs])
858         AC_DEFINE(SUPPORT_ACLS, 1)
859         ;;
860     *irix*)
861         AC_MSG_RESULT(Using IRIX ACLs)
862         AC_DEFINE(HAVE_IRIX_ACLS, 1, [true if you have IRIX ACLs])
863         AC_DEFINE(SUPPORT_ACLS, 1)
864         ;;
865     *aix*)
866         AC_MSG_RESULT(Using AIX ACLs)
867         AC_DEFINE(HAVE_AIX_ACLS, 1, [true if you have AIX ACLs])
868         AC_DEFINE(SUPPORT_ACLS, 1)
869         ;;
870     *osf*)
871         AC_MSG_RESULT(Using Tru64 ACLs)
872         AC_DEFINE(HAVE_TRU64_ACLS, 1, [true if you have Tru64 ACLs])
873         AC_DEFINE(SUPPORT_ACLS, 1)
874         LIBS="$LIBS -lpacl"
875         ;;
876     darwin*)
877         AC_MSG_RESULT(Using OS X ACLs)
878         AC_DEFINE(HAVE_OSX_ACLS, 1, [true if you have Mac OS X ACLs])
879         AC_DEFINE(SUPPORT_ACLS, 1)
880         ;;
881     *)
882         AC_MSG_RESULT(running tests:)
883         AC_CHECK_LIB(acl,acl_get_file)
884             AC_CACHE_CHECK([for ACL support],samba_cv_HAVE_POSIX_ACLS,[
885             AC_TRY_LINK([#include <sys/types.h>
886 #include <sys/acl.h>],
887 [ acl_t acl; int entry_id; acl_entry_t *entry_p; return acl_get_entry( acl, entry_id, entry_p);],
888 samba_cv_HAVE_POSIX_ACLS=yes,samba_cv_HAVE_POSIX_ACLS=no)])
889         AC_MSG_CHECKING(ACL test results)
890         if test x"$samba_cv_HAVE_POSIX_ACLS" = x"yes"; then
891             AC_MSG_RESULT(Using posix ACLs)
892             AC_DEFINE(HAVE_POSIX_ACLS, 1, [true if you have posix ACLs])
893             AC_DEFINE(SUPPORT_ACLS, 1)
894             AC_CACHE_CHECK([for acl_get_perm_np],samba_cv_HAVE_ACL_GET_PERM_NP,[
895                 AC_TRY_LINK([#include <sys/types.h>
896 #include <sys/acl.h>],
897 [ acl_permset_t permset_d; acl_perm_t perm; return acl_get_perm_np( permset_d, perm);],
898 samba_cv_HAVE_ACL_GET_PERM_NP=yes,samba_cv_HAVE_ACL_GET_PERM_NP=no)])
899             if test x"$samba_cv_HAVE_ACL_GET_PERM_NP" = x"yes"; then
900                 AC_DEFINE(HAVE_ACL_GET_PERM_NP, 1, [true if you have acl_get_perm_np])
901             fi
902         else
903             if test x"$enable_acl_support" = x"yes"; then
904                 AC_MSG_ERROR(Failed to find ACL support)
905             else
906                 AC_MSG_RESULT(No ACL support found)
907             fi
908         fi
909         ;;
910     esac
911 fi
912
913 AC_CHECK_HEADERS(attr/xattr.h)
914 AC_CHECK_HEADERS(sys/xattr.h)
915 AC_CHECK_HEADERS(sys/extattr.h)
916
917 #################################################
918 # check for extended attribute support
919 AC_MSG_CHECKING(whether to support extended attributes)
920 AC_ARG_ENABLE(xattr-support,
921     AC_HELP_STRING([--disable-xattr-support],
922             [disable extended attributes]),
923     [], [case "$ac_cv_func_getxattr$ac_cv_func_extattr_get_link" in
924         *yes*) enable_xattr_support=maybe ;;
925         *) enable_xattr_support=no ;;
926         esac])
927 AH_TEMPLATE([SUPPORT_XATTRS],
928 [Define to 1 to add support for extended attributes])
929 if test x"$enable_xattr_support" = x"no"; then
930     AC_MSG_RESULT(no)
931 else
932     case "$host_os" in
933     *linux*)
934         AC_MSG_RESULT(Using Linux xattrs)
935         AC_DEFINE(HAVE_LINUX_XATTRS, 1, [True if you have Linux xattrs])
936         AC_DEFINE(SUPPORT_XATTRS, 1)
937         ;;
938     darwin*)
939         AC_MSG_RESULT(Using OS X xattrs)
940         AC_DEFINE(HAVE_OSX_XATTRS, 1, [True if you have Mac OS X xattrs])
941         AC_DEFINE(SUPPORT_XATTRS, 1)
942         ;;
943     freebsd*)
944         AC_MSG_RESULT(Using FreeBSD extattrs)
945         AC_DEFINE(HAVE_FREEBSD_XATTRS, 1, [True if you have FreeBSD xattrs])
946         AC_DEFINE(SUPPORT_XATTRS, 1)
947         ;;
948     *)
949         if test x"$enable_xattr_support" = x"yes"; then
950             AC_MSG_ERROR(Failed to find extended attribute support)
951         else
952             AC_MSG_RESULT(No extended attribute support found)
953         fi
954         ;;
955     esac
956 fi
957
958 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
959 AC_OUTPUT
960
961 AC_MSG_RESULT()
962 AC_MSG_RESULT([    rsync ${RSYNC_VERSION} configuration successful])
963 AC_MSG_RESULT()